         TITLE 'IGC0002C, ALIAS IFG0232A - TCLOSE INITIAL FUNCTION'     00100001
         COPY  LCGASMSW                                                 00300000
IGC0002C CSECT                                                          00400021
*                                                                       00500021
*********************************************************************** 00600021
*                                                                     * 00700021
*                                                                     * 00750000
*          VS1 RELEASE 03 DELETIONS                                     00760003
*0000199547-199564,323920-323940,530820-530900                   X03004 00762003
*                                                                     * 00770000
*          VS1 RELEASE 2.6 DELETIONS                                  * 00770402
*0000409600-409700                                               XM2896 00770802
*          VS1 RELEASE 02 DELETIONS                                   * 00772002
*0000199432,530940,530960,530999,531000,531532,531666            XM1037 00772402
*0000199200-199300,563920                                        X02989 00774002
*0000                                                            XM0630 00776002
*          VS2 RELEASE 01 DELETIONS                                   * 00780000
*0000182719                                                      YM0897 00790000
*0000                                                            YM0955 00790100
*0000                                                            YM8269 00790200
*0000                                                            YM0898 00790300
*0000                                                            YM0850 00790400
*0000                                                            YM2069 00790800
*0000                                                            YM0992 00791200
*                                                                     * 00792000
*                                                                     * 00800021
*          RELEASE 25 DELETIONS/CHANGES                               * 00900021
*          RELEASE 24 DELETIONS/CHANGES                               * 01000021
*          RELEASE 23 DELETIONS/CHANGES                               * 01100021
*          RELEASE 22 DELETIONS/CHANGES                               * 01200021
*          RELEASE 21.8 DELETIONS/CHANGES                             * 01202000
*0000                                                           SA66572 01204000
*          RELEASE 21.7 DELETIONS/CHANGES                             * 01210001
*0000001000,151000,184500,207500-207700,213000-223000,224500    SA57204 01220001
*          RELEASE 21 DELETIONS/CHANGES                               * 01300021
*                                                                S21042 01400021
*                                                                M0039  01450021
*D076000-077000,079000-080000,211000-212000,218000              SA53260 01460021
*0000120000-123000,176000-179000,480000-488000,503000-504000,   SA53293 01470002
*0000514000-517000,563000                                       SA53293 01480002
*0000395000-399000,551000-552000                                 S21940 01490002
*                                                                     * 01500021
* STATUS CHANGE LEVEL 000                                             * 01600021
*                                                                     * 01700021
* FUNCTION -                                                          * 01800021
*    THIS MODULE CONTAINS THE 'TCLOSE INITIAL FUNCTION'.              * 01900021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG' FOR DETAILS.            * 02000021
*                                                                     * 02100021
* ENTRY POINTS -                                                      * 02200021
*         IGC0002C - ENTERED BY THE SUPERVISOR FROM THE SECOND-LEVEL  * 02300021
*                    INTERRUPT HANDLER (SLIH) WHEN SVC 23 (CLOSE,     * 02400021
*                    TYPE=T) IS ISSUED.                               * 02500021
*                    NOTE- IFG0232A IS AN ALIAS FOR THIS MODULE WHICH * 02560002
*                    IS USED WHEN RETURNING FROM INITIALIZATION OF    * 02570002
*                    THE OPTIONAL TRACE FACILITY.                     * 02580002
*                                                                     * 02600021
* INPUT -                                                             * 02700021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 02800021
*                                                                     * 02900021
* OUTPUT -                                                            * 03000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 03100021
*                                                                     * 03200021
* EXTERNAL REFERENCES -                                               * 03300021
*         IECPCNVT - CONVERTS A RELATIVE TRACK ADDRESS 'TTRN' TO AN   * 03400021
*            ABSOLUTE TRACK ADDRESS 'MBBCCHHR' UTILIZING THE          * 03500021
*            FOLLOWING REGISTER CONVENTUONS -                         * 03600021
*            REG    CONTENTS AT ENTRY      CONTENTS AT EXIT           * 03700021
*             0     TTRN TO BE CONVERTED   DESTROYED                  * 03800021
*             1     DEB ADDRESS            TRANSPARENT                * 03900021
*             2     ADDR OF 8-BYTE AREA    RESULTANT MBBCCHHR         * 04000021
*                   FOR MBBCCHHR                                      * 04100021
*            3-8    IGNORED                TRANSPARENT                * 04200021
*            9-13   IGNORED                DESTROYED                  * 04300021
*             14    RETURN ADDRESS         TRANSPARENT                * 04400021
*             15    ENTRY POINT ADDRESS    ERROR CODE                 * 04500021
*         THE ERROR CODE WILL BE '0' IF THE CONVERSION IS SUCCESSFUL  * 04600021
*         AND '1' IF THE 'TT' EXCEEDS THE TOTAL EXTENTS ASSIGNED.     * 04700021
*                                                                     * 04800021
* EXITS, NORMAL -                                                     * 04900021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 05000021
*                                                                     * 05100021
* EXITS, ERROR -                                                      * 05200021
*         IFG0230P - WHEN AN ERROR CONDITION OCCURS IN THIS MODULE.   * 05300021
*                    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.        * 05400021
         AIF   ('&LIB' EQ 'LIB1').LIB12CJ                               05450002
*         IDA0192P - WHEN AN ERROR OCCURS IN THIS MODULE         X02989 05460002
*                    FOR A VSAM DATA SET                         X02989 05470002
.LIB12CJ ANOP                                                           05480002
*                                                                     * 05500021
* TABLES/WORK AREAS -                                                 * 05600021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 05700021
*                                                                     * 05800021
* ATTRIBUTES -                                                        * 05900021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 06000021
*                                                                     * 06100021
* CHARACTER CODE DEPENDENCY -                                         * 06200021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 06300021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 06400021
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 06500021
*                                                                     * 06600021
* NOTES -                                                             * 06700021
*    IFG0232A IS AN ALIAS FOR THIS MODULE WHICH IS USED WHEN          * 06750002
*    RETURNING FROM INITIALIZATION OF THE OPTIONAL TRACE FACILITY.    * 06760002
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 06800021
*                                                                     * 06900021
*********************************************************************** 07000021
*                                                                       07100021
         BALR  RBASE,0                  ESTABLISH ADDRESSABILITY        07200021
         USING *,RBASE                                                  07300021
         USING FORCORE,RCORE                                            07400021
         USING IHADCB,RDCB                                              07500021
         USING WTG,RWTG                                                 07800021
         USING TIOT,RTIOT                                               08100021
         USING UCB,RUCB                 DEFINE BASE TO MAIN UCB SA57204 08110001
         USING DEB,RDEB                 DEFINE BASE TO DEB      SA57204 08120001
         USING CVT,RET                                                  08150000
         USING TCB,RD                                                   08160000
         EJECT                                                          08200021
*********************************************************************** 08300021
*                                                                     * 08400021
*                          FUNCTION PROLOG                            * 08500021
*                                                                     * 08600021
*********************************************************************** 08700021
*                                                                     * 08800021
* FUNCTION NAME -                                                     * 08900021
*    'TCLOSE INITIAL FUNCTION'                                        * 09000021
*                                                                     * 09100021
* (STATUS) -                                                          * 09200021
*    NOT APPLICABLE                                                   * 09300021
*                                                                     * 09400021
         AIF   ('&LIB' NE 'LIB1').LIB22C1                               09450000
* FUNCTION -                                                          * 09500021
*     1) VERIFIES THAT THE DCB(S) IS TO BE PROCESSED;                 * 09600021
*     2) OBTAINS MAIN STORAGE FOR THE 'WHERE-TO-GO' (WTG) TABLE;      * 09700021
*     3) OBTAINS MAIN STORAGE FOR A WORK AREA FOR EACH DCB TO BE      * 09800021
*        PROCESSED;                                                   * 09900021
*     4) INITIALIZES EACH WORK AREA WITH I/O CONTROL BLOCKS AND       * 10000021
*        CHANNEL PROGRAMS;                                            * 10100021
*     5) PURGES (QUIESCES) OUTSTANDING I/O REQUESTS FOR EACH DCB;     * 10200021
*     6) READS THE 'JOB FILE CONTROL BLOCK' (JFCB) INTO THE WORK AREA * 10300021
*        FOR EACH DCB;                                                * 10400021
*     7) INITIALIZES REGISTERS 0,1, AND 9-14  FOR THE NEXT REQUIRED   * 10500021
*        MODULE AND STORES THEM IN THE WORK AREA FOR EACH DCB;        * 10600021
*     8) MOVES THE ID/TTR OF THE NEXT REQUIRED MODULE INTO THE WTG    * 10700021
*        TABLE ENTRY FOR EACH DCB;                                    * 10800021
*     9) OBTAINS MAIN STORAGE FOR THE RESIDENT ROUTINE WORK AREA      * 10900021
*        (ECBLIST);                                                   * 11000021
*    10) BRANCHES TO THE RESIDENT ROUTINE TO CONTINUE TCLOSE.         * 11100021
*        PROCESSING, OR                                               * 11200021
*    11) EXITS TO THE SUPERVISOR IF THERE ARE NO VALID DCBS TO        * 11300021
*        PROCESS.                                                     * 11400021
*                                                                     * 11500021
.LIB22C1 ANOP                                                           11510000
         AIF   ('&LIB' EQ 'LIB1').LIB12C1                               11520000
* FUNCTION -                                                          * 11550000
*     1) VERIFIES THAT THE DCB(S) IS TO BE PROCESSED;                 * 11560000
*     2) OBTAINS MAIN STORAGE FOR THE 'WHERE-TO-GO' (WTG) TABLE;      * 11570000
*     3) OBTAINS MAIN STORAGE FOR A WORK AREA FOR EACH DCB TO BE      * 11580000
*        PROCESSED;                                                   * 11590000
*     4) INITIALIZES EACH WORK AREA WITH I/O CONTROL BLOCKS AND       * 11592000
*        CHANNEL PROGRAMS;                                            * 11594000
*     5) PURGES (QUIESCES) OUTSTANDING I/O REQUESTS FOR EACH DCB;     * 11596000
*     6) READS THE 'JOB FILE CONTROL BLOCK' (JFCB) INTO THE WORK AREA * 11598000
*        FOR EACH DCB;                                                * 11598400
*     7) INITIALIZES REGISTERS 0,1, AND 9-14  FOR THE NEXT REQUIRED   * 11598800
*        MODULE AND STORES THEM IN THE WORK AREA FOR EACH DCB;        * 11599200
*     8) MOVES THE ID/TTR OF THE NEXT REQUIRED MODULE INTO THE WTG    * 11599600
*        TABLE ENTRY FOR EACH DCB;                                    * 11599700
*     9) OBTAINS MAIN STORAGE FOR THE RESIDENT ROUTINE WORK AREA      * 11599800
*        (ECBLIST);                                                   * 11599900
*    10) BRANCHES TO THE RESIDENT ROUTINE TO CONTINUE TCLOSE.         * 11633200
*        PROCESSING, OR                                               * 11643200
*    11) EXITS TO THE SUPERVISOR IF THERE ARE NO VALID DCBS TO        * 11653200
*        PROCESS.                                                     * 11663200
*    12) DEB VALIDITY CHECKING IS ACCOMPLISHED VIA A DEB VALIDITY     * 11663600
*        CHECK ROUTINE WHICH MAINTAINS AND UPDATES A TABLE OF VALID   * 11664000
*        DEB POINTERS IN PROTECTED CORE (LSQS).                       * 11664400
*                                                                     * 11665200
.LIB12C1 ANOP                                                           11665600
* ENTRY POINTS -                                                      * 11666700
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 11700021
*                                                                     * 11800021
* INPUT -                                                             * 11900021
*    REGISTER CONTENTS AT ENTRY ARE AS FOLLOWS-                       * 11950002
*       1 - CONTAINS THE ADDRESS OF THE TCLOSE PARAMETER LIST.        * 11960002
*           EACH ENTRY IS A FULLWORD WHICH CONTAINS THE ADDRESS OF    * 11970002
*           A DCB IN THE 3 LOW ORDER BYTES AND THE TCLOSE POSITIONING * 11980002
*           OPTION IN THE HIGH ORDER BYTE. THE POSITIONING OPTIONS    * 11990002
*           ARE AS FOLLOWS-                                           * 11992002
*              X'00' - LEAVE;                                         * 12042002
*              X'10' - REREAD;                                        * 12092002
*              X'30' - LEAVE;                                         * 12142002
*           THE LAST ENTRY IN THE PARAMETER LIST HAS THE HIGH ORDER   * 12192002
*           BIT OF ITS FIRST BYTE TURNED ON (I.E., X'80').            * 12242002
*       3 - ADDRESS OF THE CVT - INITIALIZED BY THE SLIH.             * 12292002
*       4 - ADDRESS OF THE TCB - INITIALIZED BY THE SLIH.             * 12342002
*       5 - EITHER OF THE FOLLOWING-                                  * 12392002
*           1) ADDRESS OF THE TCLOSE SVRB, WHICH IS INITIALIZED BY    * 12394002
*              AND INDICATES ENTRY FROM THE SLIH, OR                  * 12396002
*           2) 0, WHICH INDICATES THAT THIS IS A RETURN FROM          * 12398002
*              INITIALIZATION OF THE OPTIONAL TRACE FACILITY.         * 12398402
*                                                                     * 12400021
* OUTPUT -                                                            * 12500021
*    1) REGISTER CONTENTS FOR A NORMAL EXIT ARE AS FOLLOWS -          * 12600021
*          'RES'   - ADDRESS OF THE RESIDENT ROUTINE;                 * 12700021
*          'RWTG'  - ADDRESS OF THE WTG TABLE;                        * 12800021
*       IF EXIT IS TO MODULE IFG0230P BECAUSE OF AN ERROR READING THE * 12900021
*       JFCB, THE FOLLOWING ADDITIONAL REGISTER CONTENTS APPLY -      * 13000021
*          'R0'    - TCLOSE INTERNAL ERROR CODE 121;                  * 13100021
*          'RDCB'  - ADDRESS OF THE DCB CURRENTLY BEING PROCESSED;    * 13200021
*          'RCORE' - ADDRESS OF THE CURRENT DCB'S WORK AREA;          * 13300021
*          'RWTGC' - ADDRESS OF THE CURRENT DCB'S WTG ENTRY;          * 13400021
*          'RTIOT' - ADDRESS OF THE CURRENT DCB'S CURRENT TIOT ENTRY; * 13500021
*          'RUCB'  - ADDRESS OF THE CURRENT DCB'S CURRENT UCB;        * 13600021
*          'RDEB'  - ADDRESS OF THE CURRENT DCB'S DEB.                * 13700021
*       AT EXIT TO IFG0239R (OPTIONAL TRACE FACILITY INITIALIZATION) -* 13750002
*          'R5' - 0, A RETURN INDICATOR.                              * 13760002
*    2) INTERNAL INDICATORS -                                         * 13800021
*          'WTGPATHS' - X'20' - NSL PROCESSING IS REQUIRED;           * 13900021
*                                                                     * 14100021
* EXTERNAL REFERENCES -                                               * 14200021
*         REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                   * 14300021
*                                                                     * 14400021
* EXITS, NORMAL -                                                     * 14500021
*    MODULE IFG0232D WITH 'RET' EQUAL 0 FOR DIRECT ACCESS PROCESSING; * 14600021
*    MODULE IFG0232G WITH 'RET' EQUAL 0 FOR SL TAPE OUTPUT PROCESSING;* 14700021
*    MODULE IFG0232M WITH 'RET' EQUAL 4 FOR SL TAPE INPUT PROCESSING; * 14800021
*    MODULE IFG0232S WITH 'RET' EQUAL 0 FOR NL TAPE POSITIONING;      * 14900021
*    MODULE IFG0232Y WITH 'RET' EQUAL 0 FOR NSL TAPE PROCESSING -     * 15000021
*       THIS MODULE IS AN ALIAS FOR IFG0202B, WHICH INTERFACES WITH   * 15100001
*       MODULES NSLETRLI (DEFERRED NSL PROCESSING) AND NSLCTRLO;      * 15200021
*    MODULE IFG0232Z WITH 'RET' EQUAL 4 FOR UNIT RECORD, GRAPHICS, OR * 15300021
*       COMMUNICATIONS DEVICE TYPES;                                  * 15400021
*    MODULE IFG0239R TO INITIALIZE FOR GTF, RETURNING TO THIS         * 15500021
*       MODULE AFTER INITIALIZATION HAS BEEN COMPLETED.               * 15600021
*                                                                     * 15700021
* EXITS, ERROR -                                                      * 15800021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 15900021
*                                                                     * 16000021
* TABLES/WORK AREAS -                                                 * 16100021
*    THE TCLOSE WORK AREA AND THE WHERE-TO-GO (WTG) TABLE ARE         * 16200021
*    DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.               * 16300021
*                                                                     * 16400021
* ATTRIBUTES -                                                        * 16500021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 16600021
*                                                                     * 16700021
* CHARACTER CODE DEPENDENCY -                                         * 16800021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 16900021
*                                                                     * 17000021
* NOTES -                                                             * 17100021
*                                                                     * 17200021
*********************************************************************** 17300021
*                                                                       17400021
         AIF   ('&LIB' NE 'LIB1').LIB22C2                               17450000
         SSM   ENABLE                   ENABLE FOR ALL INTERRUPTS       17500021
.LIB22C2 ANOP                                                           17550000
*                                                               SA53293 17560002
*****    DETERMINE WHETHER ENTRY IS FROM THE SECOND LEVEL       SA53293 17570002
*****    INTERRUPT HANDLER (SLIH) OR A RETURN FROM              SA53293 17580002
*****    INITIALIZATION OF THE OPTIONAL TRACE FACILITY.         SA53293 17590002
*                                                               SA53293 17592002
         LTR   R5,R5                    IS THIS A RETURN FROM   SA53293 17594002
*                                       ..TRACE INITIALIZATION  SA53293 17596002
         BZ    TCM14500                 ..BR IF YES TO CONTINUE SA53293 17900002
         LR    RPAR,R1                  SAVE ADDRESS OF PARAMETER LIST  18000021
         LR    RPARC,RPAR               LOAD ADDRESS OF FIRST ENTRY     18100021
         AIF   ('&LIB' EQ 'LIB1').LIB12C2                               18110000
*                                                                       18150000
*********************************************************************** 18160000
*                                                                       18170000
*  COUNT THE DCB'S IN OPEN PARAMETER LIST                               18180000
*                                                                       18190000
         LA    RC,K1                    INIT DCB COUNT 1 EXTRA   Y01018 18192000
TCM00100 EQU   *                                                 Y01018 18196000
         LA    RC,K1(RC)                INCR COUNT OF DCB'S BY 1 Y01018 18198000
         TM    PLISTOPT(RPARC),LASTNTRY  CHECK FOR LAST ENTRY    Y01018 18198400
         LA    RPARC,K4(,RPARC)         ADVANCE TO NEXT DCB      Y01018 18198800
         BZ    TCM00100                 BR IF NO TO CNT NEXT DCB Y01018 18199200
*                                                                       18199600
*********************************************************************** 18199700
*                                                                       18199800
*  GETMAIN THE WHERE-TO-GO TABLE                                        18199900
*                                                                       18233200
*                                       MULTIPLY COUNT OF DCB'S         18243200
         USING CVT,RET                  CVT ADDRESSABILITY      SA53260 18250021
         SLL   RC,K3                    BY 8 BYTES PER WTG ENTRY Y01018 18253200
         LA    RC,WTGENTRY-WTG(RC)      INCR FOR WTG TABLE BASE  Y01018 18263200
*                                                                       18265200
         GETMAIN R,LV=(RC)              GETMAIN FOR WTG TABLE    Y01018 18265600
*                                                                       18266000
         LA    RWTG,0(R1)               WTG ADDR TO RWTG REG     Y01018 18266400
         BCTR  RC,K0                    DECREMENT BY ONE BYTE    YM0897 18271900
         EX    RC,CLEARWTG              CLEAR WTG CORE           Y01018 18273900
         LA    RC,K1(,RC)               INCREMENT BY ONE BYTE    Y01018 18275900
         SRL   RC,K3                    WTG SIZE IN DOUBLE WORDS Y01018 18277600
         STC   RC,WTGLNG                SAVE IN WTG TABLE        Y01018 18283100
*                                                                       18288600
*********************************************************************** 18288700
.LIB12C2 ANOP                                                           18288800
         L     RET,CVTPTR               LOAD ADDRESS OF CVT             18288900
         L     RD,CVTTCBP               PT TO NEXT/CURRENT TCB ADDRS    18300021
         L     RD,K4(,RD)               PT TO CURRENT TCB               18400021
         AIF   ('&LIB' EQ 'LIB1').LIB12C4                               18450100
         TM    CVTDCB,CVT4MS1           MVT SYSTEM?              YM8269 18452100
         BNO   TCM00255                 NO, BR TO IGNORE ENQ     YM8269 18454100
         TM    TCBTSFLG,TCBTSTSK        TSO TASK?                Y01018 18460000
         BNO   TCM00255                 NO, BR TO IGNORE ENQ     Y01018 18470000
         MVC   WTG(TCM1667L),TCM1660K                            Y01018 18480000
         ENQ   (WTG+TCM1665K-TCM1660K,                           Y01018*18490000
               WTG+TCM1666K-TCM1660K),MF=(E,WTG)                 Y01018 18492000
         LTR   RF,RF                    WAS ENQ SUCCESSFUL?      Y01018 18494000
         BNZ   TCM00250                 NO, BR TO NOT SET BIT    Y01018 18496000
         OI    WTGPATHS+K1,WTGTSENQ     SET ENQ SUCCESSFUL BIT   Y01018 18498000
TCM00250 EQU   *                                                 Y01018 18498400
         XC    WTG(TCM1667L),WTG        CLEAR WTG CORE           Y01018 18498800
TCM00255 EQU   *                                                 Y01018 18499200
.LIB12C4 ANOP                                                           18499600
         LA    RF,TCM03000              LD ADDR FOR CHECKING NEXT DCB   18500021
*                                                                       18600021
*********************************************************************** 18700021
*              DETERMINE IF ENTRY IS TO BE PROCESSED                  * 18800021
*********************************************************************** 18900021
*                                                                       19000021
         SR    RCORE,RCORE              SET 'GO SWITCH' TO 0-    M0039  19100021
*                                       ..NO DCBS TO BE PROCESSED       19200021
         AIF   ('&LIB' EQ 'LIB1').LIB12CC                               19210000
         LR    RPARC,RPAR               SET UP PARM PTR          YM0898 19220000
.LIB12CC ANOP                                                           19230000
         AIF   ('&LIB' NE 'LIB1').LIB22C3                               19250000
         LA    RC,WTGEND-WTG            SET UP COUNTER FOR SIZE OF WTG  19300021
.LIB22C3 ANOP                                                           19350000
TCM00500 EQU   *                                                        19400021
         L     RDCB,PLISTDCB(,RPARC)    ESTABLISH ADDRESS OF USER'S DCB 19500021
         TM    DCBOFLGS,DCBOPEN+DCBOLOCK  IS THIS DCB TO BE PROCESSED-  19600021
         AIF   ('&LIB' NE 'LIB1').LIB22CA                               19650002
         BCR   12,RF                    ..BR IF NOT TO GET NEXT ENTRY   19700021
         TM    DCBMACRF,DCBMEXCP        IS THIS AN EXCP DCB-            19800021
         BCR   1,RF                     ..BR IF YES TO GET NEXT ENTRY   19900021
.LIB22CA ANOP                                                           19902002
         AIF   ('&LIB' EQ 'LIB1').LIB12C5                               19910000
         BO    TCM00600                 BR IF YES                X02989 19930002
* SET ERROR FLAGS FOR ACB'S                                      X02989 19930402
         TM    DCBMACR,DCBMEXCP         IS ACCESS METHOD EXCP    X02989 19932002
         BO    TCM03000                 BR IF YES                X02989 19934002
         TM    DCBDSORG+K1,ACBDORGA     IS CONTROL BLOCK AN ACB  X02989 19936002
         BNO   TCM03000                 BR IF NO                 X02989 19938002
         USING IFGACB,RDCB              SET BASE FOR ACB         X02989 19938402
         MVI   ACBERFLG,VSCACBCL        SET ACB ERROR FLAG       X02989 19939602
         B     TCM03000                 GET NEXT ENTRY           XM1037 19941302
         USING IHADCB,RDCB              REDEFINE BASE FOR DCB    X02989 19944502
TCM00600 EQU   *                                                 X02989 19944903
         TM    DCBMACRF,DCBMEXCP        IS ACCESS METHOD EXCP    X02989 19947902
         BO    TCM03000                 BR IF YES, NOT ACB       XM1037 19949602
         TM    DCBDSORG+K1,ACBDORGA     IS CONTROL BLOCK AN ACB  X02989 19951302
         BNO   TCM00700                 BR IF NO                 X02989 19953002
         CLI   ACBAMETH-IFGACB(RDCB),ACBVSAM  IS ACB FOR VSAM    X03004 19955003
         BNE   TCM03000                 BR IF NO                 X03004 19957003
         LA    RCORE,K1                 SET GO SWITCH            X02989 19958102
         OI    DCBOFLGS,DCBOBUSY        TURN ON BUSY BIT         X02989 19959802
         B     TCM03000                 BR TO GET NEXT ENTRY     X02989 19961502
TCM00700 EQU   *                                                 X02989 19963202
         L     RTIOT,TCBTIO             LOAD TIOT ADDRESS FROM TCB      19964902
         AH    RTIOT,DCBTIOT            CALC ADDR OF DCB'S TIOT ENTRY   19966602
         TM    TIOELINK-TIOENTRY(RTIOT),TIOSPOOL                        19968302
         BM    TCM03000                 YES BYPASS THIS PARAMETER       19970000
.LIB12C5 ANOP                                                           19980000
         TM    DCBMACRF,DCBMREAD        IS THIS A BSAM READ DCB-        20000021
         BO    TCM01000                 ..BR IF YES TO PROCESS ENTRY    20100021
         TM    DCBMACRF+K1,DCBMWRIT     IS THIS A BSAM WRITE DCB-       20200021
         BCR   12,RF                    ..BR IF NOT TO GET NEXT ENTRY   20300021
*                                                                       20400021
*****    VALIDITY-CHECK THE DEB POINTED TO BY THE DCB                   20500021
*                                                                       20600021
TCM01000 EQU   *                                                        20700021
         L     RDEB,DCBDEBAD            LOAD DEB ADDRESS FROM DCB       20800021
         CLC   DEBDCBAD+K1(K3),K1(RPARC)  DOES THE DEB PT TO THE DCB-   20900021
         BCR   7,RF                     ..BR IF NOT- INVALID DCB ENTRY  21000021
         TM    DEBDEBID,DEBIDENT        IS THE DEB ID CORRECT-  SA57204 21100001
         BCR   14,RF                    ..BR IF NOT             SA57204 21200001
*                                                                       22300001
         L     RUCB,DEBUCBAD            LOAD UCB ADDRESS FROM DEB       22400021
         LA    RUCB,K0(,RUCB)           CLEAR HIGH-ORDER BYTE           22500021
         LTR   RUCB,RUCB                TEST FOR DUMMY DATA SET OR TSO- 22600021
         BZ    TCM02500                 ..BRANCH IF EITHER ONE          22700021
         TM    UCBWGT,UCBIN             IS THIS A SYSIN DATA SET-       22800021
         BCR   1,RF                     ..BR IF YES TO GET NEXT ENTRY   22900021
         OI    DCBOFLGS,DCBOBUSY        TURN ON THE 'DCB BUSY' BIT      23000021
         LA    RCORE,K1                 SET 'GO SWITCH' TO 1- INDICATES 23100021
*                                       ..THAT A DCB IS TO BE PROCESSED 23200021
TCM02500 EQU   *                                                        23300021
         CLI   DCBDEVT,DCBDEVTM         IS THIS TSO-                    23400021
         BCR   7,RF                     ..BRANCH IF NOT                 23500021
         NI    DCBCIND1,X'FF'-DCBC1EOB  TURN OFF EOF BIT IN DCB ( THIS  23600021
*                                       ..IS THE ONLY TCLOSE            23700021
*                                       ..PROCESSING FOR TSO )          23800021
TCM03000 EQU   *                                                        23900021
         TM    PLISTDCB(RPARC),LASTNTRY IS THIS THE LAST TCLOSE ENTRY-  24000021
         AIF   ('&LIB' NE 'LIB1').LIB22C4                               24050000
         LA    RC,WTGEND-WTGENTRY(,RC)  INCREMENT REQUIRED SIZE OF WTG  24100021
.LIB22C4 ANOP                                                           24150000
         LA    RPARC,K4(,RPARC)         POINT TO THE NEXT TCLOSE ENTRY  24200021
         BNO   TCM00500                 ..BR IF NOT TO GET NEXT ENTRY   24300021
         AIF   ('&LIB' NE 'LIB1').LIB22C5                               24350000
*                                                                       24400021
*********************************************************************** 24500021
*              GET MAIN STORAGE FOR WTG TABLE                         * 24600021
*********************************************************************** 24700021
*                                                                       24800021
TCM03500 EQU   *                                                        24900021
         LTR   RCORE,RCORE              IS THERE A DCB TO BE PROCESSED- 25000021
         BZ    TCM15500                 ..BR IF NOT TO RETURN TO CALLER 25100021
         LR    R0,RC                    SET LENGTH DESIRED IN PARAMETER 25200021
         GETMAIN R,LV=(0)               GET MAIN STORAGE FOR WTG TABLE  25300021
         LR    RWTG,R1                  SAVE STARTING ADDRESS OF WTG TA 25400021
         BCTR  RC,0                     DECR WTG LENGTH BY 1, THEN      25500021
         EX    RC,CLEARWTG              ..ZERO THE ENTIRE WTG TABLE     25600021
         LA    RC,K1(,RC)               RESTORE THE WTG TABLE LENGTH    25700021
         MVC   WTGMODNM(K8),FIRSTNAM    MOVE BASIC NAME INTO WTG TBL    25800021
         MVC   WTGATTRB(K7),XCTLATTR    MOVE MOD ATTRIBUTES INTO WTG    25900021
         SRL   RC,K3                    CHANGE WTG TABLE SIZE TO DOUBLE 26000021
         STC   RC,WTGLNG                ..WORDS AND SAVE IN WTG TABLE   26100021
.LIB22C5 ANOP                                                           26150000
         AIF   ('&LIB' EQ 'LIB1').LIB12C6                               26152000
         LTR   RCORE,RCORE              ANY DCB'S TO PROCESS?    YM2069 26154000
         BZ    TCM15500                 NO, EXIT TO CALLER       YM2069 26156000
         MVC   WTGMODNM(K8),FIRSTNAM    MOVE BASIC NAME INTO WTG TBL    26160000
         MVC   WTGATTRB(K7),XCTLATTR    MOVE MOD ATTRIBUTES INTO WTG    26170000
.LIB12C6 ANOP                                                           26180000
*                                                                       26200021
*********************************************************************** 26300021
*              PREPARE TO PROCESS THE DCBS                            * 26400021
*********************************************************************** 26500021
*                                                                       26600021
         LR    RPARC,RPAR               POINT TO FIRST TCLOSE ENTRY     26700021
         LA    RWTGC,WTGENTRY           PT TO FIRST WTG ENTRY           26800021
         LA    RC,K4                    INITLZ SIZE OF ECB LIST         26900021
TCM04000 EQU   *                                                        27000021
         L     RDCB,PLISTDCB(,RPARC)    POINT TO DCB FOR THIS ENTRY     27100021
         TM    DCBOFLGS,DCBOLOCK+DCBOBUSY IS PROCESSING REQUIRED-       27200021
         BNO   TCM13000                 ..BR IF NOT TO GET NEXT ENTRY   27300021
         L     RDEB,DCBDEBAD            LOAD DEB ADDRESS FROM DCB       27400021
         L     RUCB,DEBUCBAD            LOAD UCB ADDRESS FROM DEB       27500021
         L     RET,CVTPTR               LOAD ADDRESS OF CVT             27600021
         L     RD,CVTTCBP               LOAD ADDR OF TCB DOUBLE WORDS   27700021
         L     RD,K4(,RD)               LOAD ADDRESS OF CURRENT TCB     27800021
         L     RTIOT,TCBTIO             LOAD ADDRESS OF TIOT            27900021
         AH    RTIOT,DCBTIOT            CALC CURRENT TIOT ENTRY ADDR    28000021
         DROP  RD                                                       28100021
*                                                                       28200021
*****          GET MAIN STORAGE FOR WORK AREA FOR THIS DCB              28300021
*                                                                       28400021
         LA    R0,CLOSSIZE              LOAD SIZE OF TCLOSE WK AREA     28500021
         TM    DEBOFLGS,DEBOFEOF+DEBOFNSL TEST FOR NSL AND EOF-         28600021
         BNO   TCM06000                 ..BR IF NOT- XCTL TO CLOSE NSL  28700021
         TM    DEBOPATB,DEBOPOUT        IS DCB OPENED FOR INPUT-        28800021
         BNZ   TCM06000                 ..BR IF NOT- XCTL TO CLOSE NSL  28900021
         L     RD,DCBEXLST              LD ADDR OF DCB EXIT LIST AND    29000021
         LA    RD,K0(,RD)               ..CLEAR HIGH-ORDER BYTE         29100021
         LTR   RD,RD                    IS THERE A DCB EXIT LIST ADDR-  29200021
         BZ    TCM06000                 ..BR IF NOT TO GET WK AREA      29300021
TCM04500 EQU   *                                                        29400021
         CLI   K0(RD),XLDEFNSL          WAS LABEL PROC DEFERRED-        29500021
         BE    TCM05500                 ..BR IF YES TO GET EXTRA CORE   29600021
         CLI   K0(RD),XLDEFNSL+LASTNTRY IS 'LAST ENTRY' BIT ALSO ON-    29700021
         BE    TCM05500                 ..BR IF YES TO GET EXTRA CORE   29800021
TCM05000 EQU   *                                                        29900021
         TM    K0(RD),LASTNTRY          IS THIS THE LAST LIST ENTRY-    30000021
         LA    RD,K4(,RD)               POINT TO NEXT LIST ENTRY        30100021
         BNO   TCM04500                 ..BR IF NOT TO CHK NEXT ENTRY   30200021
         B     TCM06000                 ..BR IF YES TO GET WK AREA      30300021
TCM05500 EQU   *                                                        30400021
         LA    R0,EOVSIZE               LOAD SIZE OF WORK AREA FOR      30500021
*                                       ..DEFERRED NSL INPUT PROCESSING 30600021
*                                       ..(SAME SIZE AS EOV WORK AREA)  30700021
TCM06000 EQU   *                                                        30800021
         GETMAIN R,LV=(0)               OBTAIN MAIN STORAGE FOR TCLOSE C30900021
                                        ..WORK AREA                     31000021
         LR    RCORE,R1                 SAVE ADDR OF OBTAINED CORE IN   31100021
         ST    R1,K4(,RWTGC)            ..WORK AREA BASE REGISTER AND   31200021
*                                       ..IN CURRENT WTG ENTRY          31300021
*                                                                       31400021
*********************************************************************** 31500021
*              INITIALIZE THE 'TCLOSE' WORK AREA                      * 31600021
*********************************************************************** 31700021
*                                                                       31800021
*****          INITIALIZE CONTROL BLOCKS IN WORK AREA                   31900021
*                                                                       32000021
TCM06500 EQU   *                                                        32100021
         XC    FORCORE(JFCBSQTY-FORCORE),FORCORE  CLEAR WA CORE  M0039  32200021
         XC    JFCBSQTY(DXCWAEND-JFCBSQTY),JFCBSQTY  CLEAR CORE  M0039  32300021
         AIF   ('&LIB' EQ 'LIB1').LIB12CF                               32350002
         TM    DCBMACRF,DCBMEXCP        IS ACCESS METHOD EXCP    X02989 32360002
         BO    TCM06600                 BR IF YES, NOT ACB       X02989 32370002
         TM    DCBDSORG+K1,ACBDORGA     IS CONTROL BLOCK AN ACB  X02989 32380002
         BNO   TCM06600                 BR IF NO                 X02989 32390002
         CLI   ACBAMETH-IFGACB(RDCB),ACBVSAM  IS ACB FOR VSAM    X03004 32392003
         BE    TCM07600                 BR IF YES, READ JFCB     X03004 32394003
TCM06600 EQU   *                                                 X02989 32396002
.LIB12CF ANOP                                                           32398002
         LA    RD,DXDCB                 PLACE ADDRESS OF WORK AREA DCB  32400021
         ST    RD,DXDEBDCB              ..INTO WORK AREA DEB            32500021
         ST    RD,IOBDCBPT-K1           ..AND INTO WORK AREA IOB        32600021
         MVI   DXDEBID,DEBIDENT         MOVE DEB ID INTO WORK AREA DEB  32700021
         MVC   DXDEBUCB,DEBUCBAD        MOVE DEVICE MODIFIER AND UCB    32800021
*                                       ..ADDRESS INTO WORK AREA DEB    32900021
         LA    RD,DXDEB                 PLACE ADDRESS OF WORK AREA DEB  33000021
         ST    RD,DXDCBDEB              ..INTO WORK AREA DCB            33100021
         LA    RD,DXECB                 PLACE ADDRESS OF WORK AREA ECB  33200021
         ST    RD,IOBECBPT              ..INTO WORK AREA IOB            33300021
         LA    RD,DXCCW1                PLACE ADDRESS OF WORK AREA CCW  33400021
         ST    RD,IOBSTART-K1           ..INTO WORK AREA IOB            33500021
         OI    IOBFLAG1,IOBUNREL        SET UNRELATED BIT IN IOB        33600021
         MVC   DXDEBAPP,CVTXAPG         MOVE IOS' APPENDAGE VECTOR TBL  33700021
*                                       ..ADDRESS INTO WORK AREA DEB    33800021
         AIF   ('&LIB' EQ 'LIB1').LIB12C7                               33850000
         DEBCHK (RDCB)                  VERIFY THE DEB ADDRESS   Y01021 33860000
         LR    RDEB,R1                  LOAD VERIFIED DEB ADDR   Y01021 33870000
         ST    RDEB,DXPDEBAD            SAVE VERIFIED DEB ADDR   Y01021 33880000
.LIB12C7 ANOP                                                           33890000
*                                                                       33900021
*****          PURGE I/O TO HALT ANY OUTSTANDING I/O FOR THIS DCB       34000021
*                                                                       34100021
TCM07000 EQU   *                                                        34200021
         ST    RDEB,DXCCW5              INITLZ PURGE PARAMETER LIST     34300021
         MVI   DXCCW5,PURGEFLG          INITLZ FLAGS- DO NOT POST COMP  34400021
         LA    R0,DEBUSRPG              LOAD ADDRESS OF IOB PURGE CHAIN 34500021
         ST    R0,DXCCW6                ..AND STORE IN PARAMETER LIST   34600021
         LA    R1,DXCCW5                POINT TO PURGE PARAMETER LIST   34700021
         PURGE (1)                      SVC PURGE                       34800021
         WAIT  ,ECB=DXCCW5+K4           WAIT FOR PURGE COMPLETION       34900021
         TM    DCBCIND2,DCBC2CHN        IS THIS A CHAINED SCHED DCB-    35000021
         BZ    TCM07500                 ..BRANCH IF NOT                 35100021
         L     R1,DCBIOBAD              LOAD ADDR OF IOB PREFIX         35200021
         L     R1,IOBECBPT-DXIOB+K16(R1)   GET ECB ADDR                 35300021
         MVI   DXECB-DXECB(R1),ECBCOD7F SET ECB COMPLETE                35400021
TCM07500 EQU   *                                                        35500021
         LA    RF,MOD232Z               POINT TO ID/TTR OF FINAL MOD    35600021
         LA    RET,K4                   BR TABLE OFFSET FOR THAT MOD    35700021
         TM    UCBTBYT3,UCB3TAPE+UCB3DACC IS THIS A TAPE OR DA DEVICE-  35800021
         BZ    TCM12500                 ..BR IF NOT- PROCESSING DONE    35900021
*                                                                       36000021
         AIF   ('&LIB' NE 'LIB1').LIB22C6                               36050000
*****          READ IN JFCB                                             36100021
*****                                                                   36200021
*****          THE CHANNEL PROGRAM IS INITLIALIZED AS FOLLOWS-          36300021
*****          CCW1- SEARCH EQ ID, CCHHR OF JFCB, CMD CHAIN, LNG EQ 5   36400021
*****          CCW2- TIC, ADDR OF CCW1, COMMAND CHAIN                   36500021
****           CCW3- READ DATA, ADDR OF JFCB, LENGTH EQUAL 176          36600021
*                                                                       36700021
         L     R0,TIOEJFCB-TIOENTRY(,RTIOT)   LOAD TTR OF THIS JFCB     36800021
         L     RET,CVTPTR               LOAD THE ADDRESS OF THE CVT     36900021
         L     RD,CVTJOB                LOAD THE JOB QUEUE DCB ADDR     37000021
         L     R1,DCBDEBAD-IHADCB(K0,RD)  LOAD THE JOB QUEUE DEB ADDR   37100021
         MVC   DXDEBUCB(K16),DEBUCBAD-IHADEB(R1)  MOVE EXTENT INFO FROM 37200021
*                                       ..JOB QUEUE DEB TO WORK AREA    37300021
         LA    RDCB,DXDAADDR            PLACE ADDRESS FOR CONVERTED     37400021
*                                       ..'MBBCCHHR' INTO PARAMETER REG 37500021
TCM08000 EQU   *                                                        37600021
         STM   RWTGC,RC,DXCCW5          SAVE REGISTERS                  37700021
         L     RF,CVTPCNVT              LOAD ADDRESS OF CONVERT RTN     37800021
         DROP  RET                                                      37900021
         BALR  RET,RF                   BRANCH TO CONVERT ROUTINE       38000021
         LM    RWTGC,RC,DXCCW5          RESTORE REGISTERS               38100021
         L     RDCB,DEBDCBAD            RESTORE THE DCB ADDRESS         38200021
         LA    RD,DXDAADDR+K3           PLACE ADDRESS OF CCHHR INTO     38300021
         ST    RD,DXCCW1                ..FIRST CCW                     38400021
         LA    RD,DXCCW1                PLACE ADDRESS OF SEARCH CCW     38500021
         ST    RD,DXCCW2                ..INTO TIC CCW                  38600021
         MVI   DXCCW1,CCWSCHID          SET CCW TO 'SEARCH ID EQUAL'    38700021
         MVC   DXCCW1+K4(K5),ACCW1C     SET COMMAND CHAIN BIT, LENGTH   38800021
*                                       ..EQUAL 5, AND MOVE 'TIC'       38900021
*                                       ..INTO SECOND CCW               39000021
         LA    RD,DXJBF                 PLACE ADDR OF BUFFER FOR S21940 39050002
         ST    RD,DXCCW3                ..JFCB INTO THIRD CCW    S21940 39100002
         MVC   DXCCW2+K4(K5),ACCW2C     SET CMD CHAIN IND IN     S21940 39300002
*                                       ..SECOND CCW, MAKE THIRD S21940 39400002
*                                       ..CCW A 'READ DATA' CMD  S21940 39450002
         MVC   DXCCW3+K4(K4),ACCW3C     MOVE JFCB LNG INTO CCW   S21940 39500002
         LA    RET,TABD121              INTERNAL CODE IF JFCB READ ERR  40000021
         EXCP  DXIOB                    INITIATE I/O OPERATION          40100021
         WAIT  ,ECB=DXECB               WAIT FOR I/O TO COMPLETE        40200021
         TM    DXECB,ECBNOERR           TEST FOR SUCCESSFUL COMPLETION- 40300021
         BNO   TCM16000                 ..BR IF ERROR TO ERROR RTN      40400021
.LIB22C6 ANOP                                                           40402000
         AIF   ('&LIB' EQ 'LIB1').LIB12C8                               40404000
*****          CREATE PARAMETER LIST TO READ IN JFCB                    40406000
*                                                                       40408000
TCM07600 EQU   *                                                 X02989 40408402
         L     RF,CVTPTR                ADDRESS OF CVT                  40410000
         L     RF,CVTTCBP-CVT(RF)       LOAD  ADDRESS OF TCB POINTERS   40412000
         L     RF,K4(,RF)               GET CURRENT TCB ADDRESS         40414000
         LR    RET,RCORE                ESTABLISH BASE FOR QMIOLIST     40416000
         DROP  RET                                                      40418000
         USING QMIOP,RET                                                40420000
         ST    RF,QMITCBAD              STORE TCB ADDRESS IN QMIOLIST   40422000
         LA    RF,DXJBF                 MOVE POINTER TO JFCB READ IN    40424000
         ST    RF,QMIRECAD              AREA TO QMIOLIST                40426000
         LA    R0,QMWRKSZ               LENGTH OF JES WORK AREA         40428000
         GETMAIN R,LV=(0)               GET CORE FOR JES WORK AREA      40430000
*                                                                       40432000
         ST    R1,QMIWRKAD              STORE ADDRESS OF JES WORK AREA  40434000
         L     R0,TIOEJFCB-TIOENTRY(RTIOT)   JFCB TTR                   40436000
         ST    R0,QMIDSKAD              QMIOLIST                        40438000
         MVI   QMIRECL+K1,JFCBLGTH      SET UP JFCB LENGTH              40440000
         MVI   QMIFLAGS,QMIOREAD        INDICATE READ OPERATION         40442000
         LA    RD,QMREGSAV(R1)          POINT TO REGISTER SAVE AREA     40444000
         LR    R1,RET                   POINT TO PARAMETER LIST         40446000
*                                                                       40448000
*****          ISSUE READ/WRITE JFCB MACRO                              40450000
*                                                                       40452000
         QMNGRIO                                                        40454000
*                                                                       40456000
         LR    RET,R1                   RESTORE PARM LIST BASE          40458000
         L     R1,QMIWRKAD              LOAD JES WORK AREA ADDRESS      40460000
         L     RD,QMITCBAD              RES0TORE TCB BASE ADDRESS       40462000
         LA    RET,TABD121              INTERNAL CODE IF JFCB READ ERR  40464000
         LTR   RF,RF                    TEST FOR SUCCESSFUL READ        40466000
         BP    TCM16000                 BRANCH IF READ ERROR            40468000
         LA    R0,QMWRKSZ               LOAD LENGTH OF JES WORK AREA    40470000
         DROP  RET                                                      40472000
         FREEMAIN R,LV=(0),A=(1)        FREE JES WORK AREA              40474000
*                                                                       40476000
.LIB12C8 ANOP                                                           40478000
         TM    JFCBMASK+K6,JFCTRACE     IS THE TRACE FACILITY SPEC'D-   40500021
         BNO   TCM09500                 ..BRANCH IF NOT                 40600021
         LA    RC,K8(,RC)               INCR ECB LIST SIZE FOR TRACING  40700021
         OI    WTGPATHS+K1,WTGTRACE     IND THAT TRACE FACILITY REQ'D   40800021
TCM09500 EQU   *                                                        40900021
         AIF   ('&LIB' EQ 'LIB1').LIB12CG                               40950002
         LA    RF,MOD231T               PT TO IDTTR OF VSAM MOD  X02989 40952002
         TM    DCBMACRF,DCBMEXCP        IS ACCESS METHOD EXCP    XM2896 40962002
         BO    TCM09700                 YES, CANNOT BE ACB       XM2896 40972002
         TM    DCBDSORG+K1,ACBDORGA     IS CONTROL BLOCK AN ACB  XM2896 40974002
         BNO   TCM09700                 BRANCH IF NO             XM2896 40976002
         CLI   ACBAMETH-IFGACB(RDCB),ACBVSAM IS ACB FOR VSAM     XM2896 40978002
         BE    TCM12500                 BRANCH IF YES            XM2896 40978402
TCM09700 EQU   *                                                 XM2896 40978802
.LIB12CG ANOP                                                           40980002
         LA    RF,MOD232D               PT TO ID/TTR OF DA MODULE       41000021
         SR    RET,RET                  BR TABLE OFFSET FOR THAT MOD    41100021
         MVC   DXDEBUCB,DEBUCBAD        RESTORE USER'S UCB ADDR IN WORK 41200021
         TM    UCBTBYT3,UCB3DACC        IS THIS A DIRECT ACCESS DEVICE  41300021
         BO    TCM12500                 ..BR IF YES TO PROCESS DA       41400021
*                                                                       41500021
*********************************************************************** 41600021
*              TAPE PROCESSING                                        * 41700021
*********************************************************************** 41800021
*                                                                       41900021
TCM10000 EQU   *                                                        42000021
         MVI   DXDEBMOD,DCBTRTET        SET MOD TO EVEN PARITY WITH     42100021
*                                       ..TRANSLATION                   42200021
         OC    DXDEBMOD,JFCDEN          SET DENSITY TO TO THAT WHICH    42300021
*                                       ..WAS USED TO CREATE TAPE       42400021
         SR    RET,RET                  BR TABLE OFFSET FOR NSL/SL OUT  42500021
         TM    DEBOFLGS,DEBOFNSL        IS IT NON-STANDARD LABELED TAPE 42600021
         BO    TCM11000                 ..BR IF YES- DON'T SET EOF      42700021
         TM    DCBOFLGS,DCBOWRIT        HAS A WRITE OCCURRED-           42800021
         BNO   TCM10500                 ..BR IF NOT                     42900021
         OI    DEBOFLGS,DEBOFEOF        SET EOF BIT IN USER'S DEBOFLGS  43000021
TCM10500 EQU   *                                                        43100021
         TM    JFCBLTYP,JFCBAL+JFCSL    ARE THERE STD OR ANSI LABELS-   43200021
         BNZ   TCM11500                 ..BR IF EITHER TYPE             43300021
         LA    RF,MOD232S               PT TO ID/TTR OF POSITIONING MOD 43400021
         B     TCM12500                 BR TO FINISH THIS DCB           43500021
TCM11000 EQU   *                                                        43600021
         OI    WTGPATHS,WTGTCLOS        INDICATE THAT 'TCLOSE' IS       43700021
*                                       ..PERFORMING NSL PROCESSING     43800021
         LA    RF,MOD232Y               PT TO ID/TTR OF THE 'TCLOSE'    43900021
*                                       ..ALIAS FOR THE 'CLOSE' MODULE  44000021
*                                       ..WHICH PROCESSES NSL TAPE      44100021
         B     TCM12500                 BR TO FINISH THIS DCB           44200021
TCM11500 EQU   *                                                        44300021
         TM    DCBOFLGS,DCBOWRIT        WAS OUTPUT PERFORMED-           44400021
         BO    TCM12000                 ..BR IF YES                     44500021
         TM    JFCBLTYP,JFCBUL          ARE THERE USER LABELS   SA66572 44550000
         BNO   TCM11750                 BR IF NOT               SA66572 44560000
         LA    RF,MOD232M               PT TO ID/TTR OF SL INPUT MOD    44600021
         LA    RET,K4                   BR TABLE OFFSET FOR THAT MOD    44700021
         B     TCM12500                 BR TO FINISH THIS DCB           44800021
TCM11750 EQU   *                                                        44850000
         LA    RF,MOD232S               PT TO ID/TTR OF POS MOD SA66572 44860000
         SR    RET,RET                  BR TABLE OFFSET         SA66572 44870000
         B     TCM12500                 BR TO FINISH THIS DCB   SA66572 44880000
TCM12000 EQU   *                                                        44900021
         LA    RF,MOD232G               PT TO ID/TTR OF LABEL MODULE    45000021
*                                                                       45100021
*****    INITIALIZE WORK AREAS FOR RESIDENT ROUTINE                     45200021
*                                                                       45300021
TCM12500 EQU   *                                                        45400021
         MVC   K0(K5,RWTGC),K0(RF)      MOVE ID/TTR OF NEXT MODULE      45500021
*                                       ..INTO WTG TABLE ENTRY          45600021
         STM   RTIOT,R0,DXREGSAV        STORE REGS 9-14,0,1 IN WK AREA  45700021
         LA    RC,K4(,RC)               INCREMENT ECB LIST SIZE         45800021
TCM13000 EQU   *                                                        45900021
         TM    PLISTDCB(RPARC),LASTNTRY IS THIS THE LAST TCLOSE ENTRY-  46000021
         LA    RPARC,K4(,RPARC)         POINT TO NEXT TCLOSE ENTRY      46100021
         LA    RWTGC,WTGEND-WTGENTRY(,RWTGC) PT TO NEXT WTG TABLE ENTRY 46200021
         BNO   TCM04000                 BR TO GET NEXT ENTRY            46300021
*                                                                       46400021
*********************************************************************** 46500021
*              OBTAIN RESIDENT ROUTINE WORK AREA (ECBLIST) MAIN STG   * 46600021
*********************************************************************** 46700021
*                                                                       46800021
TCM13500 EQU   *                                                        46900021
         LR    R0,RC                    LD PARM REG WITH ECBLIST SIZE   47000021
         GETMAIN R,LV=(0)               PERFORM GETMAIN FOR ECBLIST     47100021
         TM    WTGPATHS+K1,WTGTRACE     IS THE TRACE FACILITY REQ'D-    47200021
         BNO   TCM14000                 ..BRANCH IF NOT                 47300021
         LA    R1,K8(,R1)               POINT R1 PAST THE ECB PREFIX    47400021
*                                       ..(WHICH IS FOR THE TRACE RTN)  47500021
TCM14000 EQU   *                                                        47600021
         ST    R1,WTGECBAD              SAVE ECBLIST ADDR IN WTG TABLE  47700021
         ST    RPAR,K0(,R1)             SAVE TCLOSE PARM LIST ADDR IN   47800021
*                                       ..ECBLIST PREFIX SECTION        47900021
*                                                                       48900021
*****          DETERMINE WHETHER OR NOT TRACE INITIALIZATION IS REQ'D   49000021
*                                                                       49100021
         TM    WTGPATHS+K1,WTGTRACE     IS THE TRACE FACILITY REQUESTED 49200021
         BNO   TCM15000                 ..BR IF NOT TO EXIT NORMALLY    49300021
         EJECT                                                          49400021
*********************************************************************** 49500021
*              EXITS                                                  * 49600021
*********************************************************************** 49700021
*                                                                       49800021
*****          EXIT TO THE TRACE INITIALIZATION ROUTINE                 49900021
*                                                                       50000021
         MVC   DXCCW3+K4(K8),WTGENTRY   SAVE CONTENTS OF FIRST WTG ENT  50100021
         MVC   WTGENTRY(K5),MOD232A     MOVE ALIAS OF THIS MOD INTO WTG 50200021
         LA    RF,MOD239R               PT TO ID/TTR OF TRACE INITIAL-  50500021
*                                       ..IZATION ROUTINE               50600021
         SR    R5,R5                    ZERO REG TO INDICATE    SA53293 50650002
*                                       ..RETURN FROM TRACE     SA53293 50660002
*                                       ..INITIALIZATION        SA53293 50670002
         B     TCM16500                 BR TO XCTL TO TRACE RTN         50700021
*                                                                       50800021
*****          RETURN FROM THE TRACE INITIALIZATION FUNCTION            50900021
*                                                                       51000021
TCM14500 EQU   *                                                        51100021
         MVC   WTGENTRY(K8),DXCCW3+4    RESTORE FIRST WTG ENTRY         51200021
         SPACE 2                                                        51300021
*                                                               SA53293 51350002
*****          OBTAIN THE ADDRESS OF THE OPEN/CLOSE/EOV         SA53293 51400002
*****          RESIDENT ROUTINE                                 SA53293 51450002
*                                                               SA53293 51500002
TCM15000 EQU   *                                                SA53293 51700002
         L     RES,CVTPTR               LOAD ADDRESS OF CVT     SA53293 51750002
         USING CVT,RES                  CVT ADDRESSABILITY      SA53293 51760002
         L     RES,CVTDMSR              LD ADDR OF RESIDENT RTN SA53293 51770002
         DROP RES                                               SA53293 51780002
         ST    RES,K4(RWTGC)            SAVE RES RTN ADDRESS IN SA53293 51790002
*                                       ..LAST WTG TABLE ENTRY  SA53293 51792002
*                                                               SA53293 51794002
*****          EXIT TO RESIDENT ROUTINE TO BEGIN SERIAL PROCESSING      51796002
*                                                               SA53293 51798002
         IECRES XCTL                    BR TO RES RTN TO XCTL    S21940 51800002
         SPACE 2                                                        51900021
*                                                                       52000021
*****          RETURN TO CALLER- THERE ARE NO VALID DCBS TO PROCESS     52100021
*                                                                       52200021
TCM15500 EQU   *                                                        52300021
         AIF   ('&LIB' EQ 'LIB1').LIB12C9                               52360000
         USING CVT,RET                  DEFINE CVT BASE          Y01018 52360400
         L     RET,CVTPTR               LOAD ADDRESS OF CVT      Y01018 52362000
         TM    CVTDCB,CVT4MS1           MVT SYSTEM?              Y01018 52370000
         BNO   TCM15600                 NO, BR TO IGNORE DEQ     Y01018 52380000
         USING TCB,RD                   DEFINE TCB BASE          Y01018 52390000
         L     RD,CVTTCBP               PT TO NEXT TCB ADDRS     Y01018 52392000
         L     RD,K4(,RD)               PT TO CURRENT TCB        Y01018 52394000
         TM    TCBTSFLG,TCBTSTSK        TSO TASK?                Y01018 52398000
         BNO   TCM15600                 NO, BR TO IGNORE DEQ     Y01018 52398400
         TM    WTGPATHS+K1,WTGTSENQ     WAS ENQ SUCCESSFUL?      Y01018 52398500
         BZ    TCM15600                 NO, BR TO IGNORE DEQ     Y01018 52398600
         MVC   WTG(TCM1667L),TCM1660K                            Y01018 52398800
         DEQ   (WTG+TCM1665K-TCM1660K,                           Y01018*52399200
               WTG+TCM1666K-TCM1660K),MF=(E,WTG)                 Y01018 52399600
TCM15600 EQU   *                                                 Y01018 52453200
         DROP  RET                                               Y01018 52455200
         DROP  RD                                                Y01018 52457200
         SR    R0,R0                    CLEAR REG                YM2069 52459200
         IC    R0,WTGLNG                GET LENGTH OF WTG TABLE  YM2069 52461200
         SLL   R0,K3                    CONVERT TO BYTES         YM2069 52461600
         FREEMAIN R,LV=(0),A=(RWTG)     FREE WTG CORE            YM2069 52462000
         LA    RF,K4                    SET RETURN CODE          X02989 52462402
.LIB12C9 ANOP                                                           52463200
         SVC   SVCEXIT                  RETURN TO CALLER                52466700
         EJECT                                                          52500021
*********************************************************************** 52600021
*              ERROR PROCESSING                                       * 52700021
*********************************************************************** 52800021
*                                                                       52900021
TCM16000 EQU   *                                                        53000021
         AIF   ('&LIB' EQ 'LIB1').LIB12CH                               53050002
* IF ERROR OCCURRED FOR A VSAM DATA SET, GO TO VSAM PROBLEM      X02989 53052002
* DETERMINATION ROUTINE                                          X02989 53054002
         TM    DCBMACRF,DCBMEXCP        IS ACCESS METHOD EXCP    X02989 53060002
         BO    TCM16250                 BR IF YES                X02989 53070002
         USING IFGACB,RDCB              SET BASE FOR ACB         X02989 53072002
         CLI   ACBAMETH,ACBVSAM         IS ACB FOR VSAM          X03004 53082003
         BNE   TCM16250                 BR IF NO                 X03004 53090003
         MVI   ACBERFLG,VSCJFBER        SET ERROR CODE IN ACB    X02989 53092002
         LA    RET,DXIOB                LD ADDR OF WORK AREA     XM1037 53094002
         USING IDAPDPRM,RET             SET BASE FOR PARM LIST   XM1037 53096002
         XC    IDAPDPRM(PDPLNGTH),IDAPDPRM ZERO PARAMETER LIST   X02989 53098002
         MVI   PDPCALL,PDPTCLOS         INDICATE CALLER          X02989 53098402
         MVI   PDPCODE,VSJFBERR         SET INTERNAL ERROR CODE  X02989 53098802
         MVI   PDPFUNC,VSTCLOSE         SET FUNCTION CODE        X02989 53099202
         ST    RDCB,PDPACB              LD ADDR OF ACB           X02989 53099602
         ST    RTIOT,PDPTIOT            LD ADDR OF TIOT ENTRY    X02989 53099702
         L     RD,CVTADDR               GET CVT ADDR             X02989 53099802
         L     RD,CVTSVDCB-CVT(,RD)       GET SVCLIB DCB ADDR    XM1037 53099902
         MVC   DXXCTL,VSPDMOD           MOVE IN ROUTINE NAME     XM1037 53111002
         LOAD  EPLOC=DXXCTL,DCB=(RD)    GET ADDR OF ROUTINE      XM1037 53122102
         LR    RF,R0                    LOAD ADDR OF PD ROUTINE  X02989 53133202
         LR    R1,RCORE                 LD ADDR OF WORK AREA     X02989 53135202
         BALR  RET,RF                   BR TO VSAM PD ROUTINE    X02989 53143202
         DELETE EPLOC=DXXCTL            DELETE VSAM PD ROUTINE   XM1037 53153202
         XC    DXXCTL,DXXCTL            ZERO NAME                XM1037 53155202
         MVI   JFCDSRG2,JFCORGAM        SET VSAM INDICATOR       X02989 53163202
         NI    ACBOFLGS,X'FF'-DCBOBUSY  TURN OFF BUSY BIT        X02989 53165202
         LA    RF,MOD232Z               IDTTR OF FINAL LOAD      X02989 53165602
         LA    RET,K4                   LD BRANCH TABLE OFFSET   XM1037 53165702
         ICM   RET,8,MOD232Z+K5         LD LENGTH OF MODULE      XM1037 53165802
         B     TCM12500                 BR TO LD IDTTR           X02989 53166002
TCM16250 EQU   *                                                 X02989 53166402
         USING IHADCB,RDCB              REDEFINE BASE TO DCB     X02989 53166502
         DROP  RET                                               XM1037 53166602
.LIB12CH ANOP                                                           53177702
         LR    R0,RET                   MOVE ERROR CODE INTO REG 0      53188902
         MVC   DXCALLID(K2),MOD232A     IND RTN CALLED BY THIS MOD      53200021
         XC    DXRETID,DXRETID          ZERO THE RETURN ID              53300021
         LA    RF,ABEND23               PT TO ID/TTR OF ERROR MOD       53400021
TCM16500 EQU   *                                                        53500021
         MVC   WTGMODID(K2),K0(RF)      MOVE MOD ID INTO WTG TABLE      53600021
         MVC   WTGTTR(K3),K2(RF)        MOVE MODULE TTR INTO WTG TABLE  53700021
         AIF   ('&LIB' EQ 'LIB1').LIB12CZ                               53750000
         SR    RC,RC                    ZERO WORK REG            YM0992 53760000
         IC    RC,K5(RF)                GET MODULE LENGTH        YM0992 53770000
         SLL   RC,K11                   SHIFT LEFT 11 BITS       YM0992 53780000
         ST    RC,WTGMODSZ              PUT LENGTH AND           YM0992 53790000
         MVC   WTGTXTLN,WTGMODSZ+K1     SIZE IN WTG TABLE        YM0992 53792000
.LIB12CZ ANOP                                                           53794000
         LA    RC,WTGMODNM              POINT TO XCTL NAME              53800021
         XCTL  DE=(RC),SF=(E,DXXCTL)    ISSUE XCTL                      53900021
         SPACE 2                                                        54000021
*                                                                       54100021
*****          THE FOLLOWING INSTRUCTION IS USED TO CLEAR THE WTG TABLE 54200021
*                                                                       54300021
CLEARWTG XC    WTGAREA(K0),WTGAREA      ZERO BASIC WTG TABLE AREA       54400021
         SPACE 2                                                        54500021
*********************************************************************** 54600021
*              CONSTANTS                                              * 54700021
*********************************************************************** 54800021
*                                                                       54900021
         AIF   ('&LIB' NE 'LIB1').LIB22C7                               54950000
ACCW1C   DC    X'6000000508'            COMM CHAIN,SILI,5 CHAR,TIC OP C 55000021
ACCW2C   DC    X'4000000006'            COMMAND CHAIN IND, 'READ S21940 55100002
*                                       ..DATA' COMMAND CODE     S21940 55150002
ACCW3C   DC    X'000000B0'              LENGTH OF 176 BYTES FOR  S21940 55200002
*                                       ..READING A JFCB         S21940 55210002
.LIB22C7 ANOP                                                           55250000
         AIF   ('&LIB' EQ 'LIB1').LIB12CA                               55260000
TCM1660K ENQ   (,,S,4,STEP),RET=HAVE,MF=L                        Y01018 55270000
TCM1665K DC    CL8'SYSTIOT'             QNAME FOR ENQ/DEQ        Y01018 55280000
TCM1666K DC    C'TIOT'                  RNQME FOR ENQ/DEQ        Y01018 55290000
TCM1667L EQU   *-TCM1660K                                        Y01018 55292000
.LIB12CA ANOP                                                           55294000
ENABLE   DC    X'FF'                    ENABLE FOR ALL INTERRUPTS BITS  55300021
FIRSTNAM DC    C'IFG0230P'              NAME OF PROB DETERMINATION RTN  55400021
XCTLATTR DC    X'C3780004000400'        MODULE ATTRIBUTES FOR XCTLS     55500021
         EJECT                                                          55600021
*********************************************************************** 55700021
*              XCTL TABLE                                             * 55800021
*********************************************************************** 55900021
*                                                                       56000021
         AIF   ('&LIB' NE 'LIB1').LIB22C8                               56050000
XCTLTB23 XCTLTABL ID=(ABEND23,0P,MOD232A,2A,MOD232D,2D,MOD232G,2G,     C56100021
               MOD232M,2M,MOD232S,2S,MOD232Y,2Y,MOD232Z,2Z,MOD239R,9R),C56200002
               SVC=023                                          SA53293 56300002
         SPACE 2                                                        56474502
         IECDSECS CVT,                                                 C56500021
               RB,                                                     C56600021
               TCB,                                                    C56700021
               TIOT,                                                   C56800021
               DCB,                                                    C56900021
               DEB,                                                    C57000021
               UCB,                                                    C57100021
               MAIN,                                                   C57200021
               WTG,                                                    C57300021
               EXPAND=YES                                               57400021
.LIB22C8 ANOP                                                           57400402
         AIF   ('&LIB' EQ 'LIB1').LIB12CB                               57404002
VSPDMOD  DC    C'IDA0192P'              VSAM PROB DET ROUTINE    XM1037 57404402
*                                       NAME                     XM1037 57404802
XCTLTB23 XCTLTABL ID=(ABEND23,0P,MOD232A,2A,MOD232D,2D,MOD232G,2G,     C57406002
               MOD232M,2M,MOD232S,2S,MOD232Y,2Y,MOD232Z,2Z,MOD239R,9R, C57408002
               MOD231T,1T),SVC=023,LENGTH=2048,PATCH=100         X02989 57408402
         SPACE 2                                                        57408802
         IECDSECS CVT,                                                 C57409202
               RB,                                                     C57409602
               TCB,                                                    C57409702
               TIOT,                                                   C57409802
               DCB,                                                    C57409902
               DEB,                                                    C57413202
               UCB,                                                    C57415202
               MAIN,                                                   C57415602
               WTG,                                                    C57416002
               IDAPDPRM,                                               C57416402
               EXPAND=YES                                        XM0630 57416502
.LIB12CB ANOP                                                           57416602
         AIF   ('&LIB' EQ 'LIB1').LIB12CX                               57416702
*                                                                       57420000
TIOSPOOL EQU   X'06'                                                  $ 57430000
         IEFQMIOP                                                       57440000
         IEFJESCT                                                       57450000
.LIB12CX ANOP                                                           57460000
         AIF   ('&LIB' NE 'LIB1').LIB22C9                               57470000
         IECEQU ,                       INVOKE OPEN/CLOSE/EOV EQUATES   57500021
.LIB22C9 ANOP                                                           57510000
         AIF   ('&LIB' EQ 'LIB1').LIB12CD                               57520000
QMWRKSZ  EQU   328                      QMNGRIO WORK AREA SIZE          57530000
QMREGSAV EQU   256                      OFFSET TO QM REG SAVE AREA      57540000
         IECEQU AOS=YES                                                 57550000
         IFGACB                                                         57552000
.LIB12CD ANOP                                                           57560000
         SPACE 2                                                        57600021
         END                                                            57700021
