         TITLE 'IFG0552Z - EOV TAPE INPUT NEW VOLUME MOUNTING FUNCTION' 00100000
         COPY  LCGASMSW                                                 00150000
IFG0552Z CSECT                                                          00400021
*                                                                       00500021
*********************************************************************** 00600021
*                                                                     * 00700021
*                                                                     * 00800021
*          VS/1-3.0 DELETIONS/CHANGES                                   01250003
*0000                                                           XA02411 01260003
*          RELEASE 21.8 DELETIONS/CHANGES                               01270003
*0000009000-012600                                              SA65517 01280003
*          RELEASE 21 DELETIONS/CHANGES                               * 01300021
*                                                                M0110  01320021
*                                                                A39275 01340021
*                                                                A42872 01360021
*0000435000                                                      A47788 01370021
*D246000-262000                                                 SA47382 01380000
*0000318000,330000,343000,424000,542000-543000,545000           SA47795 01390021
*                                                               SA57176 01392000
*0000361000-369000,580000                                       SA52404 01392121
*0000319000-329000,332000,344500,401000,434500-435100,438000,   SA58669 01394101
*0000441500-441984,543500,545000                                SA58669 01396101
*                                                                     * 01400021
* STATUS CHANGE LEVEL 000                                             * 01500021
*                                                                     * 01600021
* FUNCTION -                                                          * 01700021
*    THIS MODULE CONTAINS THE 'EOV TAPE INPUT NEW VOLUME MOUNTING     * 01800021
*    FUNCTION'. REFER TO THE FOLLOWING 'FUNCTION PROLOG' FOR DETAILS. * 01900021
*                                                                     * 02000021
* ENTRY POINTS -                                                      * 02100021
*         IFG0552Z - REFER TO 'INPUT' FOR A LIST OF CALLING MODULES   * 02160021
*                    AND THEIR RESPECTIVE ENTRY CONDITIONS.           * 02220021
*                                                                     * 02300021
* INPUT -                                                             * 02400021
*    REGISTER 14 ('RET') WILL CONTAIN ONE OF THE BRANCH TABLE OFFSETS * 02500021
*    LISTED BELOW, THE BRANCH TABLE BEING USED TO DETERMINE AT WHICH  * 02600021
*    POINT PROCESSING IS TO BEGIN -                                   * 02700021
*        0 - ENTRY FROM IFG0552V TO MOUNT THE NEXT REQUIRED VOLUME.   * 02800021
*        4 - ENTRY FROM IFG0552V TO WAIT FOR A REWIND TO COMPLETE AND * 02900021
*            THEN TO MOUNT THE NEXT REQUIRED VOLUME.                  * 03000021
*        8 - ENTRY FROM IFG0553H TO DEMOUNT THE CURRENTLY MOUNTED NSL * 03100021
*            VOLUME- WHICH COULD NOT BE VERIFIED BY NSLEHDRI- AND TO  * 03200021
*            REPEAT THE MOUNTING PROCEDURE FOR THE DESIRED VOLUME.    * 03300021
*       12 - RETURN FROM IFG0552P FOLLOWING A 'MOUNT' MESSAGE, OR     * 03400021
*            ENTRY FROM IFG0553D FOLLOWING INSERTION OF A FILE        * 03500021
*            PROTECT RING TO VERIFY THE VOLUME SERIAL NUMBER.         * 03600021
*       16 - RETURN FROM IFG0552P AFTER A 'RETAIN' MESSAGE            * 03700021
*            IS ISSUED IN ORDER TO ISSUE A 'MOUNT' MESSAGE FOR THE    * 03800021
*            NEXT REQUIRED VOLUME.                                    * 03900021
*       20 - ENTRY FROM EITHER OF EOV INITIAL FUNCTION MODULES        * 04000021
*            IFG0551H OR IFG0551J TO MOUNT A VOLUME FOR A             * 04100021
*            CONCATENATED DATA SET.                                   * 04200021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG' FOR ADDITIONAL INPUT.   * 04400021
*                                                                     * 04500021
* OUTPUT -                                                            * 04600021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 04700021
*                                                                     * 04800021
* EXTERNAL REFERENCES -                                               * 04900021
*         IFG055RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 05000021
*                    WAIT. REFER TO THE FOLLOWING 'FUNCTION PROLOG'.  * 05100021
*                                                                     * 05200021
* EXITS, NORMAL -                                                     * 05300021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 05400021
*                                                                     * 05500021
* EXITS, ERROR -                                                      * 05600021
*          IFG0550P - WHEN AN ERROR CONDITION OCCURS IN THIS MODULE.  * 05700021
*                     REFER TO THE FOLLOWING 'FUNCTION PROLOG'.       * 05800021
*                                                                     * 05900021
* TABLES/WORK AREAS -                                                 * 06000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 06100021
*                                                                     * 06200021
* ATTRIBUTES -                                                        * 06300021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 06400021
*                                                                     * 06500021
* CHARACTER CODE DEPENDENCY -                                         * 06600021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 06700021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 06800021
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 06900021
*                                                                     * 07000021
* NOTES -                                                             * 07100021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 07200021
*                                                                     * 07300021
*********************************************************************** 07400021
*                                                                       07500021
*****    INTERNAL ERROR CODES                                           07600021
*                                                                       07700021
EABD155  EQU   155                      REWIND ERROR ( FROM PREVIOUS    07800021
*                                       ..POSITIONING MODULE )          07900021
EABD156  EQU   156                      NO DEV AVAILABLE FOR NEW VOL    08000021
EABD157  EQU   157                      ERROR UNLOADING NEXT REQ'D UNIT 08100021
EABD158  EQU   158                      ERROR REWINDING BEFORE READING  08200021
*                                       ..VOLUME LABEL                  08300021
EABD159  EQU   159                      ERROR UNLOADING VOLUME WHICH    08400021
*                                       ..WAS INCORRECTLY MOUNTED       08500021
EABD160  EQU   160                      ERROR READING VOLUME LABEL      08600021
EABD161  EQU   161                      ERROR REWINDING NL OR NSL VOL   08700021
EABD181  EQU   181                      ERROR DUPLICATE VOLUMES SA47382 08750021
EABD251  EQU   251                      UNOPENED GDG DATA SET   SA65517 08760003
*                                       OR NON-SPECIFIC REQUEST SA65517 08770003
*                                                                       08800021
         BALR  RBASE,0                  ESTABLISH ADDRESSABILITY FOR    08900021
         USING *,RBASE                  ..THIS SECTION OF CODE          09000021
         USING FORCORE,RCORE                                            09100021
         USING IHADCB,RDCB                                              09200021
         USING UCB,RUCB                                                 09300021
         USING TIOENTRY,RTIOT                                           09400021
         USING DEB,RB                                                   09500021
         USING CVT,RD                   ESTABLISH CVT BASE ADDRESS      09600021
*                                                                       09700021
         B     ETI13000(RET)            DETERMINE TYPE OF ENTRY TO MOD  09800021
ETI13000 EQU   *                                                        09900021
         B     ETI13300           ( 0)  NORMAL ENTRY- BR TO     SA47382 10000000
*                                       ..MOUNT NEXT VOLUME             10100000
         B     ETI13300           ( 4)  BR TO WAIT FOR REW      SA47382 10200000
*                                       ..TO COMPLETE, THEN CONTINUE    10300021
         B     ETI14600           ( 8)  BR IF DISMOUNT/NEW MOUNT REQ'D  10400021
         B     ETI15200           (12)  BR IF VOLUME VERIFICATION REQ'D 10500021
         B     ETI14700           (16)  RETURN FROM RETAIN MESSAGE-     10600021
*                                       ..BR TO MOUNT THE NEXT VOLUME   10700021
         B     ETI13300           (20)  RET FROM COMMON RTN- MOUNT VOL  10800021
*                                       ..FOR CONCATENATED DATA SET     10900021
         EJECT                                                          11000021
*********************************************************************** 11100021
*                                                                     * 11200021
*                          FUNCTION PROLOG                            * 11300021
*                                                                     * 11400021
*********************************************************************** 11500021
*                                                                     * 11600021
* FUNCTION NAME -                                                     * 11700021
*    'EOV TAPE INPUT NEW VOLUME MOUNTING FUNCTION'                    * 11800021
*                                                                     * 11900021
* (STATUS) -                                                          * 12000021
*    NOT APPLICABLE                                                   * 12100021
*                                                                     * 12200021
* FUNCTION -                                                          * 12300021
*    1. IF THE VOLUME POSITIONING FUNCTION HAS ISSUED A REWIND, WAIT  * 12400021
*       FOR THE REWIND TO COMPLETE.                                   * 12500021
*    2. SHIFT THE UCB ADDRESSES IN THE TIOT 1 WORD TO THE LEFT (I.E., * 12600021
*       THE UCB CONTAINING THE VOLUME AT EOV BECOMES THE LAST ONE IN  * 12700021
*       THE TIOT, THE SECOND ONE BECOMES THE FIRST ONE IN THE TIOT,   * 12800021
*       ETC.) SO THAT THE SEARCH FOR AN AVAILABLE UNIT WILL NOT BEGIN * 12900021
*       WITH A UNIT KNOWN TO HAVE A MOUNTED VOLUME.                   * 13000021
*    3. SEARCH ALL ALLOCATED UNITS FOR THE NEXT REQUIRED VOLUME;      * 13100021
*       IF THE VOLUME IS NOT MOUNTED BUT AN EMPTY UNIT IS AVAILABLE,  * 13200021
*       ISSUE MOUNT MESSAGE 'IEC001A M' FOR THE DESIRED VOLUME.       * 13300021
*    4. IF AN EMPTY UNIT IS NOT AVAILABLE, THE FIRST UNIT WITH A      * 13400021
*       DEMOUNTABLE (I.E., UNRESERVED) VOLUME IS SELECTED, THE VOLUME * 13500021
*       IS UNLOADED AND A RETAIN MESSAGE IS ISSUED.                   * 13550021
*       MOUNT MESSAGE IEC001A M IS THEN ISSUED FOR THE DESIRED VOLUME * 14400021
*       AND A REWIND COMMAND IS ISSUED TO THE TAPE DRIVE PREPARATORY  * 14500021
*       TO READING THE VOLUME LABEL.                                  * 14600021
*    5. AN ATTEMPT IS MADE TO READ A VOLUME LABEL. IF A LABEL IS READ * 14700021
*       AND AL OR SL WAS SPECIFIED, THE SERIAL NUMBER IS VERIFIED.    * 14800021
*       IF THE SERIAL NUMBER IS NOT CORRECT OR IF NO VOLUME LABEL     * 14900021
*       WAS READ, DEMOUNT MESSAGE IEC014E D IS ISSUED, THE VOLUME IS  * 15000021
*       UNLOADED, AND THE MOUNTING PROCEDURE IS REPEATED.             * 15100021
*    6. IF NO VOLUME LABEL WAS READ AND NL OR NSL WAS SPECIFIED, THE  * 15200021
*       VOLUME IS ASSUMED TO BE THE CORRECT ONE AND IS REWOUND TO     * 15300021
*       LOAD POINT. HOWEVER, IF A TAPE MARK WAS READ AND 'LEADING     * 15400021
*       TAPE MARK' (LTM) WAS SPECIFIED, THE TAPE IS LEFT AT THE       * 15500021
*       INTERBLOCK GAP FOLLOWING THE TAPE MARK. IF A VOLUME LABEL     * 15600021
*       WAS READ, DEMOUNT MESSAGE IEC014E D IS ISSUED, THE VOLUME     * 15700021
*       IS UNLOADED, AND THE MOUNTING PROCEDURE IS REPEATED.          * 15800021
*                                                                     * 15900021
* ENTRY POINTS -                                                      * 16000021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 16100021
*                                                                     * 16200021
* INPUT -                                                             * 16300021
*    1. REGISTER CONTENTS AT ENTRY ARE AS FOLLOWS-                    * 16400021
*       'RDCB' - ADDRESS OF THE DCB BEING PROCESSED;                  * 16500021
*       'RCORE'- ADDRESS OF THE WORK AREA FOR THAT DCB;               * 16600021
*       'RES'  - ADDRESS OF THE OPEN/CLOSE/EOV RESIDENT ROUTINE;      * 16700021
*       'RWTG' - ADDRESS OF THE WHERE-TO-GO TABLE;                    * 16800021
*       'RPARC'- ADDRESS OF THE EOV PSEUDO PARAMETER LIST ENTRY;      * 16900021
*       'RWTGC'- ADDRESS OF THE CURRENT WHERE-TO-GO TABLE ENTRY;      * 17000021
*       'RTIOT'- ADDRESS OF THE CURRENT TIOT ENTRY FOR THE DCB;       * 17100021
*       'RUCB' - ADDRESS OF THE CURRENT UCB FOR THE DCB;              * 17200021
*       'RDEB' - ADDRESS OF THE DCB'S DEB;                            * 17300021
*                                                                     * 17400021
* OUTPUT -                                                            * 17500021
*    1. AT EXIT TO IFG0550P (PROBLEM DETERMINATION)-                  * 17600021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 17700021
*          REGISTER 'R0' CONTAINS ONE OF THE FOLLOWING INTERNAL       * 17800021
*          ERROR CODES (THE CORRESPONDING ABEND AND RETURN CODES ARE  * 17870021
*          INDICATED IN PARENTHESES)-                                 * 17940021
*          155 (637/24)- ERROR PERFORMING REWIND (THE REWIND WAS      * 18010021
*                        ISSUED BY THE PREVIOUS MODULE).              * 18080021
*          156 (B37/04)- NO DEVICE AVAILABLE FOR NEXT REQUIRED VOLUME.* 18150021
*          157 (637/28)- ERROR UNLOADING NEXT REQUIRED UNIT.          * 18220021
*          158 (637/2C)- ERROR REWINDING PREPARATORY TO READING       * 18290021
*                        THE VOLUME LABEL.                            * 18360021
*          159 (637/30)- ERROR UNLOADING A VOLUME WHICH WAS           * 18430021
*                        INCORRECTLY MOUNTED IN RESPONSE TO MESSAGE   * 18500021
*                        IEC001A M.                                   * 18570021
*          160 (637/34)- ERROR READING THE VOLUME LABEL.              * 18640021
*          161 (637/38)- ERROR REWINDING AN NL OR NSL VOLUME.         * 18710021
*         181 (537/04)- ERROR DUPLICATE VOLUMES.                SA47382 18750021
*       WORK AREA INDICATORS-                                         * 18800021
*          'DXCALLID' CONTAINS THE 2-BYTE ID OF THIS MODULE.          * 18900021
*    2. AT EXIT TO IFG0552P (EOV TAPE MESSAGE-WRITING MODULE)-        * 19000021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 19100021
*          REGISTER 'RET' CONTAINS ONE OF THE FOLLOWING RETURN        * 19200021
*          BRANCH TABLE OFFSETS-                                      * 19300021
*             12- RETURN FROM ISSUING MOUNT MESSAGE IEC001A M;        * 19400021
*             16- RETURN FROM ISSUING MESSAGE IEC003E R.              * 19500021
*       WORK AREA INDICATORS-                                         * 19700021
*          MESSAGE BUFFER- CONTAINS ANY OF MESSAGES IEC001A M         * 19800021
*                          OR IEC003E R AND THE                       * 19900021
*                          APPROPRIATE VOLUME SERIAL NUMBER.          * 20000021
*          'DXCCW7+1' - 0 - INDICATES THAT THE DATA SET NAME FROM     * 20100021
*                           THE JFCB IS TO BE USED IF THE DATA SET    * 20200021
*                           NAME IS REQUIRED IN THE MESSAGE;          * 20300021
*          'DXRETMOD' - CONTAINS THE 5-BYTE ID/TTR OF THIS MODULE;    * 20400021
*    3. AT EXIT TO IFG0553D (DATA SET POSITIONING FUNCTION)-          * 20500021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 20600021
*          REGISTER 'RET' CONTAINS ONE OF THE FOLLOWING BRANCH TABLE  * 20700021
*          OFFSETS-                                                   * 20800021
*             '0' - NORMAL ENTRY TO POSITION TO DESIRED DATA SET;     * 20900021
*             '4' - WAIT FOR COMPLETION OF A REWIND, THEN POSITION    * 21000021
*                   TO DESIRED DATA SET.                              * 21100021
*       CONTROL BLOCK INDICATORS-                                     * 21200021
*          'SRTEDMCT' - X'80', OFF - INDICATES THAT NO MOUNT MESSAGES * 21300021
*                                    ARE OUTSTANDING;                 * 21400021
*          'SRTESTAB' - X'04' - INDICATES THAT AN AL TAPE HAS BEEN    * 21500021
*                               VERIFIED;                             * 21600021
*          'SRTESTAT' - X'01' - INDICATES THAT AN SL TAPE HAS BEEN    * 21700021
*                               VERIFIED.                             * 21800021
*                                                                     * 21900021
* EXTERNAL REFERENCES -                                               * 22000021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 22100021
*                                                                     * 22200021
* EXITS, NORMAL -                                                     * 22300021
*         IFG0552P - TO ISSUE A 'MOUNT' OR 'RETAIN' MESSAGE.          * 22400021
*         IFG0553D - TO CHECK FOR THE NEED FOR A FILE PROTECT RING    * 22600021
*                    AND TO POSITION TO THE DESIRED DATA SET.         * 22700021
*         IFG0552X - TO ISSUE IEC017I -1 MESSAGE                SA57176 22750000
*                                                                     * 22800021
* EXITS, ERROR -                                                      * 22900021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 23000021
*                                                                     * 23100021
* TABLES/WORK AREAS -                                                 * 23200021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 23300021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 23400021
*                                                                     * 23500021
* ATTRIBUTES -                                                        * 23600021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 23700021
*                                                                     * 23800021
* CHARACTER CODE DEPENDENCY -                                         * 23900021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 24000021
*                                                                     * 24100021
* NOTES -                                                             * 24200021
*                                                                     * 24300021
*********************************************************************** 24400021
*                                                                       24500021
*                                                                       26300021
*****          DETERMINE IF THE DESIRED VOLUME IS ALREADY MOUNTED       26400021
*                                                                       26500021
ETI13300 EQU   *                                                        26600021
         CLI   DXVOLSR2,ALLBITS         NON-SPECIFIC REQUEST    SA65517 26650003
*                                       OR UNOPENED GDG         SA65517 26660003
         LA    RD,EABD251               LOAD INT ABEND CODE     SA65517 26670003
         BE    ETI16600                 YES, ABEND              SA65517 26680003
         L     RET,TIOESTTB             SAVE FIRST UCB OF LIST          26700021
         LH    RD,DXNOUNIT              LOAD NO. OF UNITS ALLOC         26800021
         SR    RC,RC                    ZERO INDEX TO UCB ADDRS         26900021
ETI13400 EQU   *                                                        27000021
         L     RUCB,TIOESTTB(RC)        LOAD NEXT UCB ADDR FROM TIOT    27100021
         CLC   SRTEVOLI,DXVOLSR2        TEST IF DESIRED VOL SER         27200021
         BNE   ETI13450                 BR NOT SAME VOL SER     SA47382 27300000
*  CHECK THE DATA MANAGEMENT COUNT TO INSURE THAT NO OTHER DCB IS       27310021
*  PROCESSING THIS TAPE.                                                27320021
         LA    RD,EABD181               537 ABEND CODE          SA47382 27330021
         TM    SRTEDMCT,UCBDMC          IS DM USE COUNT 0       SA47382 27340021
         BNZ   ETI16600                 BR NO TO ABEND          SA47382 27350021
         B     ETI13800                 SAME VOL NOT USED       SA47382 27360021
*                                                               SA47382 27370021
ETI13450 EQU   *                                                SA47382 27380021
         LA    RC,K4(,RC)               ADVANCE INDEX IN TIOT           27400021
         BCT   RD,ETI13400              BR IF MORE UCB ADDRESSES        27500021
*                                                                       27600021
*****          THE DESIRED VOLUME IS NOT MOUNTED-                       27700021
*****          DETERMINE IF AN EMPTY UNIT IS AVAILABLE                  27800021
*                                                                       27900021
         LH    RD,DXNOUNIT              LOAD NO. OF UNITS ALLOC         28000021
         SR    RC,RC                    RESET INDEX TO UCB ADDRS        28100021
ETI13500 EQU   *                                                        28200021
         L     RUCB,TIOESTTB(RC)        LOAD UCB ADDR FROM TIOT         28300021
         CLI   SRTEVOLI,K0              TEST IF NO VOL SER NO.          28400021
         BNE   ETI13600                 ..BR IF VOL SERIAL NO. EXISTS   28500021
         TM    SRTEDMCT,UCBDMC          IS DM USE COUNT 0       SA47382 28530021
         BNZ   ETI13600                 BR NO, CONTINUE         SA47382 28560021
         TM    SRTESTAT,SRTERESV        TEST ALSO IF RESERVED           28600021
         BZ    ETI13800                 BR NO, USE THIS UNIT            28700021
ETI13600 EQU   *                                                        28800021
         LA    RC,K4(,RC)               ADVANCE INDEX IN TIOT           28900021
         BCT   RD,ETI13500              BR IF MORE UCB ADDRESSES        29000021
*                                                                       29100021
*****          THERE ARE NO EMPTY UNITS-                                29200021
*****          FIND A UNIT WITH A DISMOUNTABLE VOLUME                   29300021
*                                                                       29400021
         LH    RD,DXNOUNIT              LOAD NO. OF UNITS ALLOC         29500021
ETI13700 EQU   *                                                        29600021
         L     RUCB,TIOESTTB            LOAD ADDRESS OF UCB             29700021
         TM    SRTEDMCT,UCBDMC          IS DM USE COUNT 0       SA47382 29730021
         BNZ   ETI13750                 BR NO, CONTINUE         SA47382 29760021
         TM    SRTESTAT,SRTERESV        IS THIS UNIT RESERVED-          29800021
         BZ    ETI13900                 ..BR IF NOT- USE THIS UNIT      29900021
*                                                               SA47382 29930021
ETI13750 EQU   *                                                SA47382 29960021
         BCTR  RC,0                     DECR BY 1 FOR 'EXECUTE' INSTR   30000021
         EX    RC,ROTATE                SHIFT UCB POINTERS LEFT         30100021
         LA    RC,K1(,RC)               ADD BACK 1                      30200021
         ST    RUCB,TIOESTTB-4(RC)      ST OLD UCB ADDR IN LAST ENTRY   30300021
         BCT   RD,ETI13700              DECR UNIT CT- BR IF ADD'L UNITS 30400021
         LA    RD,EABD156               LOAD INTERNAL ERROR CODE AND BR 30500021
         B     ETI16600                 ..TO ERR RTN- NO DEV AVAILABLE  30600021
ROTATE   EQU   *                                                        30700021
         MVC   TIOESTTB(K0),TIOESTTB+4  SHIFT UCB ADDR LIST LEFT        30800021
ETI13800 EQU   *                                                        30900021
         ST    RUCB,TIOESTTB            NEW PTR TO START OF LIST        31000021
         ST    RET,TIOESTTB(RC)         OLD UCB PTR TO NEW PTR          31100021
ETI13900 EQU   *                                                        31200021
         MVC   DXDEBUCB+1(K3),TIOEFSRT  MOVE NEW UCB ADDR INTO WORK     31300021
         MVC   DEBUCBAD+1(K3),TIOEFSRT  ..AND USER'S DEB                31400021
         OI    SRTEDMCT,K1              INITLZ DATA MANAGEMENT CT TO 1  31500021
         OI    TIOESTTB,TIOSUSED        IND THAT DATA SET IS ON DEVICE  31600021
ETI14000 EQU   *                                                        31700021
         TM    SRTESTAB,UCBBNUL         IS UCB MOUNT MSG 'DOM' IND ON-  31900021
         BO    ETI14200                 BR IF SO                SA58669 31950001
         MVC   UCBSQC(K6),JFCBVOLS      OLD FILE SER NUM TO UCB SA58669 32000001
ETI14200 EQU   *                                                        33100021
         CLC   SRTEVOLI,DXVOLSR2        IS THIS THE DESIRED VOLUME-     33300021
         BE    ETI14900                 ..BRANCH IF YES                 33400021
*                                                                       33500021
*********************************************************************** 33600021
*              THE MOUNT-PENDING OR CURRENT TAPE ON THIS UNIT         * 33700021
*              IS UNACCEPTABLE-  CANCEL ALL OUTSTANDING MOUNT         * 33800021
*              MESSAGES ASSOCIATED WITH THE TAPE AND UNLOAD IT        * 33900021
*              IF IT IS MOUNTED                                       * 34000021
*********************************************************************** 34100021
*                                                                       34200021
         BAL   RC,ETI16400              BR AND LINK TO 'DOM' MSG        34400021
ETI14400 EQU   *                                                        34500021
         NI    SRTEDMCT,X'FF'-UCBMOUNT  CLEAR ANY MOUNT FLAG            34600021
         TM    UCBFL2,UCBNOTRD          IS THE UNIT 'READY'-            34700021
         BO    ETI14800                 ..BR IF NOT-READY               34800021
         CLI   SRTEVOLI,K0              TEST FOR ANY VOLUME MOUNTED-    34900021
         BE    ETI15000                 ..BRANCH IF NONE                35000021
*                                                                       35100021
*****          UNLOAD THE CURRENT VOLUME AND ISSUE APPROPRIATE MSG      35200021
*                                                                       35300021
         LA    RD,EABD157               LOAD INTERNAL ERROR CODE        35400021
         MVC   DXCCW1,REWULCCW          INITLZ CCW FOR 'REWIND/UNLOAD'  35500021
         BAL   RC,ETI16500              BR AND LINK TO INITIATE 'RUN'   35600021
         LA    RET,K16                  BR TABLE OFFSET FOR MSG RETURN  35700021
         MVC   MCSFLAGS(K12),RETMSG2Z   INITLZ BUFFER FOR 'RETAIN' MSG  35800021
         MVC   MSGVOLSR,SRTEVOLI        INSERT VOL SER NO. INTO MSG     35900021
         B     ETI16200                 BR TO ISSUE 'RETAIN' MESSAGE    37000021
*                                                                       37100021
*********************************************************************** 37200021
*              THE VOLUME JUST MOUNTED IS INVALID-  ISSUE A           * 37300021
*              DISMOUNT MESSAGE, UNLOAD IT, AND ASK FOR A             * 37400021
*              RE-MOUNT                                               * 37500021
*********************************************************************** 37600021
*                                                                       37700021
ETI14600 EQU   *                                                        37800021
         LA    RD,EABD159               CODE FOR ERROR UNLOADING WRONG  37900021
         MVC   DXCCW1,REWULCCW          INITLZ CCW FOR 'REWIND/UNLOAD'  38000021
         BAL   RC,ETI16500              BR AND LINK TO PERFORM 'RUN'    38100021
         MVC   MSGLSTSZ(MESSAGEL),MESSAGED  SET UP DISMOUNT MSG         38200021
         MVC   MSGUN,UCBNAME            ADD UCB UNIT NAME TO MSG        38300021
         WTO   MF=(E,MSGLSTSZ)          WRITE MSG TO OPERATOR           38400021
ETI14700 EQU   *                                                        38500021
         OI    UCBFL2,UCBNOTRD          SET UNIT NOT-READY              38600021
ETI14800 EQU   *                                                        38700021
         XC    SRTEVOLI,SRTEVOLI        ZERO UCB VOL SER NUMBER         38800021
ETI14900 EQU   *                                                        38900021
         TM    UCBFL2,UCBNOTRD          IS THE UNIT 'READY'-            39000021
         BO    ETI15000                 ..BR IF NOT TO RE-ISSUE MOUNT   39100021
*                                                                       39200021
*****    NOTE- AFTER IPL, THE UCB 'NOT-READY' BIT CAN BE FALSELY OFF    39300021
*                                                                       39400021
         CLI   SRTEVOLI,K0              IS A VOLUME MOUNTED-            39500021
         BE    ETI15000                 ..BRANCH IF NO VOL MOUNTED      39600021
         TM    SRTEDMCT,UCBMOUNT        IS A MOUNT MSG OUTSTANDING-     39700021
         BO    ETI15200                 ..BR IF YES TO TRY THIS TAPE    39800021
         LH    R1,SRTEFSCT              LOAD THE FILE SEQ COUNT         39900021
         LTR   R1,R1                    WAS VOLUME PREVIOUSLY VERIFIED- 40000021
         BZ    ETI15200                 ..BR IF NOT TO REWIND TAPE      40100021
         MVC   UCBFSER(K6),JFCBVOLS     FILE SER NUM TO UCB     SA58669 40150001
         TM    JFCBLTYP,JFCBLTM         IS THERE POSSIBLY A LEADING     40200021
*                                       ..TAPE MARK ( DOS NL TAPE )     40300021
         BNO   ETI16000                 ..BR IF NOT TO XCTL TO NEXT MOD 40400021
*                                       ..TO POSITION TO DATA SET       40500021
         B     ETI15200                 BRANCH TO READ LABEL- THIS      40600021
*                                       ..FACILITATES POSITIONING IF    40700021
*                                       ..THERE IS A DOS NL TAPE        40800021
*                                       ..WITH LEADING TAPE MARK        40900021
*                                                                       41000021
*********************************************************************** 41100021
*              ANY PREVIOUS 'MOUNT-AHEAD' HAS NOT BEEN COMPLETED-     * 41200021
*              CANCEL ALL OUTSTANDING MOUNT MESSAGES AND ISSUE A      * 41300021
*              MOUNT MESSAGE FOR THE DESIRED VOLUME                   * 41400021
*********************************************************************** 41500021
*                                                                       41600021
ETI15000 EQU   *                                                        41700021
         BAL   RC,ETI16400              BR AND LINK TO 'DOM' MSG        41800021
ETI15100 EQU   *                                                        41900021
         MVC   MCSFLAGS(K12),FLAGS0X    MOVE IN MOUNT MESSAGE           42000021
         MVC   MSGVOLSR,DXVOLSR2        MOVE VOL SER NO INTO MSG        42100021
         OI    SRTEDMCT,UCBMOUNT        SET UCB MOUNT FLAG              42200021
         MVC   SRTEVOLI,DXVOLSR2        PUT VOL SER NO. IN UCB          42300021
         LA    RET,K12                  BR TABLE OFFSET FOR MSG RETURN  42500021
         B     ETI16200                 BR TO ISSUE MOUNT MESSAGE       42600021
*                                                                       42700021
*********************************************************************** 42800021
*              REWIND THE TAPE BEFORE READING THE VOLUME LABEL-       * 42900021
*              THIS PUTS THE PROGRAM INTO A WAIT STATE UNTIL          * 43000021
*              THE TAPE IS MOUNTED                                   *  43100021
*********************************************************************** 43200021
*                                                                       43300021
ETI15200 EQU   *                                                        43400021
         MVC   DXCCW1,REWNDCCW          INITLZ CCW FOR 'REWIND' COMMAND 43600021
         EXCP  DXIOB                    INITIATE REWIND OPERATION       43700021
         IECRES WAIT                    WAIT FOR REWIND TO BEGIN        43800021
         CLI   DXECB,ECBINCPT           WAS CHANNEL PROGRAM     SA58669 43850001
*                                       INTERCEPTED             SA58669 43860001
         BNE   ETI15250                 IF NOT, GO ERROR CHECK  SA58669 43870001
*                                                               SA58669 43872001
*********************************************************************** 43874001
*              REISSUE CHANNEL PROGRAM REQUEST IF IT WAS INTERCEPTED  * 43876001
*********************************************************************** 43878001
*                                                               SA58669 43878401
         EXCP  DXIOB                    REISSUE CHANNEL PROGRAM SA58669 43880001
         IECRES WAIT                    INVOKE IECRES MACRO     SA58669 43890001
ETI15250 EQU   *                                                SA58669 43894001
         BAL   RC,ETI16400              BR AND LINK TO 'DOM' MSG, IF RE 43900021
         TM    DXECB,ECBNOERR           TEST FOR I/O ERROR-             44000021
         BO    ETI15300                 ..BR IF NOT TO CONTINUE         44100021
         TM    IOBSENS1,UCBLDPT         IS TAPE AT LOAD POINT (BOT)-    44200021
         LA    RD,EABD158               CODE FOR ERROR REWINDING A47788 44250021
*                                       NEW VO                   A47788 44260021
         BNO   ETI16600                 ..BR IF NOT TO ERROR RTN        44300021
ETI15300 EQU   *                                                        44400021
         LA    RD,EABD158               CODE FOR ERROR REWINDING A47788 44450021
*                                       NEW VO                   A47788 44460021
         MVI   DXCCW1,CCWNOP            INITLZ CCW FOR 'NOP' COMMAND    44500021
         BAL   RC,ETI16500              BR AND LINK TO ISSUE 'NOP'      44600021
         MVC   SRTEFSCT(K2),CONST10X    SET FILE SEQUENCE CT TO ONE     44700021
*                                                                       44720021
         NI    SRTESTAB,X'FF'-UCBBSTR   RESET 'AL VERIFIED' IND  A39275 44740021
         NI    SRTESTAT,X'FF'-UCBDADI   RESET 'SL VERIFIED' IND  A39275 44760021
*                                                                       44780021
         TM    JFCBLTYP,JFCBLP          TEST FOR BYPASS LBL PROCESSING  44800021
         BO    ETI16000                 ..BR IF YES- BYPASS READING LBL 44900021
         LA    R1,DXLBL                 LOAD ADDRESS OF BUFFER, THEN    45000021
         ST    R1,DXCCW1                ..STORE IT IN 'READ' CCW        45100021
         MVI   DXCCW1,CCWRDTAP          INITLZ CCW FOR 'READ' COMMAND   45200021
         LA    R1,K80                   SET DATA LENGTH OF CCW          45300021
         ST    R1,DXCCW1+K4             ..TO 80, 'SILI' BIT OFF         45400021
         LA    RD,EABD160               INTERNAL ERROR CODE             45500021
         EXCP  DXIOB                    INITIATE I/O OPERATION          45600021
         IECRES WAIT                    INVOKE IECRES MACRO TO WAIT     45700021
         TM    IOBSTAT1,X'3E'           CHAN PROG/PROT/DATA/CTRL/IFCE C 45800021
         BNZ   ETI16600                 YES,ABEND                       45900021
         TM    IOBSTAT0,X'02'           TEST FOR UNIT CHECK-            46000021
         BZ    ETI15500                 BR IF NOT                       46100021
         TM    IOBSENSE,X'F7'           TEST FOR ERRORS OTHER THAN DATA 46200021
         BNZ   ETI16600                 BR IF YES TO ABEND              46300021
         TM    IOBSENS1,X'01'           IS 'NOT CAPABLE' BIT ON-        46400021
         BO    ETI14600                 ..BR IF YES- REJECT THIS VOLUME 46500021
         B     ETI15700                 ..ELSE BR TO TEST FOR NL OR NSL 46600021
*                                                                       46700021
*********************************************************************** 46800021
*              TEST FOF A VOLUME LABEL                                * 46900021
*********************************************************************** 47000021
*                                                                       47100021
ETI15500 EQU   *                                                        47200021
         CLC   DXLBL(K4),ACONVOL        IS THIS AN ANSI VOLUME-         47300021
         BNE   ETI15600                 ..BR IF NOT TO TEST FOR SL      47400021
         CLI   IOBCNT+1,K0              MAYBE,TEST LENGTH       XA02411 47450003
         BNZ   ETI15700                 .LT. 80 CHARS, NOT ANSI XA02411 47460003
         XLATE DXLBL,K80                TRANSLATE 'ANSI' LABEL          47500021
         B     ETI15800                 BR TO CHECK TYPE OF LABEL       47600021
ETI15600 EQU   *                                                        47700021
         TM    IOBSTAT1,HEX40           TEST FOR INCORRECT LENGTH-      47800021
         BO    ETI15700                 ..BRANCH IF YES                 47900021
         CLC   DXLBL(K4),CONSTVOL       TEST FOR A VOLUME LABEL-        48000021
         BE    ETI15800                 ..BR IF A VOLUME LABEL EXISTS   48100021
ETI15700 EQU   *                                                        48200021
         TM    JFCBLTYP,JFCBAL+JFCSL    WAS AL OR SL SPECIFIED-         48300021
         BNZ   ETI14600                 ..BR IF YES- WRONG VOLUME       48400021
         TM    JFCBLTYP,JFCBLTM         IS THERE POSSIBLY A LEADING     48500021
*                                       ..TAPE MARK ( 'DOS' NL TAPE )-  48600021
         BNO   ETI15750                 ..BR IF NOT TO REWIND TAPE      48700021
         TM    IOBSTAT0,CSWUNITX        WAS A TAPE MARK READ-           48800021
         BO    ETI16000                 ..BR IF YES- POSITION IS OKAY   48900021
*                                       ..ELSE REWIND THE TAPE          49000021
ETI15750 EQU   *                                                        49100021
         LA    RD,EABD161               LOAD INTERNAL ERROR CODE        49200021
         MVC   DXCCW1(K8),REWNDCCW      INITLZ CCW FOR REWIND COMMAND   49300021
         BAL   RC,ETI16500              BR AND LINK TO INITIATE REWIND  49400021
         LA    RET,K4                   BR TABLE OFFSET FOR NEXT MODULE 49500021
         B     ETI16100                 BR TO EXIT THIS MODULE          49600021
ETI15800 EQU   *                                                        49700021
         TM    JFCBLTYP,JFCBAL+JFCSL    WAS AL OR SL SPECIFIED-         50000021
         BZ    ETI14600                 BR IF NOT TO UNLOAD TAPE        50100021
         CLC   VOLSERNO,DXVOLSR2        TEST FOR CORRECT VOLUME-        50200021
         BNE   ETI14600                 ..BR IF NOT TO REMOUNT VOL      50300021
         TM    JFCBLTYP,JFCBAL          WERE ANSI LABELS SPECIFIED-     50400021
         BZ    ETI15900                 BR IF NOT TO IND SL IN UCB      50500021
         CLI   VOLSEC,BLANK             TEST ACCESSIBILITY      SA57176 50550000
         BNE   ETI15850                 BRANCH NOT ACCESSABLE   SA57176 50560000
         OI    SRTESTAB,UCBBSTR         SET 'ASCII LABEL VERIFIED' IND  50600021
         B     ETI16000                 BR TO XCTL TO NEXT MODULE       50700021
ETI15850 LA    RET,K20                  SET TABLE OFFSET TO 20  SA57176 50750000
*                                       FOR NEXT MODULE         SA57176 50770000
         LA    RF,MOD2X2Z               POINT TO IFG0552X       SA57176 50780000
         B     ETI16300                 XCTL TO IFG0552X        SA57176 50790000
ETI15900 EQU   *                                                        50800021
         OI    SRTESTAT,UCBDADI         SET 'SL VERIFIED' INDR          50900021
ETI16000 EQU   *                                                        51000021
         SR    RET,RET                  BR TABLE OFFSET FOR NEXT MODULE 51100021
ETI16100 EQU   *                                                        51200021
         MVI   DXCCW1+4,K0              TURN OFF ALL CCW INDICATORS     51300021
         NI    SRTEDMCT,X'FF'-UCBMOUNT  CLEAR MOUNT FLAG                51400021
         SPACE 2                                                        51500021
*********************************************************************** 51600021
*              EXITS                                                  * 51700021
*********************************************************************** 51800021
*                                                                       51900021
*****          XCTL TO THE NEXT MODULE TO CONTINUE THIS FUNCTION        52000021
*                                                                       52100021
         LA    RF,MOD3D2Z               PT TO NEXT MODULE ID/TTR        52200021
         B     ETI16300                 BRANCH TO NEXT MODULE TO RD LAB 52300021
*                                                                       52400021
*                                                                       52500021
*****          XCTL TO THE WRITE-TO-OPERATOR MODULE                     52600021
*                                                                       52700021
ETI16200 EQU   *                                                        52800021
         MVC   DXRETMOD(K5),MOD2Z2Z     SAVE RETURN ID/TTR              52900021
         LA    RF,MODWTO2Z              PT TO THE WTO MODULE ID/TTR     53000021
*                                                                       53100021
ETI16300 EQU   *                                                        53200021
         IECRES XCTL,(RF),(RET)         INVOKE IECRES MACRO TO XCTL     53300021
         EJECT                                                          53400021
*********************************************************************** 53500021
*              SUBROUTINES                                            * 53600021
*********************************************************************** 53700021
*                                                                       53800021
*****          DELETE A MESSAGE TO THE OPERATOR                         53900021
*                                                                       54000021
ETI16400 EQU   *                                                        54100021
         TM    UCBSTAB,UCBBNUL          IS DOM INDICATED        SA47795 54250021
         BCR   14,RC                    ..BR IF NOT- RETURN TO  SA47795 54300021
*                                       CALLER                  SA47795 54350021
         MVI   REPLY+K4,LASTNTRY        INITIALIZE TO SHOW 1 MSGSA58669 54360001
         MVC   REPLY+K5(K3),UCBFSER     MSG ID TO PARM LIST     SA58669 54370001
         NC    UCBFSER+K3(K3),UCBFSER+3 IS THERE A 2ND ID       SA58669 54380001
         BZ    ETI16450                 IF NOT, GO DOM THE MSG  SA58669 54390001
         MVI   REPLY+K4,K0              CLEAR ONE-MSG INDICATOR SA58669 54392001
         MVI   REPLY+K8,LASTNTRY        SHOW 2 MESSAGES TO DOM  SA58669 54394001
         MVC   REPLY+K9(K3),UCBFSER+K3  2ND ID TO PARM LIST     SA58669 54396001
ETI16450 EQU   *                                                SA58669 54398001
         DOM   MSGLIST=REPLY+4          DELETE THE MESSAGE              54400021
         NI    UCBSTAB,X'FF'-UCBBNUL    TURN OFF UCB DOM IN     SA47795 54450021
         MVC   UCBSQC(K6),JFCBVOLS      RESTORE DS SER NUM      SA58669 54550001
         BR    RC                       RETURN TO CALLER OF SUBROUTINE  54600021
         SPACE 2                                                        54700021
*                                                                       54800021
*****          CLOSED SUBROUTINE TO PERFORM I/O OPERATIONS              54900021
*****          ENTRY TO THE SUBROUTINE IS VIA A'BAL  RC,ETI16500'       55000021
*                                                                       55100021
ETI16500 EQU   *                                                        55200021
         EXCP  DXIOB                    PERFORM THE I/O OPERATION       55300021
         IECRES WAIT                    INVOKE IECRES MACRO TO 'WAIT'   55400021
         TM    DXECB,ECBNOERR           TEST FOR I/O ERROR-             55500021
         BCR   1,RC                     ..BR IF NOT- RETURN TO CALLER   55600021
         TM    IOBSENS1,UCBLDPT         IS TAPE AT LOAD POINT (BOT)-    55700021
         BCR   1,RC                     ..BR IF YES- RETURN TO CALLER   55800021
*                                       ..ELSE DROP THROUGH TO ERR RTN  55900021
         EJECT                                                          56000021
*********************************************************************** 56100021
*              ERROR PROCESSING                                       * 56200021
*********************************************************************** 56300021
*                                                                       56400021
ETI16600 EQU   *                                                        56500021
         DMABCOND (RD),ABEND2Z          EXIT TO PROB DETERMINATION RTN  56600021
         SPACE 2                                                        56700021
*********************************************************************** 56800021
*              CONSTANTS                                              * 56900021
*********************************************************************** 57000021
*                                                                       57100021
REWULCCW CCW   X'0F',0,X'20',1          REWIND AND UNLOAD CCW           57200021
REWNDCCW CCW   X'07',0,X'20',1          REWIND CCW                      57300021
CONST10X DC    X'0001'                  CONSTANT ONE                    57400021
ZEROES   DC    X'000000'                COMPARE CONSTANT                57500021
ACONVOL  DC    X'564F4C31'              ASCII CODE FOR 'VOL1'           57600021
CONSTVOL DC    CL4'VOL1'                VOLUME LABEL IDENTIFIER         57700021
RETMSG2Z DC    X'8000'                  MCS FLAGS FOR RETAIN MESSAGE    57800021
         DC    C'IEC003E R '            BASIC RETAIN MESSAGE            57900021
FLAGS0X  DC    X'8000'                  MCS FLAGS FOR MOUNT MESSAGE     58200021
         DC    C'IEC001A M '            BASIC MOUNT MESSAGE             58300021
*              THE FOLLOWING 6 LINES MUST REMAIN INTACT                 58400021
MESSAGED DC    X'0011'                  LENGTH OF DISMOUNT MESSAGE      58500021
         DC    X'8000'                  MCS FLAGS FOR DISMOUNT MESSAGE  58600021
         DC    C'IEC014E D UUU'         BASIC DISMOUNT MESSAGE          58700021
         DC    X'20002000'              MCS DESCRIPTOR AND ROUTING      58800021
*                                       ..CODES FOR DISMOUNT MESSAGE    58900021
MESSAGEL EQU   *-MESSAGED               LENGTH OF DISMOUNT MSG PLUS MCS 59000021
*                                       ..DESCRIPTOR AND ROUTING CODES  59100021
         EJECT                                                          59200021
*********************************************************************** 59300021
*              XCTL TABLE                                             * 59400021
*********************************************************************** 59500021
*                                                                       59600021
         AIF   ('&LIB' EQ 'LIB1').LIB12Z1                       XA02411 59650003
         XCTLTABL ID=(ABEND2Z,0P,MODWTO2Z,2P,MOD2X2Z,2X,        XA02411C59700003
               MOD2Z2Z,2Z,MOD3D2Z,3D),SVC=055,LENGTH=2048,      XA02411C59750003
               PATCH=100                                        XA02411 59800003
         AGO   .LIB22Z1                                         XA02411 59810003
.LIB12Z1 ANOP                                                           59820003
         XCTLTABL ID=(ABEND2Z,0P,MODWTO2Z,2P,MOD2X2Z,2X,        SA57176C59850000
               MOD2Z2Z,2Z,MOD3D2Z,3D),SVC=055                   SA57176 59860000
.LIB22Z1 ANOP                                                           59870003
         SPACE 2                                                        59900021
         IECDSECS CVT,                                                 C60000021
               TCB,                                                    C60100021
               TIOT,                                                   C60200021
               SMF,                                                    C60300021
               BASE,                                                   C60400021
               DCB,                                                    C60500021
               DEB,                                                    C60600021
               UCB,                                                    C60700021
               MAIN,                                                   C60800021
               EXPAND=YES                                               60900021
         IECEQU ,                       INVOKE OPEN/CLOSE/EOV EQUATES   61000021
         SPACE 2                                                        61100021
         END                                                            61200021
