         TITLE 'IFG0552X - EOV INPUT END-OF-DATA FUNCTION'              00100021
         COPY  LCGASMSW                                                 00150000
IFG0552X CSECT                                                          00400021
*                                                                       00500021
*********************************************************************** 00600021
*                                                                     * 00700021
*          VS2 RELEASE 01 DELETIONS                                   * 00760000
*                                                                     * 00770021
*0000                                                            YM0954 00780000
*          VS1 RELEASE 03 DELETIONS                                   * 00790003
*0000007500,007900                                              XA02071 00792003
*0000306600                                                     XA01994 00794003
*         VS1 RELEASE 3.1 DELETION/CHANGES                            * 00796000
*0000                                                           XA04285 00798000
*                                                                     * 00800021
*          RELEASE 25 DELETIONS/CHANGES                               * 00900021
*          RELEASE 24 DELETIONS/CHANGES                               * 01000021
*          RELEASE 23 DELETIONS/CHANGES                               * 01100021
*          RELEASE 22 DELETIONS/CHANGES                               * 01200021
*          RELEASE 21.7 DELETIONS/CHANGES                             * 01250001
*0000092000-094000,106700,151000,153000,154000,157000-158000,   SA57967 01260001
*0000163000-166000,434000-454000,618000-623000,640000,641000,   SA57967 01270001
*0000642000-643000,644000,645200,645300,645500,647000-657500,   SA57967 01280001
*0000659200,659300,659600                                       SA57967 01290001
*0000270200,270600,270800,328200,328800                         SA59750 01292001
*0000                                                           SA61678 01294021
*          RELEASE 21 DELETIONS/CHANGES                               * 01300021
*                                                                M0003  01310021
*                                                                M0015  01320021
*                                                                M0016  01340021
*                                                                M0017  01360021
*                                                                M0018  01380021
*                                                                M0071  01382021
*                                                                M0142  01384021
*                                                                A45247 01386021
*0000369500-389000,651000                                        A38013 01390021
*0000366000-367000,479200                                        M1782  01392021
*                                                               SA57176 01394000
*0000                                                           SA50649 01394121
*                                                                     * 01400021
* STATUS CHANGE LEVEL 000                                             * 01500021
*                                                                     * 01600021
* FUNCTION -                                                          * 01700021
*    THIS MODULE CONTAINS THE 'EOV INPUT END-OF-DATA FUNCTION'.       * 01800021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG' FOR DETAILS.            * 01900021
*                                                                     * 02000021
* ENTRY POINTS -                                                      * 02100021
*         IFG0552X - REFER TO 'INPUT' IN THE 'FUNCTION PROLOG' FOR A  * 02150021
*                    LIST OF CALLING MODULES AND THEIR RESPECTIVE     * 02200021
*                    ENTRY CONDITIONS.                                * 02250021
*                                                                     * 02300021
* INPUT -                                                             * 02400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 02500021
*                                                                     * 02600021
* OUTPUT -                                                            * 02700021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 02800021
*                                                                     * 02900021
* EXTERNAL REFERENCES -                                               * 03000021
*         IFG055RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL.        * 03100021
*                    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.        * 03200021
*                                                                     * 03300021
* EXITS, NORMAL -                                                     * 03400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 03500021
*                                                                     * 03600021
* EXITS, ERROR -                                                      * 03700021
*    EXIT IS TO THE PROBLEM DETERMINATION MODULE IFG0550P IF AN       * 03800021
*    ABEND SITUATION OCCURS IN THIS MODULE.  REFER TO THE FOLLOWING   * 03900021
*    'FUNCTION PROLOG'.                                               * 04000021
*                                                                     * 04100021
* TABLES/WORK AREAS -                                                 * 04200021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 04300021
*                                                                     * 04400021
* ATTRIBUTES -                                                        * 04500021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 04600021
*                                                                     * 04700021
* CHARACTER CODE DEPENDENCY -                                         * 04800021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 04900021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 05000021
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 05100021
*                                                                     * 05200021
* NOTES -                                                             * 05300021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 05400021
*                                                                     * 05500021
*********************************************************************** 05600021
         EJECT                                                          05700021
         SPACE 1                                                        05800021
*********************************************************************** 05900021
*                                                                     * 06000021
*                          FUNCTION PROLOG                            * 06100021
*                                                                     * 06200021
*********************************************************************** 06300021
*                                                                     * 06400021
* FUNCTION NAME -                                                     * 06500021
*    'EOV INPUT END-OF-DATA FUNCTION'                                 * 06600021
*                                                                     * 06700021
* (STATUS) -                                                          * 06800021
*    NOT APPLICABLE                                                   * 06900021
*                                                                     * 07000021
* FUNCTION -                                                          * 07100021
*    1. DETERMINES WHETHER END-OF-DATA (EOD) HAS BEEN REACHED OR      * 07200021
*       IF THERE ARE CONCATENATED DATA SETS TO BE PROCESSED.          * 07300021
*    2. IF EOD HAS BEEN REACHED, PLACES THE USER'S EOD ROUTINE        * 07400021
*       ADDRESS INTO THE RESUME (OLD) PSW, SETS VARIOUS RETURN        * 07500021
*       INDICATORS, AND EXITS TO THE USER VIA SVC 3.                  * 07600021
*    3. IF THERE ARE CONCATENATED DATA SETS WITH UNLIKE ATTRIBUTES,   * 07700021
*       A SINGLE-ENTRY CLOSE PARAMETER LIST AND AN XCTL WORK AREA     * 07800021
*       ARE CONSTRUCTED IN THE SVRB EXTENDED SAVE AREA. THIS          * 07900021
*       FUNCTION THEN TRANSFERS CONTROL TO THE FIRST LOAD OF CLOSE TO * 08000021
*       FIRST CLOSE THE DCB AND THEN REOPEN IT WITH NEW ATTRIBUTES.   * 08100021
*    4. IF THERE ARE CONCATENATED DATA SETS WITH LIKE ATTRIBUTES,     * 08200021
*       THIS FUNCTION FIRST DETERMINES WHETHER OR NOT SMF RECORDS     * 08300021
*       ARE TO BE WRITTEN, TRANSFERRING CONTROL TO THE CLOSE SMF      * 08400021
*       PROCESSING MODULE IF REQUIRED. THAT MODULE RETURNS CONTROL    * 08500021
*       TO THIS MODULE UNLESS THE DATA SET AT EOF IS ON A TAPE VOLUME * 08600021
*       IN WHICH CASE CONTROL IS RETURNED TO THE EOV TAPE INPUT       * 08700021
*       VOLUME POSITIONING FUNCTION. IF SMF RECORDS ARE NOT REQUIRED  * 08800021
*       AND THE CURRENT DATA SET IS ON TAPE, CONTROL IS TRANSFERRED   * 08900021
*       DIRECTLY TO THE VOLUME POSITIONING FUNCTION. FOLLOWING SMF    * 09000021
*       PROCESSING, OR IF THAT IS NOT REQUIRED, CONTROL IS            * 09100001
*       TRANSFERRED TO THE EOV LIKE CONCATENATION PROCESSING          * 09200001
*       FUNCTION.                                                     * 09300001
*    5. IF ENTRY IS FROM THE INITIAL FUNCTION WITH THE CONCATENATION  * 09500021
*       BIT ON IN FIELD 'DCBOFLGS', THEN VARIOUS RETURN INDICATORS    * 09600021
*       ARE SET AND CONTROL IS PASSED TO THE USER VIA SVC 3 (EXCP)    * 09700021
*       OR TO THE EOV ACCESS METHOD EXECUTOR (BSAM OR QSAM            * 09800021
*       ACCESS METHOD) TO READ THE CONCATENATED DATA SET.             * 09900021
*       NOTE- THIS ENTRY CAN ONLY OCCUR WHEN THE CONCATENATED DATA    * 10000021
*       SET RESIDES ON/IN A UNIT RECORD DEVICE.                       * 10100021
*    6. IF ENTRY IS FROM THE PROBLEM DETERMINATION FUNCTION, AN       * 10200021
*       ERROR HAS PREVIOUSLY OCCURRED IN SOME EOV FUNCTION AND THE    * 10300021
*       USER HAS INDICATED THAT IT IS TO BE IGNORED. EOV WILL THEN    * 10380021
*       CLOSE THE DCB AS IN THE CASE OF CONCATENATION WITH UNLIKE     * 10460021
*       ATTRIBUTES (REFER TO (3) ABOVE), AND CLOSE WILL EXIT TO THE   * 10540021
*       USER.                                                         * 10620021
*    7. IF ENTRY IS FROM THE EOV TAPE INPUT END OF DATA (IFG0552Z)    * 10670001
*       FUNCTION, A VOLUME WITH ANSI LABELS WAS FOUND TO BE INACCESS- * 10680000
*       IBLE. IN THIS CASE, MESSAGE IEC017I A (-1) IS ISSUED, THE     * 10690000
*       DCB IS CLOSED AS IN THE CASE OF CONCATENATION WITH UNLIKE     * 10692000
*       ATTRIBUTES (REFER TO (3) ABOVE), AND CLOSE WILL EXIT TO THE   * 10694000
*       USER.                                                         * 10696000
*    8. IF ENTRY IS FROM THE EOV TAPE INPUT STANDARD HEADER LABEL     * 10700000
*       FUNCTION, A TAPE WITH ANSI LABELS WAS FOUND TO BE INACCESS-   * 10800021
*       IBLE. IN THIS CASE, MESSAGE IEC017I A (-2) IS ISSUED, THE     * 10900021
*       DCB IS CLOSED AS IN THE CASE OF CONCATENATION WITH UNLIKE     * 11000021
*       ATTRIBUTES (REFER TO (3) ABOVE), AND CLOSE WILL EXIT TO THE   * 11060021
*       USER.                                                         * 11120021
*                                                                     * 11200021
* ENTRY POINTS -                                                      * 11300021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 11400021
*                                                                     * 11500021
* INPUT -                                                             * 11600021
*    1. REGISTER CONTENTS AT ENTRY ARE AS FOLLOWS-                    * 11700021
*       'RDCB' - ADDRESS OF THE DCB BEING PROCESSED;                  * 11800021
*       'RCORE'- ADDRESS OF THE EOV WORK AREA;                        * 11900021
*       'RES'  - ADDRESS OF THE OPEN/CLOSE/EOV RESIDENT ROUTINE;      * 12000021
*       'RWTG' - ADDRESS OF THE WHERE-TO-GO TABLE;                    * 12100021
*       'RPARC'- ADDRESS OF THE CURRENT PARAMETER LIST ENTRY (DUMMY   * 12200021
*                LIST CONSTRUCTED BY THE EOV FUNCTION);               * 12300021
*       'RWTGC'- ADDRESS OF THE CURRENT WHERE-TO-GO ENTRY;            * 12400021
*       'RTIOT'- ADDRESS OF THE CURRENT TIOT ENTRY;                   * 12500021
*       'RUCB' - ADDRESS OF THE CURRENT UCB;                          * 12600021
*       'RDEB' - ADDRESS OF THE DCB'S DEB;                            * 12700021
*       'RET'  - ONE OF THE FOLLOWING BRANCH TABLE OFFSETS-           * 12800021
*           0 - ENTRY FROM EITHER IFG0551H, IFG0552R, IFG0552T,       * 12860021
*               OR IFG0553P TO PROCESS END-OF-DATA.                   * 12920021
*           4 - RETURN FROM SMF PROCESSING MODULE IFG0553B (AN        * 12980021
*               ALIAS FOR IFG0202H).                                  * 13040021
*           8 - RETURN FROM TRACE TERMINATION MODULE IFG0559R.        * 13100021
*          12 - ENTRY FROM IFG0553H TO ISSUE ANSI MESSAGE             * 13160021
*               IEC017I A (-2) AND TO CLOSE THE DATA SET.             * 13220021
*          16 - ENTRY FROM IFG0551H TO COMPLETE CONCATENATION OF      * 13280021
*               LIKE DATA SETS ON UNIT RECORD DEVICES.                * 13340021
*          20 - ENTRY FROM IFG0552Z TO ISSUE ANSI MESSAGE             * 13390000
*               IEC017I A (-1) AND TO CLOSE THE DATA SET.             * 13392000
*    2. CONTROL BLOCK FIELDS-                                         * 13400021
*       'DCBOFLGS'- X'01' OFF- INDICATES THAT ENTRY IS FROM PROBLEM   * 13500021
*                              DETERMINATION TO CLOSE THE DCB.        * 13600021
*                   X'20' ON - INDICATES THAT CONCATENATION IS TAKING * 13700021
*                              PLACE.                                 * 13800021
*                                                                     * 14000021
* OUTPUT -                                                            * 14100021
*    1. AT EXIT TO USER'S EOD ROUTINE-                                * 14200021
*       REGISTER 'RF' CONTAINS A '4' IF THE EXIT IS TAKEN AND AN EOV  * 14300021
*          RATHER THAN AN EOF LABEL WAS READ; OTHERWISE, THE REGISTER * 14400021
*          CONTAINS A '0';                                            * 14500021
*       CONTROL BLOCK FIELDS-                                         * 14600021
*          'DCBIFLGS'- X'CO'- (BSAM ONLY) INDICATES THAT NO MORE      * 14700021
*             INPUT IS TO TAKE PLACE;                                 * 14800021
*          ECB OF THE SECOND IOB CHAINED FROM THE DCB- X'49'- (QSAM   * 14900021
*             ONLY) INDICATES THAT NO MORE INPUT IS TO TAKE PLACE.    * 15000021
*    2. AT EXIT TO MODULE IFG0552Y-                                   * 15100001
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT AS FOLLOWS- * 15200021
*          'R1'   - ADDR OF CONCATENATED TIOT ENTRY                   * 15300001
*          'RET'  - ZERO BRANCH ENTRY CODE                            * 15350001
*       CONTROL BLOCK FIELDS-                                         * 15500021
*          'DCBOFLGS' - X'20'- CONCATENATION IS TAKING PLACE;         * 15600021
*          'SRTEDMCT' - (NON-DATA CELL DEVICES) DECREMENTED BY 1;     * 15900021
*          'DCELDMCT' - (2321 DATA CELL DRIVE) DECREMENTED BY 1;      * 16000021
*          'DEBTVLSQ' - (NON-DIRECT ACCESS DEVICES) SET TO 1:         * 16100021
*          'DEBVOLSQ' - (DIRECT ACCESS DEVICES) SET TO 1;             * 16200021
*    3. AT EXIT TO MODULE IFG0552V-                                   * 16700021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY;                   * 16800021
*       CONTROL BLOCK FIELDS-                                         * 16900021
*          'DCBOFLGS'- X'20'- CONCATENATION IS TAKING PLACE.          * 17000021
*    4. AT EXIT TO MODULE IFG0553B (AN ALIAS FOR IFG0202H)-           * 17100021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT AS FOLLOWS- * 17200021
*          'RET'- A BRANCH TABLE OFFSET OF '4';                       * 17300021
*       CONTROL BLOCK FIELDS-                                         * 17400021
*          'DXRETMOD' IN THE EOV WORK AREA CONTAINS THE ID/TTR OF     * 17500021
*             THE RETURN MODULE- EITHER IFG0552V (TAPE DATA SET)      * 17600021
*             OR IFG0552X (NON-TAPE DATA SET).                        * 17700021
*    5. AT EXIT TO MODULE IGC00020-                                   * 17800021
*       REGISTER 'R1' CONTAINS THE ADDRESS OF A 1-WORD PARAMETER      * 17900021
*          LIST WHICH CONTAINS THE ADDRESS OF THE DCB BEING           * 18000021
*          PROCESSED; THE HIGH-ORDER BIT OF THE FIRST BYTE IS ON.     * 18100021
         AIF   ('&LIB' EQ 'LIB1').LIB12XY                               18102000
*       FOR TSO TASKS WITH CONCATENATION OF UNLIKE ATTRIBUTES:        * 18102400
*       REGISTER 5 CONTAINS A ZERO IF THE WTGTSENQ BIT WAS 0.  IF     * 18104000
*          THE WTGTSENQ BIT WAS A 1, THEN REG 5 CONTAINS A ONE.       * 18106000
.LIB12XY ANOP                                                           18108000
*    6. AT EXIT TO IFG0550P (PROBLEM DETERMINATION)-                  * 18110021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 18120021
*          REGISTER 'R0' CONTAINS ONE OF THE FOLLOWING INTERNAL       * 18130021
*          ERROR CODES (THE CORRESPONDING ABEND AND RETURN CODES ARE  * 18140021
*          INDICATED IN PARENTHESES)-                                 * 18150021
*          174 (337/04)- NO END-OF-DATA ADDRESS WAS PROVIDED.         * 18160021
*          176 (637/0C)- CONCATENATION OF UNLIKE DEVICES WAS BEING    * 18170021
*                        PERFORMED BUT THE 'UNLIKE ATTRIBUTES' BIT    * 18180021
*                        WAS NOT SET IN FIELD 'DCBOFLGS'.             * 18190021
*                                                                     * 18200021
* EXTERNAL REFERENCES -                                               * 18300021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 18400021
*                                                                     * 18500021
* EXITS, NORMAL -                                                     * 18600021
*         IFG0551L - TO CONTINUE PROCESSING THE CONCATENATED DATA SET * 18660021
*                    WHEN THE ACCESS METHOD IS BSAM OR QSAM AND THE   * 18720021
*                    DATA SET RESIDES IN/ON A UNIT RECORD DEVICE.     * 18780021
*         IFG0552F - TO REINITIALIZE FOR CONCATENATION.               * 18840021
*         IFG0552V - TO POSITION A TAPE AT EOF WHEN CONCATENATION IS  * 18900021
*                    TAKING PLACE.                                    * 18960021
*         IFG0552Y - TO PROCESS DATA SETS CONCATENATED WITH LIKE      * 19010001
*                    ATTRIBUTES.                                      * 19012001
*         IFG0553B - (AN ALIAS FOR IFG0202H) TO PROCESS SMF RECORDS.  * 19020021
*         IGC00020 - TO CLOSE THE DATA SET AND, IN THE CASE OF        * 19080021
*                    CONCATENATION WITH UNLIKE ATTRIBUTES, TO THEN    * 19140021
*                    REOPEN IT TO CONTINUE CONCATENATION.             * 19200021
*         USER'S END-OF-DATA ROUTINE - WHEN END-OF-DATA HAS OCCURRED. * 19260021
*         USER'S PROCESSING PROGRAM - TO CONTINUE PROCESSING THE      * 19320021
*                    CONCATENATED DATA SET WHEN EXCP IS BEING USED    * 19380021
*                    AND THE DATA SET RESIDES IN/ON A UNIT RECORD     * 19440021
*                    DEVICE.                                          * 19500021
*                                                                     * 19700021
* EXITS, ERROR -                                                      * 19800021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 19900021
*                                                                     * 20000021
* TABLES/WORK AREAS -                                                 * 20100021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 20200021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 20300021
*                                                                     * 20400021
* ATTRIBUTES -                                                        * 20500021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 20600021
*                                                                     * 20700021
* CHARACTER CODE DEPENDENCY -                                         * 20800021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 20900021
*                                                                     * 21000021
* NOTES -                                                             * 21100021
*                                                                     * 21200021
*********************************************************************** 21300021
*                                                                       21400021
*****    INTERNAL ERROR CODES                                           21500021
*                                                                       21600021
EABD174  EQU   174                      NO EOD ADDRESS WAS PROVIDED     21700021
EABD176  EQU   176                      CONCATENATION OF DATA SETS WITH 21800021
*                                       ..LIKE ATTRIBUTES WAS SPECIFIED 21900021
*                                       ..BUT UNLIKE DEV WERE ALLOCATED 22000021
         BALR  RBASE,0                  ESTABLISH ADDRESSABILITY        22100021
         USING *,RBASE                                                  22200021
ECM60000 EQU   *                                                        22300021
         USING FORCORE,RCORE                                            22400021
         USING TIOENTRY,RTIOT                                           22600021
         USING DEB,RDEB                                                 22700021
         USING IHADCB,RDCB                                              22800021
         USING UCB,RUCB                                                 22900021
*                                                                       23000021
*****          POINT TO THE SVRB FOR LATER PROCESSING                   23100021
*                                                                       23200021
         L     RC,CVTPTR                LOAD ADDRESS OF CVT      M0017  23260021
         USING CVT,RC                   ESTABLISH CVT BASE ADDR  M0017  23320021
         L     RC,CVTTCBP               LOAD ADDR OF TCB POINTERS       23400021
         DROP  RC                                                M0017  23450021
         L     RC,K4(,RC)               LOAD ADDR OF ACTIVE TCB         23500021
         USING TCB,RC                   ESTABLISH TCB ADDRESSABILITY    23600021
         AIF   ('&LIB' EQ 'LIB1').LIB12X1                               23620000
         L     R0,TCBTIO                LOAD TIOT PTR                   23640000
.LIB12X1 ANOP                                                           23660000
         L     RC,TCBRBP                LOAD ADDRESS OF CURRENT SVRB    23700021
         USING RBSECT,RC                ESTABLISH RB ADDRESSABILITY     23800021
         AIF   ('&LIB' EQ 'LIB1').LIB12X2                               23804000
         TM    DCBMACRF,DCBMEXCP        EXCP ACCESS METHOD              23808000
         BO    ECM60050                 YES BYPASS SPOOL TEST           23812000
         TM    DCBCIND1,SPOOLM          IS IT A SPOOLED ENTRY           23816000
         BZ    ECM60050                 NO, CONTINUE NORMAL PROCESS     23820000
         OI    DCBOFLGS,DCBOBUSY        SET BUSY BIT ON                 23868000
         LH    RTIOT,DCBTIOT            LOAD CURRENT TIOT ENTRY OFFSET  23872000
         AR    RTIOT,R0                 GET CURRENT TIOT ENTRY ADDR     23876000
         SR    RUCB,RUCB                SET UCB REG TO 0                23880000
         NI    DXXPATHS+1,X'FF'-WTGTRACE  INDICATE TO THE TRACE RTN     23884000
*                                         TERMINATION IS REQUIRED       23888000
         B     ECM60400                 BR TO CONTINUE                  23892000
.LIB12X2 ANOP                                                           23896000
*                                                                       23900021
*****          DETERMINE TYPE OF ENTRY TO MODULE                        24000021
*                                                                       24100021
         AIF   ('&LIB' EQ 'LIB1').LIB12X3                               24120000
ECM60050 EQU   *                                                        24140000
.LIB12X3 ANOP                                                           24160000
         TM    DCBOFLGS,DCBOBUSY        TEST FOR ENTRY FROM PROBLEM     24200021
*                                       ..DETERMINATION FUNCTION-       24300021
         BZ    ECM61800                 ..BR IF YES TO CLOSE DCB M0142  24400021
*                                                                       24600021
         B     ECM60100(RET)            DETERMINE TYPE OF ENTRY TO MOD  24900021
ECM60100 EQU   *                                                        25000021
         B     ECM60200           ( 0)  BR IF ENTERED TO PROCESS EOF    25100021
         B     ECM61100           ( 4)  BR IF RETURN FROM SMF MODULE    25200021
         B     ECM62600           ( 8)  BR IF RETURN FROM TRACE         25300021
*                                       ..TERMINATION MODULE            25400021
         B     ECM61700           (12)  BR IF ENTERED TO ISSUE ANSI     25500021
*                                       ..ACCESSIBILITY MESSAGE         25600021
         B     ECM61600           (16)  BR IF ENTERED TO FINISH  M0015  25630021
*                                       ..UNIT RCD CONCATENATION M0015  25660021
         B     ECM61650           (20)  BR IF ENTERED TO ISSUE  SA57176 25690000
*                                       ..ANSI VOLUME           SA57176 25692000
*                                       ..ACCESSIBILITY MESSAGE SA57176 25694000
*                                                                       25700021
*********************************************************************** 25800021
*              END-OF-FILE FROCESSING                                 * 25900021
*********************************************************************** 26000021
*                                                                       26100021
ECM60200 EQU   *                                                        26200021
         LTR   RUCB,RUCB                IS THIS A DUMMY UCB-            26300021
         BZ    ECM60300                 ..BRANCH IF YES                 26400021
         BAL   RD,ECM62400              BR TO TEST FOR DATA CELL        26500021
ECM60300 EQU   *                                                        26600021
         OI    DEBOFLGS,DEBOFEOF        TURN ON DEB EOF INDICATORS      26700021
         OI    DEBFLGS1,DEBF1EOF        ..(THIS ONE INDICATES THAT      26800021
*                                       ..DEFERRED USER LBL PROCESSING  26900021
*                                       ..CAN TAKE PLACE)               27000021
         TM    DCBMACRF,DCBMEXCP        IS EXCP BEING USED?             27040000
         BO    ECM60400                 ..BRANCH IF YES                 27060001
         TM    DCBCIND2,DCBC2FEO        IS THIS AN FEOV ENTRY-          27100021
         BNO   ECM60400                 ..BR IF NOT FEOV                27200021
         NI    DEBOFLGS,X'FF'-DEBOFEOF  TURN OFF DEB EOF INDICATORS     27300021
         NI    DEBFLGS1,X'FF'-DEBF1EOF                                  27400021
*                                                                       27500021
*****          TEST FOR CONCATENATED DATA SETS                          27600021
*                                                                       27700021
ECM60400 EQU   *                                                        27800021
         SR    R1,R1                    CALC  ADDR OF NEXT TIOT ENTRY-  27900021
         IC    R1,TIOELNGH              ..INSERT LNG OF CURRENT ENTRY,  28000021
         AIF   ('&LIB' EQ 'LIB1').LIB12X5                               28020000
         LR    RD,R1                    SAVE TIOELNGH FOR LATER TEST    28040000
*                                       OF SPOOLED CONCAT. DATA SETS    28060000
.LIB12X5 ANOP                                                           28080000
         AR    R1,RTIOT                 ..ADD CURRENT ENTRY ADDRESS     28100021
         TM    TIOELNGH-TIOENTRY(R1),ALLBITS  TEST FOR ANY TIOT ENTRY-  28200021
         BZ    ECM60500                 ..BR IF NO MORE ENTRIES         28300021
         CLI   TIOEDDNM-TIOENTRY(R1),BLANK TEST FOR A BLANK DDNAME      28400021
         BE    ECM60900                 ..BR IF BLANK- CONCATENATION    28500021
         EJECT                                                          28600021
*********************************************************************** 28700021
*              END-OF-DATA PROCESSING                                 * 28800021
*********************************************************************** 28900021
*                                                                       29000021
ECM60500 EQU   *                                                        29100021
         LA    RD,EABD174               LOAD INTERNAL ERROR CODE        29200021
         TM    DCBMACRF,DCBMEXCP        IS THE ACCESS METHOD EXCP-      29300021
         BZ    ECM60600                 ..BRANCH IF NOT                 29400021
         TM    DCBMACRF,DCBMFOUN        IS FOUNDATION EXT PRESENT-      29500021
         BZ    ECM62800                 ..BR IF NOT TO ERROR RTN        29600021
ECM60600 EQU   *                                                        29700021
         L     RF,DCBEODAD              LOAD ADDRESS OF EODAD RTN       29800021
         LA    RF,0(,RF)                CLEAR THE HIGH-ORDER BYTE       29900021
         CH    RF,HALFWD1               IS THERE AN EODAD RTN ADDR-     30000021
         BE    ECM62800                 ..BR IF NOT TO ERROR RTN        30100021
         TM    DCBMACRF,DCBMEXCP        IS THE ACCESS METHOD EXCP-      30200021
         BO    ECM60750                 ..BRANCH IF YES         XA01994 30300003
         TM    DCBCIND2,DCBC2QSM        IS THE ACCESS METHOD QSAM-      30400021
         BZ    ECM60700                 ..BR IF NOT- BSAM DOES NOT      30500003
*                                       ..REQUIRE THE FOLLOWING INST    30600021
         AIF   ('&LIB' EQ 'LIB1').LIB12X6                               30610000
         TM    DCBCIND1,SPOOLM          TEST FOR JES DATA SET           30650000
         BO    ECM60750                 BRANCH IF JES DATA SET  XA01994 30660003
.LIB12X6 ANOP                                                           30670000
         L     RF,DCBIOBA               LOAD IOB ADDRESS FROM DCB       30700021
         L     RF,K0(,RF)               LOAD ADDRESS OF NEXT IOB        30800021
         MVI   K4(RF),PUTCCODE          INDICATE IN SECOND IOB THAT     30900021
*                                       ..EODAD EXIT WAS TAKEN          31000021
         B     ECM60750                 CONTINUE                XA01994 31050003
*                                                                       31100021
*****          SET UP 'EOV' RETURN INDICATOR                            31200021
*                                                                       31300021
ECM60700 EQU   *                                                        31400021
         TM    DCBDEVT,DCBDEVDA         TEST FOR DA             XA01994 31410003
         BNO   ECM60750                 BRANCH IF NOT DA        XA01994 31420003
         TM    DCBDSORG,DCBORGPS        TEST FOR PS WHICH       XA01994 31450003
*                                       INDICATES BSAM          XA01994 31460003
         BNO   ECM60750                 BRANCH IF NOT BSAM      XA01994 31470003
ECM60740 EQU   *                                                XA01994 31498003
         CLI   DCBNCP,X'01'             MORE THAN 1 CHANNEL PGM XA01994 31498403
         BNH   ECM60750                 BRANCH IF ONLY ONE      XA01994 31498803
         L     RD,DCBIOBA               GET IOB ADDRESS         XA01994 31498903
         LA    RD,0(,RD)                CLEAR HIGH BYTE         XA01994 31499203
         L     RUCB,4(,RD)              GET FAILING IOB         XA01994 31499703
         LA    RUCB,0(,RUCB)            CLEAR HIGH BYTE         XA01994 31513103
         CR    RD,RUCB                  IS R0 EQUAL TO NEXT     XA01994 31519803
         BE    ECM60750                 BRANCH IF EQUAL         XA01994 31526503
         TM    DCBCIND2,DCBCNCHS        CHAIN SCHEDULING?       XA04285 31528500
         BZ    ECM60745                 BRANCH IF NOT           XA04285 31530500
         MVC   DCBFDAD(K8),K32(RUCB)    MOVE CHAIN SEEK ADDR    XA04285 31532500
         B     ECM60746                 CONTINUE                XA04285 31532900
ECM60745 EQU   *                                                XA04285 31533000
         MVC   DCBFDAD(K8),K40(RUCB)    MOVE SEEK ADDRESS       XA01994 31533203
ECM60746 EQU   *                                                XA04285 31535200
         ST    RUCB,DCBIOBA             STORE NEW IOB ADDRESS   XA01994 31543203
         LR    RD,RUCB                  UPDATE RD               XA01994 31543603
         SR    RUCB,RUCB                CLEAR REGISTER          XA01994 31545203
         IC    RUCB,DCBFDAD+7           GET RECORD NUMBER       XA01994 31547203
         LA    RUCB,1(,RUCB)            ADD ONE                 XA01994 31549203
         STC   RUCB,DCBFDAD+7           STORE NEW COUNT         XA01994 31551203
         L     RD,0(,RD)                GET NEXT IOB            XA01994 31552003
         TM    DCBCIND2,DCBCNCHS        CHAIN SCHEDULING?       XA04285 31552100
         BZ    ECM60747                 BRANCH IF NOT           XA04285 31552200
         MVC   K32(8,RD),DCBFDAD        MOVE DCBFDAD TO NEXT    XA04285 31552300
         B     ECM60750                 CONTINUE                XA04285 31555900
ECM60747 EQU   *                                                XA04285 31557900
         MVC   K40(8,RD),DCBFDAD        MOVE DCBFDAD TO NEXT    XA01994 31559503
ECM60750 EQU   *                                                XA01994 31563103
         SR    RUCB,RUCB                SET THE RETURN CODE TO ZERO     31566703
         CLC   FL1LABI(K3),EOVMARK      WAS ANY LABEL PROCESSED-        31600021
         BNE   ECM60800                 ..BR IF NOT- RETURN CODE EQ 0   31700021
         LA    RUCB,K4(,RUCB)           SET THE RETURN CODE TO 4        31800021
ECM60800 EQU   *                                                        31900021
         L     RD,RBLINK                LOAD USER'S PRB ADDR FROM SVRB  32000021
         MVC   RBOPSW+5-RBSECT(K3,RD),DCBEODAD+1  MOVE EOD ADDR INTO    32600021
*                                       ..ADDR PORTION OF OLD PSW       32700021
         BAL   RD,ECM62500              BR AND LINK TO DO CLEANUP       32800021
         TM    DCBMACRF,DCBMEXCP        EXCP BEING USED?                32840000
         BO    ECM62000                 ..BRANCH IF YES                 32860000
         TM    DCBCIND2,DCBC2QSM        IS THE ACCESS METHOD QSAM-      32900021
         BZ    ECM62000                 ..BRANCH IF NOT                 33000021
         OI    DCBIFLGS,DCBIFPIO        TURN ON PERM ERROR IND IN DCB   33100021
         B     ECM62000                 BR TO RETURN TO CALLER          33200021
         EJECT                                                          33300021
*********************************************************************** 33400021
*              CONCATENATED DATA SET PROCESSING                       * 33500021
*********************************************************************** 33600021
*                                                                       33700021
ECM60900 EQU   *                                                        33800021
         OI    DCBOFLGS,DCBOCON         TURN ON EOV CONCATENATION IND   33900021
         AIF   ('&LIB' EQ 'LIB1').LIB12X8                               33905000
* TEST FOR JES SPOOLED DATA SETS, MUST SET ON UNLIKE ATTRIBUTES BIT     33910000
* IN DCB IF ONE DATA SET IN A CONCATENTATED GROUP IS SPOOLED            33915000
*                                                                       33920000
* TEST PREVIOUS DATA SET FOR SPOOLED INDICATOR                          33925000
         SR    R1,RD                    SET TIOT PTR BACK TO PREVIOUS   33930000
*                                       ENTRY                           33935000
         TM    TIOELINK-TIOENTRY(R1),TIOTSPOL  TEST SPOOLED INDICATORS  33940000
         BM    ECM61900                 YES,SPOOLED-GO SET UNLIKE BIT   33945000
* TEST THIS DATA SET                                                    33950000
         AR    R1,RD                    STEP TO NEXT ENTRY              33955000
         TM    TIOELINK-TIOENTRY(R1),TIOTSPOL  IS THIS ONE SPOOLED      33960000
         BM    ECM61900                 NO, CHECK IF USER SET BIT ON    33965000
* SET UNLIKE ATTRIBUTES BIT FOR CONCAT. DATA SETS CONTAINING SPOOLED    33970000
* DATA SET                                                              33975000
*                                                                       33980000
ECM60975 EQU   *                                                        33985000
.LIB12X8 ANOP                                                           33990000
         TM    DCBOFLGS,DCBOUNLK        TEST FOR UNLIKE ATTRIBUTES-     34000021
         BO    ECM61900                 ..BR IF YES TO CLOSE DCB M0018  34100021
         L     RET,TIOESTTB-TIOENTRY(,R1) LOAD NEXT UCB ADDRESS         34200021
         LTR   RET,RET                  IS THE NEXT UCB A 'DUMMY'-      34300021
         BNZ   ECM61000                 ..BRANCH IF NOT                 34400021
         NI    DCBOFLGS,X'FF'-DCBOCON   TURN OFF CONCATENATION SWITCH   34500021
         B     ECM60500                 BR TO PROCESS AS EOD            34600021
*                                                                       34700021
*********************************************************************** 34800021
*              PROCESS CONCATENATED DATA SETS WITH LIKE ATTRIBUTES    * 34900021
*********************************************************************** 35000021
*                                                                       35100021
ECM61000 EQU   *                                                        35200021
         NI    DEBOFLGS,X'FF'-DEBOFEOF  TURN OFF DEBEOF BITS    SA61678 35210021
         NI    DEBFLGS1,X'FF'-DEBF1EOF  TURN OFF INDICATOR FOR  SA50649 35250021
*                                       EOD TAKEN               SA50649 35260021
         CLI   UCBID-UCB(RET),UCBMAIN   IS THIS A MAIN UCB-             35300021
         BE    ECM61050                 ..BR IF YES TO CONTINUE         35400021
         USING DATACELL,RET                                             35500021
         LH    RF,DCELBBNR              CALC 2321 MAIN UCB ADDRESS-     35600021
         SLA   RF,K4                    ..CALC OFFSET FROM MAIN UCB     35700021
         LA    RF,DATACELL-UCB(,RF)     ..TO THIS BIN, THEN SUBTRACT    35800021
         SR    RET,RF                   ..FROM ADDRESS OF SUB-UCB       35900021
         DROP  RET                                                      36000021
ECM61050 EQU   *                                                        36100021
         LA    RD,EABD176               LOAD INTERNAL ERROR CODE        36200021
         CLC   UCBTBYT3(K1),UCBTBYT3-UCB(RET) TEST FOR UNLIKE DEVICES-  36300021
         BNE   ECM62800                 ..BRANCH IF UNLIKE              36400021
*                                                                       36500021
         TM    UCBTBYT3,UCB3TAPE+UCB3DACC IS THIS A UNIT RECORD DEVICE- 36800021
         BZ    ECM61400                 ..BR IF YES- BYPASS SMF         36900021
*                                                                M1782  36910021
*****          ISSUE THE VOLUME STATISTICS SVC FOR TAPE DEVICES  M1782  36920021
*                                                                M1782  36930021
         TM    UCBTBYT3,UCB3TAPE        IS THIS A TAPE DEVICE-   M1782  36940021
         BNO   ECM61080                 ..BR IF NOT              M1782  36942021
         LA    R0,K0(,RDCB)             CLEAR HIGH-ORDER BYTE OF M1782  36944021
*                                       ..DCB ADDR IN PARM REG   M1782  36946021
         VOLSTAT (R0),E                 ISSUE VOLUME STATISTICS  M1782  36948021
*                                                                       36950021
*****          DETERMINE WHETHER OR NOT SMF PROCESSING IS REQUIRED      37000021
*                                                                       37050021
ECM61080 EQU   *                                                 M1782  37100021
         TM    DXXPATHS,WTGSMF          IS SMF PROCESSING REQ'D- A38013 37600021
         BNO   ECM61200                 ..BR IF NOT TO CONTINUE  A38013 38300021
         ST    R1,DXCCW7                SAVE ADDR OF NEXT TIOT ENTRY    39000021
         LA    RF,MODSMF2X              PT TO SMF MODULE'S NAME         39100021
         LA    RET,K4                   LD BR TABLE OFFSET FOR THAT MOD 39200021
         MVC   DXRETMOD(K5),MOD2X2X     MOVE THIS MODULE'S ID/TTR       39300021
*                                       ..INTO RETURN ADDRESS SAVE AREA 39400021
         TM    UCBTBYT3,UCB3TAPE        IS THIS A TAPE DEVICE-          39500021
         BZ    ECM62300                 ..BR IF NOT TO GO TO SMF MODULE 39600021
         MVC   DXRETMOD(K5),MOD2V2X     MOVE POSITIONING MOD ID/TTR     39700021
*                                       ..INTO RETURN ADDRESS SAVE AREA 39800021
         B     ECM62300                 BR TO LEAVE THIS MOD            39900021
*                                                                       40000021
*****          CONTINUE CONCATENATION FOLLOWING SMF PROCESSING          40100021
*                                                                       40200021
ECM61100 EQU   *                                                        40300021
         L     R1,DXCCW7                RESTORE ADDR OF NEXT TIOT ENTRY 40400021
ECM61200 EQU   *                                                        40500021
         LA    RF,MOD2V2X               PT TO POSITIONING MOD ID/TTR    40600021
         SR    RET,RET                  LD BR TABLE OFFSET FOR THAT MOD 40700021
         TM    UCBTBYT3,UCB3TAPE        IS THIS A TAPE DEVICE-          40800021
         BO    ECM62300                 ..BR IF YES- GO TO TAPE POS MOD 40900021
         L     RUCB,TIOESTTB            LOAD CURRENT UCB ADDRESS        41000021
*                                                                M0071  41010021
*****          DISABLE FOR INTERRUPTS WHILE MODIFYING THE DATA   M0071  41020021
*****          MANAGEMENT COUNT                                  M0071  41030021
*                                                                M0071  41040021
         SSM   DISABL2X                 DISABLE FOR INTERRUPTS   M0071  41050021
*                                                                       41060021
         CLI   UCBID,UCBMAIN            DOES 'RUCB' PT TO A MAIN UCB-   41100021
         BE    ECM61300                 ..BR IF YES- NOT A DATA CELL    41200021
         USING DATACELL,RUCB                                            41300021
         IC    RD,DCELDMCT              DECREMENT THE DATA MANAGEMENT   41400021
         BCTR  RD,0                     ..COUNT FOR A DATA CELL         41500021
         STC   RD,DCELDMCT              ..DEVICE                 M0016  41600021
         USING UCB,RUCB                                                 41700021
         B     ECM61350                 BR TO FINISH PROCESSING         41800021
ECM61300 EQU   *                                                        41900021
         IC    RD,SRTEDMCT              DECREMENT THE DATA MANAGEMENT   42000021
         BCTR  RD,0                     ..COUNT FOR A NON-DATA CELL     42100021
         STC   RD,SRTEDMCT              ..DEVICE                        42200021
*                                                                M0071  42250021
*****          ENABLE FOR ALL INTERRUPTS                         M0071  42300021
*                                                                M0071  42350021
ECM61350 EQU   *                                                 M0071  42400021
         SSM   ENABLE2X                 ENABLE FOR INTERUPTS     M0071  42450021
*                                                                M0071  42500021
*****          INITIALIZE DCB AND DEB FOR NEW DATA SET           M0071  42550021
*                                                                M0071  42600021
         SR    RD,RD                    CLEAR WORK REGISTER             42700021
         IC    RD,DEBNMEXT              LOAD TOTAL NO. OF EXTENTS       42800021
         BCTR  RD,0                     CALC NO. OF EXTENTS LESS FIRST  42900021
         SLL   RD,K4                    CALC LENGTH OF THESE EXTENTS    43000021
         AR    RD,RDEB                  ..AND ADD DEB BASE ADDRESS      43100021
         MVI   DEBVOLSQ-DEB+1(RD),K1    SET DEB VOLUME SEQ NO. TO 1     43200021
ECM61400 EQU   *                                                        43300021
         LA    RF,MOD2Y2X               PT TO LIKE CONCAT       SA57967 44900001
*                                       ..MODULE ID/TTR         SA57967 44950001
         SR    RET,RET                  ZERO BRANCH ENTRY       SA57967 45050001
         B     ECM62300                 XCTL TO LIKE CONCAT     SA57967 45100001
*                                       FUNCTION                SA57967 45200001
*                                                                       45400001
*****          RETURN FROM THE INITIAL ROUTINE- COMPLETE PROCESSING     45500021
*****          AND RETURN TO THE CALLER OR THE ACCESS METHOD EXECUTOR   45600021
*                                                                       45700021
ECM61600 EQU   *                                                        45800021
         NI    DEBOFLGS,X'FF'-DEBOFEOF  RESET DEB EOF INDICATOR         45900021
         BAL   RD,ECM62500              BR AND LINK TO DO CLEANUP       46000021
         NI    DCBOFLGS,X'FF'-DCBOCON   CLEAR CONCATENATION INDICATOR   46100021
         TM    DCBMACRF,DCBMEXCP        IS THE ACCESS METHOD EXCP-      46200021
         BO    ECM62000                 ..BR IF YES TO RETURN TO CALLER 46300021
         MVC   DXXMODID(K2),MOD1L2X     MOVE ACCESS METHOD EXECUTOR     46400021
*                                       ..ID INTO XCTL TABLE            46500021
         B     ECM62100                 BR TO XCTL TO A/M EXECUTOR      46600021
*                                                                       46700021
*********************************************************************** 46800021
*              AN ANSI VOLUME IS NOT ACCESSABLE-                      * 46850000
*              ISSUE MESSAGE IEC017I A(-1) AND CLOSE DATA SET         * 46860000
*              A DATA SET WITH 'ANSI' LABELS IS NOT ACCESSABLE-       * 46900021
*              ISSUE MESSAGE IEC017I A (-2) AND CLOSE THE DATA SET    * 47000021
*********************************************************************** 47100021
*                                                                       47200021
         USING RBSECT,RC                ESTABLISH RB ADDRESSABILITY     47300021
ECM61650 EQU   *                                                        47350000
         XR    RET,RET                  CLEAR INDICATOR         SA57176 47360000
ECM61700 EQU   *                                                        47400021
         OI    DCBCIND2,DCBC2PIO        INDICATE PERMANENT ERROR IN DCB 47500021
         MVC   MSGLSTSZ(K33),ANSIMSG    MOVE ACCESSIBILITY MSG INTO BUF 47600021
         MVC   MSGUN,UCBNAME            MOVE UNIT ADDR INTO MESSAGE     47700021
         MVC   MSGLSTSZ+18(K8),TIOEDDNM MOVE DDNAME INTO MESSAGE        47800021
         LTR   RET,RET                  TEST IF ENTERED FOR     SA57176 47850000
*                                       VOLUME ACCESSIBILITY    SA57176 47860000
         BNZ   ECM61750                 BRANCH IF ENTERED FOR   SA57176 47870000
*                                       FILE ACCESSIBILITY      SA57176 47880000
         MVI   MSGLSTSZ+K28,C'1'        CHANGE ANSI MESSAGE     SA57176 47890000
*                                       MODIFIER FROM 2 TO 1    SA57176 47892000
ECM61750 EQU   *                                                SA57176 47894000
         WTO   MF=(E,MSGLSTSZ)          ISSUE ACCESSIBILITY MESSAGE     47900000
*                                                                       47920021
*********************************************************************** 47940021
*              MODIFY THE USER'S RESUME PSW SO THAT AN 'EXIT' IS TO   * 47960021
*              TO THE USER RATHER THAN AN ACCESS METHOD MODULE        * 47980021
*********************************************************************** 48000021
*                                                                       48020021
ECM61800 EQU   *                                                 M0142  48040021
         TM    DCBMACRF,DCBMEXCP        IS THIS AN EXCP DCB-     A45247 48060021
         BO    ECM61900                 ..BR IF YES- RESUME PSW  A45247 48080021
*                                       ..ADDRESS IS CORRECT     A45247 48100021
         TM    DCBCIND2,DCBC2FEO        WAS FEOV ISSUED-         A45247 48120021
         BO    ECM61900                 ..BR IF YES- RESUME PSW  A45247 48140021
*                                       ..ADDRESS IS CORRECT     A45247 48160021
         L     RD,RBLINK                PT TO THE PREVIOUS REQUEST BLK  48300021
         TM    DCBCIND2,DCBC2QSM        IS IT A QSAM DCB        XA02071 48350003
         BO    ECM61850                 YES, MUST LOCATE USER   XA02071 48400003
*                                       ..R14 FOR RETURN ADDR   XA02071 48450003
*                                       FOR BSAM OR BPAM REG 14 XA02071 48500003
*                                       ..IN RBSAVE AREA IS OK  XA02071 48550003
         MVC   RBOPSW+5-RBSECT(K3,RD),RBGRS14+1  MOVE RET ADDR (REG 14) 49400021
*                                       ..FROM EOV SVRB SAVE AREA TO    49500021
*                                       ..CALLER'S RESUME PSW           49600021
         B     ECM61900                 BR TO CLEANUP           XA02071 49650003
ECM61850 EQU   *                                                XA02071 49660003
         L     RET,RBGRS13               LOAD PTR TO USER SAVE  XA02071 49670003
*                                       ..AREA                  XA02071 49680003
         MVC   RBOPSW+5-RBSECT(K3,RD),K21(RET)                  XA02071 49690003
*                                       ..MOVE USER REG 14 TO   XA02071 49690403
*                                       ..RESUME PSW            XA02071 49692003
ECM61900 EQU   *                                                        49700021
         BAL   RD,ECM62500              BR AND LINK TO DO CLEANUP       49800021
         AIF   ('&LIB' EQ 'LIB1').LIB12XZ                               49810000
         L     R1,CVTPTR                GET CVT ADDR             YM0954 49850000
         USING CVT,R1                   DEFINE CVT BASE          YM0954 49860000
         TM    CVTDCB,CVT4MS1           MVT SYSTEM?              YM0954 49870000
         BNO   ECM61950                 NO, BR-IGNORE TSO PROC   YM0954 49880000
         L     R1,CVTTCBP-CVT(,R1)      GET TCB PTRS             YM0954 49890000
         L     R1,K4(,R1)               GET CURRENT TCB PTR      YM0954 49892000
         USING TCB,R1                   DEFINE TCB BASE          YM0954 49894000
         TM    TCBTSFLG,TCBTSTSK        TSO TASK?                YM0954 49896000
         BNO   ECM61950                 NO, BR-IGNORE TSO PROC   YM0954 49898000
         TM    DXXPATHS+K1,WTGTSENQ     WAS ENQ SUCCESSFUL?      YM0954 49898400
         LA    R5,K1                    SET REG5 = 1             YM0954 49898500
         BO    ECM61950                 YES, BR WITH REG5 = 1    YM0954 49898800
         SR    R5,R5                    SET REG5 = 0             YM0954 49899200
ECM61950 EQU   *                                                 YM0954 49899700
.LIB12XZ ANOP                                                           49949700
*                                                                       49966700
*********************************************************************** 50000021
*              CONSTRUCT A PARAMETER LIST FOR CLOSE AND A PARAMETER   * 50100021
*              LIST FOR XCTL IN THE EOV SVRB EXTENDED SAVE AREA       * 50200021
*********************************************************************** 50300021
*                                                                       50400021
         MVC   RBEXSAVE(K4),DXDCBLST    MOVE DCB ADDRESS INTO PARAMETER 50500021
*                                       ..LIST LOCATION                 50600021
         LA    R0,EOVSIZE               LOAD SIZE OF EOV WORK AREA      50700021
         LR    R1,RCORE                 POINT TO EOV WORK AREA          50800021
         FREEMAIN R,LV=(0),A=(1)        RELEASE EOV MAIN STG WK AREA    50900021
         LA    R1,RBEXSAVE              POINT TO PARM LIST FOR CLOSE    51000021
         AIF   ('&LIB' EQ 'LIB1').LIB12X9                               51010000
         ST    RDCB,0(R1)               PUT DCB ADDR IN PARAM LIST      51020000
         MVI   0(R1),LASTNTRY           INDICATE LAST (ONLY) ENTRY      51030000
*                                       ..IN PARAMETER LIST             51040000
.LIB12X9 ANOP                                                           51050000
         LA    RF,RBEXSAVE+8            POINT TO PARM LIST FOR XCTL     51100021
         AIF   ('&LIB' EQ 'LIB1').LIB12XA                               51150000
         XC    K4(K4,RF),K4(RF)         CLEAR AREA                      51200000
.LIB12XA ANOP                                                           51283300
         MVC   RBEXSAVE+16(K8),CONLOAD  MOVE THE NAME OF THE FIRST MOD  51300021
*                                       ..OF THE 'CLOSE' ROUTINE INTO   51400021
*                                       ..THE XCTL PARAMETER LIST       51500021
         LA    RC,RBEXSAVE+16           POINT TO THE XCTL NAME   M0018  51550021
         NI    DCBOFLGS,X'FF'-DCBOBUSY  RESET I/O SUPPORT BIT IN DCB    51600021
         B     ECM62200                 BR TO XCTL TO 'CLOSE' RTNS      51700021
         USING UCB,RUCB                 ESTABLISH UCB ADDRESSABILITY    51800021
         EJECT                                                          51900021
*********************************************************************** 52000021
*              EXITS                                                  * 52100021
*********************************************************************** 52200021
*                                                                       52300021
*****          EXIT TO THE USER                                         52400021
*                                                                       52500021
ECM62000 EQU   *                                                        52600021
         AIF   ('&LIB' EQ 'LIB1').LIB12XB                               52650000
         L     R1,CVTPTR                GET CVT PTR              Y01018 52660000
         USING CVT,R1                                            Y01018 52670000
         TM    CVTDCB,CVT4MS1           MVT SYSTEM?              Y01018 52680000
         BNO   ECM62050                 NO, BR TO IGNORE DEQ     Y01018 52690000
         L     R1,CVTTCBP-CVT(,R1)      GET TCB PTRS             Y01018 52692000
         L     R1,K4(,R1)               GET CURRENT TCB PTR      Y01018 52694000
         USING TCB,R1                                            Y01018 52696000
         TM    TCBTSFLG,TCBTSTSK        TSO TASK                 Y01018 52698000
         BNO   ECM62050                 NO, BR TO IGNORE DEQ     Y01018 52698400
         TM    DXXPATHS+K1,WTGTSENQ     WAS ENQ SUCCESSFUL?      Y01018 52707400
         BZ    ECM62050                 NO, BR TO IGNORE DEQ     Y01018 52711700
         MVC   DXXAREA(ECM6297L),ECM6290K                        Y01018 52716000
         DEQ   (DXXAREA+ECM6295K-ECM6290K,                       Y01018*52720300
               DXXAREA+ECM6296K-ECM6290K),MF=(E,DXXAREA)         Y01018 52724600
ECM62050 EQU   *                                                 Y01018 52728900
         DROP  R1                                                Y01018 52733200
.LIB12XB ANOP                                                           52743200
         LA    R0,EOVSIZE               LOAD SIZE OF EOV WORK AREA      52766700
         LR    R1,RCORE                 POINT TO EOV WORK AREA          52800021
         FREEMAIN R,LV=(0),A=(1)        RELEASE EOV MAIN STG WK AREA    52900021
         LR    RF,RUCB                  PLACE RET CODE IN REG 15 (ONLY  53000021
*                                       ..MEANINGFUL FOR THE EOD EXIT)  53100021
         NI    DCBOFLGS,X'FF'-DCBOBUSY  RESET I/O SUPPORT BIT IN DCB    53200021
*                                                                       53300021
         SVC   SVCEXIT                  RETURN TO THE CALLER            53400021
         SPACE 2                                                        53500021
*                                                                       53600021
*****          XCTL TO THE TRACE TERMINATION ROUTINES                   53700021
*                                                                       53800021
ECM62100 EQU   *                                                        53900021
         LA    RC,DXXMODNM              PT TO XCTL MOD NAME             54000021
         LA    RF,DXXCTL                PT TO XCTL PARM LIST            54100021
*                                                                       54200021
*****          XCTL TO THE 'CLOSE' ROUTINES TO CLOSE THE DATA SET       54300021
*                                                                       54400021
ECM62200 EQU   *                                                        54500021
         XCTL  EPLOC=(RC),SF=(E,(15))                                   54600021
         SPACE 2                                                        54700021
*                                                                       54800021
*****          XCTL TO ANOTHER END-OF-VOLUME MODULE                     54900021
*                                                                       55000021
ECM62300 EQU   *                                                        55100021
         IECRES XCTL,(RF),(RET)         INVOKE IECRES MACRO TO XCTL     55200021
         EJECT                                                          55300021
*********************************************************************** 55400021
*              SUBROUTINES                                            * 55500021
*********************************************************************** 55600021
*                                                                       55700021
*****          CONVERT A 2321 SUB-UCB POINTER TO A MAIN UCB POINTER     55800021
*                                                                       55900021
ECM62400 EQU   *                                                        56000021
         CLI   UCBID,UCBMAIN            IS THIS A MAIN UCB-             56100021
         BCR   8,RD                     ..BR IF YES- RET TO CALLER      56200021
         USING DATACELL,RUCB                                            56300021
         LH    RF,DCELBBNR              LOAD BIN NO. FROM DEB, CALC     56400021
         SLA   RF,K4                    ..OFFSET FROM MAIN UCB TO       56500021
         LA    RF,DATACELL-UCB(,RF)     ..THIS BIN, THEN SUBTRACT       56600021
         SR    RUCB,RF                  ..FROM ADDRESS OF SUB-UCB       56700021
         BR    RD                       RETURN TO CALLER                56800021
         SPACE 2                                                        56900021
*                                                                       57000021
*****          PERFORM FINAL PROCESSING PRIOR TO EXITING FROM           57100021
*****          THE BASIC EOV MODULES                                    57200021
*                                                                       57300021
ECM62500 EQU   *                                                        57400021
*                                                                       57500021
*****          CALCULATE THE OFFSET OF THE RETURN ADDRESS IN CASE       57600021
*****          THE TRACE TERMINATION EXIT IS TAKEN, IN WHICH CASE       57700021
*****          THIS MODULE MAY BE RELOADED INTO A DIFFERENT TRANSIENT   57800021
*****          AREA                                                     57900021
*                                                                       58000021
         LA    RWTGC,ECM60000           LOAD ADDRESS OF THE FIRST BYTE  58100021
         SR    RD,RWTGC                 CALCULATE THE RET ADDR OFFSET   58200021
*                                                                       58300021
*****          PERFORM TRACE FACILITY TERMINATION IF REQUIRED           58400021
*                                                                       58500021
         LA    RWTGC,K0                 SET INTERNAL SW TO IND THAT THE 58600021
*                                       TRACE FACILITY IS NOT ACTIVE    58700021
         TM    DXXPATHS+1,WTGTRACE      IS THE TRACE FACILITY ACTIVE-   58800021
         BNO   ECM62600                 ..BR IF NOT                     58900021
         LA    RWTGC,K1                 SET INTERNAL SW TO IND THAT THE 59000021
*                                       TRACE FACILITY IS ACTIVE        59100021
         NI    DXXPATHS+1,X'FF'-WTGTRACE INDICATE TO THE TRACE ROUTINE  59200021
*                                       THAT TERMINATION IS REQUIRED    59300021
         MVC   DXXMODID(K2),ID9R        MOVE TRACE RTN ID INTO WTG TBL  59400021
         MVC   DXXENTRY(K5),MOD2X2X     MOVE RET ID/TTR INTO SAVE AREA  59500021
         LA    RET,K8                   LOAD BR TABLE OFFSET FOR RETURN 59600021
         B     ECM62100                 BR TO XCTL                      59700021
*                                                                       59800021
*****          RELEASE THE RESIDENT ROUTINE WORK AREA (ECBLIST)         59900021
*                                                                       60000021
ECM62600 EQU   *                                                        60100021
*                                                                       60120000
         L     R1,DXXECBAD              LOAD THE ADDRESS OF THE ECB LST 60200021
         LA    R0,K8                    LD THE LENGTH OF THE ECB LIST   60300021
         LTR   RWTGC,RWTGC              WAS THE TRACE FACILITY ACTIVE-  60400021
         BZ    ECM62700                 ..BR IF NOT TO FREE ECB LIST    60500021
         SR    R1,R0                    PT TO ECB LIST PREFIX    M0071  60600021
         AR    R0,R0                    ACCT FOR PREFIX LENGTH   M0071  60700021
ECM62700 EQU   *                                                        60800021
         FREEMAIN R,LV=(0),A=(1)        RELEASE THE ECBLIST MAIN STG    60900021
         B     ECM60000(RD)             RETURN TO THE CALLER OF SUBRTN  61000021
         SPACE 2                                                        61100021
*********************************************************************** 61200021
*              ERROR PROCESSING                                       * 61300021
*********************************************************************** 61400021
*                                                                       61500021
ECM62800 EQU   *                                                        61600021
         DMABCOND (RD),ABEND2X          INVOKE ERROR PROCESSING RTNS    61700021
         EJECT                                                          61750001
*********************************************************************** 62437001
*              CONSTANTS                                              * 62438201
*********************************************************************** 62448301
*                                                                       62458401
HALFWD1  DC    H'1'                     USED TO TEST FOR EXIT LIST ADDR 62468501
CONLOAD  DC    C'IGC000'                NAME OF THE FIRST MODULE OF     62500021
         DC    Z'20'                    ..THE 'CLOSE' ROUTINE           62600021
EOVMARK  DC    C'EOV'                   END-OF-VOLUME LABEL IDENTIFIER  62700021
ID9R     DC    C'9R'                    ID OF THE TRACE INITIALIZATION/ 62800021
*                                       ..TERMINATION ROUTINE           62900021
ENABLE2X DC    X'FF'                    MASK TO ENABLE FOR       M0071  62920021
*                                       ..INTERRUPTS             M0071  62940021
DISABL2X DC    X'00'                    MASK TO DISABLE FOR      M0071  62960021
*                                       ..FOR INTERRUPTS         M0071  62980021
ANSIMSG  DS    0C                       FILE-NOT-ACCESSIBLE MESSAGE     63000021
         DC    X'001D'                  MESSAGE LENGTH FOR WTO ROUTINE  63100021
         DC    X'8000'                  MCS FLAGS FOR WTO ROUTINE       63200021
         DC    C'IEC017I A '            BASIC MESSAGE IDENTIFIER        63300021
         DC    C'XXX,'                  UNIT ADDRESS AND DELIMITER      63400021
         DC    CL9'        ,'           DDNAME AND DELIMITER            63500021
         DC    C'-2'                    ANSI MESSAGE MODIFIER           63600021
         DC    X'1000'                  MSG DESCRIPTOR CODE FOR WTO RTN 63700021
         DC    X'0020'                  MSG ROUTE CODE FOR WTO RTN      63800021
         EJECT                                                          63900021
*********************************************************************** 63950001
*              XCTL TABLE                                             * 64000001
*********************************************************************** 64050001
*                                                                       64100001
         AIF   ('&LIB' NE 'LIB1').LIB22X1                               64350000
XCTLTB2X XCTLTABL ID=(ABEND2X,0P,MOD2Y2X,2Y,MOD1L2X,1L,         SA57967C64400001
               MOD2V2X,2V,                                      SA57967C64450001
               MOD2X2X,2X,MODSMF2X,3B),SVC=055,LENGTH=1024              64500000
.LIB22X1 ANOP                                                           64510000
         AIF   ('&LIB' EQ 'LIB1').LIB12XN                               64520001
ECM6290K DEQ   (,,4,STEP),RET=HAVE,MF=L                          Y01018 64522000
ECM6295K DC    CL8'SYSTIOT'             QNAME FOR DEQ            Y01018 64524000
ECM6296K DC    C'TIOT'                  RNAME FOR DEQ            Y01018 64526000
ECM6297L EQU   *-ECM6290K                                        Y01018 64528000
XCTLTB2X XCTLTABL ID=(ABEND2X,0P,MOD2Y2X,2Y,MOD1L2X,1L,         SA57967C64530001
               MOD2V2X,2V,                                      SA57967C64532001
               MOD2X2X,2X,MODSMF2X,3B,RESRTN,RA),SVC=055,LENGTH=2048,  C64540000
               PATCH=80                                                 64542000
.LIB12XN ANOP                                                           64550001
         IECDSECS CVT,                                                 C64560001
               TCB,                                                    C64570001
               RB,                                                     C64580001
               TIOT,                                                   C64590001
               DCB,                                                    C64592001
               DEB,                                                    C64594001
               UCB,                                                    C64596001
               MAIN,                                                   C64598001
               WTG,                                                    C64598401
               EXPAND=YES                                               64599201
         SPACE 2                                                        64600021
         AIF   ('&LIB' NE 'LIB1').LIB22X2                               64660001
         SPACE 2                                                        65800021
         IECEQU ,                       INVOKE OPEN/CLOSE/EOV EQUATES   65900021
.LIB22X2 ANOP                                                           65910000
         AIF   ('&LIB' EQ 'LIB1').LIB12XP                               65920001
SPOOLM   EQU   X'08'                    DCB SPOOLED INDICATOR           65937501
TIOTSPOL EQU   X'06'                                                    65940000
         IECEQU AOS=YES                                                 65950000
.LIB12XP ANOP                                                           65960001
         SPACE 2                                                        66000021
         END                                                            66100021
