         TITLE 'IGC0002A - FIRST LOAD OF BPAM STOW ROUTINE'             00090021
         COPY  LCGASMSW                                                 00140021
IGC0002A CSECT                                                          00180021
         SPACE                                                          00270021
*********************************************************************** 00360021
*                                                                     * 00450021
         AIF   ('&LIB' EQ 'LIB1').OS    CHECK TYPE OF ENVIRONMENT       00500001
*        VS2 RELEASE 01 DELETIONS                                     * 00630001
*D617400                                                         YM0943 00680001
*        VS1 RELEASE 01 DELETIONS                                     * 00720001
*                                                                XM5415 00730001
*        VS1 RELEASE 02 DELETIONS                                       00732002
*        VS1 RELEASE 03 DELETIONS                                       00732403
* SEE CODE FLAGGED SA66881 FOR VS1 APAR XA03384                         00732821
*                                                               XA01664 00734003
*                                                               XA02999 00736003
*                                                               XA02068 00738003
.OS      ANOP                                                           00740001
*        RELEASE 21 DELETIONS                                         * 00770021
*0281                                                            A50697 00780021
*0281                                                            S01964 00780121
*                                                                     * 00810021
*                                                                     * 00900021
* STATUS : CHANGE LEVEL 010                                           * 00990002
*    THIS MODULE WAS REWRITTEN FOR RELEASE 21.  THE FOLLOWING APARS   * 01080021
*    WERE CORRECTED.  28169, 33374, 35322, 42484, AND 43923.          * 01170021
*                                                                     * 01260021
*                                                                     * 01350021
* FUNCTION :                                                          * 01440021
*    THE STOW FUNCTION MAINTAINS THE DIRECTORY PORTION OF A           * 01530021
*    PARTITIONED DATA SET. THE ENTRIES, WITHIN A DIRECTORY ARE        * 01620021
*    KEPT IN ASCENDING ORDER OF THEIR BINARY VALUE. STOW WILL         * 01710021
*    PERFORM ONE OF THE FOLLOWING FOUR FUNCTIONS DEPENDING UPON       * 01800021
*    THE USER'S REQUEST.                                              * 01890021
*                                                                     * 01980021
*              1 ADD - ADD A NEW ENTRY TO A DIRECTORY                 * 02070021
*                                                                     * 02160021
*              2 REPLACE - EITHER REPLACE AN EXISTING ENTRY WITH      * 02250021
*                          A NEW ENTRY OR ADD THE NEW ENTRY IF        * 02340021
*                          THE EXISTING ENTRY CAN NOT BE FOUND        * 02430021
*                                                                     * 02520021
*              3 DELETE - DELETE AN ENTRY FROM A DIRECTORY            * 02610021
*                                                                     * 02700021
*              4 CHANGE - CHANGE THE NAME OF AN ENTRY IN A            * 02790021
*                         DIRECTORY                                   * 02880021
*                                                                     * 02970021
*    IF THE REQUEST IS FOR EITHER AN ADD OR REPLACE FUNCTION AND      * 03060021
*    THE DIRECTORY HAS BEEN SUCCESSFULLY UPDATED, AN END OF DATA      * 03150021
*    MARK WILL BE WRITTEN AT THE END OF THE MEMBER.                   * 03240021
*    THE FOLLOWING COMMENTS DESCRIBE THE FUNCTION OF IGC0002A         * 03330021
*                                                                     * 03420021
*    IGC0002A IS THE FIRST MODULE THAT IS LOADED WHEN STOW IS         * 03510021
*    REQUESTED AND IS ENTERED VIA A SVC 21 ONLY. IGC0002A IS          * 03600021
*    RESPONSIBLE FOR PERFORMING VARIOUS DIAGNOSTICS FOR THE STOW      * 03690021
*    FUNCTION AS FOLLOWS:                                             * 03780021
*                                                                     * 03870021
*              1 DATA CONTROL BLOCK CHECK                             * 03960021
*                   A  CHECK THE DATA CONTROL BLOCK FOR OPEN          * 04050021
*                   B  CHECK TO SEE IF THE DCB IS OPEN FOR INPUT      * 04140021
*                   C  IF AN INVALID CONDITION IS DETECTED FROM       * 04230021
*                      THE ABOVE CHECKS, IGC0002A WILL SET A          * 04320021
*                      RETURN CODE IN REGISTER FIFTEEN AND RETURN     * 04410021
*                      TO THE USER VIA A SVC 3                        * 04500021
*                                                                     * 04590021
*              2 REQUEST TYPE                                         * 04770021
*                   A  THE REQUEST TYPE IS DETERMINED BY A UNIQUE     * 04860021
*                      COMBINATIONS OF THE SIGNS IN REGISTERS         * 04950021
*                      ZERO AND ONE                                   * 05040021
*                                                                     * 05130021
*              3 WORKAREA FOR THE FOLLOWING                           * 05220021
*                   A  THE INPUT/OUTPUT BUFFERS FOR MANIPULATING      * 05310021
*                      THE DIRECTORY ENTRIES                          * 05400021
*                   B  THE EVENT CONTROL BLOCK, INPUT OUTPUT BLOCK    * 05490021
*                      AND CHANNEL PROGRAMS THAT STOW WILL USE        * 05580021
*                      FOR READING AND WRITING THE DIRECTORY          * 05670021
*                      BLOCKS                                         * 05760021
*                   C  THE FUNCTIONS CODE INDICATING REQUEST TYPE     * 05850021
*                   D  THE RETURN CODE IF APPLICABLE                  * 05940021
*                   E  SAVE A COPY OF THE USER'S DEB                  * 06030021
*                   F  SAVE THE ADDRESS OF THE USER'S PARAMETERS      * 06120021
*                   G  SAVE THE RELATIVE TRACK ADDRESS, (TTR),        * 06210021
*                      FROM THE DATA CONTROL BLOCK IF THE ALIAS       * 06300021
*                      BIT IS NOT ON IN THE USER'S PARAMETER AND      * 06390021
*                      THE FUNCTION REQUEST IS EITHER AN ADD OR       * 06480021
*                      REPLACE                                        * 06570021
*                   H  IF A CHANGE FUNCTION, SAVE THE RELATIVE        * 06660021
*                      ADDRESS, (TTR), FROM THE OLD ENTRY             * 06750021
*                   I  POST A FLAG INDICATING LAST OPERATION          * 06840021
*                      PERFORMED WITH DATA CONTROL BLOCK BEFORE       * 06930021
*                      STOW WAS ISSUED.                               * 07020021
*                   J  FOR CHANGE INDICATE IN WORK AREA WHICH         * 07110021
*                      OPERATION WILL BE PERFORMED FIRST - ADD OR     * 07200021
*                      DELETE                                         * 07290021
*                                                                     * 07380021
*              4 EVENT CONTROL BLOCK, INPUT OUTPUT BLOCK              * 07470021
*                   A IGC0002A DYNAMICALLY CONSTRUCTS THE EVENT       * 07560021
*                      CONTROL BLOCK, INPUT OUTPUT BLOCK AND THE      * 07650021
*                      CHANNEL PROGRAMS THAT WILL BE USED BY IT       * 07740021
*                   B  IGC0002A EXECUTES A CHANNEL PROGRAM TO         * 07830021
*                      READ IN THE DIRECTORY BLOCK AGAINST WHICH      * 07920021
*                      SOME ACTION WILL BE PERFORMED AND THE          * 08010021
*                      FOLLOWING BLOCK IF AVAILIBLE                   * 08100021
*                   C  IF AN INPUT OUTPUT ERROR OCCURS A RETURN       * 08190021
*                      CODE WILL BE SET IN REGISTER FIFTEEN AND       * 08280021
*                      CONTROL RETURNED TO THE USER WITHOUT           * 08370021
*                      FURTHER PROCESSING                             * 08460021
*                                                                     * 08550021
*              5 DIRECTORY BLOCK DIAGNOSTICS                          * 08730021
*                   A  DETERMINE IF THE REQUEST IS VALID AND          * 08820021
*                        IF NOT SET THE APPROPIATE RETURN             * 08910021
*                        CODE AND RETURN TO THE USER VIA AN SVC 3     * 09000021
*                                                                     * 09090021
*                                                                     * 09180021
* ENTRY POINTS :                                                      * 09270021
*    VIA SUPERVISOR CALL 21 ONLY TO IGC0002A                          * 09360021
*                                                                     * 09450021
*                                                                     * 09540021
* INPUT :                                                             * 09630021
*    THE NAME OF THE ENTRY UPON WHICH ACTION IS DESIRED MUST BE       * 09720021
*    SUPPLIED. IN ADDITION, MORE INFORMATION MAY BE REQUIRED AS       * 09810021
*    FOLLOWS:                                                         * 09900021
*              1  ADD OR REPLACE FUNCTIONS - ANY USER DATA TO         * 09990021
*                   BE KEPT WITH THE ENTRY AND IF THE ALIAS BIT       * 10080021
*                   IS ON, THE BEGINNING RELATIVE ADDRESS. (TTR),     * 10170021
*                   OF THE MEMBER                                     * 10260021
*              2  CHANGE FUNCTION - EIGHT BYTES OF OLD ENTRY NAME     * 10350021
*                   FOLLOWED BY EIGHT BYTES OF NEW ENTRY NAME         * 10440021
*    IN ADDITION THE STOW MACRO FURNISHES THE ADDRESS OF THE DATA     * 10530021
*    IN REGISTER ZERO AND THE ADDRESS OF THE DATA CONTROL BLOCK       * 10620021
*    IN REGISTER ONE. THE MACRO ALSO SETS THE SIGNS IN THE TWO        * 10710021
*    REGISTERS AS FOLLOWS:                                            * 10800021
*              FUNCTION            REGISTER ZERO  REGISTER ONE        * 10890021
*                ADD                    POSITIVE       POSITIVE       * 10980021
*                REPLACE                POSITIVE       NEGATIVE       * 11070021
*                DELETE                 NEGATIVE       POSITIVE       * 11160021
*                CHANGE                 NEGATIVE       NEGATIVE       * 11250021
         EJECT                                                          11340021
*    FOLLOWING ARE THE FORMATS OF THE DATA AS REQUIRED BY STOW        * 11430021
*    FOR THE DIFFERENT FUNCTIONS:                                     * 11520021
*              ADD OR REPLACE                                         * 11610021
*                                                                     * 11700021
*              1------------1------1-------------------------1        * 11790021
*              1            1      1                         1        * 11880021
*              1NAME        1 TTRC 1 VARIABLE USER DATA      1        * 11970021
*              1            1      1                         1        * 12060021
*              1------------1------1-------------------------1        * 12150021
*                                                                     * 12240021
*              CHANGE                                                 * 12330021
*                                                                     * 12420021
*              1------------1------------1                            * 12510021
*              1            1            1                            * 12600021
*              1 OLD NAME   1 NEW NAME   1                            * 12690021
*              1            1            1                            * 12780021
*              1------------1------------1                            * 12870021
*                                                                     * 12960021
*              DELETE                                                 * 13050021
*                                                                     * 13140021
*              1------------1                                         * 13230021
*              1            1                                         * 13320021
*              1  NAME      1                                         * 13410021
*              1            1                                         * 13500021
*              1------------1                                         * 13590021
*                                                                     * 13680021
*                                                                     * 13770021
*              FIELD DEFINITIONS                                      * 13860021
*                   NAME- EIGHT BYTE NAME OF ENTRY BEING ACTED        * 13950021
*                        UPON                                         * 14040021
*                   TT - RELATIVE TRACK FROM THE BEGINNING OF THE     * 14130021
*                       DATA SET                                      * 14220021
*                   R - RELATIVE BLOCK NUMBER ON A TRACK              * 14310021
*                   C - INDICATES IF THE NAME IS AN ALIAS, THE        * 14400021
*                       NUMBER OF TTRN'S IN THE USER DATA AND THE     * 14490021
*                       LENGTH OF THE USER DATA. THE FORMAT IS AS     * 14580021
*                       FOLLOWS:                                      * 14670021
*                        BIT0 - IF ON NAME IS AN ALIAS                * 14760021
*                        BITS1-2 - NUMBER OF TTRNS IN USER DATA       * 14850021
*                                  FIELD. MAXIMUM NUMBER IS THREE     * 14940021
*                        BITS3-7 - BY THEIR BINARY VALUE, INDICATE    * 15030021
*                                  THE NUMBER OF HALF WORDS OF        * 15120021
*                                  USER DATA                          * 15210021
*                                                                     * 15300021
*                                                                     * 15390021
* OUTPUT :                                                            * 15480021
*    IGC0002A ONLY PASSES THE ADDRESS OF THE WORK AREA TO IGG0210A.   * 15570021
*                                                                     * 15660021
         EJECT                                                          15750021
*                                                                     * 15840021
* EXTERNAL REFERENCES:                                                * 15930021
*    IN THE FIRST LOAD OF STOW, (IGC0002A), REFERENCES ARE MADE       * 16020021
*    TO THE FOLLOWING SYSTEM CONTROL BLOCKS                           * 16110021
*              1  COMMUNICATION VECTOR TABLE                          * 16200021
*              2  DATA CONTROL BLOCK - USER'S                         * 16290021
*              3  DATA EXTENT BLOCK                                   * 16380021
*              4  EVENT CONTROL BLOCK                                 * 16470021
*              5  INPUT OUTPUT BLOCK                                  * 16560021
*              6  REQUEST ELEMENT                                     * 16650021
*              7  UNIT CONTROL BLOCK                                  * 16740021
*    THE FOLLOWING SYSTEM FUNCTIONS ARE USED                          * 16830021
*              1  EXECUTE CHANNEL PROGRAM, (EXCP)                     * 16920021
*              2  FREEMAIN                                            * 17010021
*              3  GETMAIN                                             * 17100021
*              4  SUPERVISOR CALL, (SVC)                              * 17190021
*              5  TRANSFER CONTROL, (XCTL)                            * 17280021
*              6  WAIT                                                * 17370021
*                                                                     * 17460021
*                                                                     * 17550021
* EXITS NORMAL :                                                      * 17640021
*    NORMAL EXIT FROM IGC0002A IS TO THE SECOND LOAD OF STOW -        * 17730021
*    IGG0210A VIA A XCTL                                              * 17820021
*                                                                     * 17910021
*                                                                     * 18000021
* EXITS ERROR :                                                       * 18090021
*    IN THE EVENT OF AN ERROR, CONTROL IS RETURNED TO THE USER        * 18180021
*    VIA A SVC 3 WITH ONE OF THE FOLLOWING RETURN CODES IN            * 18270021
*    REGISTER FIFTEEN                                                 * 18360021
*              CODE           REASON                                  * 18450021
*                04             ADD FUNCTION - ENTRY ALREADY EXIST    * 18540021
*                               CHANGE FUNCTION - THE DIRECTORY       * 18630021
*                                  ALREADY CONTAINS THE SPECIFIED     * 18720021
*                                  NEW NAME                           * 18810021
*                08             REPLACE FUNCTION - THE SPECIFIED      * 18900021
*                                  NAME COULD NOT BE FOUND            * 18990021
*                               DELETE FUNCTION - THE SPECIFIED       * 19080021
*                                  NAME COULD NOT BE FOUND            * 19170021
*                               CHANGE FUNCTION - THE SPECIFIED       * 19260021
*                                  OLD NAME COULD NOT BE FOUND        * 19350021
*                0C             ADD OR REPLACE FUNCTION - NO          * 19440021
*                                  SPACE LEFT IN THE DIRECTORY        * 19530021
*                                  THE ENTRY COULD NOT BE ADDED       * 19620021
*                                  OR REPLACED                        * 19710021
*                10             ALL FUNCTIONS - A PERMANENT INPUT     * 19800021
*                                  OR OUTPUT ERROR OCCURED            * 19890021
*                14             ALL FUNCTIONS - THE USER'S DATA       * 19980021
*                                  CONTROL BLOCK IS NOT OPEN          * 20070021
*                18             ALL FUNCTIONS - NO CORE AVAILIBLE     * 20160021
*                                                                     * 20250021
*                                                                     * 20340021
* TABLES AND WORKAREAS :                                              * 20430021
*                                                                     * 20520021
*    SEE THE DSECT OF THE WORK AREA                                   * 20610021
*                                                                     * 20700021
*                                                                     * 20790021
* ATTRIBUTES : READ-ONLY, REENTRANT, SUPERVISOR FUNCTION              * 20880021
*                                                                     * 20970021
*                                                                     * 21060021
* NOTES :                                                             * 21150021
*                                                                     * 21240021
*    DIRECTORY LAYOUT                                                 * 21330021
*                                                                     * 21420021
*        1-------1 1-------1 1---1-------------1--------------1       * 21510021
*        1 COUNT 1 1  KEY  1 1 N 1 FIRST ENTRY 1 SECOND ENTRY 1       * 21600021
*        1-------1 1-------1 1---1-------------1--------------1       * 21690021
*                                1-------------1------1----------1    * 21780021
*                                1 THIRD ENTRY 1 ETC. 1 FFFFFFFF 1    * 21870021
*                                1-------------1------1----------1    * 21960021
*                                                                     * 22050021
*                   COUNT - AN EIGHT BYTE FIELD CONTAINING THE        * 22140021
*                           ADDRESS OF THIS DIRECTOR BLOCK IN THE     * 22230021
*                           FORM OF CCHHRKDD                          * 22320021
*                   KEY   - AN EIGHT BYTE FIELD CONTAINING THE        * 22410021
*                           NAME OF THE LAST ENTRY IN THIS            * 22500021
*                           DIRECTORY BLOCK, IF THIS IS THE LAST      * 22590021
*                           BLOCK IN THE DIRECTORY THE KEY WILL       * 22680021
*                           CONTAIN X'FFFFFFFF'                       * 22770021
*                   N     - A TWO BYTE FIELD INDICATING THE TOTAL     * 22860021
*                           NUMBER OF BYTES USED IN THIS              * 22950021
*                           DIRECTORY BLOCK INCLUDING ITSELF. IF      * 23040021
*                           THIS IS THE LAST BLOCK, THE TOTAL         * 23130021
*                           WILL ALSO INCLUDE THE FOUR X'0'S          * 23220021
*                           FOLLOWING THE X'FFFFFFFF' FIELD           * 23310021
*                   F'S   - AN EIGHT BYTE FIELD SHOWING THE END       * 23400021
*                           OF THE ENTRIES FOR A DIRECTORY            * 23490021
*                                                                     * 23580021
*    DEFINITIONS -                                                    * 23670021
*                                                                     * 23760021
*        DIRECTORY: IS A SERIES OF RECORDS REFERRED TO AS BLOCKS      * 23850021
*                   ON A DIRECT ACCESS STORAGE DEVICE CONTAINING      * 23940021
*                   THE ENTRIES FOR A PARTITIONED ORGANIZATION        * 24030021
*                   DATA SET                                          * 24120021
*        ENTRY:     THE PART OF A DIRECTORY OF A PARTITIONED          * 24210021
*                   ORGANIZATION DATA SET CONTAINING THE MEMBER       * 24300021
*                   NAME, RELATIVE ADDRESS OF THE MEMBER AND ANY      * 24390021
*                   USER DATA                                         * 24480021
*        MEMBER:    THE USER'S DATA RECORD  POINTED TO BY THE ENTRY   * 24570021
*                                                                     * 24660021
*********************************************************************** 24750021
         EJECT                                                          24840021
*********************************************************************** 24930021
****                                                               **** 25020021
****     EQUATES                                                   **** 25110021
****                                                               **** 25200021
*********************************************************************** 25290021
         SPACE                                                          25380021
****     THE FOLLOWING REGISTER EQUATES WILL BE USED DURING CONSTRUC-   25470021
****     TION OF THE IOB, ECB, AND CHANNEL PROGRAMS USED BY STOW.       25560021
         SPACE                                                          25650021
R0       EQU   0                        WORK REGISTER                   25740021
R1       EQU   1                        WORK REGISTER                   25830021
R2       EQU   2                        WORK REGISTER                   25920021
R3       EQU   3                        WORK REGISTER                   26010021
R4       EQU   4                        WORK REGISTER                   26100021
R5       EQU   5                        WORK REGISTER                   26190021
R6       EQU   6                        WORK REGISTER                   26280021
R7       EQU   7                        WORK REGISTER                   26370021
R8       EQU   8                        WORK REGISTER                   26460021
R9       EQU   9                        WORK REGISTER                   26550021
R10      EQU   10                       WORK REGISTER                   26640021
R11      EQU   11                       WORK REGISTER                   26730021
R12      EQU   12                       WORK REGISTER                   26820021
R13      EQU   13                       WORK REGISTER                   26910021
R14      EQU   14                       WORK REGISTER                   27000021
R15      EQU   15                       WORK REGISTER                   27090021
         SPACE 2                                                        27180021
****     THE FOLLOWING REGISTER EQUATES WILL BE USED IN THE             27270021
****     PROGRAM FLOW                                                   27360021
         SPACE                                                          27450021
PARMRG0  EQU   R0                       POINTS TO USER DATA UPON ENTRY  27540021
DCBRG1   EQU   R1                       POINTS TO DCB UPON ENTRY        27630021
DIRSCNRG EQU   R2                       POINTS TO LOCATION IN DIRECTORY 27720021
*                                       FOR ACTION TAKING PLACE         27810021
PARMRG2  EQU   DIRSCNRG                 USED TO SAVE ADDR OF USER DATA  27900021
CVTRG    EQU   R3                       POINTS TO THE CVT               27990021
TTRCRG   EQU   CVTRG                    MANIPULATES THE AMOUNT OF       28080021
*                                       USER DATA FOR AN ENTRY          28170021
ENTADDRG EQU   R4                       CONTAINS ADDR OF ENTRY SUPPLIED 28260021
*                                       BY THE USER                     28350021
BUFADRG  EQU   R5                       ADDRESSABILITY TO BUFFERS       28440021
SVRBRG   EQU   BUFADRG                  POINTS TO THE SVRB UPON ENTRY   28530021
FUNRG    EQU   R8                       CONTAINS FUNCTION CODE          28620021
SAVECDRG EQU   R9                       SAVES THE RETURN CODE           28710021
WRKARG   EQU   R10                      ADDRESS OF THE WORK AREA        28800021
DCBRG11  EQU   R11                      ADDRESS OF THE USER'S DCB       28890021
BASERG   EQU   R12                      BASE REGISTER                   28980021
DEBRG    EQU   R13                      ADDRESS OF THE COPIED DEB       29070021
LINKRG   EQU   R14                      LINKAGE REGISTER WITHIN MODULE  29160021
RTNRG    EQU   R15                      CONTAINS RETURN CODE            29250021
         EJECT                                                          29340021
****     DISPLACEMENT AND MASK EQUATES                                  29430021
         SPACE                                                          29520021
NULL     EQU   0                        ZERO DISPLACEMENT               29610021
ONE      EQU   1                        DISPLACE BY ONE                 29700021
THREE    EQU   3                        DISPLACE BY THREE               29790021
RETURN   EQU   3                        RETURN TO USER SVC              29880021
FOUR     EQU   4                        DISPLACE BY FOUR                29970021
EIGHT    EQU   8                        DISPLACE BY EIGHT               30060021
SIXTEEN  EQU   16                       DISPLACE BY SIXTEEN             30150021
TWNTYSIX EQU   26                       DISPLACE BY TWENTY SIX          30240021
TWNTYSVN EQU   27                       DISPLACE BY TWENTY SEVEN        30330021
UNITEXCP EQU   X'01'                    TEST FOR UNIT EXCEPTION         30420021
MODLNTH  EQU   X'04'                    NUMERIC PORTION OF STOW LOAD    30510021
*                                       MODULE LENGTH FIELD             30600021
OPEN     EQU   X'10'                    TEST DCB FOR OPEN               30690021
DCBWRT   EQU   X'80'                    TEST LAST OPERATION             30780021
VRFIX    EQU   X'01'                   TESTS FOR V=R REQUEST            30830002
TCBFLGS6 EQU   X'CA'                   OFFSET TO V=R FLAG               30840002
VRRQST   EQU   X'80'                   V=R BIT                          30850002
*                                       PERFORMED WITH THE DCB          30870021
         SPACE                                                          30960021
****     ERROR CONDITION EQUATES                                        31050021
         SPACE                                                          31140021
NMEXIST  EQU   X'04'                    NAME ALREADY EXISTS             31230021
NONAME   EQU   X'08'                    NAME DOESN'T EXIST              31320021
IOERRCD  EQU   X'10'                    I/O ERROR                       31410021
DCBERR1  EQU   X'14'                    DCB NOT OPEN                    31500021
NOCORE   EQU   X'18'                    NO CORE AVAILABLE               31590021
IOTYPE   EQU   X'0F'                    TEST DCB OPEN OPTION            31680021
         EJECT                                                          31770021
*********************************************************************** 31860021
****                                                               **** 31950021
****     ESTABLISH BASE REGISTER AND ENABLE INTERRUPTS             **** 32040021
****                                                               **** 32130021
*********************************************************************** 32220021
         BALR  BASERG,NULL              ESTABLISH BASE ADDR             32310021
         USING *,BASERG                 ESTABLISH BASE ADDR             32400021
         AIF   ('&LIB' NE 'LIB1').NOS   TYPE OF ENVIROMENT              32450021
         SSM   SYSMASK                  ENABLE INTERRUPTS               32490021
.NOS     ANOP                                                           32540021
         SPACE 2                                                        32580021
*********************************************************************** 32670021
****                                                               **** 32760021
****     THIS SECTION DETERMINES THE FUNCTION OF STOW REQUESTED    **** 32850021
****                                                               **** 32940021
*********************************************************************** 33030021
         LA    FUNRG,STWADD             SET FUNCTION TO ADD             33120021
         LTR   PARMRG0,PARMRG0          TEST FOR DELETE OR CHANGE       33210021
         BP    TEST1                    BRANCH IF ADD OR REPLACE        33300021
         SLL   FUNRG,ONE                SET CODE FOR REPLACE            33390021
         SPACE                                                          33480021
TEST1    EQU   *                                                        33570021
         LTR   DCBRG1,DCBRG1            TEST FOR ADD/REPLACE            33660021
         BP    TEST02                   BRANCH IF ADD / REPLACE         33750021
         SLL   FUNRG,ONE                SET FUNCTION TO DELETE          33840021
         SPACE                                                          33930021
TEST02   EQU   *                                                        34020021
         LTR   PARMRG0,PARMRG0          TEST FOR CHANGE FUNCTION        34110021
         BP    DCBTEST                  IF NOT BRANCH                   34200021
         SLL   FUNRG,ONE                SET FUNCTION TO CHANGE          34290021
         SPACE 2                                                        34380021
*********************************************************************** 34470021
****                                                               **** 34560021
****     THIS SECTION TESTS THE DATA CONTROL BLOCK FOR OPEN        **** 34650021
****                                                               **** 34740021
*********************************************************************** 34830021
DCBTEST  EQU   *                                                        34920021
         LPR   PARMRG2,PARMRG0          MAKE PARAMETER ADDR POSITIVE    35010021
         LPR   DCBRG11,DCBRG1           MAKE DCB ADDR POSITIVE          35100021
         AIF   ('&LIB' EQ 'LIB1').NODEBCK                        S01964 35110021
         LPR   DCBRG1,DCBRG1             MAKE DCB. ADDR.         S01964 35120021
*                                       POSITIVE                 S01964 35130021
         DEBCHK  (DCBRG1),TYPE=VERIFY    ISSUE THE DEB CHECK     S01964 35140021
.NODEBCK ANOP                                                           35150021
         USING IHADCB,DCBRG11           ESTABLISH DCB ADDRESSABILITY    35190021
         TM    DCBOFLGS,OPEN            DATA CONTROL BLOCK OPEN         35280021
         BO    GETWORK                  GO GET THE WORK AREA            35370021
RTNUSR   EQU   *                                                        35460021
         LA    RTNRG,DCBERR1            SET THE RETURN CODE             35550021
         SPACE                                                          35640021
RTNUSR0  EQU   *                                                        35730021
         SVC   RETURN                   RETURN TO USER                  35820021
         SPACE 2                                                        35910021
*********************************************************************** 36000021
****                                                               **** 36090021
****     THIS SECTION GETS THE WORK AREA FOR STOW                  **** 36180021
****                                                               **** 36270021
*********************************************************************** 36360021
GETWORK  EQU   *                                                        36450021
         USING RBSECT,SVRBRG            ESTABLISH ADDRESSABILITY        36540021
*                                       TO THE SVRB                     36630021
         L     R9,DCBDEBAD              GET DEB ADDRESS                 36720021
         USING DEBBASIC,R9              ESTABLISH DEB BASE REGISTER     36810021
         TM    DEBOPATB,IOTYPE          DCB OPEN FOR INPUT              36900021
         BZ    RTNUSR                   BRANCH IF YES                   36990021
         SR    R6,R6                    CLEAR REGISTER                  37080021
         IC    R6,DEBNMEXT              GET NUMBER OF EXTENTS IN DEB    37170021
         SLL   R6,FOUR                  MULTIPLY EXTENTS BY 16          37260021
         LA    R7,CORESIZE+(DEBBASND-DEBBASIC)+32(,R6)  GET SIZE OF     37350003
*                                       STOW WORK AREA          XA02999 37440003
         MVC   RBGTMLST(LNGTMAIN),GTMNLIST  MOVE GETMAIN LIST TO        37530021
*                                       EXTENDED SAVE AREA IN THE SVRB  37620021
         ST    R7,RBGTMLST              PUT WORK AREA SIZE IN LIST      37710021
         GETMAIN  A=RBGTMARA,MF=(E,RBGTMLST)  GET THE WORK AREA         37800021
         LTR   RTNRG,RTNRG              GETMAIN SUCCESSFUL              37890021
         LA    RTNRG,NOCORE             SET RETURN CODE                 37980021
         BNZ   RTNUSR0                  RETURN TO USER IF NO CORE       38070021
         SPACE 2                                                        38160021
*********************************************************************** 38250021
****                                                               **** 38340021
****     THIS SECTION CLEARS THE WORK AREA, SAVES THE CONDITION    **** 38430021
****     AND FUNCTION CODES, AND COPIES THE BASIC AND EXTENT       **** 38520021
****     SECTIONS OF THE DEB INTO THE WORK AREA.                   **** 38610021
****                                                               **** 38700021
*********************************************************************** 38790021
         L     WRKARG,RBGTMARA          GET THE ADDRESS OF CORE         38880021
         USING STWAREA,WRKARG           ESTABLISH ADDRESSABILITY        38970021
         DROP  SVRBRG                   DROP SVRB BASE REGISTER         39060021
         XC    STWAREA(STWFLGLN),STWAREA  CLEAR THE CONDITION AND       39150021
*                                       FUNCTION BYTES                  39240021
         STC   FUNRG,STWFLAG1           SAVE FUNCTION CODE              39330021
         STH   R7,STWGMSZ               SAVE SIZE OF WORK AREA          39420021
         TM    DCBOFLGS,DCBWRT          LAST OPERATION A WRITE          39510021
         BNO   BUILDDEB                 NO, GO TO COPY DEB              39600021
         OI    STWFLAG1,STWDCBWR        INDICATE LAST OPERATION         39690021
*                                       WAS A WRITE                     39780021
         SPACE                                                          39870021
BUILDDEB EQU   *                                                        39960021
         LA    DEBRG,STWDEB             GET ADDR OF DEB IN WORK AREA    40050021
         MVC   0(DEBBASND-DEBBASIC,DEBRG),0(R9)  MOVE BASIC SECTION OF  40140021
*                                       THE DEB TO THE WORK AREA        40230021
         BCTR  R6,R0                    DECREMENT EXTENTS SIZE FOR MOVE 40320021
         EX    R6,MOVEDEB               MOVE DEB EXTENTS TO WORK AREA   40410021
         DROP  R9                       DROP DEB BASE REGISTER          40500021
         USING DEBBASIC,DEBRG           ESTABLISH DEB BASE REGISTER     40590021
         ST    DEBRG,STWDEBPT           PUT DEB ADDR IN DUMMY DCB       40680021
         USING CVTDSECT,CVTRG           ESTABLISH CVT ADDRESSABILITY    40770021
         L     CVTRG,CVTPTR             GET CVT ADDRESS                 40860021
         MVC   DEBAPPB,CVTXAPG+1        MOVE SYSTEM AVT PTR INTO DEB    40950021
         LA    ENTADDRG,STWOLDNM        POINT TO LOCATION FOR           41040002
*                                       ENTRY TO BE MOVED               41130021
         TM    STWFLAG1,STWCHNG         CHANGE FUNCTION                 41220021
         BNO   DATEST                   GO MOVE THE PARAMETER           41310021
         SPACE 2                                                        41400021
*********************************************************************** 41490021
****                                                               **** 41580021
****     WITH A CHANGE REQUEST THIS SECTION DETERMINES WHICH       **** 41670021
****     ENTRY IS THE LOWEST IN ALPHANUMERIC SEQUENCE SO           **** 41760021
****     THE FIRST SEARCH IS ON THAT ENTRY                         **** 41850021
****                                                               **** 41940021
*********************************************************************** 42030021
         USING USERPARM,PARMRG2         ESTABLISH ADDRESSABILITY        42120021
         LR    PARMRG0,PARMRG2          SAVE THE PARM. ADDR.    A50697  42170021
         CLC   USEOLDNM,USENEWNM        COMPARE OLD ENTRY NAME TO NEW   42210021
*                                       ENTRY NAME                      42300021
         BH    OLDHIGH                  BRANCH IF OLD NAME IS HIGHER    42390021
         OI    STWFLAG1,STWCHNG+STWDEL  INDICATE DELETE FUNCTION        42480021
*                                       TO BE PERFORMED FIRST           42570021
         ST    PARMRG2,STWPARM          SAVE ADDRESS OF OLD NAME        42660021
         LA    PARMRG2,USENEWNM         POINT TO NEW NAME               42750021
         ST    PARMRG2,STWHIGH          SAVE ADDRESS OF NEW NAME        42840021
         B     POINTOLD                 GO SAVE BOTH NAMES              42930021
         SPACE                                                          43020021
OLDHIGH  EQU   *                                                        43110021
         OI    STWFLAG1,STWCHNG+STWADD  INDICATE ADD FUNCTION TO        43200021
*                                       BE PERFORMED FIRST              43290021
         ST    PARMRG2,STWHIGH          SAVE ADDRESS OF OLD NAME        43380021
         LA    PARMRG2,USENEWNM         POINT TO NEW NAME               43470021
         ST    PARMRG2,STWPARM          SAVE NEW NAME ADDRESS           43560021
         SPACE                                                          43650021
POINTOLD EQU   *                                                        43740021
         LPR   PARMRG2,PARMRG0          POINT TO PARAMETER              43830021
*                                       ENTRY TO BE ACTED UPON          43920021
         MVC   STWOLDNM(L'STWOLDNM+L'STWNEWNM),USEOLDNM  SAVE THE       44010021
*                                       USER' PARAMETER FOR CHANGE      44100021
         B     BUILDIO                  GO BUILD THE I/O                44190021
         SPACE 2                                                        44280021
*********************************************************************** 44370021
****                                                               **** 44460021
****     THIS SECTION MOVES THE USER'S PARAMETER TO THE WORK AREA  **** 44550021
****                                                               **** 44640021
*********************************************************************** 44730021
DATEST   EQU   *                                                        44820021
         LA    TTRCRG,L'USENEWNM        LENGTH TO BE MOVED              44910021
         ST    PARMRG2,STWPARM          SAVE THE ENTRY ADDRESS          45000021
         TM    STWFLAG1,STWDEL          DELETE FUNCTION                 45090021
         BO    MOVEUSER                 YES GO MOVE ITS ENTRY           45180021
         DROP  PARMRG2                  DROP USER PARAMETER BASE REG    45270021
         USING USENEWNM,PARMRG2         ADDRESSABILITY TO NEW ENTRY     45360021
         IC    TTRCRG,USECTTRN          GET THE AMOUNT OF USER DATA     45450021
         SLL   TTRCRG,TWNTYSVN          CLEAR ALIAS BIT                 45540021
         SRL   TTRCRG,TWNTYSIX          RESTORE, MULTIPLY BY TWO        45630021
         LA    TTRCRG,USELNGMV(TTRCRG)  ADD NAME AND TTR LENGTH         45720021
         LA    ENTADDRG,STWNEWNM        POINT TO AREA FOR ENTRY         45810021
*                                       TO BE MOVED                     45900021
         SPACE                                                          45990021
MOVEUSER EQU   *                                                        46080021
         BCTR  TTRCRG,NULL              PREPARE FOR EXECUTE             46170021
         EX    TTRCRG,MOVEPARM          MOVE THE USER'S ENTRY           46260021
         TM    STWFLAG1,STWCHNG+STWDEL  CHANGE OR DELETE FUNCTION       46350021
         BM    BUILDIO                  IF YES, BRANCH                  46440021
         TM    STWCTTRN,STWALIAS        ALIAS BIT ON                    46530021
         BO    BUILDIO                  IF YES, BRANCH                  46620021
         MVC   STWTTR,DCBRELAD          SAVE THE RELATIVE ADDR.         46710021
         MVC   STWCTTRN,USECTTRN        GET THE USER'S LENGTH           46800021
         SPACE 2                                                        46890021
*********************************************************************** 46980021
****                                                               **** 47070021
****     THIS SECTION BUILDS THE ECB IOB AND CHANNEL PROGRAMS      **** 47160021
****     THAT WILL BE USED BY STOW.                                **** 47250021
****                                                               **** 47340021
*********************************************************************** 47430021
         SPACE 2                                                        47520021
****                                                                    47610021
****     THIS PART BUILDS THE ECB AND THE IOB                           47700021
****                                                                    47790021
BUILDIO  EQU   *                                                        47880021
         DROP  PARMRG2                  DROP ADDRESSABILITY             47970021
         AIF   ('&LIB' EQ 'LIB1').NSVS1                                 47972002
         DROP  R3                                               XA01664 47972403
         USING CVTDSECT,R15            CVT ADDR.                XA01664 47972803
         L     R15,CVTPTR              GET THE CVT ADDR.        XA01664 47974003
         L     R15,CVTTCBP             ADDR. OF NEXT & CURRENT  XA01664 47976003
         L     R15,FOUR(R15)           ADDR. OF CURRENT TCB     XA01664 47978003
         TM    TCBFLGS6(R15),VRRQST    V=R REQUEST?             XA01664 47980003
         BNO   NOTVR                   BRANCH IF NOT            XA01664 47982003
         L     R1,STWPARM              ADDR. OF FIRST ENTRY     XA01664 47988003
         LA    R2,VRRQST(R1)           END ADDR. FOR PAGE FIX   XA01664 47988403
         TM    STWFLAG1,STWCHNG+STWADD CHANGE ADD REQUEST?      XA01664 47990003
         BNO   CHNGVR                  BRANCH IF NOT            XA01664 47992003
         L     R1,STWHIGH              START ADDR FOR PAGE FIX  XA01664 47992403
         LA    R2,VRRQST(R1)           END LIST                 XA01664 47994003
CHNGVR   EQU   *                                                XA01664 47994803
         STM   R0,R2,ECB               SAVE PARAMETERS          XA01664 48020003
         LA    R1,ECB+FOUR             POINT TO PARAMETERS      XA01664 48020403
         LA    R0,ECB                  POINT TO THE ECB         XA01664 48020803
         MVI   ECB+EIGHT,VRRQST        INDICATE END OF LIST     XA01664 48021203
         PGFIX L,LA=(1),ECB=(0)        ISSUE PAGE FIX           XA01664 48022403
         WAIT  1,ECB=ECB               WAIT FOR PAGE FIX        XA01664 48023603
         OI    STWFLAG1,VRFIX          SET PAGE FIX FLAG        XA01664 48025603
NOTVR    EQU   *                                                XA01664 48027603
         DROP  R15                                              XA01664 48027703
.NSVS1   ANOP                                                           48028002
         SR    R15,R15                  CLEAR FOR ECB                   48060021
         SR    R0,R0                    CLEAR FOR IOB SENSE             48150021
         LA    R1,ECB                   POINT TO THE ECB                48240021
         SR    R2,R2                    CLEAR FOR IOB CHANNEL           48330021
         LA    R4,STWINCP               POINT TO THE CHANNEL PROG       48420021
         LA    R6,DCBDEBAD-IHADCB       GET OFFSET TO DEB PTR IN DCB    48510021
         LA    R5,STWDEBPT              GET ADDR OF DEB POINTER         48600021
         SR    R5,R6                    CALCULATE DUMMY DCB ADDRESS     48690021
         SR    R6,R6                    CLEAR FOR RESTART ADDR          48780021
         SR    R7,R7                    CLEAR FOR BLOCK COUNT           48870021
         LM    R8,R9,DEBBASND+(DEBBINUM-DEBDASD)  GET DATA SET          48960021
*                                       STARTING BBCCHH FROM THE DEB    49050021
         SRDL  R8,SIXTEEN               SET EXTENT NUMBER TO ZERO       49140021
         SLDL  R8,EIGHT                 SET RECORD NUMBER TO ZERO       49230021
         STM   R15,R9,ECB               STORE REGISTERS TO CREATE       49320021
*                                       THE ECB AND IOB                 49410021
         MVC   DEBDCBB,IOBDCBPB         PUT DUMMY DCB POINTER INTO DEB  49500021
         MVI   IOBFLAG1,IOBUNREL        SET UNRELATED FLAG              49590021
         SPACE 2                                                        49680021
****                                                                    49770021
****     THIS PART BUILDS THE CHANNEL PROGRAMS                          49860021
****                                                                    49950021
         LM    R14,R9,CHNLPRG1          LOAD SKELETON CHANNEL PROGRAM   50040021
         AR    R14,R10                  ESTABLISH ADDRESSING            50130021
*                                       FOR SEARCH ID                   50220021
         AR    R0,R10                   ESTABLISH TRANSFER ADDR         50310021
         AR    R2,R10                   ADDRESSING FOR READ COUNT       50400021
         A     R4,STWPARM               POINT TO USER ENTRY             50490021
         AR    R6,R10                   ESTABLISH ADDRESSING            50580021
         AR    R8,R10                   ESTABLISH ADDRESSING            50670021
         STM   R14,R9,STWINCP           STORE REGISTERS TO CREATE       50760021
*                                       PARTIAL CHANNEL PROGRAM         50850021
         LM    R14,R15,RDCTKDA          LOAD REST OF SKELETON           50940021
*                                       CHANNEL PROGRAM                 51030021
         AR    R14,R10                  ESTABLISH ADDRESSING            51120021
         STM   R14,R15,STWRCKD1         COMPLETE CHANNEL PROGRAM        51210021
         SPACE                                                          51300021
CSWTEST  EQU   *                                                        51390021
         BAL   LINKRG,EXCPSTW           GO EXECUTE CHANNEL PROG         51480021
         SPACE 2                                                        51570021
*********************************************************************** 51660021
****                                                               **** 51750021
****     THIS SECTION SEARCHES FOR ENTRY IN THE DIRECTORY          **** 51840021
****     THAT IS EQUAL OR HIGHER THAN THE REQUESTER'S PARAMETER    **** 51930021
****                                                               **** 52020021
*********************************************************************** 52110021
         LA    BUFADRG,STWBUF1          POINT TO THE FIRST BUFFER       52200021
         USING BUFFER,BUFADRG           ESTABLISH ADDRESSABILITY        52290021
         LA    DIRSCNRG,BUFENTRY        POINT TO FIRST ENTRY            52380021
         L     ENTADDRG,STWPARM         GET ADDRESS OF ENTRY IN         52470021
*                                       USER'S AREA                     52560021
         TM    STWFLAG1,STWFLOW         FIRST TIME THROUGH              52650021
         BNO   DIRSCAN                  YES, GO SEARCH DIRECTORY        52740021
         L     ENTADDRG,STWHIGH         NO, POINT TO SECOND ENTRY       52830021
         SPACE                                                          52920021
DIRSCAN  EQU   *                                                        53010021
         CLC   NULL(EIGHT,DIRSCNRG),NULL(ENTADDRG)  COMPARE ENTRY       53100021
*                                       NAME USER SUPPLIED TO ONE       53190021
*                                       IN THE DIRECTORY                53280021
         BNL   TSTRQST                  ENTRY IN DIRECTORY EQUAL        53370021
*                                       OR HIGH, BRANCH                 53460021
         USING ENTRY,DIRSCNRG           ESTABLISH ADDRESSABILITY        53550021
         IC    TTRCRG,ENTCTTRN          GET C OF TTRC FOR THIS ENTRY    53640021
         SLL   TTRCRG,TWNTYSVN          CLEAR TTR AND ALIAS BITS        53730021
         SRL   TTRCRG,TWNTYSIX          RESTORE AND MULTIPLY BY TWO     53820021
         LA    DIRSCNRG,ENTPREFX(TTRCRG,DIRSCNRG)  POINT TO NEXT        53910021
*                                       ENTRY IN THE DIRECTORY          54000021
         B     DIRSCAN                  GO LOOK AT NEXT ENTRY           54090021
         SPACE 2                                                        54180021
*********************************************************************** 54270021
****                                                               **** 54360021
****     THIS SECTION TESTS THE VALIDITY OF THE USER'S REQUEST     **** 54450021
****                                                               **** 54540021
*********************************************************************** 54630021
TSTRQST  EQU   *                                                        54720021
         BE    EQLENT                   IF COMPARE OF ENTRIES WAS       54810021
*                                       EQUAL, BRANCH                   54900021
         TM    STWFLAG1,STWFLOW         FIRST TIME THROUGH              54990021
         BNO   DELETFUN                 YES, BRANCH                     55080021
         TM    STWFLAG1,STWCHNG+STWADD  CHANGE-ADD TO BE PERFORMED      55170021
         BO    EREXIT1                  YES, GO RETURN TO USER          55260021
         B     SAVEOFF                  GO SAVE THE OFFSET              55350021
         SPACE                                                          55440021
DELETFUN EQU   *                                                        55530021
         TM    STWFLAG1,STWDEL          DELETE FUNCTION                 55620021
         BO    EREXIT1                  YES, RETURN TO USER             55710021
         TM    STWFLAG1,STWREPL         REPLACE FUNCTION                55800021
         BNO   SAVEOFF                  NO, BRANCH                      55890021
         MVI   STWRTN,NONAME            INDICATE ENTRY COULD NOT        55980021
*                                       BE FOUND IN THE DIRECTORY       56070021
         XI    STWFLAG1,STWREPL+STWADD  CHANGE FUNCTION TO ADD          56160021
         B     SAVEOFF                  GO SAVE OFFSET                  56250021
         SPACE                                                          56340021
EQLENT   EQU   *                                                        56430021
         TM    STWFLAG1,STWFLOW         FIRST TIME THROUGH              56520021
         BNO   ADDTEST                  YES, BRANCH                     56610021
         TM    STWFLAG1,STWCHNG+STWDEL  CHANGE-DELETE REQUESTED         56700021
         BO    ER4EXIT                  YES, RETURN TO USER             56790021
         B     MAYBEREP                 GO SAVE USER DATA               56880021
         SPACE                                                          56970021
ADDTEST  EQU   *                                                        57060021
         TM    STWFLAG1,STWADD          ADD FUNCTION                    57150021
         BNO   CHNGTEST                 NO, BRANCH                      57240021
         SPACE                                                          57330021
ER4EXIT  EQU   *                                                        57420021
         LA    SAVECDRG,NMEXIST         SET RETURN CODE                 57510021
         B     EREXIT2                  RETURN TO USER                  57600021
         SPACE                                                          57690021
CHNGTEST EQU   *                                                        57780021
         TM    STWFLAG1,STWREPL+STWCHNG CHANGE OR REPLACE               57870021
         BZ    SAVEOFF                  NO, GO SAVE OFFSET              57960021
         SPACE 2                                                        58050021
*********************************************************************** 58140021
****                                                               **** 58230021
****     THIS SECTION SAVES THE TTR AND USER DATA FROM THE         **** 58320021
****     ENTRY IN THE DIRECTORY BLOCK                              **** 58410021
****                                                               **** 58500021
*********************************************************************** 58590021
MAYBEREP EQU   *                                                        58680021
         USING ENTRY,DIRSCNRG           ESTABLISH ENTRY ADDR            58770021
         TM    STWFLAG1,STWREPL         REPLACE FUNCTION                58860021
         BNO   SAVENTRY                 NO, SAVE ENTRY FOR CHANGE       58950021
         TM    STWFLAG1,STWDCBWR        LAST OPERATION A WRITE          59040021
         BO    SAVEOFF                  YES, GO SAVE OFFSET             59130021
         TM    STWCTTRN,STWALIAS        ALIAS ENTRY?            XA02068 59180003
         BO    SAVEOFF                  YES, GO SAVE OFFSET     XA02068 59190003
         MVC   STWTTR,ENTTTR            NO, SAVE TTR FROM ENTRY         59220021
         B     SAVEOFF                  GO SAVE OFFSET                  59310021
         SPACE                                                          59400021
SAVENTRY EQU   *                                                        59490021
         IC    TTRCRG,ENTCTTRN          GET C OF THE TTRC FOR           59580021
*                                       THIS ENTRY                      59670021
         SLL   TTRCRG,TWNTYSVN          CLEAR TTR AND ALIAS BITS        59760021
         SRL   TTRCRG,TWNTYSIX          RESTORE AND MULTIPLY BY TWO     59850021
         LA    TTRCRG,THREE(TTRCRG)     SET LENGTH TO MOVE THE TTRC AND 59940021
*                                       USER DATA                       60030021
         LA    ENTADDRG,STWTTR          POINT IN WORK AREA TO           60120021
*                                       RELATIVE ADDR. FOR ENTRY        60210021
         EX    TTRCRG,MVTTRDAT          SAVE THE ENTRY'S TTRC           60300021
*                                       AND USER DATA                   60390021
         B     SAVEOFF                  GO SAVE THE OFFSET              60480021
         SPACE 2                                                        60570021
*********************************************************************** 60660021
****                                                               **** 60750021
****     THIS SECTION IS ENTERED WHEN AN ERROR IS DETECTED         **** 60840021
****     AND CONTROL IS TO BE PASSED TO THE USER                   **** 60930021
****                                                               **** 61020021
*********************************************************************** 61110021
EREXIT1  EQU   *                                                        61200021
         LA    SAVECDRG,NONAME          SET RETURN CODE                 61290021
         SPACE                                                          61380021
EREXIT2  EQU   *                                                        61470021
         AIF   ('&LIB' EQ 'LIB1').NSVS2                                 61520002
         TM    STWFLAG1,VRFIX          PAGE FIXED?              XA01664 61522003
         BNO   NOPGFREE                BRANCH IF NOT            XA01664 61524003
         L     R1,STWPARM              STARTING ADDR            XA01664 61526003
         LA    R2,VRRQST(R1)           ENDING ADDR              XA01664 61528003
         TM    STWFLAG1,STWCHNG+STWADD CHANGE REQUEST?          XA01664 61528403
         BNO   PGREL                   BRANCH IF NOT            XA01664 61528803
         L     R1,STWHIGH              STARTING ADDR            XA01664 61530003
         LA    R2,VRRQST(R1)           ENDING ADDR              XA01664 61540003
PGREL    EQU   *                                                XA01664 61542003
         PGRLSE  LA=(1),HA=(2)                                  XA01664 61544003
NOPGFREE EQU   *                                                XA01664 61546003
.NSVS2   ANOP                                                           61548002
         LH    PARMRG0,STWGMSZ          GET SIZE OF GOTTEN CORE         61560021
         LR    DCBRG1,WRKARG            PREPARE FOR FREEMAIN            61650021
         FREEMAIN  R,LV=(0),A=(1)       FREECORE                        61830021
         LR    RTNRG,SAVECDRG           GET THE RETURN CODE      YM0943 61880001
         SVC   RETURN                   RETURN TO THE USER              61920021
         SPACE 2                                                        62010021
*********************************************************************** 62100021
****                                                               **** 62190021
****     THIS SECTION ISSUES THE EXCP AND TESTS FOR                **** 62280021
****     A SUCCESSFUL COMPLETION                                   **** 62370021
****                                                               **** 62460021
*********************************************************************** 62550021
EXCPSTW  EQU   *                                                        62640021
         EXCP  IOBSTDRD                 EXECUTE THE CHANNEL PROG        62730021
         WAIT  ECB=ECBCC                WAIT FOR PROGRAM                62820021
         TM    ECBCC,ECBNORM            SUCCESSFUL COMPLETION           62910021
         BCR   1,LINKRG                 YES, RETURN TO MAIN LINE        63000021
         TM    IOBCSW+THREE,UNITEXCP    UNIT EXCEPTION                  63090021
         BCR   1,LINKRG                 YES, RETURN TO MAIN LINE        63180021
         LA    SAVECDRG,IOERRCD         SET IO ERROR CODE               63270021
         B     EREXIT2                  RETURN TO USER                  63360021
         SPACE 2                                                        63450021
*********************************************************************** 63540021
****                                                               **** 63630021
****     THIS SECTION WILL ESTABLISH THE NEW KEY TO SEARCH         **** 63720021
****     ON FOR THE CHANGE FUNCTION                                **** 63810021
****                                                               **** 63900021
*********************************************************************** 63990021
SETFRST  EQU   *                                                        64080021
         OI    STWFLAG1,STWFLOW         INDICATE SECOND TIME THROUGH    64170021
         L     ENTADDRG,STWHIGH         POINT TO THE HIGH NAME          64260021
*                                       IN USER'S AREA                  64350021
         MVC   STWKYAD1,STWHIGH+1       SET NEW SEARCH KEY              64440021
         B     CSWTEST                  GO ISSUE EXCP                   64530021
         SPACE 2                                                        64620021
*********************************************************************** 64710021
****                                                               **** 64800021
****     THIS SECTION OF CODE SAVES THE OFFSET OF THE ENTRY INTO   **** 64890021
****     THE INPUT BUFFER.                                         **** 64980021
****                                                               **** 65070021
*********************************************************************** 65160021
SAVEOFF  EQU   *                                                        65250021
         SR    DIRSCNRG,BUFADRG         DETERMINE OFFSET                65340021
         TM    STWFLAG1,STWFLOW         FIRST TIME THROUGH              65430021
         BO    NEXTLOAD                 NO, GO TO DETERMINE NEXT LOAD   65520021
         STH   DIRSCNRG,STWOFFLW        SAVE THE FIRST ENTRY OFFSET     65610021
         TM    STWFLAG1,STWCHNG         CHANGE FUNCTION                 65700021
         BO    SETFRST                  YES, RETURN TO MAINLINE         65790021
         SPACE 2                                                        65880021
*********************************************************************** 65970021
****                                                               **** 66060021
****     THIS SECTION TRANSFERS CONTROL TO THE SECOND LOAD.        **** 66150021
****                                                               **** 66240021
*********************************************************************** 66330021
NEXTLOAD EQU   *                                                        66420021
         MVC   STWXATTB,XCTLATTB        SET UP MODULE ATTRIBUTES FIELD  66510021
         MVI   STWXMODL+1,MODLNTH       MAIN STORAGE REQUIRED    XM5415 66600021
         MVI   STWXTXTL,MODLNTH         LENGTH OF FIRST TEXT RCD XM5415 66650021
         MVC   STWXNAME,XCTLNAME        MOVE COMMON AND ID PORTIONS OF  66690021
*                                       THIRD LOAD NAME TO XCTL AREA    66780021
         MVC   STWXTTR,SCNDLOAD+2       MOVE SECOND LOAD TTR TO XCTL    66870021
*                                       AREA                            66960021
         LA    R15,STWXPTR              SET UP XCTL AREA POINTER        67050021
         XCTL  DE=(WRKARG),SF=(E,(15))  XCTL TO IGGO210A                67140021
         EJECT                                                          67230021
*********************************************************************** 67320021
****                                                               **** 67410021
****     SKELETON CHANNEL PROGRAMS                                 **** 67500021
****                                                               **** 67590021
*********************************************************************** 67680021
CHNLPRG1 DS    0F                       THIS CHANNEL PROGRAM IS USED TO 67770021
*                                       READ TWO DIRECTORY BLOCKS       67860021
RDSRCHID DC    X'31'                    SEARCH ID EQUAL                 67950021
         DC    AL3(IOBCC-STWAREA)       ADDRESS OF SEARCH ARGUMENT      68040021
         DC    X'4000'                  COMMAND CHAINING                68130021
         DC    X'0005'                  NO. OF BYTES                    68220021
RDSRCTIC DC    X'08'                    TRANSFER CONTROL                68310021
         DC    AL3(STWSRCH1-STWAREA)    ADDR OF SEARCH ID               68400021
         DC    XL4'00'                  NOT USED, BUT REQUIRED          68490021
RDCOUNT  DC    X'92'                    READ COUNT                      68580021
         DC    AL3(STWBUF1-STWAREA)     ADDR. FOR COUNT                 68670021
         DC    X'4000'                  COMMAND CHAINING                68760021
         DC    X'0008'                  NO. OF BYTES TRANSFERED         68850021
RDSRCHKY DC    X'E9'                    SEARCH KEY EQUAL- HIGH          68940021
         DC    AL3(0)                   ADDR OF USER PARAMETER          69030021
         DC    X'4000'                  COMMAND CHAINING                69120021
         DC    X'0008'                  NO. BYTES TO SEARCH ON          69210021
RDSRCHTC DC    X'08'                    TRANSFER CONTROL                69300021
         DC    AL3(STWRDCT1-STWAREA)    ADDR. OF READ COUNT             69390021
         DC    XL4'00'                  NOT USED BUT REQUIRED           69480021
RDRDDATA DC    X'86'                    READ DATA                       69570021
         DC    AL3(STWBUF1+L'BUFCNT+L'BUFKEY-STWAREA)  ADDR. FOR DATA   69660021
         DC    X'4000'                  COMMAND CHAINING                69750021
         DC    X'0100'                  NO. OF BYTES TRANSFERED         69840021
RDCTKDA  DC    X'9E'                    READ COUNT KEY DATA             69930021
         DC    AL3(STWBUF2-STWAREA)     ADDR. FOR COUNT KEY DATA        70020021
         DC    X'0000'                  NO FLAGS                        70110021
         DC    X'0110'                  NO. OF BYTES TRANSFERED         70200021
         SPACE 2                                                        70290021
*********************************************************************** 70380021
****                                                               **** 70470021
****     DEFINED CONSTANTS                                         **** 70560021
****                                                               **** 70650021
*********************************************************************** 70740021
MOVEDEB  MVC   DEBBASND-DEBBASIC(0,DEBRG),DEBBASND-DEBBASIC(R9)  MOVE   70830021
*                                       DEB EXTENTS TO WORK AREA        70920021
MOVEPARM MVC   0(0,ENTADDRG),0(PARMRG2) MOVE USER PARAMETER TO          71010021
*                                       WORK AREA                       71100021
MVTTRDAT MVC   0(0,ENTADDRG),L'ENTNAME(DIRSCNRG) MOVE USER DATA FROM    71190021
*                                       DIRECTORY TO WORK AREA          71280021
SYSMASK  DC    X'FF'                    ENABLE ALL INTERRUPTS           71370021
         SPACE 2                                                        71460021
*********************************************************************** 71550021
****                                                               **** 71640021
****     GETMAIN LIST FORM AND XCTL WHERE TO GO TABLE              **** 71730021
****                                                               **** 71820021
*********************************************************************** 71910021
GTMNLIST GETMAIN  EC,LV=0,MF=L          GETMAIN LIST FORM               72000021
LNGTMAIN EQU   *-GTMNLIST               LENGTH OF GETMAIN LIST FORM     72090021
         SPACE                                                          72180021
XCTLATTB DC    X'C3F0'                  ATTRIBUTES OF ALL LOADS OF STOW 72270021
         DC    CL6' '                   RESERVE SPACE FOR COMMON        72360021
*                                       PORTION OF XCTL NAME            72450021
         XCTLTABL ID=(SCNDLOAD,0A),SVC=021                              72540021
         ORG   SCNDLOAD-6               INSURE THAT THE COMMON AND ID   72630021
*                                       PORTIONS OF THE XCTL NAME ARE   72720021
*                                       CONTIGUOUS                      72810021
XCTLNAME DC    CL6'IGG021'              COMMON PORTION OF XCTL NAME     72900021
         EJECT                                                          72990021
STWAREA  DSECT                                                          73080021
         SPACE 2                                                        73170021
*********************************************************************** 73260021
****                                                               **** 73350021
****     THIS DSECT MAPS THE WORK AREA USED BY THE STOW MODULES    **** 73440021
****                                                               **** 73530021
*********************************************************************** 73620021
         SPACE 2                                                        73710021
****                                                                    73800021
****     XCTL AREA USED BY FIRST AND SECOND LOAD MODULES OF STOW        73890021
****                                                                    73980021
STWXAREA DS    0CL32                    XCTL AREA                       74070021
STWXNAME DS    0CL8                     MODULE NAME                     74160021
STWXCOMN DS    CL6                      COMMON PORTION OF MODULE NAME   74250021
STWXID   DS    CL2                      ID PORTION OF MODULE NAME       74340021
         DS    XL6                      UNUSED - MUST BE ZEROS          74430021
STWXTTR  DS    XL3                      TTR OF MODULE                   74520021
         DS    XL5                      UNUSED - MUST BE ZEROS          74610021
STWXATTB DS    XL2                      ATTRIBUTES OF ALL LOADS         74700021
STWXMODL DS    XL3                      MAIN STORAGE REQUIRED    XM5415 74790021
STWXTXTL DS    XL2                      LENGTH OF FIRST TEXT RCD XM5415 74880021
         DS    XL3                      UNUSED - MUST BE ZEROS          74970021
STWXPTR  DS    2A                       POINTER TO XCTL AREA AND DCB    75060021
*                                       (DCB PTR IS ZEROS FOR SVCLIB)   75150021
         SPACE 2                                                        75240021
****                                                                    75330021
****     POINTERS AND USER DATA SAVE AREA                               75420021
****                                                                    75510021
STWPARM  DS    A                        ADDR OF USER SUPPLIED ENTRY     75600021
*                                       NAME (LOWER OF 2 FOR CHANGE)    75690021
STWHIGH  DS    A                        ADDR OF HIGHER OF 2 USER SUPP-  75780021
*                                       LIED ENTRY NAMES (CHANGE ONLY)  75870021
STWDEBPT DS    A                        ADDR OF DEB IN WORK AREA        75960021
STWGMSZ  DS    H                        SIZE OF CORE GOTTEN FOR WORK    76050021
*                                       AREA                            76140021
STWOFFLW DS    H                        OFFSET TO ADD, REPLACE, OR      76230021
*                                       DELETE LOCATION IN LOW BLOCK    76320021
STWOLDNM DS    CL8                      NAME OF ENTRY BEING DELETED     76410021
STWNEWNM DS    CL8                      NAME OF NEW ENTRY               76500021
STWTTR   DS    AL3                      MEMBER'S RELATIVE ADDRESS       76590021
STWCTTRN DS    XL1                      ALIAS BIT, NUMBER OF TTRNS,     76680021
*                                       AND LENGTH OF USER DATA         76770021
STWALIAS EQU   X'80'                    THIS MEMBER NAME IS AN ALIAS    76860021
STWDATA  DS    CL62                     USER DATA FOR ENTRY             76950021
         SPACE 2                                                        77040021
****                                                                    77130021
****     FLAG, CONDITION, AND SWITCH BYTES                              77220021
****                                                                    77310021
STWFLAG1 DS    B                        FIRST FLAG BYTE                 77400021
*                       BIT DEFINITIONS                                 77490021
*        BIT   7                        RESERVED                        77580021
STWCHNG  EQU   X'80'                    CHANGE FUNCTION, USED IN COMBI- 77670021
*                                       NATION WITH STWADD AND STWDEL   77760021
STWDEL   EQU   X'40'                    DELETE FUNCTION                 77850021
STWREPL  EQU   X'20'                    REPLACE FUNCTION                77940021
STWADD   EQU   X'10'                    ADD FUNCTION                    78030021
STWDRYRN EQU   X'08'                    DRY RUN BEING MADE ON DIRECTORY 78120021
STWFLOW  EQU   X'04'                    USED TO CONTROL PROGRAM FLOW    78210021
STWDCBWR EQU   X'02'                    LAST DCB OPERATION WAS A WRITE  78300021
*                                                                       78390021
STWRTN   DS    CL1                      RETURN CODE SAVE AREA           78480021
*                                                                       78570021
STWFLGLN EQU   *-STWAREA                LENGTH OF SAVE AND FLAG AREAS   78660021
         EJECT                                                          78750021
****                                                                    78840021
****     CONTROL BLOCKS FOR STOW'S CHANNEL PROGRAMS                     78930021
****                                                                    79020021
         IHAECB  DSECT=NO                                               79110021
         ORG   *-16                     SET STANDARD IOB BEHIND ECB     79200021
         IEZIOB  DSECT=NO                                               79290021
         SPACE 2                                                        79380021
****                                                                    79470021
****     STOW'S CHANNEL PROGRAMS                                        79560021
****                                                                    79650021
         ORG   IOBR+1                   PLACE CHANNEL PROGRAMS          79740021
*                                       BEHIND THE IOB SEEK FIELD       79830021
STWINCP  DS    0D                       THIS CHANNEL PROGRAM READS THE  79920021
*                                       INITIAL TWO DIRECTORY BLOCKS    80010021
STWSRCH1 DS    2F                       SEARCH ID EQUAL                 80100021
STWTIC11 DS    2F                       TRANSFER CONTROL TO SEARCH ID   80190021
STWRDCT1 DS    2F                       READ COUNT                      80280021
STWSRKY1 DS    XL1                      SEARCH ON KEY EQUAL OR HIGH     80370021
STWKYAD1 DS    AL3                      KEY ADDRESS                     80460021
         DS    XL4                      FLAGS AND BYTE COUNT            80550021
STWTIC12 DS    2F                       TRANSFER CONTROL TO READ COUNT  80640021
STWRDAT1 DS    2F                       READ DATA                       80730021
STWRCKD1 DS    2F                       READ COUNT KEY DATA             80820021
         SPACE                                                          80910021
STWWRDCP DS    0D                       THIS CHANNEL PROGRAM WRITES     81000021
*                                       AND READS DIRECTORY BLOCKS      81090021
STWSRCH2 DS    XL1                      SEARCH ID EQUAL                 81180021
STWIDAD2 DS    AL3                      ID ADDRESS                      81270021
         DS    XL4                      FLAGS AND BYTE COUNT            81360021
STWTIC2  DS    2F                       TRANSFER CONTROL TO SEARCH ID   81450021
STWWRKD1 DS    XL1                      WRITE KEY AND DATA              81540021
STWWRAD2 DS    AL3                      WRITE ADDRESS                   81630021
STWWFLG2 DS    B                        FLAGS                           81720021
STWCMDCH EQU   X'40'                    COMMAND CHAIN TO NEXT CCW       81810021
         DS    XL3                      BYTE COUNT                      81900021
STWRCKD2 DS    XL1                      READ COUNT KEY DATA             81990021
STWRDAD2 DS    AL3                      READ ADDRESS                    82080021
         DS    XL4                      FLAGS AND BYTE COUNT            82170021
STWRCKD3 DS    XL1                      READ COUNT KEY DATA             82260021
STWRDAD3 DS    AL3                      READ ADDRESS                    82350021
         DS    XL4                      FLAGS AND BYTE COUNT            82440021
         SPACE 2                                                        82530021
****                                                                    82620021
****     COMMAND CODE EQUATES FOR CHANNEL PROGRAMS                      82710021
****                                                                    82800021
STWIDEQ  EQU   X'31'                    SEARCH ON IDENTIFIER EQUAL      82890021
STWWRKD  EQU   X'0D'                    WRITE KEY AND DATA              82980021
STWRDKD  EQU   X'8E'                    READ KEY AND DATA               83070021
STWRDCKD EQU   X'9E'                    READ COUNT, KEY, AND DATA       83160021
         SPACE 2                                                        83250021
****                                                                    83340021
****     STOW'S INPUT - OUTPUT BUFFERS.  FOR DETAILS SEE THE            83430021
****     BUFFER DSECT.                                                  83520021
****                                                                    83610021
STWBUF1  DS    0F                       INITIALLY CONTAINS THE FIRST    83700021
         DS    CL276                    OF TWO DIRECTORY BLOCKS READ    83790021
STWBUF2  DS    0F                       INITIALLY CONTAINS THE SECOND   83880021
         DS    CL276                    OF TWO DIRECTORY BLOCKS READ    83970021
STWBUF3  DS    0F                       INITIALLY USED AS THE FIRST     84060021
         DS    CL276                    OUTPUT BUFFER                   84150021
STWBUF4  DS    0F                       USED AS AN INPUT BUFFER SA66881 84200021
         DS    CL272                    IN LAST LOAD OF STOW    SA66881 84210021
STWDEB   DS    0F                       LOCATION OF COPIED DEB          84240021
STWEND   EQU   *                        END OF WORK AREA                84330021
CORESIZE EQU   STWEND-STWAREA           SIZE OF STOW'S WORK AREA        84420021
         EJECT                                                          84510021
BUFFER   DSECT                                                          84600021
         SPACE                                                          84690021
*********************************************************************** 84780021
****                                                               **** 84870021
****     THIS DSECT MAPS STOW'S INPUT - OUTPUT BUFFERS             **** 84960021
****                                                               **** 85050021
*********************************************************************** 85140021
         SPACE                                                          85230021
BUFCNT   DS    CL8                      COUNT FIELD CONTAINING          85320021
*                                       ABSOLUTE DISK ADDRESS           85410021
BUFKEY   DS    CL8                      KEY FIELD (HIGHEST MEMBER NAME) 85500021
BUFDATA  DS    0CL256                   DATA AREA                       85590021
BUFN     DS    H                        NUMBER OF BYTES USED IN         85680021
*                                       THIS DIRECTORY BLOCK            85770021
BUFENTRY DS    CL254                    DIRECTORY ENTRIES               85860021
BUFADDR  DS    A                        USED TO CHAIN THE BUFFERS       85950021
BUFPREFX EQU   L'BUFCNT+L'BUFKEY+L'BUFN  OFFSET TO BUFFER ENTRY AREA    86040021
         SPACE 4                                                        86130021
ENTRY    DSECT                                                          86220021
         SPACE                                                          86310021
*********************************************************************** 86400021
****                                                               **** 86490021
****     THIS DSECT MAPS A DIRECTORY ENTRY                         **** 86580021
****                                                               **** 86670021
*********************************************************************** 86760021
         SPACE                                                          86850021
ENTNAME  DS    CL8                      ENTRY NAME                      86940021
ENTTTR   DS    AL3                      MEMBER'S RELATIVE ADDRESS       87030021
ENTCTTRN DS    XL1                      ALAIS BIT, NUMBER OF TTRNS,     87120021
*                                       AND LENGTH OF USER DATA         87210021
ENTALAIS EQU   X'80'                    THIS MEMBER NAME IS AN ALAIS    87300021
ENTDATA  DS    CL62                     USER DATA FOR ENTRY             87390021
ENTPREFX EQU   L'ENTNAME+L'ENTTTR+L'ENTCTTRN  SIZE OF AREA PRECEDING    87480021
*                                       USER DATA AREA                  87570021
         SPACE 4                                                        87660021
USERPARM DSECT                                                          87750021
         SPACE                                                          87840021
*********************************************************************** 87930021
****                                                               **** 88020021
****     THIS DSECT MAPS THE USER PARAMETER FIELD                  **** 88110021
****                                                               **** 88200021
*********************************************************************** 88290021
         SPACE                                                          88380021
USEOLDNM DS    CL8                      OLD NAME FOR DELETE OR CHANGE   88470021
USENEWNM DS    CL8                      NEW NAME FOR ADD, REPLACE, OR   88560021
*                                       CHANGE                          88650021
USETTR   DS    XL3                      RELATIVE ADDRESS OF MEMBER      88740021
USECTTRN DS    XL1                      ALIAS AND LENGTH OF USER DATA   88830021
USEDATA  DS    CL62                     USER DATA                       88920021
USELNGMV EQU   L'USENEWNM+L'USECTTRN+L'USETTR  LENGTH OF NAME AND TTRC  89010021
         EJECT                                                          89100021
CVTDSECT DSECT                                                          89190021
         CVT                                                            89280021
         EJECT                                                          89370021
         DCBD  DSORG=PO,DEVD=DA                                         89460021
         EJECT                                                          89550021
         IEZDEB                                                         89640021
         EJECT                                                          89730021
         IKJRB                                                          89820021
         SPACE 4                                                        89910021
         ORG   RBEXSAVE                                                 90000021
*********************************************************************** 90090021
****                                                               **** 90180021
****     DSECT OF THE EXTENDED SAVE AREA OF THE SVRB               **** 90270021
****                                                               **** 90360021
*********************************************************************** 90450021
RBGTMLST DS    F                                                        90540021
         DS    F                                                        90630021
         DS    F                                                        90720021
RBGTMARA DS    F                                                        90810021
         END                                                            90900021
