         TITLE 'IFG0555J, ALIAS IFG0196P/EOV, OPEN - DA OUTPUT USER HEAX00100000
               DER LABELS'                                              00200000
         GBLC  &LIB                     DEFINE GLOBAL CHAR VARIABLE     00300000
&LIB     SETC  'LIB1'                   SET VALUE FOR OS /360           00400000
IFG0555J CSECT                                                          00500000
*********************************************************************** 00600000
*                                                                     * 00700000
*                                                                     * 00800000
*          RELEASE 25 DELETIONS/CHANGES                               * 00900000
*          RELEASE 24 DELETIONS/CHANGES                               * 01000000
*          RELEASE 23 DELETIONS/CHANGES                               * 01100000
*          RELEASE 22 DELETIONS/CHANGES                               * 01200000
*          RELEASE 21 DELETIONS/CHANGES                               * 01300000
*                                                                     * 01400000
* STATUS CHANGE LEVEL 000                                             * 01500000
*                                                                     * 01600000
* FUNCTION -                                                          * 01700000
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 01800000
*    DA OUTPUT USER HEADER LABELS                                     * 01900000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)' FOR DETAILS.         * 02000000
*                                                                     * 02100000
* ENTRY POINTS -                                                      * 02200000
*         IFG0555J, ALIAS IFG0196P                                    * 02300000
*                                                                     * 02400000
* INPUT -                                                             * 02500000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 02600000
*                                                                     * 02700000
* OUTPUT -                                                            * 02800000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 02900000
*                                                                     * 03000000
* EXTERNAL REFERENCES -                                               * 03100000
*         IFG019RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 03200000
*            WAIT.                                                    * 03300000
*         REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                * 03400000
*                                                                     * 03500000
* EXITS, NORMAL -                                                     * 03600000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 03700000
*                                                                     * 03800000
* EXITS, ERROR -                                                      * 03900000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 04000000
*                                                                     * 04100000
* TABLES/WORK AREAS -                                                 * 04200000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 04300000
*                                                                     * 04400000
* ATTRIBUTES -                                                        * 04500000
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 04600000
*                                                                     * 04700000
* CHARACTER CODE DEPENDENCY -                                         * 04800000
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 04900000
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 05000000
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 05100000
*                                                                     * 05200000
* NOTES -                                                             * 05300000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05400000
*                                                                     * 05500000
*********************************************************************** 05600000
         EJECT                                                          05700000
*********************************************************************** 05800000
*                                                                     * 05900000
*                          FUNCTION PROLOG                            * 06000000
*                                                                     * 06100000
*********************************************************************** 06200000
*                                                                     * 06300000
* FUNCTION NAME -                                                     * 06400000
*    DA OUTPUT USER HEADER LABELS                                     * 06500000
*                                                                     * 06600000
* (STATUS) -                                                          * 06700000
*    NOT APPLICABLE                                                   * 06800000
*                                                                     * 06900000
* FUNCTION -                                                          * 07000000
*    THIS MODULE WRITES OUTPUT USER HEADER LABELS FOR OPEN AND EOV    * 07100000
*    UNDER THE CONTROL OF THE USER'S OUTPUT USER HEADER TRAILER       * 07200000
*    LABERL ROUTINE, OR MERELY FORMATS THE USER LABEL TRACK IF        * 07300000
*    NO USER LABEL EXIT ROUTINE EXISTS AND THE DATA SET IS BEING      * 07400000
*    PROCESSED FOR OUTPUT AND LABEL=SUL.                              * 07500000
*                                                                     * 07600000
*    AN AREA OF MAIN STORAGE IS OBTAINED FROM SUBPOOL 250 FOR         * 07700000
*    USE AS A WORK AREA, LABEL BUFFER, AND PARAMETER LIST.            * 07800000
*                                                                     * 07900000
*    IF A USER LABEL TRACK WAS ALLOCATED (ALWAYS THE FIRST EXTENT     * 08000000
*    IN THE FORMAT 1 DSCB), CONTROL IS GIVEN TO THE USER'S USER LABEL * 08100000
*    EXIT ROUTINE VIA A SYNCH SVC 12.                                 * 08200000
*                                                                     * 08300000
*    AFTER THE USER'S ROUTINE HAS PROCESSED THE LABEL,                * 08400000
*    THE CODE RETURNED BY THE USER DIRECTS FURTHER PROCESSING         * 08500000
*    AS FOLLOWS -                                                     * 08600000
*                                                                     * 08700000
*       RETURN CODE      ACTION TAKEN BY THIS ROUTINE                 * 08800000
*          0    NO LABEL IS WRITTEN FROM THE LABEL BUFFER AREA.       * 08900000
*               NORMAL PROCESSING IS RESUMED.                         * 09000000
*                                                                     * 09100000
*          4    USER LABEL IS WRITTEN FROM THE LABEL BUFFER AREA.     * 09200000
*               NORMAL PROCESSING IS RESUMED.                         * 09300000
*                                                                     * 09400000
*          8    USER LABEL IS WRITTEN FROM THE LABEL BUFFER AREA.     * 09500000
*               IF LESS THAN EIGHT LABELS HAVE BEEN CREATED,          * 09600000
*               CONTROL IS RETURNED TO THE EXIT ROUTINE, WHICH        * 09700000
*               THEN CREATES THE NEXT LABEL.  IF EIGHT LABELS         * 09800000
*               HAVE BEEN CREATED, NORMAL PROCESSING IS RESUMED.      * 09900000
*                                                                     * 10000000
* ENTRY POINTS -                                                      * 10100000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 10200000
*                                                                     * 10300000
* INPUT -                                                             * 10400000
*    REGISTERS -                                                      * 10500000
*       RC 12 - CONTENTS OF FULL WORK OF USER'S DCB EXIT LIST ENTRY   * 10600000
*          THAT IS BEING PROCESSED.  THE HIGH ORDER BYTE CONTAINS THE * 10700000
*          OUTPUT UHL OPTION X'02', POSSIBLY WITH THE END OF LIST X80'* 10800000
*          X'80' BIT ON.  SINCE THIS ROUTINE CAN CURRENTLY ONLY BE    * 10900000
*          ENTERED FOR THIS CODE, THE HIGH ORDER BYTE IS NOT USED.    * 11000000
*          THE LOW ORDER THREE BYTES IS THE ADDRESS OF THE USER'S     * 11100000
*          USER LABEL EXIT ROUTINE.  THIS ADDRESS IS ZERO IF THE      * 11200000
*          EXIT IS NOT ACTIVE, OR IF NO EXIT WAS SPECIFIED.           * 11300000
*          THIS ENTRY WITH A ZERO ADDRESS TO THIS MODULE IS DONE      * 11400000
*          IN ORDER TO FORMAT THE USER LABEL TRACK TO ALLOW           * 11500000
*          SUBSEQUENT TRAILER LABELS TO BE WRITTEN OR HEADER/TRAILER  * 11600000
*          LABELS TO BE READ DURING A LATER OPEN FOR INPUT.           * 11700000
*    WORK AREAS -                                                     * 11800000
*       RBGRS2-RBGRS13 - USER'S REGISTERS 2-13, WHICH WERE SAVED IN   * 11900000
*          THE SVRB GENERAL REGISTER SAVE AREA.                       * 12000000
*       DSCEXTYP - THE EXTENT TYPE AND SIZE OF THE FIRST EXTENT IN    * 12100000
*          THE FORMAT 1 DSCB, NORMALLY THE UL EXTENT.                 * 12200000
*       DXDAADDR - THE MBB..... MUST ALREADY BE SET UP FOR EXTENT 0,  * 12300000
*          AND THE BIN NUMBER FOR THIS VOLUME.                        * 12400000
*       DXDEBMOD-DXDEBNTR - MUST BE SET UP TO COVER THE WHOLE VOLUME, * 12500000
*          AND THEREFORE TO COVER THE UL EXTENT.                      * 12600000
*       DXVOLMT2 - USED AS A SAVE AREA BY OPEN ONLY TO SAVE THE CCHHR * 12700000
*          OF THE FORMAT 1 DSCB FROM DXCCW7, SINCE DXCCW7 IS NEEDED   * 12800000
*          FOR A CHANNEL PROGRAM.                                     * 12900000
*    USER LABELS -                                                    * 13000000
*       USER HEADER LABELS ARE CONSTRUCTED BY THE USER EXIT ROUTINE.  * 13100000
*                                                                     * 13200000
* OUTPUT -                                                            * 13300000
*    USER LABELS -                                                    * 13400000
*       THE USER LABELS CONSTRUCTED BY THE USER LABEL EXIT ROUTINE    * 13500000
*       ARE WRITTEN ON THE USER LABEL TRACK ALLOCATED FOR THIS        * 13600000
*       DATA SET.                                                     * 13700000
*    REGISTERS -                                                      * 13800000
*       AT FINAL EXIT FROM THIS MODULE, REGISTERS 2, 4-14 ARE THE     * 13900000
*       SAME AS THEY WERE AT ENTRY.  THIS ALLOWS THIS MODULE TO BE    * 14000000
*       CALLED AS THOUGH IT WAS A SUBROUTINE.                         * 14100000
*    WORK AREAS -                                                     * 14200000
*       DXDAADDR - MBB..... SAME AS AT ENTRY TO MODULE.               * 14300000
*                  ...CCHHR SHOULD BE CONSIDERED UNDEFINED.           * 14400000
*       DXCCW1-DXCCW6 - SHOULD BE CONSIDERED UNDEFINED.               * 14500000
*       DXCCW7 - SHOULD BE CONSIDERED UNDEFINED BY EOV.               * 14600000
*                                                                     * 14700000
* EXTERNAL REFERENCES -                                               * 14800000
*    THE USER'S INPUT USER HEADER OR TRAILER LABEL EXIT ROUTINE.      * 14900000
*    IT IS ENTERED VIA A SYNCH SVC 12 WITH THE FOLLOWING INPUT -      * 15000000
*       REGISTER 0 - CONTAINS NO MEANINGFUL INFORMATION.              * 15100000
*       REGISTER 1 - POINTER TO A 4 WORD PARAMETER LIST WHICH CONTAINS* 15200000
*          POINTER TO 80 BYTE USER LABEL BUFFER.                      * 15300000
*          POINTER TO THE USER'S DCB.                                 * 15400000
*          FLAG BYTE, POINTER TO STATUS INFORMATION (IF PERMANENT I/O * 15500000
*             ERROR) OR ZERO.                                         * 15600000
*          POINTER TO THE IMAGE AREA IF USER TOTALING WAS REQUESTED   * 15700000
*             (OPTCD=T), OR IT IS ZERO.                               * 15800000
*       REGISTERS 2-13 - USER'S REGISTERS BEFORE CALL TO OPEN, FEOV,  * 15900000
*          OR ROUTINE THAT CALLED EOV.                                * 16000000
*       REGISTER 14  - RETURN ADDRESS, SET BY SYNCH SVC 12.           * 16100000
*       REGISTER 15  - USER LABEL EXIT ROUTINE ADDRESS.               * 16200000
*    BEFORE EXITING, THIS MODULE'S REGISTERS 2-13 ARE SAVED IN THE    * 16300000
*    SVRB EXTENDED SAVE AREA.  THE USER'S REGISTERS 2-13 ARE RESTORED * 16400000
*    FROM THE SVRB GENERAL REGISTER SAVE AREA.  THE LOCK BIT (BIT 6)  * 16500000
*    IN DCBOFLGS IS SET TO 1 TO PREVENT THE USER FROM REQUESTING      * 16600000
*    ANOTHER I/O SUPPORT FUNCTION TO OPERATE ON THIS DCB WILE HE IS   * 16700000
*    IN CONTROL.  ON RETURN FROM THE USER'S ROUTINE, THIS BIT IS      * 16800000
*    RESET TO 0.                                                      * 16900000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 17000000
*                                                                     * 17100000
* EXITS, NORMAL -                                                     * 17200000
*    VIA XCTL TO MODULE WHOSE IDTTR IS IN DXRETMOD.  THIS IS NORMALLY * 17300000
*    THE CALLER OF THIS MODULE OR THE NEXT MODULE THAT IT WOULD HAVE  * 17400000
*    GONE TO HAD THERE BEEN NO USER LABELS TO PROCESS.                * 17500000
*                                                                     * 17600000
* EXITS, ERROR -                                                      * 17700000
*    NO USER LABEL TRACK ALLOCATED -                                  * 17800000
*       THE USER'S ROUTINE IS ENTERED WITH THE BUFFER POINTER         * 17900000
*       SET TO ZERO.  OTHER INPUT AS USUAL.                           * 18000000
*    I/O ERROR WRITING USER LABEL -                                   * 18100000
*       THE USER'S ROUTINE IS ENTERED AGAIN WITH BIT O OF THE FLAG    * 18200000
*       BYTE SET TO 1, AND A POINTER TO THE STATUS INFORMATION IN     * 18300000
*       THE WORK AREA IOB.  ON RETURN, THE RETURN CODE IS IGNORED AND * 18400000
*       NORMAL PROCESSING RESUMES FOR EOV.                            * 18500000
*       HOWEVER, FOR OPEN THE DCBOFLGS BUSY BIT IS TURNED OFF TO      * 18600000
*       TERMINATE THE OPEN OF THE DCB.  CONTROL IS PASSED TO THE END  * 18700000
*       OF OPEN TO FREE MAIN WORK AREAS AND TO RETURN TO THE CALLER   * 18800000
*       OF OPEN WITHOUT SETTING THE DCBOFLGS OPEN BIT.                * 18900000
*                                                                     * 19000000
* TABLES/WORK AREAS -                                                 * 19100000
*    THE FORMAT AND CONTENTS OF THE WORK AREAS USED ARE DESCRIBED BY  * 19200000
*    THE DSECTS AT THE END OF THE LISTING.                            * 19300000
*                                                                     * 19400000
* ATTRIBUTES -                                                        * 19500000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 19600000
*                                                                     * 19700000
* CHARACTER CODE DEPENDENCY -                                         * 19800000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 19900000
*                                                                     * 20000000
* NOTES -                                                             * 20100000
*   *UNLIKE UHL, WHERE THE KEY OF THE RECORD CORRESSPONDS TO THE UHL  * 20200000
*    NUMBER, UTL1 HAS A KEY OF UTL0.                                  * 20300000
*   *USER LABELS FOR PARALLEL DCB'S ARE NOT PROCESSED IN PARALLEL.    * 20400000
*    THIS HAS THE ADVANTAGE THAT ONLY ONE USER LABEL WORK AREA        * 20500000
*    IS PRESENT AT ONE TIME AND THEREFORE THE TOTAL WORK AREA         * 20600000
*    REQUIREMENT IS LESS.                                             * 20700000
*    ALSO THIS MAY PROTECT SOME POORLY WRITTEN USER LABEL ROUTINES    * 20800000
*    THAT EXPECT TO PROCESS ONLY ONE SET OF LABELS AT A TIME FROM     * 20900000
*    GETTING THE LABELS MIXED UP.  HOWEVER, SINCE THIS IS NOT A       * 21000000
*    SPECIFICATION, THIS MAY BE CHANGED AT ANY TIME.                  * 21100000
*                                                                     * 21200000
*                                                                     * 21300000
*********************************************************************** 21400000
         EJECT                                                          21500000
         IECDSECS CVT,TCB,RB,DCB,       DEFINE DESIRED DSCTS TO BE     X21600000
               MAIN,DEB,USERLAB,        EXPANDED AT THE END            X21700000
               USERTOT,WTG                                              21800000
*                                                                       21900000
         IECEQU ,                       DEFINE EQUATES                  22000000
*                                                                       22100000
         USING IHADCB,RDCB              DEFINE BASE TO USER'S DCB       22200000
         USING FORCORE,RCORE            DEFINE BASE TO MAIN WORK AREA   22300000
         USING WTG,RWTG                 DEFINE BASE TO XCTL/WTG TABLE   22400000
         USING ULWK1,RUCB               DEFINE BASE TO UL WORK AREA     22500000
*                                                                       22600000
         BALR  RBASE,0                  ESTABLISH BASE REGISTER         22700000
         USING *,RBASE                  DEFINE BASE REGISTER            22800000
*                                                                       22900000
*********************************************************************** 23000000
*                                                                       23100000
*  OBTAIN MAIN STORAGE IN USER'S PROTECTION KEY FOR                     23200000
*  WORK AREA, LABEL BUFFER AND PARAMETER LIST (40+80+16=136)            23300000
*                                                                       23400000
         GETMAIN R,LV=ULWKEND-ULWK1,SP=250  GETMAIN FROM SUB-POOL 250   23500000
*                                                                       23600000
         LR    RUCB,R1                  SET BASE FOR ULWK DSECT         23700000
         XC    ULWK1(ULWKEND-ULWK1),ULWK1  CLEAR USER LABEL WORK AREA   23800000
*                                                                       23900000
         MVC   DXCCW11,DXCCW8           SAVE SAVED REGS 9-10 IN 0-1     24000000
*                                                                       24100000
         CLI   WTGMODNM+K5,C'9'         IS THIS OPEN (IFG0196P)         24200000
         BNE   ULHDR08A                 BR IF NO                        24300000
         MVC   DXVOLMT2(K5),DXCCW7      SAVE DSCB CCHHR ADDR FOR OPEN   24400000
*                                                                       24500000
ULHDR08A EQU   *                                                        24600000
*                                                                       24700000
*        DETERMINE IF A USER LABEL EXTENT HAS BEEN ALLOCATED FOR THIS   24800000
*        DATA SET.                                                      24900000
*                                                                       25000000
         CLI   DSCEXTYP,ULEXT           IS 1ST EXTENT FOR USER LABELS   25100000
         BNE   ULNOEXT                  BR IF NO, GO TO USER            25200000
*                                                                       25300000
*********************************************************************** 25400000
*                                                                       25500000
*        EXTENT EXISTS - PROCESS USER LABELS                            25600000
*                                                                       25700000
         MVC   DXDAADDR+K3(K4),DSCLOWLM  CCHH FROM START OF 1ST EXTENT  25800000
         MVI   DXDAADDR+K7,K0           START SEARCH ID AT R0           25900000
*                                                                       26000000
*                                                                       26100000
*  SET UP CHANNEL PROGRAM TO WRITE A HEADER LABEL.                      26200000
*  EACH HEADER LABEL WRITTEN IS FOLLOWED BY TWO FILE MARKS -            26300000
*  UHL(N+1) AND UTL0.                                                   26400000
*                                                                       26500000
*        SEARCH ID EQ                                                   26600000
*        TIC *-8                                                        26700000
*        WRITE COUNT,KEY,DATA           ULWK1, UHLN,     LABEL          26800000
*        WRITE COUNT,KEY,(DATA)         ULWK5, UHL(N+1), FILE MARK      26900000
*        WRITE COUNT,KEY,(DATA)         ULWK2, UTL0,     FILE MARK      27000000
*        SEARCH ID EQ                                                   27100000
*        TIC *-8                                                        27200000
*        READ  COUNT,KEY,DATA           READ BACK UHLN CHECK            27300000
*                                                                       27400000
         XC    DXCCW1(K64),DXCCW1       CLEAR CCW AREA                  27500000
         LA    R1,DXDAADDR+K3                                           27600000
         ST    R1,DXCCW1                SEARCH ID FROM IOBDADAD+3       27700000
         LA    R1,DXCCW1                                                27800000
         ST    R1,DXCCW2                TIC TO CCW1                     27900000
         LA    R1,ULWK8                 WRITE C,K,DATA (UHL1)           28000000
         ST    R1,DXCCW3                FROM ULWK8                      28100000
         LA    R1,ULWK5                 WRITE C,K (UHL2)                28200000
         ST    R1,DXCCW4                FROM ULWK5                      28300000
*                                                                       28400000
         LA    R1,ULWK2                                                 28500000
         ST    R1,DXCCW5                WRITE FILE MARK FROM ULWK2      28600000
         OC    DXCCW1(K40),ULCP26P      OR IN CMND, FLAGS, LENGTH       28700000
*                                                                       28800000
         MVC   DXCCW6(K24),DXCCW1       APPEND WRITE CHECK TO CHNL PGM  28900000
         LA    R1,DXCCW6                                                29000000
         ST    R1,DXCCW7                TIC BACK TO CCW6                29100000
         MVI   DXCCW7,CCWTIC            RESTORE TIC OP                  29200000
         MVI   DXCCW8,X'1E'             MAKE OP READ                    29300000
         MVI   DXCCW8+K4,X'10'          SET SKIP BIT ON, CHAIN OFF      29400000
*                                                                       29500000
*        STRUCTURE COUNT AND KEY FIELDS IN WORK AREA.                   29600000
*                                                                       29700000
         MVC   ULWK8,DXDAADDR+K3        CCHH TO COUNT FIELD IN WK AREA  29800000
         MVC   ULWK9(K8),UHLCON6P       RKDD, KEY TO WORK AREA FOR UHLN 29900000
*                                                                       30000000
         MVC   ULWK5(K12),ULWK8         CT, KEY FOR UHL(N+1)  FILE MARK 30100000
         MVC   ULWK2(K8),ULWK8          CT FOR UTLO  FILE MARK          30200000
         MVC   ULWK4,UTLCON6P           KEY FOR UTLO                    30300000
*                                                                       30400000
*        DETERMINE IF ACTIVE EXIT LIST ENTRY EXISTS.                    30500000
*                                                                       30600000
         LA    RC,0(RC)                 ZERO HIGH ORDER BYTE            30700000
         LTR   RC,RC                    CHECK FOR ACTIVE EXIT           30800000
         BZ    ULHDR17                  BR IF NO                        30900000
*                                                                       31000000
*********************************************************************** 31100000
*                                                                       31200000
*        COMPLETE STRUCTURING OF WORK AREA FOR WRITING HEADER LABEL     31300000
*                                                                       31400000
ULHDR09  EQU   *                                                        31500000
         MVI   ULWK9+K3,K80             DATA LENGTH=80 FOR LABEL        31600000
         SR    R1,R1                    CLEAR REG.                      31700000
         IC    R1,ULWK9                 PICK UP R FROM CT FIELD OF LBL  31800000
         LA    R1,K1(R1)                INCR R BY 1                     31900000
         STC   R1,ULWK6                 R+1  UHL(N+1)                   32000000
         LA    R1,K1(R1)                INCR R BY 1                     32100000
         STC   R1,ULWK3                 R+2  UTL0                       32200000
         IC    R1,ULWK10+K3             PICK UP N FROM LABEL KEY        32300000
         LA    R1,K1(R1)                INCR N BY 1                     32400000
         STC   R1,ULWK7+K3              N+1                             32500000
         CLI   ULWK10+K3,C'8'           CHECK NO. LABELS GT 8           32600000
         BH    ULHDROUT                 BR IF YES TO SET UP RETURN      32700000
*                                                                       32800000
         MVC   ULBUFR(K4),ULWK10        PRIME THE LABEL BUFFER UHLN     32900000
*                                                                       33000000
*        SET UP AND EXECUTE SYNCHRONOUS EXIT TO USER'S ROUTINE FOR      33100000
*        LABEL CONSTRUCTION.                                            33200000
*                                                                       33300000
         BAL   RD,ULSYNC6P              GO EXIT TO USER'S ROUTINE       33400000
         MVC   ULBUFR(K4),ULWK10        REINSERT UHLN                   33500000
         LTR   RF,RF                    CHECK RETURN CODE FOR ZERO      33600000
         BZ    ULHDR13                  CODE=0, NO LABEL CREATED-BRANCH 33700000
         ST    RF,ULWK1                 SAVE RETURN CODE                33800000
         CLI   ULWK1+K3,K4              CHECK FOR RETURN CODE=4         33900000
         BE    ULHDR099                 RETURN CODE IS 4,CONTINUE       34000000
         CLI   ULWK1+K3,K8              CHECK FOR RETURN CODE=8         34100000
         BNE   ULHDR13                  RET CODE NOT 4,8-INVALID        34200000
*                                       RETURNED,NO FURTHER PROCESSING  34300000
ULHDR099 EQU   *                                                        34400000
         OI    DXCCW2+K4,X01            SET SWITCH INDIC NOT FIRST      34500000
         BAL   RC,ULEXCP6P              GO WRITE LABEL                  34600000
*                                                                       34700000
         TM    DXECB,ECBNOERR           CHECK FOR I/O ERROR             34800000
         BZ    ULHDR10                  BR IF YES                       34900000
*                                                                       35000000
         CLI   ULWK1+K3,K4              CHECK RET CODE FOR MORE LABELS  35100000
         BE    ULHDROUT                 NO, PREV LABEL WAS LAST         35200000
*                                                                       35300000
         MVC   DXDAADDR+K7(K1),ULWK9    R OF LABEL JUST WRITTEN TO IOB  35400000
         MVC   ULWK8(K12),ULWK5         CT,KEY OF UHL(N+1) BECOMES CT,  35500000
*                                       KEY OF NEXT USER LABEL          35600000
         B     ULHDR09                  BR TO PROCESS NEXT LABEL        35700000
*                                                                       35800000
*********************************************************************** 35900000
*                                                                       36000000
*  I/O ERROR OCURRED WHILE WRITING USER LABELS.                         36100000
*                                                                       36200000
ULHDR10  EQU   *                                                        36300000
         LA    R1,DXIOB                 INSERT POINTER TO STATUS INFO   36400000
         ST    R1,ULERRPTR              IN PARAMETER LIST               36500000
         OI    ULERRPTR,ERROR           FLAG ERROR                      36600000
         BAL   RD,ULSYNC61              GO TO SYNCH TO USER             36700000
*                                                                       36800000
ULHDR105 EQU   *                                                        36900000
         CLI   WTGMODNM+K5,C'9'         IS THIS OPEN (IFG0196P)         37000000
         BNE   ULOUT1                   BR IF NO                        37100000
*                                                                       37200000
         NI    DCBOFLGS,X'FF'-DCBOBUSY  TURN OFF DCBOFLGS BUSY BIT TO   37300000
*                                       STOP OPEN                       37400000
         B     ULHDROUT                 BR TO SET UP RETURN             37500000
*                                                                       37600000
*********************************************************************** 37700000
*                                                                       37800000
ULHDR13  EQU   *                                                        37900000
         TM    DXCCW2+K4,X01            IS IT FIRST TIME                38000000
         BO    ULHDROUT                 BR IF NO                        38100000
*                                                                       38200000
         MVI   ULWK6,K1                 R=1     UHL                     38300000
         MVI   ULWK7+K3,C'1'            N=1     UHL                     38400000
*                                                                       38500000
*        IF THE USER REQUESTS, VIA THE RETURN CODE, THAT NO USER        38600000
*        HEADER LABELS BE WRITTEN OR                                    38700000
*        IF THE EXIT IS INACTIVE, BUT AN EXTENT HAS BEEN ALLOCATED FOR  38800000
*        USER LABELS, OPEN AND EOV MUST WRITE TWO FILE MARKS (UHL1      38900000
*        AND UTL0).                                                     39000000
*                                                                       39100000
ULHDR17  EQU   *                                                        39200000
         MVI   ULWK3,K2                 R=2 FOR UTL0                    39300000
         MVC   DXCCW3(K16),DXCCW4       SET CP TO WRITE 2 FILEMARKS     39400000
         NI    DXCCW4+K4,X'FF'-CCWCMDCH  TURN OFF CC FLAG IN LAST CCW   39500000
*                                                                       39600000
         BAL   RC,ULEXCP6P              GO WRITE FILEMARKS              39700000
         TM    DXECB,ECBNOERR           CHECK FOR I/O ERROR             39800000
         BO    ULHDROUT                 BR IF NO ERROR                  39900000
*                                                                       40000000
         L     R1,DXREGC                OBTAIN DCB EXIT LIST ENTRY      40100000
         LA    R1,0(R1)                 ZERO CODE BYTE                  40200000
         LTR   R1,R1                    IS USER EXIT ACTIVE             40300000
         BNZ   ULHDR10                  BR IF YES TO GO TO EXIT RTN     40400000
         B     ULHDR105                 BR TO END LABEL PROCESSING      40500000
*                                                                       40600000
*********************************************************************** 40700000
*                                                                       40800000
*        NO USER LABEL TRACK WAS ALLOCATED.  EXIT TO USER'S ROUTINE     40900000
*        WITH POINTER TO LABEL BUFFER ZEROED.                           41000000
*                                                                       41100000
ULNOEXT  EQU   *                                                        41200000
         XC    ULERRPTR,ULERRPTR        CLEAR ANY ERROR INDICATOR       41300000
         SR    R1,R1                    BUFFER POINTER TO ZERO          41400000
         BAL   RD,ULSYNC62              GO SYNCH TO USER                41500000
*                                                                       41600000
*********************************************************************** 41700000
*                                                                       41800000
ULHDROUT EQU   *                        SET RETURN FOR HEADER PROCESSNG 41900000
ULOUT1   EQU   *                                                        42000000
*                                                                       42100000
*        FREE  WORKAREA AND LABEL BUFFER AND XCTL TO I/O SUPPORT        42200000
*        MODULE WHICH CALLED THIS MODULE.                               42300000
*                                                                       42400000
         FREEMAIN R,LV=ULWKEND-ULWK1,SP=250,A=(RUCB)  FREE UL AREA,    X42500000
                                        LABEL BUFFER AND PARAMETER LIST 42600000
*                                                                       42700000
         LM    RB,RET,DXREGB            RESTORE REGS 11-14              42800000
         LM    RTIOT,RUCB,DXREG0        RESTORE REGS 9-10 FROM 0-1      42900000
*                                                                       43000000
         CLI   WTGMODNM+K5,C'9'         IS THIS OPEN (IFG0196P)         43100000
         BNE   ULHDR08B                 BR IF NO                        43200000
         MVC   DXCCW7(K5),DXVOLMT2      RESTORE DSCB CCHHR FOR OPEN     43300000
         TM    DCBOFLGS,DCBOBUSY        IS DCB STILL BEING OPENED       43400000
         BO    ULHDR08B                 BR IF YES                       43500000
*                                                                       43600000
         IECRES XCTL,LOAD8N6P,4         XCTL TO OPEN FINAL STRING       43700000
*                                                                       43800000
ULHDR08B IECRES XCTL,DXRETMOD,(RET)     XCTL TO NEXT MODULE             43900000
*                                                                       44000000
*********************************************************************** 44100000
*                                                                       44200000
*        CLOSED SUBROUTINE TO ISSUE I/O OPERATIONS                      44300000
*                                                                       44400000
ULEXCP6P EQU   *                                                        44500000
         EXCP  DXIOB                    WRITE USER HEADER LABEL         44600000
*                                                                       44700000
         WAIT  ECB=DXECB                WAIT FOR WRITE TO COMPLETE      44800000
*                                                                       44900000
         BR    RC                       RETURN FROM I/O SUBROUTINE      45000000
*                                                                       45100000
*********************************************************************** 45200000
*                                                                       45300000
*        CLOSED SUBROUTINE TO SAVE AND RESTORE REGISTERS, SET UP INPUT, 45400000
*        AND ISSUE THE SVC SYNCH  FOR SYNCHRONOUS EXIT TO PROBLEM PROG. 45500000
*        THIS MODULE'S REGISTERS 2-13 ARE SAVED IN THE SVRB EXTENDED    45600000
*        SAVE AREA AND THE USER'S REGISTERS 2-13 ARE RESTORED FROM THE  45700000
*        SVRB.  REGISTER CONTENTS ARE AS FOLLOWS-                       45800000
*                        R0 - CONTAINS NO MEANINGFUL INFO               45900000
*                        R1 - PTR TO PARAMETER LIST                     46000000
*                    R2-R13 - USER'S CONTENTS BEFORE I/O SUPPORT        46100000
*                       R14 - RETURN ADDRESS (SET BY SYNCH)             46200000
*                       R15 - USER'S EXIT ROUTINE ADDRESS               46300000
*                                                                       46400000
ULSYNC6P EQU   *                                                        46500000
         XC    ULERRPTR,ULERRPTR        ZERO ERROR INDICATORS           46600000
ULSYNC61 EQU   *                                                        46700000
         LA    R1,ULBUFR                PTR TO LABEL BUFFER             46800000
ULSYNC62 EQU   *                                                        46900000
         STM   R1,RDCB,ULBUFPTR         BUFFER,DCB PTRS TO PARM LIST    47000000
         XC    ULTOTPTR,ULTOTPTR        ZERO TOTALING AREA              47100000
         TM    DCBDSORG,DCBORGDA        CK FOR DIRECT ORGANIZATION      47200000
         BO    ULSYNCH3                 BR IF DIRECT                    47300000
         CLI   WTGMODNM+K5,C'9'         IS THIS OPEN (IFG0196P)         47400000
         BE    ULSYNCH3                 BR IF YES, SKIP USER TOTALING   47500000
         TM    DCBMACRF,DCBMEXCP        TEST IF EXCP                    47600000
         BO    ULSYNCH3                 BR IF YES, SKIP USER TOTALING   47700000
         TM    DCBOPTCD,DCBOPTT         TEST IF USER TOTALING           47800000
         BZ    ULSYNCH3                 HAS BEEN REQUESTED, BR IF NO    47900000
*                                                                       48000000
         L     RDEB,DCBDEBAD            GET ADDR OF USER'S DEB          48100000
         SR    R1,R1                    CLEAR WORK REG                  48200000
         IC    R1,DEBNMEXT-DEB(,RDEB)   GET NUMBER OF EXTENTS           48300000
         SLL   R1,K4                    MULTIPLY BY 16                  48400000
         L     RDEB,K36(R1,RDEB)        GET ADDR TOTALING WORK AREA     48500000
*                                       DEB ADDR+32+4+LENGTH EXTENTS    48600000
         USING TOTSAVWA,RDEB            SET BASE - TOTALING AREA        48700000
         MVC   ULTOTPTR,TOTEOVPT        CURRENT IMAGE AREA ADDR TO      48800000
*                                       USER LBL PARM LIST              48900000
         DROP  RDEB                     DROP TOTALING AREA BASE         49000000
*                                                                       49100000
ULSYNCH3 EQU   *                                                        49200000
         LA    R1,ULPARM                POINT TO PARAMETER LIST         49300000
         L     RET,CVTPTR               CVT ADDRESS                     49400000
         L     RET,CVTTCBP-CVT(,RET)    TCB PTR                         49500000
         L     RET,K4(,RET)             TCB ADDRESS                     49600000
         L     RET,TCBRBP-TCB(,RET)     SVRB ADDRESS                    49700000
         USING RBSECT,RET               DEFINE BASE TO SVRB             49800000
         NI    DCBOFLGS,X'FF'-DCBOLOCK  SET LOCK BIT = 0                49900000
         STM   RDCB,RD,RBEXSAVE         SAVE I/O SUPP REGS IN SVRB ESA  50000000
         L     RF,DXREGC                ADDRESS OF USER'S ROUTINE       50100000
         LA    RF,0(RF)                 ROUTINE                         50200000
         L     RD,RBLINK                PTR TO PREVIOUS RB              50300000
         TM    RBCDFLGS-RBSECT(RD),RBFTSVRB  IS PREVIOUS A SVRB         50400000
         BNO   ULSYNCH4                 BR IF NO                        50500000
         LR    RET,RD                   USE PREVIOUS RB (CLOSE SVRB)    50600000
ULSYNCH4 LM    RDCB,RD,RBGRS2           RESTORE USER REGS 2-13          50700000
*                                                                       50800000
         SYNCH (15)                     SYNCH TO USER EXIT ROUTINE      50900000
*                                                                       51000000
         L     RET,CVTPTR               CVT ADDRESS                     51100000
         L     RET,CVTTCBP-CVT(,RET)    TCB PTR                         51200000
         L     RET,K4(,RET)             TCB ADDRESS                     51300000
         L     RET,TCBRBP-TCB(,RET)     SVRB ADDRESS                    51400000
         LM    RDCB,RD,RBEXSAVE         RESTORE I/O SUPP REGS 2-13      51500000
         OI    DCBOFLGS,DCBOLOCK        SET LOCK BIT = 1                51600000
         MVC   ULBUFR(K4),ULWK10        REINSERT UHLN                   51700000
         BR    RD                       RETURN FROM SYNCH EXIT SUBR     51800000
*                                                                       51900000
         DROP  RUCB,RWTG,RET                                            52000000
*                                                                       52100000
*********************************************************************** 52200000
*                                                                       52300000
*        CONSTANTS                                                      52400000
*                                                                       52500000
UHLCON6P DC    0F'0',X'01040000'        RKDD - R0, COUNT, KEY FOR UHL   52600000
         DC    C'UHL1'                  KEY                             52700000
UTLCON6P DC    C'UTL0'                  KEY FOR SEARCH ARGUMENT         52800000
*                                                                       52900000
*  CCW'S TO WRITE USER HEADER LABELS FOLLOWED BY UHL(N+1) UTL0 FILE MKS 53000000
ULCP26P  DC    X'3100000040000005'      SEARCH ID EQ                    53100000
         DC    X'0800000000000000'      TIC *-8                         53200000
         DC    X'1D0000004000005C'      WRITE CKD    UHLN     LABEL     53300000
         DC    X'1D0000004000000C'      WRITE CKD    UHL(N+1) FILE MARK 53400000
         DC    X'1D0000004000000C'      WRITE CKD    UTL0     FILE MARK 53500000
*                                                                       53600000
         XCTLTABL ID=(LOAD8N6P,8N),SVC=019  FINAL LOAD OF OPEN          53700000
*                                                                       53800000
         IECDSECS EXPAND=YES            EXPAND DESIRED DSECTS HERE      53900000
*                                                                       54000000
         END                                                            54100000
