         TITLE ' EOV MOUNT NEW VOLUME VERIFICATION (2321) - IFG0553R'   00200000
         COPY  LCGASMSW                                                 00400000
*********************************************************************** 00800000
*                                                                     * 01000000
*                                                                     * 01200000
*           RELEASE 25 DELETIONS/CHANGES                              * 01400000
*           RELEASE 24 DELETIONS/CHANGES                              * 01600000
*           RELEASE 23 DELETIONS/CHANGES                              * 01800000
*           RELEASE 22 DELETIONS/CHANGES                              * 02000000
*           RELEASE 21.7 DELETIONS/CHANGES                            * 02050001
*0000720000,724000                                              SA56453 02100001
*0000542000,698000-700000,734000-754000                         SA61315 02160001
*           RELEASE 21 DELETIONS/CHANGES                              * 02200000
*0000404000                                                      A37815 02250021
*0000828000                                                      M0190  02300021
*                                                                     * 02400000
* STATUS CHANGE LEVEL 000                                             * 02600000
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 02800000
*                                                                     * 03000000
* FUNCTION -                                                          * 03200000
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 03400000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S) FOR DETAILS.          * 03600000
*                                                                     * 03800000
* ENTRY POINTS -                                                      * 04000000
*         IFG0553R                                                    * 04200000
*                                                                     * 04400000
* INPUT -                                                             * 04600000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 04800000
*                                                                     * 05000000
* OUTPUT -                                                            * 05200000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05400000
*                                                                     * 05600000
* EXTERNAL REFERENCES -                                               * 05800000
*         IFG055RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 06000000
*            WAIT. '--' REFERS TO THE TWO DIGITS IN THE SAME POSITION * 06200000
*            IN THIS MODULE'S NAME.                                   * 06400000
*         REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                * 06600000
*                                                                       06800000
* EXITS, NORMAL -                                                     * 07000000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 07200000
*                                                                     * 07400000
* EXITS, ERROR -                                                      * 07600000
*    EXIT IS TO THE PROBLEM DETERMINATION MODULE IFG0550P, IF AN      * 07800000
*    ABEND SITUATION OCCURS IN THIS MODULE.  REFER TO THE FOLLOWING   * 08000000
*    'FUNCTION PROLOG(S)'.  '--' REFERS TO THE DIGITS IN THE SAME     * 08200000
*    POSITION IN THIS MODULE'S NAME.                                  * 08400000
*                                                                     * 08600000
* TABLE/WORK AREA -                                                   * 08800000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 09000000
*                                                                     * 09200000
* ATTRIBUTES -                                                        * 09400000
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 09600000
*                                                                     * 09800000
* CHARACTER CODE DEPENDENCY -                                         * 10000000
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 10200000
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 10400000
*    DIFFERENT CHARACTER SET IS USED FOR EXECTION.                    * 10600000
*                                                                     * 10800000
* NOTES -                                                             * 11000000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 11200000
*                                                                     * 11400000
*********************************************************************** 11600000
          EJECT                                                         11800000
*********************************************************************** 12000000
*                                                                     * 12200000
*                           FUNCTION PROLOG                           * 12400000
*                                                                     * 12600000
*********************************************************************** 12800000
*FUNCTION/OPERATION  PERFORMS NEW VOLUME MOUNTING AND VOLUME LABEL    * 13000000
*   VERIFICATION.  FIRST DETERMINES WHETHER VOLUME IS ALREADY MOUNTED.* 13200000
*   IF MOUNTED, VERIFY VOLUME LABEL.  IF A MOUNT MESSAGE HAS BEEN     * 13400000
*   ISSUED, VERIFY THAT CORRECT VOLUME IS MOUNTED.  IF LABEL NOT      * 13600000
*   VERIFIED, CONTROL IS GIVEN TO IFG0554J TO ISSUE MOUNT MESSAGE.    * 13800000
*                                                                     * 14000000
*ENTRY POINTS- IFG0553R:.                                             * 14200000
*              FROM IFG0553P OR IFG0554J VIA THE RESIDENT ROUTINE.    * 14400000
*                                                                     * 14600000
*INPUT: THE FOLLOWING REGISTERS HAVE BEEN SET UP UPON ENTRY           * 14800000
*   REGISTER   2 -  ADDRESS OF THE USER'S DCB                         * 15000000
*   REGISTER   4 -  ADDRESS OF THE WORK AREA (SEE BELOW)              * 15200000
*   REGISTER   5 -  ADDRESS OF THE RESIDENT ROUTINE                     15400000
*   REGISTER   6 -  ADDRESS START OF XCTL/WTG TABLE                     15600000
*   REGISTER   8 -  ADDRESS OF CURRENT ENTRY WTG TABLE                  15800000
*   REGISTER   9 -  CURRENT ENTRY IN THE TIOT                         * 16000000
*   REGISTER  10 -  ADDRESS OF UCB CURRENTLY PROCESSING               * 16200000
*   REGISTER  11 -  ADDRESS OF USER'S DEB                               16400000
*   REGISTER  14 -  RETURN ADDRESS / ENTRY INDICATOR                  * 16600000
*   UPON ENTRY,IT IS ALSO ASSUMED THAT THE WORK AREA CONTROL          * 16800000
*   BLOCKS (DCB,DEB AND IOB) ARE SET UP.ALSO THE JFCB HAS BEEN        * 17000000
*   READ INTO THE WORK AREA.                                          * 17200000
*                                                                     * 17400000
*OUTPUT: NONE OF THE INPUT REGISTERS SPECIFIED UNDER INPUT ABOVE      * 17600000
*   HAVE BEEN MODIFIED.THE CORRECT VOLUME TO BE NEXT PROCESSED HAS    * 17800000
*   BEEN MOUNTED AND THE UCB'S IN THE TIOT ENTRY HAVE BEEN REARRANGED * 18000000
*   SO THAT THE NEW UNIT IS IN THE FIRST UCB SLOT OF THE TIOT ENTRY   * 18200000
*                                                                     * 18400000
*EXTERNAL ROUTINES: IECPRLTV  MBBCCHHR TO TTR CONVERSION              * 18600000
*   THE FOLLOWING SVC'S MAY ALSO BE ISSUED                            * 18800000
*        EXCP - READ THE VOLUME LABEL                                 * 19000000
*        ABEND  ABNORMALLY TERMINATE (SEE EXITS-ERROR)                * 19200000
*                                                                     * 19400000
*EXITS-NORMAL   TO IFG0553V - CONTINUE END OF VOLUME PROCESS            19600000
*               TO IFG0554J - ISSUE MOUNT MESSAGE.                *     19800000
*     -ERROR :ABEND ISSUED WITH ERROR CODES                           * 20000000
*                   166  -  NO UNIT AVAILABLE TO MOUNT REQUIRED VOL   * 20200000
*                   167 - I/O ERROR WHILE READING VOLUME LABEL        * 20400000
*                                                                     * 20600000
         AIF   ('&LIB' NE 'LIB1').LIB23R0                               20650000
*TABLES/WORK AREAS- A 536 BYTE WORK AREA IS USED TO PERFORM READING OF* 20800000
*   VOLUME LABEL.INCLUDED IN THE AREA ARE A SKELETON DCB,DEB,IOB,CCW'S* 21000000
*   ETC..CONSULT THE DSECT LABELED FORCORE FOR FURTHER DETAIL         * 21200000
*                                                                     * 21400000
.LIB23R0 ANOP                                                           21410000
         AIF   ('&LIB' EQ 'LIB1').LIB13R0                               21420000
*TABLES/WORK AREAS- A 544 BYTE WORK AREA IS USED TO PERFORM READING OF* 21450000
*   VOLUME LABEL.INCLUDED IN THE AREA ARE A SKELETON DCB,DEB,IOB,CCW'S* 21500000
*   ETC..CONSULT THE DSECT LABELED FORCORE FOR FURTHER DETAIL         * 21550000
*                                                                     * 21560000
.LIB13R0 ANOP                                                           21570000
*ATTRIBUTES: REENTRANT,REUSEABLE,PRIVILEGED,ENABLED                   * 21600000
*                                                                     * 21800000
*NOTES : A ONE SENTENCE DESCRIPTION PRECEDES EACH NEW FUNCTION        * 22000000
*   WHICH IS PERFORMED.                                               * 22200000
*                                                                     * 22400000
*********************************************************************** 22600000
IFG0553R CSECT                                                          22800000
ERR166   EQU   166                      ABEND CODE                      23000000
ERR167   EQU   167                      ABEND CODE                      23200000
*********************************************************************** 23400000
***      DIRECT ACCESS INPUT END OF VOLUME LOAD                         23600000
*********************************************************************** 23800000
         BALR  RBASE,0                  ESTABLISH ADDRESSABILITY        24000000
         USING FORCORE,RCORE                                            24200000
         USING TIOENTRY,RTIOT                                           24400000
         USING UCB,RC                                                   24600000
         USING UCBDCELL,RUCB                                            24800000
         USING DEB,RDEB                                                 25000000
         USING IHADCB,RDCB                                              25200000
         USING *,RBASE                                                  25400000
         AIF   ('&LIB' NE 'LIB1').LIB23R1                               25450000
         L     RDEB,DCBDEBAD            ADDRESS OF USER DEB             25600000
.LIB23R1 ANOP                                                           25650000
         AIF   ('&LIB' EQ 'LIB1').LIB13R1                               25700000
         L     RDEB,DXPDEBAD            ADDRESS OF USER DEB      Y01021 25750000
.LIB13R1 ANOP                                                           25760000
         B     EDI02100(RET)            BRANCH ACCORDING TO RETURN CODE 25800000
EDI02100 EQU   *                                                        26000000
         B     EDI02200                 BR TO CONTINUE EOV PROCESSING   26200000
         B     EDI03800                 BR IF RETURING FROM MESS MOD    26400000
*                                                                       26600000
*****    VOLUME SEARCHER                                                26800000
*                                                                       27000000
*                        SEARCHING PERFORMED IN FOLLOWING ORDER         27200000
*                             1.IS VOLUME ALREADY MOUNTED               27400000
*                             2.HAS A MOUNT MESSAGE BEEN ISSUED         27600000
*                             3.IS THERE A UNIT WITH NO VOLUME MOUNTED  27800000
*                             4.IS THERE A VOLUME WHICH MAY BE DISMOUNT 28000000
         SPACE 1                                                        28200000
EDI02200 EQU   *                        MOUNT NEXT VOLUME AND VERIFY IF 28400000
*                       NOT ALREADY DONE                                28600000
*                                                                       28800000
         LA    R1,K1                    SET L=1                         29000000
         SR    R7,R7                    SET INDEX REGISTER TO ZERO      29200000
EDI02300 L     RUCB,TIOESTTB(R7)        UPDATE OF UCB REGISTER          29400000
         BAL   RF,EDI03500              SET RC POINT TO MAIN UCB        29600000
*                                                                       29800000
*                   IS V(N+1) ON SRT(L)                                 30000000
*                                                                       30200000
         CLC   UCBDVOLI(K6),DXVOLSR2    COMPARE SRT AND JFCB VOL        30400000
         BE    EDI02800                 GO TO VOL FOUND ON SRT(L)       30600000
*                                                                       30800000
*                   IS LAST SRT - L =J                                  31000000
*                                                                       31200000
         BAL   RF,EDI03600              CHECK FOR LAST ENTRY            31400000
         BNE   EDI02300                 IF NOT LAST ENT,GO CHECK NEXT   31600000
         SPACE 1                                                        31800000
*                   SEE IF UNIT ON WHICH MOUNT MESSAGE HAS BEEN ISSUED  32000000
         SPACE 1                                                        32200000
         SR    R7,R7                    CLEAR WORK REGISTER             32400000
         LA    R1,K1                    COUNTER TO SAY ONE UNIT CHECK   32600000
EDI02400 L     RUCB,TIOESTTB(R7)        PICK UP THE NEXT UCB IN TIOT    32800000
         BAL   RF,EDI03500              SET RC POINT TO MAIN UCB        33000000
         TM    UCBDDMCT,UCBMOUNT        HAS A MOUNT MESSAGE BEEN ISSUED 33200000
         BO    EDI02800                 YES,GO VERIFY IT IS CORRECT     33400000
         BAL   RF,EDI03600              CHECK FOR LAST ENTRY            33600000
         BNE   EDI02400                 IF NOT LAST ENT,GO CHECK NEXT   33800000
         SPACE 1                                                        34000000
*                   SEE IF THERE IS A UNIT WITH NO VOLUME MOUNTED       34200000
         SPACE 1                                                        34400000
         SR    R7,R7                    CLEAR WORK REGISTER             34600000
         LA    R1,K1                    SET COUNTER, ONE UNIT CHECKED   34800000
EDI02500 L     RUCB,TIOESTTB(R7)        PICK UP THE NEXT UCB IN TIOT    35000000
         BAL   RF,EDI03500              SET RC POINT TO MAIN UCB        35200000
         CLC   UCBDVOLI,AZEROS9I        A VOLUME MOUNTED ON THIS UNIT   35400000
         BE    EDI02800                 NO,GO TO ISSUE MOUNT MESSAGE    35600000
         BAL   RF,EDI03600              CHECK FOR LAST ENTRY            35800000
         BC    6,EDI02500               IF NOT LAST ENTRY,GO CHECK NEXT 36000000
         SPACE 1                                                        36200000
*                   IS THERE A VOLUME WHICH MAY BE DISMOUNTED           36400000
         SPACE 1                                                        36600000
         SR    R7,R7                    CLEAR WORK REGISTER             36800000
         LA    R1,K1                    LOAD ONE IN R1                  37000000
EDI02600 L     RUCB,TIOESTTB(R7)        GET NEXT UCB                    37200000
         BAL   RF,EDI03500              SET RC POINT TO MAIN UCB        37400000
         TM    UCBDSTAT,UCBRESV+UCBPRES+UCBSYSR  RESV,SYSR,PM,RES       37600000
*                                       IS DEVICE RESERVED              37800000
         BC    5,EDI03300               YES, CANNONT DISMOUNT           38000000
         TM    UCBDSTAB,UCBBSVL         IS THIS A SHARE VOLUME          38200000
         BZ    EDI03300                 YES, CANNOT DISMOUNT            38400000
         CLI   UCBDDMCT,K0              IS IT MORE THAN 1 USER          38600000
         BH    EDI03300                 GO TO MORE THAN ONE USER        38800000
         CLC   K60(K6,RUCB),DXVOLSR1                                    39000000
*                                       PREVIOUSLY PROCESSED VOLUME     39200000
         BNE   EDI02700                 NO,BRANCH                       39400000
         TM    K12(RDEB),K4             IS THIS UPDATE MODE             39600000
         BZ    EDI02700                 NO BRANCH                       39800000
         TM    K12(RDEB),DEBOPOUT-DEBOPUPD  TEST UPDATE FURTHER         40000000
         BNZ   EDI02700                 BRANCH,NOT UPDATE               40200000
         TM    DCBMACRF,DCBMEXCP        IS THIS AN EXCP DCB-     A37815 40300021
         BO    EDI02700                 BR IF YES- NO IOB ADDR   A37815 40400021
         L     R8,DCBIOBA               LOAD ADDR OF IOB PREFIX  A37815 40500021
         TM    K0(R8),K4                IS THIS A SPAN VOLUME           40600000
*                                       RECORD                          40800000
         BZ    EDI02700                 BRANCH IF NOT                   41000000
         CH    R1,DXNOUNIT              IS THIS THE ONLY UNIT           41200000
         BNE   EDI03300                 BRANCH IF NOT                   41400000
EDI02700 EQU   *                                                        41600000
         OI    UCBFL1,UCBNOTRD          INDICATE UNIT IS NOT READY      41800000
*                                                                       42000000
*****    AVAILABLE UNIT FOUND                                           42200000
*                                                                       42400000
*                                                                       42600000
*        EXCHANGE SRT(L) WITH SRT(1)                                    42800000
*                                                                       43000000
EDI02800 SR    RET,RET                  CLEAR WORK REGISTER             43200000
         AIF   ('&LIB' NE 'LIB1').LIB23R2                               43250000
         SSM   *+K1                     DISABLE / DMCT                  43400000
.LIB23R2 ANOP                                                           43450000
         AIF   ('&LIB' EQ 'LIB1').LIB13R2                               43500000
         MODESET ENABLE=NO              DISABLE                  Y01082 43550000
.LIB13R2 ANOP                                                           43560000
         IC    RET,UCBDDMCT             PICK UP CURRENT NUM OF USERS OF 43600000
         LA    RET,1(,RET)              THIS VOL AND ADD 1 TO REFLECT   43800000
         STC   RET,UCBDDMCT             THAT THIS DCB USES THIS UNIT    44000000
         AIF   ('&LIB' NE 'LIB1').LIB23R3                               44050000
         SSM   CLENAB0I                 ENABLE  / DMCT                  44200000
.LIB23R3 ANOP                                                           44250000
         AIF   ('&LIB' EQ 'LIB1').LIB13R3                               44300000
         MODESET ENABLE=YES             ENABLE                   Y01082 44350000
.LIB13R3 ANOP                                                           44360000
         L     R1,TIOESTTB              PICK UP THE PREVIOUS UNIT       44400000
         ST    R1,TIOESTTB(R7)          STORE SRT(1) ON SRT(L)          44600000
         ST    RUCB,TIOESTTB            STORE SRT(L) ON SRT(1)          44800000
         BAL   RF,EDI03500              UPDATE UCB ADDRESS              45000000
         ST    RC,DXCCW11               STORE  UCB ADDRESS              45200000
         MVC   DXDEBUCB+K1(K3),DXCCW11+K1  MOVE UCB ADDR TO WORK DEB    45400000
         MVC   DXDEBBIN(K2),UCBDBBNR    MOVE BIN NUMBER TO WORK DEB     45600000
*                                                                       45800000
*****    VOLUME LABEL READER                                            46000000
*                                                                       46200000
         CLC   DXVOLSR2(K6),UCBDVOLI    IS  CORRECT VOL SER             46400000
         BE    EDI03100                 YES,VOLUME LABEL ALREADY READ   46600000
         TM    UCBFL1,UCBNOTRD          IS THE UNIT IN READY STATUS     46800000
         BZ    EDI03000                 YES,DO NOT ISSUE MOUNTING MESSA 47000000
EDI02900 EQU   *                                                        47200000
         MVC   MCSFLAGS(K12),FLAG12I    MOUNT MSG                       47400000
         MVC   MSGVOLSR+K2,DXVOLSR2     VOLUME SERIAL NO. TO MESSAGE    47600000
         OI    UCBFL1,UCBNOTRD          SET UCB NOT READY               47800000
         B     EDI03700                 GO WTO                          48000000
*                                                                       48200000
*        SETTING UP AND EXECUTING VOL LABEL READING CHANEL PROGRAM      48400000
*                                                                       48600000
*        SETTING UP                                                     48800000
*                                                                       49000000
*        ID TO SEARCH                                                   49200000
*                                                                       49400000
EDI03000 MVC   DXDAADDR(K8),COLCVT9I    MOVE ID INTO DUMMY ID ADDR      49600000
         MVC   DXDAADDR+K1(K2),UCBDBBNR  MOVE BB TO DUMMY               49800000
*                                                                       50000000
*                                                                       50200000
*                                                                       50400000
*   THE FOLLOWING SUBROUTINE SETS UP A CHANNEL PROGRAM TO READ          50600000
*   THE DSCB OR VOLUME LABEL INTO THE WORK AREA.  THE LENGTH AND        50800000
*   COMMAND CODE ARE LEFT BLANK, TO BE SET BY CALLER, IN THIRD CCW.     51000000
*                                                                       51200000
*                   SEARCH ID EQUAL   IOBDADAD+3  CC,SILI   5           51400000
*                   TIC               *-8         -         -           51600000
*                   ---               WORKAREA    -         -           51800000
         XC    DXCCW1(K24),DXCCW1       CLEAR THREE CCW'S               52000000
         LA    R0,DXDAADDR+K3           ADDRESS OF IOBDADAD+K3          52200000
         ST    R0,DXCCW1                SEARCH ADDR IN CCW1             52400000
         LA    R0,DXCCW1                ADDR SEARCH CCW                 52600000
         ST    R0,DXCCW2                PUT IN CCW2                     52800000
         ST    RCORE,DXCCW3             WORKAREA ADDR IN CCW3           53000000
         MVI   DXCCW1,CCWSCHID          SEARCH ID COMMAND CODE          53200000
         MVC   DXCCW1+K4(K5),ACCW10I    REST OF CCW1 AND TIC COMMAND    53400000
         MVI   DXCCW3+K7,X'50'          EIGHTY CHARACTERS               53600000
         MVI   DXCCW3,CCWRDDA           READ DATA OPERATION CODE        53800000
*                                                                       54000000
         EXCP  DXIOB                    READ VOLUME LABEL       SA61315 54050001
*                                                                       54100001
         IECRES WAIT                    WAIT FOR COMPLETION     SA61315 54150001
         LA    R8,REPLY+K4              PTR TO MSG ID           SA61315 54200001
         DOM   MSGLIST=(8)              DELETE THE MSG          SA61315 54250001
         TM    DXECB,ALLBITS-DCBMEXCP   WAS THERE AN I/O ERROR  SA61315 54350001
         BNO   EDI04000                 I/O ERROR-ABEND 737             54400000
         CLC   DXVOLSR2(K6),VOLSERNO    VOLSER IN LABEL CORRECT         54600000
         BC    6,EDI02900               NO, REISSUE MOUNTING MESSAGE    54800000
         MVC   UCBDVOLI(K6),VOLSERNO    PUT VOLSERNO IN SRT (1)         55000000
*                                                                       55200000
*****    CONVERTING THE VTOC ADDRESS IN VOL LABEL TO TTR FOR SRT(1)     55400000
*                                                                       55600000
         ST    RDCB,DXCCW7              SAVE DCB ADDRESS                55800000
         STM   RTIOT,RD,DXCCW8          SAVE REGISTERS                  56000000
*                                                                       56200000
*                   SET MBBCCHHR                                        56400000
*                                                                       56600000
         MVI   DXCCW5,K0                SET M=0                         56800000
         MVC   DXCCW5+K3(K5),VOLVTOC    SET UP CCHHR OF THE VTOC        57000000
         LA    R1,DXDEB                 LOAD ADDR OF WORK DEB           57200000
         LA    RDCB,DXCCW5              LOAD MBBCCHHR ADDRESS           57400000
         L     RF,CVTPTR                ADDR OF COMM VECTOR TABLE       57600000
         L     RF,CVTPRLTV-CVT(RF)      ENTRY FOR MBBCCHHR TO TTR       57800000
         BALR  RET,RF                   MBBCCHHR TO TTR CONVERT ROUTINE 58000000
*                                                                       58200000
*                   PUT VTOC TTR INTO UCB                               58400000
*                                                                       58600000
         L     RDCB,DXCCW7              RESETING RDCB                   58800000
         LM    RTIOT,RD,DXCCW8          RESETING REGISTERS              59000000
         IC    R0,UCBDUSER              PICK UP NUMBER OF USERS         59200000
         ST    R0,UCBDVTOC              PLACE TTR OF VTOC INTO UCB      59400000
         NI    UCBDDMCT,UCBMAIN-UCBMOUNT  RESET MOUNT INDICATOR         59600000
         SPACE 1                                                        59800000
EDI03100 EQU   *                                                        60000000
         LA    RF,LOA2553V              ID/TTR OF NEXT MOD              60200000
         LA    RET,K0                   SET RETURN CODE TO ZERO         60400000
EDI03200 EQU   *                                                        60600000
         LA    RWTGC,DXXENTRY           CURRENT MODULE NAME             60800000
         LA    RWTG,DXXAREA             NEXT MODULE NAME                61000000
         IECRES XCTL,(RF),(RET)                                         61200000
         SPACE 1                                                        61400000
         SPACE 1                                                        61600000
*                                                                       61800000
*                   IS LAST SRT - L =J                                  62000000
*                                                                       62200000
EDI03300 CH    R1,DXNOUNIT              COMPARE VOLSER WITH NUMBER IN   62400000
*                                       JFCB                            62600000
         BNE   EDI03400                 BRANCH,IF NO                    62800000
         LA    R0,ERR166                ADDRESS OF ABEND CODE           63000000
         B     EDI04100                 GO TO NON AVAILABLE UNIT        63200000
*                                                                       63400000
*                   L = L+1                                             63600000
*                                                                       63800000
EDI03400 LA    R1,K1(,R1)               INCREMENT VOLSER NUMBER         64000000
         LA    R7,K4(,R7)               INCREMENT UCB INDEX REG         64200000
         B     EDI02600                 GO GET NEXT UCB IN TIOT         64400000
*                                                                       64600000
*        SET UP RC TO POINT TO MAIN UCB                                 64800000
*                                                                       65000000
EDI03500 EQU   *                                                        65200000
         LH    RC,UCBDBBNR              PICK UP BB                      65400000
         SLA   RC,K4                    TIMES SIXTEEN                   65600000
         LA    RC,UCBDCELL-UCBOB(RC)    SIXTEEN+BB+MAIN UCB LENGTH      65800000
         LCR   RC,RC                    NEGATE                          66000000
         AR    RC,RUCB                  MAIN UCB ADDRESS                66200000
         BR    RF                       RETURN TO CALLER                66400000
*                                                                     * 66600000
EDI03600 LH    R8,DXNOUNIT              NUMBER OF UNITS                 66800000
         CR    R8,R1                    HAVE ALL AVAILABLE UNITS        67000000
*                                       BEEN CHECKED                    67200000
         LA    R1,K1(,R1)               INCREMENT NO. OF UNITS CHECKED  67400000
         LA    R7,K4(,R7)               POINT TO NEXT UCB IN TIOT       67600000
         BR    RF                       RETURN TO CALLER                67800000
*                                                                     * 68000000
*                                                                     * 68200000
EDI03700 EQU   *                                                        68400000
         L     RB,DESCO912              MCS CODES FOR USE IN 554J       68600000
         MVC   MSGUN,UCBNAME            PICK UP UNIT NAME               68800000
         MVC   MSGUN+K4(K1),UCBDBBNR+K1 PICK UP BB                      69000000
         OI    MSGUN+K4,ZONEOF          CHANGE BIN NO. TO HEX           69200000
         MVI   MSGUN+K3,SLASH           SLASH FOLLOWS BIN NUM           69400000
         MVI   MSGUN+K5,COMMA           MOVE IN COMMA AFTER BIN NO.     69600000
         LA    R1,MSGLSTSZ              MSG PTR                         70200000
*                                                                       70400000
         LA    RF,LOA2554J              ADDRESS OF ID/TTR MODULE 4J     70600000
         MVC   DXRETMOD(K5),LOA2553R    RETURN ID/TTR TO WORK AREA      70800000
         LA    RET,K4                   SET RETURN CODE                 71000000
         B     EDI03200                 GO TO RESIDENT ROUTINE          71200000
*                                                                       71400000
*                                                                       71600000
EDI03800 EQU   *                                                        71800000
         CLI   MSGSERLO+K1,CHARA        WAS AMOUNT ISSUED               72200000
         BNE   EDI02200                 NO, DISMOUNT FROM 553P  SA56453 72400001
         MVI   DXCCW9,UCBMAIN           TURN ON DOM INDICATOR           72600000
         B     EDI03000                 CONTINUE                        72800000
*                                                                       73000000
*                                                                       73200000
*                                                                       75600000
*                                                                       75800000
*                   ABNORMAL END OF TASK                                76000000
*                        SET UP DATA MANAGEMENT COUNT SO THAT           76200000
*                             ABNORMAL CLOSE WILL DECREMENT             76400000
*                             THE COUNT CORRECTLY                       76600000
         SPACE 1                                                        76800000
EDI04000 EQU   *                                                        77000000
         LA    R0,ERR167                SET UP ABEND CODE               77200000
         SR    RET,RET                  CLEAR WORK REGISTER             77400000
         AIF   ('&LIB' NE 'LIB1').LIB23R4                               77450000
         SSM   *+K1                     DISABLE / DMCT                  77600000
.LIB23R4 ANOP                                                           77650000
         AIF   ('&LIB' EQ 'LIB1').LIB13R4                               77700000
         MODESET ENABLE=NO              DISABLE                  Y01082 77750000
.LIB13R4 ANOP                                                           77760000
         IC    RET,UCBDDMCT             PICK UP DMCT ON                 77800000
         BCTR  RET,K0                   NEW VOLUME AND SUBTRACT 1 SINCE 78000000
         STC   RET,UCBDDMCT             CLOSE HAS NO KNOWLEDGE OF THIS  78200000
EDI04100 EQU   *                                                        78400000
         LH    RUCB,DEBBINUM            PICK UP BB                      78600000
         SLA   RUCB,K4                  TIMES SIXTEEN                   78800000
         LA    RUCB,UCBDCELL-UCBOB(RUCB)  SIXTEEN+BB+MAIN UCB LENGTH    79000000
         AL    RUCB,DEBUCBAD            POINT TO SUB UCB                79200000
         IC    RET,UCBDDMCT             ADD ONE TO DM COUNT             79400000
         LA    RET,K1(,RET)             SINCE ABNORMAL CLOSE WILL SUBTR 79600000
         STC   RET,UCBDDMCT             ONE FROM THIS UCB WHEN IT GAINS 79800000
*                                       CONTROL                         80000000
         AIF   ('&LIB' NE 'LIB1').LIB23R5                               80050000
         SSM   CLENAB0I                 ENABLE  / DMCT                  80200000
.LIB23R5 ANOP                                                           80250000
         AIF   ('&LIB' EQ 'LIB1').LIB13R5                               80300000
         MODESET ENABLE=YES             ENABLE                   Y01082 80350000
.LIB13R5 ANOP                                                           80360000
         LA    RWTGC,DXXENTRY           CURRENT MODULE NAME             80400000
         LA    RWTG,DXXAREA             NEXT MODULE NAME                80600000
         DMABCOND (R0),LOAD0P           PROBLEM DETERMINATION MACRO     80800000
         DS    0F                       ON A FULLWORD BOUNDARY          81000000
DESCO912 DC    X'4000'                  MCS DESCRIPTOR CODE             81200000
         DC    X'1000'                  MCS ROUTING CODE         M0190  81300021
FLAG12I  DC    X'8000'                  FLAGS FOR MOUNT MESSAGE         81400000
MOUNTS9I DC    C'IEC001A M '            MOUNT MESSAGE                   81600000
         DS    0F                       ON A FULLWORD BOUNDARY          81800000
         AIF   ('&LIB' NE 'LIB1').LIB23R6                               81850000
CLENAB0I DC    X'FF'                    CONSTANT TO RE-ENABLE           82000000
.LIB23R6 ANOP                                                           82050000
ACCW10I  DC    X'6000000508'            SILI,COMMAND CHAIN,5 CHAR,TIC O 82200000
COLCDU0I DC    X'0000000000C700097FFF'  EXTENT TO COVER ENTIRE BIN      82400000
         DS    0F                                                       82600000
MCSDE2I1 DC    X'2000'                  MCS DESCRIPTOR CODE      M0190  82700021
         DC    X'1000'                  MCS ROUTING CODE         M0190  82800021
         DS    0F                       ON A FULLWORD BOUNDARY          83000000
AZEROS9I EQU   *                                                        83200000
COLCVT9I DC    X'0000000000000003'      ID FOR DUMMY DEB                83400000
         XCTLTABL ID=(LOA2553R,3R,LOA2553V,3V,LOA2554J,4J,             X83600000
               LOAD0P,0P),SVC=055                                       83800000
         IECDSECS CVT,TCB,TIOT,DCB,DEB,UCB,MAIN,EXPAND=YES              84000000
         IECEQU                                                         84200000
         END                                                            84400000
