         TITLE 'IGC0002H - CATALOG OPEN/EXTEND MODULE'                  00050000
*                                                                       00100000
*********************************************************************** 00150000
*                                                                       00200000
* /* START OF SPECIFICATIONS ****                                       00250000
*                                                                       00300000
*01* MODULE-NAME = IGC0002H                                             00350000
*01* STATUS = 00                                                        00400000
*01* CHANGE-ACTIVITY = NEW FOR RELEASE 21                               00450000
*A 351100                                                       PTM2140 00460044
*01* DESCRIPTIVE-NAME = CATALOG OPEN/EXTEND MODULE                      00500000
*01* FUNCTION = OPEN AND EXTEND SYSCTLG DATA SET.  THIS INCLUDES        00550000
*    STEPPING TO THE NEXT EXTENT OF THE CATALOG DATA SET.               00600000
*01* NOTES                                                              00650000
*02*    DEPENDENCIES = IGG0553A (EXTEND), IGG0CLF2 (FORMAT)             00700000
*       CHARACTER CODE = REQUIRES REASSEMBLY.                           00750000
*02*    PERFORMANCE = SEE PERFORMANCE SPECIFICATIONS.                   00800000
*02*    RESTRICTIONS = ALL DIRECT ACCESS STORAGE DEVICES EXCEPT 2321    00850000
*       DATA CELL ARE SUPPORTED BY CATALOG MANAGEMENT.                  00900000
*02*    REGISTER-CONVENTIONS = AS FOLLOWS                               00950000
*              RFKEY = R0  INPUT TYPE KEY.                              01000000
*              RPARM = R1  INPUT PARAMETER.                             01050000
*              RCVT  = R3  CVT POINTER.                                 01100000
*              RCWA  = R6  CATALOG WORK AREA BASE.                      01150000
*              RBASE = R12 CSECT BASE REGISTER.                         01200000
*              RGAREA= R13 OPEN DCB/DEB BASE.                           01250000
*              RGRET = R14 RETURN REGISTER.                             01300000
*              RBR   = R15 RETURN CODE REGISTER.                        01350000
*02*    PATCH-LABEL = NONE                                              01400000
*01* MODULE-TYPE = MODULE                                               01450000
*02*    PROCESSOR = ASSEMBLER                                           01500000
*02*    MODULE-SIZE = 1024 BYTES                                        01550000
*02*    ATTRIBUTES = REENTERABLE, READ ONLY, ENABLED, SUPERVISORY MODE  01600000
*01* ENTRY = IGC0002H                                                   01650000
*02*    PURPOSE = OPEN OR EXTEND CATALOG DATA SET.                      01700000
*02*    LINKAGE = SVC 28  AND XCTL                                      01750000
*02*    INPUT = 1. IF REQUEST IS TO OPEN CATALOG (SVC 28)               01800000
*03*           A. REGISTER 0 - CONTAINS ZEROS.                          01850000
*03*           B. REGISTER 1 - CONTAINS THE UCB ADDRESS OF THE          01900000
*                 VOLUME WHOSE CATALOG IS TO BE OPENED.                 01950000
*03*           C. REGISTER 15 - CONTAINS THE ADDRESS OF A WORK AREA     02000000
*                 IN WHICH THE DCB/DEB CHAIN IS TO BE BUILT.  THIS      02050000
*                 WORK AREA ALSO CONTAINS ENOUGH SPACE TO READ IN       02100000
*                 A DSCB. IF OPEN IS SUCCESSFUL, CORE BEYOND THE DEB IS 02150000
*                 FREED.                                                02200000
*02*    2. IF REQUEST IS TO LOCATE NEXT EXISTING EXTENT (SVC 28)        02250000
*03*           A. REGISTER 0 - CONTAINS THE DCB ADDRESS.                02300000
*04*                 1. THE ADDRESS OF THE CATALOG WORK AREA IS         02350000
*                       LOCATED AT OFFSET 8 (DEC) OF THE DCB AREA.      02400000
*02*    3. IF REQUEST IS TO OBTAIN AN ADDITIONAL EXTENT (SVC 28)        02450000
*03*           A. REGISTER 0 - CONTAINS THE DCB ADDRESS.                02500000
*04*                 1. THE ADDRESS OF THE CATALOG WORK AREA IS         02550000
*                       LOCATED AT OFFSET 8(DEC) OF THE DCB AREA.       02600000
*04*                 2. THE REQUEST IS FOR A NEW EXTENT IF THE 'M'+1    02650000
*                       OF THE MBBCCHHR IN THE IOB OF THE CATALOG       02700000
*                       WORK AREA IS EQUAL TO THE 'M' IN THE NUMBER     02750000
*                       OF EXTENTS IN THE DEB.                          02800000
*02*     4. IF CONTROL HAS RETURNED FROM THE EXTEND ROUTINES (XCTL)     02850000
*03*           A. REGISTER 0 - CONTAINS A NEGATIVE VALUE.               02900000
*03*           B. REGISTER 4 - CONTAINS ADDRESS OF EXTEND WORK AREA.    02950000
*03*           C. REGISTER 9 - CONTAINS THE DCB ADDRESS FOR CATALOG.    03000000
*03*           D. REGISTER 10 - CONTAINS THE TTR OF THE NEW EXTENT.     03050000
*03*           E. REGISTER 11 - CONTAINS THE UCB ADDRESS FOR THE        03100000
*                 CATALOG VOLUME.                                       03150000
*02*    OUTPUT = THE ADDRESS OF THE DCB IS RETURNED TO THE              03200000
*       CALLER IN REGISTER 1.                                           03250000
*02*    EXIT-NORMAL = 'FORMAT' IF FORMAT REQUIRED OR 'RETURN'           03300000
*02*    EXIT-ERROR = RETURN                                             03350000
*              R15 = 4 IF SYSCTLG DATA SET NOT FOUND.                   03400000
*              R15 = 8 IF NO EXTENTS ALLOCATED.                         03450000
*              R15 = 12 IF AN IO ERROR OCCURRED.                        03500000
*01* EXTERNAL-REFERENCES = CVT, UCB, CATALOG IOB, SYSCTLG DSCB          03550000
*02*    ROUTINES = IECPRLTV                                             03600000
*02*    DATA-SETS = SYSCTLG                                             03650000
*02*    DATA-AREA = DESCRIBED BY DSECTS IN THE LISTING.                 03700000
*01* TABLES = CVT                                                       03750000
*01* MACROS = EXCP, FREEMAIN, GETMAIN, XCTL, WAIT                       03800000
**** END OF SPECIFICATIONS ***/                                         03850000
*                                                                       03900000
*********************************************************************** 03950000
         EJECT                                                          04000000
*/*IGC0002H: CHART AMODE */                                             04050000
*/*HEADER                                                CATALOG        04100000
*/*OPEN/EXTEND MODULE */                                                04150000
*                                                                       04200000
*********************************************************************** 04250000
*                                                                       04300000
         SPACE                                                          04350000
*/*IGC0002H:  E                        OPEN ENTRY. */                   04400000
         SPACE                                                          04450000
IGC0002H CSECT                                                          04500000
         BALR  RBASE,0            SET THE BASE REGISTER.                04550000
         USING *,RBASE            SET ADDRESSABILITY.                   04600000
         SSM   FF                 ENABLE.                               04650000
         SPACE                                                          04700000
*/*         D     (1ST,EXTEND,2ND,EXTENDB,NO,) 1ST, 2ND EXTEND PASS OR  04750000
*/*OPEN */                                                              04800000
         SPACE                                                          04850000
         L     RCVT,CVTPTR        PICK UP THE CVT POINTER.              04900000
         LR    RGAREA,R15         LOAD AREA ADDRESS.                    04950000
         LTR   RFKEY,RFKEY        TEST FOR RET FROM EXTEND.             05000000
         BM    EXTENDB            BRANCH IF YES.                        05050000
         LTR   RGAREA3,RFKEY      SAVE THE INPUT DCB ADDRESS            05100000
         BP    EXTEND             BRANCH FOR AN EXTEND REQUEST.         05150000
         USING CVT,RCVT           SET CVT ADDRESSABILITY.               05200000
         USING AREA,RGAREA        SET DCB/DEB ADDRESSABILITY.           05250000
         USING UCB,RUCB           SET UCB ADDRESSABILITY.               05300000
         LR    RUCB,RPARM         SET UP UCB BASE REGISTER.             05350000
         XC    FMTSW(SWL),FMTSW   CLEAR ALL SWITCHES.                   05400000
         EJECT                                                          05450000
*                                                                       05500000
*********************************************************************** 05550000
*                                                                       05600000
* THE FOLLOWING CODE FROM THE LABEL BLDEB TO YESFMT INITIALIZES A       05650000
* DCB AND DEB IN THE WORK AREA PROVIDED.                                05700000
*                                                                       05750000
*********************************************************************** 05800000
*                                                                       05850000
         SPACE                                                          05900000
*/*BLDEB:   P                        CLEAR DEB AND SET UCB ADDR. */     05950000
         SPACE                                                          06000000
RVTTR    EQU   0                  REG 0 HOLDS VTOC TTR                  06050000
RDBSET   EQU   6                  REG 4 USED TO SET UP THE DEB.         06100000
BLDEB    EQU   *                                                        06150000
         XC    DEB(DEBL),DEB      CLEAR THE DEB AREA.                   06200000
         ST    RUCB,DEBUCBAD      STORE UCB ADDRESS IN THE DEB.         06250000
         L     RVTTR,SRTEFSCT     GET THE VTOC TTR.                     06300000
         SPACE                                                          06350000
*/*         P                        INIT. APPENDAGE VECTOR TABLE. */   06400000
         SPACE                                                          06450000
         MVC   DEBAPPAD,CVTXAPG   MOVE APP VECTOR TABLE ADDRESS.        06500000
         MVI   DEBAPPAD,FOUR      SET EXTENT CLASS.                     06550000
         SPACE                                                          06600000
*/*         P                        SET DEBDCBAD. */                   06650000
         SPACE                                                          06700000
         LA    RDBSET,DEBDEBAD    USE AS DCB.                           06750000
         S     RDBSET,FDEBAD      MINUS DEB ID COMPL & DISPL.           06800000
         ST    RDBSET,DEBDCBAD    ACTUAL DCB ADDRESS.                   06850000
         MVI   DEBDVMOD,X10       FILE MASK, PERMIT SEEK HH.            06900000
         MVC   DEBENDCC(L'HICCHHNT),HICCHHNT SET HI UPPER EXTENT.       06950000
         MVI   DEBNMEXT,X01       NUMBER OF EXTENTS.                    07000000
         SPACE                                                          07050000
*/*         P                        CONVERT RELATIVE TO ACTUAL ADDR.   07100000
*/**/                                                                   07150000
         SPACE                                                          07200000
RDEBP    EQU   1                  DEB POINTER FOR INPUT TO CNVT.        07250000
RRES     EQU   2                  RESULT RETURN AREA POINTER.           07300000
         IC    RVTTR,ZEROA        SET CONCAT NO. TO ZERO.               07350000
         L     RBR,CVTPCNVT       ENTRY OF CNVT RTN.                    07400000
         LA    RDEBP,DEB          GET DEB ADDRESS.                      07450000
         ST    RDEBP,DEBDEBAD     DEB POINTER.                          07500000
         LA    RRES,MBBCCHHR      CONVERTED RESULT AREA.                07550000
         LR    RGAREA2,RGAREA     SAVE AREA ADDR.                       07600000
         STM   R9,R13,DSCBK       SAVE VOLITILE REGISTERS.              07650000
         BALR  RGRET,RBR          GO TO THE CONVERT ROUTINE.            07700000
         LM    R9,R13,DSCBK-AREA(R8)        RESTORE VOLATILE REGS.      07750000
         DROP  RCVT                                                     07800000
         DROP  RUCB                                                     07850000
         MVI   DS1FMTID,X00       ZERO THE FORMAT ID FIELD.             07900000
         SPACE                                                          07950000
*/*         P                        CONSTRUCT AN IOB AND ECB. */       08000000
         SPACE                                                          08050000
RECBA    EQU   0                  REGS USED TO SET UP ECB.              08100000
RECBB    EQU   2                  REGS USED TO SET UP ECB.              08150000
RECBC    EQU   5                  REGS USED TO SET UP ECB.              08200000
RECBD    EQU   8                  REGS USED TO SET UP ECB.              08250000
         SR    RECBA,RECBA        ECB.                                  08300000
         LA    RECBB,AECB         ECB POINTER.                          08350000
         LA    RECBC,CHPG         CHANNEL PROGRAM POINTER.              08400000
         SR    RECBD,RECBD        BLOCK INCR FLD.                       08450000
         STM   RECBA,RECBD,AECB   STORE ECB AND IOB.                    08500000
         MVI   AIOB,X42           SET UNRELATED REQUEST.                08550000
         SPACE                                                          08600000
*/*         P                        RELOCATE CHAN PROG FOR DSCB READ.  08650000
*/**/                                                                   08700000
         SPACE                                                          08750000
RCCWA    EQU   0                  REGS USED TO SET CCW ADDRESSES.       08800000
RCCWB    EQU   2                  REGS USED TO SET CCW ADDRESSES.       08850000
RCCWC    EQU   4                  REGS USED TO SET CCW ADDRESSES.       08900000
RCCWD    EQU   6                  REGS USED TO SET CCW ADDRESSES.       08950000
RCCWE    EQU   8                  REGS USED TO SET CCW ADDRESSES.       09000000
RCCWF    EQU   11                 REGS USED TO SET CCW ADDRESSES.       09050000
         LM    RCCWA,RCCWF,CCW1   GET THE CCW CONSTANTS.                09100000
         AR    RCCWA,RGAREA       MODIFY THE ADDRESSES                  09150000
         AR    RCCWB,RGAREA       IN THE PATTERN CCWS.                  09200000
         AR    RCCWC,RGAREA                                             09250000
         AR    RCCWD,RGAREA                                             09300000
         AR    RCCWE,RGAREA                                             09350000
         STM   RCCWA,RCCWF,CHPG   STORE THE CHANNEL PROGRAM.            09400000
RCCWG    EQU   7                  REGS USED TO SET CCW ADDRESSES.       09450000
         LM    RCCWA,RCCWG,CCW7   MORE CCW CONSTANTS.                   09500000
         AR    RCCWA,RGAREA       MODIFY THE ADDRESSES                  09550000
         AR    RCCWB,RGAREA       IN THE PATTERN CCWS.                  09600000
         AR    RCCWC,RGAREA                                             09650000
         AR    RCCWD,RGAREA                                             09700000
         STM   RCCWA,RCCWG,CHPGA   STORE REMAINDER OF CHAN PROGS.       09750000
         SPACE                                                          09800000
*/*         P                        SET SEARCH ARG & READ DSCB. */     09850000
         SPACE                                                          09900000
         MVC   DSCBK(L'SYSCTLG),SYSCTLG  SET DS NAME.                   09950000
         MVC   DSCBK+8(L'DSCBK-L'SYSCTLG),DSCBK+7  BLANK REMAINDER      10000000
         SPACE                                                          10050000
*/*         S                        IO: EXCP, WAIT AND CHECK. */       10100000
         SPACE                                                          10150000
         BAL   RGRET,IO           GO TO THE IO ROUTINE.                 10200000
         SPACE                                                          10250000
*/*         D     (NO,ERROR4,YES,)   SYSCTLG DATA SET FOUND */          10300000
         SPACE                                                          10350000
         TM    DS1FMTID,XFF       CHECK FORMAT ID FIELD.                10400000
         BZ    ERROR4             SYSCTLG DATA SET NOT FOUND.           10450000
         MVC   DSCBTRK,COUNT      SAVE CCHH OF SYSCTLG DSCB.            10500000
         SPACE                                                          10550000
*/*         D     (1ST,EXTENDA,2ND,YESFMT,NO,)  EXTEND 1ST, 2ND PASS OR 10600000
*/*OPEN */                                                              10650000
         SPACE                                                          10700000
         CLI   EXTDSW,1           TEST THE EXTEND SWITCH.               10750000
         BE    EXTENDA            BRANCH IF 1ST PASS OF EXTEND.         10800000
         BH    YESFMT             BRANCH IF 2ND PASS OF EXTEND.         10850000
         EJECT                                                          10900000
*                                                                       10950000
* NOTE THAT THIS CODE IS ENTERED ONLY IF THE REQUEST IS FOR AN OPEN.    11000000
* THIS CODE BUILDS THE ACTUAL DEB/DCB FOR THE SYSCTLG DATA SET.         11050000
*                                                                       11100000
         SPACE                                                          11150000
*/*         D     (NO,NOFMT,YES,)    FORMAT REQUIRED FOR OPEN */        11200000
         SPACE                                                          11250000
         TM    DS1LSTAR+2,XFF     'R' OF TTRLL IN DSCB.                 11300000
         BO    NOFMT              DON'T FORMAT.                         11350000
         SPACE                                                          11400000
*/*YESFMT:  P                        SET THE FORMAT FLAG ON. */         11450000
         SPACE                                                          11500000
YESFMT   EQU   *                                                        11550000
         MVC   FMTSW,DS4DEVDB     SAVE DIRECTORY BLOCKS/TRACK.          11600000
         SPACE                                                          11650000
*/*NOFMT:   P                        GET NO. EXTENTS ALLOCATED */       11700000
         SPACE                                                          11750000
REXT     EQU   3                  NUMBER OF EXTENTS REGISTER.           11800000
NOFMT    EQU   *                                                        11850000
         SR    REXT,REXT                                                11900000
         IC    REXT,DS1NOEPV      GET NUMBER OF EXTENTS.                11950000
         SPACE                                                          12000000
*/*         D     (NO,ERROR4,YES,)   EXTENTS ALLOCATED */               12050000
         SPACE                                                          12100000
         LTR   REXT,REXT          IS EXTENT ALLOCATION ZERO?            12150000
         BZ    ERROR4             BRANCH IF NO EXTENTS ALLOCATED.       12200000
         SPACE                                                          12250000
*/*         P                        FORMAT 1 DSCB EXT LOOP. */         12300000
         SPACE                                                          12350000
RTOB     EQU   4                  EXTENT TO BASE.                       12400000
RFRL     EQU   7                  FROM LIMIT REGISTER.                  12450000
RFRS     EQU   6                  SIZE FO FROM REGISTER.                12500000
RFRB     EQU   5                  EXTENT FROM BASE.                     12550000
         STC   REXT,DEBNMEXT      STORE NO. OF EXTENTS.                 12600000
         LR    RTOB,RGAREA        'TO' BASE.                            12650000
         LA    RFRL,DS1EXT3       LIMIT FOR BXLE.                       12700000
         LA    RFRS,DS1EXT2-DS1EXT1 SIZE OF 'FROM' EXTENT.              12750000
         LA    RFRB,DS1SCALO+1    'FROM' BASE.                          12800000
BLDXTLP  EQU   *                                                        12850000
         LA    RTOB,EXTL(RTOB)    GO TO NEXT EXTENT IN DEB.             12900000
         BXLE  RFRB,RFRS,BLDXTM   BR IF STILL IN FORMAT 1 DSCB.         12950000
         SPACE                                                          13000000
*/*         S                        IO: READ FORMAT 3 DSCB. */         13050000
         SPACE                                                          13100000
RCCWH    EQU   1                  REG USED IN RELOCATING CCWS.          13150000
         MVC   CCHHR(CCHHRL),DS1PTRDS  FORMAT 3 POINTER.                13200000
         LM    RCCWA,RCCWH,CCWRDKD  READ KEY DATA CCW.                  13250000
         AR    RCCWA,RGAREA       RELOCATE.                             13300000
         STM   RCCWA,RCCWH,CHPG+CCW3-CCW1    MODIFY EXISTING CHAN PROG. 13350000
         BAL   RGRET,IO           EXCP, WAIT CHECK.                     13400000
         MVC   DS1FMTID(NINTY),DS1DSSN  SHIFT FLD LEFT 1 BYTE.          13450000
         LA    RFRB,DSCBK4        'FROM' EXTENT BASE.                   13500000
         SPACE                                                          13550000
*/*BLDXTM:  P                        SET FORMAT 3 EXTENTS. */           13600000
         SPACE                                                          13650000
BLDXTM   EQU   *                                                        13700000
         MVC   DEBUCBAD-AREA((L'DEBUCBAD+L'DEBBINUM),RTOB),DEBUCBAD     13750000
*                                 MOVE DVMOD, UCBADR,BB TO DEB.         13800000
         MVC   DEBSTRCC-AREA(EIGHT,RTOB),TWO(RFRB)                      13850000
*                                 MOVE CCHH TO DEB.                     13900000
         CLI   0(RFRB),X81        CHECK EXTENT TYPE.                    13950000
         BE    CALCNT             BRANCH ON CYLINDER BOUNDARY.          14000000
         MVI   DEBUCBAD-AREA(RTOB),X18  FILE MASK TO INHIBIT HD SW.     14050000
         SPACE                                                          14100000
*/*CALCNT:  P                        CALC NO. TKS IN EXTENT. */         14150000
         SPACE                                                          14200000
CALCNT   EQU   *                                                        14250000
RCVTA    EQU   8                  SECOND CVT BASE REGISTER.             14300000
RTTCT    EQU   10                 COUNT OF TT REGISTER.                 14350000
RTTCTA   EQU   0                  COUNT OF TT REG A.                    14400000
         L     RCVTA,CVTPTR                                             14450000
         USING CVT,RCVTA                                                14500000
         L     RBR,CVTPRLTV       CONVERT ROUTINE ADDRESS.              14550000
         LA    RDEBP,DEB          REGISTER 1 = DEB ADDRESS.             14600000
         LA    RRES,COUNT         RRES = ADDRESS OF RESULTS.            14650000
         STM   R11,R15,REGS2      SAVE REGS.                            14700000
         LR    RGAREA2,RGAREA     SAVE AREA ADDR.                       14750000
         DROP  RGAREA                                                   14800000
         USING AREA,RGAREA2                                             14850000
         MVC   COUNT+3(L'DEBSTRCC+L'DEBSTRHH),DEBSTRCC-AREA(RTOB)       14900000
*                                 MOVE START CCHH TO DEB.               14950000
         BALR  RGRET,RBR          CONVERT TO START TT.                  15000000
         ST    RTTCTA,REGSAVE     SAVE START TT.                        15050000
         L     RBR,REGS6          RESTORE ROUTINE ADDR.                 15100000
         MVC   COUNT+3(L'DEBENDCC+L'DEBENDHH),DEBENDCC-AREA(RTOB)       15150000
*                                 MOVE END CCHH TO DEB.                 15200000
         BALR  RGRET,RBR          CONVERT TO END TT.                    15250000
         LM    R10,R15,REGSAVE    LOAD START TT AND RESTORE REGS.       15300000
         SR    RTTCT,RTTCTA       START TT - END TT = -(NT-1)           15350000
         SRL   RTTCT,16           GET -(NT-1) AS HALF WORD.             15400000
         BCTR  RTTCT,RTTCTA       -(NT-1)-1=-NT                         15450000
         LCR   RTTCT,RTTCT        NT= NUMBER OF TKS IN EXTENT.          15500000
         STH   RTTCT,DEBNMTRK-AREA(RTOB)      PUT IN EXTENT.            15550000
         DROP  RCVTA                                                    15600000
         USING AREA,RGAREA                                              15650000
         BCT   REXT,BLDXTLP       BRANCH IF ANOTHER EXTENT.             15700000
         SPACE                                                          15750000
*/*         P                        CALC NO. BYTES IN DCB, QCB, DEB */ 15800000
         SPACE                                                          15850000
RNMA     EQU   1                  REGS USED TO CALCULATE BYTES TO BE    15900000
*                                 FREED AFTER OPEN.                     15950000
RNMB     EQU   2                  NUMBER OF BYTES.                      16000000
RNMT     EQU   0                  NUMBER OF TRACKS                      16050000
         LA    RNMB,DEBDVMOD-AREA(RTOB)   ADDR OF AREA TO BE FREED.     16100000
         LR    RNMA,RNMB          SAVE FOR FREEMAIN.                    16150000
         SR    RNMB,RGAREA        NO. OF BYTES IN QCB & DEB.            16200000
         ST    RNMB,NMBYTES       TO BE FREED LATER.                    16250000
         MVI   NMBYTES,B253       SET SUB-POOL NUMBER.                  16300000
         MVC   DEBDVMOD(MAXEL),DEBDVMOD+EXTL REMOVE DUMMY EXTENT.       16350000
         L     RNMT,SPBYTES       ORIGINAL NO. BYTES.                   16400000
         SR    RNMT,RNMB          NO. TO BE FREED NOW.                  16450000
RBT      EQU   2                  BLOCKS PER TRACK REGISTER.            16500000
         SR    RBT,RBT                                                  16550000
         IC    RBT,FMTSW          GET COUNT OF BLOCKS/TRACK.            16600000
         LH    RTTRP,EXTDTT       LOAD FORMATTING START TT.             16650000
         SLL   RTTRP,16           SET THE TTRN.                         16700000
         SPACE                                                          16750000
*/*         P                        FREE EXCESS CORE. */               16800000
         SPACE                                                          16850000
         FREEMAIN R,LV=(0),A=(1)                                        16900000
         EJECT                                                          16950000
*                                                                       17000000
* THIS CODE HANDLES THE INTERFACE WITH THE FORMAT ROUTINE.              17050000
*                                                                       17100000
         SPACE                                                          17150000
*/*         D     (YES,FORMAT,NO,)   IS FORMAT REQUIRED */              17200000
         SPACE                                                          17250000
RFSW     EQU   2                  FORMAT SWITCH REGISTER.               17300000
RRP      EQU   1                  RETURN REGISTER POINTER.              17350000
         LTR   RFSW,RFSW          TEST FORMAT SW.                       17400000
         BC    7,FORMAT           BRANCH TO FORMAT.                     17450000
         L     RRP,DEBDCBAD       LOAD THE DCB ADDRESS.                 17500000
         SPACE                                                          17550000
*/*         R                        RETURN TO CALLER. */               17600000
         SPACE                                                          17650000
RRC      EQU   15                 RETURN CODE REGISTER.                 17700000
         SR    RRC,RRC            SET ZERO RETURN CODE.                 17750000
         SVC   EXIT               EXIT SVC TO CALLER.                   17800000
         SPACE                                                          17850000
*/*FORMAT:  P                        SET UP FORMAT XCTL. */             17900000
         SPACE                                                          17950000
FORMAT   EQU   *                                                        18000000
RTTRP    EQU   6                  TTRN PARM REGISTER.                   18050000
         LA    R0,FMWAL           SET SP=0, LEN=512.                    18100000
         LR    R3,R0              SAVE BYTE COUNT FOR CLF2.             18150000
         GETMAIN R,LV=(0)                                               18200000
         LR    R4,R1              SAVE WORK AREA ADDR.                  18250000
         L     R1,DEBDCBAD        LOAD THE DCB ADDRESS.                 18300000
         SR    RFKEY,RFKEY        SET CATALOG CALL INDICATOR.           18350000
         LA    RBR,XCTLCONF       FORMAT MODULE NAME ADDR.              18400000
         SPACE                                                          18450000
*/*XCTL:    R                        XCTL SUBROUTINE. */                18500000
         SPACE                                                          18550000
XCTL     EQU   *                                                        18600000
         XC    FOUR(FOUR,RTOB),FOUR(RTOB)  ZERO XCTL DCB ADDRESS.       18650000
         MVC   EIGHT(EIGHT,RTOB),0(RBR)   MODULE NAME.                  18700000
         LA    RBR,EIGHT(RTOB)    SET XCTL PTR TO MOD NAME.             18750000
         ST    RBR,0(RTOB)                                              18800000
         XCTL  MF=(E,(1)),SF=(E,(4))                                    18850000
         EJECT                                                          18900000
*                                                                       18950000
* THE FOLLOWING CODE HANDLES THE EXTENDING OF CATALOGS.                 19000000
*                                                                       19050000
* INITIAL ENTRY FOR THE EXTEND FUNCTION IS AT THE LABEL 'EXTEND'.       19100000
* CHECK FIRST TO SEE IF THE REQUEST IS FOR A NEW EXTENT OR STEP TO      19150000
* THE NEXT EXTENT.                                                      19200000
*                                                                       19250000
         SPACE                                                          19300000
*/*EXTEND:  D     (NEW,EXTENDC,OLD,) NEW EXTENT OR OLD */               19350000
         SPACE                                                          19400000
EXTEND   EQU   *                                                        19450000
         DROP  RGAREA                                                   19500000
         USING DCBAREA,RGAREA3                                          19550000
         L     RCWA,CATWAP         GET CAT WORK AREA POINTER.           19600000
         USING WORKAREA,RCWA                                            19650000
         MVC   OPTNCCW,TIC2        SET TIC TO BYPASS WRITE VERIFY.      19700000
         LH    RTTCT,VCLSTBLK      LOAD THE TT OF EXTENT.               19750000
         LA    RTTCT,ONE(RTTCT)    STEP TO NEXT RELATIVE TRACK.         19800000
         SR    RIOBS,RIOBS         CLEAR AN ARITHMETIC REG.             19850000
         IC    RIOBS,IOBSKADD      PICK UP 'M' FROM THE IOB.            19900000
         LA    RIOBS,ONE(RIOBS)    STEP M TO M+1.                       19950000
         STC   RIOBS,IOBSKADD      STORE IT BACK IN THE IOB.            20000000
         CLC   DEBNMEXT,IOBSKADD   COMPARE 'M' TO NO. OF EXTENTS.       20050000
         BE    EXTENDC             BRANCH FOR NEW EXTENT.               20100000
         SPACE                                                          20150000
*                                                                       20200000
* THE REQUEST IS FOR A STEP TO THE NEXT EXISTING EXTENT.                20250000
* SATISFY THAT REQUEST HERE.                                            20300000
*                                                                       20350000
         SPACE                                                          20400000
*/*         P                        SET IOB TO NEXT EXTENT. */         20450000
         SPACE                                                          20500000
RIOBS    EQU   15                 REGISTERS USED TO SET CAT IOB.        20550000
         SLL   RIOBS,FOUR         SHIFT M TO USE AS AN INDEX.           20600000
         LA    RIOBS,DEBSTRCC(RIOBS) POINT R3 TO CCHH OF                20650000
*                                        NEXT EXTENT.                   20700000
         MVC   IOBSKADD+3(FOUR),0(RIOBS)   MOVE THE CCHH TO THE IOB     20750000
         MVI   IOBSKADD+7,X00     SET R TO ZERO.                        20800000
         MVI   THETA,X00          SET RPS THETA TO ZERO.                20850000
         SR    RRC,RRC            ZERO THE RETURN CODE.                 20900000
         SPACE                                                          20950000
*/*         R                        RETURN TO CALLER. */               21000000
         SPACE                                                          21050000
         SVC   EXIT               SVC EXIT.                             21100000
         DROP  RCWA                                                     21150000
         EJECT                                                          21200000
*                                                                       21250000
* PREPARE TO GET A NEW EXTENT FOR THE USER.                             21300000
*                                                                       21350000
         SPACE                                                          21400000
*/*EXTENDC: P                        GET MAIN FOR EXTEND. */            21450000
         SPACE                                                          21500000
EXTENDC  EQU   *                                                        21550000
         L     RUCB,DEBUCBAD      GET THE UCB ADDRESS.                  21600000
         DROP  RGAREA3                                                  21650000
         L     RNMT,XTBYTES       GET SUB-POOL AND LENGTH.              21700000
         BAL   RGRET,GETMAINB     BRANCH TO GET MAIN ROUTINE.           21750000
         SPACE                                                          21800000
*/*         P     (,BLDEB)           INITIALIZE FOR 1ST PASS. */        21850000
         SPACE                                                          21900000
         USING AREA,RGAREA                                              21950000
         MVI   EXTDSW,X01         INDICATE 1ST PASS OF EXTEND.          22000000
         STM   R9,R10,EXTDRGSV    SAVE THE INPUT PARAMETERS.            22050000
         B     BLDEB              GO TO GET DSCB FOR EXTEND.            22100000
         EJECT                                                          22150000
*                                                                       22200000
* THE FOLLOWING CODE COMPLETES THE BLOCKS FOR THE CALL TO EXTEND        22250000
* AND THEN DOES THE XCTL TO THE EXTEND ROUTINE.                         22300000
*                                                                       22350000
         SPACE                                                          22400000
*/*EXTENDA: D     (YES,EXTENDAA,NO,) IS SEC ALLOC QTY ZERO */           22450000
         SPACE                                                          22500000
EXTENDA  EQU   *                                                        22550000
         LM    R9,R10,EXTDRGSV    RESTORE REGS 9 & 10.                  22600000
         OC    DS1SCALO+1(L'DS1SCALO-1),DS1SCALO+1  SEC ALLOC ZERO      22650000
         BC    8,EXTENDAA         BRANCH IF NO SEC ALLOCATION.          22700000
         MVC   NMBYTES,DS1SCALO   SAVE SEC ALLOCATION REQUEST.          22750000
         SPACE                                                          22800000
*/*         P                        CONSTRUCT DUMMY JFCB. */           22850000
         SPACE                                                          22900000
         MVC   JFCBDSNM,DSCBK     D.S. NAME OF SYSCTLG.                 22950000
         XC    JFCBELNM(X184),JFCBELNM   ZERO JFCB, ECB AND IOB.        23000000
         MVC   JFCBCTRI(L'NMBYTES),NMBYTES  SEC ALLOC REQUEST.          23050000
         MVI   JFCBDRLH,ONE       AVE REC LENGTH = 1.                   23100000
         STM   R9,R10,JFCBELNM    SAVE SOME REGISTERS.                  23150000
         SPACE                                                          23200000
*/*         P                        CONSTRUCT THE IOB. */              23250000
         SPACE                                                          23300000
RIOBR    EQU   0                  REGISTERS USED TO SET THE IOB.        23350000
RIOBT    EQU   4                  REGISTERS USED TO SET THE IOB.        23400000
         LM    RIOBR,RCVT,JFCBTSDM    LOAD ZEROS.                       23450000
         LA    RIOBR,DXECB        ECB ADDRESS.                          23500000
         LA    RCVT,DXCCW         CHANNEL PROGRAM START ADDRESS.        23550000
         LA    RIOBT,DXDCB        DCB ADDRESS.                          23600000
         STM   RIOBR,RIOBT,IOBECBPT     STORE THEM IN THE IOB.          23650000
         SPACE                                                          23700000
*/*         P                        CONSTRUCT THE DEB. */              23750000
         SPACE                                                          23800000
         MVC   DXDEB(DEBL),DEB    GET FROM ALL READY CONSTRUCTED DEB.   23850000
         MVC   DXDEBDCB+1(L'DXDEBDCB-1),IOBDCBPT  NEW DCB POINTER.      23900000
         SPACE                                                          23950000
*/*         P                        CONSTRUCT THE DCB. */              24000000
         SPACE                                                          24050000
RXDEB    EQU   0                  DEB ADDRESS MANIPULATING REG.         24100000
         LA    RXDEB,DXDEB                                              24150000
         ST    RXDEB,DXDCBDEB     STORE THE DEB POINTER.                24200000
         SPACE                                                          24250000
*/*         P     (,XCTL)            SET UP FOR EXTEND XCTL. */         24300000
         SPACE                                                          24350000
RXP1     EQU   2                  XCTL PARM REG 1.                      24400000
RXP2     EQU   4                  XCTL PARM REG 2                       24450000
RXP3     EQU   5                  XCTL PARM REG 3.                      24500000
RXP4     EQU   10                 XCTL PARM REG 4.                      24550000
         LR    RXP1,RGAREA3       SET THE DCB ADDRESS.                  24600000
         LR    RXP2,RGAREA        SET THE WORK AREA ADDRESS.            24650000
         DROP  RGAREA                                                   24700000
         USING DCBAREA,RGAREA3                                          24750000
         LA    RXP3,DEB           SET THE DEB ADDRESS.                  24800000
         L     RXP4,DEBUCBAD      SET THE UCB ADDRESS.                  24850000
         DROP  RGAREA3                                                  24900000
         LA    RGAREA,TWO         INDICATE SYSCTLG EXTEND.              24950000
         LA    RBR,XCTLCONX       EXTEND MODULE NAME ADDRESS.           25000000
         B     XCTL               GO CALL EXTEND                        25050000
         SPACE                                                          25100000
*                                                                       25150000
* THIS CODE HANDLES THE CASE WHERE EXTEND WAS REQUESTED BUT NO          25200000
* SECONDARY SPACE HAS BEEN ALLOCATED.                                   25250000
*                                                                       25300000
         SPACE                                                          25350000
*/*EXTENDAA: P                       FREE THE EXTEND WORK AREA. */      25400000
         SPACE                                                          25450000
EXTENDAA EQU   *                                                        25500000
         L     RNMT,XTBYTES       EXTEND WORK AREA LENGTH.              25550000
         LA    RNMA,0(RGAREA)     LOAD WORK AREA ADDRESS.               25600000
         SVC   FREEMAIN           FREE THE EXTEND WORK AREA CORE.       25650000
         SPACE                                                          25700000
*/*         R                        RETURN TO CALLER. */               25750000
         SPACE                                                          25800000
         LR    RRP,RGAREA3        SET DCB AREA ADDRESS FOR RETURN.      25850000
         LA    RRC,EIGHT          SET NO EXTENT RETURN CODE.            25900000
         SVC   EXIT               SVC EXIT.                             25950000
         EJECT                                                          26000000
*                                                                       26050000
* THIS CODE HANDLES THE ENTRY FROM THE EXTEND MODULES AFTER THEY        26100000
* HAVE COMPLETED THEIR WORK.                                            26150000
* NOTE THAT IF AN ERROR OCCURRED IN EXTEND, THE RETURN IS DIRECTLY      26200000
* BACK TO THE CALLING MODULE THRU AN SVC EXIT.                          26250000
*                                                                       26300000
         SPACE                                                          26350000
*/*EXTENDB: P                        FREE EXTEND WORK AREA CORE. */     26400000
         SPACE                                                          26450000
EXTENDB  EQU   *                                                        26500000
         L     RNMT,XTBYTES       EXTEND WORK AREA LENGTH.              26550000
         LA    RNMA,0(RXP2)       EXTEND WORK AREA ADDRESS.             26600000
         SVC   FREEMAIN           FREE THE EXTEND CORE.                 26650000
         SPACE                                                          26700000
*/*         P                        FREE OLD SYSCTLG DEB/DCB. */       26750000
         SPACE                                                          26800000
         USING DCBAREA,RGAREA3                                          26850000
         L     RCWA,CATWAP        SAVE CAT WORK AREA POINTER.           26900000
         L     RNMT,NMBYTES       GET NUMBER OF BYTES.                  26950000
         LA    RNMA,NMBYTES       GET AREA ADDRESS.                     27000000
         SVC   FREEMAIN           FREE THE OLD DCB AREA.                27050000
         DROP  RGAREA3                                                  27100000
         SPACE                                                          27150000
*/*         P     (,BLDEB)           GET NEW SYSCTLG DEB/DCB CORE. */   27200000
         SPACE                                                          27250000
         BAL   RGRET,GETMAIN      BRANCH TO GET MAIN ROUTINE.           27300000
         USING AREA,RGAREA                                              27350000
         ST    RCWA,CATWAP             STORE THE CAT WORK AREA PTR.     27400000
         STH   RTTCT,EXTDTT       SAVE TT START OF NEW AREA.            27450000
         MVI   EXTDSW,TWO         INDICATE SECOND PASS.                 27500000
         B     BLDEB              GO TO BUILD NEW DEB.                  27550000
         EJECT                                                          27600000
*                                                                       27650000
* THE FOLLOWING ARE SUB-ROUTINES USED BY THE OPEN MODULE.               27700000
*                                                                       27750000
         SPACE                                                          27800000
GETMAIN  EQU   *                                                        27850000
         L     RNMT,SPBYTES       NO OF BYTES FOR SYSCTLG DEB/DCB.      27900000
GETMAINB EQU   *                                                        27950000
         GETMAIN R,LV=(0)                                               28000000
         LR    RGAREA,RPARM       SET GOTTEN AREA ADDRESS IN BASE.      28050000
         BR    RGRET              RETURN TO THE CALLER.                 28100000
         SPACE                                                          28150000
*                                                                       28200000
* EXCP, WAIT AND IO ERROR CHECKING ROUTINE.                             28250000
*                                                                       28300000
IO       EQU   *                                                        28350000
         EXCP  AIOB                                                     28400000
         WAIT  1,ECB=AECB                                               28450000
         CLI   AECB,X7F           TEST ECB CONDITION.                   28500000
         BCR   8,RGRET            BRANCH NO ERROR.                      28550000
RRCA     EQU   2                  TEMP RETURN CODE REGISTER.            28600000
         LA    RRCA,TWELVE        SET IO ERROR CONDITION CODE.          28650000
         SPACE                                                          28700000
*                                                                       28750000
* RETURN TO THE CALLER IF AN ERROR HAS OCCURRED.                        28800000
*                                                                       28850000
         SPACE                                                          28900000
*/*RETURN:  R                             RETURN TO CALLER. */          28950000
         SPACE                                                          29000000
RETURN   EQU   *                                                        29050000
         L     RCWA,CATWAP        SAVE THE CATALOG WORK AREA ADDR.      29100000
         L     RNMT,SPBYTES       LOAD WORK AREA LENGTH.                29150000
         LA    RNMA,0(RGAREA)     GET DCB AREA ADDRESS.                 29200000
         SVC   FREEMAIN           FREE DCB AREA CORE.                   29250000
*                                                                       29300000
* THIS CODE IS TO SET DCB/DEB AREA CORE RELEASED FLAG.                  29350000
*                                                                       29400000
         SPACE                                                          29450000
         USING WORKAREA,RCWA                                            29500000
         OI    FLAG1,FREEDCB      TURN ON CORE FREED FLAG.              29550000
         DROP  RCWA                                                     29600000
*                                                                       29650000
         LR    RRC,RRCA           SET CONDITION CODE.                   29700000
         SVC   EXIT               SVC EXIT.                             29750000
         SPACE                                                          29800000
*/*ERROR4:  P     (,RETURN)                SET ERROR EXIT CODE 4. */    29850000
         SPACE                                                          29900000
ERROR4   EQU   *                                                        29950000
         LA    RRCA,FOUR          SET ERROR CODE IN R2.                 30000000
         B     RETURN             GO TO RETURN TO CALLER.               30050000
         EJECT                                                          30100000
*                                                                       30150000
* THIS AREA OF CODE CONTAINS THE CONSTANTS USED BY THIS MODULE.         30200000
*                                                                       30250000
SPBYTES  DS    0F                 GET SP 253 PARAMETER WORD.            30300000
         DC    AL1(253)           SUBPOOL NUMBER.                       30350000
         DC    AL3(AREAEND-AREA)  NUMBER OF BYTES.                      30400000
XTBYTES  DC    AL1(253)           SUBPOOL NUMBER.                       30450000
         DC    AL3(512)           EXTEND WORK AREA LENGTH.              30500000
FDEBAD   DS    0F                 ARITHMETIC CONSTANT EQUAL TO          30550000
         DC    X'F1'              2'S COMPL OF PROT TAG, DEB ID AND     30600000
         DC    AL3(DEBAD)         DEB ADDR DISPLACEMENT.                30650000
HICCHHNT DC    X'7FFF7FFF7FFF'    HIGH CCHH COUNT.                      30700000
FF       EQU   HICCHHNT+1         EQUATES TO A 1 BYTE FF CONSTANT.      30750000
ZEROA    DC    H'00'              A ONE BYTE ZERO CONSTANT.             30800000
SYSCTLG  DC    C'SYSCTLG '        SYSCTLG NAME.                         30850000
XCTLCONF DC    C'IGG0CLF2'        FORMAT MODULE NAME.                   30900000
XCTLCONX DC    C'IGG0553A'        EXTEND MODULE NAME.                   30950000
         EJECT                                                          31000000
*                                                                       31050000
* CCW'S USED BY THE IO ROUTINES.                                        31100000
*                                                                       31150000
CCW1     CCW   X'31',MBBCCHHR+3-AREA,X'40',5 SEARCH EQUAL ID.           31200000
CCW2     CCW   X'08',CHPG-AREA,0,1          TIC TO CCW1                 31250000
CCW3     CCW   X'06',IECSDSF4-AREA,X'60',48 READ VTOC DSCB.             31300000
CCW4     CCW   X'D1',DS4HPCHR-AREA,X'40',5  SEARCH HI ID.               31350000
CCW5     CCW   X'08',CHPG+48-AREA,0,1       TIC TO CCW7.                31400000
CCW6     CCW   X'03',0,0,1                  CONTROL NOP.                31450000
CCW7     CCW   X'29',DS1DSNAM-AREA,X'60',44 SEARCH KEY EQUAL            31500000
CCW8     CCW   X'08',CHPG+24-AREA,0,1       TIC TO CCW4.                31550000
CCW9     CCW   X'06',DS1FMTID-AREA,X'40',96 READ SYSCTLG DSCB.          31600000
CCW10    CCW   X'12',COUNT-AREA,0,8         READ COUNT.                 31650000
CCWRDKD  CCW   X'0E',DSCBK-AREA,0,140       READ KEY AND DATA.          31700000
         EJECT                                                          31750000
*                                                                       31800000
* THE FOLLOWING ARE MISCELLANEOUS EQUATES USED IN THIS PROGRAM.         31850000
*                                                                       31900000
DEBAD    EQU   44                 OFFSET FROM DCBADDR TO DEBADDR.       31950000
X00      EQU   X'00'              MISC EQUATE                           32000000
X01      EQU   X'01'              MISC EQUATE                           32050000
X10      EQU   X'10'              MISC EQUATE                           32100000
X18      EQU   X'18'              MISC EQUATE                           32150000
X20      EQU   X'20'              MISC EQUATE                           32200000
X42      EQU   X'42'              MISC EQUATE                           32250000
X7F      EQU   X'7F'              MISC EQUATE                           32300000
X81      EQU   X'81'              MISC EQUATE                           32350000
XFF      EQU   X'FF'              MISC EQUATE                           32400000
X184     EQU   184                MISC EQUATE                           32450000
FMWAL    EQU   512                FORMAT WORK AREA LENGTH.              32500000
B253     EQU   253                SUBPOOL 253 CONSTANT.                 32550000
EXIT     EQU   3                  SVC EXIT EQUATE.                      32600000
ONE      EQU   1                  NUMERIC EQUATE                        32650000
TWO      EQU   2                  NUMERIC EQUATE                        32700000
FOUR     EQU   4                  NUMERIC EQUATE                        32750000
EIGHT    EQU   8                  NUMERIC EQUATE                        32800000
TWELVE   EQU   12                 NUMERIC EQUATE                        32850000
FREEMAIN EQU   10                 SVC TEN EQUATE.                       32900000
NINTY    EQU   90                 DSCB MOVE LENGTH.                     32950000
         EJECT                                                          33000000
*                                                                       33050000
* REGISTERS USED IN THIS MODULE ARE EQUATED AS FOLLOWS.                 33100000
*                                                                       33150000
         SPACE                                                          33200000
R0       EQU   0                  REGISTER 0 EQUATE                     33250000
RFKEY    EQU   0                  INPUT FUNCTION REQUEST KEY.           33300000
R1       EQU   1                  REGISTER 1 EQUATE                     33350000
RPARM    EQU   1                  INPUT PARAMETER REGISTER.             33400000
R2       EQU   2                  REGISTER 2 EQUATE                     33450000
R3       EQU   3                  REGISTER 3 EQUATE                     33500000
RCVT     EQU   3                  CVT BASE REGISTER.                    33550000
R4       EQU   4                  REGISTER 4 EQUATE                     33600000
R5       EQU   5                  REGISTER 5 EQUATE                     33650000
R6       EQU   6                  CATALOG WORK AREA BASE.               33700000
RCWA     EQU   6                  CATALOG WORK AREA BASE.               33750000
R7       EQU   7                  REGISTER 7 EQUATE                     33800000
R8       EQU   8                  REGISTER 8 EQUATE                     33850000
RGAREA2  EQU   8                  SECONDARY DCB BASE REGISTER.          33900000
R9       EQU   9                  UCB BASE REGISTER.                    33950000
RGAREA3  EQU   9                  TERTIARY DCB BASE REGISTER.           34000000
R10      EQU   10                 REGISTER 10 EQUATE                    34050000
RFKEYA   EQU   10                 POSSIBLE TTR KEY FROM EXTEND.         34100000
R11      EQU   11                 REGISTER 11 EQUATE                    34150000
RUCB     EQU   11                 UCB BASE REGISTER.                    34200000
R12      EQU   12                 MODULE BASE REGISTER.                 34250000
RBASE    EQU   12                 BASE REGISTER.                        34300000
R13      EQU   13                 DCB/DEB AREA BASE REGISTER.           34350000
RGAREA   EQU   13                 DCB/DEB AREA BASE REGISTER.           34400000
R14      EQU   14                 EXTERNAL RETURN REGISTER.             34450000
RGRET    EQU   14                 RETURN REGISTER.                      34500000
R15      EQU   15                 RETURN CODE REGISTER.                 34550000
RBR      EQU   15                 RETURN CODE REGISTER.                 34600000
         SPACE                                                          34650000
*                                                                       34700000
**********************************************************************  34750000
*                                                                       34800000
* END OF THE IGC0002H CSECT.                                            34850000
*                                                                       34900000
OPENSIZE EQU   *                  EQUATE TO LAST BYTE OF CSECT.         34950000
MAXSIZE  EQU   IGC0002H+X'400'    MAXIMUM ALLOWABLE LENGTH.             35000000
AVAILABL EQU   MAXSIZE-OPENSIZE   FREE SPACE REMAINING.                 35050000
*                                                                       35100000
         ORG   IGC0002H+X'400'                                  PTM2140 35110044
**********************************************************************  35150000
*                                                                       35200000
         EJECT                                                          35250000
*                                                                       35300000
* THIS DSECT DESCRIBES THE DCB/DEB AREA.                                35350000
*                                                                       35400000
DCBAREA  DSECT                                                          35450000
         DS    6F                 DCB AREA FILLER.                      35500000
AREA     DS    0F                 WORK AREA REFERENCE.                  35550000
NMBYTES  DS    F                  NUMBER OF BYTES.                      35600000
DSCBTRK  DS    F                  CC HH OF SYSCTLG DSCB.                35650000
CATWAP   DS    1F                 CURRENT VOL SER NO. FOR LOCATE.       35700000
         DS    1F                 FILLER                                35750000
DEB      DS    0F                 START OF THE DEB.                     35800000
DEBTCBAD DS    F                  TCB ADDRESS.                          35850000
DEBAMIND DS    0X                 AM INDICATOR.                         35900000
DEBDEBAD DS    F                  NEXT DEB ADDRESS.                     35950000
         DS    2F                 IRB AND SYS PURGE CHAIN.              36000000
DEBNMEXT DS    0X                 NO OF EXTENTS.                        36050000
         DS    2F                 USER PURGE AND PURGE ECB ADDR.        36100000
DEBDCBAD DS    F                  DCB ADDRESS.                          36150000
DEBAPPAD DS    F                  APPENDAGE VECTOR TABLE ADDRESS.       36200000
DEBDVMOD DS    0X                 DEBICE MODIFIER MASK.                 36250000
DEBUCBAD DS    F                  UCB ADDRESS.                          36300000
DEBBINUM DS    H                  BIN NUMBER.                           36350000
DEBSTRCH DS    0CL8               START/END CCHH.                       36400000
DEBSTRCC DS    H                  START CYLINDER.                       36450000
DEBSTRHH DS    H                  START HEAD.                           36500000
DEBENDCC DS    H                  END CYLINDER.                         36550000
DEBENDHH DS    H                  END HEAD.                             36600000
DEBNMTRK DS    H                  NUMBER OF TRACKS.                     36650000
EXTL     EQU   16                 LENGTH OF AN EXTENT ENTRY.            36700000
MAXEL    EQU   256                MAXIMUM EXTENT AREA LENGTH.           36750000
DEBEND   EQU   *                                                        36800000
DEBL     EQU   DEBEND-DEB         DEB LENGTH.                           36850000
         EJECT                                                          36900000
*                                                                       36950000
* FORMAT 4 DSCB DEFINITION.                                             37000000
*                                                                       37050000
         SPACE                                                          37100000
         IECSDSL1 (4)                                                   37150000
         ORG   IECSDSF4+48        ORG TO CCW AREA.                      37200000
CHPG     DS    6D                 CHANNEL PROGRAM RELOCATE AREA.        37250000
CHPGA    DS    4D                 CHANNEL PROGRAM RELOCATE AREA.        37300000
AECB     DS    F                  EVENT CONTROL BLOCK.                  37350000
AIOB     DS    8F                 I/O CONTROL BLOCK.                    37400000
MBBCCHHR DS    CL8                SEEK ADDRESS IN THE IOB.              37450000
CCHHR    EQU   MBBCCHHR+3         CHANNEL-HEAD ADDRESS.                 37500000
CCHHRL   EQU   5                  LENGTH OF CCHHR.                      37550000
DSCBK    DS    CL44               DATA SET NAME AREA.                   37600000
DSCBK4   EQU   DSCBK+4            FOUR BYTES OFF DSCBK                  37650000
DSCBD    EQU   DSCBK+44           FOURTY FOUR BYTES OFF DSCBK           37700000
*                                                                       37750000
* FORMAT 1 DSCB DEFINITION.                                             37800000
*                                                                       37850000
         SPACE                                                          37900000
         ORG   DSCBK              ORG COUNT AREA.                       37950000
         IECSDSL1 (1)                                                   38000000
COUNT    DS    CL8                SYSCTLG DSCB DISK ADDR/               38050000
COUNTA   EQU   COUNT+4                                                  38100000
*                                 WORKAREA FOR CONVERT ROUTINE.         38150000
REGSAVE  DS    1F                 REGISTER SAVE AREA                    38200000
REGS2    DS    1F                 REGISTER SAVE AREA.                   38250000
REGS3    DS    1F                 REGISTER SAVE AREA                    38300000
REGS4    DS    1F                 REGISTER SAVE AREA.                   38350000
REGS5    DS    1F                 REGISTER SAVE AREA.                   38400000
REGS6    DS    1F                 REGISTER SAVE AREA.                   38450000
NUMUCB   DS    H                  NUMBER OF UCB'S.                      38500000
SWL      EQU   6                  LENGTH OF SWITCH AREA.                38550000
FMTSW    DS    X                  COUNT OF BLOCK TRACK.                 38600000
EXTDSW   DS    X                  EXTEND COUNTER.                       38650000
EXTDTT   DS    F                  RELATIVE TRACK ADDRESS.               38700000
AREAEND  DS    0D                 USED TO DETERMINE NUMBER BYTES.       38750000
EXTDRGSV DS    2F                 REGISTER SAVE AREA.                   38800000
*                                                                       38850000
* EXTEND WORK AREA DEFINITION.                                          38900000
*                                                                       38950000
         ORG   AREA               ORG TO EXTEND AREA.                   39000000
EXTDAREA DS    0F                                                       39050000
         IECDSECT                                                       39100000
         EJECT                                                          39150000
*                                                                       39200000
* THIS IS THE UCB DEFINITION DSECT.                                     39250000
*                                                                       39300000
         SPACE                                                          39350000
UCB      DSECT                                                          39400000
         IEFUCBOB                                                       39450000
         EJECT                                                          39500000
*                                                                       39550000
* THIS IS THE DSECT FOR THE COMMUNICATION VECTOR TABLE.                 39600000
*                                                                       39650000
         SPACE                                                          39700000
CVT      DSECT                                                          39750000
         CVT   SYS=MIN                                                  39800000
         EJECT                                                          39850000
*                                                                       39900000
* THE FOLLOWING IS THE DSECT USED BY THE CATALOG ROUTINES.  IT IS       39950000
* USED BY THE OPEN MODULE TO HANDLE END OF EXTENT PROCESSING FOR        40000000
* THE CATALOG MODULES.                                                  40050000
*                                                                       40100000
         SPACE                                                          40150000
WORKAREA DSECT                                                          40200000
BLDLIST  DS    F                       BEGINNING OF BLDL PARM LIST      40250000
SAVETTR3 EQU   BLDLIST                 TEMPORARY TTR SAVE               40300000
NAMTTR0  DS    0XL12                   CURRENT LEVEL NAME, TTR, TYPE    40350000
NAMTTR   DS    0XL11                   CURRENT LEVEL NAME, TYPE         40400000
NAME     DS    0CL8                    CURRENT LEVEL NAME               40450000
         DS    CL1                     CHAR 'G' FOR GDG NAME            40500000
GENNO    DS    CL4                     GENERATION NUMBER                40550000
         DS    CL3                     VERSION NUMBER                   40600000
ALIASNAM EQU   NAME                    ALIAS NAME                       40650000
TTR0     DS    0XL4                    TTR & TYPE                       40700000
TTR      DS    XL3                     TTR TO NEXT LEVEL OR DSCB TTR    40750000
TYPE     DS    XL1                     TYPE OF CATALOG ENTRY            40800000
TRUE     DS    0XL8                    TRUE NAME FOR ALIAS ENTRY        40850000
VOLCNT   DS    0XL2                    VOLUME COUNT FOR DSPE ENTRY      40900000
DATA     DS    XL62                    DATA (USUALLY VOL INFORMATION)   40950000
         DS    2F                      FILLER                           41000000
*                                                                       41050000
         ORG   TYPE                    DATA RETURNED FROM BLDL          41100000
         DS    XL2                     ZERO                             41150000
TYPEB    DS    XL1                     TYPE OF CAT ENTRY                41200000
TRUEB    DS    0XL8                    TRUE NAME LOCATED                41250000
VOLCNTB  DS    0XL2                    VOLUME COUNT LOCATED             41300000
DATAB    DS    XL62                    DATA LOCATED                     41350000
*                                                                       41400000
         ORG   VOLCNT                                                   41450000
DSNAME   DS    CL44                    FULL DSN FOR SCRATCH             41500000
SCRPARM  DS    3F                      SCRATCH PARAMETERS               41550000
SCRVOLS  DS    F                       VOLUMES FOR SCRATCH              41600000
*                                                                       41650000
         ORG   DATA+16                                                  41700000
NAMTABLE EQU   *                       EACH LEVEL OF NAME HAS AN ENTRY  41750000
*                                      COMPOSED OF DISP. FROM BEGINNING 41800000
*                                      AND LENGTH OF LEVEL MINUS 1      41850000
         DS    XL1'00'                 DISPLACEMENT FOR FIRST LEVEL     41900000
NAMLEN1  DS    XL1                     LENGTH OF NAME MINUS 1 FOR       41950000
*                                      FIRST LEVEL                      42000000
NAMDISP2 DS    XL1                     DISPLACEMENT FOR SECOND LEVEL    42050000
NAMLEN2  DS    XL1                     LEN-1 SECOND LEVEL               42100000
         DS    XL40                    REMAINING LEVEL NAME ENTRIES     42150000
NAMDELIM DS    XL1                     LAST DELIM IN NAME-- ' ' OR '('  42200000
*                                                                       42250000
         ORG                                                            42300000
ERRCODE  DS    0XL2                    ERROR CODES                      42350000
ERRCATSV DS    XL1                     NON-LOCATE ERROR CODE            42400000
ERRLOCSV DS    XL1                     LOCATE ERROR CODE                42450000
ERFLAG12 DS    0XL2                    FLAG1 AND FLAG2 FOR ENVIR REC    42500000
FLAG1    DS    XL1                     SEE BELOW                        42550000
RECATF   EQU   X'01'                   INDIC RECAT                      42600000
LOCATEF  EQU   X'02'                   INDIC LOCATE                     42650000
UCATDXF  EQU   X'04'                   INDIC UCATDX                     42700000
UCATDXFC EQU   X'FF'-UCATDXF           TURN UCATDX OFF TO UNCAT ONLY    42750000
CATBXF   EQU   X'08'                   INDIC CATBX                      42800000
CATBXFC  EQU   X'FF'-CATBXF            TURN CATBX OFF TO CAT ONLY       42850000
FREEDCB  EQU   X'10'                   INDIC SVC 28 FREED DCB           42900000
ERRFULL  EQU   X'20'                   CATLG FULL DURING CATBX OR BLDX  42950000
READICEF EQU   X'40'                   INDIC ICE MUST BE READ           43000000
RTNBLK   EQU   X'80'                   INDIC NEED TO RETURN BLK         43050000
FLAG2    DS    XL1                     SEE BELOW                        43100000
ALIASBLT EQU   X'01'                   INDIC ALIAS ENTRY IS BUILT       43150000
GDGSW    EQU   X'02'                   INDIC GIPE IS FOUND              43200000
CVOLF    EQU   X'04'                   INDIC LAST ENTRY FOUND IS CVPE   43250000
CVOLFC   EQU   X'FF'-CVOLF             TURN OFF CVOL FLAG               43300000
RPSDEV   EQU   X'20'                   INDIC CATALOG IS ON RPS DEVICE   43350000
         DS    0F                      ALIGN ON WORD BOUNDARY           43400000
SAVEAREA DS    XL28                    REGISTER SAVE AREA               43450000
*                                                                       43500000
         ORG   SAVEAREA                                                 43550000
SVAREA4  DS    XL16                    4 WORD SAVE AREA                 43600000
*                                                                       43650000
         ORG   SAVEAREA                                                 43700000
SVAREA5  DS    XL20                    5 WORD SAVE AREA                 43750000
SVAREA2X DS    XL8                     2 WORD SAVE AREA (AT END)        43800000
*                                                                       43850000
         ORG   SAVEAREA                                                 43900000
SVAREA6  DS    XL24                    6 WORD SAVE AREA                 43950000
TEMPBUFF EQU   SVAREA6                 INPUT BUFFER FOR ICE AND VICE    44000000
*                                                                       44050000
         ORG   TEMPBUFF                                                 44100000
LSTBLK   DS    XL3                     '.LSTBLK' FIELD OF ICE OR VICE   44150000
         DS    XL1                     TYPE FIELD                       44200000
FSTBLK   DS    XL3                     FST BLK OF LO LEV OR VOL INDEX   44250000
*                                                                       44300000
         ORG   SAVEAREA                                                 44350000
SVAREA7  DS    XL28                    7 WORD SAVE AREA                 44400000
NEXTCNT  DS    0XL8                    COUNT FIELD OF NEXT FREE BLK     44450000
NXTCCHHR DS    XL5                     CCHHR OF NEXT FREE BLK           44500000
         DS    XL3                     KEY AND DATA LENGTH              44550000
NEXTKEY  EQU   NEXTCNT                 KEY FIELD FOLLOWING BLK JUST RD  44600000
***************************************                                 44650000
         DS    0F                      ALIGN ON A FULL WORD             44700000
ICE      DS    0XL18                   PERTINENT INDEX CONTROL ENTRY    44750000
INAME    DS    0XL8                    NAME FIELD                       44800000
ICEPERT  DS    0XL8                    PERTINENT PORTION OF ICE         44850000
ILSTBLK  DS    XL3                     LAST BLOCK IN THIS INDEX         44900000
ITYPE    DC    XL1'03'                 TYPE FIELD                       44950000
IFSTBLK  DS    XL3                     TTR OF THIS BLOCK                45000000
ILIASCNT DS    XL1                     ALIAS COUNT                      45050000
         DS    0XL2                    ZERO                             45100000
***************************************                                 45150000
VICE     DS    0XL22                   VOLUME INDEX CONTROL ENTRY       45200000
VNAME    DS    0XL8                    NAME FIELD                       45250000
VICEPERT DS    0XL12                   PERTINENT PORTION OF VICE        45300000
VLSTBLK  DS    XL3                     TTR OF LAST BLOCK IN VOL INDEX   45350000
VTYPE    DC    XL1'05'                 TYPE FIELD                       45400000
VCLSTBLK DS    0XL3                    LAST BLOCK IN CATALOG DATA SET   45450000
         DS    XL2                     TT OF LAST BLK                   45500000
VHIREC   DS    XL1                     NUMBER OF RECORDS ON A TRACK     45550000
ZERO     DC    XL1'00'                 CONSTANT                         45600000
VSAVE    DS    0XL3                    SAVED PORTION OF VICE            45650000
VFHOLE   DS    XL3                     FIRST KEY = ZERO IN CATALOG      45700000
         DC    XL1'00'                 ZERO                             45750000
         DS    0XL2                    ZERO                             45800000
***************************************                                 45850000
UCATNAM  EQU   VNAME                   LEVEL NAME TO BE REMOVED(UCATDX) 45900000
*                                                                       45950000
         ORG   ICE                                                      46000000
RELNUMBR DS    D                       EBCDIC OF REL GDG NUMBER         46050000
PKDNUMBR DS    D                       PACKED EQUIVALENT OF 'RELNUMBR'  46100000
*                                                                       46150000
         ORG                                                            46200000
FLAG3    DS    XL1                     SERVICES PERFORMED BY IGG0CLC5   46250000
WRBLK    EQU   X'01'                   INDIC BLOCK TO BE WRITTEN        46300000
FRVCB    EQU   X'02'                   INDIC VCB CHAIN TO BE FREED      46350000
BLVCB    EQU   X'04'                   INDIC VCB CHAIN TO BE BUILT      46400000
WRLST    EQU   X'08'                   INDIC LAST BLK OF GDG TO BE WRIT 46450000
EMPTY    EQU   X'10'                   INDIC GDG TO BE EMPTIED          46500000
NEEDBLK  EQU   X'20'                   INDIC NEED TO READ BLK FOR UPDAT 46550000
FRBLK    EQU   X'40'                   INDIC BLOCK TO BE FREED          46600000
GDS      EQU   X'80'                   INDIC GXXXXV00 IS 'NAME' FORMAT  46650000
FLAG4    DS    XL1                     FLOW CONTROL IN IGG0CLC6         46700000
CONTIGL  EQU   X'01'                   INDIC FREE BLK FOLLOWS LINKTTR   46750000
CONTIGLC EQU   X'FF'-CONTIGL           TURN OFF CONTIGL                 46800000
CONTIGW  EQU   X'10'                   INDIC FREE BLK FOLLOWS WRITETTR  46850000
CONTIGWC EQU   X'FF'-CONTIGW           TURN OFF CONTIGW                 46900000
CONTIGC  EQU   X'FF'-CONTIGL-CONTIGW   TURN OFF CONTIGW AND CONTIGL     46950000
UPDATING EQU   X'80'                   INDIC UPDATE IN PROCESS          47000000
UPDATED  EQU   X'40'                   INDIC UPDATE IS COMPLETE         47050000
COMPLETE EQU   UPDATING+UPDATED        USED IN AN XI INSTRUCTION        47100000
*                                           TO TURN UPDATING OFF AND    47150000
*                                           UPDATED ON                  47200000
WROTE    EQU   X'02'                   TURNED ON AT FIRST WRITE         47250000
STOP     EQU   UPDATED+WROTE           USED AS A MASK. WHEN RESULT IS   47300000
*                                           MIXED, OK TO STOP UPDATE.   47350000
*                                           (UPDATED IS ON & WROTE IS   47400000
*                                           OFF)                        47450000
NAMLEN   DS    H                       (LENGTH-1) OF FULL NAME          47500000
         DS    0F                      ALIGN ON WORD BDY                47550000
NAMDELMP DS    F                       LAST DELIM IN NAME               47600000
NAMLSTP  DS    F                       LAST DISPL OF NAME IN TABLE      47650000
         DS    XL1                     *RESERVED*                       47700000
FLAG5    DS    XL1                     FLOW CONTROL IN IGG0CLC7         47750000
FST      EQU   X'01'                   INDIC '.FSTBLK' NEEDS UPDATE     47800000
LST      EQU   X'02'                   INDIC '.LSTBLK' NEEDS UPDATE     47850000
VFH      EQU   X'04'                   INDIC 'VFHOLE' NEEDS UPDATE      47900000
LIN      EQU   X'08'                   INDIC LOW LEVEL IS INVOLVED      47950000
MODMAP1  DS    XL1                     MODULE MAP BYTE                  48000000
MODCLC1  EQU   X'80'                   INDICATE ENTRY TO IGG0CLC1       48050000
MODCLC2  EQU   X'40'                   INDICATE ENTRY TO IGG0CLC2       48100000
MODCLC3  EQU   X'20'                   INDICATE ENTRY TO IGG0CLC3       48150000
MODCLC4  EQU   X'10'                   INDICATE ENTRY TO IGG0CLC4       48200000
MODCLC5  EQU   X'08'                   INDICATE ENTRY TO IGG0CLC5       48250000
MODCLC6  EQU   X'04'                   INDICATE ENTRY TO IGG0CLC6       48300000
MODCLC7  EQU   X'02'                   INDICATE ENTRY TO IGG0CLC7       48350000
         DS    0F                      ALIGN ON WORD BOUNDARY           48400000
BLDLPARM DS    0XL12                   INPUT PARAMETERS TO IECPBLDL     48450000
EPBLDL   DS    F                       ENTRY POINT TO IECPBLDL          48500000
BLDLISTP DS    F                       POINTS TO BLDL PARM LIST         48550000
PTRS     DS    0XL12                   DCBADDR, DEBADDR, AND FOUNDENT   48600000
DCBADDR  DS    F                       DCB ADDRESS                      48650000
RPSAVEP  EQU   DCBADDR                 RPS WORKAREA POINTER             48700000
DEBADDR  DS    F                       DEB ADDRESS                      48750000
FOUNDENT DS    F                       POINTS TO FOUND ENTRY IN BLOCK   48800000
CONVERTS DS    0XL8                    CONVERT ENRTY POINTS             48850000
EPTORLTV DS    F                       ENTRY POINT TO IECPRLTV          48900000
EPTOABSL DS    F                       ENTRY POINT TO IECPCNVT          48950000
SVRBEXTP DS    F                       PTR TO SVRB EXTENTED SAVE AREA   49000000
ADDING   DS    F                       PTR SAVE WHILE MOVING NEW ENTRY  49050000
UCATICE  EQU   ADDING                  TTR OF ICE OF BLOCK TO BE UPDTD  49100000
*                                      FOR UCATDX FCN, C2, C3           49150000
         DS    0D                      ALIGN ON DOUBLE WORD             49200000
XCTLPARM DS    0XL16                   XCTL PARAMETERS                  49250000
XCTLPTR  DS    1F                      POINTS TO MODULE NAME            49300000
         DS    1F                      ZERO                             49350000
XCTLNAME DS    XL8                     MODULE NAME (IGG0CLCX)           49400000
XCTLNUMB EQU   XCTLNAME+7              XCTL NO. (1, 2, 3, 4, 5, 6, 7)   49450000
         DS    0F                      ALIGN ON WORD BOUNDARY           49500000
LNKENTRY DS    0XL12                   LINK ENTRY                       49550000
HIBIN    DC    XL8'FFFFFFFFFFFFFFFF'   HIGH BINARY NUMBER               49600000
MASKFF   EQU   HIBIN                   USED TO COMPLEMENT GDG NO.       49650000
ERTTRS   DS    0XL28                   FOR ENVIRONMENT RECORD           49700000
TTRS     DS    0XL12                   TTRS FOR ZEROING                 49750000
LINKTTR  DS    F                       LINK TTR                         49800000
WRITETTR DS    F                       TTR TO WRITE BLK                 49850000
VCBTTR   EQU   LINKTTR                 VCB TTR                          49900000
DELTTR3  DS    F                       FIRST DELETABLE VCB              49950000
EXCLUDE  EQU   DELTTR3                 BLOCK LEFT OUT OF CHAIN UPDATE   50000000
ICETTR   DS    F                       TTR TO CURRENT ICE               50050000
DELTTR1  DS    F                       TTR OF BLK TO DELETE             50100000
SAVETTR  EQU   DELTTR1                 TEMPORARY SAVE FOR A TTR         50150000
READTTR  DS    F                       TTR OF BLK TO READ               50200000
NAMLF    DS    H                       NUMBER OF LEVELS IN NAME FOUND   50250000
NAMLG    DS    H                       NUMBER OF LEVELS IN NAME GIVEN   50300000
DEVOL    DS    0XL13                   SEE BELOW                        50350000
DEVTYPE  DS    XL4                     DEVICE TYPE FOR CURRENT SYSCTLG  50400000
THETA    DS    XL1                     RPS THETA VALUE                  50450000
INDEXLEN DS    XL1                     LENGTH OF ALL LEVELS GIVEN       50500000
*                                      EXCEPT LAST. USED FOR SCRATCH    50550000
ERRSV2H  DS    XL1                     TEMP STORAGE FOR SVC 28 ERROR    50600000
VOLSN    DS    CL6                     VOL SER OF CURRENT SYSCTLG       50650000
         ORG   WORKAREA                                                 50700000
RETDATA  DS    0XL256                  AREA FOR RETURNED DATA           50750000
         DS    XL242                   VOLUME LIST                      50800000
         DC    XL10'00'                ALWAYS ZERO FOR VCB              50850000
RETDSCBT DS    0XL4                    TTR OF THE DATA SET'S DSCB       50900000
RETVCBLK DS    XL3                     VCB LINK TTR                     50950000
         DS    XL1                     ZERO                             51000000
RETDVTYP EQU   RETDSCBT                DEVICE TYPE OF THE CVOL          51050000
         DS    XL3                     FILLER                           51100000
RETCVOL  DS    CL6                     VOLUME SERIAL OF THE CVOL        51150000
         ORG                                                            51200000
*                                                                       51250000
*********************************************************************** 51300000
VICESAVE DS    XL3                       VICE SAVEAREA                  51350000
BALREGS  DS    F                         SAVE ONE BALREG                51400000
*********************************************************************** 51450000
*                                                                       51500000
BLDLAREA DS    50D                       BLDL WORKAREA                  51550000
BLDLEND  EQU   *                                                        51600000
*                                                                       51650000
*                                                                       51700000
         ORG   BLDLAREA                                                 51750000
BLDLBUFF DS    XL256                   BLDL BUFFER                      51800000
BLDLCNT  DS    XL5                     CCHHR OF BLK READ BY BLDL        51850000
         DS    XL3                     KEY AND DATA LEN OF BLK          51900000
BLDLCCWS DS    6D                      BLDL CCWS                        51950000
BLDLECB  DS    F                       BLDL ECB                         52000000
BLDLIOB  DS    8F                      BLDL IOB                         52050000
BLDLMBB  DS    XL3                     IOB MBB                          52100000
BLDLCHR  DS    XL5                     IOB CCHHR                        52150000
BLDLCONS DS    5F                      BLDL CONSTANTS                   52200000
BASESAVE DS    1F                      BASE OF CATALOG WA               52250000
*                                                                       52300000
         ORG   BLDLCCWS                                                 52350000
RESALIAS DS    CL44                    SAVE AREA FOR GIVEN ALIAS NAME   52400000
*                                                                       52450000
         ORG   BLDLAREA                                                 52500000
INPUT    DS    0XL256                  INPUT BUFFER                     52550000
TRTABLE  EQU   INPUT                   TRT TABLE                        52600000
INDATA   DS    0XL256                  DESCRIBES INPUT DATA BLK         52650000
INBYTSU  DS    XL2                     INPUT, BYTES USED FIELD          52700000
INENTRY  DS    XL254                   INPUT, ENTRY DATA                52750000
CHPROG   DS    0D                      CHANNEL PROG--ALIGN ON DBLE WD   52800000
CCWFRST5 DS    0XL40                   FIRST 5 CCWS                     52850000
SIDE1    DS    1D                      SEARCH ID EQUAL CCW              52900000
TIC1     DS    1D                      TIC TO ABOVE CCW (SIDE1)         52950000
ERCCWL   DS    0CL16                   ER CCWS RELOCATION               53000000
OPTNCCW  DS    1D                      OPTION CCW                       53050000
RC       DS    1D                      READ COUNT CCW                   53100000
RCOP     EQU   X'92'                   READ COUNT OP CODE               53150000
SKE      DS    1D                      SEARCH KEY EQUAL CCW             53200000
CCWSEC2  DS    0XL16                   LAST TWO CCWS                    53250000
TIC2     DS    1D                      TIC TO RC CCW                    53300000
NOP      DS    1D                      NOP CCW                          53350000
ECB      DS    F                       ECB (BUILT BY BLDL)              53400000
IOB      DS    0XL40                   IOB (SEE BELOW)                  53450000
         DS    F                       FIRST WORD OF IOB                53500000
IOBECB   DS    F                       ECB CODE AND ADDRESS             53550000
         DS    2F                      CSW                              53600000
IOBCHPR  DS    F                       POINTER TO CHANNEL PROG.         53650000
IOBDCB   DS    F                       POINTER TO DCB                   53700000
         DS    2F                      SYSTEM USE                       53750000
IOBSKADD DS    2F                      SEEK ADDRESS (MBBCCHHR)          53800000
CCWLST3  DS    0XL24                   PART OF CCW POOL                 53850000
RKD      DS    XL8                     READ KEY AND DATA CCW            53900000
RKDOP    EQU   X'0E'                   READ KEY AND DATA OP CODE        53950000
RD       DS    XL8                     READ DATA CCW                    54000000
RDOP     EQU   X'06'                   READ DATA OP CODE                54050000
WKD      DS    XL8                     WRITE KEY AND DATA CCW           54100000
WKDOP    EQU   X'0D'                   WRITE KEY AND DATA OP CODE       54150000
WDOP     EQU   X'05'                   WRITE DATA OP CODE               54200000
OUTPUT   DS    0XL264                  OUTPUT BUFFER                    54250000
OUTKEY   DS    XL8                     KEY FIELD OF BUFFER              54300000
OUTDATA  DS    0XL256                  DATA FIELD OF BUFFER             54350000
OUTBYTSU DS    XL2                     OUTPUT, BYTES USED FIELD         54400000
OUTENTRY DS    XL254                   OUTPUT, ENTRY DATA               54450000
OUTLKLMT EQU   OUTENTRY+242            LAST POSSIBLE LOCATION FOR ENTRY 54500000
*                                                                       54550000
         ORG   OUTENTRY                                                 54600000
OUTICE   DS    0CL18                   ***ICE***                        54650000
         DS    CL8                     ICE NAME                         54700000
OUTILBLK DS    CL3                     LAST BLK IN THIS INDEX           54750000
OUTICECD DC    XL1'03'                 TYPE FIELD                       54800000
OUTILL   DS    CL3                     TTR OF THIS BLOCK                54850000
         DC    XL3'00'                 ZERO                             54900000
         ORG                                                            54950000
*                                                                       55000000
*                                                                       55050000
WORKEND  EQU   *                       END LABEL                        55100000
*                                                                       55150000
         EJECT                                                          55200000
         DS    0D                      ALIGN ON DOUBLE WORD             55250000
RPSD     DSECT                                                          55300000
RPSCCW   DS    0XL16                   RPS CCWS                         55350000
RPSSS    DS    1D                      SET SECTOR CCW                   55400000
RPSTIC   DS    1D                      TICS TO NORMAL CHANNEL PROGRAM   55450000
RPSINPUT DS    0XL16                   INPUT PARAMETERS                 55500000
RPSCNVT  DS    1F                      SECTOR VALUE CONVERT ROUTINE     55550000
*                                           ADDR                        55600000
RPSDDKR  DS    1F                      DD=BLOCKSIZE=256, K=KEY LENGTH=  55650000
*                                           8, R=RECORD NUMBER          55700000
RPSR1    DS    1F                      ADDRESS OF THIS DSECT SINCE IT   55750000
*                                           IS BASED ON R1              55800000
RPSPTR   DS    1F                      DEVTYP CODE & PTR TO SECTOR VAL  55850000
RPSAVE   DS    10F                     REGISTER SAVE AREA               55900000
*                                                                       55950000
*                                                                       56000000
RPSEND   EQU   *                       RPS END LABEL                    56050000
*                                                                       56100000
         END                                                            56150000
