         TITLE 'IFG0555B / DA OUTPUT USER TRAILER LABEL PROCESSING'     00200000
         GBLC  &LIB                                                     00400000
&LIB     SETC  'LIB1'                                                   00600000
*TITLE - IFG0555B / DA OUTPUT USER TRAILER LABEL PROCESSING           * 00800000
*********************************************************************** 01000000
*                                                                     * 01200000
*                                                                     * 01400000
*         RELEASE 25 DELETIONS/CHANGES                                * 01600000
*         RELEASE 24 DELETIONS/CHANGES                                * 01800000
*         RELEASE 23 DELETIONS/CHANGES                                * 02000000
*         RELEASE 22 DELETIONS/CHANGES                                * 02200000
*         RELEASE 21 DELETIONS/CHANGES                                * 02400000
*                                                                     * 02600000
*STATUS CHANGE LEVEL 000                                              * 02800000
*                                                                     * 03000000
*FUNCTION/OPERATION -                                                 * 03200000
*   THIS MODULE IS USED BY I/O SUPPORT ROUTINE  (EOV) TO WRITE        * 03400000
*   UP TO EIGHT USER TRAILER LABELS AS REQUIRED FOR DATA SETS         * 03600000
*   ON DIRECT ACCESS VOLUMES.  IT IS ENTERED ONCE FOR EACH DCB TO     * 03800000
*   BE PROCESSED.                                                     * 04000000
*      THE MODULE GETS AN AREA OF MAIN STORAGE WHICH IS USED AS A     * 04200000
*   WORKAREA-BUFFER IN WHICH THE USER LABEL RECORDS ARE FORMATTED AND * 04400000
*   AS A SAVE AREA FOR THE REGISTERS OF THE I/O SUPPORT FUNCTION      * 04600000
*   REQUIRING USER LABEL PROCESSING.  THE LAST PART OF THE AREA       * 04800000
*   OBTAINED IS USED FOR A 16-BYTE PARAMETER LIST.                    * 05000000
*      IF A TRACK WAS ALLOCATED FOR USER LBLS,CONTROL IS GIVEN TO THE * 05200000
*   USER'S LABEL CONSTRUCTION ROUTINE VIA SYNCHRONOUS EXIT (SVC 12).  * 05400000
*   ON RETURN FROM THE USER'S ROUTINE, IF A LABEL WAS CONSTRUCTED, IT * 05600000
*   IS WRITTEN FOLLOWED BY 2 FILEMARKS FOR HEADERS (UHL(N+1),UTL0) OR * 05800000
*   ONE FILEMARK FOR TRAILERS (UTL(N+1).  DEPENDING ON THE RETURN     * 06000000
*   CODE PASSED BY THE USER'S ROUTINE, ANOTHER LABEL IS PROCESSED OR  * 06200000
*   CONTROL IS GIVEN BACK TO THE I/O SUPPORT FUNCTION WHICH CALLED    * 06400000
*   THIS MODULE.                                                      * 06600000
*                                                                     * 06800000
*ENTRY POINTS -                                                       * 07000000
*   IFG0555B -INITIAL ENTRY TO THIS MODULE IS BY MEANS OF XCTL FROM   * 07200000
*             EOV.                                                    * 07400000
*                                                                     * 07600000
*INPUT -                                                              * 07800000
*   REGISTERS                                                         * 08000000
*     RDCB  2  -ADDRESS OF DCB AT END OF VOLUME.                      * 08200000
*     RCORE 4  -ADDRESS OF 536 BYTE WORK AREA.                        * 08400000
*     RES   5  -ADDRESS OF RESIDENT ROUTINE.                          * 08600000
*     RTIOT 9  -ADDRESS OF THE DATA SET ENTRY IN THE TIOT.            * 08800000
*     RUCB 10  -ADDRESS OF UCB FOR  UNIT AT END OF VOLUME.            * 09000000
*     RDEB 11  -ADDRESS OF DEB FOR DATA SET AT END OF VOLUME.         * 09200000
*             12   - EXIT LIST ENTRY FOR EXIT TO BE TAKEN             * 09400000
*                    BITS 3-7 EXIT TYPE CODE                          * 09600000
*                         8-31 EXIT ADDRESS, ZEROES IF NO ACTIVE EXIT * 09800000
*                                                                     * 10000000
*   JFCBMASK+5 (IN I/O SUPPORT WORK AREA) BITS 5-6 INDICATE FUNCTION  * 10200000
*              REQUIRING USER LABEL PROCESSING                        * 10400000
*                                                                     * 10600000
*                    EOV    11                                        * 10800000
*                                                                     * 11000000
*OUTPUT -                                                             * 11200000
*   USER LABELS ARE WRITTEN AS REQUESTED                              * 11400000
*   ON FINAL EXIT REGISTERS 2-11 HAVE CONTENTS AS AT ENTRY TO THIS    * 11600000
*   MODULE.                                                           * 11800000
*                                                                     * 12000000
*EXTERNAL ROUTINES -                                                  * 12200000
*   USER'S OUTPUT LABEL EXIT ROUTINES - ENTERED BY MEANS OF           * 12400000
*      SYNCHRONOUS EXIT (SVC 12) WITH THE FOLLOWING INPUT             * 12600000
*                                                                     * 12800000
*                    REG 0    CONTAINS NO MEANINGFUL INFO             * 13000000
*                        1    POINTER TO 4 WORD PARAMETER LIST WHICH  * 13200000
*                             CONTAINS -                              * 13400000
*                               POINTER TO LABEL BUFFER               * 13600000
*                               POINTER TO DCB                        * 13800000
*                               FLAG BYTE, PTR TO STATUS INFO (IF     * 14000000
*                                          PERMANENT ERROR) OR ZERO   * 14200000
*                               POINTER TO IMAGE AREA (IF TOTALING    * 14400000
*                               WAS REQUESTED) OR ZERO                * 14600000
*                        2-13 CONTENTS OF USER'S REGS BEFORE I/O SUPP * 14800000
*                        14   RETURN ADDRESS                          * 15000000
*                        15   EXIT ADDRESS                            * 15200000
*                                                                     * 15400000
*      BEFORE EXITING, THIS MODULE'S REGISTERS 2-13 ARE SAVED IN THE  * 15600000
*      SVRB EXTENDED SAVE AREA.  THE USER'S REGISTERS 2-13 ARE        * 15800000
*      RESTORED FROM THE SVRB.  THE LOCK BIT (BIT 6) IN DCBOFLGS      * 16000000
*      FIELD IS SET TO 1 TO PREVENT ANOTHER I/O SUPPORT FUNCTION FROM * 16200000
*      OPERATING ON THIS DCB WHILE THE USER IS IN CONTROL.  ON RETURN * 16400000
*      FROM THE USER'S ROUTINE, THIS BIT IS RESET TO 0.               * 16600000
*                                                                     * 16800000
*EXITS-NORMAL                                                         * 17000000
*   EXIT IS MADE TO THE USER' OUTPUT HEADER OR OUTPUT TRAILER         * 17200000
*   ROUTINES AS REQUESTED BY USER (MAXIMUM NUMBER OF LABELS IS EIGHT).* 17400000
*                                                                     * 17600000
*   FINAL EXIT IS VIA XCTL TO THE I/O SUPPORT FUNCTION WHICH CALLED   * 17800000
*      THIS MODULE.                                                   * 18000000
*                                                                     * 18200000
*                   TRAILER PROCESSING                                * 18400000
*                        EOV     IFG0554Z                             * 18600000
*                                                                     * 18800000
*EXITS-ERROR                                                          * 19000000
*   NO USER    LABEL EXTENT EXISTS-THE APPROPRIATE EXIT ROUTINE IS    * 19200000
*      ENTERED WITH THE BUFFER POINTER SET TO ZERO.   OTHER           * 19400000
*      INPUT AS USUAL.                                                * 19600000
*                                                                     * 19800000
*   I/O ERROR WRITING A USER LABEL - THE USER'S ROUTINE IS ENTERED.   * 20000000
*      AGAIN WITH                                                     * 20200000
*                 BIT 0 OF FLAG BYTE SET TO ONE, PTR TO STANDARD      * 20400000
*                 STATUS INFORMATION                                  * 20600000
*                 OTHER INPUT AS FOR NORMAL ENTRY                     * 20800000
*                                                                     * 21000000
*TABLES/WORKAREAS -                                                   * 21200000
*   FORMAT AND CONTENTS OF THE WORK AREAS USED ARE DESCRIBED BY THE   * 21400000
*   DSECTS AT THE END OF THIS LISTING.                                * 21600000
*                                                                     * 21800000
*ATTRIBUTES -                                                         * 22000000
*   REENTRANT, ENABLED, PRIVILEGED                                    * 22200000
*                                                                     * 22400000
*NOTES- N/A                                                           * 22600000
*                                                                     * 22800000
*                                                                     * 23000000
*********************************************************************** 23200000
         EJECT                                                          23400000
*********************************************************************** 23600000
*                                                                     * 23800000
*                                                                     * 24000000
*                                                                     * 24200000
*                                                                       24400000
IFG0555B CSECT                                                          24600000
         IECEQU                                                         24800000
         USING ULWK,R8                                                  25000000
         USING IHADCB,RDCB                                              25200000
         USING FORCORE,RCORE                                            25400000
         USING UCBOB,RUCB                                               25600000
         USING TCB,RET                                                  25800000
         BALR  RBASE,0                  ESTABLISH BASE REGISTER         26000000
         USING *,RBASE                                                  26200000
*                                                                       26400000
         GETMAIN R,LV=USERL,SP=250      GET CORE FOR WORK AREA, LABEL   26600000
*                                       BUFFER AND PARAMETER LIST (72+8 26800000
*                                                                       27000000
         STM   RPAR,RC,K0(R1)           SAVE REGS 5-12 FOR CALLER       27200000
         XC    K32(K120,R1),K32(R1)     CLEAR WKAREA AND BUFFER         27400000
         LR    R8,R1                    SET BASE FOR ULWK DSECT         27600000
         L     R7,DXCCW5                PICK UP INFO AND SAVE IN DXCCW9 27800000
         NI    K28(R8),X'FF'-LASTNTRY   TURN OFF LAST ENTRY INDIC IF ON 28000000
         XC    DXCCW1(K80),DXCCW1       CLEAR CHAN PROG AREA            28200000
         ST    R7,DXCCW9                SAVE INFO FOR 554Z              28400000
*                                                                       28600000
*        DETERMINE IF A USER LABEL EXTENT HAS BEEN ALLOCATED FOR THIS   28800000
*        DATA SET.                                                      29000000
*                                                                       29200000
         CLI   DSCEXTYP,ULEXTYP         IS 1ST EXTENT FOR USER LABELS   29400000
         BNE   EDO18050                 NO EXTENT, GO TO USER           29600000
*                                                                       29800000
*        EXTENT EXISTS - PROCESS USER LABELS                            30000000
*                                                                       30200000
         XC    DXDAADDR(K8),DXDAADDR    ZERO IOBOADAD IN IOS' IOB       30400000
         MVC   DXDAADDR+K3(K4),DSCLOWLM  CCHH FROM START OF 1ST EXTENT  30600000
*                                       IF 2321, GET BB FROM UCB        30800000
         CLI   UCBID,UCBMAIN            IS DEVICE 2321                  31000000
         BE    EDO16700                 NO,BRANCH AROUND 2321 CODE      31200000
         USING UCBDCELL,RUCB                                            31400000
         MVC   DXDAADDR+K1(K2),UCBDBBNR  2321, GET BB FROM SUB-VCB      31600000
         USING UCBOB,RUCB                                               31800000
*                                                                       32000000
EDO16700 EQU   *                                                        32200000
*                                                                       32400000
*        PROCESS USER TRAILER LABELS.                                   32600000
*                                                                       32800000
*                        SET UP CHANNEL PROGRAM TO FIND                 33000000
*                                                                       33200000
*        STRUCTURE COUNT AND KEY FIELDS IN WORK AREA.  SET IOBDADAD     33400000
*        IN I/O SUPPORT'S IOB.                                          33600000
*                                                                       33800000
         LA    R1,ULWK8                                                 34000000
         ST    R1,DXCCW1                READ COUNT INTO WK1             34200000
         LA    R1,ULWK10                                                34400000
         ST    R1,DXCCW2                SEARCH ON KEY IN WK3            34600000
         LA    R1,DXCCW1                                                34800000
         ST    R1,DXCCW3                TIC TO CCW1                     35000000
         OC    DXCCW1(K32),ULCP13       OR CP SKELETON OVER ADDRESSES   35200000
         MVC   ULWK10(K4),UTLCONS3      KEY=UTLO FOR SEARCH KEY EQUAL   35400000
*                                                                       35600000
         BAL   RC,EDO18100              EXECUTE CP TO FIND UTL0         35800000
         TM    DXECB,ECBNOERR           CHECK FOR I/O ERROR             36000000
         BZ    EDO17200                 ERROR, BR TO SET UP EXIT TO USR 36200000
*                                                                       36400000
*                        SET UP  CP TO WRITE USER TRAILE                36600000
*                        AS EACH LABEL (UTLN) IS WRITTEN, A FILE        36800000
*                           MARK (UTL(N+1)) WILL BE WRITTEN FOLLOWING   37000000
*                                                                       37200000
         XC    DXCCW1(K32),DXCCW1       CLEAR CHNL PGM 1 OUT            37400000
         BAL   RPARC,EDO18000           GO SET UP CP                    37600000
         OC    DXCCW1(K32),ULCP23       OR CP SKELETON OVER ADDRESSES   37800000
         MVC   DXCCW5(K24),DXCCW1       APPEND CP FOR WRITE CHECKING    38000000
         LA    R1,DXCCW5                                                38200000
         ST    R1,DXCCW6                TIC BACK TO CCW5                38400000
         MVI   DXCCW6,CCWTIC            RESTORE TIC OP                  38600000
         MVI   DXCCW7,X'1E'             MAKE OP READ                    38800000
         OI    DXCCW7+K4,X'10'          SET SKIP BIT ON                 39000000
         NI    DXCCW7+K4,X'FF'-CCWCMDCH  TURN OFF CC FLAG IN LAST CCW   39200000
         MVC   ULWK5(K12),ULWK8         SET UP COUNT, KEY FOR FILE MARK 39400000
         SR    R1,R1                    CLEAR RF                        39600000
         STC   R1,ULWK6+K3              DATA LENGTH=0 FOR FILE MRK      39800000
*                                       IF DISP=MOD,UTL0 MAY HAVE       40000000
*                                       LENGTH OF 80 BYTES              40200000
*                                                                       40400000
EDO17100 EQU   *                                                        40600000
         IC    R1,ULWK9                 R OF COUNT FOR UTL TO BE WRITTN 40800000
         BCTR  R1,0                     R-1                             41000000
         STC   R1,DXDAADDR+K7           R IN IOBDADAD                   41200000
         LA    R1,K2(,R1)               R-1+2=R+1                       41400000
         STC   R1,ULWK6                 R IN COUNT FIELD OF UTL(N+1)    41600000
*                                                                       41800000
         IC    R1,ULWK10+K3             N FROM LABEL TO BE WRITTEN      42000000
         LA    R1,K1(,R1)               N+1                             42200000
         STC   R1,ULWK7+K3              KEY FOR UTL(N+1)                42400000
*                                                                       42600000
         MVI   ULWK9+K3,K80             DATA LENGTH = 80 FOR UTLN       42800000
*                                                                       43000000
         CLI   ULWK10+K3,X'F8'          CHECK IF 8 TRAILERS WERE WRITTN 43200000
         BNL   EDO17300                 YES, BRANCH TO SET UP RETURN    43400000
*                                                                       43600000
         MVC   ULBUFR(K4),ULWK7         PRIME LABEL BUFFER WITH UTLN    43800000
*                                                                       44000000
*        GO TO USER'S ROUTINE TO CONSTRUCT LABEL.                       44200000
*                                                                       44400000
         BAL   RPARC,EDO18200           GO EXIT TO USER'S ROUTINE       44600000
         MVC   ULBUFR(K4),ULWK7         REINSERT UTLN                   44800000
         LTR   RF,RF                    CHECK FOR RETURN CODE=0         45000000
         BZ    EDO17300                 CODE IS ZERO, BRANCH TO RETURN  45200000
         ST    RF,ULWK1                 SAVE RETURN CODE                45400000
         BAL   RC,EDO18100              GO WRITE LABEL                  45600000
*                                                                       45800000
         TM    DXECB,ECBNOERR           CHECK FOR I/O ERROR             46000000
         BZ    EDO17200                 YES, BR TO TAKE SPECIAL EXIT    46200000
         CLI   ULWK1+K3,XLOUTL          CHECK RET CODE FOR MORE LABELS  46400000
         BE    EDO17300                 NO, PREVIOUS LABEL WAS LAST     46600000
         CLI   ULWK1+K3,X'08'           CHECK,BR IF RETURN CODE         46800000
         BNE   EDO17300                 WAS NOT VALID                   47000000
*                                                                       47200000
         MVC   ULWK8(K12),ULWK5         UTL(N+1) BECOMES C,K OF NXT LBL 47400000
         B     EDO17100                 BR TO PROCESS NEXT LABEL        47600000
EDO17200 EQU   *                                                        47800000
*                                                                       48000000
*        IF AN I/O ERROR OCCURS WRITING USER TRAILER LABELS, A SPECIAL  48200000
*        EXIT IS TAKEN TO THE USER'S ROUTINE.  INPUT TO THE USER'S      48400000
*        ROUTINE IS THE SAME AS FOR OTHER EXITS WITH ONE EXCEPTION-     48600000
*        IN THE THIRD WORD OF THE PARAMETER LIST, BIT 0 IS SET TO ONE   48800000
*        AND THE THREE LOW ORDER BYTES CONTAIN A POINTER TO STATUS      49000000
*        INFO (PTR TO IOB).                                             49200000
*                                                                       49400000
         LA    R1,DXIOB                 INSERT POINTER TO STATUS INFO   49600000
         ST    R1,ULPARM+K8             IN PARAMETER LIST               49800000
         OI    ULPARM+K8,ERROR          FLAG ERROR                      50000000
         BAL   RPARC,EDO18300           GO TO SYNCH TO USER             50200000
*                                                                       50400000
*        DETERMINE WHICH I/O SUPPORT FUNCTION  REQUIRED USER            50600000
*        TRAILER LABELS TO BE WRITTEN                                   50800000
*                                                                       51000000
EDO17300 EQU   *                        SET RETURN FOR TRLR PROCESSING  51200000
         TM    JFCBMASK+K5,X'06'        DETERMINE CALLER                51400000
         BO    EDO17900                 BR IF CALLED FROM EOV           51600000
*                                                                       51800000
*        CONTROL IS FROM CLOSE.  FOR NEW DIRECT DATA SETS, THE          52000000
*        UCB ADDRESS IN THE WORK DEB REFLECTS THE 1ST VOLUME AND MUST   52200000
*        BE RESTORED TO THE UCB ADDRESS FOR THE CURRENT VOLUME BEFORE   52400000
*        CONTINUING WITH CLOSE PROCESSING.                              52600000
*                                                                       52800000
         USING TIOENTRY,RTIOT           ESTABLISH BASE FOR TIOT ENTRY   53000000
         L     RUCB,TIOESTTB            GET ADDRESS OF CURRENT UCB      53200000
         DROP  RTIOT                    DROP TIOT BASE                  53400000
*                                                                       53600000
*              COMPUTE MAIN UCB ADDRESS                                 53800000
*                                                                       54000000
         SR    RET,RET                  CLEAR REG                       54200000
         CLI   UCBID,UCBMAIN            IS DEVICE 2321                  54400000
         BE    EDO17400                 BR IF NOT 2321                  54600000
         USING UCBDCELL,RUCB            BASE FOR SUB-UCB                54800000
         LH    RET,UCBDBBNR             PICK UP BB                      55000000
         SLA   RET,K4                   MPY BY 16                       55200000
         LA    RET,UCBDCELL-UCBOB(RET)  16(BB)+LENGTH MAIN UCB          55400000
         LCR   RET,RET                  NEGATE                          55600000
EDO17400 EQU   *                                                        55800000
         AR    RET,RUCB                 MAIN UCB ADDRESS                56000000
*                                                                       56200000
         ST    RET,DXCCW10              STORE MAIN UCB ADDRESS          56400000
         MVC   DXDEBUCB+K1(K3),DXCCW10+K1  RESTORE WORK DEB UCB ADDR    56600000
         OI    K31(RWTG),X'08'          SET UL-RETURN INDICATION        56800000
*                              USED BY OPEN/CLOSE                       57000000
*                                                                       57200000
*        FREE  WORKAREA AND LABEL BUFFER AND XCTL TO I/O SUPPORT        57400000
*        MODULE WHICH CALLED THIS MODULE.                               57600000
*                                                                       57800000
EDO17900 EQU   *                                                        58000000
         MVC   DXCCW5(K8),DXCCW9        RESTORE DXCCW5 FOR 554Z         58200000
*                                                                       58400000
         LR    R1,R8                    START OF AREA TO BE FREED       58600000
         LM    RPAR,RDEB,K0(R1)         RESTORE CALLING MODULE'S REGS   58800000
         FREEMAIN R,LV=USERL,SP=250,A=(1)  FREE USER LABEL WORK AREA,  C59000000
                                        LABEL BUFFER AND PARAMETER LIST 59200000
         LA    RET,K4                                                   59400000
         LA    R7,EOVT                  SET XCTL TO 554Z                59600000
         LA    RWTGC,DXXENTRY           SET R8 FOR RES RTN              59800000
         LA    RWTG,DXXAREA             POINT TO EOV WTG                60000000
         IECRES XCTL,(R7),(RET)                                         60200000
*                                                                       60400000
EDO18000 EQU   *                                                        60600000
         LA    R1,DXDAADDR+K3                                           60800000
         ST    R1,DXCCW1                SEARCH ID FROM IOBDADAD+3       61000000
         LA    R1,DXCCW1                                                61200000
         ST    R1,DXCCW2                TIC TO CCW1                     61400000
         LA    R1,ULWK8                                                 61600000
         ST    R1,DXCCW3                WRITE C,K FROM ULWK1            61800000
         LA    R1,ULWK5                                                 62000000
         ST    R1,DXCCW4                WRITE LABEL FROM BUFFER         62200000
         BR    RPARC                    UNCONDITIONAL BRANCH            62400000
*                                                                       62600000
*                                                                       62800000
*        NO USER LABEL TRACK WAS ALLOCATED.  EXIT TO USER'S ROUTINE     63000000
*        WITH POINTER TO LABEL BUFFER ZEROED.                           63200000
*                                                                       63400000
EDO18050 EQU   *                                                        63600000
         XC    ULPARM+K8(K4),ULPARM+K8  CLEAR ANY ERROR INDICTNS        63800000
         SR    R1,R1                    BUFFER POINTER TO ZERO          64000000
         LA    RPARC,EDO17300           POINT TO RETURN AFTER SYNCH     64200000
         B     EDO18400                 GO SYNCH TO USER                64400000
*                                                                       64600000
         SPACE 2                                                        64800000
*                                                                       65000000
*        CLOSED SUBROUTINE TO ISSUE I/O OPERATIONS                      65200000
*                                                                       65400000
         SPACE                                                          65600000
*        IT IS ASSUMED THAT ALL CONTROL BLOCKS HAVE ALREADY BEEN SET UP 65800000
         SPACE 3                                                        66000000
EDO18100 EQU   *                                                        66200000
         EXCP  DXIOB                                                    66400000
*                                                                       66600000
         WAIT  ,ECB=DXECB                                               66800000
*                                                                       67000000
         BR    RC                       UNCONDITIONAL BRANCH            67200000
         SPACE 5                                                        67400000
*        CLOSED SUBROUTINE TO SAVE AND RESTORE REGISTERS, SET UP INPUT, 67600000
*        AND ISSUE THE SVC SYNCH  FOR SYNCHRONOUS EXIT TO PROBLEM PROG. 67800000
*        THIS MODULE'S REGISTERS 2-13 ARE SAVED IN THE SVRB EXTENDED    68000000
*        SAVE AREA AND THE USER'S REGISTERS 2-13 ARE RESTORED FROM THE  68200000
*        SVRB.  REGISTER CONTENTS ARE AS FOLLOWS-                       68400000
*                        R0 - CONTAINS NO MEANINGFUL INFO               68600000
*                        R1 - PTR TO PARAMETER LIST                     68800000
*                    R2-R13 - USER'S CONTENTS BEFORE I/O SUPPORT        69000000
*                       R14 - RETURN ADDRESS (SET BY SYNCH)             69200000
*                       R15 - EXIT ADDRESS                              69400000
*                                                                       69600000
EDO18200 EQU   *                                                        69800000
         XC    ULPARM+K8(K4),ULPARM+K8  ZERO ERROR INDICATIONS          70000000
EDO18300 EQU   *                                                        70200000
         LA    R1,ULBUFR                PTR TO LABEL BUFFER             70400000
EDO18400 EQU   *                                                        70600000
         STM   R1,RDCB,ULPARM           BUFFER,DCB PTRS TO PARM LIST    70800000
         NI    ULDCBPTR,X'FF'-EOFFLG    INSURE EOF FLG IS OFF           71000000
         XC    ULPARM+K12(K4),ULPARM+K12  ZERO TOTALING AREA            71200000
         TM    DCBDSORG,DCBORGDA        CK FOR DIRECT ORGANIZATION      71400000
         BO    EDO18500                 BR IF DIRECT                    71600000
         TM    DCBOFLGS,DCBOPEN         CK IF DCB ALREADY OPEN          71800000
         BZ    EDO18500                 IF YES, CTL FROM OPEN, BYPASS   72000000
*                                       TOTALING                        72200000
         TM    DCBMACRF,DCBMEXCP        CK IF EXCP                      72400000
         BO    EDO18500                 BR IF EXCP,SKIP TOTALING        72600000
         TM    DCBOPTCD,DCBOPTT         TEST,BR IF USER TOTALING        72800000
         BZ    EDO18500                 HAS NOT BEEN REQUESTED          73000000
*                                                                       73200000
         L     RDEB,DCBDEBAD            GET ADDRESS OF USER'S DEB       73400000
         SR    R1,R1                    CLEAR WORK REG                  73600000
         IC    R1,DEBNMEXT-DEB(RDEB)    GET NUMBER OF EXTENTS           73800000
         SLL   R1,K4                    MULTIPLY BY 16                  74000000
         L     RDEB,K36(R1,RDEB)        GET ADDR TOTALING WORKAREA-     74200000
*                                       DEB ADDR+32+4+LENGTH EXTENTS    74400000
         USING TOTSAVWA,RDEB            SET BASE - TOTALING AREA        74600000
         MVC   ULTOTPTR,TOTEOVPT        CURRENT IMAGE AREA ADDR TO      74800000
*                                       USR LBL PARM LIST               75000000
         DROP  RDEB                     DROP TOTALING AREA BASE         75200000
*                                                                       75400000
EDO18500 EQU   *                                                        75600000
         LA    R1,ULPARM                POINT TO PARAMETER LIST         75800000
         L     RET,CVTPTR               CVT ADDRESS                     76000000
         L     RET,CVTTCBP-CVT(,RET)    TCB PTR                         76200000
         L     RET,K4(,RET)             TCB ADDRESS                     76400000
         L     RET,TCBPRB               SVRB ADDRESS                    76600000
         NI    DCBOFLGS,X'FF'-DCBOLOCK  SET LOCK BIT = 0                76800000
         STM   RDCB,RD,K96(RET)         SAVE I/O SUPP REGS IN SVRB AREA 77000000
         L     RF,K28(,R8)              ADDRESS OF USER'S ROUTINE       77200000
         LA    RF,K0(,RF)               ROUTINE                         77400000
         L     RD,K28(,RET)             PTR TO PREVIOUS RB              77600000
         TM    K10(RD),X'C0'            IS PREVIOUS A PRB?              77800000
         BNO   EDO18600                 YES,BRANCH                      78000000
         LR    RET,RD                   USE PREVIOUS RB                 78200000
EDO18600 EQU   *                                                        78400000
         LM    RDCB,RD,K40(RET)         RESTORE USER REGS               78600000
         SYNCH (RF)                                                     78800000
         L     RET,CVTPTR               CVT ADDRESS                     79000000
         L     RET,CVTTCBP-CVT(,RET)    TCB  PTR                        79200000
         L     RET,K4(,RET)             TCB  ADDRESS                    79400000
         L     RET,TCBPRB               SVRB ADDRESS                    79600000
         LM    RDCB,RD,K96(RET)         RESTORE I/O SUPPORT REGS        79800000
         OI    DCBOFLGS,DCBOLOCK        SET LOCK BIT = 1                80000000
         MVC   ULBUFR(K4),ULWK10        REINSERT  UTLN/UHLN             80200000
         BR    RPARC                    UNCONDITIONAL BRANCH            80400000
         SPACE 5                                                        80600000
         DS    0F                                                       80800000
UTLCONS3 DC    C'UTL0'                  KEY USED IN SEARCH KEY EQ       81000000
ULCP13   CCW   X'12',0,X'40',8          READ COUNT                      81200000
         CCW   X'29',0,X'40',4          SEARCH KEY EQUAL                81400000
         CCW   X'08',0,0,0              TIC                             81600000
         CCW   X'03',0,0,1              NOP                             81800000
*                                                                       82000000
ULCP23   CCW   X'31',0,X'40',5          SEARCH ID EQUAL                 82200000
         CCW   X'08',0,0,0              TIC TO CCW1                     82400000
         CCW   X'1D',0,X'40',92         WRITE CKD    UHLN     LABEL     82600000
         CCW   X'1D',0,X'40',12         WRITE CKD    UHL(N+1) FILE MARK 82800000
         CCW   X'1D',0,X'40',12         WRITE CKD    UTL0     FILE MARK 83000000
*                                                                       83200000
*        XCTL  TABLE FOR IFG0555B                                       83400000
*                                                                       83600000
         XCTLTABL SVC=055,ID=(EOVT,4Z)                                  83800000
         IECDSECS CVT,TCB,TIOT,SMF,DCB,DEB,UCB,MAIN,UNITTAB,           X84000000
               USERLAB,USERTOT,WTG,EXPAND=YES                           84200000
         END                                                            84400000
