         TITLE 'IFG0553F - NEW VOLUME HEADER LABEL VERIFICATION'        00100021
         COPY  LCGASMSW                                                 00200000
IFG0553F CSECT                                                          00400021
*                                                                       00500021
*********************************************************************** 00600021
*                                                                     * 00700021
*                                                                     * 00800021
*          RELEASE 25 DELETIONS/CHANGES                               * 00900021
*          RELEASE 24 DELETIONS/CHANGES                               * 01000021
*          RELEASE 23 DELETIONS/CHANGES                               * 01100021
*          RELEASE 22 DELETIONS/CHANGES                               * 01200021
*          RELEASE 21.8 DELETIONS/CHANGES                             * 01210021
*0000297996                                                     SA70404 01250021
*          RELEASE 21 DELETIONS/CHANGES                               * 01300021
*                                                                M0150  01320021
*                                                                A41662 01340021
*                                                                S21940 01360021
*0000470000,473000,482000,543000-546000                          M0961  01370021
*                                                                     * 01400021
* STATUS CHANGE LEVEL 000                                             * 01500021
*                                                                     * 01600021
* FUNCTION -                                                          * 01700021
*    THIS MODULE CONTAINS PART I OF THE 'EOV TAPE INPUT STANDARD      * 01800021
*    HEADER LABEL FUNCTION'.                                          * 01900021
*                                                                     * 02000021
* ENTRY POINTS -                                                      * 02100021
*         IFG0553F - REFER TO 'INPUT' FOR A LIST OF CALLING MODULES   * 02160021
*                    AND THEIR RESPECTIVE ENTRY CONDITIONS.           * 02220021
*                                                                     * 02300021
* INPUT -                                                             * 02400021
*    REGISTER 14 ('RET') WILL CONTAIN ONE OF THE BRANCH TABLE OFFSETS * 02430021
*    LISTED BELOW, THE BRANCH TABLE BEING USED TO DETERMINE AT WHICH  * 02460021
*    POINT PROCESSING IS TO BEGIN-                                    * 02490021
*       0 - ENTRY FROM IFG0553D TO VERIFY THE DATA SET NAME AND TO    * 02520021
*           PROCESS USER LABELS, IF REQUIRED.                         * 02550021
*                                                                     * 02600021
* OUTPUT -                                                            * 02700021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 02800021
*                                                                     * 02900021
* EXTERNAL REFERENCES -                                               * 03000021
*         IFG055RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 03100021
*                    WAIT. REFER TO THE FOLLOWING 'FUNCTION PROLOG'.  * 03200021
*                                                                     * 03300021
* EXITS, NORMAL -                                                     * 03400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 03500021
*                                                                     * 03600021
* EXITS, ERROR -                                                      * 03700021
*         IFG0550P - WHEN AN ERROR CONDITION OCCURS IN THIS MODULE.   * 03800021
*                    REFER TO 'OUTPUT' IN THE FOLLOWING 'FUNCTION     * 03860021
*                    PROLOG' FOR A LIST OF ERROR CONDITIONS.          * 03920021
*                                                                     * 04000021
* TABLES/WORK AREAS -                                                 * 04100021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 04200021
*                                                                     * 04300021
* ATTRIBUTES -                                                        * 04400021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 04500021
*                                                                     * 04600021
* CHARACTER CODE DEPENDENCY -                                         * 04700021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 04800021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 04900021
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 05000021
*                                                                     * 05100021
* NOTES -                                                             * 05200021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 05300021
*                                                                     * 05400021
*********************************************************************** 05500021
*                                                                       05503021
*****          INTERNAL ERROR CODES                                     05506021
*                                                                       05509021
EABD164  EQU   164                      ERROR READING HEADER LABEL      05512021
EABD165  EQU   165                      INCORRECT DATA SET NAME         05515021
EABD191  EQU   191                      ERROR POSITIONING TO            05518021
*                                       ..FIRST DATA RECORD             05521021
EABD195  EQU   195                      INVALID HEADER LABEL READ       05524021
EABD196  EQU   196                      ERR POSITIONING FOLLOWING USER  05527021
*                                       ..HEADER LABEL PROCESSING       05530021
*                                                                       05533021
         BALR  RBASE,0                  ESTABLISH ADDRESSABILITY        05536021
         USING *,RBASE                                                  05539021
         USING FORCORE,RCORE                                            05542021
         USING IHADCB,RDCB                                              05545021
         USING UCB,RUCB                                                 05548021
         USING DEB,RDEB                                                 05551021
*                                                                       05554021
*****          DETERMINE TYPE OF ENTRY INTO MODULE                      05557021
*****          ALTHOUGH THERE IS ONLY A SINGLE ENTRY TO THIS            05560021
*****          MODULE, THE BRANCH TABLE IS UTILIZED TO PERMIT           05563021
*****          ADDITION OF NEW ENTRY POINTS AT A LATER DATE             05566021
*                                                                       05569021
         B     ETI23000(RET)            DETERMINE TYPE OF ENTRY  S21940 05572021
ETI23000 EQU   *                                                 S21940 05575021
         B     ETI23100            (0)  BR TO VERIFY DSNAME      S21940 05578021
*                                                                       05581021
         EJECT                                                          05600021
*********************************************************************** 05700021
*                                                                     * 05800021
*                          FUNCTION PROLOG                            * 05900021
*                                                                     * 06000021
*********************************************************************** 06100021
*                                                                     * 06200021
* FUNCTION NAME -                                                     * 06300021
*    'EOV TAPE INPUT STANDARD HEADER LABEL FUNCTION', PART I          * 06400021
*                                                                     * 06500021
* (STATUS) -                                                          * 06600021
*    NOT APPLICABLE                                                   * 06700021
*                                                                     * 06800021
         AIF   ('&LIB' NE 'LIB1').LIB23F0                               06850000
* FUNCTION -                                                          * 06900021
*    1. READ FILE LABEL 1 AND VERIFY THAT IT IS EITHER HDR1, EOV1,    * 07000021
*       OR EOF1;                                                      * 07100021
*    2. COMPARE THE LEAST SIGNIFICANT (I.E., LAST) 17 CHARACTERS OF   * 07200021
*       THE DATA SET NAME IN THE JFCB TO THE DATA SET NAME IN FILE    * 07300021
*       LABEL 1. IF THE NAMES ARE NOT IDENTICAL AND THE DATA SET IS   * 07400021
*       A MEMBER OF A GENERATION DATA GROUP, THEN THE UNQUALIFIED     * 07500021
*       DATA SET NAME, THE GENERATION NUMBER, AND THE VERSION NUMBER  * 07600021
*       ARE ALL VERIFIED SEPARATELY. AN ERROR EXIT IS TAKEN WHEN THE  * 07700021
*       VARIOUS COMPARANDS ARE NOT IDENTICAL;                         * 07800021
*    3. IF THE DCB CONTAINS A TAPE-DEPENDENT SECTION, THE BLOCK COUNT * 07900021
*       FROM THE LABEL IS CONVERTED TO BINARY AND PLACED IN THE DCB.  * 08000021
*    4. PROCESS INPUT USER HEADER LABELS, IF REQUIRED-                * 08100021
*       A. OBTAIN A 168-BYTE USER LABEL WORK AREA IN MAIN STORAGE;    * 08200021
*       B. A LABEL IS READ AND CONTROL IS PASSED TO THE USER VIA A    * 08300021
*          'SYNCH' MACRO (SVC 12). ADDITIONAL LABELS ARE READ         * 08400021
*          IF THE USER PASSES A RETURN CODE OF '4'; THIS CONTINUES    * 08500021
*          UNTIL EITHER THE MAXIMUM NUMBER OF LABELS HAS BEEN READ OR * 08600021
*          UNTIL THE USER INDICATES THAT PROCESSING IS TO TERMINATE.  * 08700021
*       C. THE USER LABEL INTERFACE IS AS FOLLOWS-                    * 08800021
*          REGISTERS ARE INITIALIZED FOR THE USER AS FOLLOWS-         * 08900021
*             1    - ADDRESS OF A 4-WORD USER LABEL PARAMETER LIST;   * 09000021
*             2-13 - USER'S REGISTERS AT ENTRY TO END-OF-VOLUME;      * 09100021
*             15   - USER'S LABEL EXIT ROUTINE ADDRESS.               * 09200021
*          PARAMETER LIST CONTENTS-                                   * 09300021
*             WORD 1- ADDRESS OF THE USER LABEL BUFFER, OR '0' IF     * 09400021
*                     NO LABELS WERE READ (I.E., TAPE MARK WAS READ); * 09500021
*             WORD 2- ADDRESS OF THE DCB BEING PROCESSED; THE HIGH    * 09600021
*                     ORDER BIT OF THE FIRST BYTE IS ON IF THIS IS    * 09700021
*                     EOF AND IT IS OFF IF THIS IS EOV;               * 09800021
*             WORD 3- '0' IF NO ERRORS WERE ENCOUNTERED; OTHERWISE,   * 09900021
*                     THE ADDRESS OF THE IOB WHICH INCURRED THE ERROR,* 10000021
*                     WITH THE HIGH ORDER BIT OF THE FIRST BYTE ON;   * 10100021
*             WORD 4- '0';                                            * 10200021
*          CONTROL BLOCK INDICATORS-                                  * 10300021
*             'DCBOFLGS' - X'02', OFF - THE 'LOCK' BIT IS TURNED OFF  * 10400021
*                          WHEN CONTROL IS PASSED TO THE USER AND IS  * 10500021
*                          TURNED BACK ON UPON RETURN.                * 10600021
*          USER RETURN CODES (PASSED IN REGISTER 15)-                 * 10700021
*             0 - CONTINUE READING USER LABELS;                       * 10800021
*             4 - DISCONTINUE PROCESSING USER LABELS;                 * 10900021
*                                                                     * 11400021
.LIB23F0 ANOP                                                           11410000
         AIF   ('&LIB' EQ 'LIB1').LIB13F0                               11420000
* FUNCTION -                                                          * 11450000
*    1. READ FILE LABEL 1 AND VERIFY THAT IT IS EITHER HDR1, EOV1,    * 11460000
*       OR EOF1;                                                      * 11470000
*    2. COMPARE THE LEAST SIGNIFICANT (I.E., LAST) 17 CHARACTERS OF   * 11480000
*       THE DATA SET NAME IN THE JFCB TO THE DATA SET NAME IN FILE    * 11490000
*       LABEL 1. IF THE NAMES ARE NOT IDENTICAL AND THE DATA SET IS   * 11492000
*       A MEMBER OF A GENERATION DATA GROUP, THEN THE UNQUALIFIED     * 11494000
*       DATA SET NAME, THE GENERATION NUMBER, AND THE VERSION NUMBER  * 11496000
*       ARE ALL VERIFIED SEPARATELY. AN ERROR EXIT IS TAKEN WHEN THE  * 11498000
*       VARIOUS COMPARANDS ARE NOT IDENTICAL;                         * 11498400
*    3. IF THE DCB CONTAINS A TAPE-DEPENDENT SECTION, THE BLOCK COUNT * 11498800
*       FROM THE LABEL IS CONVERTED TO BINARY AND PLACED IN THE DCB.  * 11499200
*    4. PROCESS INPUT USER HEADER LABELS, IF REQUIRED-                * 11499600
*       A. OBTAIN A 168-BYTE USER LABEL WORK AREA IN MAIN STORAGE;    * 11499700
*       B. A LABEL IS READ AND CONTROL IS PASSED TO THE USER VIA A    * 11499800
*          'SYNCH' MACRO (SVC 12). ADDITIONAL LABELS ARE READ         * 11499900
*          IF THE USER PASSES A RETURN CODE OF '4'; THIS CONTINUES    * 11533200
*          UNTIL EITHER THE MAXIMUM NUMBER OF LABELS HAS BEEN READ OR * 11543200
*          UNTIL THE USER INDICATES THAT PROCESSING IS TO TERMINATE.  * 11553200
*       C. THE USER LABEL INTERFACE IS AS FOLLOWS-                    * 11563200
*          REGISTERS ARE INITIALIZED FOR THE USER AS FOLLOWS-         * 11565200
*             1    - ADDRESS OF A 4-WORD USER LABEL PARAMETER LIST;   * 11565600
*             2-13 - USER'S REGISTERS AT ENTRY TO END-OF-VOLUME;      * 11566000
*             15   - USER'S LABEL EXIT ROUTINE ADDRESS.               * 11566400
*          PARAMETER LIST CONTENTS-                                   * 11566500
*             WORD 1- ADDRESS OF THE USER LABEL BUFFER, OR '0' IF     * 11566600
*                     NO LABELS WERE READ (I.E., TAPE MARK WAS READ); * 11577700
*             WORD 2- ADDRESS OF THE DCB BEING PROCESSED; THE HIGH    * 11587700
*                     ORDER BIT OF THE FIRST BYTE IS ON IF THIS IS    * 11588100
*                     EOF AND IT IS OFF IF THIS IS EOV;               * 11588500
*             WORD 3- '0' IF NO ERRORS WERE ENCOUNTERED; OTHERWISE,   * 11588600
*                     THE ADDRESS OF THE IOB WHICH INCURRED THE ERROR,* 11588700
*                     WITH THE HIGH ORDER BIT OF THE FIRST BYTE ON;   * 11588800
*             WORD 4- '0';                                            * 11592500
*          CONTROL BLOCK INDICATORS-                                  * 11594500
*             'DCBOFLGS' - X'02', OFF - THE 'LOCK' BIT IS TURNED OFF  * 11594900
*                          WHEN CONTROL IS PASSED TO THE USER AND IS  * 11595300
*                          TURNED BACK ON UPON RETURN.                * 11595700
*          USER RETURN CODES (PASSED IN REGISTER 15)-                 * 11596100
*             0 - CONTINUE READING USER LABELS;                       * 11596200
*             4 - DISCONTINUE PROCESSING USER LABELS;                 * 11622100
*    5. POSITION THE TAPE TO THE FIRST DATA RECORD; I.E., AT THE      * 11632100
*       INTERBLOCK GAP PRECEDING THE FIRST DATA RECORD (READ FORWARD) * 11642100
*       OR AT THE INTERBLOCK GAP FOLLOWING THE LAST DATA RECORD       * 11644100
*       (RDBACK).                                                     * 11646100
*    6. DEB VALIDITY CHECKING IS ACCOMPLISHED VIA A DEB VALIDITY CHECK* 11646500
*       ROUTINE WHICH MAINTAINS AND UPDATES A TABLE OF VALID DEB      * 11646900
*       POINTERS IN PROTECTED CORE (LSQS).                            * 11647300
*                                                                     * 11648100
.LIB13F0 ANOP                                                           11656700
* ENTRY POINTS -                                                      * 11665500
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 11674100
*                                                                     * 11700021
* INPUT -                                                             * 11800021
*    1. REGISTER CONTENTS AT ENTRY ARE AS FOLLOWS-                    * 11900021
*       'RDCB' - ADDRESS OF THE DCB BEING PROCESSED;                  * 12000021
*       'RCORE'- ADDRESS OF THE WORK AREA FOR THAT DCB;               * 12100021
*       'RES'  - ADDRESS OF THE OPEN/CLOSE/EOV RESIDENT ROUTINE;      * 12200021
*       'RWTG' - ADDRESS OF THE WHERE-TO-GO TABLE;                    * 12300021
*       'RPARC'- ADDRESS OF THE EOV PSEUDO PARAMETER LIST ENTRY;      * 12400021
*       'RWTGC'- ADDRESS OF THE CURRENT WHERE-TO-GO TABLE ENTRY;      * 12500021
*       'RTIOT'- ADDRESS OF THE CURRENT TIOT ENTRY FOR THE DCB;       * 12600021
*       'RUCB' - ADDRESS OF THE CURRENT UCB FOR THE DCB;              * 12700021
*       'RDEB' - ADDRESS OF THE DCB'S DEB;                            * 12800021
*                                                                     * 12900021
* OUTPUT -                                                            * 13000021
*    1. AT EXIT TO IFG0553H (DATA SET SECURITY TESTS)-                * 13100021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 13200021
*          REGISTER 'RET' CONTAINS A BRANCH TABLE OFFSET OF '0'OR '4' * 13300003
*       CONTROL BLOCK INDICATORS-                                     * 13400021
*          'DCBBLKCT' - CONTAINS THE BLOCK CT FOUND IN FILE LABEL 1;  * 13500021
*    2. AT EXIT TO IFG0550P (PROBLEM DETERMINATION)-                  * 13700021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 13800021
*          REGISTER 'R0' CONTAINS ONE OF THE FOLLOWING INTERNAL       * 13900021
*          ERROR CODES (THE CORRESPONDING ABEND AND RETURN CODES ARE  * 13970021
*          INDICATED IN PARENTHESES)-                                 * 14040021
*          164 (137/14)- ERROR READING FILE LABEL 1.                  * 14110021
*          165 (237/08)- INCORRECT DATA SET NAME IN LABEL.            * 14180021
*          191 (137/18)- ERROR POSITIONING TO FIRST DATA RECORD.      * 14250021
*          195 (137/20)- INCORRECT DATA SET LABEL READ.               * 14320021
*          196 (637/4C)- ERROR POSITIONING FOLLOWING USER TRAILER     * 14390021
*                        LABEL PROCESSING.                            * 14460021
*       WORK AREA INDICATORS-                                         * 14600021
*          'DXCALLID' - CONTAINS THE ID OF THIS MODULE.               * 14700021
*                                                                     * 14800021
* EXTERNAL REFERENCES -                                               * 14900021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 15000021
*                                                                     * 15100021
* EXITS, NORMAL -                                                     * 15200021
*         IFG0553H - TO TEST FOR DATA SET SECURITY.                   * 15300021
*                                                                     * 15400021
* EXITS, ERROR -                                                      * 15500021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 15600021
*                                                                     * 15700021
* TABLES/WORK AREAS -                                                 * 15800021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 15900021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 16000021
*                                                                     * 16100021
* ATTRIBUTES -                                                        * 16200021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 16300021
*                                                                     * 16400021
* CHARACTER CODE DEPENDENCY -                                         * 16500021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 16600021
*                                                                     * 16700021
* NOTES -                                                             * 16800021
*                                                                     * 16900021
*********************************************************************** 17000021
*                                                                       18700021
*********************************************************************** 18800021
*              VERIFY HEADER LABEL ( TRAILER LABEL IF READBACK )      * 18900021
*********************************************************************** 19000021
*                                                                       19100021
*****          READ LABEL                                               19200021
*                                                                       19300021
ETI23100 EQU   *                                                        19400021
         LA    RC,DXLBL                 LOAD ADDRESS OF LABEL BUFFER    19500021
         ST    RC,DXCCW1                ..STORE IT INTO 'READ' CCW      19600021
         MVI   DXCCW1,CCWRDTAP          INITLZ CCW FOR 'READ' COMMAND   19700021
         MVC   DXCCW1+4(K4),ARDCCW7     IND NO FLAGS, LNG EQ 80 BYTES   19800021
         TM    JFCBLTYP,JFCBAL          WERE 'ANSI' LABELS SPECIFIED-   19900021
         BZ    ETI23200                 ..BR IF NOT TO READ LABEL       20000021
         MVI   DXCCW1+4,CCWSILI         TURN ON SILI INDICATOR          20100021
ETI23200 EQU   *                                                        20200021
         LA    RD,EABD164               LOAD INTERNAL ERROR CODE        20300021
         BAL   RC,ETI26400              BR AND LINK TO READ LABEL       20400021
         BNO   ETI26500                 BR TO ERROR RTN IF I/O ERROR    20500021
         TM    SRTESTAB,UCBBSTR         IS AN 'ANSI' VOLUME MOUNTED-    20600021
         BZ    ETI23300                 ..BR IF NOT TO VERIFY LABEL     20700021
         XLATE DXLBL,K80                TRANSLATE 'ANSI' LABEL DATA     20800021
*                                                                       20900021
*****          PERFORM FILE LABEL 1 VERIFICATION                        21000021
*                                                                       21100021
ETI23300 EQU   *                                                        21200021
         LA    RD,EABD195               LOAD INTERNAL ERROR CODE        21300021
         CLC   FL1LABI,AVOL7            IS THIS A VOLUME LABEL-         21400021
         BE    ETI23200                 ..BR IF YES- READ ANOTHER LABEL 21500021
         CLC   FL1LABI,UVOL0C           IS THIS A USER VOLUME LABEL-    21600021
         BE    ETI23200                 ..BR IF YES READ ANOTHER LABEL  21700021
         BAL   RC,ETI26420              GO CHECK LABEL            99223 21750003
         B     ETI26500                 BRANCH TO ERROR ROUT      99223 21760003
*                                                                       22400021
****           DETERMINE 17 LEAST SIGNIFICANT NON-BLANK                 22500021
****           CHARACTERS IN DATA SET NAME IN JFCB                      22600021
*                                                                       22700021
*              NOTE- RDEB ( 'RB' ) IS NOW USED AS A WORK REGISTER       22800021
ETI23400 EQU   *                                                        22900021
         LA    R0,JFCBDSNM              PT TO JFCB DSNAME FIELD  A41622 23000021
         LA    RC,JFCBDSNM+K27          POINT TO FIRST POSSIBLE  A41662 23100021
*                                       ..SIGNIFICANT CHARACTER  A41662 23200021
ETI23500 EQU   *                                                 A41662 23300021
         CLI   K16(RC),BLANK            IS THE 17TH SIGNIFICANT  A41662 23400021
*                                       ..CHARACTER A BLANK-     A41662 23500021
         BNE   ETI23600                 ..BR IF NOT- 'RC' PTS TO A41662 23600021
*                                       ..FIRST SIGNIFICANT CHAR A41662 23700021
         BCT   RC,ETI23500              DECR STARTING ADDR AND   A41662 23800021
*                                       ..BR TO CHECK AGAIN      A41662 23900021
ETI23600 EQU   *                                                 A41662 24000021
         LA    RB,K17(,RC)              PT TO FIRST BLANK BEYOND A41662 24100021
*                                       ..17 SIGNIFICANT CHARS   A41662 24200021
         CLR   RC,R0                    IS DSNAME STARTING ADDR  A41662 24300021
*                                       ..WITHIN JFCB DSN FIELD- A41662 24400021
         BNL   ETI23700                 ..BR IF YES- USE 'RC'    A41662 24500021
         LR    RC,R0                    ..ELSE USE JFCBDSNM      A41662 24600021
*                                       ..AS STARTING ADDRESS    A41662 24700021
*                                                                A41662 24800021
*****          COMPARE THE 17 LEAST SIGNIFICANT CHARACTERS IN    A41662 24900021
*****          THE JFCB DSNAME TO THE DATA SET LABEL DSNAME      A41662 25000021
*****          INCLUDING THE GENERATION AND VERSION NUMBERS      A41662 25100021
*                                                                A41662 25200021
ETI23700 EQU   *                                                 A41662 25300021
         CLC   FL1ID,K0(RC)             ARE THE NAMES IDENTICAL- A41662 25400021
         BE    ETI23900                 ..BR IF CORRECT DATA SET NAME   25500021
*                                                                       25600021
*****          THE DSNAMES IN THE JFCB AND THE HEADER LABEL ARE NOT     25700021
*****          THE SAME. IN THE EVENT THAT THIS IS A 'DOS' TAPE,        25800021
*****          VERIFY THE DATA SET NAME, GENERATION NUMBER, AND         25900021
*****          VERSION NUMBER SEPARATELY. OTHERWISE, EXIT TO THE        26000021
*****          ERROR ROUTINE.                                           26100021
*                                                                       26200021
ETI23800 EQU   *                                                 A41662 26250021
         TM    JFCBIND1,JFCGDG          IS THIS A GENERATION DATA SET-  26300021
         BZ    ETI26450                 ..BR IF NOT TO ERROR RTN        26400021
         LA    RET,K9                   LD LENGTH OF GENERATION  A41662 26440021
*                                       ..AND VERSION NUMBER     A41662 26480021
         SR    RB,RET                   POINT TO THE PERIOD PRE- A41662 26520021
*                                       ..CEDING GENERATION NO.  A41662 26560021
         CLC   FL1GNO,K2(RB)            IS THE GENERATION NO. CORRECT-  26600021
         BNE   ETI26450                 ..BR IF NOT TO ERROR RTN        26700021
         CLC   FL1VNG,K7(RB)            IS THE VERSION NUMBER CORRECT-  26800021
         BNE   ETI26450                 ..BR IF NOT TO ERROR RTN        26900021
*                                                                A41662 26910021
*****          'R0' NOW POINTS TO 'JFCBDSNM'                     A41662 26920021
*****          'RB' NOW POINTS TO THE PERIOD PRECEDING THE       A41662 26930021
*****             GENERATION AND VERSION NUMBERS                 A41662 26940021
*****          'RC' NOW POINTS TO THE BEGINNING OF THE 17 LEAST  A41662 26950021
*****             SIGNIFICANT CHARACTERS- INCLUDING THE GENER-   A41662 26960021
*****             ATION AND VERSION NUMBERS                      A41662 26970021
*                                                                A41662 26980021
         LA    RD,K17                   LD LENGTH OF LABEL NAME  A41662 26990021
         SR    RB,R0                    CALC LENGTH OF DSN WITHOUT GDG  27000021
         CR    RB,RD                    IS THIS NAME GREATER THAN 17    27100021
*                                       ..CHARACTERS-                   27200021
         BH    ETI23840                 ..BR IF YES TO ADJUST ADDRESS   27300021
*                                       ..OF START OF JFCB DSNAME       27400021
         LR    RC,R0                    POINT TO START OF        A41662 27460021
*                                       ..JFCBDSNM FIELD         A41662 27520021
         B     ETI23860                 BRANCH TO COMPARE DSNAMES       27600021
*                                                                A41662 27610021
*****          THE FOLLOWING INSTRUCTION IS USED TO COMPARE THE  A41662 27620021
*****          DATA SET LABEL'S DSNAME TO THE DSNAME IN THE JFCB A41662 27630021
*****          WITHOUT THE GENERATION AND VERSION NUMBERS        A41662 27640021
*                                                                A41662 27650021
ETI23820 CLC   FL1ID(K0),K0(RC)         COMPARE DSNAMES          A41662 27660021
*                                                                A41662 27670021
ETI23840 EQU   *                                                        27700021
         SR    RC,RET                   CALC STARTING ADDR OF    A41662 27770021
*                                       ..DSNAME GREATER THAN    A41662 27840021
*                                       ..17 CHARACTERS LONG     A41662 27910021
         LR    RB,RD                    LOAD DSNAME LENGTH OF 17 CHARS  28000021
ETI23860 EQU   *                                                        28100021
         BCTR  RB,0                     DECR LNG FOR USE IN 'CLC' INST  28200021
         EX    RB,ETI23820              IS THE DSNAME CORRECT-   A41662 28300021
         BNE   ETI26450                 ..BR IF NOT TO ERROR RTN        28400021
*                                                                       28500021
****           PLACE BLOCK COUNT INTO THE DCB                           28600021
*                                                                       28700021
ETI23900 EQU   *                                                        28800021
         TM    DCBMACRF,DCBMEXCP        IS THE ACCESS METHOD EXCP-      28900021
         BNO   ETI24000                 ..BR IF NOT - BLK CT EXISTS     29000021
         TM    DCBMACRF+1,DCBMDEV       IS THERE A TAPE SECTION-        29100021
         BZ    ETI24100                 ..BR IF NOT- BYPASS BLK CT      29200021
ETI24000 EQU   *                                                        29300021
         PACK  DXCCW6,FL1BLKCT          CONVERT BLK CT FROM EBCDIC TO   29400021
         OI    DXCCW6+7,X'0F'           ..UNPACKED, INSURE PROPER SIGN, 29500021
         CVB   RC,DXCCW6                ..CONVERT TO BINARY, AND STORE  29600021
         ST    RC,DCBBLKCT              ..BLOCK COUNT INTO THE DCB      29700021
*********************************************************************** 29750003
* IF THE TAPE UNIT IS A 6250 BPI UNIT AND IBM STANDARD LABELS ARE     * 29760003
* BEING PROCESSED,THE SERIAL NUMBER OF THE CREATING TAPE DEVICE       * 29770003
* IS OBTAINED FROM THE HDR2/EOF2/EOV2 LABEL AND PLACED IN THE UCB     * 29780003
* EXTENSION AREA OF THE TAPE UNIT THAT IS PROCESSING THE TAPE.        * 29790003
*********************************************************************** 29792003
         TM    SRTESTAB,UCBBSTR         IS ANSI VOL MOUNTED       99223 29794003
         BO    ETI24100                 ..YES,CHECK FOR USER LABS 99223 29796003
         CLI   UCBTBYT4,X'03'           3400 SERIES UNIT          99223 29798003
         BZ    ETI24100                 ..NO,CHECK USER LABS      99223 29798403
         LA    RD,EABD164               LOAD ERROR CODE           99223 29798803
         BAL   RC,ETI26400              GO READ LABEL             99223 29799203
         BO    ETI24025                 BR,NO ERROR             SA70404 29799621
         TM    IOBSTAT0,CSWUNITX        WAS A TAPE MARK READ    SA70404 29812221
         BNO   ETI26500                 NO, BR TO ERROR ROUTINE SA70404 29822221
         MVC   DXCCW1(K16),BSFNOP1      SET UP 'BSF,NOP' CCWS   SA70404 29824221
         LA    RD,EABD196               LOAD INT ERROR CODE     SA70404 29824621
         BAL   RC,ETI26400              GO BACKSPACE FILE       SA70404 29824721
         BNO   ETI26500                 BR IF I/O ERROR         SA70404 29828921
         B     ETI24100                 BR,TEST FOR USER LABELS SA70404 29830921
ETI24025 EQU   *                                                SA70404 29832921
         BAL   RC,ETI26420              GO VERIFY LABEL TYPE      99223 29833221
*                                                                       29837421
         B     ETI24050                 GO BACKSPACE,NO LAB 2     99223 29850003
**                                        RETURN +4 IF LABEL OK   99223 29860003
         CLI   FL2ID+K4,BLANK           IS ID FIELD BLANK         99223 29870003
         BE    ETI24100                 .YES,CHECK USER LABS      99223 29880003
         PACK  DXCCW6,FL2ID             CONVERT TAPE ID FROM      99223 29890003
         OI    DXCCW6+K7,SIGNMSK        --EBCDIC TO DECIMAL       99223 29892003
         CVB   RC,DXCCW6                --INSURE PROPER SIGN      99223 29894003
         L     RB,UCBXTN                POINT TO UCB EXTENSION   99223  29896003
         STH   RC,K8(RB)                STORE TAPE ID             99223 29898003
         B     ETI24100                 GO CHECK USER LABELS      99223 29898403
*********************************************************************** 29900021
ETI24050 EQU   *                        BACKSPACE RECORD          99223 29950003
         MVI   DXCCW1,CCWBSR            SET 'BSR' OP CODE         99223 29960003
         LA    RD,EABD196               LOAD INT ERROR CODE       99223 29970003
         MVC   DXCCW1+K1(K15),BSFNOP1+K1  COMPLETE CCW FOR BSR    99223 29980003
*                                       --AND INSERT 'NOP'        99223 29990003
         BAL   RC,ETI26400              GO BACKSPACE RECORD       99223 29992003
         BNO   ETI26500                 BR IF I/O ERROR           99223 29994003
*********************************************************************** 29996003
*              USER HEADER LABEL PROCESSING                           * 30000021
*********************************************************************** 30100021
*                                                                       30200021
****           DETERMINE IF USER LABELS ARE TO BE PROCESSED             30300021
*                                                                       30400021
ETI24100 EQU   *                                                        30500021
         AIF   ('&LIB' NE 'LIB1').LIB23F1                               30550000
         L     RDEB,DCBDEBAD            RESTORE THE DEB ADDRESS         30600021
.LIB23F1 ANOP                                                           30650000
         AIF   ('&LIB' EQ 'LIB1').LIB13F1                               30660000
         L     RDEB,DXPDEBAD            LOAD PROTECTED DEB ADDR  Y01021 30670000
.LIB13F1 ANOP                                                           30680000
         TM    JFCBLTYP,JFCBUL          WERE USER LABELS SPECIFIED-     30700021
         BNO   ETI26100                 ..BR IF NOT- BYPASS USER LBLS   30800021
         TM    DCBMACRF,DCBMEXCP        IS THE ACCESS METHOD EXCP-      30900021
         BZ    ETI24200                 ..BR IF NOT- TEST FOR EXIT LIST 31000021
         TM    DCBMACRF,DCBMFOUN        IS THERE A TAPE DEPEND SECTION- 31100021
         BZ    ETI26100                 ..BR IF NOT- BYPASS USER LBLS   31200021
ETI24200 EQU   *                                                        31300021
         L     RC,DCBEXLST              LOAD EXIT LIST ADDR FROM DCB    31400021
         LA    RC,K0(,RC)               ZERO HIGH ORDER BYTE            31500021
         LTR   RC,RC                    IS THERE A DCB EXIT LIST-       31600021
         BE    ETI26100                 ..BR IF NOT- BYPASS USER LBLS   31700021
ETI24300 EQU   *                                                        31800021
         CLI   K0(RC),XLIUHL            IS THERE AN INPUT HDR LBL EXIT- 31900021
         BE    ETI24500                 ..BR IF YES- CHECK FOR ADDR     32000021
         CLI   K0(RC),LASTNTRY+XLIUHL   IS 'LAST ENTRY' IND ALSO ON-    32100021
         BE    ETI24500                 ..BR IF YES- CHECK FOR ADDR     32200021
ETI24400 EQU   *                                                        32300021
         TM    K0(RC),LASTNTRY          IS THIS THE LAST LIST ENTRY-    32400021
         LA    RC,K4(,RC)               POINT TO NEXT ENTRY             32500021
         BNO   ETI24300                 ..BR IF NOT- CHECK NEXT ENTRY   32600021
         B     ETI26100                 ..ELSE BYPASS USER LABELS       32700021
ETI24500 EQU   *                                                        32800021
         L     RC,K0(,RC)               LOAD EXIT LIST ADDRESS          32900021
         LA    RC,K0(,RC)               ZERO THE HIGH ORDER BYTE        33000021
         LTR   RC,RC                    IS THERE A VALID ADDRESS-       33100021
         BZ    ETI26100                 ..BR IF NOT- BYPASS USER LABELS 33200021
*                                                                       33300021
*****          PROCESS USER HEADER LABELS                               33400021
*                                                                       33500021
ETI24600 EQU   *                                                        33600021
         GETMAIN R,LV=USERL,SP=250      OBTAIN MAIN STORAGE FOR USER   C33700021
                                        ..LABEL WORK AREA               33800021
         USING ULWK,R1                                                  33900021
         STM   RES,RC,ULWK              SAVE REGS (INCLUDES DCB EXIT    34000021
*                                       ..LIST ADDR FOR USER LABELS)    34100021
         DROP  R1                                                       34200021
*                                                                       34300021
*****          RUCB IS NOW USED AS THE USER LABEL WORK AREA BASE REG    34400021
*                                                                       34500021
         LR    RUCB,R1                  POINT TO OBTAINED AREA          34600021
         USING ULWK,RUCB                ESTABLISH ADDRESSABILITY        34700021
         LA    R1,CHAR0                 INITIALIZE LABEL COUNT          34800021
         STH   R1,ULCNT                 ..AND SAVE FOR LATER USE        34900021
ETI24700 EQU   *                                                        35000021
         LA    R1,ULBUFR                LOAD ADDRESS OF LABEL BUFFER    35100021
         ST    R1,DXCCW1                ..AND STORE IN READ CCW         35200021
         MVI   DXCCW1,CCWRDTAP          INITLZ CCW FOR READ COMMAND     35300021
*                                       INDICATOR ON LNG STILL IN CCW)  35400021
         MVI   DXCCW1+4,CCWSILI         SET 'SILI' FLAG ON              35500021
ETI24800 EQU   *                                                        35600021
         BAL   RC,ETI26400              BR AND LINK TO READ A LABEL     35700021
         BO    ETI24900                 BR IF NO I/O ERROR              35800021
         TM    IOBSTAT0,CSWUNITX        WAS A TAPE MARK READ-           35900021
         BO    ETI25700                 ..BR IF YES                     36000021
         B     ETI25600                 ..ELSE BR RO PROCESS ERROR      36100021
ETI24900 EQU   *                                                        36200021
         TM    JFCBLTYP,JFCBAL+JFCBUL   WERE ANSI USER LBLS SPECIFIED-  36300021
         BNO   ETI25000                 ..BR IF NOT- BYPASS TRANSLATION 36400021
         XLATE ULBUFR,K80               TRANSLATE ANSI LABEL            36500021
ETI25000 EQU   *                                                        36600021
         CLC   ULBUFR(K3),AUHL7         WAS A USER HEADER LABEL READ-   36700021
         BE    ETI25100                 ..BR IF YES                     36800021
         CLC   ULBUFR(K3),AUTL7         WAS A USER TRAILER LABEL READ-  36900021
         BE    ETI25100                 ..BR IF YES                     37000021
*                                                                       37100021
*              NOTE - INPUT TRAILER LABEL PROCESSING LEAVES THE TAPE    37200021
*              POSITIONED BETWEEN THE FIRST AND SECOND DATA SET         37300021
*              TRAILER LABELS. THE FOLLOWING ALLOWS PROCESSING OF USER  37400021
*              LABELS EVEN THOUGH THE TAPE MAY CONTAIN MORE DATA SET    37500021
*              LABELS THAN CAN CURRENTLY BE CREATED UNDER O/S.          37600021
*                                                                       37700021
         BAL   RC,ETI26420              GO VERIFY LABEL TYPE      99223 37750003
         B     ETI25050                 WRONG LABEL TYPE          99223 37760003
         B     ETI24800                 GO READ NEXT LABEL        99223 37770003
ETI25050 EQU   *                        BACKSPACE RECORD          99223 37780003
         MVI   DXCCW1,CCWBSR            INITLZ CCW FOR 'BSR' COMMAND    38400021
         B     ETI25900                 BR- AN 'UNKNOWN' LABEL WAS READ 38500021
ETI25100 EQU   *                                                        38600021
         MVC   ULCNT+1(K1),ULBUFR+3     SAVE LABEL NUMBER               38700021
         XC    ULPARM+8(K4),ULPARM+8    ZERO ERROR IND                  38800021
*                                                                       38900021
*****          PASS CONTROL TO USER FOR USER PROCESSING                 39000021
*                                                                       39100021
ETI25200 EQU   *                                                        39200021
         LA    R1,ULBUFR                POINT TO LABEL BUFFER           39300021
         LA    RD,ETI25500              LOAD ADDR FOR RETURN FROM SYNCH 39400021
ETI25300 EQU   *                                                        39500021
         STM   R1,RDCB,ULPARM           STORE POINTERS TO LABEL BUFFER  39600021
*                                       ..AND DCB IN PARAMETER LIST     39700021
         XC    ULTOTPTR(K4),ULTOTPTR    ZERO THE USER TOTALING ENTRY    39800021
         MVI   ULDCBPTR,K0              CLEAR FLAG BYTE                 39900021
         LA    R1,ULPARM                POINT TO PARAMETER LIST         40000021
         L     RF,ULREQ                 LOAD PTR TO USER LABEL ROUTINE  40100021
         L     RC,CVTPTR                LOAD CVT ADDRESS                40200021
         USING CVT,RC                   ESTABLISH CVT ADDRESSABILITY    40300021
         L     RC,CVTTCBP               LD PT TO NEXT AND CURRENT TCBS  40400021
         L     RC,K4(,RC)               LOAD CURRENT TCB ADDRESS        40500021
         USING TCB,RC                   ESTABLISH TCB ADDRESABILITY     40600021
         L     RC,TCBRBP                GET CURRENT SVRB ADDRESS        40700021
         USING RBSECT,RC                ESTABLISH RB ADDRESSABILITY     40800021
         STM   RDCB,RD,RBEXSAVE         SAVE EOV REGISTERS 2-13         40900021
         NI    DCBOFLGS,X'FF'-DCBOLOCK  IND USER EXIT HAS BEEN TAKEN    41000021
ETI25350 EQU   *                                                        41100021
         L     RD,RBLINK                PT TO THE PREVIOUS REQUEST BLK  41200021
         TM    RBSTAB-RBSECT(RD),RBFTSVRB IS IT THE USER'S 'PRB'-       41300021
         BZ    ETI25400                 ..BR IF YES- 'RC' POINTS TO THE 41400021
*                                       ..SVRB WITH THE USER'S REGS     41500021
         LR    RC,RD                    NO- PT TO SVRB WITH USER'S REGS 41600021
         B     ETI25350                 BR- REPEAT TEST FOR USER'S PRB  41700021
ETI25400 EQU   *                                                        41800021
         LM    RDCB,RD,RBGRS2           RESTORE USERS REGS 2-13         41900021
         SYNCH (RF)                     PASS CONTROL TO USER            42000021
         L     RC,CVTPTR                LOAD CVT ADDRESS                42100021
         USING CVT,RC                   ESTABLISH CVT ADDRESSABILITY    42200021
         L     RC,CVTTCBP               LD PT TO NEXT AND CURRENT TCBS  42300021
         L     RC,K4(,RC)               LOAD CURRENT TCB ADDRESS        42400021
         USING TCB,RC                   ESTABLISH TCB ADDRESSABILITY    42500021
         L     RC,TCBRBP                LOAD CURRENT SVRB ADDRESS       42600021
         USING RBSECT,RC                ESTABLISH RB ADDRESSABILITY     42700021
         AIF   ('&LIB' EQ 'LIB1').LIB13F2                               42750000
         LR    RD,RF                    SAVE USER RETURN CODE    Y01021 42752000
         LM    RDCB,RCORE,RBEXSAVE      REGISTERS FOR DEBCHK     Y01021 42754000
         DEBCHK (RDCB)                  VALIDATE DEB             Y01021 42760000
         ST    R1,DXPDEBAD              STORE VALIDATED DEBAD    Y01021 42760400
         LR    RF,RD                    RESTORE USER RETURN CODE Y01021 42762000
         LM    RPAR,RD,RBEXSAVE+K12     RESTORE OTHER REGISTERS  Y01021 42764000
.LIB13F2 ANOP                                                           42766000
         AIF   ('&LIB' NE 'LIB1').LIB23F2                               42770000
         LM    RDCB,RD,RBEXSAVE         RESTORE EOV REGISTERS 2-13      42800021
.LIB23F2 ANOP                                                           42850000
         DROP  RC                                                       42900021
         OI    DCBOFLGS,DCBOLOCK        INDICATE DCB BEING PROCESSED    43000021
         BR    RD                       RETURN TO CALLER                43100021
ETI25500 EQU   *                                                        43200021
         CH    RF,RDAGAIN1              SHOULD ADD'L LABELS BE READ-    43300021
         BNE   ETI26000                 ..BR IF NOT- ALL DONE           43400021
         TM    JFCBLTYP,JFCBAL+JFCBUL   WERE ANSI USER LBLS SPECIFIED-  43500021
         BO    ETI24800                 ..BR IF YES- READ ANOTHER LABEL 43600021
         CLI   ULCNT+1,MAXNOLAB         HAS MAX NO. OF LABELS BEEN READ 43700021
         BNL   ETI26000                 ..BR IF YES- ALL DONE           43800021
         B     ETI24800                 ..BR IF NOT TO READ NEXT LABEL  43900021
*                                                                       44000021
*****          ERROR ENCOUNTERED DURING READ                            44100021
*                                                                       44200021
ETI25600 EQU   *                                                        44300021
         LA    R1,DXIOB                 INSERT POINTER TO STATUS INFO   44400021
         ST    R1,ULPARM+8              ..IN PARAMETER LIST             44500021
         OI    ULPARM+8,ERROR           INDICATE THAT AN ERROR OCCURRED 44600021
         LH    R1,ULCNT                 LOAD THE CURRENT LABEL NUMBER,  44700021
         LA    R1,K1(,R1)               ..INCREMENT IT BY 1, AND        44800021
         STH   R1,ULCNT                 ..SAVE IT IN THE WORK AREA      44900021
         STC   R1,ULBUFR+3              SAVE NO. OF LABEL WHICH COULD   45000021
*                                       ..NOT BE READ                   45100021
         B     ETI25200                 BR TO SYNCH TO USER             45200021
*                                                                       45300021
*              A TAPE MARK HAS BEEN READ. IF USER HAS PREVIOUSLY        45400021
*              PROCESSED ANY LABELS,  REPOSITION TAPE, FREEMAIN,        45500021
*              AND RETURN TO CALLER. IF USER HAS NOT PREVIOUSLY         45600021
*              PROCESSED ANY LABELS, SYNCH TO USER WITH LABEL           45700021
*              BUFFER POINTER SET TO ZERO, THEN REPOSITION              45800021
*              TAPE, FREEMAIN, AND RETURN TO CALLER.                    45900021
*                                                                       46000021
ETI25700 EQU   *                                                        46100021
         CLI   ULCNT+1,CHAR0            HAVE ANY LABELS BEEN PROCESSED- 46200021
         BH    ETI25800                 ..BR IF YES- ALL DONE           46300021
         TM    JFCBLTYP,JFCBAL+JFCBUL   WERE ANSI USER LBLS SPECIFIED-  46400021
         BO    ETI25800                 ..BR IF YES- ALL DONE           46500021
         XC    ULPARM+8(K4),ULPARM+8    ZERO ERROR PARAMETER            46600021
         SR    R1,R1                    ZERO BUFFER POINTER             46700021
         BAL   RD,ETI25300              BR AND LINK TO SYNCH TO USER    46800021
ETI25800 EQU   *                                                        46900021
         MVI   DXCCW1,CCWBSF            INITLZ CCW FOR 'BSF' CMD M0961  47000021
ETI25900 EQU   *                                                        47100021
         LA    RD,EABD196               LOAD INTERNAL ERROR CODE        47200021
         MVC   DXCCW1+1(K15),BSFNOP1+1  COMPLETE BACKSPACE CCW   M0961  47300021
*                                       ..AND INSERT 'NOP' CCW   M0961  47350021
         BAL   RC,ETI26400              BR AND LINK TO BACKSPACE        47400021
         BNO   ETI26500                 BR IF I/O ERROR                 47500021
ETI26000 EQU   *                                                        47600021
         LR    R1,RUCB                  LOAD ADDR OF USER LABEL WK AREA 47700021
         LM    RES,RC,ULWK              RESTORE REGISTERS 5-12          47800021
         FREEMAIN R,LV=USERL,SP=250,A=(1) RELEASE USER LABEL WORK AREA C47900021
                                        ..MAIN STORAGE                  48000021
         USING UCB,RUCB                 RE-ESTABLISH UCB ADDRESSABILITY 48100021
*                                                                       48200021
         SPACE 2                                                        50200021
*********************************************************************** 50300021
*              EXIT                                                   * 50400021
*********************************************************************** 50500021
*                                                                       50600021
*    NEXT MODULE POSITIONS TO FIRST DATA RECORD                         50610003
ETI26100 EQU   *                        SELECT NEXT MODULE        99223 50650003
ETI26300 EQU   *                                                        50700021
         IECRES XCTL,MOD3F3H,K0         INVOKE IECRES MACRO TO XCTL     50750003
         EJECT                                                          51400021
*********************************************************************** 51500021
*              SUBROUTINES                                            * 51600021
*********************************************************************** 51700021
*                                                                       51800021
*****          CLOSED SUBROUTINE TO PERFORM I/O OPERATIONS              51900021
*****          ENTRY TO THE SUBROUTINE IS VIA A 'BAL  RC,ETI26400'      52000021
*                                                                       52100021
ETI26400 EQU   *                                                        52200021
         EXCP  DXIOB                    INITIATE I/O OPERATION          52300021
         IECRES WAIT                    INVOKE IECRES MACRO TO 'WAIT'   52400021
         TM    DXECB,ECBNOERR           TEST FOR AN I/O ERROR-          52500021
         BR    RC                       RETURN TO CALLER WITH           52600021
*                                       ..CONDITION CODE SET            52700021
         SPACE 2                                                        52800021
*  CLOSED SUBROUTINE USED TO VERIFY THAT LABEL IS HDR,EOF,OR EOV. 99223 52850003
*  RETURN TO CALLER VIA REGISTER RC.RETURN IS RC+4 IF PROPER TYPE.99223 52852003
ETI26420 EQU   *                        VERIFY HDR,EOF,EOV        99223 52860003
         CLC   FL1LABI,AHDR7            HEADER LABEL              99223 52870003
         BE    ETI26430                 YES,RETURN PLUS FOUR      99223 52880003
         CLC   FL1LABI,AEOF7            E-O-F LABEL               99223 52890003
         BE    ETI26430                 YES,RETURN PLUS FOUR      99223 52892003
         CLC   FL1LABI,EOV7             E-O-V LABEL              99223  52894003
         BNE   ETI26440                 YES,TAKE NORMAL RETURN    99223 52896003
ETI26430 EQU   *                        RETURN PLUS FOUR          99223 52898003
         LA    RC,K4(RC)                ADD 4 TO RETURN ADDR      99223 52898403
ETI26440 EQU   *                        NORMAL RETURN             99223 52898803
         BR    RC                       RETURN TO CALLER          99223 52899203
*********************************************************************** 52900021
*              ERROR PROCESSING                                       * 53000021
*********************************************************************** 53100021
*                                                                       53200021
ETI26450 EQU   *                                                        53300021
         LA    RD,EABD165               LOAD INTERNAL ERROR CODE        53400021
ETI26500 EQU   *                                                        53500021
         DMABCOND (RD),ABEND3F          EXIT TO PROB DETERMINATION RTN  53600021
         SPACE 2                                                        53700021
*********************************************************************** 53800021
*              CONSTANTS                                              * 53900021
*********************************************************************** 54000021
*                                                                       54100021
SIGNMSK  EQU   X'0F'                    SIGN MASK                 99223 54150003
AFSFCCW  CCW   X'3F',0,X'20',1          FORWARD SPACE FILE              54200021
BSFNOP1  DC    X'2F00000060000001'      BSF COMMAND, CMD CHAIN,  M0961  54300021
*                                       ..SILI, AND LNG EQUAL 1  M0961  54350021
         DC    X'0300000020000001'      NOP CMD, SILI, LNG EQ 1  M0961  54400021
ARDCCW7  DC    X'00000050'              LENGTH EQ 50 FOR RD DATA M0961  54500021
RDAGAIN1 DC    H'4'                     'READ LABEL AGAIN' CODE  M0961  54600021
AVOL7    DC    C'VOL'                   VOLUME IDENTIFIER               54800021
AHDR7    DC    C'HDR'                   HEADER LABEL IDENTIFIER         54900021
EOV7     DC    C'EOV'                   END OF VOLUME IDENTIFIER        55000021
AEOF7    DC    C'EOF'                   END OF FILE IDENTIFIER          55100021
AUHL7    DC    C'UHL'                   USER HEADER LABEL IDENTIFIER    55200021
AUTL7    DC    C'UTL'                   USER TRAILER LABEL IDENTIFIER   55300021
UVOL0C   DC    C'UVL'                   USER VOLUME LABEL               55400021
         EJECT                                                          55500021
*********************************************************************** 55600021
*              XCTL TABLE                                             * 55700021
*********************************************************************** 55800021
*                                                                       55900021
XCTLTB3F XCTLTABL ID=(ABEND3F,0P,MOD3F3H,3H),SVC=055                    56000021
         SPACE 2                                                        56100021
         IECDSECS CVT,                                                 C56200021
               TCB,                                                    C56300021
               RB,                                                     C56400021
               DCB,                                                    C56500021
               DEB,                                                    C56600021
               UCB,                                                    C56700021
               MAIN,                                                   C56800021
               USERLAB,                                                C56900021
               EXPAND=YES                                               57000021
         IECEQU ,                       INVOKE OPEN/CLOSE/EOV EQUATES   57100021
         SPACE 2                                                        57200021
         END                                                            57300021
