 TITLE 'IFG0553D - EOV TAPE INPUT NEW VOLUME MOUNTING FUNCTION (CONT.)' 00100000
         GBLC  &LIB                      DEFINE GLOBAL CHAR VARIABLE    00200000
&LIB     SETC  'LIB1'                    SET VALUE FOR &LIB             00300000
IFG0553D CSECT                                                          00400000
*                                                                       00500000
*********************************************************************** 00600000
*                                                                     * 00700000
*                                                                     * 00800000
*          RELEASE 25 DELETIONS/CHANGES                               * 00900000
*          RELEASE 24 DELETIONS/CHANGES                               * 01000000
*          RELEASE 23 DELETIONS/CHANGES                               * 01100000
*          RELEASE 22 DELETIONS/CHANGES                               * 01200000
*          RELEASE 21 DELETIONS/CHANGES                               * 01300000
*0000222000,229000,390000                                        M0026  01350021
*                                                                     * 01400000
* STATUS CHANGE LEVEL 000                                             * 01500000
*                                                                     * 01600000
* FUNCTION -                                                          * 01700000
*    THIS MODULE CONTAINS THE FOLLOWING FUNCTIONS-                    * 01800000
*       1) 'EOV TAPE INPUT NEW VOLUME MOUNTING FUNCTION', PART II;    * 01900000
*       2) 'EOV TAPE INPUT DATA SET POSITIONING FUNCTION'.            * 02000000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS' FOR DETAILS.           * 02100000
*                                                                     * 02200000
* ENTRY POINTS -                                                      * 02300000
*         IFG0553D                                                    * 02400000
*                                                                     * 02500000
* INPUT -                                                             * 02600000
*    REGISTER 14 ('RET') WILL CONTAIN ONE OF THE BRANCH TABLE OFFSETS * 02700000
*    LISTED BELOW, THE BRANCH TABLE BEING USED TO DETERMINE AT WHICH  * 02800000
*    POINT PROCESSING IS TO BEGIN -                                   * 02900000
*       0 - ENTRY FROM IFG0552Z TO TEST FOR THE NEED FOR A FILE       * 03000000
*           PROTECT RING;                                             * 03100000
*       4 - ENTRY FROM IFG0552Z TO WAIT FOR COMPLETION OF THE         * 03200000
*           REWIND OF AN NL OR NSL VOLUME FOLLOWING THE VOLUME        * 03300000
*           VERIFICATION PROCESS; THEN TEST FOR THE NEED FOR A FILE   * 03400000
*           PROTECT RING;                                             * 03500000
*       8 - RETURN FROM MESSAGE-WRITING MODULE IFG0552P AFTER         * 03600000
*           ISSUING A FILE PROTECT MESSAGE TO WAIT FOR A REPLY.       * 03700000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS' FOR ADDITIONAL INPUT.  * 03800000
*                                                                     * 03900000
* OUTPUT -                                                            * 04000000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 04100000
*                                                                     * 04200000
* EXTERNAL REFERENCES -                                               * 04300000
*         IFG055RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 04400000
*                    WAIT. REFER TO THE FOLLOWING 'FUNCTION PROLOGS'. * 04500000
*                                                                     * 04600000
* EXITS, NORMAL -                                                     * 04700000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 04800000
*                                                                     * 04900000
* EXITS, ERROR -                                                      * 05000000
*         IFG0550P - WHEN AN ERROR CONDITION OCCURS IN THIS MODULE.   * 05100000
*                    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.        * 05200000
*                                                                     * 05300000
* TABLES/WORK AREAS -                                                 * 05400000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 05500000
*                                                                     * 05600000
* ATTRIBUTES -                                                        * 05700000
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 05800000
*                                                                     * 05900000
* CHARACTER CODE DEPENDENCY -                                         * 06000000
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 06100000
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 06200000
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 06300000
*                                                                     * 06400000
* NOTES -                                                             * 06500000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 06600000
*                                                                     * 06700000
*********************************************************************** 06800000
*                                                                       06900000
*****    INTERNAL ERROR CODES                                           07000000
*                                                                       07100000
EABD161  EQU   161                      ERROR REWINDING NL/NSL VOL      07200000
EABD162  EQU   162                      ERROR POS CONCATENATED DATA SET 07300000
EABD163  EQU   163                      ERROR POS NEW VOL FOR RD FWD    07400000
EABD192  EQU   192                      ERROR READING SENSE BYTES OR    07500000
*                                       ..UNLOADING TAPE IN ORDER TO    07600000
*                                       ..INSERT FILE PROTECT RING      07700000
EABD194  EQU   194                      ERROR POS NEW VOL FOR RDBACK    07800000
*                                                                       07900000
         BALR  RBASE,0                  ESTABLISH ADDRESSABILITY FOR    08000000
         USING *,RBASE                  ..THIS SECTION OF CODE          08100000
         USING FORCORE,RCORE                                            08200000
         USING IHADCB,RDCB                                              08300000
         USING UCB,RUCB                                                 08400000
         USING TIOENTRY,RTIOT                                           08500000
         USING DEB,RDEB                                                 08600000
*                                                                       08700000
         B     ETI18000(RET)            DETERMINE TYPE OF ENTRY TO MOD  08800000
ETI18000 EQU   *                                                        08900000
         B     ETI18200            (0)  BR IF NORMAL ENTRY TO MODULE    09000000
         B     ETI18100            (4)  BR TO WAIT FOR REWIND OF        09100000
*                                       ..NL OR NSL VOLUME              09200000
         B     ETI18400            (8)  BR TO WAIT FOR REPLY FROM FILE  09300000
*                                       .. PROTECT MESSAGE IEC010D      09400000
         EJECT                                                          09500000
*********************************************************************** 09600000
*                                                                     * 09700000
*                          FUNCTION PROLOG                            * 09800000
*                                                                     * 09900000
*********************************************************************** 10000000
*                                                                     * 10100000
* FUNCTION NAME -                                                     * 10200000
*    'EOV TAPE INPUT NEW VOLUME MOUNTING FUNCTION', PART II           * 10300000
*                                                                     * 10400000
* (STATUS) -                                                          * 10500000
*    NOT APPLICABLE                                                   * 10600000
*                                                                     * 10700000
* FUNCTION -                                                          * 10800000
*    1. WAIT FOR THE COMPLETION OF THE REWIND OF AN NL OR NSL VOLUME  * 10900000
*       FOLLOWING THE VOLUME VERIFICATION PROCESS.                    * 11000000
*    2. WHEN THE DCB IS OPENED FOR 'INOUT', READ THE SENSE BYTES TO   * 11100000
*       DETERMINE WHETHER OR NOT THE TAPE IS FILE PROTECTED. IF IT    * 11200000
*       IS, ISSUE FILE PROTECT MESSAGE 'IEC010D F' TO DETERMINE       * 11300000
*       WHETHER OR NOT A FILE PROTECT RING IS REQUIRED, IN WHICH CASE * 11400000
*       THE TAPE IS UNLOADED AND VOLUME VERIFICATION IS REPEATED.     * 11500000
*                                                                     * 11600000
* ENTRY POINTS -                                                      * 11700000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 11800000
*                                                                     * 11900000
* INPUT -                                                             * 12000000
*    1. REGISTER CONTENTS AT ENTRY ARE AS FOLLOWS-                    * 12100000
*       'RDCB' - ADDRESS OF THE DCB BEING PROCESSED;                  * 12200000
*       'RCORE'- ADDRESS OF THE WORK AREA FOR THAT DCB;               * 12300000
*       'RES'  - ADDRESS OF THE OPEN/CLOSE/EOV RESIDENT ROUTINE;      * 12400000
*       'RWTG' - ADDRESS OF THE WHERE-TO-GO TABLE;                    * 12500000
*       'RPARC'- ADDRESS OF THE EOV PSEUDO PARAMETER LIST ENTRY;      * 12600000
*       'RWTGC'- ADDRESS OF THE CURRENT WHERE-TO-GO TABLE ENTRY;      * 12700000
*       'RTIOT'- ADDRESS OF THE CURRENT TIOT ENTRY FOR THE DCB;       * 12800000
*       'RUCB' - ADDRESS OF THE CURRENT UCB FOR THE DCB;              * 12900000
*       'RDEB' - ADDRESS OF THE DCB'S DEB;                            * 13000000
*                                                                     * 13100000
* OUTPUT -                                                            * 13200000
*    1. AT EXIT TO THE EOV TAPE INPUT DATA SET POSITIONING FUNCTION-  * 13300000
*       REGISTER AND WORK AREA CONTENTS ARE VIRTUALLY THE SAME AS     * 13400000
*          AT ENTRY.                                                  * 13500000
*    2. AT EXIT TO IFG0552P (EOV TAPE MESSAGE-WRITING MODULE)-        * 13600000
*       REGISTER CONTENTS ARE THE SAME AS ENTRY EXCEPT THAT REGISTER  * 13700000
*          'RET' CONTAINS A RETURN BRANCH TABLE OFFSET OF '8';        * 13800000
*       WORK AREA INDICATORS-                                         * 13900000
*          MESSAGE BUFFER- CONTAINS BASIC FILE PROTECT MESSAGE        * 14000000
*                          IEC010D F WITH THE VOLUME SERIAL NUMBER;   * 14100000
*          'DXCCW7+1' - 0 - INDICATES THAT THE DATA SET NAME FROM     * 14200000
*                           THE JFCB IS TO BE USED IF THE DATA SET    * 14300000
*                           NAME IS REQUIRED IN THE MESSAGE;          * 14400000
*          'DXRETMOD' - CONTAINS THE 5-BYTE ID/TTR OF THIS MODULE.    * 14500000
*          'REPLYLTH' - CONTAINS THE LENGTH OF THE OPERATOR REPLY IN  * 14600000
*                       THE FIRST BYTE AND THE ADDRESS FOR THE REPLY  * 14700000
*                       IN THE LAST 3 BYTES;                          * 14800000
*          'REPLYECB' - CONTAINS THE ADDRESS OF THE EVENT CONTROL     * 14900000
*                       BLOCK FOR THE OPERATOR'S REPLY IN THE LAST 3  * 15000000
*                       BYTES;                                        * 15100000
*    3. AT EXIT TO MODULE IFG0552Z-                                   * 15200000
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 15300000
*          REGISTER 'RET' CONTAINS A BRANCH TABLE OFFSET OF '12';     * 15400000
*       CONTROL BLOCK INDICATORS-                                     * 15500000
*          'SRTEVOLI' - 0 - INDICATES THAT THE VOLUME MUST BE         * 15600000
*                           AGAIN BE VERIFIED;                        * 15700000
*          'UCBFL2' - X'40' - INDICATES THAT THE UNIT IS 'NOT READY'. * 15800000
*       TAPE POSITION- THE TAPE IS BEING REWOUND AND UNLOADED.        * 15900000
*    4. AT EXIT TO IFG0550P (PROBLEM DETERMINATION MODULE)-           * 16000000
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 16100000
*          REGISTER 'R0' CONTAINS INTERNAL ERROR CODE 192;            * 16200000
*       WORK AREA INDICATORS-                                         * 16300000
*          'DXCALLID' - CONTAINS THE 2-BYTE ID OF THIS MODULE.        * 16400000
*                                                                     * 16500000
* EXTERNAL REFERENCES -                                               * 16600000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 16700000
*                                                                     * 16800000
* EXITS, NORMAL -                                                     * 16900000
*    PART II OF THIS MODULE- THE 'EOV TAPE INPUT DATA SET             * 17000000
*    POSITIONING FUNCTION'                                            * 17100000
*                                                                     * 17200000
* EXITS, ERROR -                                                      * 17300000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 17400000
*                                                                     * 17500000
* TABLES/WORK AREAS -                                                 * 17600000
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 17700000
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 17800000
*                                                                     * 17900000
* ATTRIBUTES -                                                        * 18000000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 18100000
*                                                                     * 18200000
* CHARACTER CODE DEPENDENCY -                                         * 18300000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 18400000
*                                                                     * 18500000
* NOTES -                                                             * 18600000
*                                                                     * 18700000
*********************************************************************** 18800000
         EJECT                                                          18900000
*                                                                       19000000
*****          WAIT FOR REWIND OF NL OR NSL VOLUME FOLLOWING            19100000
*****          READING OF THE VOLUME LABEL                              19200000
*                                                                       19300000
ETI18100 EQU   *                                                        19400000
         LA    RD,EABD161               LOAD INTERNAL ERROR CODE        19500000
         MVI   DXCCW1,CCWNOP            INITLZ CCW FOR 'NOP'            19600000
         BAL   RC,ETI21500              BR AND LINK TO ISSUE 'NOP'      19700000
         BNO   ETI21600                 BR IF ERROR ON REWIND           19800000
*                                                                       19900000
*********************************************************************** 20000000
*              TEST FOR THE NEED FOR A FILE PROTECT RING              * 20100000
*********************************************************************** 20200000
*                                                                       20300000
ETI18200 EQU   *                                                        20400000
         ST    RTIOT,DXCCW6+4           SAVE TIOT ADDRESS        M0026  20450021
         TM    JFCBLTYP,JFCNSL          IS NSL TAPE SPECIFIED-          20500000
         BNO   ETI18250                 ..BR IF NOT                     20600000
         TM    DCBOFLGS,DCBORDBK        IS THE DCB OPENED FOR 'RDBACK'- 20700000
         BO    ETI20800                 ..BR IF YES TO UPDATE UCB FILE  20800000
*                                       ..SEQUENCE COUNT AND NO. FOR    20900000
*                                       ..'RDBACK'                      21000000
         B     ETI20200                 ..ELSE BR TO UPDATE THEM FOR    21100000
*                                       ..READ FORWARD                  21200000
ETI18250 EQU   *                                                        21300000
         TM    DEBOPATB,DEBOPIO-DEBOPRBK  IS MODE INOUT, OUTPUT, OUTIN- 21400000
         BZ    ETI18700                 ..BR IF NOT- NO ADD'L TESTS     21500000
         TM    DEBOPATB,DEBOPOUT-DEBOPIO  IS MODE INOUT-                21600000
         BNZ   ETI18700                 ..BR IF NOT TO CONTINUE         21700000
*                                                                       21800000
*****          PROCESSING IS 'INOUT'- DETERMINE IF A FILE PROTECT       21900000
*****          RING IS INSERTED                                         22000000
*                                                                       22100000
         LA    R0,DXCCW5                LOAD ADDRESS FOR SENSE   M0026  22200021
         ST    R0,DXCCW1                ..BYTES AND STORE IN CCW        22300000
         MVI   DXCCW1,CCWSENSE          INITLZ CCW FOR SENSE COMMAND    22400000
         MVC   DXCCW1+4(K4),SEN6        SET LNG EQ 6, 'SILI' IND ON     22500000
         LA    RD,EABD192               LOAD INTERNAL ERROR CODE        22600000
         BAL   RC,ETI21500              BR AND LINK TO READ SENSE BYTES 22700000
         BNO   ETI21600                 ..BR IF ERROR TO ERROR RTN      22800000
         TM    DXCCW5+1,UCBPRTCT        IS TAPE FILE PROTECTED-  M0026  22900021
         BZ    ETI18700                 ..BRANCH IF NOT TO CONTINUE     23000000
*                                                                       23100000
*****          A FILE PROTECT RING IS NOT INSERTED- ISSUE FILE PROTECT  23200000
*****          MSG 'IEC010D' TO DETERMINE WHETHER OR NOT IT IS REQUIRED 23300000
*                                                                       23400000
ETI18300 EQU   *                                                        23500000
         MVC   MCSFLAGS(K12),FPFLAGS    MOVE FILE PROTECT MSG INTO BFR  23600000
         LA    R1,REPLY                 LOAD REPLY ADDRESS AND          23700000
         ST    R1,REPLYLTH              STORE IT FOR WTOR               23800000
         MVI   REPLYLTH,K1              SET REPLY LENGTH TO 1           23900000
         LA    R1,DXECB                 LOAD ECB ADDRESS AND            24000000
         ST    R1,REPLYECB              ..STORE IT FOR WTOR             24100000
         MVI   DXECB,K0                 CLEAR ECB FOR WTOR              24200000
         MVC   MSGVOLSR,DXVOLSR2        MOVE VOLUME SERIAL NO. INTO MSG 24300000
         LA    RF,MODWTO3D              PT TO ID/TTR OF WTO MOD         24400000
         LA    RET,K8                   LOAD BR TABLE OFFSET FOR RETURN 24500000
         MVC   DXRETMOD(K5),MOD3D3D     SAVE RETURN MODULE ID/TTR       24600000
         B     ETI21100                 BR TO XCTL TO WRITE MSG         24700000
*                                                                       24800000
*****          WAIT FOR THE OPERATOR'S REPLY TO THE FILE PROTECT MSG    24900000
*                                                                       25000000
ETI18400 EQU   *                                                        25100000
         IECRES WAIT                    INVOKE IECRES MACRO TO 'WAIT'   25200000
         CLI   REPLY,C'F'               SHOULD OPERATOR INSERT RING-    25300000
         BNE   ETI18500                 ..BR IF NOT TO TEST FOR OTHER   25400000
*                                       ..REPLY                         25500000
*                                                                       25600000
*****          A FILE PROTECT RING IS REQUIRED- REWIND AND UNLOAD THE   25700000
*****          VOLUME TO ALLOW THE RING TO BE INSERTED, THEN REPEAT     25800000
*****          THE VOLUME VERIFICATION PROCESS                          25900000
*                                                                       26000000
         MVC   DXCCW1,RUNCCW3D          INITLZ CCW FOR REWIND/UNLOAD    26100000
         BAL   RC,ETI21500              BR AND LINK TO UNLOAD TAPE      26200000
         BNO   ETI21600                 BR IF ERROR UNLOADING TAPE      26300000
         XC    SRTEVOLI,SRTEVOLI        ZERO UCB VOLUME SERIAL NUMBER   26400000
         OI    UCBFL2,UCBNOTRD          SET UCB NOT-READY               26500000
         LA    RF,MOD3D2Z               PT TO ID/TTR OF DISMOUNT/MT MOD 26600000
         LA    RET,K12                  LOAD BR TBL OFFSET FOR THAT MOD 26700000
         B     ETI21100                 BR TO XCTL TO MT/DISMT MOD      26800000
ETI18500 EQU   *                                                        26900000
         CLI   REPLY,C'U'               CAN THIS VOL BE USED WITHOUT    27000000
*                                       ..THE FILE PROTECT RING-        27100000
         BNE   ETI18300                 ..BR IF NOT TO REISSUE MESSAGE- 27200000
*                                       ..REPLY WAS NOT ACCEPTABLE,     27300000
*                                       ..OTHERWISE CONTINUE PROCESSING 27400000
       TITLE 'IFG0553D - EOV TAPE INPUT DATA SET POSITIONING FUNCTION'  27500000
*********************************************************************** 27600000
*                                                                     * 27700000
*                          FUNCTION PROLOG                            * 27800000
*                                                                     * 27900000
*********************************************************************** 28000000
*                                                                     * 28100000
* FUNCTION NAME -                                                     * 28200000
*    'EOV TAPE INPUT DATA SET POSITIONING FUNCTION'                   * 28300000
*                                                                     * 28400000
* (STATUS) -                                                          * 28500000
*    NOT APPLICABLE                                                   * 28600000
*                                                                     * 28700000
* FUNCTION -                                                          * 28800000
*    1. THIS FUNCTION POSITIONS DATA SETS ON AL, NL, AND SL TAPE      * 28900000
*       TO THE DESIRED DATA SET AS INDICATED BELOW.                   * 29000000
*    2. WHEN AN END-OF-VOLUME CONDITION HAS OCCURRED, THE DESIRED     * 29100000
*       DATA SET IS EITHER THE FIRST ONE ON THE TAPE (READ FORWARD)   * 29200000
*       OR THE LAST ONE ('RDBACK').                                   * 29300000
*       A. NL TAPES ARE POSITIONED TO EITHER THE INTERBLOCK GAP       * 29400000
*          PRECEDING THE FIRST DATA RECORD (READ FORWARD) OR TO THE   * 29500000
*          INTERBLOCK GAP FOLLOWING THE LAST DATA RECORD ('RDBACK').  * 29600000
*       B. AL AND SL TAPES ARE POSITIONED TO EITHER THE INTERBLOCK    * 29700000
*          GAP PRECEDING HEADER LABEL 1 (READ FORWARD) OR PRECEDING   * 29800000
*          TRAILER LABEL 1 ('RDBACK').                                * 29900000
*    3. WHEN A CONCATENATED DATA SET IS TO BE PROCESSED, THE JFCB     * 30000000
*       FILE SEQUENCE NUMBER (JFCBFLSQ) INDICATES THAT DATA SET'S     * 30100000
*       POSITION ON THE TAPE; THIS FIELD IS UTILIZED AS FOLLOWS-      * 30200000
*       A. FOR NL TAPES OR DATA SETS ON AL OR SL TAPE WITH A JFCB     * 30300000
*          FILE SEQUENCE NO. OF 1, THE DESIRED POSITION (JFCBFLSQ) IS * 30400000
*          COMPARED TO THE CURRENT TAPE POSITION (SRTEFSCT) AND THE   * 30500000
*          TAPE IS MOVED BACKWARD OR FORWARD AS REQUIRED. POSITION    * 30600000
*          WITHIN THE DATA SET IS AS SPECIFIED IN SECTION (2) ABOVE.  * 30700000
*       B. FOR DATA SETS ON AL OR SL TAPE WITH A JFCB FILE SEQUENCE   * 30800000
*          SEQUENCE NUMBER GREATER THAN 1, HEADER LABEL 1 OF THE      * 30900000
*          FIRST DATA SET ON THE TAPE IS READ TO OBTAIN THE FILE      * 31000000
*          SEQUENCE NUMBER (I.E., LOGICAL POSITION) ON THE TAPE       * 31100000
*          OF THAT DATA SET. IF THAT FILE SEQUENCE NUMBER IS '1',     * 31200000
*          THEN THE TAPE IS POSITIONED AS IN (A) ABOVE. IF THAT       * 31300000
*          FILE SEQUENCE NUMBER IS GREATER THAN '1', THEN THE         * 31400000
*          DIFFERENCE BETWEEN THIS FILE SEQUENCE NUMBER AND THAT      * 31500000
*          OF THE DESIRED DATA SET INDICATES THE PHYSICAL POSITION    * 31600000
*          OF THE DESIRED DATA SET ON THE TAPE. POSITIONING WITHIN    * 31700000
*          THE DATA SET IS AS SPECIFIED IN SECTION (2) ABOVE.         * 31800000
*                                                                     * 31900000
* ENTRY POINTS -                                                      * 32000000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 32100000
*                                                                     * 32200000
* INPUT -                                                             * 32300000
*    1. REGISTER CONTENTS AT ENTRY ARE AS FOLLOWS-                    * 32400000
*       'RDCB' - ADDRESS OF THE DCB BEING PROCESSED;                  * 32500000
*       'RCORE'- ADDRESS OF THE WORK AREA FOR THAT DCB;               * 32600000
*       'RES'  - ADDRESS OF THE OPEN/CLOSE/EOV RESIDENT ROUTINE;      * 32700000
*       'RWTG' - ADDRESS OF THE WHERE-TO-GO TABLE;                    * 32800000
*       'RPARC'- ADDRESS OF THE EOV PSEUDO PARAMETER LIST ENTRY;      * 32900000
*       'RWTGC'- ADDRESS OF THE CURRENT WHERE-TO-GO TABLE ENTRY;      * 33000000
*       'RTIOT'- ADDRESS OF THE CURRENT TIOT ENTRY FOR THE DCB;       * 33100000
*       'RUCB' - ADDRESS OF THE CURRENT UCB FOR THE DCB;              * 33200000
*       'RDEB' - ADDRESS OF THE DCB'S DEB;                            * 33300000
*                                                                     * 33400000
* OUTPUT -                                                            * 33500000
*    1. AT ALL EXITS EXCEPT THE ONE TO IFGO550P, UNIT CONTROL BLOCK   * 33600000
*       FIELDS 'SRTEFSCT' AND 'SRTEFSEQ' HAVE BEEN UPDATED TO REFLECT * 33700000
*       THE LOGICAL AND PHYSICAL POSITION OF THE DATA SET AND FIELD   * 33800000
*       'SRTEDMCT' (THE DATA MANAGEMENT COUNT) HAS BEEN SET TO '1'.   * 33900000
*    2. AT EXIT TO IFG0550P (PROBLEM DETERMINATION)-                  * 34000000
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 34100000
*          REGISTER 'R0' CONTAINS ONE OF THE FOLLOWING INTERNAL       * 34200000
*          ERROR CODES-                                               * 34300000
*          162- ERROR POSITIONING A CONCATENATED DATA SET;            * 34400000
*          163- ERROR POSITIONING THE SAME DATA SET FOR READ FORWARD; * 34500000
*          193- ERROR POSITIONING THE SAME DATA SET FOR 'RDBACK'.     * 34600000
*       WORK AREA INDICATORS-                                         * 34700000
*          'DXCALLID' - CONTAINS THE 2-BYTE ID OF THIS MODULE.        * 34800000
*    3. AT EXIT TO IFG0553F, OUTPUT IS VIRTUALLY THE SAME AS AT ENTRY * 34900000
*       TO THE FUNCTION EXCEPT AS NOTED IN SECTION (1) ABOVE.         * 35000000
*    4. AT EXIT TO IFG0553H, REGISTER CONTENTS ARE THE SAME AS AT     * 35100000
*       ENTRY EXCEPT THAT REGISTER 'R0' CONTAINS A BRANCH TABLE       * 35200000
*       OFFSET OF '24'.                                               * 35300000
*    5. AT EXIT TO NSLEHDRI (NSL HEADER LABEL PROCESSING)- REGISTER   * 35400000
*       CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT REGISTER 'RET'  * 35500000
*       CONTAINS A BRANCH TABLE OFFSET OF '20' FOR RETURN TO IFG0553H * 35600000
*       (ALIAS IGG0550D).                                             * 35700000
*                                                                     * 35800000
* EXTERNAL REFERENCES -                                               * 35900000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 36000000
*                                                                     * 36100000
* EXITS, NORMAL -                                                     * 36200000
*          IFG0553F - TO VERIFY THE DATA SET NAME OF A DATA SET ON AL * 36300000
*                     OR SL TAPE;                                     * 36400000
*          IFG0553H - TO MOUNT AHEAD ANY ADDITIONAL VOLUMES OR TO     * 36500000
*                     EXIT FROM EOV FOR A DATA SET ON NL TAPE;        * 36600000
*          NSLEHDRI - TO PERFORM VOLUME AND DATA SET VERIFICATION AND * 36700000
*                     DATA SET POSITIONING FOR A DATA SET ON NSL TAPE.* 36800000
*                                                                     * 36900000
* EXITS, ERROR -                                                      * 37000000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 37100000
*                                                                     * 37200000
* TABLES/WORK AREAS -                                                 * 37300000
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 37400000
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 37500000
*                                                                     * 37600000
* ATTRIBUTES -                                                        * 37700000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 37800000
*                                                                     * 37900000
* CHARACTER CODE DEPENDENCY -                                         * 38000000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 38100000
*                                                                     * 38200000
* NOTES -                                                             * 38300000
*                                                                     * 38400000
*********************************************************************** 38500000
*                                                                       38600000
*****    NOTE- 'RTIOT' AND 'RDEB' ARE NOW USED AS WORK REGISTERS        38700000
*                                                                       38800000
ETI18700 EQU   *                                                        38900000
         TM    DCBOFLGS,DCBORDBK        IS THE DCB OPENED FOR 'RDBACK'- 39100000
         BO    ETI20300                 ..BR IF YES TO POS FOR 'RDBACK' 39200000
         LA    RD,EABD163               LOAD INTERNAL ERROR CODE        39300000
         TM    DCBOFLGS,DCBOCON         IS CONCATENATION IN PROGRESS-   39400000
         BZ    ETI19900                 ..BRANCH IF NOT                 39500000
*                                                                       39600000
*********************************************************************** 39700000
*              POSITIONING FOR A CONCATENATED DATA SET                * 39800000
*********************************************************************** 39900000
*                                                                       40000000
ETI18800 EQU   *                                                        40100000
         LA    RD,EABD162               LOAD INTERNAL ERROR CODE        40200000
         LH    RET,JFCBFLSQ             LOAD FILE SEQ NO. FROM JFCB     40300000
         CH    RET,REWND+6              IS JFCB FILE SEQ NO. EQ 1-      40400000
         BE    ETI18900                 ..BR IF YES                     40500000
         BH    ETI19000                 ..BR IF GREATER THAN 1          40600000
*                                                                       40700000
*****          PROCESS FILE SEQUENCE NUMBER EQUAL TO 0                  40800000
*                                                                       40900000
         LA    RET,K1                   INITLZ FOR FILE SEQ NO. EQUAL 1 41000000
         MVI   JFCBFLSQ+1,K1            SET JFCB FILE SEQ NO. TO 1      41100000
         OI    DXXPATHS,WTGJFCBW       TURN ON JFCB 'WRITE-BACK' IND    41200000
*                                                                       41300000
*****          PROCESS FILE SEQUENCE NUMBER EQUAL TO 1                  41400000
*                                                                       41500000
ETI18900 EQU   *                                                        41600000
         STH   RET,SRTEFSEQ             ST LOGICAL FILE SEQ NO. IN UCB  41700000
         B     ETI19900                 BR TO PERFORM POSITIONING       41800000
*                                                                       41900000
*****          PROCESS FILE SEQUENCE NUMBER GREATER THAN 1              42000000
*                                                                       42100000
ETI19000 EQU   *                                                        42200000
         TM    JFCBLTYP,JFCBAL+JFCSL    WAS SL OR AL SPECIFIED-         42300000
         BZ    ETI19500                 ..BR IF NOT- PERFORM NL POS     42400000
         CLC   SRTEFSCT(K2),REWND+6     IS THE CURRENT POSITION '1'-    42500000
         BNE   ETI19300                 ..BR IF NOT TO POSITION         42600000
*                                                                       42700000
*****          AN SL TAPE IS CURRENTLY POSITIONED TO THE FIRST          42800000
*****          PHYSICAL DATA SET ON THE TAPE- USE THE DATA SET          42900000
*****          SEQUENCE NUMBER ( LOGICAL ) FROM THE HEADER 1 LABEL      43000000
*****          OF THAT DATA SET TO CALCULATE THE RELATIVE OFFSET        43100000
*****          ( PHYSICAL ) OF THE DESIRED DATA SET                     43200000
*                                                                       43300000
         LA    RC,DXLBL                 LOAD ADDRESS OF LABEL BUFFER,   43400000
         ST    RC,DXCCW1                ..STORE IT INTO 'READ' CCW      43500000
         MVI   DXCCW1,CCWRDTAP          INITLZ CCW FOR 'READ' COMMAND   43600000
         MVC   DXCCW1+4(K4),ARDCCW0C    IND NO FLAGS, LNG EQ 80 BYTES   43700000
         TM    JFCBLTYP,JFCBAL          WERE 'ANSI' LABELS SPECIFIED-   43800000
         BZ    ETI19100                 ..BR IF NOT TO READ LABEL       43900000
         OI    DXCCW1+4,CCWSILI         TURN ON 'SILI' INDICATOR        44000000
ETI19100 EQU   *                                                        44100000
         BAL   RC,ETI21500              BR AND LINK TO READ LABEL       44200000
         BNO   ETI21600                 BR TO ERROR RTN IF I/O ERROR    44300000
         TM    SRTESTAB,UCBBSTR         IS AN 'ANSI' VOLUME MOUNTED-    44400000
         BZ    ETI19200                 ..BR IF NOT TO CHK LABEL TYPE   44500000
         XLATE DXLBL,K80                TRANSLATE 'ANSI' LABEL DATA     44600000
ETI19200 EQU   *                                                        44700000
         CLC   FL1LABI,AVOL0C           IS THIS A VOLUME LABEL-         44800000
         BE    ETI19100                 ..BR IF YES- READ ANOTHER LABEL 44900000
         CLC   FL1LABI,UVOL3D           IS THIS A USER VOLUME LABEL-    45000000
         BE    ETI19100                 ..BR IF YES- READ ANOTHER LABEL 45100000
         CLC   FL1LABI,AHDR             IS THIS A HEADER LABEL-         45200000
         BNE   ETI21600                 ..BR IF NOT- ERROR              45300000
         MVI   DXCCW1,CCWBSR            INITLZ CCW FOR BSR COMMAND      45400000
         BAL   RC,ETI21500              BR AND LINK TO BSR PAST LABEL   45500000
         BNO   ETI21600                 BR IF ERROR TO ERROR RTN        45600000
         PACK  DXCCW2,FL1FILSQ          PACK LABEL FILE SEQ NO., THEN   45700000
         CVB   RET,DXCCW2               ..CONVERT IT TO BINARY AND      45800000
         STH   RET,SRTEFSEQ             ..STORE IT IN THE UCB           45900000
         CH    RET,JFCBFLSQ             IS DESIRED DATA SET 1ST ON TAPE 46000000
*                                       ..(PHYSICAL POS EQ 1, LOGICAL   46100000
*                                       ..POSITION EQUAL ANYTHING )-    46200000
         BE    ETI20900                 ..BR IF YES- POS COMPLETE       46300000
         BH    ETI21600                 ..BR IF SPECIFIED SEQ NO. IS    46400000
*                                       ..LESS THAN THAT OF 1ST         46500000
*                                       ..PHYSICAL DATA SET- ERROR      46600000
*                                                                       46700000
*****          DETERMINE HOW TO POSITION AN SL DATA SET                 46800000
*                                                                       46900000
ETI19300 EQU   *                                                        47000000
         LH    RTIOT,SRTEFSEQ           LOAD CURRENT LOGICAL SEQ NO.    47100000
         MVC   SRTEFSEQ,JFCBFLSQ        ST DESIRED LOG SEQ NO. IN UCB   47200000
         SH    RTIOT,SRTEFSEQ           CALC RELATIVE OFFSET OF THE 2   47300000
*                                       ..DATA SETS-                    47400000
         BZ    ETI20900                 ..BR IF 0- POS COMPLETE         47500000
         BP    ETI19400                 ..BR IF POSITIVE TO BACKSPACE   47600000
*                                                                       47700000
*****          FORWARD SPACE TO AN SL DATA SET                          47800000
*                                                                       47900000
         LPR   RET,RTIOT                CALC NEW PHYSICAL SEQ NO.-      48000000
         AH    RET,SRTEFSCT             ..ADD RELATIVE OFFSET TO CUR    48100000
         STH   RET,SRTEFSCT             ..PHYSICAL POS AND STORE IN UCB 48200000
         B     ETI19600                 BR TO ACTUALLY PERFORM POS      48300000
*                                                                       48400000
*****          BACKSPACE TO A SL DATA SET                               48500000
*                                                                       48600000
ETI19400 EQU   *                                                        48700000
         LR    RET,RTIOT                SAVE RELATIVE OFFSET            48800000
         SH    RET,SRTEFSCT             CALC NEW PHYSICAL SEQ NO.-      48900000
         BNM   ETI21600                 ..BR IF NOT MINUS- ERROR        49000000
         LPR   RET,RET                  INSURE POSITIVE SEQ NUMBER      49100000
         STH   RET,SRTEFSCT             ..AND STORE IN UCB              49200000
         B     ETI19600                 BR TO ACTUALLY PERFORM POS      49300000
*                                                                       49400000
*****          DETERMINE HOW TO POSITION AN NL DATA SET                 49500000
*                                                                       49600000
ETI19500 EQU   *                                                        49700000
         LH    RTIOT,SRTEFSCT           LOAD CURRENT PHYSICAL SEQ NO.   49800000
         STH   RET,SRTEFSEQ             STORE DESIRED LOGICAL AND       49900000
         STH   RET,SRTEFSCT             ..PHYSICAL SEQ NOS. IN UCB      50000000
         SR    RTIOT,RET                GET POSITIONING FACTOR          50100000
*                                                                       50200000
*****          PERFORM ACTUAL TAPE POSITIONING                          50300000
*                                                                       50400000
ETI19600 EQU   *                                                        50500000
         TM    JFCBLTYP,JFCBLP+JFCNL    WAS NL OR BLP SPECIFIED-        50600000
         BNZ   ETI19700                 ..BR IF YES TO CONTINUE         50700000
         MH    RTIOT,CONTHREE           MULTIPLY POSITIONING FACTOR BY  50800000
*                                       ..3 TO ACCOUNT FOR STD LABELS   50900000
ETI19700 EQU   *                                                        51000000
         MVI   DXCCW1,CCWBSF            INITLZ CCW FOR BSF COMMAND      51100000
         LTR   RTIOT,RTIOT              WHICK WAY DO WE POSITION-       51200000
         BM    ETI19800                 ..BR IF POSITIONING FORWARD     51300000
         BZ    ETI20900                 ..BR IF POSITIONING COMPLETE    51400000
         LA    RTIOT,K1(,RTIOT)         INCREASE NO. OF BSF BY 1        51500000
         BAL   RDEB,ETI21300            BR TO EXECUTE THE I/O LOOP      51600000
         TM    IOBSENSE+1,UCBLDPT       WAS LOAD POINT REACHED-         51700000
         BO    ETI20900                 ..BR IF YES- POS COMPLETE       51800000
         LA    RTIOT,K1                 INITLZ FOR 1 FWD SPACE FILE     51900000
ETI19800 EQU   *                                                        52000000
         LPR   RTIOT,RTIOT              INSURE POSITIVE POS FACTOR      52100000
         MVI   DXCCW1,CCWFSF            INITLZ CCW FOR FSF COMMAND      52200000
         BAL   RDEB,ETI21300            BR TO EXECUTE THE I/O LOOP      52300000
         B     ETI20900                 ..BR- CONCATENATION POS DONE    52400000
*                                                                       52500000
*****          POSITIONING FOR READ FORWARD ON THE SAME DATA SET        52600000
*                                                                       52700000
ETI19900 EQU   *                                                        52800000
         CLC   SRTEFSCT(K2),CONSTONE    IS CURRENT POSITION EQUAL '1'-  52900000
         BE    ETI20200                 ..BR IF YES- POS COMPLETE       53000000
ETI20000 EQU   *                                                        53100000
         MVI   DXCCW1,CCWREW            INITLZ CCW FOR REWIND COMMAND   53200000
         BAL   RC,ETI21500              BR AND LINK TO REWIND TAPE      53300000
         BNO   ETI21600                 BR IF ERROR TO ERROR RTN        53400000
         MVI   DXCCW1,CCWNOP            INITLZ CCW FOR A 'NOP'          53500000
         BAL   RC,ETI21500              BR AND LINK TO INITIATE 'NOP'   53600000
         BNO   ETI21600                 BR IF ERROR TO ERROR RTN        53700000
ETI20200 EQU   *                                                        53800000
         TM    DCBOFLGS,DCBOCON         IS CONCATENATION TAKING PLACE-  53900000
         BO    ETI20900                 ..BR IF TO FINISH               54000000
         MVC   SRTEFSEQ(K2),DXCCW7+6    UPDATE LOG SEQ NO. FROM WK AREA 54100000
         MVC   SRTEFSCT(K2),CONSTONE    INITLZ PHYSICAL SEQ NO. TO 1    54200000
         B     ETI20900                 BR TO FINISH                    54300000
*                                                                       54400000
*****          POSITIONING FOR 'RDBACK' ON THE SAME DATA SET            54500000
*                                                                       54600000
ETI20300 EQU   *                                                        54700000
         LA    RD,EABD194               INTERNAL CODE FOR POS ERROR     54800000
         LH    RTIOT,DXCCW7+4           LOAD OLD PHYSICAL SEQ NO.       54900000
         LH    RET,SRTEFSCT             LOAD CURRENT PHYSICAL SEQ NO.   55000000
         TM    JFCBLTYP,JFCBLP+JFCNL    WAS NL OR BLP SPECIFIED-        55100000
         BM    ETI20600                 ..BR IF YES                     55200000
         SR    RTIOT,RET                CALC POSITIONING FACTOR         55300000
         BNM   ETI20400                 BR TO POSITION FORWARD          55400000
         LA    RTIOT,K2                 INITLZ POS FACTOR FOR 2 BSF     55500000
         MVI   DXCCW1,CCWBSF            INITLZ CCW FOR BSF COMMAND      55600000
         BAL   RDEB,ETI21300            BR TO EXECUTE THE I/O LOOP      55700000
         LA    RTIOT,K2                 INITLZ POS FACTOR FOR FSF       55800000
         B     ETI20500                 BR TO FORWARD SPACE FILE        55900000
ETI20400 EQU   *                                                        56000000
         AH    RTIOT,CONSTONE           PLUS ONE TO POSITIONING FACTOR  56100000
         MH    RTIOT,CONTHREE           MULTIPLY POSITIONING FACTOR BY  56200000
*                                       ..3 TO ACCOUNT FOR STD LABELS   56300000
ETI20500 EQU   *                                                        56400000
         MVI   DXCCW1,CCWFSF            INITLZ CCW FOR FSF COMMAND      56500000
         BAL   RDEB,ETI21400            BR TO EXECUTE THE I/O LOOP      56600000
         B     ETI20800                 BR TO UPDATE UCB FILE SEQUENCE  56700000
*                                       ..COUNT AND NUMBER              56800000
ETI20600 EQU   *                                                        56900000
         SR    RTIOT,RET                CALCULATE POSITIONING FACTOR    57000000
         BM    ETI20700                 BR TO POSITION BACKWARD         57100000
         AH    RTIOT,CONSTONE           PLUS ONE TO POSITIONING FACTOR  57200000
         MVI   DXCCW1,CCWFSF            INITLZ CCW FOR FSF COMMAND      57300000
         BAL   RDEB,ETI21300            BR TO EXECUTE THE I/O LOOP      57400000
ETI20700 EQU   *                                                        57500000
         MVI   DXCCW1,CCWBSF            INITLZ CCW FOR BSF COMMAND      57600000
         LA    RTIOT,K1                 INITLZ POSITIONING FACTOR TO 1  57700000
         BAL   RDEB,ETI21300            BR TO EXECUTE THE I/O LOOP      57800000
ETI20800 EQU   *                                                        57900000
         MVC   SRTEFSCT(K4),DXCCW7+4    INITLZ PHYSICAL AND LOGICAL SEQ 58000000
*                                       ..NOS. FROM SAVE AREA           58100000
*                                                                       58200000
*****    NOTE- 'RDEB' AND 'RTIOT' ARE NO LONGER USED AS WORK REGS       58300000
*                                                                       58400000
ETI20900 EQU   *                                                        58500000
         L     RDEB,DCBDEBAD            RESTORE DEB ADDRESS FROM DCB    58600000
         L     RTIOT,DXCCW6+4           RESTORE TIOT ADDR FROM WK AREA  58700000
         NI    DCBOFLGS,X'FF'-DCBOEOF   RESET 'TAPE MARK READ' IND      58800000
         OI    SRTEDMCT,K1              INITLZ DATA MANAGEMENT CT TO 1  58900000
         SPACE 2                                                        59000000
*********************************************************************** 59100000
*              EXITS                                                  * 59200000
*********************************************************************** 59300000
*                                                                       59400000
         TM    JFCBLTYP,JFCBAL+JFCSL    WAS AL OR SL SPECIFIED-         59500000
         BZ    ETI21000                 ..BRANCH IF NOT                 59600000
*                                                                       59700000
*****          EXIT TO PROCESS STANDARD HEADER LABELS                   59800000
*                                                                       59900000
         LA    RF,MOD3D3F               PT TO ID/TTR OF HDR LBL MOD     60000000
         SR    RET,RET                  BR TABLE OFFSET FOR THAT MODULE 60100000
         B     ETI21100                 BR TO XCTL                      60200000
*                                                                       60300000
*****          NL AND NSL EXIT DETERMINATION                            60400000
*                                                                       60500000
ETI21000 EQU   *                                                        60600000
         LA    RF,MOD3D3H               PT TO ID/TTR OF MT-AHEAD MOD    60700000
         TM    JFCBLTYP,JFCNSL          WAS NSL SPECIFIED-              60800000
         BO    ETI21200                 ..BRANCH IF YES                 60900000
         LA    RET,K24                  BR TABLE OFFSET FOR NL          61000000
ETI21100 EQU   *                                                        61100000
         IECRES XCTL,(RF),(RET)         INVOKE IECRES MACRO TO XCTL     61200000
         EJECT                                                          61300000
*                                                                       61400000
*****          XCTL TO 'NSLEHDRI' TO PROCESS HEADER LABELS              61500000
*                                                                       61600000
ETI21200 EQU   *                                                        61700000
         MVC   DXXMODNM(K8),NSLHDRI     PLACE NSL HEADER LABEL MODULE   61800000
*                                       ..NAME INTO XCTL AREA           61900000
         LA    RET,K20                  BR TABLE OFFSET FOR NSL RETURN  62000000
         LA    RF,DXXCTL                POINT TO XCTL WORK AREA         62100000
         LA    R0,DXXMODNM              POINT TO XCTL MODULE NAME       62200000
         XCTL  EPLOC=(R0),SF=(E,(15))                                   62300000
         SPACE 2                                                        62400000
*********************************************************************** 62500000
*              SUBROUTINES FOR VOLUME/DATA SET VERIFICATION           * 62600000
*********************************************************************** 62700000
*                                                                       62800000
*****          CLOSED SUBROUTINE TO ISSUE MULTIPLE POSITIONING CMDS     62900000
*                                                                       63000000
ETI21300 EQU   *                                                        63100000
         BAL   RC,ETI21500              BR AND LINK TO DO I/O           63200000
         BO    ETI21400                 BR IF NO ERROR TO CONTINUE      63300000
         TM    IOBSENS1,UCBLDPT         IS THE TAPE AT LOAD POINT-      63400000
         BNO   ETI21600                 ..BR IF NOT TO ERROR RTN        63500000
ETI21400 EQU   *                                                        63600000
         BCT   RTIOT,ETI21300           DECREMENT THE POSITIONING       63700000
*                                       ..FACTOR- CONTINUE IF MORE I/O, 63800000
         BR    RDEB                     ..ELSE RETURN TO CALLER         63900000
         SPACE 2                                                        64000000
*                                                                       64100000
*****          CLOSED SUBROUTINE TO PERFORM I/O OPERATIONS              64200000
*****          ENTRY TO THE SUBROUTINE IS VIA A 'BAL  RC,ETI21500'      64300000
*                                                                       64400000
ETI21500 EQU   *                                                        64500000
         EXCP  DXIOB                                                    64600000
         IECRES WAIT                    INVOKE IECRES MACRO TO 'WAIT'   64700000
         TM    DXECB,ECBNOERR           TEST FOR AN I/O ERROR           64800000
         BR    RC                       RETURN TO CALLER WITH           64900000
*                                       ..CONDITION CODE SET            65000000
         EJECT                                                          65100000
*********************************************************************** 65200000
*              ERROR PROCESSING                                       * 65300000
*********************************************************************** 65400000
*                                                                       65500000
ETI21600 EQU   *                                                        65600000
         DMABCOND (RD),ABEND3D          EXIT TO PROB DETERMINATION RTN  65700000
         SPACE 2                                                        65800000
*********************************************************************** 65900000
*              CONSTANTS                                              * 66000000
*********************************************************************** 66100000
*                                                                       66200000
REWND    CCW   X'07',0,X'20',1          REWIND CCW                      66300000
RUNCCW3D DC    X'0F00000020000001'      CCW FOR REWIND AND UNLOAD       66400000
ARDCCW0C DC    X'00000050'              CCW FOR READ OP - NO FLAGS,80 C 66500000
SEN6     DC    X'20000006'              SENSE 6 BYTES- SILI BIT ON      66600000
HALFWD8  DC    H'8'                     CONSTANT OF 8                   66700000
CONSTONE DC    X'0001'                  CONSTANT ONE                    66800000
CONTHREE DC    X'0003'                  HALFWORD CONSTANT OF 3          66900000
AVOL0C   DC    C'VOL'                   VOLUME LABEL IDENTIFIER         67000000
AHDR     DC    C'HDR'                   HEADER LABEL IDENTIFIER         67100000
AEOV     DC    C'EOV'                   END-OF-VOLUME LABEL IDENTIFIER  67200000
AEOF0C   DC    C'EOF'                   END-OF-FILE LABEL IDENTIFIER    67300000
UVOL3D   DC    C'UVOL'                  USER VOLUME LABEL IDENTIFIER    67400000
NSLHDRI  DC    C'NSLEHDRI'              NSL HEADER LABEL MODULE NAME    67500000
IFG0551L DC    C'IFG0551L'              NAME OF THE A/M EXECUTOR        67600000
FPFLAGS  DC    X'8000'                  MCS FLAGS FOR FILE PROTECT MSG  67700000
FPMSG    DC    C'IEC010D F '            BASIC FILE PROTECT MESSAGE      67800000
ID9R     DC    C'9R'                    ID OF THE TRACE INITIALIZATION/ 67900000
*                                       ..TERMINATION ROUTINE           68000000
IDRA     DC    C'RA'                    ID OF THE RESIDENT ROUTINE      68100000
         SPACE 2                                                        68200000
*********************************************************************** 68300000
*              XCTL TABLE                                             * 68400000
*********************************************************************** 68500000
*                                                                       68600000
XCTLTB3D XCTLTABL ID=(ABEND3D,0P,MODWTO3D,2P,MOD3D2Z,2Z,MOD3D3D,3D,    C68700000
               MOD3D3F,3F,MOD3D3H,3H),SVC=055                           68800000
         SPACE 2                                                        68900000
         IECDSECS CVT,                                                 C69000000
               TCB,                                                    C69100000
               RB,                                                     C69200000
               TIOT,                                                   C69300000
               DCB,                                                    C69400000
               DEB,                                                    C69500000
               UCB,                                                    C69600000
               MAIN,                                                   C69700000
               WTG,                                                    C69800000
               EXPAND=YES                                               69900000
         IECEQU ,                       INVOKE OPEN/CLOSE/EOV EQUATES   70000000
         SPACE 2                                                        70100000
         END                                                            70200000
