         COPY  LCGASMSW                                                 00050001
IFG0552V CSECT                                                          00400021
*                                                                       00500021
*********************************************************************** 00600021
*                                                                     * 00650001
*          VS1 RELEASE 2.6 DELETIONS                                  * 00660002
*0000375000,475000-479000,498000-506000,543000-544000,          XA00825 00670001
*    592000-599000,615120-615280                                XA00825 00680001
*0000                                                            XM2945 00690002
*                                                                     * 00700021
*          VS2 RELEASE 2.6 DELETIONS                                  * 00750001
*0000      REFER TO XA00825                                     YA00332 00760001
*                                                                     * 00800021
*          RELEASE 25 DELETIONS/CHANGES                               * 00900021
*          RELEASE 24 DELETIONS/CHANGES                               * 01000021
*          RELEASE 23 DELETIONS/CHANGES                               * 01100021
*          RELEASE 22 DELETIONS/CHANGES                               * 01200021
*          RELEASE 21.7 DELETIONS/CHANGES                               01250000
*0000                                                           SA56485 01260000
*0000      REFER TO XA00825                                     SA59475 01270001
*0000                                                           SA59750 01270101
*0000615040-615120                                              SA61313 01280101
*          RELEASE 21 DELETIONS/CHANGES                               * 01300021
*0000                                                            M0025  01350021
*                                                              SA47382* 01360021
*                                                                     * 01400021
* STATUS CHANGE LEVEL 000                                             * 01500021
*                                                                     * 01600021
* FUNCTION -                                                          * 01700021
*    THIS MODULE CONTAINS THE FOLLOWING FUNCTIONS -                   * 01800021
*       1. 'EOV TAPE INPUT VOLUME DISPOSITION FUNCTION', PART II;     * 01900021
*       2. 'EOV TAPE INPUT VOLUME POSITIONING FUNCTION'.              * 02000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)' FOR DETAILS.         * 02100021
*                                                                     * 02200021
* ENTRY POINTS -                                                      * 02300021
*         IFG0552V                                                    * 02400021
*                                                                     * 02500021
* INPUT -                                                             * 02600021
*    REGISTER 14 ('RET') WILL CONTAIN ONE OF THE BRANCH TABLE OFFSETS * 02700021
*    LISTED BELOW, THE BRANCH TABLE BEING USED TO DETERMINE AT WHICH  * 02800021
*    POINT PROCESSING IS TO BEGIN -                                   * 02900021
*       0 - ENTRY FROM IFG0552T OR IFG0552X TO COMPLETE PROCESSING    * 03000021
*           ON THE CURRENT VOLUME;                                    * 03100021
*       4 - ENTRY FROM IFG0553B (ALIAS FOR IFG0202H) TO COMPLETE      * 03200021
*           PROCESSING ON THE CURRENT VOLUME FOLLOWING SMF            * 03300021
*           PROCESSING.                                               * 03400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 03500021
*                                                                     * 03600021
* OUTPUT -                                                            * 03700021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 03800021
*                                                                     * 03900021
* EXTERNAL REFERENCES -                                               * 04000021
*         IFG055RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 04100021
*                    WAIT. REFER TO THE FOLLOWING 'FUNCTION           * 04200021
*                    PROLOG(S)'.                                      * 04300021
*                                                                     * 04400021
* EXITS, NORMAL -                                                     * 04500021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 04600021
*                                                                     * 04700021
* EXITS, ERROR -                                                      * 04800021
*          IFG0550P - WHEN AN ERROR CONDITION OCCURS IN THIS MODULE.  * 04900021
*                     REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.    * 05000021
*                                                                     * 05100021
* TABLES/WORK AREAS -                                                 * 05200021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05300021
*                                                                     * 05400021
* ATTRIBUTES -                                                        * 05500021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 05600021
*                                                                     * 05700021
* CHARACTER CODE DEPENDENCY -                                         * 05800021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 05900021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 06000021
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 06100021
*                                                                     * 06200021
* NOTES -                                                             * 06300021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 06400021
*                                                                     * 06500021
*********************************************************************** 06600021
*                                                                       06700021
*****    INTERNAL ERROR CODES                                           06800021
*                                                                       06900021
EABD151  EQU   151                      ERROR POSITIONING FOR LEAVE     07000021
EABD152  EQU   152                      ERROR POSITIONING FOR REREAD    07100021
EABD153  EQU   153                      ERROR POSITIONING FOR 'PASS'    07200021
EABD154  EQU   154                      ERROR UNLOADING FOR 'KEEP'      07300021
EABD155  EQU   155                      ERROR REWINDING FOR COBOL       07400021
*                                       ..REWIND OR 'DELETE'            07500021
*                                                                       07600021
         BALR  RBASE,0                  ESTABLISH ADDRESSABILITY        07700021
         USING *,RBASE                                                  07800021
         USING FORCORE,RCORE                                            07900021
         USING IHADCB,RDCB                                              08000021
         USING UCB,RUCB                                                 08100021
         USING TIOENTRY,RTIOT                                           08200021
         USING DEB,RDEB                                                 08300021
         USING WTG,RWTG                                                 08400021
*                                                                       08500021
         B     ETI08000(RET)            DETERMINE WHERE TO CONT PROCESS 08600021
ETI08000 EQU   *                                                        08700021
         B     ETI08100            (0)  BR IF NORMAL ENTRY              08800021
         B     ETI08100            (4)  BR IF RETURN FROM SMF MODULE    08900021
         EJECT                                                          09000021
*********************************************************************** 09100021
*                                                                     * 09200021
*                          FUNCTION PROLOG                            * 09300021
*                                                                     * 09400021
*********************************************************************** 09500021
*                                                                     * 09600021
* FUNCTION NAME -                                                     * 09700021
*    'EOV TAPE INPUT VOLUME DISPOSITION FUNCTION', PART II            * 09800021
*                                                                     * 09900021
* (STATUS) -                                                          * 10000021
*    NOT APPLICABLE                                                   * 10100021
*                                                                     * 10200021
* FUNCTION -                                                          * 10300021
*    1. THE FOLLOWING FUNCTIONS ARE PERFORMED IN THIS MODULE BECAUSE  * 10400021
*       NO CONTROL BLOCK FIELDS MAY BE MODIFIED UNTIL AFTER SMF       * 10500021
*       PROCESSING HAS TAKEN PLACE-                                   * 10600021
*       A. IF THE DCB CONTAINS A TAPE-DEPENDENT SECTION, ZERO THE     * 10700021
*          BLOCK COUNT IN THE DCB;                                    * 10800021
*       B. INCREMENT (READ FORWARD) OR DECREMENT ('RDBACK') BY '1'    * 10900021
*          THE VOLUME SEQUENCE COUNT IN THE DEB;                      * 11000021
*       C. IF THE DCB IS OPENED FOR 'RDBACK' AND THE NEXT VOLUME WILL * 11100021
*          BE THE LAST ONE (I.E., FIRST PHYSICAL VOLUME OF THE DATA   * 11200021
*          SET), THE FILE SEQUENCE NUMBER THAT IS BEING SAVED IN THE  * 11300021
*          WORK AREA IS SET EQUAL TO THE FILE SEQUENCE COUNT THAT IS  * 11400021
*          BEING SAVED IN THE WORK AREA.                              * 11500021
*                                                                     * 11600021
* ENTRY POINTS -                                                      * 11700021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 11800021
*                                                                     * 11900021
* INPUT -                                                             * 12000021
*    1. REGISTER CONTENTS AT ENTRY ARE AS FOLLOWS-                    * 12100021
*       'RDCB' - ADDRESS OF THE DCB BEING PROCESSED;                  * 12200021
*       'RCORE'- ADDRESS OF THE WORK AREA FOR THAT DCB;               * 12300021
*       'RES'  - ADDRESS OF THE OPEN/CLOSE/EOV RESIDENT ROUTINE;      * 12400021
*       'RWTG' - ADDRESS OF THE WHERE-TO-GO TABLE;                    * 12500021
*       'RPARC'- ADDRESS OF THE EOV PSEUDO PARAMETER LIST ENTRY;      * 12600021
*       'RWTGC'- ADDRESS OF THE CURRENT WHERE-TO-GO TABLE ENTRY;      * 12700021
*       'RTIOT'- ADDRESS OF THE CURRENT TIOT ENTRY FOR THE DCB;       * 12800021
*       'RUCB' - ADDRESS OF THE CURRENT UCB FOR THE DCB;              * 12900021
*       'RDEB' - ADDRESS OF THE DCB'S DEB;                            * 13000021
*                                                                     * 13100021
* OUTPUT -                                                            * 13200021
*    1. AT EXIT TO PART II OF THIS MODULE, THE 'EOV TAPE INPUT VOLUME * 13300021
*       POSITIONING FUNCTION', REGISTER CONTENTS ARE VIRTUALLY THE    * 13400021
*       SAME AS AT ENTRY AND CONTROL BLOCK AND WORK AREA CONTENTS ARE * 13500021
*       INDICATED UNDER 'FUNCTION'.                                   * 13600021
*                                                                     * 13700021
* EXTERNAL REFERENCES -                                               * 13800021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 13900021
*                                                                     * 14000021
* EXITS, NORMAL -                                                     * 14100021
*    PART II OF THIS MODULE- 'EOV TAPE INPUT VOLUME POSITIONING       * 14200021
*    FUNCTION'                                                        * 14300021
*                                                                     * 14400021
* EXITS, ERROR -                                                      * 14500021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 14600021
*                                                                     * 14700021
* TABLES/WORK AREAS -                                                 * 14800021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 14900021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 15000021
*                                                                     * 15100021
* ATTRIBUTES -                                                        * 15200021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 15300021
*                                                                     * 15400021
* CHARACTER CODE DEPENDENCY -                                         * 15500021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 15600021
*                                                                     * 15700021
* NOTES -                                                             * 15800021
*    PART I OF THIS MODULE IS LOCATED IN IFG0552R.                    * 15900021
*                                                                     * 16000021
*********************************************************************** 16100021
*                                                                       16200021
*********************************************************************** 16300021
*              COMPLETE PROCESSING ON CURRENT VOLUME                  * 16400021
*********************************************************************** 16500021
*                                                                       16600021
ETI08100 EQU   *                                                        16700021
         L     RUCB,TIOESTTB            INSURE CORRECT TIOT ADDR M0025  16750021
         TM    DCBMACRF,DCBMEXCP        IS THE ACCESS METHOD EXCP-      16800021
         BZ    ETI08200                 ..BR IF NOT TO ZERO BLK CT      16900021
         TM    DCBMACRF+1,DCBMDEV       IS THERE A TAPE DEPEND SECTION- 17000021
         BZ    ETI08300                 ..BR IF NONE- CAN'T ZERO BLK CT 17100021
ETI08200 EQU   *                                                        17200021
         XC    DCBBLKCT,DCBBLKCT        ZERO BLOCK COUNT IN DCB         17300021
ETI08300 EQU   *                                                        17400021
         TM    DCBOFLGS,DCBOCON         IS CONCATENATION IN PROGRESS-   17500021
         BO    ETI08600                 ..BR IF YES TO POSITION VOL     17600021
         TM    DCBOFLGS,DCBORDBK        IS THIS 'READBACK' MODE-        17700021
         BO    ETI08400                 ..BR IF YES TO DECR DEB VOL SEQ 17800021
         LH    RC,DEBTVLSQ              LOAD VOLUME SEQ NO. FROM DEB,   17900021
         LA    RC,K1(,RC)               ..INCR IT FOR FORWARD READ,     18000021
         STH   RC,DEBTVLSQ              ..STORE IT BACK IN DEB          18100021
         B     ETI08500                 BR TO POSITION VOL AT E-O-V     18200021
ETI08400 EQU   *                                                        18300021
         LH    RC,DEBTVLSQ              LOAD VOLUME SEQ NO. FROM DEB,   18400021
         SH    RC,CNST0101              ..DECREMENT IT BY 1, THEN       18500021
         STH   RC,DEBTVLSQ              ..STORE IT BACK IN THE DEB      18600021
         CLI   DEBTVLSQ+1,K1            IS THE NEXT VOL THE LAST ONE-   18700021
         BNE   ETI08500                 ..BR IF NOT TO POSITION VOL     18800021
         MVC   DXCCW7+4(K2),DXCCW7+6    ..YES- MOVE FILE SEQ NO. TO     18900021
*                                       ..FILE SEQ CT IN WORK AREA      19000021
         TITLE 'IFG0552V - EOV TAPE INPUT VOLUME POSITIONING FUNCTION'  19100021
*********************************************************************** 19200021
*                                                                     * 19300021
*                          FUNCTION PROLOG                            * 19400021
*                                                                     * 19500021
*********************************************************************** 19600021
*                                                                     * 19700021
* FUNCTION NAME -                                                     * 19800021
*    'EOV TAPE INPUT VOLUME POSITIONING FUNCTION'                     * 19900021
*                                                                     * 20000021
* (STATUS) -                                                          * 20100021
*    NOT APPLICABLE                                                   * 20200021
*                                                                     * 20300021
* FUNCTION -                                                          * 20400021
*    1. THIS FUNCTION PERFORMS ALL VOLUME POSITIONING FOR DATA SETS   * 20500021
*       AT EOV OR EOF (WHEN CONCATENATION IS TAKING PLACE) ON AL,     * 20600021
*       NL, AND SL TAPES; NSL VOLUMES CAN ONLY BE UNLOADED. THE       * 20700021
*       FOLLOWING TERMINOLOGY APPLIES THROUGHOUT THIS FUNCTION-       * 20800021
*       A. LOGICAL END OF DATA SET-                                   * 20900021
*          FOR READ FORWARD-  THE INTERBLOCK GAP FOLLOWING EITHER THE * 21000021
*             TAPE MARK FOLLOWING THE DATA (NL) OR THE TAPE MARK      * 21100021
*             FOLLOWING THE DATA SET TRAILER LABELS (AL AND SL);      * 21200021
*          FOR 'RDBACK'- THE INTERBLOCK GAP PRECEDING EITHER THE      * 21300021
*             FIRST DATA RECORD (NL) OR HEADER LABEL 1 (AL AND SL);   * 21400021
*       B. LOGICAL BEGINNING OF DATA SET-                             * 21500021
*          FOR READ FORWARD- SAME AS FOR 'RDBACK' IN (A) ABOVE;       * 21600021
*          FOR 'RDBACK'- SAME AS FOR READ FORWARD IN (A) ABOVE.       * 21700021
*    2. POSITION ACCORDING TO ANY FEOV OPTIONS-                       * 21800021
*       A. 'REWIND'- REWIND THE TAPE;                                 * 21900021
*       B. 'LEAVE' - POSITION THE TAPE TO THE LOGICAL END OF THE DATA * 22000021
*                    SET;                                             * 22100021
*    3. POSITION ACCORDING TO ANY POSITIONING OPTION SPECIFIED IN THE * 22200021
*       OPEN MACRO-                                                   * 22300021
*       A. 'REREAD'- POSITION THE TAPE TO THE LOGICAL BEGINNING OF    * 22400021
*                    DATA SET;                                        * 22500021
*       B. 'LEAVE' - POSITION THE TAPE TO THE LOGICAL END OF THE DATA * 22600021
*                    SET;                                             * 22700021
*       C. 'DISP'  - REFER TO SECTION (4) BELOW.                      * 22800021
*    4. IF THERE ARE NONE OF THE ABOVE OPTIONS OR IF THE OPEN POSI-   * 22900021
*       TIONING OPTION IS 'DISP', POSITIONING TAKES PLACE AS FOLLOWS- * 23000021
*       A. PASSED DATA SET- POSITION THE TAPE TO THE LOGICAL END OF   * 23100021
*                           THE DATA SET;                             * 23200021
*       B. NOT PASS, PUBLIC VOLUME- REWIND THE TAPE;                  * 23300021
*       C. NOT PASS, PRIVATE VOLUME- UNLOAD THE TAPE AND ISSUE        * 23400021
*                                    MESSAGE 'IEC002E K'.             * 23500021
*    5. INCREMENT THE UCB FILE SEQUENCE COUNT AND NUMBER BY '1' EACH  * 23600021
*       WHEN THE TAPE IS POSITIONED TO THE PHYSICAL END OF THE DATA   * 23700021
*       SET.                                                          * 23800021
*    6. IF THERE ARE CONCATENATED DATA SETS, UPDATE THE DCB, DEB, AND * 23900021
*       UCB TO REFLECT THE CONCATENATED DATA SET AND TRANSFER CONTROL * 24000021
*       TO THE EOV INITIAL FUNCTION TO CONTINUE CONCATENATION.        * 24100021
*                                                                     * 24200021
* ENTRY POINTS -                                                      * 24300021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 24400021
*                                                                     * 24500021
* INPUT -                                                             * 24600021
*    1. REGISTER CONTENTS AT ENTRY ARE AS FOLLOWS-                    * 24700021
*       'RDCB' - ADDRESS OF THE DCB BEING PROCESSED;                  * 24800021
*       'RCORE'- ADDRESS OF THE WORK AREA FOR THAT DCB;               * 24900021
*       'RES'  - ADDRESS OF THE OPEN/CLOSE/EOV RESIDENT ROUTINE;      * 25000021
*       'RWTG' - ADDRESS OF THE WHERE-TO-GO TABLE;                    * 25100021
*       'RPARC'- ADDRESS OF THE EOV PSEUDO PARAMETER LIST ENTRY;      * 25200021
*       'RWTGC'- ADDRESS OF THE CURRENT WHERE-TO-GO TABLE ENTRY;      * 25300021
*       'RTIOT'- ADDRESS OF THE CURRENT TIOT ENTRY FOR THE DCB;       * 25400021
*       'RUCB' - ADDRESS OF THE CURRENT UCB FOR THE DCB;              * 25500021
*       'RDEB' - ADDRESS OF THE DCB'S DEB;                            * 25600021
*                                                                     * 25700021
* OUTPUT -                                                            * 25800021
*    1. AT EXIT TO IFG0550P (PROBLEM DETERMINATION)-                  * 25900021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 26000021
*          REGISTER 'R0' CONTAINS ONE OF THE FOLLOWING INTERNAL       * 26100021
*          ERROR CODES-                                               * 26200021
*          151- ERROR POSITIONING FOR 'LEAVE';                        * 26300021
*          152- ERROR POSITIONING FOR 'REREAD';                       * 26400021
*          153- ERROR POSITIONING A PASSED DATA SET;                  * 26500021
*          154- ERROR PERFORMING REWIND/UNLOAD FOR A NOT-PASSED DATA  * 26600021
*               SET ON A PRIVATE VOLUME;                              * 26700021
*          155- ERROR REWINDING VOLUME FOR FEOV 'REWIND' OR FOR A     * 26800021
*               NOT-PASSED DATA SET ON A PUBLIC VOLUME.               * 26900021
*       WORK AREA INDICATORS-                                         * 27000021
*          'DXCALLID' CONTAINS THE 2-BYTE ID OF THIS MODULE.          * 27100021
*    2. AT EXIT TO IFG0551F (EOV INITIAL FUNCTION)-                   * 27200021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT AS FOLLOWS- * 27300021
*          'RTIOT'- ADDRESS OF THE CONCATENATED DATA SET'S TIOT ENTRY;* 27400021
*          'RUCB' - ADDRESS OF THE CONCATENATED DATA SETS'S UCB;      * 27500021
*       CONTROL BLOCK FIELDS-                                         * 27600021
*          'DCBTIOT'  - CONTAINS THE TIOT OFFSET OF THE CONCATENATED  * 27700021
*             DATA SET'S TIOT ENTRY;                                  * 27800021
*          'DEBTVLSQ' - 1 - INDICATES FIRST VOLUME OF DATA SET;       * 27900021
*          'DEBUCBAD' - CONTAINS THE ADDRESS OF THE CONCATENATED DATA * 28000021
*             SET'S UCB IN THE 3 LOW ORDER BYTES.                     * 28100021
*          'SRTEDMCT' - 0 - INDICATES NO DATA SET OPEN ON UNIT;       * 28200021
*    3. AT EXIT TO IFG0552P (EOV TAPE MESSAGE-WRITING MODULE)-        * 28300021
*       REGISTER CONTENTS ARE THE SAME AS ENTRY EXCEPT THAT REGISTER  * 28400021
*          'RET' CONTAINS A BRANCH TABLE OFFSET OF '0' FOR RETURN     * 28500021
*          MODULE IFG0552Z (WHEN THERE IS NO CONCATENATION);          * 28600021
*       WORK AREA INDICATORS-                                         * 28700021
*          MESSAGE BUFFER- CONTAINS BASIC KEEP MESSAGE IEC002E K      * 28800021
*                          WITH THE VOLUME SERIAL NUMBER;             * 28900021
*          'DXCCW7+1' - 0 - INDICATES THAT THE DATA SET NAME FROM     * 29000021
*                           THE JFCB IS TO BE USED IF THE DATA SET    * 29100021
*                           NAME IS REQUIRED IN THE MESSAGE;          * 29200021
*          'DXRETMOD' - CONTAINS THE 5-BYTE ID/TTR OF MODULE IFG0552Z * 29300021
*                       (NO CONCATENATION) OR MODULE IFG0551F (WHEN   * 29400021
*                       THERE IS CONCATENATION;                       * 29500021
*          'SRTEVOLI' - 0 - INDICATES NO VOLUME MOUNTED;              * 29600021
*          'UCBFL2'   - X'40' - INDICATES UNIT NOT-READY.             * 29700021
*    4. AT EXIT TO IFG0552Z ( NEW VOLUME MOUNTING FUNCTION)-          * 29800021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 29900021
*          REGISTER 'RET' CONTAINS ONE OF THE FOLLOWING BRANCH TABLE  * 30000021
*          OFFSETS-                                                   * 30100021
*             '0' - NORMAL ENTRY TO MOUNT NEXT DESIRED VOLUME;        * 30200021
*             '4' - WAIT FOR COMPLETION OF A REWIND, THEN MOUNT NEXT  * 30300021
*                   DESIRED VOLUME.                                   * 30400021
*       CONTROL BLOCK INDICATORS- REFER TO (5) UNDER 'FUNCTION'.      * 30500021
*                                                                     * 30600021
* EXTERNAL REFERENCES -                                               * 30700021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 30800021
*                                                                     * 30900021
* EXITS, NORMAL -                                                     * 31000021
*         IFG0551F - TO PROCESS CONCATENATED DATA SETS;               * 31100021
*         IFG0552P - TO ISSUE KEEP MESSAGE 'IEC0002E K';              * 31200021
*         IFG0552Z - TO WAIT FOR A REWIND TO COMPLETE AND/OR MOUNT    * 31300021
*                    THE NEXT DESIRED VOLUME.                         * 31400021
*                                                                     * 31500021
* EXITS, ERROR -                                                      * 31600021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 31700021
*                                                                     * 31800021
* TABLES/WORK AREAS -                                                 * 31900021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 32000021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 32100021
*                                                                     * 32200021
* ATTRIBUTES -                                                        * 32300021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 32400021
*                                                                     * 32500021
* CHARACTER CODE DEPENDENCY -                                         * 32600021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 32700021
*                                                                     * 32800021
* NOTES -                                                             * 32900021
*                                                                     * 33000021
*********************************************************************** 33100021
         EJECT                                                          33200021
*********************************************************************** 33300021
*              CURRENT VOLUME POSITIONING                             * 33400021
*********************************************************************** 33500021
*                                                                       33600021
ETI08500 EQU   *                                                        33700021
         CLI   DXNOUNIT+1,K1            IS ONE UNIT ALLOCATED TO DS-    33800021
         BE    ETI11000                 ..BR IF YES- NO POSITIONING     33900021
ETI08600 EQU   *                                                        34000021
         TM    UCBFL2,UCBNOTRD          IS THE UNIT 'READY'-            34100021
         BO    ETI11000                 ..BR IF NOT                     34200021
         TM    JFCBLTYP,JFCNSL          WAS NSL SPECIFIED-              34300021
         BO    ETI09600                 ..BR IF YES TO AVOID FEOV POS   34400021
         NI    UCBWGT,X'FF'-UCBREW      TURN OFF THE UCB REWIND BIT     34500021
         MVI   DXCCW1,CCWFSF            INITLZ CCW FOR FWD SPACE FILE   34600021
*                                                                       34700021
*********************************************************************** 34800021
*              POSITIONING FOR FEOV                                   * 34900021
*********************************************************************** 35000021
*                                                                       35100021
         TM    DCBMACRF,DCBMEXCP        EXCP DCB                SA59750 35150001
         BO    ETI09600                 YES, BYPASS FEOV PROC   SA59750 35160001
         TM    DCBCIND2,DCBC2FEO        IS THIS AN FEOV ENTRY-          35200021
         BNO   ETI09600                 ..BR IF NOT TO CONTINUE         35300021
         TM    DXDCBLST,PLISTLV         TEST FOR COBOL/FEOV OPTIONS-    35400021
         BM    ETI09100                 ..BR IF FEOV 'REWIND'           35500021
         BO    ETI08700                 ..BR IF COBOL/FEOV 'LEAVE'      35600021
         TM    DEBOPATB,DEBOPLV         IS THERE AN 'OPEN' POS OPTION-  35700021
         BZ    ETI10500                 ..BR IF NOT                     35800021
         BM    ETI09200                 ..BR IF 'REREAD'                35900021
*                                                                       36000021
*****          POSITION FOR LEAVE FOLLOWING FORWARD READ                36100021
*                                                                       36200021
ETI08700 EQU   *                                                        36300021
         LA    RD,EABD151               LOAD INTERNAL ERROR CODE        36400021
         BAL   RC,ETI11500              INCREMENT THE FILE SEQUENCE     36500021
*                                       ..COUNT AND NUMBER IF REQ'D     36600021
         TM    DCBOFLGS,DCBORDBK        TEST FOR 'RDBACK' PROCESSING-   36700021
         BO    ETI08900                 ..BR IF YES TO HANDLE 'RDBACK'  36800021
         TM    DCBOFLGS,DCBOEOF         WAS A TAPE MARK READ-           36900021
         BO    ETI08800                 ..BR IF YES- BYPASS FIRST FSF   37000021
         BAL   RC,ETI11700              BR AND LINK TO FSF PAST TM      37100021
*                                       ..WHICH FOLLOWS DATA            37200021
ETI08800 EQU   *                                                        37300021
         TM    JFCBLTYP,JFCBAL+JFCSL    WAS AL OR SL SPECIFIED-         37400021
         BZ    ETI11000                 ..BR IF NOT             XA00825 37500001
         B     ETI10300                 ..ELSE BR TO PERFORM 'FSF' CMD  37600021
*                                                                       37700021
*****          POSITION FOR LEAVE FOLLOWING 'RDBACK'                    37800021
*                                                                       37900021
ETI08900 EQU   *                                                        38000021
         MVI   DXCCW1,CCWBSF            INITLZ CCW FOR 'BSF' COMMAND    38100021
         TM    DCBOFLGS,DCBOEOF         WAS A TAPE MARK READ-           38200021
         BO    ETI09000                 ..BR IF YES                     38300021
         BAL   RC,ETI11700              BR AND LINK TO PERFORM 'BSF'    38400021
ETI09000 EQU   *                                                        38500021
         TM    JFCBLTYP,JFCBAL+JFCSL    WAS AL OR SL SPECIFIED-         38600021
         BZ    ETI10300                 ..BR IF NOT TO FSF              38700021
         BAL   RC,ETI11700              BR AND LINK TO PERFORM 'BSF'    38800021
         B     ETI10300                 BR TO PERFORM LAST FSF          38900021
*                                                                       39000021
*****          POSITION FOR COBOL/FEOV 'REWIND'                         39100021
*                                                                       39200021
ETI09100 EQU   *                                                        39300021
         LA    RD,EABD155               REWIND ERROR CODE               39400021
         MVI   DXCCW1,CCWREW            INITLZ CCW FOR 'REWIND' CMD     39500021
         BAL   RC,ETI11700              BR AND LINK TO REWIND TAPE      39600021
         OI    UCBWGT,UCBREW            TURN ON REWIND BIT FOR TASK SCH 39700021
         LH    RC,SRTEFSEQ              CALC NEW LOGICAL FILE POSITION- 39800021
         SH    RC,SRTEFSCT              ..SUBTRACT PHYSICAL POS FROM    39900021
         AH    RC,CLCOMBSF+6            ..LOGICAL POSITION AND ADD 1,   40000021
         STH   RC,SRTEFSEQ              ..THEN STORE BACK IN UCB        40100021
         MVC   SRTEFSCT(K2),CLCOMBSF+6  SET PHYSICAL POSITION TO 1      40200021
         LA    RET,K4                   BR TABLE OFFSET FOR NEXT MODULE 40300021
         B     ETI11100                 BR- POSITIONING COMPLETE        40400021
*                                                                       40500021
*****          POSITION FOR 'REREAD' FOLLOWING FORWARD READ             40600021
*                                                                       40700021
ETI09200 EQU   *                                                        40800021
         LA    RD,EABD152               REREAD POSITIONING ERROR CODE   40900021
         TM    DCBOFLGS,DCBORDBK        IS THE DCB OPENED FOR 'RDBACK'- 41000021
         BO    ETI09400                 ..BR IF YES                     41100021
         LH    RC,UCBFSCT               GET PHYSICAL SEQ NO     XA00825 41150001
         CH    RC,CNST0101              IS IT THE FIRST FILE    XA00825 41160001
         BE    ETI10750                 YES, GO REWIND          XA00825 41170001
         MVI   DXCCW1,CCWBSF            INITLZ CCW FOR BSF COMMAND      41200021
         TM    DCBOFLGS,DCBOEOF         WAS A TAPE MARK READ-           41300021
         BNO   ETI09300                 ..BR IF NOT                     41400021
         BAL   RC,ETI11700              BR AND LINK TO BSF              41500021
ETI09300 EQU   *                                                        41600021
         TM    JFCBLTYP,JFCBAL+JFCSL    WAS SL OR AL SPECIFIED-         41700021
         BZ    ETI10000                 ..BR IF NOT TO PERFORM 1 BSF    41800021
         B     ETI09900                 ..ELSE BR TO PERFORM 2 BSF      41900021
*                                                                       42000021
*****          POSITION FOR 'REREAD' FOLLOWING 'RDBACK'                 42100021
*                                                                       42200021
ETI09400 EQU   *                                                        42300021
         TM    DCBOFLGS,DCBOEOF         WAS A TAPE MARK READ-           42400021
         BNO   ETI09500                 ..BR IF NOT-BYPASS 1ST FSF      42500021
         BAL   RC,ETI11700              BR AND LINK TO FSF              42600021
ETI09500 EQU   *                                                        42700021
         BAL   RC,ETI11600              INCREMENT UCB FILE SEQ  SA56485 42750000
*                                       COUNT AND NO.           SA56485 42760000
         TM    JFCBLTYP,JFCBAL+JFCSL    WAS SL OR AL SPECIFIED-         42800021
         BZ    ETI10300                 ..BR IF NOT- DO 1 FSF           42900021
         BAL   RC,ETI11700              BR AND LINK TO FSF              43000021
         B     ETI10300                 BR TO TO SECOND FSF             43100021
         EJECT                                                          43200021
*********************************************************************** 43300021
*              POSITION ACCORDING TO 'OPEN' OPTION 2                  * 43400021
*********************************************************************** 43500021
*                                                                       43600021
ETI09600 EQU   *                                                        43700021
         TM    DEBOPATB,DEBOPLV         TEST FOR 'OPEN' OPTION 2        43800021
         BZ    ETI10500                 ..BR IF NONE SPECIFIED          43900021
         TM    JFCBLTYP,JFCNSL          WAS NSL SPECIFIED-              44000021
         BO    ETI11000                 ..BR IF YES- DON'T POS FOR NSL  44100021
         TM    DEBOPATB,DEBOPLV         WAS 'REREAD' SPECIFIED-         44200021
         BM    ETI09700                 ..BR IF YES                     44300021
*                                                                       44400021
*****          POSITION FOR 'OPEN' OPTION 2 'LEAVE'                     44500021
*                                                                       44600021
ETI09650 EQU   *                                                        44700021
         BAL   RC,ETI11500              BR AND LINK TO INCR SEQ CT/NO.  44800021
*                                       ..IF IN READ FORWARD MODE       44900021
         TM    JFCBLTYP,JFCBAL+JFCSL    WAS SL OR AL SPECIFIED-         45000021
         BM    ETI11000                 ..BR IF YES- POS COMPLETE       45100021
         TM    DCBOFLGS,DCBORDBK        IS THE DCB OPENED FOR 'RDBACK'- 45200021
         BZ    ETI11000                 ..BR IF NOT- POS COMPLETE       45300021
         TM    DCBOFLGS,DCBOEOF         WAS A TAPE MARK READ-           45400021
         BZ    ETI11000                 ..BR IF NOT- POS COMPLETE       45500021
         B     ETI10300                 BR TO FSF PAST LEADING TAPE MK  45600021
*                                                                       45700021
*****          POSITION FOR 'OPEN' OPTION 2 'REREAD' FOLLOWING FWD READ 45800021
*                                                                       45900021
ETI09700 EQU   *                                                        46000021
         LA    RD,EABD152               LOAD INTERNAL ERROR CODE        46100021
         TM    DCBOFLGS,DCBORDBK        IS THE DCB OPENED FOR 'RDBACK'- 46200021
         BO    ETI10200                 ..BR IF YES                     46300021
         LH    RC,UCBFSCT               GET PHYSICAL SEQ NO     XA00825 46350001
         CH    RC,CNST0101              IS IT THE FIRST FILE    XA00825 46360001
         BE    ETI10750                 YES, GO REWIND          XA00825 46370001
         MVI   DXCCW1,CCWBSF            INITLZ CCW FOR BACKSPACE FILE   46400021
         TM    JFCBLTYP,JFCBAL+JFCSL    WAS AL OR SL SPECIFIED-         46500021
         BZ    ETI09900                 ..BR IF NOT TO DO 2 BSF         46600021
         BAL   RC,ETI11700              BR AND LINK TO BACKSPACE FILE   46700021
ETI09800 EQU   *                                                        46800021
         BAL   RC,ETI11700              BR AND LINK TO BACKSPACE FILE   46900021
ETI09900 EQU   *                                                        47000021
         BAL   RC,ETI11700              BR AND LINK TO BACKSPACE FILE   47100021
ETI10000 EQU   *                                                        47200021
         BAL   RC,ETI11700              BR AND LINK TO BACKSPACE FILE   47300021
ETI10100 EQU   *                                                        47400021
         B     ETI10300                 ..BR IF NOT TO BYPASS LEAD TM   48000021
*                                                                       48100021
*****          POSITION FOR 'OPEN OPTION 2' 'REREAD' FOLLOWING 'RDBACK' 48200021
*                                                                       48300021
ETI10200 EQU   *                                                        48400021
         BAL   RC,ETI11600              BR AND LINK TO INCR SEQ CT/NO.  48500021
         MVI   DXCCW1,CCWFSF            INITLZ CCW FOR 'FSF' COMMAND    48600021
         TM    JFCBLTYP,JFCBAL+JFCSL    WAS AL OR SL SPECIFIED-         48700021
         BZ    ETI10250                 ..BR IF NOT- BYPASS FIRST FSF   48800021
         BAL   RC,ETI11700              BR AND LINK TO FWD SPACE FILE   48900021
ETI10250 EQU   *                                                        49000021
         TM    DCBOFLGS,DCBOEOF         WAS A TAPE MARK READ-           49100021
         BNO   ETI10300                 ..BR IF NOT- BYPASS FSF         49200021
         BAL   RC,ETI11700              BR AND LINK TO FSF              49300021
ETI10300 EQU   *                                                        49400021
         MVI   DXCCW1,CCWFSF            INITLZ CCW FOR 'FSF' COMMAND    49500021
*                                       ..(ENTRY MAY FOLLOW 'BSF' CMD)  49600021
         BAL   RC,ETI11700              BR AND LINK TO FWD SPACE FILE   49700021
         B     ETI11000                 BR- POSITIONING COMPLETE        50700021
*                                                                       50800021
*********************************************************************** 50900021
*              POSITION ACCORDING TO DATA SET DISPOSITION-            * 51000021
*              NO 'OPEN' OPTION 2 WAS SPECIFIED                       * 51100021
*********************************************************************** 51200021
*                                                                       51300021
ETI10500 EQU   *                                                        51400021
         TM    SRTESTAT,SRTERESV        IS CURRENT VOLUME RESERVED-     51500021
         BO    ETI10600                 ..BR IF YES                     51600021
         TM    UCBWGT,UCBREW            HAS A REWIND BEEN PERFORMED-    51700021
         BO    ETI11000                 ..BR IF YES- ALL DONE           51800021
         CLI   SRTEJBNR,K0              IS THE DISPOSITION 'PASS'-      51900021
         BE    ETI10700                 ..BR IF NOT                     52000021
*                                                                       52100021
*****          POSITION A DATA SET WITH DISPOSITION 'PASS' OR           52200021
*****          A DATA SET ON A RESERVED VOLUME                          52300021
*                                                                       52400021
ETI10600 EQU   *                                                        52500021
         LA    RD,EABD153               LOAD INTERNAL ERROR CODE        52600021
         TM    JFCBLTYP,JFCNSL          WAS NSL SPECIFIED-              52700021
         BO    ETI11000                 ..BR IF YES- ALL DONE           52800021
         TM    DCBMACRF,DCBMEXCP        EXCP DCB                SA59750 52850001
         BO    ETI09650                 YES, FINISH EOV POS     SA59750 52860001
         TM    DCBCIND2,DCBC2FEO        WAS 'FEOV' ISSUED-              52900021
         BO    ETI08700                 ..BR IF YES TO FINISH FEOV POS  53000021
         B     ETI09650                 ..ELSE BR TO FINISH EOV POS     53100021
*                                                                       53200021
*****          POSITION A DATA SET WITH DISPOSITION 'DELETE'            53300021
*****          ( TEMPORARY DATA SET ON A PUBLIC VOLUME )                53400021
*                                                                       53500021
ETI10700 EQU   *                                                        53600021
         TM    SRTESTAB,UCBBPRV         IS THE VOLUME 'PRIVATE'-        53700021
         BO    ETI10800                 ..BR IF YES TO ISSUE 'DEMOUNT'  53800021
         MVC   UCBFSCT(K4),CNST0101     SET BOTH UCB FILE SEQ   XA00825 53850001
*                                        COUNT AND NUMBER TO 1  XA00825 53860001
ETI10750 EQU   *                                                        53870001
         MVI   DXCCW1,CCWREW            INITLZ CCW FOR 'REWIND' COMMAND 53900021
         OI    UCBWGT,UCBREW            TURN ON REWIND BIT FOR TSK/SCHD 54000021
         LA    RD,EABD155               LOAD 'REWIND' ERROR CODE        54100021
         BAL   RC,ETI11700              BR TO INITIATE 'REWIND'         54200021
         LA    RET,K4                   BR TABLE OFFSET FOR NEXT MOD    54500021
         B     ETI11100                 BR TO XCTL TO MT MODULE TO      54600021
*                                       ..TO WAIT FOR REWIND TO END     54700021
*                                                                       54800021
*****          POSITION A DATA SET WITH DISPOSITION 'KEEP'              54900021
*****          ( VOLUME IS 'PRIVATE' AND DATA SET IS NOT 'PASSED' )     55000021
*                                                                       55100021
ETI10800 EQU   *                                                        55200021
         MVC   MCSFLAGS(K12),KEEP2V     MOVE BASIC KEEP MSG INTO BUF    55300021
         MVC   MSGVOLSR(MVOLL),SRTEVOLI PUT VOLUME SERIAL NO. IN MSG    55400021
         MVI   DXCCW1,CCWRUN            INITLZ CCW FOR 'REWIND/UNLOAD'  55500021
         LA    RD,EABD154               LOAD INTERNAL ERROR CODE        55600021
         BAL   RC,ETI11700              BR AND LINK TO INITIATE 'RUN'   55700021
         XC    SRTEVOLI(K6),SRTEVOLI    CLEAR VOLUME SERIAL NUMBER      55800021
         XC    SRTEFSCT(K4),SRTEFSCT    CLEAR FILE SEQ COUNT AND NUMBER 55900021
         OI    UCBFL2,UCBNOTRD          SET TO NOT READY                56000021
         SR    RET,RET                  BR TABLE OFFSET FOR NEXT MOD    56100021
*                                                                       56200021
*********************************************************************** 56300021
*              EXITS                                                  * 56400021
*********************************************************************** 56500021
*                                                                       56600021
*****          PREPARE TO XCTL TO ISSUE A KEEP MESSAGE                  56700021
*                                                                       56800021
ETI10900 EQU   *                                                        56900021
         LA    RF,MODWTO2V              PT TO ID/TTR OF WTO MOD         57000021
         MVC   DXRETMOD(K5),MOD2V2Z     MOVE ID/TTR OF NEXT MODULE INTO 57100021
*                                       ..RETURN ADDRESS SAVE AREA      57200021
         TM    DCBOFLGS,DCBOCON         IS THIS A CONCATENATED DATA SET 57300021
         BZ    ETI11400                 ..BR IF NOT TO EXIT             57400021
         MVC   DXRETMOD(K5),MOD2V1F     MOVE INIT MODULE'S ID/TTR INTO  57500021
*                                       ..RETURN ADDRESS SAVE AREA      57600021
         B     ETI11350                 BR TO FINISH CONCATENATION      57700021
         EJECT                                                          57800021
*                                                                       57900021
*****          PREPARE TO XCTL TO NEW-VOLUME MOUNTING MODULE            58000021
*****          OR TO INITIALIZATION MODULE ( CONCATENATED DATA SETS )   58100021
*                                                                       58200021
ETI11000 EQU   *                                                        58300021
         SR    RET,RET                  CLEAR BR TABLE OFFSET REG       58400021
ETI11100 EQU   *                                                        58500021
         LA    RF,MOD2V2Z               PT TO ID/TTR OF VOL-MT MODULE   58600021
         TM    DCBOFLGS,DCBOCON         IS CONCATENATION IN PROGRESS-   58700021
         BZ    ETI11400                 ..BR IF NOT TO EXIT             58800021
*                                                                       58900021
*****          COMPLETE CONCATENATION PROCESSING                        59000021
*                                                                       59100021
*                                                                       60000021
*****          INITIALIZE DCB AND DEB FOR CONCATENATED DATA SET         60100021
*                                                                       60200021
ETI11300 EQU   *                                                        60300021
         LA    RF,MOD2V1F               PT TO ID/TTR OF INITIAL MOD     60400021
ETI11350 EQU   *                                                        60500021
         MVI   DEBTVLSQ+1,K1            SET DEB VOL SEQ NO. TO 1        60600021
*                                       ..FOR CONCATENATED DATA SET     60700021
         SR    RC,RC                    LOAD TIOT OFFSET OF CONCATEN-   60800021
         IC    RC,TIOELNGH              ..ATED ENTRY FROM CURRENT ENTRY 60900021
         AR    RTIOT,RC                 CALC NEW TIOT ENTRY ADDR        61000021
         AH    RC,DCBTIOT               CALC NEW DCBTIOT OFFSET         61100021
         STH   RC,DCBTIOT               ..AND SAVE IN DCBTIOT           61200021
         MVC   DEBUCBAD+1(K3),TIOEFSRT  PLACE NEW UCB ADDR INTO DEB     61300021
         SR    RET,RET                  CLEAR REG               SA47382 61350000
ETI11400 EQU   *                                                        61400021
         NI    SRTEDMCT,X'FF'-K1        SET DM COUNT TO 0               61500021
*                                                                       61532021
*              ROTATE UCB POINTERS IN TIOT TO SPREAD OUT USEAGE         61536021
*              OF ALLOCATED UNITS. THIS ALLOWS THE NEXT TAPE TO         61540021
*              BE MOUNTED IMMEDIATELY, EVEN IF THE PREVIOUS TAPE        61544021
*              IS IN THE PROCESS OF DOING A REWIND AND UNLOAD.          61548021
*                                                                       61552021
ETI11450 EQU   *                                                        61556021
         TM    DCBOFLGS,DCBOCON         IS CONCATENATION         XM2945 61558002
         BNZ   ETI11470                 BR IF SO TO EXIT         XM2945 61558402
         LH    RD,DXNOUNIT              LOAD NO. OF UNITS       SA47382 61560021
         SLL   RD,K2                    CALC NO. OF BYTES TO    SA47382 61564021
*                                       ..MOVE                          61568021
         BCTR  RD,0                     DECR FOR 'EXECUTE'      SA47382 61572021
         EX    RD,ROTATE                MOVE UCB ADDR LEFT      SA47382 61576021
         LA    RD,K1(,RD)               ADD 1 TO NO. OF UNITS   SA47382 61580021
         ST    RUCB,TIOESTTB-4(RD)      OLD UCB PT TO END OF    SA47382 61584021
*                                       ..TIOT                          61588021
         LTR   RET,RET                  TEST TO MOUNT NEXT      SA61313 61588401
*                                       ..VOLUME                SA61313 61588801
         BZ    ETI11470                 BR TO MOUNT, ELSE WAIT  SA61313 61589201
*                                       ..FOR REWIND            SA61313 61589601
         LA    RET,K4                   SET BR TABLE OFFSET     SA47382 61590000
         LA    RF,MOD2V2Z               POINT TO MOD ID         SA47382 61592000
*                                                                       61598021
ETI11470 EQU   *                                                SA47382 61598421
         IECRES XCTL,(RF),(RET)         INVOKE IECRES MACRO TO 'XCTL'   61600021
*                                                                       61650000
ROTATE   EQU   *                                                SA47382 61660021
         MVC   TIOESTTB(K0),TIOESTTB+4  SHIFT UCB ADDR LIST     SA47382 61670021
*                                       ..LEFT                          61680021
         EJECT                                                          61700021
*********************************************************************** 61800021
*              SUBROUTINES                                            * 61900021
*********************************************************************** 62000021
*                                                                       62100021
*****          INCREMENT THE UCB FILE SEQUENCE COUNT AND NUMBER         62200021
*                                                                       62300021
ETI11500 EQU   *                                                        62400021
         TM    DCBOFLGS,DCBORDBK        IS THE DCB OPENED FOR 'RDBACK'- 62500021
         BCR   1,RC                     ..BR IF YES TO RET TO CALLER    62600021
ETI11600 EQU   *                                                        62700021
         L     RF,SRTEFSCT              LD THE UCB FILE SEQ CT AND NO., 62800021
         A     RF,CNST0101              ..INCR EACH NUMBER BY 1, THEN   62900021
         ST    RF,SRTEFSCT              ..STORE THEM BACK IN THE UCB    63000021
         BR    RC                       RETURN TO CALLER                63100021
         SPACE 2                                                        63200021
*                                                                       63300021
*****          CLOSED SUBROUTINE TO PERFORM I/O OPERATIONS              63400021
*****          ENTRY TO THE SUBROUTINE IS VIA A 'BAL  RC,ETI11700'      63500021
*                                                                       63600021
ETI11700 EQU   *                                                        63700021
         EXCP  DXIOB                    PERFORM I/O OPERATION           63800021
         IECRES WAIT                    INVOKE IECRES MACRO TO 'WAIT'   63900021
         TM    DXECB,ECBNOERR           WAS THERE A PERMANENT I/O ERR-  64000021
         BCR   1,RC                     ..BR IF NOT- RETURN TO CALLER   64100021
         TM    IOBSENS1,UCBLDPT         IS THE TAPE AT 'LOAD POINT'-    64200021
         BCR   1,RC                     ..BR IF YES- RETURN TO CALLER   64300021
*                                       ..ELSE DROP THROUGH TO ERR RTN  64400021
         SPACE 2                                                        64500021
*********************************************************************** 64600021
*              ERROR PROCESSING                                       * 64700021
*********************************************************************** 64800021
*                                                                       64900021
ETI11800 EQU   *                                                        65000021
         DMABCOND (RD),ABEND2V          EXIT TO PROB DETERMINATION RTN  65100021
         EJECT                                                          65200021
*********************************************************************** 65300021
*              CONSTANTS                                              * 65400021
*********************************************************************** 65500021
*                                                                       65600021
CLCOMBSF CCW   X'2F',0,X'20',1          BACKSPACE FILE CCW              65700021
CNST0101 DC    F'65537'                 THE HEXADECIMAL FULLWORD '00010 65800021
AEOF13   DC    C'EOF'                   E-O-F LABEL IDENTIFIER          65900021
EOVMARK  DC    C'EOV'                   'EOV' TRAILER LABEL IDENTIFIER  66000021
KEEP2V   DC    X'8000'                  MCS FLAGS FOR KEEP MSG          66100021
         DC    C'IEC002E K '            BASIC KEEP MESSAGE              66200021
         SPACE 2                                                        66300021
*********************************************************************** 66400021
*              XCTL TABLE                                             * 66500021
*********************************************************************** 66600021
*                                                                       66700021
XCTLTB2V XCTLTABL ID=(ABEND2V,0P,MOD2V1F,1F,MODWTO2V,2P,MOD2V2Z,2Z),   C66800021
               SVC=055                                                  66900021
         SPACE 2                                                        67000021
         IECDSECS TIOT,                                                C67100021
               DCB,                                                    C67200021
               DEB,                                                    C67300021
               UCB,                                                    C67400021
               MAIN,                                                   C67500021
               WTG,                                                    C67600021
               EXPAND=YES                                               67700021
         IECEQU ,                       INVOKE OPEN/CLOSE/EOV EQUATES   67800021
         SPACE 2                                                        67900021
         END                                                            68000021
