         TITLE 'IFG0553H - EOV TAPE INPUT STD HEADER LABEL FUNCTION'    00100021
         COPY  LCGASMSW                                                 00150000
IFG0553H CSECT                                                          00400021
*********************************************************************** 00800021
*                                                                     * 00900021
*          VS1 RELEASE 03.1 DELETIONS/CHANGES                         * 00950021
*SEE SA69185                                                    XA04640 00951021
*        VS1 RELEASE 2 DELETIONS                                      * 00952000
*                                                                     * 00954000
*0000                                                            XM8246 00960000
*                                                                     * 00960400
*        VS2 RELEASE 1 DELETIONS/CHANGES                              * 00960800
*                                                                     * 00961200
*0000                                                            YM3271 00962000
*                                                                     * 01000021
*          RELEASE 25 DELETIONS/CHANGES                               * 01100021
*          RELEASE 24 DELETIONS/CHANGES                               * 01200021
*          RELEASE 23 DELETIONS/CHANGES                               * 01300021
*          RELEASE 22 DELETIONS/CHANGES                               * 01400021
*          RELEASE 21.8 DELETIONS/CHANGES                             * 01450021
*0000009500-009504,009700-009800,189000,385000-393000           SA69185 01460021
*          RELEASE 21 DELETIONS/CHANGES                               * 01500021
*0000                                                            M0027  01520021
*                                                                M0004  01550021
*                                                                A42872 01560021
*                                                                M0110  01570021
*0000006000-007000,155000,219000,234000                          M0038  01580021
*                                                               SA47382 01590021
*0000482000-490000,611000                                       SA52404 01592021
*                                                                     * 01600021
*          RELEASE 21.7 DELETION/CHANGES                              * 01650021
*0000                                                           SA62427 01660021
* STATUS CHANGE LEVEL 000                                             * 01700021
*                                                                     * 01800021
* FUNCTION -                                                          * 01900021
*    THIS MODULE CONTAINS THE FOLLOWING FUNCTIONS-                    * 02000021
*       1) 'EOV TAPE INPUT STANDARD HEADER LABEL FUNCTION', PART II;  * 02100021
*       2) 'EOV TAPE INPUT VOLUME MOUNT-AHEAD FUNCTION'.              * 02200021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS' FOR DETAILS.           * 02300021
*                                                                     * 02400021
* ENTRY POINTS -                                                      * 02500021
*         IFG0553H - REFER TO 'INPUT' FOR A LIST OF CALLING MODULES   * 02580021
*                    AND THEIR RESPECTIVE ENTRY CONDITIONS. NOTE THAT * 02660021
*                    IGG0550D IS AN ALIAS FOR THIS MODULE AND IS USED * 02740021
*                    AS A RETURN ADDRESS FOR NSLEHDRI.                * 02820021
*                                                                     * 02900021
* INPUT -                                                             * 03000021
*    REGISTER 14 ('RET') WILL CONTAIN ONE OF THE BRANCH TABLE OFFSETS * 03100021
*    LISTED BELOW, THE BRANCH TABLE BEING USED TO DETERMINE AT WHICH  * 03200021
*    POINT PROCESSING IS TO BEGIN -                                   * 03300021
*        0 - ENTRY FROM IFG0553F TO TEST FOR DATA SET SECURITY.       * 03400021
*        4 - RETURN FROM IFG0552P AFTER ISSUING 'RETAIN' MESSAGE.     * 03500021
*        8 - RETURN FROM IFG0552P AFTER ISSUING A 'MOUNT' MESSAGE.    * 03700021
*       12 - RETURN FROM TRACE TERMINATION MODULE IFG0559R.           * 03800021
*       16 - RETURN FROM SECURITY MODULE IFG0195T AFTER VERIFYING     * 03900021
*            THE PASSWORD OF A PROTECTED DATA SET.                    * 04000021
*       20 - ENTRY FROM NSLEHDRI TO MOUNT THE 'MOUNT-AHEAD' VOLUME.   * 04100021
*       24 - ENTRY FROM IFG0553D TO MOUNT THE 'MOUNT-AHEAD' VOLUME.   * 04200021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS' FOR ADDITIONAL INPUT.  * 04300021
*                                                                     * 04400021
* OUTPUT -                                                            * 04500021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 04600021
*                                                                     * 04700021
* EXTERNAL REFERENCES -                                               * 04800021
*         IFG055RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 04900021
*                    WAIT. REFER TO THE FOLLOWING 'FUNCTION PROLOGS'. * 05000021
*                                                                     * 05100021
* EXITS, NORMAL -                                                     * 05200021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 05300021
*                                                                     * 05400021
* EXITS, ERROR -                                                      * 05500021
*         IFG0550P - WHEN AN ERROR CONDITION OCCURS IN THIS MODULE.   * 05600021
*                    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.       * 05650021
*                                                                     * 05700021
* TABLES/WORK AREAS -                                                 * 05800021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 05900021
*                                                                     * 06000021
* ATTRIBUTES -                                                        * 06100021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 06200021
*                                                                     * 06300021
* CHARACTER CODE DEPENDENCY -                                         * 06400021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 06500021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 06600021
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 06700021
*                                                                     * 06800021
* NOTES -                                                             * 06900021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 07000021
*                                                                     * 07100021
*********************************************************************** 07200021
         EJECT                                                          07250021
*                                                                       07300021
*****    INTERNAL ERROR CODES                                           07400021
*                                                                       07500021
EABD193  EQU   193                      ERROR UNLOADING MT-AHEAD UNIT   07600021
EABD191  EQU   191                      ERROR POSITIONING TO            07650000
*                                       ..FIRST DATA RECORD             07660000
*                                                                       07700021
         BALR  RBASE,0                  ESTABLISH ADDRESSABILITY FOR    07800021
         USING *,RBASE                  THIS SECTION OF CODE            07900021
         USING FORCORE,RCORE                                            08000021
         USING IHADCB,RDCB                                              08100021
         USING UCB,RUCB                                                 08200021
         USING TIOENTRY,RTIOT                                           08300021
         USING DEB,RDEB                                                 08400021
*                                                                       08500021
*                                                                       08600021
         B     ETI28000(RET)            DETERMINE TYPE OF ENTRY TO MOD  08700021
ETI28000 EQU   *                                                        08800021
         B     ETI28200           ( 0)  NORMAL ENTRY- BR TO TEST FOR    08900021
*                                       ..DATA SET SECURITY             09000021
         B     ETI29900           ( 4)  RETURN FROM DISMOUNT MSG- BR    09100021
*                                       ..TO ISSUE MOUNT MESSAGE        09200021
         B     ETI30200           ( 8)  RETURN FROM MOUNT MESSAGE-      09300021
*                                       ..BR TO EXIT FROM MODULE        09400021
         B     ETI30300           (12)  RETURN FROM TRACE TERMINATION-  09500021
*                                       ..BR TO RELEASE RES RTN WK AREA 09600021
         B     ETI28800           (16)  BR IF RETURN FROM SECURITY      09700021
         B     ETI28100           (20)  BR IF RET FROM NSLEHDRI         09800021
         B     ETI28900           (24)  BR IF ENTRY FOR NL              09900021
*                                                                       10000021
ETI28100 EQU   *                                                        10100021
         AIF   ('&LIB' EQ 'LIB1').LIB13H4                               10102000
         MVC   DXXMODNM(L'IFG055NM),IFG055NM  MOVE IN MOD PREFIX YM3271 10106000
.LIB13H4 ANOP                                                           10108000
         AIF   ('&LIB' NE 'LIB1').LIB23H2                               10110000
         MVI   DXXMODNM+1,C'F'          CHANGE WTG NAME TO 'IFG' M0027  10120021
         MVC   DXXMODID(2),MOD3H3H      CHANGE WTG MODULE NAME   M0027  10140021
.LIB23H2 ANOP                                                           10150000
         MVC   DXXIDTTR(2),MOD3H3H      ..AND ENTRY IDS TO '3H'  M0027  10160021
         TM    SRTEDMCT,UCBMOUNT        WAS NSL VOLUME THE CORRECT ONE- 10200021
         BZ    ETI28900                 ..BR IF YES TO MOUNT-AHEAD RTN  10300021
*                                       ..NO- EXIT TO DISMT/MOUNT RTN   10400021
         LA    RF,MOD2Z3H               PT TO ID/TTR OF DISMT/MT MOD    10500021
         LA    RET,K8                   BR TABLE OFFSET FOR THAT MODULE 10600021
         B     ETI30100                 BR TO XCTL                      10700021
         EJECT                                                          10800021
*********************************************************************** 10900021
*                                                                     * 11000021
*                          FUNCTION PROLOG                            * 11100021
*                                                                     * 11200021
*********************************************************************** 11300021
*                                                                     * 11400021
* FUNCTION NAME -                                                     * 11500021
*    'EOV TAPE INPUT STANDARD HEADER LABEL FUNCTION', PART II.        * 11600021
*                                                                     * 11700021
* (STATUS) -                                                          * 11800021
*    NOT APPLICABLE                                                   * 11900021
*                                                                     * 12000021
* FUNCTION -                                                          * 12100021
*    1. POSITION VOLUME TO FIRST DATA RECORD.                           12150000
*    2. FOR DATA SETS ON AL OR SL TAPE, TEST FOR DATA SET SECURITY.   * 12200000
*       A DATA SET MAY BE BOTH READ AND WRITE PROTECTED, IN WHICH     * 12300021
*       CASE THE PASSWORD IS ALWAYS REQUIRED, OR IT MAY BE WRITE-     * 12400021
*       PROTECTED, IN WHICH CASE THE PASSWORD IS ONLY REQUIRED IF     * 12500021
*       THE DATA SET IS OPENED FOR 'INOUT'. IF THE PASSWORD HAS NOT   * 12600021
*       BEEN PREVIOUSLY VERIFIED, CONTROL IS TRANSFERRED TO THE       * 12700021
*       OPEN/EOV SECURITY MODULE TO DETERMINE WHETHER OR NOT ACCESS   * 12800021
*       IS AUTHORIZED. IF AN ANSI TAPE HAS AN UNRECOGNIZABLE SECURITY * 12900021
*       INDICATOR, CONTROL IS TRANSFERRED TO MODULE IFG0552X TO       * 13000021
*       ISSUE AN ACCESSABILITY MESSAGE AND CLOSE THE DATA SET.        * 13100021
*                                                                     * 13200021
* ENTRY POINTS -                                                      * 13300021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 13400021
*                                                                     * 13500021
* INPUT -                                                             * 13600021
*    1. REGISTER CONTENTS AT ENTRY ARE AS FOLLOWS-                    * 13700021
*       'RDCB' - ADDRESS OF THE DCB BEING PROCESSED;                  * 13800021
*       'RCORE'- ADDRESS OF THE WORK AREA FOR THAT DCB;               * 13900021
*       'RES'  - ADDRESS OF THE OPEN/CLOSE/EOV RESIDENT ROUTINE;      * 14000021
*       'RWTG' - ADDRESS OF THE WHERE-TO-GO TABLE;                    * 14100021
*       'RPARC'- ADDRESS OF THE EOV PSEUDO PARAMETER LIST ENTRY;      * 14200021
*       'RWTGC'- ADDRESS OF THE CURRENT WHERE-TO-GO TABLE ENTRY;      * 14300021
*       'RTIOT'- ADDRESS OF THE CURRENT TIOT ENTRY FOR THE DCB;       * 14400021
*       'RUCB' - ADDRESS OF THE CURRENT UCB FOR THE DCB;              * 14500021
*       'RDEB' - ADDRESS OF THE DCB'S DEB;                            * 14600021
*    2. CONTROL BLOCK INDICATORS-                                     * 14610021
*       'DCBOFLGS' - X'20', ON - INDICATES THAT CONCATENATION IS      * 14620021
*                                TAKING PLACE.                        * 14630021
*       'DEBFLGS1' - X'80', ON - INDICATES THAT 'OPEN' OR 'EOV' HAS   * 14640021
*                                PREVIOUSLY VERIFIED THE PASSWORD     * 14650021
*                                FOR THIS PROTECTED DATA SET.         * 14660021
*                                                                     * 14700021
* OUTPUT -                                                            * 14800021
*    1. AT EXIT TO IFG0195T (OPEN/EOV SECURITY MODULE)-               * 14900021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 15000021
*          REGISTER 'RET' CONTAINS A BRANCH TABLE OFFSET OF '0';      * 15100021
*       CONTROL BLOCK INDICATORS-                                     * 15200021
*          'DCBOFLGS' - X'20', OFF - INDICATES THAT CONCATENATION     * 15300021
*                                    HAS BEEN COMPLETED.              * 15400021
*          'DEBFLGS1' - X'80', OFF - INDICATES THAT THE PASSWORD HAS  * 15500021
*                                    NOT PREVIOULY BEEN VERIFIED.     * 15600021
*    2. AT EXIT TO IFG0552X (EOD FUNCTION)-                           * 15700021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 15800021
*          REGISTER 'RET' CONTAINS A BRANCH TABLE OFFSET OF '12'.     * 15900021
*    3. AT EXIT TO THE 'EOV TAPE INPUT VOLUME MOUNT-AHEAD FUNCTION',  * 16000021
*       OUTPUT IS VIRTUALLY THE SAME AS AT INPUT.                     * 16100021
*                                                                     * 16200021
* EXTERNAL REFERENCES -                                               * 16300021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 16400021
*                                                                     * 16500021
* EXITS, NORMAL -                                                     * 16600021
*         IFG0195T - TO VERIFY THAT A SECURITY-PROTECTED DATA SET MAY * 16700021
*                    BE ACCESSED;                                     * 16800021
*         PART II OF THIS MODULE- TO MOUNT ANY ADDITIONAL VOLUMES.    * 16900021
*                                                                     * 17000021
* EXITS, ERROR -                                                      * 17100021
*         IFG0552X - TO ISSUE ANSI ACCESSABILITY MESSAGE IEC017I A    * 17200021
*                    (-2) AND THEN CLOSE THE DATA SET.                * 17300021
*         REFER TO THE PRECEEDING MODULE PROLOG.                      * 17400021
*                                                                     * 17500021
* TABLES/WORK AREAS -                                                 * 17600021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 17700021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 17800021
*                                                                     * 17900021
* ATTRIBUTES -                                                        * 18000021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 18100021
*                                                                     * 18200021
* CHARACTER CODE DEPENDENCY -                                         * 18300021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 18400021
*                                                                     * 18500021
* NOTES -                                                             * 18600021
*                                                                     * 18700021
*********************************************************************** 18800021
         EJECT                                                          18900021
*                                                                       19300021
*********************************************************************** 19450000
*              POSITION NEW VOLUME TO FIRST DATA RECORD               * 19460000
*********************************************************************** 19470000
*                                                                       19480000
ETI28200 EQU   *                                                  99223 19490000
         LA    RD,EABD191               LOAD INTERNAL ERROR CODE  99223 19492000
         MVC   DXCCW1,AFSFCCW8          INITLZ CCW FOR FSF COMMAND99223 19494000
         TM    DCBOFLGS,DCBORDBK         DCB OPENED FOR 'RDBACK'- 99223 19496000
         BNO   ETI28240                 ..BR IF NOT TO ISSUE FSF  99223 19498000
         MVI   DXCCW1,CCWBSF            INITLZ CCW FOR BSF COMMAND99223 19498400
ETI28240 EQU   *                                                  99223 19498800
         BAL   RC,ETI30700              GO TO TO POSITION TAPE    99223 19499200
         BNO   ETI30800                 BR IF I/O ERROR           99223 19499600
         MVI   DXCCW1,CCWNOP            INITLZ CCW FOR 'NOP' COM  99223 19499700
         BAL   RC,ETI30700              BR TO WAIT FOR DEVICE END 99223 19499800
         BO    ETI28250                 BR IF NO I/O ERROR        99223 19499900
         TM    IOBSENS1,UCBLDPT         IS TAPE AT 'LOAD POINT'-  99223 19533200
         BNO   ETI30800                 ..BR IF NOT TO ERR RTN    99223 19543200
*                                       ..ELSE DROP THROUGH       99223 19553200
*********************************************************************** 19563200
*              TEST FOR DATA SET SECURITY                             * 19565200
*********************************************************************** 19565600
ETI28250 EQU   *                                                  99223 19566000
         TM    JFCBLTYP,JFCBAL          WERE ANSI LABELS SPECIFIED-     19566700
         BZ    ETI28300                 ..BR IF NOT- TEST SL SECURITY   19600021
*                                                                       19700021
*****          PERFORM SECURITY TESTS FOR AN ANSI ( AL ) DATA SET       19800021
*                                                                       19900021
         CLI   FL1FSEC,BLANK            IS ACCESSIBILITY LIMITED-       20000021
         BE    ETI28900                 ..BR IF NOT TO CONTINUE         20100021
         CLI   FL1FSEC,FL1SECTY         IS SECURITY FOR READ AND WRITE- 20200021
         BE    ETI28300                 ..BR IF YES TO TEST DEB FOR     20300021
*                                       ..PREVIOUS AUTHORIZATION        20400021
*                                                                       20500021
*****          THE ANSI DATA SET LABEL CONTAINS AN INVALID SECURITY     20600021
*****          INDICATOR- XCTL TO ISSUE ACCESSIBILITY MESSAGE           20700021
*****          IEC017I A ( -2 ) AND TO CLOSE THE DATA SET               20800021
*                                                                       20900021
         LA    RF,MOD2X3H               PT TO ID/TTR OF EOD MODULE      21000021
         LA    RET,K12                  BR TABLE OFFSET FOR THAT MOD    21100021
         B     ETI30100                 BR TO XCTL TO CLOSE DCB         21200021
*                                                                       21300021
*****          CONTINUE SECURITY TESTS FOR SL AND AL DATA SETS          21400021
*                                                                       21500021
ETI28300 EQU   *                                                        21600021
         TM    DCBOFLGS,DCBOCON         IS CONCATENATION TAKING PLACE-  21700021
         BNO   ETI28600                 ..BR IF NOT                     21800021
         NI    DEBFLGS1,X'FF'-DEBPWCKD  CLEAR THE 'PASSWORD      M0038  21900021
*                                       ..CHECKED' INDICATOR            22000021
ETI28600 EQU   *                                                        22100021
         CLI   FL1FSEC,FL1SECTY         IS SECURITY FOR READ AND WRITE- 22200021
         BE    ETI28700                 ..BRANCH IF YES TO GET PASSWORD 22300021
         CLI   FL1FSEC,FL1WRSEC         IS SECURITY FOR WRITE ONLY-     22400021
         BNE   ETI28900                 ..BR IF NOT TO CONTINUE         22500021
*                                                                       22600021
*****          A PASSWORD IS REQUIRED IF THE USER HAS OPENED FOR        22700021
*****          'INOUT' AND THE DATA SET IS PROTECTED FOR OUTPUT         22800021
*                                                                       22900021
         TM    DEBOPATB,DEBOPOUT-DEBOPRBK IS THIS INPUT OR READBACK-    23000021
         BZ    ETI28900                 ..BRANCH IF YES                 23100021
*                                       ..MODE IS 'INOUT'- GET PASSWORD 23200021
ETI28700 EQU   *                                                        23300021
         TM    DEBFLGS1,DEBPWCKD        HAS PSWD BEEN CHECKED-   M0038  23400021
         BO    ETI28900                 ..BR IF YES TO CONTINUE         23500021
*                                                                       23600021
*****          XCTL TO CHECK PASSWORD                                   23700021
*                                                                       23800021
         NI    DCBOFLGS,X'FF'-DCBOCON   TURN OFF CONCATENATION IND      23900021
         MVC   DXXMODNM(K8),IFG0195T    MOVE SECURITY MODULE NAME INTO  24000021
*                                       ..XCTL WORK AREA                24100021
         MVC   DXXIDTTR(K2),IFG0195T+K6  SET ID IN DXXIDTTR     SA62427 24150021
         SR    RET,RET                  BR TBL OFFSET FOR SECURITY MOD  24200021
         B     ETI30650                 BR- XCTL TO CHECK PASSWD M0110  24300021
*                                                                       24400021
*****          RETURN ADDRESS AFTER SUCCESSFULLY CHECKING THE PASSWORD  24500021
*                                                                       24600021
ETI28800 EQU   *                                                        24700021
         AIF   ('&LIB' NE 'LIB1').LIB23H1                               24750000
         L     RDEB,DCBDEBAD            RESTORE THE DEB ADDRESS         24800021
.LIB23H1 ANOP                                                           24850000
         AIF   ('&LIB' EQ 'LIB1').LIB13H1                               24860000
         L     RDEB,DXPDEBAD            RESTORE THE DEB ADDRESS  Y01021 24870000
.LIB13H1 ANOP                                                           24880000
         TITLE 'IFG0553H - EOV TAPE INPUT VOLUME MOUNT-AHEAD FUNCTION'  24900021
*********************************************************************** 25000021
*                                                                     * 25100021
*                          FUNCTION PROLOG                            * 25200021
*                                                                     * 25300021
*********************************************************************** 25400021
*                                                                     * 25500021
* FUNCTION NAME -                                                     * 25600021
*    'EOV TAPE INPUT VOLUME MOUNT-AHEAD FUNCTION'                     * 25700021
*                                                                     * 25800021
* (STATUS) -                                                          * 25900021
*    NOT APPLICABLE                                                   * 26000021
*                                                                     * 26100021
* FUNCTION -                                                          * 26200021
*    1. SEARCH FOR THE NEXT REQUIRED, OR MOUNT-AHEAD, VOLUME ON ALL   * 26300021
*       OF THE UNITS WHICH ARE ALLOCATED TO THE DATA SET. THE SEARCH  * 26400021
*       BEGINS WITH THE SECOND UNIT IN THE TIOT, SINCE THE FIRST UNIT * 26500021
*       CONTAINS THE VOLUME ON WHICH PROCESSING WILL CONTINUE WHEN    * 26600021
*       EOV EXITS TO THE CALLER.                                      * 26700021
*    2. IF THE VOLUME IS NOT MOUNTED BUT AN EMPTY UNIT IS AVAILABLE,  * 26800021
*       ISSUE MOUNT MESSAGE 'IEC001E M' FOR THE DESIRED VOLUME.       * 27000021
*    3. IF AN EMPTY UNIT IS NOT AVAILABLE, THE FIRST UNIT WITH A      * 27100021
*       DEMOUNTABLE (I.E., UNRESERVED) VOLUME IS SELECTED, THE VOLUME * 27200021
*       IS UNLOADED AND A RETAIN MESSAGE IS ISSUED. MOUNT MESSAGE     * 27300021
*       IEC001E M IS THEN ISSUED FOR THE DESIRED VOLUME.              * 27350021
*       MOUNT MESSAGE IEC001E M IS THEN ISSUED FOR THE DESIRED VOLUME.* 28100021
*    4. IF THE OPTIONAL TRACE FACILITY WAS ACTIVE, TRANSFER CONTROL   * 28200021
*       TO THE TRACE TERMINATION FUNCTION TO TERMINATE THAT FACILITY. * 28300021
*    5. RELEASE THE RESIDENT ROUTINE MAIN STORAGE WORK AREA (ECBLIST).* 28400021
*    6. IF THE ACCESS METHOD IS EXCP, RELEASE THE END-OF-VOLUME MAIN  * 28500021
*       STORAGE WORK AREA AND EXIT TO THE USER.                       * 28600021
*    7. IF THE ACCESS METHOD IS BSAM OR QSAM, TRANSFER CONTROL TO THE * 28700021
*       ACCESS METHOD EXECUTOR.                                       * 28800021
*                                                                     * 28900021
* ENTRY POINTS -                                                      * 29000021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 29100021
*                                                                     * 29200021
* INPUT -                                                             * 29300021
*    1. REGISTER CONTENTS AT ENTRY ARE AS FOLLOWS-                    * 29400021
*       'RDCB' - ADDRESS OF THE DCB BEING PROCESSED;                  * 29500021
*       'RCORE'- ADDRESS OF THE WORK AREA FOR THAT DCB;               * 29600021
*       'RES'  - ADDRESS OF THE OPEN/CLOSE/EOV RESIDENT ROUTINE;      * 29700021
*       'RWTG' - ADDRESS OF THE WHERE-TO-GO TABLE;                    * 29800021
*       'RPARC'- ADDRESS OF THE EOV PSEUDO PARAMETER LIST ENTRY;      * 29900021
*       'RWTGC'- ADDRESS OF THE CURRENT WHERE-TO-GO TABLE ENTRY;      * 30000021
*       'RTIOT'- ADDRESS OF THE CURRENT TIOT ENTRY FOR THE DCB;       * 30100021
*       'RUCB' - ADDRESS OF THE CURRENT UCB FOR THE DCB;              * 30200021
*       'RDEB' - ADDRESS OF THE DCB'S DEB;                            * 30300021
*                                                                     * 30400021
* OUTPUT -                                                            * 30500021
*    1. AT EXIT TO IFG0550P (PROBLEM DETERMINATION)-                  * 30540021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 30580021
*          REGISTER 'R0' WILL CONTAIN ONE OF THE FOLLOWING INTERNAL   * 30620021
*          ERROR CODES (THE CORRESPONDING ABEND AND RETURN CODES ARE  * 30660021
*          INDICATED IN PARENTHESES)-                                 * 30700021
*          193 (637/48)- ERROR UNLOADING THE 'MOUNT-AHEAD' UNIT.      * 30740021
*       WORK AREA INDICATORS-                                         * 30780021
*          'DXCALLID' - CONTAINS THE 2-BYTE ID OF THIS MODULE.        * 30820021
*    2. AT EXIT TO IFG0551L (ACCESS METHOD EXECUTOR)-                 * 30900021
*          REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT     * 31000021
*             REGISTER 'RES' NO LONGER POINTS TO THE RESIDENT ROUTINE.* 31100021
*          CONTROL BLOCK INDICATORS-                                  * 31200021
*             'DCBOFLGS' - X'20', OFF - INDICATES THAT CONCATENATION  * 31300021
*                                       HAS BEEN COMPLETED.           * 31400021
*    3. AT EXIT TO IFG0552P (EOV TAPE MESSAGE-WRITING MODULE)-        * 31500021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 31600021
*          REGISTER 'RET' CONTAINS ONE OF THE FOLLOWING RETURN        * 31700021
*          BRANCH TABLE OFFSETS-                                      * 31800021
*             4 - RETURN FROM ISSUING MESSAGE IEC003E R.              * 31900021
*             8 - RETURN FROM ISSUING MOUNT MESSAGE IEC001E M.        * 32100021
*       WORK AREA INDICATORS-                                         * 32200021
*          MESSAGE BUFFER- CONTAINS ANY OF MESSAGES IEC001E M         * 32300021
*                          OR IEC003E R AND THE                       * 32400021
*                          APPROPRIATE VOLUME SERIAL NUMBER.          * 32500021
*          'DXCCW7+1' - 0 - INDICATES THAT THE DATA SET NAME FROM     * 32600021
*                           THE JFCB IS TO BE USED IF THE DATA SET    * 32700021
*                           NAME IS REQUIRED IN THE MESSAGE;          * 32800021
*          'DXRETMOD' - CONTAINS THE 5-BYTE ID/TTR OF THIS MODULE;    * 32900021
*    4. AT EXIT TO IFG0559R (TRACE INITIATION/TERMINATION MODULE)-    * 33000021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT AS FOLLOWS- * 33100021
*          'RWTGC'- CONTAINS A '1', INDICATING UPON RETURN FROM THE   * 33200021
*                   TRACE TERMINATION FUNCTION THAT THE TRACE         * 33300021
*                   FACILITY WAS ACTIVE.                              * 33400021
*          'RET'  - CONTAINS A RETURN BRANCH TABLE OFFSET OF '12'.    * 33500021
*       WORK AREA INDICATORS-                                         * 33600021
*          'DXXENTRY' - CONTAINS THE 5-BYTE ID/TTR OF THIS MODULE.    * 33700021
*          'DXXPATHS+1' - X'80', OFF - INDICATES THAT THE TRACE       * 33800021
*                                      FACILITY IS TO BE TERMINATED.  * 33900021
*    5. AT EXIT TO THE USER-                                          * 34000021
*       CONTROL BLOCK INDICATORS-                                     * 34100021
*          DCBOFLGS' - X'20', OFF - INDICATES THAT CONCATENATION      * 34200021
*                                   HAS BEEN COMPLETED.               * 34300021
*                      X'01', OFF - INDICATES THAT PROCESSING BY AN   * 34400021
*                                   I/O SUPPORT FUNCTION (EOV) HAS    * 34500021
*                                   BEEN COMPLETED.                   * 34600021
*                                                                     * 34700021
* EXTERNAL REFERENCES -                                               * 34800021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 34900021
*                                                                     * 35000021
* EXITS, NORMAL -                                                     * 35100021
*         IFG0551L - TO FINISH EOV PROCESSING WHEN THE ACCESS METHOD  * 35200021
*                    IS BSAM OR QSAM.                                 * 35300021
*         IFG0552P - TO ISSUE A 'MOUNT' OR 'RETAIN' MESSAGE.          * 35400021
*         IFG0559R - TO TERMINATE THE OPTIONAL TRACE FACILITY.        * 35600021
*         USER     - UPON COMPLETION OF EOV PROCESSING WHEN THE       * 35700021
*                    ACCESS METHOD IS EXCP.                           * 35800021
*                                                                     * 35900021
* EXITS, ERROR -                                                      * 36000021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 36100021
*                                                                     * 36200021
* TABLES/WORK AREAS -                                                 * 36300021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 36400021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 36500021
*                                                                     * 36600021
* ATTRIBUTES -                                                        * 36700021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 36800021
*                                                                     * 36900021
* CHARACTER CODE DEPENDENCY -                                         * 37000021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 37100021
*                                                                     * 37200021
* NOTES -                                                             * 37300021
*                                                                     * 37400021
*********************************************************************** 37500021
         EJECT                                                          37550021
*                                                                       37600021
ETI28900 EQU   *                                                        37700021
         CLI   DXNOUNIT+1,K1            IS ONLY ONE DEVICE ALLOCATED-   37800021
         BE    ETI30200                 ..BR IF YES- ALL DONE           37900021
         LA    RET,DXVOLSR2             LD ADDR OF CURRENT VOL SER NO.  38000021
         TM    DCBOFLGS,DCBORDBK        IS THE DCB OPENED FOR 'RDBACK'- 38100021
         BO    ETI29100                 ..BR IF YES TO RDBACK RTN       38200021
         AH    RET,CONST60D             UPDATE THE VOLUME SERIAL NO.    38300021
*                                       ..POINTER                       38400021
         CLC   JFCBNVOL(K1),DEBTVLSQ+K1  ARE THERE MORE VOLUMES SA69185 39300021
         BE    ETI30200                 ..BR IF NOT- ALL DONE           39400021
         B     ETI29200                 ..ELSE BR TO TEST FOR SER NO.   39500021
ETI29100 EQU   *                                                        39600021
         SH    RET,CONST60D             UPDATE VOLUME SERIAL POINTER    39700021
         LH    RC,DEBTVLSQ              SET UP THE CURRENT SEQ. NUMBER  39800021
         BCT   RC,ETI29200              TEST FOR ADD'L VOLUMES AND BR   39900021
*                                       ..TO PROCESS THEM IF THEY EXIST 40000021
         B     ETI30200                 ..ELSE PROCESSING IS COMPLETE   40100021
ETI29200 EQU   *                                                        40200021
         CLI   K0(RET),K0               ARE THERE ADD'L VOLUMES TO MT-  40300021
         BE    ETI30200                 ..BR IF NOT- ALL DONE           40400021
         CLI   K0(RET),BLANK            ARE THERE ADD'L VOLUMES TO MT-  40500021
         BE    ETI30200                 ..BR IF NOT- ALL DONE           40600021
*                                                                       40700021
*********************************************************************** 40800021
*              MOUNT-AHEAD IF A UNIT IS AVAILABLE AND A VOLUME IS     * 40900021
*              INDICATED FOR ONE VOLUME AHEAD OF THE VOLUME           * 41000021
*              CURRENTLY BEING PROCESSED.                             * 41100021
*********************************************************************** 41200021
*                                                                       41300021
*****          DETERMINE IF THE DESIRED VOLUME IS ALREADY MOUNTED       41400021
*                                                                       41500021
         ST    RET,DXCCW6               SAVE ADDR OF MT-AHEAD VOL       41600021
         LH    RD,DXNOUNIT              LOAD NO. OF UNITS ALLOC         41700021
         SR    RC,RC                    ZERO INDEX TO UCB ADDRS         41800021
ETI29300 EQU   *                                                        41900021
         L     RUCB,TIOESTTB(RC)        LOAD UCB ADDR FROM TIOT         42000021
         CLC   SRTEVOLI,K0(RET)         IS THE DESIRED VOLUME MOUNTED-  42100021
         BE    ETI30200                 ..BR IF YES- POS COMPLETE       42200021
         LA    RC,K4(,RC)               ADVANCE INDEX IN  TIOT          42300021
         BCT   RD,ETI29300              DECREMENT THE COUNT OF THE NO.  42400021
*                                       ..OF UNITS- BR IF MORE EXIST    42500021
*                                                                       42600021
*****          THE DESIRED VOLUME IS NOT MOUNTED-                       42700021
*****          DETERMINE IF AN EMPTY UNIT IS AVAILABLE                  42800021
*                                                                       42900021
         LH    RD,DXNOUNIT              LOAD NO. OF UNITS ALLOCATED     43000021
         LA    RC,K4                    INITLZ INDEX TO UCB(2)          43100021
         BCTR  RD,0                     DECR NO. UNITS BY 1             43200021
ETI29400 EQU   *                                                        43300021
         L     RUCB,TIOESTTB(RC)        LOAD UCB ADDR FROM TIOT         43400021
         CLI   SRTEVOLI,K0              IS THE UNIT EMPTY-              43500021
         BNE   ETI29500                 ..BRANCH IF NOT                 43600021
         TM    SRTEDMCT,UCBDMC          IS DM USE COUNT 0       SA47382 43650021
         BNZ   ETI29500                 BR NO, CONTINUE         SA47382 43660021
         TM    SRTESTAT,SRTERESV        IS THIS UNIT RESERVED-          43700021
         BZ    ETI29700                 ..BR IF NOT- USE THIS UNIT      43800021
ETI29500 EQU   *                                                        43900021
         LA    RC,K4(,RC)               ADVANCE INDEX IN TIOT           44000021
         BCT   RD,ETI29400              DECREMENT THE COUNT OF THE NO.  44100021
*                                       ..OF UNITS- BR IF MORE EXIST    44200021
*                                                                       44300021
*****          THERE ARE NO EMPTY UNITS-                                44400021
*****          FIND A UNIT WITH A DISMOUNTABLE VOLUME                   44500021
*                                                                       44600021
         LH    RD,DXNOUNIT              LOAD NO. OF UNITS ALLOC         44700021
         LA    RC,K4                    SET INDEX TO UCB(2)             44800021
         BCTR  RD,0                     DECR NO. UNITS BY 1             44900021
ETI29600 EQU   *                                                        45000021
         L     RUCB,TIOESTTB(RC)        LOAD UCB ADDR FROM TIOT         45100021
         TM    SRTEDMCT,UCBDMC          IS DM USE COUNT 0       SA47382 45150021
         BNZ   ETI29650                 BR NO, CONTINUE         SA47382 45160021
         TM    SRTESTAT,SRTERESV        IS THIS UNIT RESERVED-          45200021
         BZ    ETI29700                 ..BR IF NOT- USE THIS ONE       45300021
         LA    RC,K4(,RC)               ADVANCE INDEX IN TIOT           45400021
*                                                               SA47382 45450021
ETI29650 EQU   *                                                SA47382 45460021
         BCT   RD,ETI29600              DECREMENT THE COUNT OF THE NO.  45500021
*                                       ..OF UNITS- BR IF MORE EXIST    45600021
         B     ETI30200                 ..ELSE BR- ALL DONE             45700021
ETI29700 EQU   *                                                        45800021
         ST    RUCB,DXCCW7              SET UP UCB ADDRESS IN           45900021
         MVC   DXDEBUCB+1(K3),DXCCW7+1  ..WORK AREA DEB                 46000021
         TM    UCBFL2,UCBNOTRD          IS THIS UNIT READY-             46100021
         BO    ETI29900                 ..BR IF NOT TO MOUNT VOLUME     46200021
         CLI   SRTEVOLI,K0              IS A VOLUME MOUNTED-            46300021
         BE    ETI29900                 ..BR IF NOT TO MOUNT VOLUME     46400021
*                                                                       46500021
*****          REWIND/UNLOAD THE VOLUME ON THE MOUNT-AHEAD UNIT         46600021
*****          AND ISSUE THE APPROPRIATE DEMOUNT MESSAGE                46700021
*                                                                       46800021
         AR    RC,RTIOT                 CALCULATE ADDRESS OF THIS TIOT  46900021
         NI    TIOESTTB-TIOENTRY(RC),X'FF'-TIOSUSED  TURN OFF THE 'DATA 47000021
*                                       ..SET ON THIS UNIT' INDICATOR   47100021
         MVC   DXCCW1(K8),CCWRUN8       INITLZ CCW FOR 'REWIND/UNLOAD'  47200021
         LA    RD,EABD193               LOAD INTERNAL ERROR CODE        47300021
         BAL   RC,ETI30700              BR AND LINK TO UNLOAD VOLUME    47400021
         OI    UCBFL2,UCBNOTRD          SET UCB TO 'NOT READY'          47500021
         MVC   MCSFLAGS(K12),RETMSG3H   MOVE RETAIN MSG INTO BUFFER     47600021
         MVC   MSGVOLSR,SRTEVOLI        MOVE VOL SER NO. INTO BUFFER    47700021
         XC    SRTEVOLI,SRTEVOLI        ZERO UCB VOLUME SERIAL NO.      47800021
         XC    UCBSQC(K6),UCBSQC        ZERO UCB DATA SET SERIAL NO.    47900021
         LA    RET,K4                   BR TABLE OFFSET FOR RETURN      48000021
         B     ETI30000                 BR TO XCTL TO WTO MODULE        49100021
*                                                                       49200021
*****          ISSUE MOUNT MESSAGE FOR THE MOUNT-AHEAD VOLUME AND UNIT  49300021
*                                                                       49400021
ETI29900 EQU   *                                                        49500021
         L     RET,DXCCW6               LOAD ADDR OF MT-AHEAD VOLUME    49600021
*                                       ..FROM SAVE AREA                49700021
         MVC   MCSFLAGS(K12),MTFLAGS    MOVE IN MOUNT MESSAGE           49800021
         MVC   MSGVOLSR(MVOLL),K0(RET)  MOVE SERIAL NO.INTO MSG         49900021
         OI    SRTEDMCT,UCBMOUNT        SET UCB MOUNT INDICATOR         50000021
         XC    SRTEFSCT(K2),SRTEFSCT    ZERO UCB FILE SEQ NO.           50100021
         MVC   SRTEVOLI,K0(RET)         MOVE VOL SER INTO UCB           50200021
         LA    RET,K8                   BR TABLE OFFSET FOR RETURN      50300021
ETI30000 EQU   *                                                        50400021
         LA    RF,MODWTO3H              PT TO ID/TTR OF WTO MODULE      50500021
         MVC   DXRETMOD(K5),MOD3H3H     MOVE RET ID/TTR INTO SAVE AREA  50600021
         EJECT                                                          50700021
*********************************************************************** 50800021
*              EXITS                                                  * 50900021
*********************************************************************** 51000021
*                                                                       51100021
*****          XCTL VIA THE RESIDENT ROUTINE                            51130021
*                                                                       51160021
ETI30100 EQU   *                                                        51200021
         IECRES XCTL,(RF),(RET)         INVOKE IECRES MACRO TO 'XCTL'   51300021
         SPACE 2                                                        51400021
*                                                                       51500021
*****          EXIT TO USER OR ACCESS METHOD EXECUTOR                   51600021
*                                                                       51700021
ETI30200 EQU   *                                                        51800021
         NI    DCBOFLGS,X'FF'-DCBOCON   TURN OFF CONCATENATION IND      51900021
*                                                                       52000021
*****          PERFORM TRACE FACILITY TERMINATION IF REQUIRED           52100021
*                                                                       52200021
         LA    RWTGC,K0                 SET INTERNAL SW TO IND THAT THE 52300021
*                                       ..TRACE FACILITY IS NOT ACTIVE  52400021
         TM    DXXPATHS+1,WTGTRACE      IS THE TRACE FACILITY ACTIVE-   52500021
         BNO   ETI30300                 ..BR IF NOT                     52600021
         LA    RWTGC,K1                 SET INTERNAL SW TO IND THAT THE 52700021
*                                       TRACE FACILITY IS ACTIVE        52800021
         NI    DXXPATHS+1,X'FF'-WTGTRACE  IND TO THE TRACE ROUTINE      52900021
*                                       ..THAT TERMINATION IS REQUIRED  53000021
         LA    RF,MOD9R3H               PT TO TRACE TERMINATION  M0110  53060021
*                                       ..MODULE ID/TTR          M0110  53120021
         MVC   DXXENTRY(K5),MOD3H3H     MOVE RET ID/TTR INTO SAVE AREA  53200021
         LA    RET,K12                  LOAD BR TABLE OFFSET FOR RETURN 53300021
         B     ETI30500                 BR TO XCTL                      53400021
*                                                                       53500021
*****          RELEASE THE RESIDENT ROUTINE WORK AREA (ECBLIST)         53600021
*                                                                       53700021
ETI30300 EQU   *                                                        53800021
         L     R1,DXXECBAD              LOAD THE ADDRESS OF THE ECB LST 53900021
         LA    R0,K8                    LD THE LENGTH OF THE ECB LIST   54000021
         LTR   RWTGC,RWTGC              WAS THE TRACE FACILITY ACTIVE-  54100021
         BZ    ETI30400                 ..BR IF NOT TO FREE ECB LIST    54200021
         SR    R1,R0                    PT TO ECBLIST PREFIX     M0110  54300021
         AR    R0,R0                    ACCT FOR PREFIX LENGTH   M0110  54400021
ETI30400 EQU   *                                                        54500021
         FREEMAIN R,LV=(0),A=(1)        RELEASE THE ECBLIST MAIN STG    54600021
         EJECT                                                          54650021
*                                                                       54700021
*****          DETERMINE APPROPRIATE EXIT                               54800021
*                                                                       54900021
         TM    DCBMACRF,DCBMEXCP        IS THE ACCESS METHOD EXCP-      55000021
         BNZ   ETI30600                 ..BR IF YES TO EXIT             55100021
*                                                                       55200021
*****          EXIT TO THE ACCESS METHOD EXECUTOR                       55300021
*                                                                       55400021
         LA    RF,MOD1L3H               PT TO EXECUTOR ID/TTR    M0110  55440021
*                                                                       55480021
*****          XCTL BY TTR                                              55520021
*                                                                       55560021
ETI30500 EQU   *                                                        55600021
         MVC   DXXMODID,K0(RF)          MOVE MODULE ID INTO NAME M0110  55620021
         MVC   DXXTTR,K2(RF)            MOVE MODULE TTR INTO     M0110  55640021
*                                       ..PSEUDO BLDL LIST       M0110  55660021
         AIF   ('&LIB' EQ 'LIB1').LIB13HY                               55670000
         SR    R0,R0                    ZERO WORK REG            XM8246 55680000
         IC    R0,K5(RF)                GET MODULE LENGTH        XM8246 55690000
         SLL   R0,K11                   SHIFT LEFT 11 BITS       XM8246 55692000
         ST    R0,DXXMODSZ              STORE LENGTH AND         XM8246 55694000
         MVC   DXXTXTLN,DXXMODSZ+K1     SIZE IN WTG TABLE        XM8246 55696000
.LIB13HY ANOP                                                           55698000
         LA    RF,DXXCTL                POINT TO XCTL WORK AREA         55700021
         LA    R0,DXXMODNM              POINT TO XCTL NAME              55800021
         XCTL  DE=(R0),SF=(E,(15))      ISSUE XCTL BY TTR        M0110  55860021
         SPACE 2                                                        55920021
*                                                                       56000021
*****          RETURN TO USER                                           56100021
*                                                                       56200021
ETI30600 EQU   *                                                        56300021
         AIF   ('&LIB' EQ 'LIB1').LIB13H2                               56350000
         L     RF,CVTPTR                GET CVT ADDR             Y01018 56360000
         USING CVT,RF                   DEFINE CVT BASE          Y01018 56370000
         TM    CVTDCB,CVT4MS1           MVT SYSTEM?              Y01018 56380000
         BNO   ETI30625                 NO, BR TO IGNORE DEQ     Y01018 56390000
         L     RF,CVTTCBP-CVT(,RF)      GET TCB ADDR             Y01018 56392000
         L     RF,K4(,RF)               GET CURRENT TCB ADDR     Y01018 56394000
         USING TCB,RF                   DEFINE TCB BASE          Y01018 56396000
         TM    TCBTSFLG,TCBTSTSK        TSO TASK?                Y01018 56398000
         BNO   ETI30625                 NO, BR TO IGNORE DEQ     Y01018 56398400
         TM    DXXPATHS+K1,WTGTSENQ     WAS ENQ SUCCESSFUL?      Y01018 56399600
         BZ    ETI30625                 NO, BR TO IGNORE DEQ     Y01018 56399800
         MVC   DXXAREA(ETI3097L),ETI3090K                        Y01018 56400000
         DEQ   (DXXAREA+ETI3095K-ETI3090K,                       Y01018*56409700
               DXXAREA+ETI3096K-ETI3090K),MF=(E,DXXAREA)         Y01018 56419700
ETI30625 EQU   *                                                 Y01018 56424900
.LIB13H2 ANOP                                                           56433200
         LR    R1,RCORE                 PT TO BEGINNING OF EOV WK AREA  56466700
         LA    R0,EOVSIZE               LOAD SIZE OF EOV WORK AREA      56500021
         FREEMAIN R,LV=(0),A=(1)        RELEASE EOV WORK AREA CORE      56600021
         NI    DCBOFLGS,X'FF'-DCBOBUSY  RESET I/O SUPPORT BIT           56700021
         SVC   SVCEXIT                  RETURN TO CALLER                56800021
         SPACE 2                                                        56810021
*                                                                       56820021
*****          XCTL BY NAME                                             56830021
*                                                                       56840021
ETI30650 EQU   *                                                 M0110  56850021
         LA    RF,DXXCTL                POINT TO XCTL WORK AREA  M0110  56860021
         LA    R0,DXXMODNM              POINT TO XCTL NAME       M0110  56870021
         XCTL  EPLOC=(R0),SF=(E,(15))   ISSUE XCTL BY NAME       M0110  56880021
         EJECT                                                          56890021
         SPACE 2                                                        56900021
*********************************************************************** 57000021
*              SUBROUTINES                                            * 57100021
*********************************************************************** 57200021
*                                                                       57300021
*****          CLOSED SUBROUTINE TO PERFORM I/O OPERATIONS              57400021
*****          ENTRY TO THE SUBROUTINE IS VIA A 'BAL  RC,ETI30700'      57500021
*                                                                       57600021
ETI30700 EQU   *                                                        57700021
         EXCP  DXIOB                    PERORM I/O OPERATION            57800021
         IECRES WAIT                    INVOKE IECRES MACRO TO 'WAIT'   57900021
         TM    DXECB,ECBNOERR           TEST FOR AN I/O ERROR-          58000021
         BCR   1,RC                     ..BR IF NOT- RETURN TO CALLER   58100021
         TM    IOBSENS1,UCBLDPT         IS TAPE AT LOAD POINT (BOT)-    58200021
         BCR   1,RC                     ..BR IF YES- RETURN TO CALLER   58300021
*                                       ..ELSE DROP THROUGH TO ERR RTN  58400021
         SPACE 2                                                        58500021
*********************************************************************** 58600021
*              ERROR PROCESSING                                       * 58700021
*********************************************************************** 58800021
*                                                                       58900021
ETI30800 EQU   *                                                        59000021
         DMABCOND (RD),ABEND3H          EXIT TO PROB DETERMINATION RTN  59100021
         SPACE 2                                                        59200021
*********************************************************************** 59300021
*              CONSTANTS                                              * 59400021
*********************************************************************** 59500021
*                                                                       59600021
         AIF   ('&LIB' EQ 'LIB1').LIB13H3                               59650000
ETI3090K DEQ   (,,4,STEP),RET=HAVE,MF=L                          Y01018 59660000
ETI3095K DC    CL8'SYSTIOT'             QNAME FOR DEQ            Y01018 59670000
ETI3096K DC    C'TIOT'                  RNAME FOR DEQ            Y01018 59680000
ETI3097L EQU   *-ETI3090K                                        Y01018 59690000
IFG055NM DC    C'IFG055'                PREFIX FOR XCTL  (EOV)   YM3271 59690400
.LIB13H3 ANOP                                                           59692000
AFSFCCW8 CCW   X'3F',0,X'20',1          FORWARD SPACE FILE              59700021
CCWRUN8  DC    X'0F00000020000001'      CCW FOR REWIND AND UNLOAD       59800021
EOVIND   DC    X'01000000'              EOV INDICATOR                   59900021
CONST10D DC    X'0001'                  HALFWORD CONSTANT OF 1          60100021
CONST60D DC    X'0006'                  HALFWORD CONSTANT OF 6          60200021
IFG0195T DC    C'IFG0195T'              NAME OF THE SECURITY MODULE     60300021
MTFLAGS  DC    X'8000'                  MCS FLAGS FOR MOUNT-AHEAD MSGS  60700021
         DC    C'IEC001E M '            BASIC MOUNT-AHEAD MESSAGE       60800021
RETMSG3H DC    X'8000'                  MCS FLAGS FOR RETAIN MESSAGE    60900021
         DC    C'IEC003E R '            BASIC RETAIN MESSAGE            61000021
         EJECT                                                          61300021
*********************************************************************** 61400021
*              XCTL TABLE                                             * 61500021
*********************************************************************** 61600021
*                                                                       61700021
XCTLTB3H XCTLTABL ID=(ABEND3H,0P,MOD1L3H,1L,MODWTO3H,2P,MOD2X3H,2X,    C61800021
               MOD2Z3H,2Z,MOD3H3H,3H,MOD9R3H,9R),SVC=055                61900021
         SPACE 2                                                        62000021
         IECDSECS CVT,                                                 C62100021
               TCB,                                                    C62200021
               RB,                                                     C62300021
               TIOT,                                                   C62400021
               DCB,                                                    C62500021
               DEB,                                                    C62600021
               UCB,                                                    C62700021
               MAIN,                                                   C62800021
               WTG,                                                    C62900021
               EXPAND=YES                                               63000021
         IECEQU ,                       INVOKE OPEN/CLOSE/EOV EQUATES   63100021
         SPACE 2                                                        63200021
         END                                                            63300021
