         TITLE ' MOUNT NEXT VOLUME VERIFICATION NOT 2321-IFG0553T '     00200021
         COPY  LCGASMSW                                                 00400000
*********************************************************************** 00800021
*                                                                     * 01000021
*                                                                     * 01200021
*           RELEASE 25 DELETIONS/CHANGES                              * 01400021
*           RELEASE 24 DELETIONS/CHANGES                              * 01600021
*           RELEASE 23 DELETIONS/CHANGES                              * 01800021
*           RELEASE 22 DELETIONS/CHANGES                              * 02000021
*           RELEASE 21.8 DELETIONS/CHANGES                            * 02010000
*0000270000                                                     SA70836 02020000
*           RELEASE 21.7 DELETIONS/CHANGES                            * 02050001
*0000440000,488000,490000,492000                                SA56453 02100001
*           RELEASE 21 DELETIONS/CHANGES                              * 02200021
*                                                                A37815 02230021
*                                                                S21940 02260021
*0000508000,844000-846000                                        M0190  02300021
*                                                                     * 02400021
* STATUS CHANGE LEVEL 000                                             * 02600021
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 02800021
*                                                                     * 03000021
* FUNCTION -                                                          * 03200021
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 03400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S) FOR DETAILS.          * 03600021
*                                                                     * 03800021
* ENTRY POINTS -                                                      * 04000021
*         IFG0553T                                                    * 04200021
*                                                                     * 04400021
* INPUT -                                                             * 04600021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 04800021
*                                                                     * 05000021
* OUTPUT -                                                            * 05200021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05400021
*                                                                     * 05600021
* EXTERNAL REFERENCES -                                               * 05800021
*         IFG055RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 06000021
*            WAIT. '--' REFERS TO THE TWO DIGITS IN THE SAME POSITION * 06200021
*            IN THIS MODULE'S NAME.                                   * 06400021
*         REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                * 06600021
*                                                                       06800021
* EXITS, NORMAL -                                                     * 07000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 07200021
*                                                                     * 07400021
* EXITS, ERROR -                                                      * 07600021
*    EXIT IS TO THE PROBLEM DETERMINATION MODULE IFG0550P, IF AN      * 07800021
*    ABEND SITUATION OCCURS IN THIS MODULE.  REFER TO THE FOLLOWING   * 08000021
*    'FUNCTION PROLOG(S)'.  '--' REFERS TO THE DIGITS IN THE SAME     * 08200021
*    POSITION IN THIS MODULE'S NAME.                                  * 08400021
*                                                                     * 08600021
* TABLE/WORK AREA -                                                   * 08800021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 09000021
*                                                                     * 09200021
* ATTRIBUTES -                                                        * 09400021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 09600021
*                                                                     * 09800021
* CHARACTER CODE DEPENDENCY -                                         * 10000021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 10200021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 10400021
*    DIFFERENT CHARACTER SET IS USED FOR EXECTION.                    * 10600021
*                                                                     * 10800021
* NOTES -                                                             * 11000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 11200021
*                                                                     * 11400021
*********************************************************************** 11600021
          EJECT                                                         11800021
*********************************************************************** 12000021
*                                                                     * 12200021
*                          FUNCTION PROLOG                            * 12400021
*                                                                     * 12600021
*********************************************************************** 12800021
*FUNCTION/OPERATION                                                   * 13000021
*   THE NEXT VOLUME IS THEN MOUNTED (IF NOT ALREADY                   * 13200021
*   MOUNTED) AND VERIFIED.  EXIT IS THEN MADE VIA XCTL TO IFG0553V    * 13400021
*   ALL MESSAGES ARE ISSUED BY INTERFACING WITH IFG0554J.             * 13600021
*                                                                     * 13800021
*ENTRY POINTS - IFG0553T ENTRY IS VIA XCTL FROM IFGO553P OR FROM      * 14000021
*   IFG0554J AFTER MESSAGE IS ISSUED TO OPERATOR.                     * 14200021
*                                                                     * 14400021
*INPUT - THE FOLLOWING REGISTERS HAVE BEEN SET UP UPON ENTRY          * 14600021
*   REGISTER   2 -  ADDRESS OF THE USER'S DCB                         * 14800021
*   REGISTER   4 -  ADDRESS OF THE WORK AREA (SEE BELOW)              * 15000021
*   REGISTER   5 -  ADDRESS OF THE RESIDENT ROUTINE                     15200021
*   REGISTER   6 -  ADDRESS START OF XCTL/WTG TABLE                     15400021
*   REGISTER   8 -  ADDRESS OF CURRENT ENTRY WTG TABLE                  15600021
*   REGISTER   9 -  CURRENT ENTRY IN THE TIOT                         * 15800021
*   REGISTER  10 -  ADDRESS OF UCB CURRENTLY PROCESSING               * 16000021
*   REGISTER  11 -  ADDRESS OF USER'S DEB                               16200021
*   REGISTER  14 -  RETURN ADDRESS / ENTRY INDICATOR                  * 16400021
*   UPON ENTRY IT IS ALSO ASSUMED THAT THE WORK AREA CONTROL BLOCKS   * 16600021
*   (DCB,DEB, AND IOB) ARE SET UP.  ALSO THE JFCB HAS BEEN READ INTO  * 16800021
*   THE WORK AREA.                                                    * 17000021
*                                                                     * 17200021
*OUTPUT - NONE OF THE INPUT REGISTERS SPECIFIED UNDER INPUT ABOVE HAVE* 17400021
*   BEEN MODIFIED.  THE CORRECT VOLUME TO BE NEXT PROCESSED HAS BEEN  * 17600021
*   MOUNTED AND THE UCB'S IN THE TIOT ENTRY HAVE BEEN REARRANGED SO   * 17800021
*   THAT THE NEW UNIT IS IN THE FIRST UCB SLOT OF THE TIOT ENTRY.     * 18000021
*                                                                     * 18200021
*EXTERNAL ROUTINES - IECPRLTV MBBCCHHR TO TTR CONVERSION              * 18400021
*   THE FOLLOWING SVC'S MAY ALSO BE ISSUED                            * 18600021
*                 EXCP - READ THE VOLUME LABEL                        * 18800021
*                 ABEND- ABNORMALLY TERMINATE (SEE EXITS-ERROR)       * 19000021
*                                                                     * 19200021
*EXITS - NORMAL    TO IFG0553V - CONTINUE EOV PROCESSING              * 19400021
*                  TO IFGO554J - TO ISSUE MESSAGE TO OPERATOR     *   * 19600021
*      - ERROR    ABEND ISSUED WITH ERROR CODES                       * 19800021
*                 168 - NO UNIT AVAILABLE TO MOUNT REQUIRED VOLUME    * 20000021
*                 169 -                                               * 20200021
*                                                                     * 20400021
         AIF   ('&LIB' NE 'LIB1').LIB23T0                               20450000
*TABLES/WORK AREAS - A 536 BYTE WORK AREA IS USED TO PERFORM READING  * 20600021
*   OF VOLUME LABEL.  INCLUDED IN THE WORK AREA ARE A SKELETON DCB,   * 20800021
*   DEB,IOB,CCW'S,ETC..  CONSULT THE DSECT LABELED FORECORE FOR       * 21000021
*   FURTHER DETAIL.                                                   * 21200021
*                                                                     * 21400021
.LIB23T0 ANOP                                                           21410000
         AIF   ('&LIB' EQ 'LIB1').LIB13T0                               21420000
*TABLES/WORK AREAS - A 544 BYTE WORK AREA IS USED TO PERFORM READING  * 21450000
*   OF VOLUME LABEL.  INCLUDED IN THE WORK AREA ARE A SKELETON DCB,   * 21500000
*   DEB,IOB,CCW'S,ETC..  CONSULT THE DSECT LABELED FORECORE FOR       * 21550000
*   FURTHER DETAIL.                                                   * 21560000
*                                                                     * 21570000
.LIB13T0 ANOP                                                           21580000
*ATTRIBUTES - REENTRANT,REUSEABLE,PRIVILEGED,ENABLED                  * 21600021
*                                                                     * 21800021
*NOTES - A ONE SENTENCE DESCRIPTION PRECEDES EACH NEW FUNCTION WHICH  * 22000021
*   IS PERFORMED.                                                     * 22200021
*                                                                     * 22400021
*********************************************************************** 22600021
IFG0553T CSECT                          ************************        22800021
ERR168   EQU   168                                                      23000021
ERR169   EQU   169                                                      23200021
***********************************************************             23400021
*                                                                       23600021
*********************************************************************** 23800021
***      DIRECT ACCESS INPUT END OF VOLUME LOAD                         24000021
*********************************************************************** 24200021
         BALR  RBASE,0                  ESTABLISH ADDRESSABILITY        24400021
         USING FORCORE,RCORE                                            24600021
         USING TIOENTRY,RTIOT                                           24800021
         USING UCB,RUCB                                                 25000021
         USING DEB,RDEB                                                 25200021
         USING IHADCB,RDCB                                              25400021
         USING *,RBASE                                                  25600021
*                                                                       25800021
         AIF   ('&LIB' NE 'LIB1').LIB23T1                               25850000
         L     RDEB,DCBDEBAD            USER'S DEB ADDRESS              26000021
.LIB23T1 ANOP                                                           26050000
         AIF   ('&LIB' EQ 'LIB1').LIB13T1                               26100000
         L     RDEB,DXPDEBAD            USER'S DEB ADDRESS       Y01021 26110000
.LIB13T1 ANOP                                                           26150000
         B     EDI04200(RET)            BRANCH ACCORDING TO RETURN CODE 26200021
EDI04200 EQU   *                                                        26400021
         B     EDI04400                 CONTINUE EOV PROCESSING         26600021
EDI04300 EQU   *                                                        26800021
         CLC   MESSAGEA+K6(K1),MOUNTS9I+K6  WAS IT A MOUNT MSG  SA70836 27000000
         BE    EDI05200                 YES,GO READ VOLID               27200021
         L     RUCB,DXCCW2              NO,RESTORE UCB POINTER          27400021
         B     EDI05100                 GO SET-UP MOUNT MESSAGE         27600021
*                                                                     * 27800021
*****  VOLUME SEARCHER                                            ***** 28000021
*                                                                     * 28200021
*      SEARCH PERFORMED IN THE FOLLOWING ORDER -                      * 28400021
*                     1. IS VOLUME ALREADY MOUNTED                    * 28600021
*                     2. HAS A MOUNT MESSAGE BEEN ISSUED              * 28800021
*                     3. IS THERE A UNIT WITH NO VOLUME MOUNTED       * 29000021
*                     4. IS THERE A VOLUME WHICH MAY BE DISMOUNTED    * 29200021
EDI04400 EQU   *                                                        29400021
*                                                                     * 29600021
*****  MOUNT NEXT VOLUME AND VERIFY IF NOT ALREADY DONE           ***** 29800021
*                                                                     * 30000021
         LA    R1,K1                    SET L=1                         30200021
         SR    R7,R7                    SET INDEX REGISTER TO ZERO      30400021
EDI04500 L     RUCB,TIOESTTB(R7)        UPDATE OF UCB REGISTER          30600021
*                                                                     * 30800021
*****  IS V(N+1) ON SRT(L)                                        ***** 31000021
*                                                                     * 31200021
         CLC   UCBVOLI(K6),DXVOLSR2                                     31400021
*                                       COMPARE SRT AND JFCB VOL NO.    31600021
         BE    EDI05000                 GO TO VOL FOUND ON SRT(L)       31800021
*                                                                       32000021
*****  IS LAST SRT - L = J                                              32200021
*                                                                       32400021
*                                                                     * 32600021
*        CH    R1,DXNOUNIT              UNIT WITH MOUNT MESSAGE ISSUED  32800021
*****  L = L + 1                                                  ***** 33000021
*                                                                     * 33200021
         BAL   RF,EDI06100              GO TO COMPARE UNITS             33400021
         BNE   EDI04500                 IF NOT LAST ENTRY,GO CHECK NEXT 33600021
*                                                                     * 33800021
*****  SEE IF UNIT ON WHICH MOUNT MESSAGE HAS BEEN ISSUED         ***** 34000021
*                                                                     * 34200021
         SR    R7,R7                    CLEAR WORK REGISTER             34400021
         LA    R1,K1                    SET COUNTER TO SAY ONE UNIT     34600021
EDI04600 L     RUCB,TIOESTTB(R7)        PICK UP THE NEXT UCB IN TIOT    34800021
         TM    UCBDMCT,UCBMOUNT         HAS A MOUNT MESSAGE BEEN ISSUED 35000021
         BO    EDI05000                 YES,GO VERIFY IT IS CORRECT     35200021
*        CH    R1,DXNOUNIT              NO,HAVE ALL AVAILABLE UNITS     35400021
*                                       BEEN CHECKED                    35600021
         BAL   RF,EDI06100              GO TO COMPARE UNITS             35800021
         BNE   EDI04600                 IF NOT LAST ENT,GO CHECK NEXT   36000021
*                                       ENTRY                           36200021
*                                                                     * 36400021
*****  SEE IF THERE IS A UNIT WITH NO VOLUME MOUNTED              ***** 36600021
*                                                                     * 36800021
         SR    R7,R7                    CLEAR WORK REGISTER             37000021
         LA    R1,K1                    SET COUNTER TO SAY ONE UNIT     37200021
*                                       CHECKED                         37400021
EDI04700 L     RUCB,TIOESTTB(R7)        PICK UP THE NEXT UCB IN TIOT    37600021
         CLC   UCBVOLI,AZEROS9I         IS A VOL MOUNTED ON THIS UNIT   37800021
         BE    EDI05000                 NO,GO TO ISSUE MOUNT MESSAGE    38000021
*        CH    R1,DXNOUNIT              YES,HAVE ALL AVAILABLE UNITS    38200021
*                                       BEEN CHECKED                    38400021
         BAL   RF,EDI06100              GO TO COMPARE UNITS             38600021
         BC    K6,EDI04700              IF NOT LAST ENTRY,CHECK NEXT    38800021
*                                                                     * 39000021
*****  IS THERE A VOLUME WHICH MAY BE DISMOUNTED                  ***** 39200021
*                                                                     * 39400021
         SR    R7,R7                    CLEAR WORK REGISTER             39600021
         LA    R1,K1                    LOAD ONE IN RF                  39800021
EDI04800 L     RUCB,TIOESTTB(R7)        UPDATE OF UCB REGISTER          40000021
         TM    UCBSTAT,UCBRESV+UCBSYSR+UCBPRES                          40200021
*                                       RESRV,SYSRES,PM RES             40400021
         BC    K5,EDI05400              BRANCH                          40600021
         TM    UCBSTAB,UCBBSVL          IS THIS A SHARED VOLUME         40800021
         BZ    EDI05400                 YES,CANNOT DISMOUNT             41000021
         CLI   UCBDMCT,K0               IS IT MORE THAN ONE USER        41200021
         BH    EDI05400                 GO TO MORE THAN ONE USER        41400021
         CLC   K28(K6,RUCB),DXVOLSR1                                    41600021
*                                       PREVIOUSLY PROCESSED VOL        41800021
         BNE   EDI04900                 BRANCH IF VOL IS NOT LAST       42000021
         TM    K12(RDEB),K4             IS THIS UPDATE MODE             42200021
         BZ    EDI04900                 BRANCH IF NO                    42400021
         TM    K12(RDEB),DEBOPOUT-DEBOPUPD  IS THIS UPDATE MODE         42600021
         BNZ   EDI04900                 BRANCH IF NO                    42800021
*                                                                       42860021
         TM    DCBMACRF,DCBMEXCP        IS THIS AN EXCP DCB-     A37815 42920021
         BO    EDI04900                 ..BR IF YES- NO IOB ADDR A37815 42980021
*                                                                       43040021
         L     R8,DCBIOBA               LOAD ADDR OF IOB PREFIX  S21940 43100021
         TM    K0(R8),K4                IS THIS A SPAN VOL RECORD       43200021
         BZ    EDI04900                 BRANCH,LAST RECORD NOT SPAN     43400021
         CH    R1,DXNOUNIT              IS THIS THE ONLY UNIT           43600021
         BNE   EDI05400                 BRANCH IF MORE THAN 1 UNIT      43800021
EDI04900 EQU   *                                                SA56453 44000001
*                                                                     * 44200021
*****  AVAILABLE UNIT FOUND                                       ***** 44400021
*                                                                     * 44600021
*                                                                     * 44800021
*****  EXCHANGE SRT(L) WITH SRT(1)                                ***** 45000021
*                                                                     * 45200021
EDI05000 SR    RET,RET                  CLEAR WORK REGISTER             45400021
         AIF   ('&LIB' NE 'LIB1').LIB23T2                               45450000
         SSM   *+K1                     DISABLE TO INCREMENT DM COUNT   45600021
.LIB23T2 ANOP                                                           45650000
         AIF   ('&LIB' EQ 'LIB1').LIB13T2                               45700000
         MODESET ENABLE=NO              DISABLE                  Y01082 45750000
.LIB13T2 ANOP                                                           45760000
         IC    RET,UCBDMCT              PICK UP CURRENT NUMBER OF       45800021
         LA    RET,K1(K0,RET)           USER'S OF THIS VOLUME           46000021
         STC   RET,UCBDMCT              TO REFLECT THAT THIS DCB IS     46200021
         AIF   ('&LIB' NE 'LIB1').LIB23T3                               46250000
         SSM   CLENAB0I                 SET SYSTEM MASK                 46400021
.LIB23T3 ANOP                                                           46450000
         AIF   ('&LIB' EQ 'LIB1').LIB13T3                               46500000
         MODESET ENABLE=YES             ENABLE                   Y01082 46550000
.LIB13T3 ANOP                                                           46560000
*                                       USING THIS UNIT                 46600021
         L     R1,TIOESTTB              PICK UP THE PREVIOUS UNIT       46800021
         ST    R1,TIOESTTB(R7)          STORE SRT(1) ON SRT(L)          47000021
         ST    RUCB,TIOESTTB            STORE SRT(L) ON SRT(1)          47200021
         MVC   DXDEBUCB+K1(K3),TIOESTTB+K1                              47400021
*                                        UPDATE UCB ADDR IN DUMMY DEB   47600021
*                                                                     * 47800021
*****  VOLUME LABEL READER                                        ***** 48000021
*                                                                     * 48200021
         CLC   DXVOLSR2(K6),UCBVOLI     CORRECT VOLUME SER NO.          48400021
         BE    EDI05300                 YES,VOLUME LABEL ALREADY READ   48600021
         TM    UCBDMCT,UCBMOUNT         HAS A MOUNT MSG BEEN    SA56453 48800001
*                                       ISSUED                  SA56453 48850001
         BO    EDI05200                 YES,DO NOT ISSUE        SA56453 49000001
*                                       MOUNTING MSG                    49200001
*****  ISSUE RETAIN OPERATOR MESSAGE TO REMOVE THE VOLUME         ***** 49400021
*****  CURRENTLY MOUNTED.                                         ***** 49600021
*                                                                     * 49800021
         CLC   UCBVOLI,AZEROS9I         CHECK IF VALID VOL SER NO       50000021
         BE    EDI05100                 BR IF BINARY ZEROS              50200021
         MVC   MCSFLAGS(K12),FLAG19I    MOVE IN BASIC DISMNT MSG        50400021
         ST    RUCB,DXCCW2              SAVE CURRENT UCB PTR            50600021
         L     RB,MCSDE2I1              MCS CODES FOR USE IN 554J       51000021
         MVC   MSGVOLSR,UCBVOLI         PUT VOL SER ON UNIT IN MSG      51200021
         XC    UCBVOLI,UCBVOLI          CLEAR VOL SER IN UCB            51400021
         B     EDI05600                 GO ISSUE MOUNT MESSAGE          51600021
*                                                                     * 51800021
*****  ISSUE MOUNT MESSAGE TO MOUNT THE NEXT VOLUME               ***** 52000021
*                                                                     * 52200021
EDI05100 EQU   *                                                        52400021
         MVC   MCSFLAGS(K12),FLAG12I    MOVE IN BASIC MOUNT MESSAGE     52600021
         L     RB,DESCO912              MCS CODES FOR USE IN 554J       52800021
         MVC   MSGVOLSR,DXVOLSR2        DESIRED VOLUME SERIAL NO TO MSG 53000021
         OI    UCBFL1,UCBNOTRD          SET UCB NOT READY               53200021
         OI    UCBDMCT,UCBMOUNT         SET MOUNT BIT IN UCB            53400021
         B     EDI05600                 GO ISSUE DISMOUNT MSG           53600021
*                                                                     * 53800021
*****  SETTING UP AND EXECUTING VOL LABEL READING CHANNEL PROGRAM ***** 54000021
*****  SETTING UP ID TO SEARCH                                    ***** 54200021
*                                                                     * 54400021
EDI05200 MVC   DXDAADDR(K8),COLCVT9I                                    54600021
*                                                                       54800021
*                                       MOVE ID INTO DUMMY ID ADDR      55000021
*                                                                       55200021
*****  THE FOLLOWING SUBROUTINE SETS UP A CHANNEL PROGRAM TO READ ***** 55400021
*****  THE DSCB OR VOLUME LABEL INTO THE WORKAREA.  THE LENGTH AND***** 55600021
*****  COMMAND CODE ARE LEFT BLANK, TO BE SET BY CALLER, IN THIRD ***** 55800021
*****  CCW.                                                       ***** 56000021
*                                                                     * 56200021
*                   SEARCH ID EQUAL     IOBDADAD+3     C,SILI    5    * 56400021
*                   TIC                 *-8            -         -    * 56600021
*                   ---                 WORKAREA       -         -    * 56800021
*                                                                     * 57000021
         XC    DXCCW1(K24),DXCCW1       CLEAR 3 CCW'S                   57200021
         LA    R0,DXDAADDR+K3           ADDRESS OF IOBDADAD+3           57400021
         ST    R0,DXCCW1                SEARCH ADDR IN CCW1             57600021
         LA    R0,DXCCW1                ADDR SEARCH CCW                 57800021
         ST    R0,DXCCW2                PUT IN CCW2                     58000021
         ST    RCORE,DXCCW3             WORKAREA ADDR IN CCW3           58200021
         MVI   DXCCW1,CCWSCHID          SEARCH ID COMMAND CODE          58400021
         MVC   DXCCW1+K4(K5),ACCW10I                                    58600021
*                                       REST OF CCW1 AND TIC COMMAND    58800021
         MVI   DXCCW3+K7,K80            80 CHARACTERS                   59000021
         MVI   DXCCW3,CCWRDDA           READ DATA OPERATION CODE        59200021
*                                                                     * 59400021
*****  EXECUTING                                                  ***** 59600021
*                                                                     * 59800021
         BAL   RD,EDI05900              EXCP                            60000021
         BC    K14,EDI06200             BR IF I/O ERROR - ABEND 737     60200021
         CLC   DXVOLSR2(K6),VOLSERNO    VOLSER IN LABEL CORRECT         60400021
         BNE   EDI05100                 NO,GO TO REISSUE MOUNTING MSG   60600021
         MVC   UCBVOLI(K6),VOLSERNO                                     60800021
*                                       PUT VOLSERNO IN SRT(1)          61000021
*                                                                       61200021
*****  CONVERT THE VTOC ADDRESS IN VOL LABEL TO TTR FOR SRT(1)          61400021
*                                                                       61600021
         ST    RDCB,DXCCW7              SAVE DCB ADDRESS                61800021
         STM   RTIOT,RD,DXCCW8          SAVE REGISTERS                  62000021
*                                                                     * 62200021
*****  SET MBBCCHHR                                               ***** 62400021
*                                                                     * 62600021
         MVI   DXCCW5,K0                SET M=0                         62800021
         MVC   DXCCW5+K1(K2),DEBBINUM                                   63000021
*                                       SET BB                          63200021
         MVC   DXCCW5+K3(K5),VOLVTOC                                    63400021
*                                       SET UP CCHHR OF THE VTOC        63600021
         LA    R1,DXDEB                 ADDR OF WORK DEB TO PARAM REG   63800021
         LA    RDCB,DXCCW5              LOAD MBBCCHHR ADDRESS           64000021
         L     RF,CVTPTR                ADDR OF CVT                     64200021
         L     RF,CVTPRLTV-CVT(K0,RF)                                   64400021
*                                       ENTRY FOR MBBCCHHR TO TTR CONVT 64600021
         BALR  RET,RF                   GO TO MBBCCHHR TO TTR CNVRT RT  64800021
*                                                                     * 65000021
*****  PUT VTOC TTR INTO UCB                                      ***** 65200021
*                                                                     * 65400021
         L     RDCB,DXCCW7              RESETTING RDCB                  65600021
         LM    RTIOT,RD,DXCCW8          RESETTING REGISTERS             65800021
         ST    R0,UCBFSCT               PLACE TTR OF VTOC INTO VCB      66000021
         NI    UCBDMCT,UCBMAIN-UCBMOUNT RESET MOUNT INDICATOR           66200021
EDI05300 EQU   *                                                        66400021
         BAL   RET,EDI06400             SET UP RWTGC AND RWTG           66600021
         LA    RET,K0                   SET RETURN CODE TO ZERO         66800021
         LA    RF,LOA3553V              PTR TO ID/TTR MODULE 3V         67000021
         B     EDI05700                 XCTL TO NEXT MODULE             67200021
*                                                                     * 67400021
*****  IS LAST SRT - L = J                                        ***** 67600021
*                                                                     * 67800021
EDI05400 CH    R1,DXNOUNIT              COMPARE VOLSER WITH NO. IN JFCB 68000021
         BNE   EDI05500                 BRANCH IF NOT EQUAL             68200021
         LA    R0,ERR168                PUT INTERNAL ABEND CODE IN REG  68400021
*                                       FOR PROBLEM DETERMINATION       68600021
         B     EDI06300                 NON AVAILABLE UNIT              68800021
*                                                                     * 69000021
*****  L = L + 1                                                  ***** 69200021
*                                                                     * 69400021
EDI05500 LA    R1,K1(K0,R1)             INCREMENT VOLSER NO.            69600021
         LA    R7,K4(K0,R7)             INCREMENT UCB INDEX REG         69800021
         B     EDI04800                 GO GET NEXT UCB                 70000021
EDI05600 LA    R1,MSGLSTSZ              POINT TO MSG AREA               70200021
         BAL   RET,EDI06400             SET UP RWTGC AND RWTG           70400021
         LA    RF,LOA3554J              ADDRESS OF ID/TTR MODULE 4J     70600021
         LA    RET,K4                   RETURN CODE IS 4                70800021
         MVC   DXRETMOD(K5),LOA3553T    ID/TTR OF RETURN MODULE         71000021
EDI05700 EQU   *                                                        71200021
         IECRES XCTL,(RF),(RET)         TO RES FOR XCTL                 71400021
*                                                                     * 71600021
*****  THIS SUBROUTINE ISSUES I/O OPERATIONS                      ***** 71800021
*                                                                     * 72000021
EDI05900 EQU   *                                                        72200021
         EXCP  DXIOB                    EXECUTE CHANNEL PROGRAM         72400021
         BAL   RET,EDI06400             SET UP RWTGC AND RWTG           72600021
         IECRES WAIT                    WAIT FOR COMPLETION             72800021
         LTR   RDCB,RDCB                IS A DOM NEEDED                 73000021
         BNZ   EDI06000                 NO                              73200021
         LA    RDCB,REPLY+K4            PTR TO MSG ID TO BE DELETED     73400021
         DOM   MSGLIST=(2)              DELETE THE MSG                  73600021
         L     RDCB,K24(RDEB)           RESTORE DCB POINTER             73800021
EDI06000 EQU   *                                                        74000021
         TM    DXECB,ALLBITS-DCBMEXCP   WAS THERE AN I/O ERROR          74200021
         BR    RD                       RETURN TO CALLING POINT         74400021
*         CLOSE SUBROUTINE TO CHECK THE AVAILABLE UNITS        ******   74600021
*                                                                     * 74800021
EDI06100 EQU   *                                                        75000021
         LH    R8,DXNOUNIT              NUMBER OF UNIT IN WORKAREA      75200021
         CR    R8,R1                    COMPARE UNITS                   75400021
         LA    R1,K1(K0,R1)             INCREMENT NO. OF UNIT CHECKED   75600021
         LA    R7,K4(K0,R7)             POINT TO NEXT UCB IN TIOT       75800021
         BR    RF                       RETURN TO CALLER                76000021
*                                                                       76200021
*                                                                       76400021
*****  ABNORMAL END OF TASK                                       ***** 76600021
*****  SET UP DATA MANAGEMENT COUNT SO THAT ABNORMAL CLOSE WILL   ***** 76800021
*****  DECREMENT THE COUNT CORRECTLY                              ***** 77000021
*                                                                     * 77200021
EDI06200 SR    RET,RET                  CLEAR WORK REGISTER             77400021
         AIF   ('&LIB' NE 'LIB1').LIB23T4                               77450000
         SSM   *+K1                     DISABLE TO DECREMENT DATA  UL17 77600021
*                                       MANAGEMENT COUNT                77800021
.LIB23T4 ANOP                                                           77850000
         AIF   ('&LIB' EQ 'LIB1').LIB13T4                               77900000
         MODESET ENABLE=NO              DISABLE TO DECREMENT     Y01082 77950000
*                                       DATA MANAGEMENT COUNT           77960000
.LIB13T4 ANOP                                                           77970000
         IC    RET,UCBDMCT              PICK UP DATA MANAGEMENT COUNT   78000021
         BCTR  RET,K0                   ON NEW VOLUME AND SUBTRACT 1    78200021
         STC   RET,UCBDMCT              SINCE ABCLOSE HAS NO KNOWLEDGE  78400021
*                                       OF THIS VOLUME                  78600021
         LA    R0,ERR169                SET UP ABEND CODE               78800021
*                                       FOR PROBLEM DETERMINATION       79000021
EDI06300 EQU   *                                                        79200021
         L     RUCB,DEBUCBAD            ESTABLISH ADDR OF UCB CAUSING   79400021
*                                       EOV                             79600021
         IC    RET,UCBDMCT              ADD 1 TO THE DATA MANAGEMENT    79800021
         LA    RET,K1(K0,RET)           COUNT SINCE ABNORMAL CLOSE W    80000021
         STC   RET,UCBDMCT              SUBTRACT 1 FROM THIS UCB WHEN   80200021
*                                       IT GAINS CONTROL                80400021
         AIF   ('&LIB' NE 'LIB1').LIB23T5                               80450000
         SSM   CLENAB0I                 RE-ENABLE                       80600021
.LIB23T5 ANOP                                                           80650000
         AIF   ('&LIB' EQ 'LIB1').LIB13T5                               80700000
         MODESET ENABLE=YES             RE-ENABLE                Y01082 80750000
.LIB13T5 ANOP                                                           80760000
         BAL   RET,EDI06400             SET UP RWTGC AND RWTG           80800021
         DMABCOND (R0),LOAD0P                                           81000021
*                                                                       81200021
****           SUBROUTINE TO RESTORE RWTGC AND RWTGC                  * 81400021
*                                                                       81600021
EDI06400 EQU   *                                                        81800021
         LA    RWTGC,DXXENTRY           CURRENT MODULE NAME             82000021
         LA    RWTG,DXXAREA             NEXT MODULE NAME                82200021
         BR    RET                      RETURN TO CALLER                82400021
*                                                                     * 82600021
*        CONSTANTS                                                      82800021
         DS    0F                                                       83000021
         AIF   ('&LIB' NE 'LIB1').LIB23T6                               83050000
CLENAB0I DC    X'FF'                    CONSTANT TO RE-ENABLE           83200021
.LIB23T6 ANOP                                                           83250000
ACCW10I  DC    X'6000000508'            SILI,COMMAND CHAIN,5 CHAR,TIC   83400021
COLCDUEX DC    X'00000000FFFFFFFF7FFF'  EXTENT TO COVER ENTIRE DISK     83600021
FLAG19I  DC    X'8000'                  KEEP MSG TEST                   83800021
MESRETN  DC    C'IEC003E R '            RETAIN MESSAGE                  84000021
         DS    0F                                                       84200021
MCSDE2I1 DC    X'2000'                  MCS DESCRIPTOR CODE      M0190  84400021
         DC    X'1000'                  MCS ROUTING CODE         M0190  84600021
DESCO912 DC    X'4000'                  MCS DESCRIPTOR CODE             84800021
         DC    X'1000'                  MCS ROUTING CODE         M0190  84900021
FLAG12I  DC    X'8000'                                                  85000021
MOUNTS9I DC    C'IEC001A M '            MOUNT MESSAGE                   85200021
AZEROS9I EQU   *                                                        85400021
COLCVT9I DC    X'0000000000000003'      X                               85600021
*                                       + LAST                          85800021
SULDFR0I DC    X'0C'                    DEFER UTL PROC CODE BYTE        86000021
         DC    X'8C'                    DEFER UTL PROC CODE BYTE        86200021
*                                       +LAST                           86400021
*                                                                       86600021
         XCTLTABL ID=(LOA3553V,3V,LOA3554J,4J,LOA3553T,3T,             X86800021
               LOAD0P,0P),SVC=055                                       87000021
         IECDSECS CVT,TCB,TIOT,DCB,DEB,UCB,MAIN,WTG,EXPAND=YES          87200021
         IECEQU                                                         87400021
         END                                                            87600021
