         TITLE 'IFG0554L, ALIAS IFG0195F/EOV, OPEN - DA INPUT USER HEADX00100000
               ER/TRAILER LABELS'                                       00200000
         COPY  LCGASMSW                                                 00300000
IFG0554L CSECT                                                          00500000
*********************************************************************** 00600021
*                                                                     * 00700000
*           VS1 RELEASE 02 DELETIONS                                  * 00750002
*0000                                                            XM1389 00760002
*                                                                     * 00800000
*          RELEASE 25 DELETIONS/CHANGES                               * 00900000
*          RELEASE 24 DELETIONS/CHANGES                               * 01000000
*          RELEASE 23 DELETIONS/CHANGES                               * 01100000
*          RELEASE 22 DELETIONS/CHANGES                               * 01200000
*          RELEASE 21 DELETIONS/CHANGES                               * 01300000
*          RELEASE 21.7 DELETIONS/CHANGES                               01350000
*0000259000,265000,268000,307500-307700,311000,318000,370000,   SA55619 01360021
*0000371000,417500,418000,431000-432000,460000,497000,499000,   SA55619 01370021
*0000505500,506000,510000,519000,534000-535000,566000,          SA55619 01380021
*0000568000-570000,574500,575000,579000,580500,590000-591000,   SA55619 01390021
*0000593000,596000-598000,600000-601000,608000,609000-612540,   SA55619 01392021
*0000612560-612588,612600-612800,612900,617000,625000,          SA55619 01394021
*0000632500-633000,637000-638000,642000,644000-645000,658000    SA55619 01396021
*0000594000,594500,608500,617900                                SM05248 01396221
*                                                                     * 01400000
* STATUS CHANGE LEVEL 000                                             * 01500000
*                                                                     * 01600000
* FUNCTION -                                                          * 01700000
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 01800000
*    DA INPUT USER HEADER/TRAILER LABELS                              * 01900000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)' FOR DETAILS.         * 02000000
*                                                                     * 02100000
* ENTRY POINTS -                                                      * 02200000
*         IFG0554L, ALIAS IFG0195F                                    * 02300000
*                                                                     * 02400000
* INPUT -                                                             * 02500000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 02600000
*                                                                     * 02700000
* OUTPUT -                                                            * 02800000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 02900000
*                                                                     * 03000000
* EXTERNAL REFERENCES -                                               * 03100000
*         IFG019RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 03200000
*            WAIT.                                                    * 03300000
*         REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                * 03400000
*                                                                     * 03500000
* EXITS, NORMAL -                                                     * 03600000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 03700000
*                                                                     * 03800000
* EXITS, ERROR -                                                      * 03900000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 04000000
*                                                                     * 04100000
* TABLES/WORK AREAS -                                                 * 04200000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 04300000
*                                                                     * 04400000
* ATTRIBUTES -                                                        * 04500000
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 04600000
*                                                                     * 04700000
* CHARACTER CODE DEPENDENCY -                                         * 04800000
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 04900000
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 05000000
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 05100000
*                                                                     * 05200000
* NOTES -                                                             * 05300000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05400000
*                                                                     * 05500000
*********************************************************************** 05600000
         EJECT                                                          05700000
*********************************************************************** 05800000
*                                                                     * 05900000
*                          FUNCTION PROLOG                            * 06000000
*                                                                     * 06100000
*********************************************************************** 06200000
*                                                                     * 06300000
* FUNCTION NAME -                                                     * 06400000
*    DA INPUT USER HEADER/TRAILER LABELS                              * 06500000
*                                                                     * 06600000
* (STATUS) -                                                          * 06700000
*    NOT APPLICABLE                                                   * 06800000
*                                                                     * 06900000
         AIF   ('&LIB' NE 'LIB1').LIB24L0                               06950000
* FUNCTION -                                                          * 07000000
*    THIS MODULE READS USER HEADER/TRAILER LABELS FOR PRESENTATION TO * 07100000
*    THE USER'S INPUT HEADER OR TRAILER LABEL PROCESSING ROUTINE.     * 07200000
*                                                                     * 07300000
*    AN AREA OF MAIN STORAGE IS OBTAINED FROM SUBPOOL 250 FOR         * 07400000
*    USE AS A WORK AREA, LABEL BUFFER, AND PARAMETER LIST.            * 07500000
*    LABELS ARE READ AND PRESENTED TO THE USER UNTIL                  * 07600000
*    1) AN EOF IS ENCOUNTERED,                                        * 07700000
*    2) THE USER INDICATES TERMINATION OF PROCESSING VIA A            * 07800000
*       RETURN CODE, OR                                               * 07900000
*    3) THE MAXIMUM NUMBER OF LABELS (8) HAVE BEEN PROCESSED.         * 08000000
*                                                                     * 08100000
*    AFTER THE USER'S ROUTINE HAS PROCESSED THE LABEL PASSED TO IT,   * 08200000
*    THE CODE RETURNED BY THE USER DIRECTS FURTHER PROCESSING         * 08300000
*    AS FOLLOWS -                                                     * 08400000
*                                                                     * 08500000
*       RETURN CODE      ACTION TAKEN BY THIS ROUTINE                 * 08600000
*          0    IF THERE ARE ANY REMAINING LABELS IN THE LABEL GROUP, * 08700000
*               THEY ARE IGNORED.                                     * 08800000
*               NORMAL PROCESSING IS RESUMED.                         * 08900000
*                                                                     * 09000000
*          4    THE NEXT LABEL IS READ INTO THE LABEL BUFFER AREA     * 09100000
*               AND CONTROL IS RETURNED TO THE EXIT ROUTINE.          * 09200000
*               IF THERE ARE NO MORE LABELS IN THE LABEL GROUP,       * 09300000
*               NORMAL PROCESSING IS RESUMED.                         * 09400000
*                                                                     * 09500000
*          8  * THE LABEL IS WRITTEN FROM THE LABEL BUFFER AREA.      * 09600000
*               NORMAL PROCESSING IS RESUMED.                         * 09700000
*                                                                     * 09800000
*          12 * THE LABEL IS WRITTEN FROM THE LABEL BUFFER AREA.      * 09900000
*               THE NEXT LABEL IS READ INTO THE LABEL BUFFER AREA     * 10000000
*               AND CONTROL IS RETURNED TO THE LABEL PROCESSING       * 10100000
*               ROUTINE.  IF THERE ARE NO MORE LABELS,                * 10200000
*               NORMAL PROCESSING IS RESUMED.                         * 10300000
*                                                                     * 10400000
*             * ONLY FOR A PHYSICAL SEQUENTIAL DATA SET OPENED        * 10500000
*               FOR UPDAT (UHL,UTL), A PHYSICAL SEQUENTIAL DATA SET   * 10600000
*               OPENED FOR OUTPUT OR OUTIN WITH DISP=MOD (UTL), OR    * 10700000
*               A DIRECT DATA SET OPENED FOR UPDAT OR OUTPUT (UHL,UTL)* 10800000
*                                                                     * 10900000
.LIB24L0 ANOP                                                           10910000
         AIF   ('&LIB' EQ 'LIB1').LIB14L0                               10920000
* FUNCTION -                                                          * 10950000
*    THIS MODULE READS USER HEADER/TRAILER LABELS FOR PRESENTATION TO * 10960000
*    THE USER'S INPUT HEADER OR TRAILER LABEL PROCESSING ROUTINE.     * 10970000
*                                                                     * 10980000
*    AN AREA OF MAIN STORAGE IS OBTAINED FROM SUBPOOL 250 FOR         * 10990000
*    USE AS A WORK AREA, LABEL BUFFER, AND PARAMETER LIST.            * 10992000
*    LABELS ARE READ AND PRESENTED TO THE USER UNTIL                  * 10994000
*    1) AN EOF IS ENCOUNTERED,                                        * 10996000
*    2) THE USER INDICATES TERMINATION OF PROCESSING VIA A            * 10998000
*       RETURN CODE, OR                                               * 10998400
*    3) THE MAXIMUM NUMBER OF LABELS (8) HAVE BEEN PROCESSED.         * 10998800
*                                                                     * 10999200
*    AFTER THE USER'S ROUTINE HAS PROCESSED THE LABEL PASSED TO IT,   * 10999600
*    THE CODE RETURNED BY THE USER DIRECTS FURTHER PROCESSING         * 10999700
*    AS FOLLOWS -                                                     * 10999800
*                                                                     * 10999900
*       RETURN CODE      ACTION TAKEN BY THIS ROUTINE                 * 11033200
*          0    IF THERE ARE ANY REMAINING LABELS IN THE LABEL GROUP, * 11043200
*               THEY ARE IGNORED.                                     * 11053200
*               NORMAL PROCESSING IS RESUMED.                         * 11063200
*                                                                     * 11065200
*          4    THE NEXT LABEL IS READ INTO THE LABEL BUFFER AREA     * 11065600
*               AND CONTROL IS RETURNED TO THE EXIT ROUTINE.          * 11066000
*               IF THERE ARE NO MORE LABELS IN THE LABEL GROUP,       * 11066400
*               NORMAL PROCESSING IS RESUMED.                         * 11066500
*                                                                     * 11066600
*          8  * THE LABEL IS WRITTEN FROM THE LABEL BUFFER AREA.      * 11077700
*               NORMAL PROCESSING IS RESUMED.                         * 11087700
*                                                                     * 11088100
*          12 * THE LABEL IS WRITTEN FROM THE LABEL BUFFER AREA.      * 11088500
*               THE NEXT LABEL IS READ INTO THE LABEL BUFFER AREA     * 11088600
*               AND CONTROL IS RETURNED TO THE LABEL PROCESSING       * 11088700
*               ROUTINE.  IF THERE ARE NO MORE LABELS,                * 11088800
*               NORMAL PROCESSING IS RESUMED.                         * 11092500
*                                                                     * 11094500
*             * ONLY FOR A PHYSICAL SEQUENTIAL DATA SET OPENED        * 11094900
*               FOR UPDAT (UHL,UTL), A PHYSICAL SEQUENTIAL DATA SET   * 11095300
*               OPENED FOR OUTPUT OR OUTIN WITH DISP=MOD (UTL), OR    * 11095700
*               A DIRECT DATA SET OPENED FOR UPDAT OR OUTPUT (UHL,UTL)* 11096100
*                                                                     * 11096200
*    DEB VALIDITY CHECKING IS ACCOMPLISHED VIA A DEB VALIDITY CHECK   * 11096300
*    ROUTINE WHICH MAINTAINS AND UPDATES A TABLE OF VALID DEB POINTERS* 11097400
*    IN PROTECTED CORE (LSQS).                                        * 11099400
*                                                                     * 11100000
.LIB14L0 ANOP                                                           11122100
* ENTRY POINTS -                                                      * 11148200
*    IFG0554L - CONTROL IS PASSED TO THIS MODULE VIA AN XCTL BY       * 11174100
*    THE RESIDENT ROUTINE FROM OPEN OR EOV, IF THE USER HAS           * 11200000
*    SPECIFIED LABEL=SUL FOR A PHYSICAL SEQUENTIAL OR DIRECT DATA     * 11300000
*    SET AND IF THE APPROPRIATE USER LABEL EXIT IS ACTIVE (IE., THE   * 11400000
*    DCB EXIT LIST CONTAINS A NON-ZERO USER LABEL EXIT ADDRESS IN     * 11500000
*    THE USER LABEL EXIT ENTRY).                                      * 11600000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 11700000
*                                                                     * 11800000
* INPUT -                                                             * 11900000
*    REGISTERS -                                                      * 12000000
*       RC 12 - CONTENTS OF FULL WORD OF USER'S DCB EXIT LIST ENTRY   * 12100000
*          THAT IS BEING PROCESSED.  THE HIGH ORDER BYTE CONTAINS THE * 12200000
*          UHL/UTL OPTION, POSSIBLY WITH THE END OF LIST X'80' BIT ON.* 12300000
*          THE LOW ORDER THREE BYTES IS THE ADDRESS OF THE USER'S     * 12400000
*          USER LABEL EXIT ROUTINE.  THIS ADDRESS IS ZERO IF THE      * 12500000
*          EXIT IS NOT ACTIVE.  HOWEVER, IN THIS CASE THIS MODULE     * 12600000
*          MUST NOT BE CALLED.                                        * 12700000
*    WORK AREAS -                                                     * 12800000
*       RBGRS2-RBGRS13 - USER'S REGISTERS 2-13, WHICH WERE SAVED IN   * 12900000
*          THE SVRB GENERAL REGISTER SAVE AREA.                       * 13000000
*       DSCEXTYP - THE EXTENT TYPE AND SIZE OF THE FIRST EXTENT IN    * 13100000
*          THE FORMAT 1 DSCB, NORMALLY THE UL EXTENT.                 * 13200000
*       DXDAADDR - THE MBB..... MUST ALREADY BE SET UP FOR EXTENT 0,  * 13300000
*          AND THE BIN NUMBER FOR THIS VOLUME.                        * 13400000
*       DXDEBMOD-DXDEBNTR - MUST BE SET UP TO COVER THE WHOLE VOLUME, * 13500000
*          AND THEREFORE TO COVER THE UL EXTENT.                      * 13600000
*       DXVOLMT2 - USED AS A SAVE AREA ONLY BY OPEN TO SAVE THE CCHHR * 13700000
*          OF THE FORMAT 1 DSCB FROM DXCCW7, SINCE DXCCW7 IS NEEDED   * 13800000
*          FOR A CHANNEL PROGRAM.                                     * 13900000
*    USER LABELS -                                                    * 14000000
*       EXISTING USER HEADER OR TRAILER LABELS ARE READ FROM THE      * 14100000
*       ONE TRACK USER LABEL EXTENT FOR THIS DATA SET.                * 14200000
*                                                                     * 14300000
* OUTPUT -                                                            * 14400000
*    USER LABELS -                                                    * 14500000
*       IF OPENED FOR UPDAT, THE USER LABELS MAY BE MODIFIED AND      * 14600000
*       WRITTEN BACK AT THE OPTION OF THE USER'S USER LABEL EXIT      * 14700000
*       ROUTINE.                                                      * 14800000
*    REGISTERS -                                                      * 14900000
*       AT FINAL EXIT FROM THIS MODULE, REGISTERS 0-2, 4-14 ARE THE   * 15000000
*       SAME AS THEY WERE AT ENTRY.  THIS ALLOWS THIS MODULE TO BE    * 15100000
*       CALLED AS THOUGH IT WAS A SUBROUTINE.                         * 15200000
*    WORK AREAS -                                                     * 15300000
*       DXDAADDR - MBB..... SAME AS AT ENTRY TO MODULE.               * 15400000
*                  ...CCHHR SHOULD BE CONSIDERED UNDEFINED.           * 15500000
*       DXCCW1-DXCCW6 - SHOULD BE CONSIDERED UNDEFINED.               * 15600000
*       DXCCW7 - SHOULD BE CONSIDERED UNDEFINED BY EOV.               * 15700000
*                                                                     * 15800000
* EXTERNAL REFERENCES -                                               * 15900000
*    THE USER'S INPUT USER HEADER OR TRAILER LABEL EXIT ROUTINE.      * 16000000
*    IT IS ENTERED VIA A SYNCH SVC 12 WITH THE FOLLOWING INPUT -      * 16100000
*       REGISTER 0 - CONTAINS NO MEANINGFUL INFORMATION.              * 16200000
*       REGISTER 1 - POINTER TO A 4 WORD PARAMETER LIST WHICH CONTAINS* 16300000
*          POINTER TO 80 BYTE USER LABEL BUFFER.                      * 16400000
*          POINTER TO THE USER'S DCB.                                 * 16500000
*          FLAG BYTE, POINTER TO STATUS INFORMATION (IF PERMANENT I/O * 16600000
*             ERROR) OR ZERO.                                         * 16700000
*          4 BYTES RESERVED.  (FOR OUTPUT, THIS FIELD POINTS TO THE   * 16800000
*             IMAGE AREA IF USER TOTALING WAS REQUESTED - DCBOPTCD=T) * 16900000
*             OR IS ZERO.                                             * 17000000
*       REGISTERS 2-13 - USER'S REGISTERS BEFORE CALL TO OPEN, FEOV,  * 17100000
*          OR ROUTINE THAT CALLED EOV.                                * 17200000
*       REGISTER 14  - RETURN ADDRESS, SET BY SYNCH SVC 12.           * 17300000
*       REGISTER 15  - USER LABEL EXIT ROUTINE ADDRESS.               * 17400000
*    BEFORE EXITING, THIS MODULE'S REGISTERS 2-13 ARE SAVED IN THE    * 17500000
*    SVRB EXTENDED SAVE AREA.  THE USER'S REGISTERS 2-13 ARE RESTORED * 17600000
*    FROM THE SVRB GENERAL REGISTER SAVE AREA.  THE LOCK BIT (BIT 6)  * 17700000
*    IN DCBOFLGS IS SET TO 1 TO PREVENT THE USER FROM REQUESTING      * 17800000
*    ANOTHER I/O SUPPORT FUNCTION TO OPERATE ON THIS DCB WILE HE IS   * 17900000
*    IN CONTROL.  ON RETURN FROM THE USER'S ROUTINE, THIS BIT IS      * 18000000
*    RESET TO 0.                                                      * 18100000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 18200000
*                                                                     * 18300000
* EXITS, NORMAL -                                                     * 18400000
*    VIA XCTL TO MODULE WHOSE IDTTR IS IN DXRETMOD.  THIS IS NORMALLY * 18500000
*    THE CALLER OF THIS MODULE OR THE NEXT MODULE THAT IT WOULD HAVE  * 18600000
*    GONE TO HAD THERE BEEN NO USER LABELS TO PROCESS.                * 18700000
*                                                                     * 18800000
* EXITS, ERROR -                                                      * 18900000
*    NO USER LABEL TRACK ALLOCATED -                                  * 19000000
*       THE USER'S ROUTINE IS ENTERED WITH THE BUFFER POINTER         * 19100000
*       SET TO ZERO.  OTHER INPUT AS USUAL.                           * 19200000
*    NO LABELS CAN BE READ -                                          * 19300000
*       EXIT TO USER'S ROUTINE WITH THE LABEL BUFFER POINTER IN THE   * 19400000
*       PARMAETER LIST SET TO ZERO.  OTHER PARAMETERS UNCHANGED.      * 19500000
*       ON RETURN FROM USER'S ROUTINE, THE RETURN CODE IS IGNORED     * 19600000
*       AND NORMAL PROCESSING CONTINUES.                              * 19700000
*    I/O ERROR READING USER LABEL -                                   * 19800000
*       THE USER'S ROUTINE IS ENTERED AGAIN WITH BIT 0 OF THE FLAG    * 19900000
*       BYTE SET TO 1, AND A POINTER TO THE STATUS INFORMATION IN     * 20000000
*       THE WORK AREA IOB.                                            * 20100000
*    I/O ERROR WRITING UPDATED USER LABEL -                           * 20200000
*       IN ADDITION TO SETTING BIT 0 OF THE FLAG BYTE, BIT 1 IS ALSO  * 20300000
*       SET.  A POINTER TO THE STATUS INFORMATION IN THE WORK AREA    * 20400000
*       IOB IS PASSED.  THE OTHER PARAMETERS ARE UNCHANGED.           * 20500000
*                                                                     * 20600000
* TABLES/WORK AREAS -                                                 * 20700000
*    THE FORMAT AND CONTENTS OF THE WORK AREAS USED ARE DESCRIBED BY  * 20800000
*    THE DSECTS AT THE END OF THE LISTING.                            * 20900000
*                                                                     * 21000000
* ATTRIBUTES -                                                        * 21100000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 21200000
*                                                                     * 21300000
* CHARACTER CODE DEPENDENCY -                                         * 21400000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 21500000
*                                                                     * 21600000
* NOTES -                                                             * 21700000
*   *IF THIS MODULE EVER HAS TO BE SPLIT, THIS COULD PROBABLY BE      * 21800000
*    BEST DONE BY DIVIDING IT INTO TWO MODULES, ONE FOR INPUT USER    * 21900000
*    HEADER LABELS AND ONE FOR INPUT USER TRAILER LABELS.             * 22000000
*    A SIGNIFICANT AMOUNT OF CODE IS IN THIS MODULE TO HANDLE THE     * 22100000
*    INCONSISTENCY BETWEEN HEADER AND TRAILER LABELS AND THE NUMBER   * 22200000
*    IN THE KEY WITH WHICH THEY ARE WRITTEN.                          * 22300000
*   *UNLIKE UHL, WHERE THE KEY OF THE RECORD CORRESSPONDS TO THE UHL  * 22400000
*    NUMBER, UTL1 HAS A KEY OF UTL0.                                  * 22500000
*   *USER LABELS FOR PARALLEL DCB'S ARE NOT PROCESSED IN PARALLEL     * 22600000
*    BY THIS MODULE IN ORDER TO AVOID AN ABEND WHICH COULD BE CAUSED  * 22700000
*    IF TWO DCB'S WERE TO OPEN TO THE SAME DATA SET AND AN ENQ WERE   * 22800000
*    TO BE DONE ON BOTH OF THEM FOR THE SAME USER LABEL TRACK.        * 22900000
*    THIS ALSO HAS THE ADVANTAGE THAT ONLY ONE USER LABEL WORK AREA   * 23000000
*    IS PRESENT AT ONE TIME AND THEREFORE THE TOTAL WORK AREA         * 23100000
*    REQUIREMENT IS LESS.                                             * 23200000
*    ALSO THIS MAY PROTECT SOME POORLY WRITTEN USER LABEL ROUTINES    * 23300000
*    THAT EXPECT TO PROCESS ONLY ONE SET OF LABELS AT A TIME FROM     * 23400000
*    GETTING THE LABELS MIXED UP.  HOWEVER, SINCE THIS IS NOT A       * 23500000
*    SPECIFICATION, THIS MAY BE CHANGED AT ANY TIME.                  * 23600000
*                                                                     * 23700000
*********************************************************************** 23800000
         EJECT                                                          23900000
         IECDSECS CVT,TCB,RB,DCB,       DEFINE DESIRED DSCTS TO BE     X24000000
               MAIN,DEB,USERLAB,WTG     EXPANDED AT THE END             24100000
*                                                                       24200000
         IECEQU ,                       DEFINE EQUATES                  24300000
*                                                                       24400000
         USING IHADCB,RDCB              DEFINE BASE TO DCB              24500000
         USING FORCORE,RCORE            DEFINE BASE TO DCB WORK AREA    24600000
         USING WTG,RWTG                 DEFINE BASE TO XCTL/WTG TABLE   24700000
         USING ULWK1,RUCB               DEFINE BASE TO UL WORK AREA     24800000
         USING DEB,RDEB                 DEFINE BASE FOR DEB             24900000
*                                                                       25000000
         BALR  RBASE,0                  ESTABLISH BASE REGISTER         25100000
         USING *,RBASE                  DEFINE BASE REGISTER            25200000
ULT000   EQU   *                                               SA55619  25250021
*                                                                       25300000
*********************************************************************** 25400000
*                                                                       25500000
*  OBTAIN MAIN STORAGE IN USER'S PROTECTION KEY FOR                     25600000
*  WORK AREA, LABEL BUFFER AND PARAMETER LIST (40+80+16=136)            25700000
*                                                                       25800000
         L     R0,ULBFRLNG              LOAD BUFFER LENGTH AND  SA55619 25850021
*                                       SUBPOOL NO. INTO REG 0  SA55619 25860021
         GETMAIN R,LV=(0)               GETMAIN FROM SPL 250    SA55619 25900021
*                                                                       26000000
         LR    RUCB,R1                  SET BASE FOR ULWK AREA          26100000
         XC    ULWK1(ULWKEND-ULWK1),ULWK1  CLEAR USER LABEL WORK AREA   26200000
*                                                                       26300000
         CLI   WTGMODNM+K5,C'9'         IS THIS OPEN (IFG0195F)         26400000
         BNE   ULT020                   BR IF NO                SA55619 26500021
         MVC   DXVOLMT2(K5),DXCCW7      SAVE DSCB CCHHR FOR OPEN        26600000
*                                                                       26700000
ULT020   EQU   *                                                SA55619 26800021
         CLI   DSCEXTYP,ULEXT           IS FIRST EXTENT FOR USER LABELS 26900000
         BNE   ULT300                   BR IF NO TO INFORM TO USER      27000000
*                                                                       27100000
*********************************************************************** 27200000
*                                                                       27300000
*  SET UP CHANNEL PROGRAM AND WORK AREA TO READ FIRST HEADER / TRAILER  27400000
*  LABEL                                                                27500000
*                                                                       27600000
*        READ COUNT        INTO ULWK8                                   27700000
*        SEARCH KEY EQ     KEY IN ULWK6 = 'UHL1'/'UTL0'                 27800000
*        TIC *-16                                                       27900000
*        READ DATA (LABEL) INTO BUFFER                                  28000000
*                                                                       28100000
         XC    DXCCW1(K32),DXCCW1       CLEAR CCW AREA                  28200000
         LA    R1,ULWK8                 POINT TO AREA INTO WHICH        28300000
         ST    R1,DXCCW1                COUNT IS READ                   28400000
         LA    R1,ULWK6                 POINT TO AREA CONTAINING        28500000
*                                       SEARCH ARGUMENT                 28600000
         ST    R1,DXCCW2                FOR SEARCH KEY EQUAL            28700000
         LA    R1,DXCCW1                POINT TO READ COUNT CCW         28800000
         ST    R1,DXCCW3                IN TIC                          28900000
         LA    R1,ULBUFR                POINT TO LABEL BUFFER           29000000
         ST    R1,DXCCW4                IN READ DATA                    29100000
         OC    DXCCW1(K32),ULCP1        OR IN CMND, FLAGS, LENGTH       29200000
*                                                                       29300000
*        INITIALIZE IOBDADAD WITH R=0                                   29400000
*                                                                       29500000
*                                       MBB SET BEFORE ENTRY            29600000
         MVC   DXDAADDR+K3(K4),DSCLOWLM  CCHH FROM START OF 1ST EXTENT  29700000
         MVI   DXDAADDR+K7,K0           START SEARCH AT R0              29800000
*                                                                       29900000
         TM    DCBDSORG,DCBORGDA        IS THIS DIRECT ORGANIZATION     30000000
         BZ    ULT040                   BR IF NO                        30100000
*                                                                       30200000
         BAL   RC,ULT400                GO SET UP PARM LIST FOR ENQ     30300000
         ENQ   MF=(E,(1))               ENQ ON USER LABEL TRACK         30400000
*                                                                       30500000
ULT040   EQU   *                                                        30600000
         MVC   ULWK6,UHLCONST           SET UP SEARCH ARG = UHL1        30700000
         NI    DXREGC,X'7F'             TURN OFF HIGH ORDER BIT SA55619 30750021
         CLI   DXREGC,XLIUHL            IS THIS INPUT UHL EXIT  SA55619 30760021
         BE    ULT045                   BR IF YES               SA55619 30770021
         MVC   ULWK6,UTLCONST           SET UP SEARCH ARG = UTL0        31000000
ULT045   EQU   *                                                SA55619 31100021
         MVC   ULWK10,ULWK6             NECESSARY SINCE FIRST CHANNEL   31200000
*                                       PROGRAM DOES NOT READ KEY       31300000
         OI    ULWK2,X01                SET FIRST READ SWITCH           31400000
*                                                                       31500000
*        READ FIRST HEADER / TRAILER LABEL                              31600000
*                                                                       31700000
         BAL   RC,ULT470                GO READ USER LABEL      SA55619 31800021
*                                                                       31900000
*********************************************************************** 32000000
*                                                                       32100000
*  ESTABLISH CHANNEL PROGRAM FOR SUBSEQUENT USE, THEN TEST              32200000
*  FOR I/O ERROR.                                                       32300000
*                                                                       32400000
*  SET UP CHANNEL PROGRAM TO WRITE BACK LABEL AND READ NEXT LABEL       32500000
*                                                                       32600000
*        SEARCH KEY EQ       KEY = UHL(N) / UTL(N)                      32700000
*        TIC *-8                                                        32800000
*        WRITE DATA          WRITE UPDATED LABEL                        32900000
*        SEARCH ID EQ        ID OF RECORD PRIOR TO UHL(N)  / UTL(N)     33000000
*        TIC *-8             CHECK                                      33100000
*        RD CKD    (SKIP)    LABEL JUST WRITTEN                         33200000
*        RD CKD              READ NEXT LABEL                            33300000
*                                                                       33400000
*  WHEN ONLY UPDATING IS PERFORMED, CC FLAG IN RD CKD IS TURNED OFF.    33500000
*                                                                       33600000
*  WHEN NO UPDATING IS PERFORMED,CHANNEL PROGRAM TO READ NEXT LABEL IS  33700000
*                                                                       33800000
*        SEARCH KEY EQ       KEY OF PREVIOUS LABEL                      33900000
*        TIC *-8                                                        34000000
*        RD CKD              READ NEXT LABEL                            34100000
*                                                                       34200000
*  PROCEDURE USED BELOW IS TO USE KEY IN ULWK10 (KEY OF LABEL           34300000
*  PROCESSED) AS SEARCH ARGUMENT FOR SUBSEQUENT I/O OPERATIONS.         34400000
*                                                                       34500000
         MVC   DXCCW1(K16),DXCCW2       SEARCH KEY CCW TO DXCCW1        34600000
*                                       AND TIC *-8 TO DXCCW2           34700000
         XC    DXCCW3(K40),DXCCW3       CLEAR REMAINING CCW AREA        34800000
*                                                                       34900000
*  DXCCW3 IS ESTABLISHED AFTER USER RETURNS CODE                        35000000
         LA    R1,DXDAADDR+K3           ADDR OF IOBADDR+3 (CCHHR) FOR   35100000
         ST    R1,DXCCW4                SEARCH ID                       35200000
         LA    R1,DXCCW4                TIC TO                          35300000
         ST    R1,DXCCW5                DXCCW4                          35400000
         LA    R1,ULWK8                 RD CKD INTO                     35500000
         ST    R1,DXCCW7                ULWK8                           35600000
         OC    DXCCW4(K32),ULCP3        OR IN CMND, FLAGS, LENGTH       35700000
*                                                                       35800000
*********************************************************************** 35900000
*                                                                       36000000
ULT050   EQU   *                                                        36100000
         TM    DXECB,ECBCOD7F           TEST IF I/O ERROR               36200000
         BNO   ULT200                   BR IF YES                       36300000
*                                                                       36400000
         NI    ULWK2,X'FF'-X01          SET 1ST-READ-SW OFF IF ON       36500000
         IC    R1,ULWK9                 'R' OF COUNT READ IN            36600000
         BCTR  R1,0                     DECR BY 1 - USED IN ORIENTATION 36700000
         STC   R1,DXDAADDR+K7           FOR WRITE VERIFICATION          36800000
*                                                                       36900000
         LA    R1,ULBUFR                PTR TO LABEL BUFFER     SA55619 36950021
         BAL   RD,ULT410                GO TO SYNCH TO USER     SA55619 37000021
*                                       EXIT RTN                        37100000
         LTR   RF,RF                    DID USER RETURN A CODE = 0      37200000
         BZ    ULT500                   BR IF YES (NO MORE PROCESSING)  37300000
*                                                                       37400000
ULT130   EQU   *                                                        37500000
*  SOME TYPE OF I/O WILL BE INITIATED.  SEARCH WILL BE BASED UPON KEY   37600000
*  OF LABEL 'JUST PROCESSED'.                                           37700000
         MVC   ULWK6,ULWK10             SET UP SEARCH ARGUMENT          37800000
         XC    DXCCW3,DXCCW3            ENSURE THAT PRVIUS CCW DOES NOT 37900000
*        CONFLICT WITH CHANNEL PROGRAM TO BE COMPLETED BELOW.           38000000
         CLI   ULRETCOD,READNEXT        DIS USER RETURN A CODE = 4      38100000
         BE    ULT150                   BR IF YES TO READ NEXT LABEL    38200000
*                                                                       38300000
*  CHECK IF 8 OR 12 IS A VALID RETURN CODE                              38400000
         AIF   ('&LIB' NE 'LIB1').LIB24L1                               38450000
         L     RDEB,DCBDEBAD            POINTER TO USER'S DEB           38500000
.LIB24L1 ANOP                                                           38550000
         AIF   ('&LIB' EQ 'LIB1').LIB14L1                               38560000
         L     RDEB,DXPDEBAD            LOAD PROTECTED DEB ADDR  Y01021 38570000
.LIB14L1 ANOP                                                           38580000
         CLI   WTGMODNM+K5,C'9'         IS THIS OPEN (IFG0195F)         38600000
         BNE   ULT135                   BR IF NO, USER'S DEB EXISTS     38700000
         LA    RDEB,DXDEB               DURING OPEN USE WORK DEB        38800000
ULT135   EQU   *                                                        38900000
         TM    DEBOPATB,DEBOPOUT-DEBOPUPD  TEST IF OPENED FOR OUTPUT    39000000
         BO    ULT140                   BR IF YES                       39100000
         BM    ULT500                   BR IF NOT UPDAT OR INPUT        39200000
         TM    DEBOPATB,DEBOPUPD        TEST IF OPENED FOR UPDAT        39300000
         BO    ULT145                   BR IF YES                       39400000
         B     ULT500                   BR OPENED FOR INPUT             39500000
*                                                                       39600000
ULT140   EQU   *                                                        39700000
         TM    DCBDSORG,DCBORGDA        IF NOT UPDATE, DIRECT DATA SET  39800000
         BZ    ULT500                   FOR OUTPUT IS ALSO VALID.       39900000
*                                                                       40000000
*  SET UP THIRD CCW TO WRITE UPDATED LABEL                              40100000
*                                                                       40200000
ULT145   EQU   *                                                        40300000
         LA    R1,ULBUFR                ESTABLISH WRITE DATA CCW3 TO    40400000
         ST    R1,DXCCW3                WRITE FROM LABEL BUFFER         40500000
         OC    DXCCW3,ULCP2             OR IN CMND, FLAGS, LENGTH       40600000
*                                                                       40700000
         CLI   ULRETCOD,WRITNEXT        IS LABEL TO BE WRITTEN ONLY     40800000
         BE    ULT170                   BR IF YES                       40900000
         CLI   ULRETCOD,WRITNEXT+READNEXT  IS LABEL TO BE WRITTEN AND   41000000
         BE    ULT160                   NEXT LABEL READ, BR IF YES      41100000
         B     ULT500                   INVALID CODE RETURNED, END      41200000
*                                       PROCESSING IN THIS MODULE       41300000
*                                                                       41400000
*        READ NEXT LABEL                                                41500000
*                                                                       41600000
ULT150   EQU   *                                                        41700000
         CLI   DXREGC,XLIUHL            IS THIS INPUT UHL EXIT  SA55619 41750021
         BE    ULT151                   BR IF YES               SA55619 41800021
         CLI   ULWK10+K3,C'7'           HAS MAX NO. OF UTL ALREADY      42000000
         BNL   ULT500                   BEEN READ, BR IF YES            42100000
         B     ULT152                   BR NO TO CONTINUE               42200000
ULT151   CLI   ULWK10+K3,C'8'           HAS MAX NO. OF UHL ALREADY      42300000
         BNL   ULT500                   BEEN READ, BR IF YES            42400000
*        ESTABLISH THIRD CCW TO READ NEXT LABEL                         42500000
ULT152   LA    R1,ULWK8                 SET RD CKD CCW TO READ INTO     42600000
         ST    R1,DXCCW3                AREA STARTING AT ULWK8          42700000
         OC    DXCCW3,RDCKD             OR IN CMND, FLAGS, LENGTH       42800000
*                                                                       42900000
ULT155   EQU   *                        GO READ NEXT LABEL (OR WRITE    43000000
         BAL   RC,ULT470                UPDATED LABEL AND READ SA55619  43100000
*                                       NEXT LABEL                      43200000
         B     ULT050                   GO CHECK FOR ERROR              43300000
*                                                                       43400000
*        WRITE UPDATED LABEL AND READ NEXT LABEL                        43500000
*                                                                       43600000
ULT160   EQU   *                                                        43700000
         CLI   DXREGC,XLIUHL            IS THIS INPUT UHL EXIT  SA55619 43750000
         BE    ULT161                   BR IF YES               SA55619 43800000
         CLI   ULWK10+K3,C'7'           HAS MAX NO. OF UTL ALREADY      44000000
         BNL   ULT165                   BEEN READ, BR IF YES            44100000
         B     ULT162                   BR NO TO CONTINUE               44200000
ULT161   CLI   ULWK10+K3,C'8'           HAS MAX NO. OF UHL ALREADY      44300000
         BNL   ULT165                   BEEN READ, BR IF YES            44400000
ULT162   OI    DXCCW6+K4,CCWCMDCH       ENSURE COMMAND CHAIN FLAG IN    44500000
*                                       VERIFICATION RD CKD IS ON       44600000
         B     ULT155                   GO PERFORM I/O                  44700000
*                                                                       44800000
*        MAXIMUM NUMBER OF LABELS HAVE ALREADY BEEN READ,               44900000
*        RETURN CODE CHANGED TO WRITE LABEL ONLY.                       45000000
*                                                                       45100000
ULT165   EQU   *                                                        45200000
         MVI   ULRETCOD,WRITNEXT        CHANGE RETURN CODE TO UPDATE    45300000
*                                                                       45400000
*        WRITE UPDATED LABEL                                            45500000
ULT170   EQU   *                                                        45600000
         NI    DXCCW6+K4,X'FF'-CCWCMDCH  TURN OFF CMND CHAIN FLAG IN RD 45700000
*                                  CCW THAT PERFORMS WRITE VERIFICATION 45800000
*                                                                       45900000
         BAL   RC,ULT470                GO WRITE UPDATED LABEL  SA55619 46000000
*                                                                       46100000
         TM    DXECB,ECBCOD7F           TEST IF I/O ERROR               46200000
         BO    ULT500                   BR IF NO, NO MORE PROCESSING    46300000
*                                                                       46400000
*********************************************************************** 46500000
*                                                                       46600000
*  I/O ERROR HAS OCCURRED                                               46700000
*                                                                       46800000
ULT200   EQU   *                                                        46900000
         LA    R1,DXIOB                 PUT PTR TO STATUS INFO IN       47000000
         ST    R1,ULERRPTR              PARAMETER LIST                  47100000
         MVI   ULERRPTR,ERROR           FLAG ERROR CONDITION(ALSO RESET 47200000
*                                       OTHER ERROR FLAGS TO ZERO).     47300000
*  DETERMINE TYPE OF CHANNEL PROGRAM BEING USED WHEN ERROR OCCURRED.    47400000
*                                                                       47500000
         CLI   ULRETCOD,WRITNEXT        IS ERROR ON READ ONLY           47600000
         BL    ULT210                   BR IF YES                       47700000
*                                       (IF ERROR ON FIRST READ,        47800000
*                                       ULRETCOD=0, BR TAKEN)           47900000
*        EITHER WRITING OR WRITING THEN READING                         48000000
         MVC   ULWK3+K1(K3),IOBCOMAD+K1  OBTAIN CSW POINTER             48100000
         L     R1,ULWK3                 FROM IOB                        48200000
         LA    R0,DXCCW7+K8             POINT 8 BYTES PAST READ CCW,    48300000
         CR    R1,R0                    THEN COMPARE WITH CSW POINTER   48400000
         BNE   ULT230                   BR IF ERROR DURING WRITE        48500000
*                                                                       48600000
*  READ ERROR                                                           48700000
*                                                                       48800000
ULT210   EQU   *                                                        48900000
         SR    R1,R1                                                    49000000
         IC    R1,ULWK6+K3              OBTAIN LAST CHAR OF KEY         49100000
         TM    ULWK2,X01                TEST IF ERROR ON FIRST READ     49200000
         BO    ULT220                   BR IF YES                       49300000
*                                       RECONSTRUCT KEY AREA            49400000
         MVC   ULWK10(K3),UHLCONST      'UHL' TO KEY AREA               49500000
         TM    DXREGC,XLIUTL            IS THIS INPUT UTL EXIT          49600000
         BNO   ULT215                   BR IF NO                SA55619 49700021
         MVC   ULWK10(K3),UTLCONST      'UTL' TO KEY AREA               49800000
ULT215   EQU   *                                                SA55619 49900021
         LA    R1,K1(R1)                INCREMENT 'N' OF KEY            50000000
         STC   R1,ULWK10+K3             AND PLACE IN KEY AREA           50100000
*        SET UP BUFFER TO TELL USER WHAT LABEL WE WERE UNABLE TO READ   50200000
ULT220   EQU   *                                                        50300000
         NI    ULWK2,X'FF'-X01          SET 1ST READ SW OFF IF ON       50400000
         MVC   ULBUFR(K3),UHLCONST      'UHL' TO BUFFER                 50500000
         CLI   DXREGC,XLIUHL            IS THIS INPUT UHL EXIT  SA55619 50550021
         BE    ULT225                   BR IF YES               SA55619 50600021
         MVC   ULBUFR(K3),UTLCONST      'UTL' TO BUFFER                 50800000
         LA    R1,K1(R1)                INCR N BY 1 SINCE START AT UTL0 50900000
ULT225   EQU   *                                                SA55619 51000021
         STC   R1,ULBUFR+K3             LABEL NUMBER TO BUFFER          51100000
         B     ULT240                   GO TO SYNCH TO USER EXIT RTN    51200000
*                                                                       51300000
*  WRITE ERROR                                                          51400000
*                                                                       51500000
ULT230   EQU   *                                                        51600000
         OI    ULERRPTR,ERROROUT        FLAG WRITE ERROR CONDITION      51700000
ULT240   EQU   *                                                        51800000
         LA    R1,ULBUFR                PTR TO LABEL BUFFER     SA55619 51850021
         BAL   RD,ULT420                GO TO SYNCH TO USER     SA55619 51900021
*                                                                       52000000
         LTR   RF,RF                    DID USER RETURN A CODE = 0      52100000
         BZ    ULT500                   BR IF YES, (NO MORE PROCESSING) 52200000
         ST    RF,ULWK1                 SAVE RETURN CODE                52300000
         CLI   ULRETCOD,READNEXT        DID USER RETURN A CODE = 4      52400000
         BE    ULT130                   BR IF YES, TO READ NEXT LABEL   52500000
         B     ULT500                   BR, INVALID CODE RETURNED       52600000
*                                                                       52700000
*********************************************************************** 52800000
*                                                                       52900000
*  NO USER LABEL TRACK WAS ALLOCATED FOR THIS DATA SET.                 53000000
*                                                                       53100000
ULT300   EQU   *                                                        53200000
         SR    R1,R1                    ZERO USER LABEL BUFFER PTR      53300000
         BAL   RD,ULT410                GO TO SYNCH TO USER     SA55619 53500021
*                                       EXIT RTN                        53550000
         B     ULT510                   BR TO RETURN TO CALLER          53600000
*                                                                       53700000
*********************************************************************** 53800000
*                                                                       53900000
*  SET UP ENQ/DEQ PARAMETER LIST (USING LABEL BUFFER AREA)              54000000
*                                                                       54100000
ULT400   EQU   *                                                        54200000
         MVC   ULBUFR(K4),ENQLIST       SET UP ENQ/DEQ CONSTANTS        54300000
         MVC   ULBUFR+K12(K8),QNAME     SET UP QNAME = SYSUSERL         54400000
         MVC   ULBUFR+K20(K2),DXDEBUCB+K2  SET UP RNAME AS              54500000
         MVC   ULBUFR+K22(K6),DXDAADDR+K1  UCB PTR AND BBCCHH           54600000
         LA    R0,ULBUFR+K12            PLACE POINTERS TO QNAME AND     54700000
         LA    R1,ULBUFR+K20            RNAME                           54800000
         STM   R0,R1,ULBUFR+K4          IN PARAMETER LIST               54900000
         LA    R1,ULBUFR                POINT TO PARAMETER LIST         55000000
         BR    RC                       RETURN TO CALLER                55100000
*                                                                       55200000
*********************************************************************** 55300000
*                                                                       55400000
*        CLOSED SUBROUTINE TO SAVE AND RESTORE REGISTERS, SET UP INPUT, 55500000
*        AND ISSUE THE SVC SYNCH  FOR SYNCHRONOUS EXIT TO PROBLEM PROG. 55600000
*        THIS MODULE'S REGISTERS 2-13 ARE SAVED IN THE SVRB EXTENDED    55700000
*        SAVE AREA, AND THE USER'S REGISTERS 2-13 ARE RESTORED FROM THE 55800000
*        SVRB.  REGISTER CONTENTS ARE AS FOLLOWS-                       55900000
*                        R0 - CONTAINS NO MEANINGFUL INFORMATION        56000000
*                        R1 - PTR TO PARAMETER LIST                     56100000
*                    R2-R13 - USER'S CONTENTS BEFORE I/O SUPPORT        56200000
*                       R14 - RETURN ADDRESS (SET BY SYNCH)             56300000
*                       R15 - USER'S EXIT ROUTINE ADDRESS               56400000
*                                                                       56500000
ULT410   EQU   *                                                SA55619 56600021
         XC    ULERRPTR,ULERRPTR        ZERO ERROR INDICATOR            56700000
ULT420   EQU   *                                                SA55619 57000021
         STM   R1,RDCB,ULBUFPTR         ESTABLISH PARMS- LABEL BUFFER   57100000
*                                       PTR AND DCB PTR                 57200000
         NI    ULDCBPTR,X'FF'-LASTNTRY  INSURE HI-ORDER BIT OF SECOND   57300000
*                              PARAMETER IS OFF (WOULD BE ON IF FEOV)   57400000
         CLI   DXREGC,XLIUHL            IS THIS INPUT UHL EXIT  SA55619 57450021
         BE    ULT450                   BR IF YES               SA55619 57500021
         AIF   ('&LIB' NE 'LIB1').LIB24L2                               57650000
         L     RDEB,DCBDEBAD            USER'S DEB ADDRESS              57700000
.LIB24L2 ANOP                                                           57750000
         AIF   ('&LIB' EQ 'LIB1').LIB14L2                               57760000
         L     RDEB,DXPDEBAD            LOAD PROTECTED DEB ADDR  Y01021 57770000
.LIB14L2 ANOP                                                           57780000
         CLI   WTGMODNM+K5,C'9'         IS THIS OPEN (IFG0195F)         57800000
         BE    ULT450                   BR IF YES               SA55619 57900021
         TM    DCBDSORG,DCBORGDA        IS DSORG DIRECT                 58000000
         BO    ULT425                   BR IF YES, INDICATE EOF SA55619 58050021
         SR    R1,R1                    CLEAR WORK REGISTER             58200000
         IC    R1,DEBNMEXT-DEB(,RDEB)   GET NUMBER OF EXTENTS           58300000
         SLL   R1,K4                    16(NO.EXTNTS)=LNGTH IN DEB      58400000
         LH    R1,K32(R1,RDEB)          GET DEB VOL SEQ NUMBER          58500000
         AH    R1,JFCBVLSQ              ADD JFCB VOL SEQ NUMBER         58600000
         SR    RF,RF                    CLEAR WORK REGISTER             58700000
         IC    RF,JFCBNVOL              GET TOTAL NUMBER OF VOLS        58800000
         CR    R1,RF                    COMPARE VOLS USED TO TOTAL      58900000
         BL    ULT450                   BR IF LOW, INDICATE EOV SA55619 59000021
ULT425   EQU   *                                                SA55619 59050021
         OI    ULDCBPTR,EOFFLG          INDICATE EOF            SA55619 59100021
*                                                                       59200000
ULT450   EQU   *                                                SA55619 59300021
         BAL   R1,ULT460                LOCATE SVRB             SM05248 59450021
         USING RBSECT,RET               DEFINE BASE TO SVRB             59500000
         NI    DCBOFLGS,X'FF'-DCBOLOCK  SET LOCK BIT TO 0               59850000
         STM   RDCB,RD,RBEXSAVE         SAVE I/O SUPP REGS IN SVRB ESA  59900000
         LA    R1,ULPARM                POINT TO PARAMETER LIST SM05248 59950021
         L     RF,DXREGC                GET ADDR OF USER'S EXIT         60200000
         LA    RF,0(RF)                 ROUTINE                         60300000
         LM    RDCB,RD,RBGRS2           RESTORE USER REGS 2-13          60400000
         DROP  RBASE                                            SA55619 60450021
*                                                                       60500000
         SYNCH (15)                     SYNCH TO USER EXIT ROUTINE      60600000
         DROP  RET                                                      60650000
*                                                                       60700000
         BALR  RET,0                    ESTABLISH TEMP BASE     SA55619 60800021
         USING *,RET                                            SA55619 60810021
         BAL   R1,ULT460                LOCATE SVRB             SM05248 60850021
         DROP  RET                                                      60860000
         USING RBSECT,RET               DEFINE BASE TO SVRB     SA55619 60900021
         LM    RDCB,RD,RBEXSAVE         RESTORE EOV REGISTERS   SA55619 61254021
         USING ULT000,RBASE             REESTABLISH ORIGINAL    SA55619 61254221
*                                       BASE                    SA55619 61254321
         AIF   ('&LIB' EQ 'LIB1').LIB14L3                               61259200
         CLI   WTGMODNM+K5,C'9'         IS THIS OPEN             Y01021 61261400
         BE    ULT455                   BRANCH IF YES           SA55619 61263621
*                                       DEBCHK ONLY FOR EOV      Y01021 61265800
         LR    RD,RF                    SAVE USER RETURN CODE    Y01021 61268000
         DEBCHK (RDCB)                  VALIDATE DEB             Y01021 61270200
         LR    RF,RD                    RESTORE RETURN CODE      Y01021 61272400
         L     RD,RBEXSAVE+K44          RESTORE REGISTER 13      Y01021 61274600
         LR    RDEB,R1                  LOAD VERIFIED DEB ADDR   Y01021 61276800
         ST    RDEB,DXPDEBAD            STORE VERIFIED DEB ADDR  Y01021 61279000
ULT455   EQU   *                                                SA55619 61281221
.LIB14L3 ANOP                                                           61283400
         OI    DCBOFLGS,DCBOLOCK        SET LOCK BIT = 1                61300000
         ST    RF,ULWK1                 SAVE RETURN CODE                61400000
         BR    RD                       RETURN FROM SYNCH EXIT SUBR     61500000
*                                                                       61600000
*                        SUBRTN TO LOCATE SVRB                          61700000
ULT460   EQU   *                                                SA55619 61710021
         L     RET,CVTPTR               LOAD CVT PTR            SA55619 61750021
         L     RET,CVTTCBP-CVT(,RET)    TCB DBL WDS             SA55619 61760021
         L     RET,K4(,RET)             TCB ADDRESS             SA55619 61770021
         L     RET,TCBRBP-TCB(,RET)     SVRB PTR                SA55619 61780021
         BR    R1                       RETURN TO CALLER        SM05248 61790021
*                                                                       61800000
*********************************************************************** 61900000
*                                                                       62000000
*                   CLOSED SUBROUTINE TO ISSUE I/O OPERATIONS           62100000
*                                                                       62200000
*        IT IS ASSUMED THAT ALL CONTROL BLOCKS HAVE ALREADY BEEN SET UP 62300000
*                                                                       62400000
ULT470   EQU   *                                                SA55619 62500021
         EXCP  DXIOB                    UPDATE / READ USER LABEL        62600000
*                                                                       62700000
         WAIT  ECB=DXECB                WAIT FOR I/O TO COMPLETE        62800000
*                                                                       62900000
         TM    IOBSTAT0,CSWUNITX        TEST IF UNIT EXCEPTION (EOF)    63000000
         BCR   14,RC                    BR RETURN IF NO                 63100000
*                                                                       63200000
         CLI   DXREGC,XLIUHL            IS THIS INPUT UHL EXIT  SA55619 63250021
         BE    ULT480                   BR IF YES               SA55619 63300021
         CLI   ULWK10+K3,C'0'           HAVE ANY UTL BEEN READ          63500000
         BH    ULT500                   PREVIOUSLY, BR IF YES           63600000
         B     ULT490                   BR NO TO CONTINUE       SA55619 63700021
ULT480   CLI   ULWK10+K3,C'1'           HAVE ANY UHL BEEN READ  SA55619 63800021
         BH    ULT500                   PREVIOUSLY, BR IF YES           63900000
*                                                                       64000000
*        NO HEADERS EXIST ON USER LABEL TRACK.                          64100000
ULT490   SR    R1,R1                    ZERO USER LABEL BUFFER  SA55619 64200021
*                                       PTR                             64250000
         XC    ULERRPTR,ULERRPTR        ZERO ERROR INDICATORS           64300000
         BAL   RD,ULT420                GO TO SYNCH TO USER     SA55619 64400021
*                                       EXIT RTN                        64500000
*********************************************************************** 64600000
*                                                                       64700000
*        NO FURTHER UL PROCESSING IS PERFORMED.  FREE CORE AND RETURN   64800000
*        TO CALLER.                                                     64900000
*                                                                       65000000
ULT500   EQU   *                                                        65100000
         TM    DCBDSORG,DCBORGDA        IS DS DIRECT ORGANIZATION       65200000
         BZ    ULT510                   BR IF NO                        65300000
         BAL   RC,ULT400                GO SET UP DEQ PARAMETER LIST    65400000
         DEQ   MF=(E,(1))               DEQ FROM USER LABEL TRACK       65500000
*                                                                       65600000
ULT510   EQU   *                                                        65700000
         L     R0,ULBFRLNG              LOAD BUFFER LENGTH AND  SA55619 65750021
*                                       SUBPOOL NO. INTO REG 0          65760000
         FREEMAIN R,LV=(0),A=(RUCB)     FREE UL AREA,           SA55619*65800021
                                        LABEL BUFFER AND PARAMETER LIST 65900000
*                                                                       66000000
*  RETURN TO CALLER                                                     66100000
*                                                                       66200000
         CLI   WTGMODNM+K5,C'9'         IS THIS OPEN (IFG0195F)         66300000
         BNE   ULT530                   BR IF NO                        66400000
         MVC   DXCCW7(K5),DXVOLMT2      RESTORE DSCB CCHHR ADDR         66500000
*                                                                       66600000
ULT530   EQU   *                                                        66700000
         LM    RTIOT,RET,DXREG9         RESTORE REGISTERS 9-14          66800000
         LM    R0,R1,DXREG0             RESTORE REGISTERS 0-1           66900000
*                                                                       67000000
         AIF   ('&LIB' EQ 'LIB1').LIB14L5                               67050002
         XC    DXRETTTR,DXRETTTR        ZERO TTR                 XM1389 67060002
.LIB14L5 ANOP                                                           67080002
         IECRES XCTL,DXRETMOD,(RET)     XCTL TO NEXT MODULE             67100000
*                                                                       67200000
         DROP  RUCB,RWTG                                                67300000
*                                                                       67400000
*********************************************************************** 67500000
*                                                                       67600000
*        CONSTANTS                                                      67700000
         DS    0F                                               SA55619 67750021
ULBFRLNG DC    AL1(250)                 SUBPOOL FOR USER LABEL  SA55619 67760021
*                                       BUFFER                  SA55619 67770021
         DC    AL3(ULWKEND-ULWK1)       LNG OF USER LABEL BFR   SA55619 67780021
*                                                                       67800000
*  CHANNEL PROGRAM TO READ FIRST HEADER/TRAILER LABEL                   67900000
ULCP1    DC    X'1200000040000008'      READ COUNT                      68000000
         DC    X'2900000040000004'      SEARCH KEY EQ                   68100000
         DC    X'0800000000000000'      TIC *-16                        68200000
         DC    X'0600000000000050'      READ DATA                       68300000
*                                                                       68400000
*  CCW 3 OF CHANNEL PROGRAM TO UPDATE LABEL                             68500000
ULCP2    DC    X'0500000040000050'      WRITE DATA                      68600000
*                                                                       68700000
*  PART OF CHANNEL PROG TO READ NEXT LABEL AFTER UPDATE PREVIOUS LABEL  68800000
ULCP3    DC    X'3100000040000005'      SEARCH ID EQ                    68900000
         DC    X'0800000000000000'      TIC *-8                         69000000
         DC    X'1E0000005000005C'      READ COUNT,KEY,DATA (SKIP)      69100000
RDCKD    DC    X'1E0000000000005C'      READ COUNT,KEY,DATA             69200000
*                                                                       69300000
UHLCONST DC    C'UHL1'                  KEY OF FIRST HEADER LABEL       69400000
UTLCONST DC    C'UTL0'                  KEY OF FIRST TRAILER LABEL      69500000
*  ENQ PARM LIST EQUIVALENT TO  ENQ (,,E,8,SYSTEM),MF=L                 69600000
ENQLIST  DC    X'FF084000'              ENQ/DEQ PARM LIST CONSTANT      69700000
QNAME    DC    C'SYSUSERL'              QNAME USED IN ENQ/DEQ ON        69800000
*                                       USER LABEL TRACK                69900000
*                                                                       70000000
         AIF   ('&LIB' NE 'LIB1').LIB24L4                               70050000
         XCTLTABL SVC=055                                               70100000
.LIB24L4 ANOP                                                           70150000
         AIF   ('&LIB' EQ 'LIB1').LIB14L4                               70160000
         XCTLTABL SVC=055,LENGTH=2048,PATCH=100                  Y01021 70170000
.LIB14L4 ANOP                                                           70180000
*                                                                       70200000
         IECDSECS EXPAND=YES            EXPAND DESIRED DSECTS HERE      70300000
*                                                                       70400000
         END                                                            70500000
