906H     TITLE 'IGC0906H - SYNADAF SECONDARY LOAD'                      00100021
         COPY  LCGASMSW                 DETERMINE SYSTEM         X03962 00100221
IGC0906H CSECT                                                   X03962 00200021
*          RELEASE 21 DELETIONS                                         00400020
*1036298000                                                      M0827  00420021
*1036380000                                                      A45619 00450021
*1036198000,204000                                               A44437 00500021
*                                                                A34969 00600020
*        RELEASE 21.7 CHANGES                                           00610021
*                                                               SA53858 00650021
*                                                                SM5476 00700021
*        VS1 RELEASE 2.6 CHANGES                                        00710021
*                                                                XM1552 00750002
*        RELEASE 21.8 CHANGES                                           00750221
*  APAR 68815 BACKS OUT APAR 58037 (FROM REL. 21.7 AND FLAGGED AS       00750421
*  SM5476) AND 65028  (REL. 21.8), WHICH WERE MEANT TO SUPPORT 37507    00750621
*  (REL. 21.0),  WHICH WAS BACKED OUT IN RELEASE 21.8 BY APAR 62466.    00750821
*D208500,446500-447700                                          SA68815 00750921
*C316000                                                         X03962 00751021
*D498000,530500-531000,638000-640000,680000,690000               X03962 00751221
*                                                                       00757121
*        VS1 RELEASE 3.1 CHANGES                                        00763621
*  XA04282 IS FLAGGED AS SA68815.                               XA04282 00775421
*  XA04282 BACKS OUT APAR 00367 (FROM VS1 REL. 2.6) AND XM1552          00781321
*  (REL. 2.6), WHICH WERE MEANT TO SUPPORT REL. 1 CODE WHICH            00787221
*  WAS BACKED OUT IN RELEASE 3.0 BY APAR 02335.                         00793121
*                                                                       00793221
         SPACE 1                                                        00799021
*STATUS CHANGE LEVEL 004                                                00800021
         SPACE                                                          01000020
*********************************************************************** 01200020
*                            SVC 68                                   * 01400020
*                                                                     * 01600020
*                 SYNAD ANALYZE AND FORMAT SVC                        * 01800020
*                                                                     * 02000020
*                 SECONDARY INITIAL LOAD                              * 02200020
*                                                                     * 02400020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 02600020
*                                                                     * 02800020
* FUNCTION - THIS MODULE IS SPLIT FROM IGC0006H.  IT CONTINUES THE    * 03000020
*     GENERALIZED ANALYSIS OF AN ERROR FOR BDAM, QSAM, BPAM, AND BSAM.* 03200021
*                                                                     * 03400020
* ENTRY POINT - IGC0906H   CONTROL IS TRANSFERED (XCTL) FROM          * 03600020
*     IGC0006H.                                                       * 03800020
*                                                                     * 03810021
* ATTRIBUTES - REENTRANT,ENABLED,REFRESHABLE,SUPERVISOR STATE,KEY ZERO* 03820021
*              OPERATES IN SVC TRANSIENT AREA                         * 03830021
*                                                                     * 04000020
* INPUT PARAMETERS - REGISTERS AS PASSED BY IGC0006H, AND ADDRESS OF  * 04200020
*     REGISTER SAVE AREA AND A 136 BYTE MESSAGE BUFFER.               * 04400020
*                                                                     * 04600020
* EXITS -                                                             * 04800020
*        NORMAL - XCTL TO IGC0106H FOR BPAM, BDAM, BSAM AND QSAM      * 05000020
*                 XCTL TO IGC0206H FOR BDAM IF NO IOB                 * 05010021
*                 XCTL TO IGC0606H FOR OCR BSAM AND QSAM              * 05200020
*                 XCTL TO IGC0406H FOR TCAM                           * 05400020
*        ERROR -  SVC 3 TO PROBLEM PROGRAM                            * 05600021
*                                                                     * 05800020
*        OUTPUT PARAMETERS - REG. 13, ADJUSTED SAVE AREA POINTER.     * 06000020
*                            REG. 15, RETURNED UNCHANGED TO CALLER    * 06010021
*                            REG.  1, POINTER TO 136 BYTE BUFFER.     * 06200020
*                            REG.  0, RETURN CODE                     * 06400020
*              RETURN CODES- 0 = PROCESSED SUCCESSFULLY               * 06600020
*                            4 = PROCESSED SUCCESSFULLY, READ I/O     * 06800020
*                                 ERROR                               * 07000020
*                            8 = ERROR ENCOUNTERED, COULD NOT PROCEDE * 07200020
*                                                                     * 07400020
*********************************************************************** 07600020
*                                                                       07800020
*********************************************************************** 08200020
*                                                                     * 08400020
*        REGISTER EQUATES                                             * 08600020
*                                                                     * 08800020
*********************************************************************** 09000020
RGZ      EQU   0                       COMPLETION CODE                  09200020
COREREG  EQU   1                       BASE REG FOR MESSAGE BUFFER      09400020
LNKRG1   EQU   2                       LINK REGISTER                    09600020
CVTREG   EQU   3                       CVT POINTER                      09800020
TCBREG   EQU   4                       TCB POINTER                      10000020
SVRBREG  EQU   5                       SVRB POINTER                     10200020
IOBREG   EQU   6                       IOB POINTER                      10400020
DCBREG   EQU   7                       DCB POINTER                      10600020
DEBREG   EQU   8                       DEB POINTER                      10800020
UCBREG   EQU   9                       UCB POINTER                      11000020
CHECKER  EQU   10                      ADDRESS OF CHECK ROUTINE         11200020
CKREG    EQU   11                      CHECK REGISTER                   11400020
BASREG   EQU   12                      BASE REGISTER                    11600020
WK1      EQU   13                      WORK                             11800020
WK2      EQU   14                       REGISTERS                       12000020
RGF      EQU   15                      USER'S RETURN ADDRESS            12200020
*********************************************************************** 12400020
         EJECT                                                          12600020
*                                                                     * 12800020
*        EQUATES                                                      * 13000020
*                                                                     * 13200020
*********************************************************************** 13400020
CHAIN    EQU   61                      DISPLACEMENT IN DCB FOR CHAIN    13600020
*                                       SCHEDULING INDICATOR     A34969 13800020
CHAINIOB EQU   28                CHAINING IOB OFFSET IN DCB      A34969 14000020
CVTMZ00  EQU   164                     MAXLOC IN CORE-OFFSET IN CVT     14200020
DCBDEB   EQU   44                      DISP IN DCB FOR DEB ADDRESS      14400020
DCBIOB   EQU   68                      DISP IN DCB FOR IOB ADDRESS      14600020
DCBTIOT  EQU   40                      TITOT OFFSET IN DCB (HALFWORD)   14800020
DEBENT   EQU   16                      SIZE OF AREA FOR DEB EXTENT      15000020
DEBEXT   EQU   28                      EXTENT SCALE                     15200020
DEBUCB   EQU   32                      DISP IN DEB FOR UCB ADDRESS      15400020
DEVTYPE  EQU   17                      DISP TO DEVICE TYPE IN DCB       15600020
EXTMSK   EQU   X'FE'                   NUMBER OF EXTENTS INDICATOR      15800020
FOUR     EQU   C'4'                    LOAD ID FOR IGC0406H             16000020
GETREAD  EQU   X'80'                   READ OP CODE INDICATOR           16200020
GOOD     EQU   X'7F'                   NORMAL COMPLETION                16400020
INCR     EQU   40                      MAX OFFSET FOR INSPECT OF CORE   16600020
IOBCOD   EQU   4                       SAM IOB POST CODE                16800020
IOBCSW   EQU   8                       DISP IN IOB TO CSW               17000020
IOBDAM   EQU   32                      DISP IN IOB TO SPECIAL SEEK ADDR 17200020
IOBNXT   EQU   0                       DISP IN IOB TO IOB LINK FIELD    17400020
IOERR    EQU   X'41'                   I/O ERROR INDICATOR              17600020
MICRIOB  EQU   X'1C'                   DISP TO MICR IOB ADDR            17800020
MICRTYPE EQU   X'5D'                   MICR DEVICE TYPE INDICATOR       18000020
NVCNTL   EQU   X'20'                   CONTROL INDICATOR                18200020
OC1      EQU   X'1A'                   OCR TYPE 1 MASK                  18400020
OC2      EQU   X'1C'                   OCR TYPE 2 MASK                  18600020
OCR3886  EQU   X'17'                   UCB DEVTYPE FOR 3886 OCR XL03127 18650000
ONE      EQU   C'1'                    LOAD ID FOR IGC0106H             18800020
OUT      EQU   3                       SVC - EXIT                       19000020
POINT    EQU   X'28'                   ILLOG BLOCK POINTER INDICATOR    19200020
PUTWRITE EQU   X'40'                   TYPE OF ERROR INDICATOR-REG 1    19400020
READDTA  EQU   X'10'                   READ ERROR INDICATOR             19600020
SIX      EQU   C'6'                    OCR LOAD IDENTIFICATION   A44437 19800021
TCBTIOT  EQU   12                      TITOT OFFSET IN TCB              20000020
TIOEQNAM EQU   X'08'                                                    20200020
TWO      EQU   C'2'                    BDAM LOAD IDENTIFICATION  A44437 20400021
UCBIDV   EQU   X'FF'                   VALIDITY CHECK FOR UCB           20800020
XCTL     EQU   7                       SVC 7 - XCTL                     21600020
X04      EQU   X'04'                   CHAIN SCHEDULING FLAG     A34969 21800020
         EJECT                                                          22000020
*********************************************************************** 22200020
*                                                                     * 22400020
*        EQUATES USED FOR DISPLACEMENT AND LENGTH CONSTANTS           * 22600020
*                                                                     * 22800020
*********************************************************************** 23000020
K0       EQU   0                       WORK AREA CONSTANT AND INDEX     23200020
K1       EQU   1                       WORK AREA CONSTANT               23400020
K2       EQU   2                       WORK AREA CONSTANT               23600020
K3       EQU   3                       WORK AREA CONSTANT               23800020
K4       EQU   4                       WORK AREA CONSTANT               24000020
K5       EQU   5                       WORKM AREA CONSTANT              24200020
K6       EQU   6                       WORK AREA CONSTANT               24400020
K8       EQU   8                       WORK AREA CONSTANT               24600020
K12      EQU   12                      WORK AREA CONSTANT               24800020
K16      EQU   16                      WORK AREA CONSTANT               25000020
K17      EQU   17                      WORK AREA CONSTANT               25200020
K18      EQU   18                      WORK AREA CONSTANT               25400020
K20      EQU   20                      WORK AREA CONSTANT               25600020
K72      EQU   72                      WORK AREA CONSTANT               26000020
         EJECT                                                          26200020
*   BEGINNING OF CODE                                                   26400021
         BALR  BASREG,RGZ                                               26600020
         USING *,BASREG                                                 26800020
         USING AREA+K72,CHECKER                                         27000020
         USING UCBOB,UCBREG                                     SA53858 27050021
         LM    IOBREG,CKREG,SAVE       RESTORE REGISTERS FROM LOAD 1    27200020
         LR    RGF,CKREG               RESTORE USERS BASE REGISTER      27400020
         LR    COREREG,CHECKER         RESTORE BUFFER AREA REGISTER     27600020
         DROP  CHECKER                                                  27800020
         USING AREA+K72,COREREG                                         28000020
         MVI   LOADSW,ONE              SET LOAD ID FOR IGC0106H         28200020
         LA    CHECKER,CHECK           LOAD CHECK ROUTINE ADDRESS       28400020
         MVC   START(K20),SKELETON     RESTORE MESSAGE SKELETON         28600020
*********************************************************************** 28610021
*    TEST WHICH ACCESS METHOD AND BRANCH TO APPROPRIATE ROUTINE.        28612021
*********************************************************************** 28620021
         CLC   ACCESSM(K5),BDAMS       IS ACCESS METHOD BDAM            28800020
         BE    BDAMSECT                YES - GO TO SET UP OPERATION     29000020
         CLC   ACCESSM(K5),BPAMS       IS ACCESS METHOD BPAM            29200020
         BE    DMCOM01                 YES - HANDLE LIKE BSAM           29400020
         CLC   ACCESSM(K5),QSAMS       IS ACCESS METHOD QSAM            29600020
         BNE   DMCOM01                 NO - MUST BE BSAM         M0827  29800021
         LA    WK2,DMLIST2             INIT AT TOP OF LIST FOR QSAM     30000020
         B     BSAMSECT                HANDLE LIKE BSAM                 30200020
BDAMSECT EQU   *                                                        30400020
         L     WK1,PARAMREG            POINT TO DECB                    30600020
         L     DCBREG,PARAMREG+K4      POINT TO DCB                     30800020
         CLC   K17(K3,WK1),ZERO        IS IOB PRESENT                   31000020
         BNE   BDAM01                  YES - BRANCH                     31200020
         MVI   LOADSW,TWO              NO - SET LOAD ID FOR IGC0206H    31400020
         B     GOXCTL                  GO XCTL TO FINISH MSG     X03962 31600021
BDAM01   EQU   *                                                        31800020
         L     CKREG,K16(WK1)          POINT TO IOB                     32000020
         LR    IOBREG,CKREG            SET IOBREG TEMPORARY             32200020
         SH    CKREG,EIGHT             ADJUST IOB POINTER               32400020
         BALR  LNKRG1,CHECKER          BOUNDARY CHECK                   32600020
         LR    WK1,CKREG               SAVE IOB ADDRESS                 32800020
         CLI   IOBCOD+K8(WK1),IOERR    IS IOB ECB CODE 41               33000020
         BE    BDAM02                  YES - LOAD MODIFIER IS OK        33200020
         MVI   LOADSW,TWO              NO - SET LOAD ID FOR IGC0206H    33400020
BDAM02   EQU   *                                                        33600020
         LA    WK2,DMLIST1             SET PTR TO TOP OF LIST           33800020
         LA    CKREG,K4(K0,IOBREG)     POINT TO ECB                     34000020
         B     DMCOM04B                GO TO SET OPERATION              34200020
DMCOM01  EQU   *                                                        34400020
         LA    WK2,DMLIST1             ADDRESS OF OPERATION LIST        34600020
         EJECT                                                          34800020
BSAMSECT EQU   *                                                        35000020
         L     DCBREG,PARAMREG+K4      GET DCB POINTER                  35200020
         LA    DCBREG,K0(DCBREG)       CLEAR HIGH ORDER BYTE            35400020
         L     WK1,TCBTIOT(K0,TCBREG)  TIOT ADDRESS                     35600020
         AH    WK1,DCBTIOT(K0,DCBREG)  TIOT ENTRY ADDRESS               35800020
         TM    K3(WK1),TIOEQNAM        TCAM DUMMY DATA SET              36000020
         BO    GOXCTL3                 YES - GO TO PROPER MODULE        36200020
         CLI   DEVTYPE(DCBREG),MICRTYPE DEVICE TYPE 1419        XL03123 36400000
         BNE   NOTMICR                 NO - BRANCH                      36600020
         L     WK1,MICRIOB(K0,DCBREG)  YES - LOAD IOB ADDRESS           36800020
         B     MICRIOBA                BRANCH TO GET NEXT IOB ADDR.     37000020
NOTMICR  EQU   *                                                 A34969 37200020
         TM    CHAIN(DCBREG),X04       CHAIN SCHEDULING USED     A34969 37400020
         BO    CHAINSCH                YES - GET PROPER IOB      A34969 37600020
         L     WK1,DCBIOB(K0,DCBREG)   NO - GET LAST IOB USED    A34969 37800020
         B     MICRIOBA                CONTINUE PROCESS          A45619 38000021
CHAINSCH EQU   *                                                 A34969 38200020
         L     WK1,CHAINIOB(K0,DCBREG) ADDR OF IOB               A34969 38400020
         B     IOBSAVE                 CONTINUE NORMAL PROCESS   A34969 38600020
MICRIOBA EQU   *                                                        38800020
         L     WK1,K0(K0,WK1)          LINK FWD 1 IOB GETS NXT AVAIL    39000020
IOBSAVE  EQU   *                                                        39200020
         LA    WK1,K0(K0,WK1)          CLEAR HIGH-ORDER BYTE            39400020
         LR    IOBREG,WK1              SAVE FIRST IOB POINTER           39600020
DMCOM03B EQU   *                                                        39800020
         L     CKREG,K12(K0,WK1)       GET ECB POINTER                  40000020
         CLI   K0(CKREG),GOOD          TEST FOR NORMAL COMPLETION       40200020
         BNE   DMCOM04B                NO - ERROR FOUND                 40400020
         L     WK1,IOBNXT(K0,WK1)      YES - LINK TO NEXT IOB           40600020
         LA    WK1,K0(K0,WK1)          CLEAR HIGH-ORDER BYTE            40800020
         CR    WK1,IOBREG              IS THIS THE STARTING POINT       41000020
         BE    ERR01                   YES - LOOPING-NO ERR FOUND       41200020
         B     DMCOM03B                NO - CONTINUE SCANNING IOB'S     41400020
*********************************************************************** 41600020
*                                                                     * 41800020
*        CHECK FOR OPTICAL CHAR READER TYPE. IF OCR SET UP TO XCTL TO * 42000020
*        IGC0606H                                                     * 42200020
*        OCR DEVICES AND RESPECTIVE UCBTYPE HEX CODES ARE:      XL03127 42250000
*        3886.1285.1287.1288  /  17,1A,1B,1C                    XL03127 42300000
*********************************************************************** 42400020
DMCOM04B EQU   *                                                        42600020
         L     DEBREG,DCBDEB(DCBREG)   GET DEB POINTER                  42800020
         L     UCBREG,DEBUCB(K0,DEBREG) GET UCB POINTER                 43000020
         TM    UCBTBYT3,UCB3UREC       UNIT RECORD CLASS        SA53858 43200021
         BNO   DMCOM4D                 NO - SKIP OCR CHECK              43400020
         CLI   UCBTBYT4,OCR3886        YES- IS IT A 3886 OCR    XL03127 43450000
         BE    OCR01                    YES- PROCESS FOR OCR    XL03127 43500000
         CLI   UCBTBYT4,OC1            NO-IS IT 1285    XL03127,SA53858 43600000
         BL    DMCOM4D                 NO - CONTINUE PROCESSING         43800020
         CLI   UCBTBYT4,OC2            YES-IS IT 1288   XL03127,SA53858 44000000
         BNH   OCR01                   YES - PROCESS FOR OCR            44200020
         SPACE 4                                                 X03962 44400021
DMCOM4D  EQU   *                                                        44600020
*********************************************************************** 44600121
*     BSAM, BPAM, QSAM AND BDAM CAN COME HERE.                          44600221
*     SET THE OPERATION TYPE FIELD OF THE MESSAGE BEING CONSTRUCTED.    44602221
*********************************************************************** 44610021
         MVC   OPERATN(K6),K18(WK2)    SET ERR OPERATION IN MESSAGE     44800020
         TM    WKAREA2,POINT           POINT TO ILLOG BLOCK             45000020
         BO    DMCOM05                 YES - CONTINUE                   45200020
         MVC   OPERATN(K6),K12(WK2)    NO - SET NEXT ERR OPERATION IN   45400020
*                                       MESSAGE                         45600020
         TM    WKAREA2,NVCNTL          CONTROL OPERATION                45800020
         BO    DMCOM05                 YES - CONTINUE                   46000020
         MVC   OPERATN(K6),K0(WK2)     NO - SET FOR NEXT ERR OPERATION  46200020
         TM    WKAREA2,GETREAD         TEST FOR READ OP CODE            46400020
         BO    DMCOM04C                YES - CONTINUE                   46600020
         MVC   OPERATN(K6),K6(WK2)     NO - SET FOR NEXT ERR OPERATION  46800020
         TM    WKAREA2,PUTWRITE        TEST FOR WRITE OP CODE           47000020
         BO    DMCOM05                 YES - CONTINUE                   47200020
         MVC   OPERATN(K6),DMLIST2+12  NO - IT'S AN UNKNOWN CONDITION   47400021
         B     DMCOM05                 CONTINUE PROCESSING              47600020
DMCOM04C EQU   *                                                        47800020
         TM    WKAREA2,READDTA         DID WE READ DATA                 48000020
         BZ    DMCOM05                 NO - EXIT                        48200020
         CLI   K0(CKREG),IOERR         I/O ERROR                        48400020
         BNE   DMCOM05                 NO - CSW NOT VALID               48600020
         L     WK2,IOBCSW+K8(K0,WK1)   OBTAIN CCW ADDR + 8              48800020
         SH    WK2,EIGHT               OBTAIN TRUE CCW ADDRESS          49000020
         MVC   READERR(K4),K0(WK2)     BUFFER ADDR IN READERR           49200020
         LH    CKREG,K6(K0,WK2)        GET ORIGINAL COUNT               49400020
         SH    CKREG,IOBCSW+K8+K6(K0,WK1) SUBTRACT RESIDUAL COUNT       49600021
         STH   CKREG,READERR+K4        NUMBER OF BYTES READ             50000020
DMCOM05  EQU   *                                                        50200020
         CLI   LOADSW,TWO              IS IGC0206H TO BE LOADED         50400020
         BE    C001                    YES - CHECK DCB ADDRESS          50600020
         LA    IOBREG,K8(K0,WK1)       NO - OBTAIN IOS IOB POINTER      50800020
         EJECT                                                          51000020
*********************************************************************** 51010021
*     SET THE DEVICE TYPE FIELD IN THE MESSAGE ACCORDING TO THE UCB.  * 51012021
*********************************************************************** 51020021
C001     L     CKREG,PARAMREG+K4       GET DCB ADDRESS                  51200020
         BALR  LNKRG1,CHECKER          CHECK DCB ADDRESS                51400020
         LR    DCBREG,CKREG            SAVE DCB ADDRESS                 51600020
         L     CKREG,DCBDEB(DCBREG)    GET DEB ADDRESS                  51800020
         BALR  LNKRG1,CHECKER          CHECK DEB ADDRESS                52000020
         LR    DEBREG,CKREG            SAVE DEB ADDRESS                 52200020
         SR    WK1,WK1                 CLEAR THE                        52400020
         SR    WK2,WK2                   WORK REGISTERS                 52600020
         TM    DEBENT(DEBREG),EXTMSK   ANY EXTENTS                      52800020
         BZ    DMCOM06                 NO - SKIP EXTENT PROCESSING      53000020
         IC    WK2,DEBEXT(K0,DEBREG)   YES - GET SIZE                   53200020
         IC    WK1,IOBDAM(IOBREG)      M FROM IOB SPECIAL SEEK FIELD    53400020
         SLL   WK1,K0(WK2)             POINT AT UCB                     53600020
DMCOM06  EQU   *                                                        53800020
         L     CKREG,DEBUCB(WK1,DEBREG) GET UCB POINTER                 54000020
         BALR  LNKRG1,CHECKER          CHECK UCB                        54200020
         LR    UCBREG,CKREG            SAVE UCB ADDRESS                 54400020
         AIF   ('&LIB' EQ 'LIB1').ISOS  SKIP TEST IF ON OS       X03962 54400221
         TM    UCBID,UCBIDV            IS THIS A VALID UCB      SA53858 54600021
         BNO   ERR01                   NO - EXIT                        54800020
.ISOS    ANOP      IN OS, THE UCB COULD BE FOR A 2321 SUB-CELL   X03962 54800221
TYPE     MVC   UNITID(K3),UCBNAME      SET DEVICE NAME                  55000021
         LA    WK1,LIST-K3             INITIALIZE POINTER TO DEVICE     55200020
*                                       LIST                            55400020
TYP001   LA    WK1,K3(K0,WK1)          INCR. TO NEXT IN LIST            55600020
         MVC   WKAREA1(K1),UCBTBYT3    SET TYPE                 SA53858 55800021
*                                            TEMPORARILY                55850021
         NC    WKAREA1(K1),K0(WK1)     DO THEY MATCH                    56000020
         BZ    TYP001                  NO - GO TO NEXT ITEM             56200020
         MVC   UNITTYP(K2),K1(WK1)     SET TYPE IN MESSAGE              56400020
GOXCTL   EQU   *                                                        56600020
         LR    CHECKER,COREREG         SAVE CONTENT OF REGISTER 1       56800020
         LR    CKREG,RGF               SAVE CONTENT OF REGISTER 15      57000020
         STM   IOBREG,CKREG,SAVE       SAVE REGISTER FOR XCTL           57200020
         MVC   XCTLLIST+K4(K12),XLIST  SET UP LIST                      57400020
         LA    WK1,XCTLLIST+K8         FORM PTR TO NAME                 57600020
         ST    WK1,XCTLLIST            PLACE PTR IN LIST                57800020
         LA    RGF,XCTLLIST            SET PARAMETER                    58000020
         MVC   XCTLLIST+K12(K1),LOADSW SET MODULE NAME                  58200020
         SVC   XCTL                    XCTL                             58400021
*                                                                       58410021
*     SET UP TO XCTL TO THE TCAM-PROCESSING ROUTINE.                    58420021
GOXCTL3  EQU *                                                          58600020
         MVI   ACCESSM,K1              SET TCAM FLAG FOR IGC0406H       58800020
         MVC   DDNAME2(K8),K4(WK1)     SET UP DDNAME                    59000020
         MVI   LOADSW,FOUR             SET LOAD MODIFIER                59200020
         B     GOXCTL                  XCTL TO PROPER MODULE            59400020
         EJECT                                                          59600020
*********************************************************************** 59610021
*     ERROR EXIT ROUTINE.  GIVE BAD RETURN CODE & INCOMPLETE MESSAGE.   59612021
*********************************************************************** 59620021
ERR01    EQU   *                                                        59800021
         LA    RGZ,K8                  ERROR CODE                       60000021
EIGHT    EQU   *-2                     ABOVE INSTR USED AS CONSTANT     60200020
         SVC   OUT                     TERMINATE THIS FUNCTION          60400020
         SPACE 3                                                        60402021
*********************************************************************** 60410021
*     ADDRESS VALIDITY-CHECK ROUTINE.                                   60412021
*********************************************************************** 60420021
CHECK    LR    WK1,CKREG               STORE TEMP                       60600020
         SLL   WK1,30                  KEEP LOW                         60800020
         LTR   WK1,WK1                 CHECK WORD BOUNDARY              61000020
         BNZ   ERR01                   NO - ERROR                       61200021
         LA    WK1,INCR(K0,CKREG)      YES - INCR BY MAX FIELD          61400021
         C     WK1,CVTMZ00(CVTREG)     CHECK OUT OF CORE                61600020
         BCR   K12,LNKRG1              NO - RETURN                      61800020
         B     ERR01                   YES - PROCESS AS ERROR           62000021
         SPACE 3                                                        62002021
*********************************************************************** 62010021
*     OCR (OPTICAL CHARACTER READER) ROUTINE.                           62012021
*********************************************************************** 62020021
OCR01    EQU   *                                                        62200020
         MVI   LOADSW,SIX              SET UP LOAD ID FOR IGC0606H      62400020
         L     WK1,DCBIOB(DCBREG)      LOAD OCR IOB ADDRESS             62600020
         L     CKREG,K12(WK1)          LOAD OCR ECB ADDRESS             62800020
         TM    WKAREA2,GETREAD         READ OP CODE                     63000020
         BO    DMCOM04C                YES - CHECK ERROR                63200020
         B     DMCOM05                 NO - MAKE VALIDITY CHECKS        63400020
         SPACE                                                          63600020
ZERO     DC    X'000000'                                                64200020
XLIST    DC    A(0)                    LIST FOR XCTL                    64400020
         DC    CL8'IGC0106H'                                            64600020
LIST     DC    X'80'                   SEARCH FOR DEVICE TYPE           64800020
         DC    C'TA'                                                    65000020
         DC    X'20'                                                    65200020
         DC    C'DA'                                                    65400020
         DC    X'08'                                             M0827  65500021
         DC    C'UR'                                                    65600020
         DC    X'10'                                                    65800020
         DC    C'GR'                                                    66000020
         DC    X'40'                                                    66200020
         DC    C'TP'                                                    66400020
         DC    X'FF'                                                    66600020
UNDFN    DC    C'U '                                                    67000020
         SPACE 2                                                        67010021
*********************************************************************** 67020021
*     TABLE OF OPERATION TYPES FOR BASIC ACCESS METHODS.                67022021
*********************************************************************** 67030021
DMLIST1  DC    C'READ  '               FILL IN FOR TYPE OF OPERATION    67200020
         DC    C'WRITE '                                                67400020
         DC    C'CNT-OP'                                                67600020
         DC    C'POINT '               POINT OPERATION                  67800020
*********************************************************************** 67810021
*     TABLE OF OPERATION TYPES FOR QUEUED ACCESS METHODS.               67820021
*********************************************************************** 67830021
DMLIST2  DC    C'GET   '                                                68200020
         DC    C'PUT   '                                                68400020
         DC    C'UNKOWN'                                                68600020
         DC    C'UNKOWN'                                                68800020
*    NAMES OF ACCESS METHODS SUPPORTED BY THIS ROUTINE.                 68810021
QSAMS    DC    C'QSAM '                                                 69200020
BPAMS    DC    C'BPAM '                                                 69400020
BDAMS    DC    C'BDAM '                                                 69600020
SKELETON DC    C' ,********,********,'                                  69800020
PATCH    EQU   *                       PATCH AREA               SA53858 69850021
PATCHEND EQU   IGC0906H+1024           END OF PATCH AREA         X03962 69900021
PATCHLN  DC    (PATCHEND-PATCH)C' '    LENGTH OF PATCH AREA     SA53858 69950021
AREA     DSECT                         BUFFER DEF-USER 13 POINTS HERE   70000020
         DS    18F                     SAVE AREA                        70200020
VLFLD    DS    1D                      LENGTH FIELD FOR V.L. RECORDS    70400020
READERR  DS    1F                      RETURN INFO IF READ ERROR        70600020
         DS    1H                      NUMBER OF BYTES READ             70800020
PURGSW   DS    0C                                                       71000020
ACMTH    DS    1C                      ACCESS METHOD INPUT CODE         71200020
LOADSW   DS    1C                      MODULE NAME MODIFIER             71400020
WKAREA1  DS    1F                      WK1                              71600020
WKAREA2  DS    1F                      WK2                              71800020
MAXLOC   DS    1F                      MAX MACHINE ADDR                 72000020
SAVE     DS    20C                     REGISTER SAVE AREA ACROSS XCTL   72200020
START    DS    2C                      BLANK COMMA                      72400020
JOBNM    DS    2C                                                       72600020
XCTLLIST DS    0C                      LIST FOR XCTL                    72800020
PAD      DS    7C                                                       73000020
STEPNM   DS    9C                                                       73200020
UNITID   DS    4C                                                       73400020
UNITTYP  DS    3C                                                       73600020
DDNAME2  DS    9C                                                       73800020
OPERATN  DS    7C                                                       74000020
ERROR    DS    16C                                                      74200020
POSITION DS    15C                                                      74400020
ACCESSM  DS    6C                                                       74600020
PARAMREG DS    2F                                                       74800020
SRT      DSECT                                                  SA53858 74850021
         IEFUCBOB                                               SA53858 74900021
         END                                                            75000020
