         GBLC  &LIB                                                     00050021
&LIB     SETC  'LIB1'                   SET VARIABLE TO LIB1            00100021
         TITLE 'IGC0K95B -   RESTART,SVC52 - NON-DA UNIT SELECTION AND *00150021
               VOLUME MOUNTING/VERIFICATION'                            00200021
IGC0K95B START                                                          00250021
*        RELEASE 21.7 DELETIONS                                         00252021
*0000                                                           SA59342 00260021
*0000135000,184000,184400-184800                                 SM5481 00270021
*        RELEASE 21.8 DELETIONS                                         00280021
*0000                                                           SA66314 00290021
*0000                                                           SA66736 00292021
*0000                                                           SA64449 00294021
*0000119800,120000,142200,187000,187200                         SA70225 00296021
*0000                                                           SM00258 00298021
*                                                                       00300021
* STATUS = CHANGE LEVEL 000                                             00350021
*                                                                       00400021
* FUNCTION = 1. FOR DATA SETS ON MAGNETIC TAPE, SEARCH ALL ALLOCATED  * 00450021
*               UNITS FOR THE REQUIRED VOLUME; IF IT IS NOT MOUNTED-  * 00500021
*               A. SELECT THE FIRST AVAILABLE ALLOCATED UNIT (I.E.,   * 00550021
*                  ONE WITH NO RESERVED OR PERMANENTLY RESIDENT       * 00600021
*                  VOLUME)                                            * 00650021
*               B. READ THE JFCB FOR THE CORRESPONDING DD CARD IN     * 00700021
*                  ORDER TO OBTAIN THE DATA SET'S NAME FOR A MOUNT  *   00750021
*                  MESSAGE                                            * 00800021
*               C. ISSUE MOUNT MESSAGE 'IEC400A M' FOR THE REQUIRED   * 00850021
*                  VOLUME.                                            * 00900021
*               D. UNLOAD THE UNIT IF A NOLUME IS CURRENTLY MOUNTED.  * 00950021
*            2. REWIND THE JUST-MOUNTED VOLUME PREPARATORY TO READING * 01000021
*               THE VOLUME LABEL.                                     * 01050021
*            3. AN ATTEMPT IS MADE TO READ A VOLUME LABEL UNLESS      * 01100021
*               'BYPASS LABEL PROCESSING' IS SPECIFIED.               * 01150021
*               A. IF 'AL' OR 'SL' IS SPECIFIED AND A VOLUME LABEL    * 01200021
*                  WAS READ, THE VOLUME SERIAL NUMBER IS VERIFIED.    * 01250021
*                  IF THE VOLUME SERIAL NUMBER IS INCORRECT OR IF NO  * 01300021
*                  VOLUME LABEL WAS READ, THEN THE MOUNTING PROCEDURE * 01350021
*                  IS REPEATED FROM (1-B) OR (1-C) ABOVE, AS REQUIRED.* 01400021
*               B. IF 'NL' OR 'NSL' IS SPECIFIED AND A VOLUME LABEL   * 01450021
*                  WAS NOT READ, THE VOLUME IS ASSUMED TO BE THE      * 01500021
*                  CORRECT ONE BECAUSE NO OTHER VERIFICATION IS       * 01550021
*                  POSSIBLE. IF A VOLUME LABEL WAS READ, THEN THE     * 01600021
*                  MOUNTING PROCEDURE IS REPEATED FROM (1-B) OR (1-C) * 01650021
*                  ABOVE AS REQUIRED.                                 * 01700021
*            4. UPDATE THE UCB TO REFLECT THE CURRENT VOLUME STATUS   * 01750021
*               FOLLOWING VOLUME VERIFICATION.                        * 01800021
*            5. UPDATE THE UCB POINTER IN THE DEB TO REFLECT THE NEW  * 01850021
*               UNIT FOR SYSIN, SYSOUT, UNIT RECORD,GRAPHICS, AND     * 01900021
*               MAGNETIC TAPE DATA SETS FOLLOWING VOLUME VERIFICATION.* 01950021
*               THIS INCLUDES UPDATING THE SECONDARY CONTROL UNIT     * 02000021
*               (SCU) ADDRESS IN THE DEB FOR SOME MICR AND OCR        * 02050021
*               DEVICES.                                              * 02100021
*            6. REORDER THE TIOT ENTRY SUCH THAT THE CURRENT UCB IS   * 02150021
*               THE FIRST ONE IN THE LIST OF UCB'S.                   * 02200021
*                                                                       02250021
* NOTES = THIS MODULE WAS CREATED IN OS RELEASE 21.7 AS A SPLIT       * 02300021
*         OF MODULE IGCOKO5B DUE TO APAR 53310. IT PRECEDES IGCOKO5B  * 02350021
*         DURING EXECUTION IN ORDER TO MINIMIZE CHANGES TO THE        * 02400021
*         RESTART NSL ROUTINE INTERFACE.                              * 02450021
*                                                                       02500021
* MODULE TYPE = CONTROL                                               * 02550021
*                                                                     * 02600021
*    PROCESSOR = ASSEMBLER                                              02650021
*    MODULE SIZE = 1024 DECIMAL BYTES                                   02700021
*    ATTRIBUTES = ENABLED, PRIVILEDGED, READ ONLY, REENTRANT,           02750021
*                 REFRESHABLE, REUSABLE,TRANSIENT                       02800021
*                                                                       02850021
** ENTRY POINT = IGC0K95B                                               02900021
*                                                                       02950021
*    LINKAGE = ENTRY VIA XCTL FROM IGC0I05B, THE RESTART TABLE          03000021
*              COMPLETION MODULE.                                       03050021
*              ENTRY VIA XCTL FROM IGC0K05B TO VERIFY VOLUME FOR        03100021
*              FILE PROTECT AND TO REISSUE MOUNT MESSAGE IF NSL         03150021
*              ROUTINE DETERMINES WRONG VOLUME WAS MOUNTED.             03200021
*                                                                       03250021
*    INPUT = REGISTER 8 CONTAINS THE ADDRESS OF THE FIRST TABLE ENTRY.  03300021
*            REGISTER 10 CONTAINS THE ADDRESS OF THE RESTART WORK AREA. 03350021
*                                                                       03400021
* EXIT-NORMAL = XCTL TO IGC0K05B TO COMPLETE TAPE VOLUME MOUNTING       03450021
*               AND VERIFICATION.                                       03500021
*                                                                       03550021
* EXIT-ERROR = XCTL TO IGC0V05B TO TERMINATE RESTART PROCESSING.        03600021
*              ERROR CODES:                                             03650021
*               24 = ERROR READING JFCB                                 03700021
*               40 = ERROR IN TAPE POSITIONING OR READING VOLUME LABEL  03750021
*               44 = NO UCB AVAILABLE ON WHICH TO MOUNT THE REQUIRED    03800021
*                    VOLUME.                                            03850021
*               45 = SCR ADDRESS COULD NOT BE FOUND.                    03900021
*                                                                       03950021
* SVC'S                                                                 04000021
*    SVC   0 (EXCP) - PERFORM I/0 OPERATIONS                            04050021
*    SVC   1 (WAIT) - WAIT FOR I/O OPERATIONS TO COMPLETE               04100021
*    SVC   7 (XCTL) - TRANSFER CONTROL                                  04150021
*    SVC  35 (WTO)  - WRITE TO OPERATOR                                 04200021
*    SVC  87 (DOM)  - DELETE MSG FROM OPERATORS CONSOLE                 04250021
*    SVC 103 (XLATE)- TRANSLATE 'ANSI' VOL. LABEL TO 'EBCDIC'           04300021
*                                                                       04350021
*TABLES/WORKAREAS-                                                      04400021
*                                                                       04450021
*********************************************************************** 04500021
*                                                                     * 04550021
*    THE FOLLOWING IS A DESCRIPTION OF THE 48 BYTE TABLE ENTRY THAT   * 04600021
*    IS USED IN THE RESTART PORTION OF CHECKPOINT/RESTART.  EACH      * 04650021
*    ENTRY IN THE TABLE (ONE FOR EACH OPEN DATA SET AT CHECKPOINT)    * 04700021
*    IS 48 BYTES LONG.                                                * 04750021
*                                                                     * 04800021
*********************************************************************** 04850021
*                                                                       04900021
*        ------------------- 4 BYTES -----------------                  04950021
*                                                                       05000021
*      0 +++++++++++++++++++++++++++++++++++++++++++++                  05050021
*        +DATA SET  +           DCB                  +                  05100021
*        + ORGN.    +         ADDRESS                +                  05150021
*        +++++++++++++++++++++++++++++++++++++++++++++ 4                05200021
*        +FLAG BYTE +    WORKAREA SEGMENT            +                  05250021
*        + NO. 1    +         ADDRESS                +                  05300021
*      8 +++++++++++++++++++++++++++++++++++++++++++++                  05350021
*        +NUMBER    +         JFCB TTR               +                  05400021
*        + OF VOLS  +         ADDRESS                +                  05450021
*        +++++++++++++++++++++++++++++++++++++++++++++ 12               05500021
*                                                                       05550021
*     12 +++++++++++++++++++++++                                        05600021
*        +TAPE LABL + FILE SEQ +        DEVICE = TAPE                   05650021
*        +INFO BYTE + NUMBER   +                                        05700021
*        +++++++++++++++++++++++                                        05750021
*                                                                       05800021
*     12 +++++++++++++++++++++++                                        05850021
*        +    OLD   TIOT       +        DA AND UNIT RECORD              05900021
*        +      OFFSET         +                                        05950021
*        +++++++++++++++++++++++                                        06000021
*                                                                       06050021
*                              +++++++++++++++++++++++                  06100021
*                              +FLAG BYTE +FLAG BYTE +                  06150021
*                              +  NO. 2   +  NO. 3   +                  06200021
*     16 +++++++++++++++++++++++++++++++++++++++++++++                  06250021
*        +FLAG BYTE +FLAG BYTE +                     +                  06300021
*        + NO. 4    + NO. 5    +   VOLUME ID NO. 1   +                  06350021
*        +++++++++++++++++++++++                     + 20               06400021
*        +                                           +                  06450021
*        +                                           +                  06500021
*     24 +++++++++++++++++++++++++++++++++++++++++++++                  06550021
*        +                                           +                  06600021
*        +   VOLUME ID NO. 2                         +                  06650021
*        +                     +++++++++++++++++++++++ 28               06700021
*        +                     +                     +                  06750021
*        +                     +   VOLUME ID NO. 3   +                  06800021
*     32 +++++++++++++++++++++++                     +                  06850021
*        +                                           +                  06900021
*        +                                           +                  06950021
*        +++++++++++++++++++++++++++++++++++++++++++++ 36               07000021
*        +                                           +                  07050021
*        +   VOLUME ID NO. 4                         +                  07100021
*     40 +                     +++++++++++++++++++++++                  07150021
*        +                     +                     +                  07200021
*        +                     +                     +                  07250021
*        +++++++++++++++++++++++   VOLUME ID NO. 5   + 44               07300021
*        +                                           +                  07350021
*        +                                           +                  07400021
*        +++++++++++++++++++++++++++++++++++++++++++++ 48               07450021
*                                                                       07500021
* MACROS = CVT     - TO DEFINE THE CVT DSECT                            07550021
*          DCBD    - DCB DESECT                                         07600021
*          DOM     -TO ISSUE SVC 87                                     07650021
*          EXCP    - TO ISSUE SVC 0                                     07700021
*          IEEVRSWA- RESTART WORK AREA DSECT                            07750021
*          IEFJFCBN- JFCB DSECT                                         07800021
*          IEFTIOT1- TIOT DSECT                                         07850021
*          IEFUCBOB- UCB DSECT                                          07900021
*          IEZDEB  - DEB DSECT                                          07950021
*          IKFTCB  - TCB DSECT                                          08000021
*          WAIT    - TO ISSUE SVC 1                                     08050021
*          WTO     - TO ISSUE SVC 35                                    08100021
*          XCTL    - TO ISSUE SVC 7                                     08150021
*          XLATE   - TO ISSUE SVC 103                                   08200021
*                                                                       08220021
* CHANGE ACTIVITY =                                                     08240021
*        CHANGES/DELETIONS FOR RELEASE 21                               08260021
*                                                                       08280021
*0000                                                           SA53310 08300021
*                                                                       08320021
*                                                                       08340021
         SPACE                                                          08360021
*********************************************************************** 08380021
*                                                                       08400021
*        EQUATES                                                        08420021
*                                                                       08440021
*********************************************************************** 08460021
*                                                                       08480021
*****    REGISTER EQUATES                                               08500021
*                                                                       08520021
WRKR1    EQU   0                   WORK/PARAMETER REGISTER              08540021
WRKR2    EQU   1                   WORK/PARAMETER REGISTER              08560021
DCBR     EQU   2                   ADDR OF THE DCB FOR THE              08580021
*                                  CURRENT TABLE ENTRY                  08600021
BASER    EQU   3                   MODULE BASE ADDRESS                  08620021
DEBR     EQU   4                   ADDR OF DEB FOR THE CURRENT          08640021
*                                  TABLE ENTRY                          08660021
UCBR     EQU   5                   CURRENT UCB ADDRESS                  08680021
TIOTR    EQU   6                   ADDR OF THE NEW TIOT                 08700021
TCBR     EQU   7                   ADDR OF THE TCB                      08720021
TABLR    EQU   8                   ADDR OF THE FIRST TABLE ENTRY        08740021
CTABLR   EQU   9                   ADDR OF THE CURRENT TABLE ENTRY      08760021
BUFR     EQU   10                  ADDR OF THE RESTART WORK AREA        08780021
DSCNTR   EQU   11                  WORK REGISTER                        08800021
WRKR3    EQU   12                  WORK REGISTER                        08820021
WRKR4    EQU   13                  WORK REGISTER                        08840021
WRKR5    EQU   14                  WORK REGISTER                        08860021
WRKR6    EQU   15                  WORK/PARAMETER REGISTER              08880021
*                                                                       08900021
*****    GENERAL EQUATES NOT FOUND IN DSECTS                            08920021
*                                                                       08940021
DCBRERR  EQU   X'04'               REDUCED ERR RCVRY IN DCB     SA59342 08950021
CCWREAD  EQU   X'02'               TAPE READ COMMAND CODE               08960021
CCWREW   EQU   X'07'               REWIND COMMAND CODE                  08980021
CCWRUN   EQU   X'0F'               REWIND/UNLOAD CMD CODE               09000021
CCWSCHID EQU   X'31'               SEARCH ID EQUAL CMD                  09020021
ERRJFCB  EQU   24                  CODE FOR ERROR WHILE READING JFCB    09040021
ERRTAPE  EQU   40                  CODE FOR ERROR WHILE POSITIONING     09060021
*                                  TAPE OR READING A VOL LABEL          09080021
ERRNOUCB EQU   44                  CODE INDICATING NO UCB AVAILABLE     09100021
*                                  FOR VOLUME                           09120021
ERRSCU   EQU   45                  NO SCU                               09140021
MODECLR  EQU   X'C0'               MASK TO CLEAR ALL BUT DENSITY        09160021
*                                  FROM DEB DEVICE MODE FIELD           09180021
SETMODE  EQU   X'2B'               EVEN PARITY,TRANSLATE MODE,CONVERT   09200021
*                                  CONVERT OFF IN DEB DEVICE MODE FIELD 09220021
DOMSW    EQU   X'80'               INDICATES 'DOM' REQ'D                09240021
PERMERR  EQU   X'7F'               NORMAL COMPLETION CODE               09260021
*                                  FOR AN I/O OPERATION                 09280021
DEV1275  EQU   X'1F'               INDICATES 1275 OPTICAL CHAR          09300021
*                                  READER IN UCBTBYT4                   09320021
DEV1419  EQU   X'1D'               INDICATES 1419 MAGNETIC INK          09340021
*                                  CHARACTER READER IN UCBTYP4          09360021
REMOUNT  EQU   X'04'               INDICATE MOUNT MUST BE ISSUED        09380021
REVERF   EQU   X'08'               INDICATES VOL MUST BE VERIFIED       09400021
         EJECT                                                          09420021
         BALR  BASER,0             ESTABLISH BASE ADDRESS               09440021
         USING *,BASER             MODULE ADDRESSABILITY                09460021
*                                                                       09480021
         USING RSTWA,BUFR          RESTART WORK AREA ADDR.              09500021
MNTTP000 EQU   *                                                        09520021
         TM    RSDCBFLG,REMOUNT    IS THE REMOUNT BIT ON                09540021
         BO    MNTTP005            BR IF YES TO REISSUE MOUNT           09560021
         TM    RSDCBFLG,REVERF     MUST VOLUME BE VERIFIED              09580021
         BO    MNTTP040            BR IF YES                            09600021
*                                                                       09620021
         L     TCBR,RSTCBAD        LOAD TCB ADDRESS                     09640021
         USING TCB,TCBR            TCB ADDRESSABILITY                   09660021
         L     TIOTR,TCBTIO        LOAD TIOT ADDRESS                    09680021
         USING TIOT,TIOTR          TIOT ADDRESSABILITY                  09700021
         XC    RSMWOFST,RSMWOFST   CLEAR DOM WORKAREA            SM5481 09710021
*                                                                       09720021
*********************************************************************** 09740021
*                                                                       09780021
*        UPDATE THE BLOCK COUNT OF THE PROBLEM PROGRAM CHECKPOINT       09800021
*        DCB FROM INFORMATION IN THE RESTART WORK AREA (TAPE ONLY)      09820021
*********************************************************************** 09840021
*                                                                       09860021
         TM    RSFLAG1,RSTAPE      IS THE CHKPT D.S. ON TAPE?   SA66736 09870021
         BZ    MNTTP002            NO, BYPASS BLKCT UPDATE      SA66736 09872021
         L     WRKR4,RSCKDCB       LOAD ADDR OF PROBLEM PROGRAM         09880021
*                                  CHECKPOINT DCB                       09900021
         MVC   DCBBLKCT-IHADCB(4,WRKR4),RSBDCB+DCBBLKCT-IHADCB  SA66314 09920021
*                                  UPDATE DCB BLOCK COUNT               09940021
MNTTP002 EQU   *                                                SA66736 09950021
         LR    CTABLR,TABLR        LD 1ST TABLE ENTRY ADDR              09960021
         USING TABL,CTABLR         TABL ADDRESSABILITY                  09980021
MNTTP005 EQU   *                                                        10000021
         L     DCBR,TABDCBAD-1     LOAD DCB ADDRESS                     10020021
         USING IHADCB,DCBR         DCB ADDRESSABILITY                   10040021
         LH    WRKR5,DCBTIOT       LOAD TIOT ENTRY OFFSET               10060021
         L     DEBR,DCBDEBAD       LOAD DEB ADDRESS                     10080021
         USING DEBBASIC,DEBR       DEB ADDRESSABILITY                   10100021
         LA    WRKR5,16(WRKR5)     CALCULATE OFFSET TO 1ST UCB PTR      10120021
         LA    WRKR6,0(TIOTR,WRKR5) CALCULATE ADDR OF 1ST UCB POINTER   10140021
         L     UCBR,0(TIOTR,WRKR5) LOAD FIRST UCB ADDRESS               10160021
         USING UCBOB,UCBR          UCB ADDRESSABILITY                   10180021
         L     WRKR4,TABFLG1       LD WK AREA SEGMENT ADDR              10200021
         USING RSDSECT,WRKR4       WK AREA ADDRESSABILITY               10220021
*                                                                       10240021
*********************************************************************** 10260021
*                                                                       10280021
*        DETERMINE IF DATA SET IS TO BE PROCESSED                       10300021
*                                                                       10320021
*********************************************************************** 10340021
*                                                                       10360021
         TM    TABFLG1,TABF1NUL+TABF1DA+TABF1TCM TEST FOR NULL          10380021
*                                  OR TCAM D. S. OR DIRECT ACCESS DEV   10400021
         BNZ   MNTTP125            BR IF ANY- DO NOT PROCESS            10420021
         ST    WRKR6,TABVLID2      SAVE POINTER TO FIRST UCB ADDR       10440021
         TM    TABFLG1,TABF1SYS+TABF1UR TEST FOR SYSIN/SYSOUT OR        10460021
*                                  UNIT RECORD DEVICE-                  10480021
         BNZ   MNTTP095            BR IF ANY TO UPDATE DEB AND          10500021
*                                  TIOT ENTRY                           10520021
*********************************************************************** 10540021
*                                                                       10560021
*                                                                       10580021
*        TAPE PROCESSING-                                               10600021
*        SELECT A UNIT FOR THE REQUIRED VOLUME                          10620021
*                                                                       10640021
*********************************************************************** 10660021
*                                                                       10680021
*****    DETERMINE IF THE REQUIRED VOLUME IS MOUNTED                    10700021
*                                                                       10720021
MNTTP010 EQU   *                                                        10740021
         TM    SRTEDMCT,UCBMOUNT   WAS A MOUNT MSG ISSUED               10760021
         BO    MNTTP045            BR IF YES- VERIFY VOL                10780021
         CLC   TABVLID1,SRTEVOLI   IS CORRECT VOL MOUNTED-              10800021
         BE    MNTTP045            BR IF YES- VERIFY VOL                10820021
*                                                                       10840021
         BAL   DSCNTR,NEXTUCB      BR TO GET NEXT UCB ADDR              10860021
*                                                                       10880021
         BNE   MNTTP010            BR IF NOT LAST UCB TO TEST FOR       10900021
*                                  MOUNTED VOL- CONDITION CODE SET BY   10920021
*                                  'GET NEXT UCB' SUBRTN                10940021
*****    THE REQUIRED VOLUME WAS NOT MOUNTED.                           10960021
*****    SELECT THE FIRST AVAILABLE UNIT                                10980021
*                                                                       11000021
         LH    WRKR5,DCBTIOT       LOAD TIOT ENTRY OFFSET               11020021
         LA    WRKR5,16(WRKR5)     CALCULATE OFFSET TO 1ST UCB PTR      11040021
         L     UCBR,0(TIOTR,WRKR5) LOAD ADDR OF FIRST UCB               11060021
         B     MNTTP020            BR TO TEST FOR CORRECT VOLUME        11080021
MNTTP015 EQU   *                                                        11100021
         BAL   DSCNTR,NEXTUCB      BR TO GET NEXT UCB ADDR              11120021
         LA    WRKR2,ERRNOUCB      LOAD ERROR CODE                      11140021
         BE    ERRORRTN            BR IF LAST UCB- ERROR                11160021
MNTTP020 EQU   *                                                        11180021
         TM    SRTEDMCT,UCBDMC     IS THE DATA MANAGEMENT CT ZERO       11200021
         BNZ   MNTTP015            BR IF NOT- TEST NEXT UCB             11220021
         TM    SRTESTAT,UCBRESV+UCBPRES IS THE CURRENT VOL RESERVED OR  11240021
*                                  PERMANENTLY RESIDENT-                11260021
         BNZ   MNTTP015            BR IF EITHER- GET NEXT UCB           11280021
*                                                                SM5481 11290021
* BEFORE USING THIS UCB, DELETE ANY MOUNT MESSAGE THAT           SM5481 11292021
* MAY HAVE BEEN ISSUED FOR IT.                                   SM5481 11294021
*                                                                SM5481 11296021
         TM    UCBSTAB,UCBBNUL     TEST FOR MSG TO DOM           SM5481 11298021
         BZ    MNTTP025            SKIP IF NONE                  SM5481 11298421
         MVC   RSMWOFST+1(3),UCBFSER COPY MSG ID TO FULLWORD     SM5481 11299221
         L     WRKR2,RSMWOFST      ID TO PARAMETER REG           SM5481 11299621
         DOM   MSG=(1)             DELETE MESSAGE                SM5481 11299721
         NI    UCBSTAB,X'FF'-UCBBNUL TURN OFF MSG INDICATOR      SM5481 11299821
         XC    UCBFSER(6),UCBFSER  CLEAR MSG ID                  SM5481 11299921
*********************************************************************** 11300021
*                                                                       11320021
*        ISSUE A MOUNT MESSAGE FOR THE REQUIRED VOLUME ON THE           11340021
*        SELECTED UNIT                                                  11360021
*********************************************************************** 11380021
*                                                                       11400021
*****    READ THE JFCB IN ORDER TO OBTAIN THE DATA SET NAME             11420021
*****    FOR THE MESSAGE- THE CHANNEL PROGRAM FOR READING THE           11440021
*****    JFCB IS STILL IN THE WORKAREA, HAVING BEEN BUILT               11460021
*****    BY THE TABLE BUILD MODULES, AND IT IS AS FOLLOWS-              11480021
*****     CCW1- SEARCH ID ON CCHHR IN 'RSIOBDAD+3, COMMAND              11500021
*****           CHAIN TO CCW2, COUNT OF 5 (LENGTH OF CCHHR)             11520021
*****     CCW2  TIC TO CCW1                                             11540021
*****     CCW3  READ DATA INTO 'RSJFCB', COUNT OF 176 (LENGTH           11560021
*****           OF JFCB)                                                11580021
*                                                                       11600021
MNTTP025 EQU   *                                                        11620021
         L     WRKR1,TABVLID5+2    LOAD PARAMETER REGISTER WITH TTR     11640021
         TM    TABFLG2,TABF2GT5    ARE THERE GT 5 VOLUMES-              11660021
         BO    MNTTP030            BR IF YES- READ JFCB                 11680021
         L     WRKR1,TABNVOLS      ELSE LOAD JFCB 'TTR'                 11700021
MNTTP030 EQU   *                                                        11720021
         DROP  DEBR                DEB                                  11740021
         LR    TCBR,DEBR           SAVE DEB ADDRESS                     11760021
         SLL   WRKR1,8             LEFT-JUSTIFY THE 'TTR'               11780021
         LA    DEBR,RSJFCB         LOAD SAVE AREA ADDRESS               11800021
         STM   WRKR1,WRKR6,0(DEBR) SAVE REGISTERS                       11820021
         L     WRKR2,CVTPTR        LOAD CVT ADDRESS                     11840021
         USING CVT,WRKR2           CVT ADDRESSABILITY                   11860021
         L     WRKR6,CVTPCNVT      LOAD CONVERT RTN ADDR                11880021
         L     DCBR,CVTJOB         LOAD SYS1.SYSJOBQUE DCB ADDR         11900021
         DROP  WRKR2               CVT                                  11920021
         XC    RSCCWLST,RSCCWLST   ZERO  CCW INSTRUCTIONS       SA70225 11922021
         LA    WRKR2,RSIOBDAD+3    LD SEARCH ARGUMENT ADDR              11940021
         ST    WRKR2,RSCCW1        AND STORE IN CCW1                    11960021
         LA    WRKR2,RSCCW1        ADDR TO RETURN IN TIC        SA70225 11962021
         ST    WRKR2,RSCCW2        SAVE TIC ADDR                SA70225 11964021
         LA    WRKR2,RSBUFSEG      ADDR TO READ IN JFCB         SA70225 11966021
         ST    WRKR2,RSCCW3        SAVE ADDR                    SA70225 11968021
         OC    RSCCWLST,CCWLIST    MOVE THE CCW INSTRUCTIONS    SA70225 11970021
         L     WRKR2,DCBDEBAD      LOAD SYS1.SYSJOBQUE DEB ADDR         12020021
*                                  INTO PARAMETER REG                   12040021
         MVC   RSDEBUCB(4),RSDEBUCB-RSDSECT(WRKR2) COPY UCB INFO        12060021
         DROP  DCBR                                                     12080021
         LA    DCBR,RSIOBDAD       LD ADDR FOR 'MBBCCHHR'               12100021
*                                  INTO PARAMETER REGISTER              12120021
*                                                                       12140021
*                                                                       12160021
*****    BRANCH AND LINK TO THE CONVERT ROUTINE-                        12180021
*****    NOTE THAT THERE IS NO TEST FOR ERRORS UPON RETURN              12200021
*                                                                       12220021
         BALR  WRKR5,WRKR6         BR TO CONVERT ROUTINE                12240021
*                                                                       12260021
         LM    WRKR1,WRKR6,0(DEBR) RESTORE REGISTERS                    12280021
         USING IHADCB,DCBR         DCB ADDRESSABILITY                   12300021
         LR    DEBR,TCBR           RESTORE DEB ADDRESS                  12320021
         USING DEBBASIC,DEBR       DEB ADDRESSABILITY                   12340021
*                                                                       12360021
         BAL   DSCNTR,IOSUBRTN     BRANCH TO READ JFCB                  12380021
*                                                                       12400021
         LA    WRKR2,ERRJFCB       LOAD ERROR CODE                      12420021
         BNO   ERRORRTN            BR IF ERR READING JFCB- CONDITION    12440021
*                                  CODE SET BY I/O SUBROUTINE           12460021
*                                                                       12480021
*****    CONSTRUCT THE MOUNT MESSAGE                                    12500021
*                                                                       12520021
MNTTP035 EQU   *                                                        12540021
         MVC   RSMSG(18),MOUNTMSG  MOVE MESSAGE LENGTH AND BASIC        12560021
*                                  MSG TO WK AREA                       12580021
         MVC   RSMSGUCB,UCBNAME    MOVE UNIT NAME TO MSG                12600021
         MVC   RSMSGVOL,TABVLID1   MOVE VOL SER NO. TO MSG              12620021
         MVI   RSMSGVOL+6,C'/'     DELIMIT VOL SER NO TO MT MSG         12640021
         MVC   RSMSGDSN,JFCBDSNM   MOVE DATA SET NAME TO                12660021
*                                  MOUNT MESSAGE                        12680021
         MVC   RSMSGEND(4),MCSCODES MOVE DESCRIPTOR AND ROUTING         12700021
*                                  CODES TO MSG                         12720021
         OI    SRTEDMCT,UCBMOUNT   TURN ON UCB 'MOUNT IND'              12740021
         LA    WRKR2,RSMSG         LOAD MESSAGE ADDR INTO PARAMETER     12760021
*                                  REGISTER                             12780021
         WTO   MF=(E,(1))          ISSUE MOUNT MESSAGE                  12800021
*                                                                       12820021
         ST    WRKR2,RSMWOFST      SAVE MSG ID FOR 'DOM'         SM5481 12840021
         XC    UCBFSER(6),UCBFSER  CLEAR MSG ID AREA             SM5481 12842021
         OI    UCBSTAB,UCBBNUL     TURN ON DOM INDIC             SM5481 12850021
         MVC   UCBFSER(3),RSMWOFST+1 PUT MSG ID IN UCB           SM5481 12852021
*                                                                       12860021
*********************************************************************** 12880021
*                                                                       12900021
*        REWIND AND UNLOAD THE SELECTED UNIT IF REQUIRED                12920021
*********************************************************************** 12940021
*                                                                       12960021
MNTTP040 EQU   *                                                        12980021
         BAL   DSCNTR,BUILDCCW     BR TO BUILD CCW                      13000021
*                                                                       13020021
*****    DETERMINE IF THE REWIND AND UNLOAD IS REQUIRED                 13040021
*****    NOTE THAT THE UCB 'NOT READY' INDICATOR MAY BE OFF             13060021
*****    IN ERROR AFTER IPL. IN THIS CASE, THE REWIND/UNLOAD            13080021
*****    IS ISSUED ONLY IF A VOLUME IS THOUGHT TO BE MOUNTED.           13100021
*                                                                       13120021
         TM    UCBFL2,UCBNOTRD     IS THE DEVICE READY-                 13140021
         BO    MNTTP045            BR IF NOT- REWIND/UNLOAD IS          13160021
*                                  NOT REQUIRED                         13180021
         CLI   SRTEVOLI,X'00'      IS A VOLUME MOUNTED                  13200021
         BE    MNTTP045            BR IF NOT- REWIND/UNLOAD IS          13220021
*                                  NOT REQUIRED                         13240021
         BAL   DSCNTR,IOSUBRTN     BR TO REWIND/UNLOAD                  13260021
*                                                                       13280021
         LA    WRKR2,ERRTAPE       LOAD ERROR CODE                      13300021
         BNO   ERRORRTN            BR IF ERR ON UNLOAD- CONDITION       13320021
*                                  CODE SET BY I/O SUBROUTINE           13340021
         OI    UCBFL2,UCBNOTRD     SET UCB 'NOT READY' IND              13360021
MNTTP045 EQU   *                                                        13380021
         BAL   DSCNTR,BUILDCCW     BR TO BUILD CCW                      13400021
*                                                                       13420021
         MVI   RSCCW1,CCWREW       MAKE COMMAND A 'REWIND'              13440021
         EX    0,MNTTP090          EXECUTE INSTRUCTION TO MOVE          13460021
*                                  VOL SER TO UCB                       13480021
*                                                                       13520021
         BAL   DSCNTR,IOSUBRTN     BR TO REWIND BEFORE READING          13540021
*                                  VOLUME LABEL                         13560021
         LA    WRKR2,ERRTAPE       LOAD ERROR CODE                      13580021
         BO    MNTTP046            BR IF NO I/O ERROR TO VOLUME SA53800 13600021
*                                  LABEL PROCESSING             SA53800 13620021
         CLI   RSECBAD,X'44'       TEST FOR CHANNEL PGM         SA53800 13624021
*                                  INTECEPTED                   SA53800 13624821
         BNE   ERRORRTN            BR IF NOT TO ERROR RTN       SA53800 13628021
         BAL   DSCNTR,IOSUBRTN     FOR INTECEPT REISSUE REWIND  SA53800 13632021
         LA    WRKR2,ERRTAPE       LOAD ERROR CODE              SA53800 13636021
         BNO   ERRORRTN            IF I/O ERROR OCCURS DURING   SA53800 13636821
*                                  SECOND REWIND OPERATION      SA53800 13636921
*                                  BRANCH TO ERROR ROUTINE      SA53800 13637621
*                                                                       13640021
*********************************************************************** 13660021
*                                                                       13680021
*        VERIFY THE VOLUME LABEL                                        13700021
*********************************************************************** 13720021
*                                                                       13740021
MNTTP046 EQU   *                                                SA53800 13744021
         TM    TABTPLBL,TABTPBLP   WAS BLP SPECIFIED-                   13760021
         BO    MNTTP085            BR IF YES- DON'T VERIFY THE          13780021
*                                  VOLUME LABEL                         13800021
         MVI   RSCCW1,CCWREAD      MAKE COMMAND A 'READ'                13820021
*                                                                       13840021
         OI    RSDEBOFL,RSDEBRER   SET REDUCED ERR RCVRY        SA59342 13850021
         BAL   DSCNTR,IOSUBRTN     BR TO READ VOLUME LABEL              13860021
         NI    RSDEBOFL,X'FF'-RSDEBRER  RESET ERROR RCVRY       SA59342 13870021
*                                                                       13880021
         TM    RSIOBCSW+5,X'3E'    TEST FOR CHANNEL CHECK, DATA         13900021
*                                  CHECK, PROTECTION CK, CTRL,ETC.      13920021
         BNZ   ERRORRTN            BR IF YES- ERROR                     13940021
         TM    RSIOBCSW+4,X'02'    REST FOR UNIT CHECK-                 13960021
         BZ    MNTTP050            BR IF NOT TO VERIFY LBL              13980021
         TM    RSIOBSN1,X'F7'      TEST FOR OTHER THAN DATA ERRORS      14000021
         BNZ   ERRORRTN            BR IF YES- ERROR                     14020021
         TM    RSIOBSN2,X'01'      IS 'NOT CAPABLE' IND ON-             14040021
         BO    MNTTP025            BR IF YES- WRONG VOLUME              14060021
         B     MNTTP060            BR TO TEST FOR NL/NSL                14080021
*                                                                       14100021
*****    TEST FOR A VOLUME LABEL                                        14120021
*                                                                       14140021
MNTTP050 EQU   *                                                        14160021
         CLC   RSVOLID,ANSIVOL1    IS LABEL AN AL 'VOL1'-               14180021
         BNE   MNTTP055            BR IF NOT- TEST FOR SL               14200021
*                                                               SA70225 14202021
*        THE NEXT 3 INSTRUCTIONS REPLACES THE 'XLATE' MACRO     SA70225 14204021
*                                  TRANSLATE ANSI LABEL         SA70225 14206021
         LA    WRKR2,RSVOLSER      ADDR OF TRANSLATE AREA       SM00258 14208021
*                                  HIGH ORDER BYTE INDICATES    SA70225 14210021
*                                  TRANSLATE TO EBCDIC          SA70225 14212021
         LA    WRKR1,6             LENGTH TO TRANSLATE          SA70225 14214021
         SVC   103                 ISSUE TRANSLATE SVC          SA70225 14216021
         B     MNTTP065            BR TO TEST LABEL TYPE                14240021
MNTTP055 EQU   *                                                        14260021
         TM    RSIOBCSW+5,X'40'    TEST FOR INCORRECT LNG-              14280021
         BO    MNTTP060            BR IF YES                            14300021
         CLC   RSVOLID,SLVOL1      TEST FOR A VOLUME LABEL              14320021
         BE    MNTTP065            BR IF YES- TEST TYPE                 14340021
MNTTP060 EQU   *                                                        14360021
         TM    TABTPLBL,TABTPAL+TABTPSL IS LABEL TYPE AL OR SL          14380021
         BNZ   MNTTP025            BR IF YES- WRONG VOLUME              14400021
         B     MNTTP085            BR IF NOT- CORRECT VOL               14420021
MNTTP065 EQU   *                                                        14440021
         TM    TABTPLBL,TABTPAL+TABTPSL IS LABEL TYPE AL OR SL          14460021
         BZ    MNTTP025            BR IF NOT- WRONG VOLUME              14480021
         CLC   RSVOLSER,TABVLID1   IS CORRECT VOL MOUNTED-              14500021
         BNE   MNTTP025            BR IF NOT- CORRECT VOL               14520021
*                                                                       14540021
*********************************************************************** 14560021
*        UPDATE THE UCB TO REFLECT THE STATUS OF THE NEW VOLUME         14580021
*********************************************************************** 14600021
*                                                                       14620021
MNTTP075 EQU   *                                                        14640021
         TM    TABTPLBL,TABTPAL    IS LABEL TYPE AL                     14660021
         BZ    MNTTP080            BR IF NOT- SET SL VER.               14680021
         OI    SRTESTAB,UCBBSTR    SET 'AL VERIFIED' IND                14700021
         B     MNTTP085            BR- UPDATE TIOT ENTRY                14720021
MNTTP080 EQU   *                                                        14740021
         OI    SRTESTAT,UCBDADI    SET 'AL VERIFIED' IND                14760021
MNTTP085 EQU   *                                                        14780021
         MVI   RSCCW1,CCWREW       MAKE COMMAND A 'REWIND'              14800021
         BAL   DSCNTR,IOSUBRTN     BR TO REWIND                         14820021
         LA    WRKR2,ERRTAPE       LOAD ERROR CODE                      14840021
         BNO   ERRORRTN            BR IF ERROR CONDITION                14860021
MNTTP090 EQU   *                                                        14880021
         MVC   SRTEVOLI,TABVLID1   MOVE VOL SER TO UCB                  14900021
         MVC   UCBFSER(6),TABVLID3  MOVE DATA SET SER NO TO UCB         14920021
         MVC   SRTEDMCT(5),ONEEACH SET DATA MANAGEMENT CT AND FILE      14940021
*                                  SEQ COUNT AND NO. EACH TO 1          14960021
         EJECT                                                          14964021
*********************************************************************** 14980021
*                                                                       15000021
*        TAPE, UNIT RECORD, AND NON-DA SYSIN/SYSOUT PROCESSING          15020021
*                                                                       15040021
*        UPDATE THE TIOT ENTRY TO REFLECT CURRENT UCB USAGE,            15060021
*        AND UPDATE THE DEB TO REFLECT THE CORRECT UCB.                 15080021
*********************************************************************** 15100021
*                                                                       15120021
MNTTP095 EQU   *                                                        15140021
         LA    WRKR6,0(WRKR5,TIOTR) PT TO CURRENT UCB IN TIOT ENTRY     15160021
         L     DSCNTR,TABVLID2     LOAD ADDR OF 1ST UCB IN TIOT ENTRY   15180021
         MVC   0(4,WRKR6),0(DSCNTR) SWITCH 1ST AND CURRENT              15200021
         ST    UCBR,0(DSCNTR)      UCB ADDR IN TIOT ENTRY               15220021
         OI    0(WRKR6),TIOSUSED   INDICATE THAT DATA SET IS            15240021
*                                  ON DEVICE                            15260021
         MVC   DEBSUCBB(3),1(DSCNTR) MOVE UCB ADDR TO WK DEB            15280021
*                                                                       15300021
*****    DETERMINE IF PROCESSING IS COMPLETE                            15320021
*                                                                       15340021
         CLI   UCBTBYT4,DEV1275    TEST FOR 1275 OPTICAL        SA64449 15360021
*                                  CHARACTER READER-                    15380021
         BE    MNTTP100            BR IF YES- PROCESS 1275              15400021
         CLI   UCBTBYT4,DEV1419    TEST FOR 1419 MAGNETIC       SA64449 15420021
*                                  INK CHARACTER READER-                15440021
         BNE   MNTTP125            BR IF NOT- ALL DONE                  15460021
*                                                                       15480021
*********************************************************************** 15500021
*                                                                       15520021
*        1275 OPTICAL CHARACTER READER AND                              15540021
*        1419 MAGNETIC INK CHARACTER READER PROCESSING                  15560021
*                                                                       15580021
*        UPDATE THE DEB TO REFLECT THE NEW SECONDARY CONTROL            15600021
*        CONTROL UNIT (SCU) ADDRESS                                     15620021
*********************************************************************** 15640021
*                                                                       15660021
*****    DETERMINE THE ADDRESS OF THE SCR FROM THE                      15680021
*****    'UCB LOOK-UP' TABLE                                            15700021
*                                                                       15720021
MNTTP100 EQU   *                                                        15740021
         LH    WRKR2,UCBCHA        LOAD CHANNEL AND DEV ADDR            15760021
         SLL   WRKR2,21            CLEAR INDICATORS                     15780021
         SRL   WRKR2,21            REPOSITION CHANNEL AND               15800021
*                                  DEVICE ADDRESS                       15820021
         LA    WRKR2,1(,WRKR2)     INCR TO SCU ADDRESS                  15840021
         L     DSCNTR,CVTPTR       LOAD CVT ADDRESS                     15860021
         USING CVT,DSCNTR          CVT ADDRESSABILITY                   15880021
         L     DSCNTR,CVTILK2      LOAD ADDRESS OF UCB LOOK-UP TABLE    15900021
         DROP  DSCNTR              CVT                                  15920021
MNTTP105 EQU   *                                                        15940021
         LH    WRKR5,0(,DSCNTR)    LOAD UCB ADDR FROM TBL               15960021
         LTR   WRKR5,WRKR5         IS THERE AN ADDRESS-                 15980021
         BZ    MNTTP115            BR IF NULL ENTRY-CHECK               16000021
*                                  NEXT UCB ENTRY                       16020021
         BP    MNTTP110            BR IF VALID UCB ADDR                 16040021
         LA    WRKR2,ERRSCU        LOAD 'NO SCU' ERROR CODE             16060021
         B     ERRORRTN            BR TO PROCESS ERROR                  16080021
MNTTP110 EQU   *                                                        16100021
         LH    WRKR6,4(,WRKR5)     LOAD CHANNEL AND DEVICE ADDR FROM    16120021
*                                  UCB POINTED TO BY LOOK-UP TBL ENTRY  16140021
         SLL   WRKR6,21            CLEAR INDICATORS                     16160021
         SRL   WRKR6,21            REPOSITION CHANNEL AND DEVICE ADDR   16180021
         CR    WRKR6,WRKR2         ARE THE TWO CHANNEL AND DEVICE       16200021
*                                  ADDRESSES EQUAL-                     16220021
         BE    MNTTP120            BR IF YES TO UPDATE DEB REG 'WRKR5'  16240021
*                                  CONTAINS THE SCU ADDRESS             16260021
MNTTP115 EQU   *                                                        16264021
         LA    DSCNTR,2(,DSCNTR)   INCR TO NEXT ENTRY           SA64449 16268021
         B     MNTTP105            BR TO REPEAT TESTS                   16272021
MNTTP120 EQU   *                                                        16280021
         STH   WRKR5,DEBSUCBA+6    STORE SCU ADDR INTO SECOND DEB       16300021
*                                  EXTENT                               16320021
*                                                                       16340021
*********************************************************************** 16360021
*        VOLUME MOUNTING AND VERIFICATION IS COMPLETE-                  16380021
*        PROCESS THE NEXT TABLE ENTRY                                   16400021
*********************************************************************** 16420021
*                                                                       16440021
MNTTP125 EQU   *                                                        16460021
         TM    RSDCBFLG,REMOUNT+REVERF WAS ENTRY FROM K05B              16480021
         BNZ   MNTTP130            BR IF YES FOR XCTL                   16500021
         TM    TABFLG1,TABLLAST    IS THIS THE LAST ENTRY               16520021
         LA    CTABLR,TABLEND-TABL(CTABLR) INCR TO NEXT ENTRY           16540021
         BZ    MNTTP005            BR IF NOT- PROCESS NEXT              16560021
*                                  TABLE ENTRY                          16580021
*                                                                       16600021
*****    PREPARE TO EXIT TO NEXT REQUIRED MODULE                        16620021
*                                                                       16640021
MNTTP130 EQU   *                                                        16660021
         LA    WRKR2,MODTAPE       POINT TO NEXT MOD'S NAME             16680021
         B     XCTLRTN             BR TO XCTL                           16700021
         EJECT                                                          16720021
*********************************************************************** 16740021
*                                                                       16760021
*        ERROR PROCESSING                                               16780021
*                                                                       16800021
*********************************************************************** 16820021
*                                                                       16840021
ERRORRTN EQU   *                                                        16860021
         STC   WRKR2,RSRETCOD+1    PLACE RETURN CODE IN AREA            16880021
*                                  FOR ERROR MODULE                     16900021
         LA    WRKR2,MODERROR      POINT TO NAME OF ERROR-              16920021
*                                  PROCESSING MODULE                    16940021
*********************************************************************** 16960021
*                                                                       16980021
*        XCTL TO NEXT REQUIRED MODULE                                   17000021
*                                                                       17020021
*********************************************************************** 17040021
*                                                                       17060021
XCTLRTN  EQU   *                                                        17080021
         MVC   RSPPM(8),0(WRKR2)   MOVE MODULE NAME TO XCTL             17100021
*                                  PARAMETER LIST                       17120021
         LR    WRKR2,BUFR          LOAD REG 1 WITH ADDRESS OF           17140021
*                                  RESTART WORK AREA                    17160021
         LA    WRKR6,RSPPM+8       PT TO SCTL PARM LIST                 17180021
         XCTL  EPLOC=RSPPM,SF=(E,(15)) XCTL TO NEXT REQ'D MODULE        17200021
         EJECT                                                          17220021
*********************************************************************** 17240021
*                                                                       17260021
*        SUBROUTINES                                                    17280021
*                                                                       17300021
*********************************************************************** 17320021
*                                                                       17340021
*****    CLOSED SUBROUTINE TO OBTAIN THE ADDRESS OF THE NEXT            17360021
*****    AVAILABLE UCB                                                  17380021
*****    SUBROUTINE CONVENTIONS-                                        17400021
*****      ENTRY- VIA 'BAL  DSCNTR,NEXTUCB'                             17420021
*****      EXIT - VIA 'BR   DSCNTR',  WITH CONDITION CODE 8             17440021
*****             WHEN THERE ARE NO MORE AVAILABLE UCBS.                17460021
*                                                                       17480021
NEXTUCB  EQU   *                                                        17500021
         LA    WRKR5,4(WRKR5)      INCR TO NEXT UCB PTR                 17520021
         LH    WRKR3,DCBTIOT       LOAD DCB TIOT OFFSET                 17540021
         SR    WRKR6,WRKR6         CLEAR WORK REGISTER                  17560021
         IC    WRKR6,0(TIOTR,WRKR3) OBTAIN DD ENTRY LENGTH              17580021
         AR    WRKR3,TIOTR         CALC ADDR OF THIS ENTRY              17600021
         AR    WRKR3,WRKR6         CALC ADD OF NEXT ENTRY               17620021
         LA    WRKR6,0(TIOTR,WRKR5) CALC ADDR OF NEXT UCB               17640021
*                                  POINTER                              17660021
         CR    WRKR3,WRKR6         ARE THERE MORE UCBS-                 17680021
         L     UCBR,0(TIOTR,WRKR5) LOAD POTENTIAL UCB ADDRESS           17700021
         BR    DSCNTR              RETURN TO CALLER                     17720021
         SPACE 1                                                        17740021
*                                                                       17760021
*****    CLOSED SUBROUTINE TO BUILD A CHANNEL PROGRAM FOR               17780021
*****    TAPE POSITIONING AND INPUT/OUTPUT OPERATIONS-                  17800021
*****    SUBROUTINE CONVENTIONS-                                        17820021
*****      ENTRY- VIA   'BAL  DSCNTR,BUILDCCW'                          17840021
*****      EXIT - VIA   'BR   DSCNTR', WITH RSCCW1 INITIALIZED          17860021
*****             TO PERFORM A REWIND/UNLOAD OPERATION BUT WITH         17880021
*****             FLAGS, BUFFER ADDRESS, AND LENGTH READY FOR           17900021
*****             READING A VOLUME LABEL                                17920021
*                                                                       17940021
BUILDCCW EQU   *                                                        17960021
         ST    UCBR,RSDEBUCB       ST UCB ADDR IN WORK DEB              17980021
         MVC   RSDEBUCB(1),DEBSDVM MOVE MODE SET TO WORK DEB            18000021
         NI    RSDEBUCB,MODECLR    CLEAR ALL BUT DENSITY                18020021
         OI    RSDEBUCB,SETMODE    SET EVEN PARITY,TRANS-               18040021
*                                  LAGE MODE, CONVERT OFF               18060021
         LA    TCBR,X'50'          GET CCW BYTE COUNT                   18064021
         ST    TCBR,RSCCW1+4       STORE IN FIRST CCW                   18068021
         LA    TCBR,RSVOLLBL       LOAD LABEL READ-IN ADDR              18080021
         ST    TCBR,RSCCW1         AND STORE IN FIRST CCW               18100021
         MVI   RSCCW1,CCWRUN       SET REWIND/UNLOAD                    18120021
         BR    DSCNTR              RETURN TO CALLER                     18160021
*                                                                       18180021
*****    CLOSED SUBROUTINE TO PERFORM I/O OPERATIONS-                   18200021
*****    SUBROUTINE CONVENTIONS-                                        18220021
*****      ENTRY- VIA   'BAL   DSCNTR,IOSUBRTN'                         18240021
*****      EXIT - VIA   'BR    DSCNTR',WITH COND CODE SET 1             18260021
*****             WHEN I/O IS COMPLETE WITHOUT ERROR                    18280021
*                                                                       18300021
IOSUBRTN EQU   *                                                        18320021
         EXCP  RSIOB               INITIATE I/O OPERATION               18340021
         WAIT  ,ECB=RSECBAD        WAIT FOR I/O                         18360021
*                                                                       18380021
         TM    UCBSTAB,UCBBNUL     TEST IF MSG TO DELETE         SM5481 18390021
         BZ    TESTERR             BR IF NOT TO ERROR TEST              18420021
         MVC   RSMWOFST+1(3),UCBFSER COPY ID TO FULLWORD         SM5481 18430021
         L     WRKR2,RSMWOFST      ID TO PARAMETER REG           SM5481 18440021
         DOM   MSG=(1)             DELETE OPERATOR MESSAGE       SM5481 18460021
         NI    UCBSTAB,X'FF'-UCBBNUL TURN OFF 'DOM' IND          SM5481 18480021
         XC    UCBFSER(6),UCBFSER  CLEAR MSG ID                  SM5481 18490021
TESTERR  EQU   *                                                        18500021
         TM    RSECBAD,PERMERR     TEST FOR I/O ERROR                   18520021
         BR    DSCNTR              RETURN TO CALLER                     18540021
         EJECT                                                          18560021
*********************************************************************** 18580021
*                                                                       18600021
*        CONSTANTS                                                      18620021
*                                                                       18640021
*********************************************************************** 18660021
*                                                                       18680021
CCWLIST  DC    X'3100000040000005'      SEARCH                  SA70225 18682021
         DC    X'0800000000067FFF'      TIC                     SA70225 18684021
         DC    X'06000000000000B0'      READ                    SA70225 18686021
*                                                               SA70225 18688021
ONEEACH  DC    X'0100010001'       CONSTANT USED TO SET DATA            18820021
*                                  MANAGEMENT CT AND UCB FILE           18840021
*                                  SEQUENCE COUNT AND NUMBER            18860021
*                                  EACH TO 1                            18880021
ANSIVOL1 DC    X'564F4C31'         ASCII CODE FOR 'VOL1'                18900021
SLVOL1   DC    C'VOL1'             VOLUME LABEL IDENTIFIER              18920021
MODTAPE  DC    CL8'IGC0K05B'       NAME OF THE SECOND TAPE              18940021
*                                  PROCESSING MODULE                    18960021
MODERROR DC    CL8'IGC0V05B'       NAME OF ERROR PROCESSING MODULE      18980021
*                                                                       19000021
MOUNTMSG DC    X'00458000'         MSG LEN AND A MSG CODE               19020021
         DC    C'IEC400A M XXX,'   BASIC MOUNT MSG TEXT                 19040021
MCSCODES DC    X'40002800'         MCS DESCRIPTOR AND ROUTING CODES     19060021
*                                                                       19080021
         SPACE 1                                                        19100021
*********************************************************************** 19120021
*                                                                       19140021
*        PATCH AREA DEFINITION                                          19160021
*                                                                       19180021
*********************************************************************** 19200021
*                                                                       19220021
LENGTHK9 EQU   *-IGC0K95B          LNG BEFORE PATCH AREA                19240021
*                                                                       19260021
PATCHK9  EQU   1024-LENGTHK9       LENGTH OF PATCH AREA                 19280021
*                                                                       19300021
K9PATCH  EQU   *                                                        19320021
         DC    (PATCHK9)X'00'      ZEROED PATCH AREA                    19340021
         EJECT                                                          19360021
*********************************************************************** 19380021
*                                                                     * 19400021
*        SYSTEM CONTROL BLOCK AND WORK AREA DSECTS                    * 19420021
*                                                                     * 19440021
*********************************************************************** 19460021
         SPACE 2                                                        19480021
*********************************************************************** 19500021
*        RESTART WORK AREA DEFINITION                                 * 19520021
*********************************************************************** 19540021
*                                                                       19560021
         IEEVRSWA ,                     INVOKE RESTART WORK AREA MACRO  19580021
         EJECT                                                          19620021
*********************************************************************** 19640021
*        RESTART TABLE ENTRY DEFINITION                               * 19660021
*********************************************************************** 19680021
*                                                               SA53310 19700021
TABL     DSECT           ***** AS OF 3 OCT 67 *****                     19720021
         DS    0CL48                                                    19740021
TABDSORG DS    CL1                      DATA SET ORGANIZATION   SA53310 19760021
TABORGIS EQU   X'80'                    ..INDEXED SEQUENTIAL    SA53310 19780021
TABORGPS EQU   X'40'                    ..PHYSICAL SEQUENTIAL   SA53310 19800021
TABORGDA EQU   X'20'                    ..DIRECT                SA53310 19820021
TABORGPO EQU   X'02'                    ..PARTITIONED           SA53310 19840021
TABORGUM EQU   X'01'                    ..UNMOVABLE DATA SET    SA53310 19860021
*                                                               SA53310 19880021
TABDCBAD DS    CL3                      ADDR OF DCB FOR THIS ENTRY      19900021
*                                                               SA53310 19920021
TABFLG1  DS    CL1                      FLAG BYTE NO. 1                 19940021
TABF1NUL EQU   X'80'                    ..NULLFILE OR SYSCHECK  SA53310 19960021
TABF1SYS EQU   X'40'                    ..SYSIN/SYSOUT DATA SET SA53310 19980021
TABF1DA  EQU   X'20'                    ..DIRECT ACCESS DEVICE  SA53310 20000021
TABF1TAP EQU   X'10'                    ..TAPE DEVICE           SA53310 20020021
TABLLAST EQU   X'08'                    ..INDICATES TABLE END   SA53310 20040021
TABF1UR  EQU   X'04'                    ..UNIT RECORD OR OTHER  SA53310 20060021
*                                       ..NON-TAPE/DA DEVICE    SA53310 20080021
TABF1TCM EQU   X'02'                    ..TCAM DATA SET         SA53310 20100021
TABSEGAD DS    CL3                      ADDR OF W.A. SEG ASSIGNED       20120021
*                                                               SA53310 20140021
TABNVOLS DS    CL1                      TOTAL NO OF VOLUMES             20160021
TABJFCB  DS    CL3                      TTR ADDR OF JFCB - THIS DATASET 20180021
*                                                               SA53310 20200021
TABOTIOT DS    0CL2                     OLD USER TIOT OFFSET (DA ONLY)  20220021
*                                                               SA53310 20240021
TABTPLBL DS    CL1                      TAPE LABEL INFORMATION BYTE     20260021
TABNSLER EQU   X'80'                    ..ERROR IN NSL RTN      SA5331- 20280021
TABNSLMT EQU   X'40'                    ..NSL MOUNT SWITCH      SA53310 20300021
TABNSLCM EQU   X'20'                    ..NSL COMMUNICATION IND SA53310 20320021
TABTPBLP EQU   X'10'                    ..LABEL EQUAL 'BLP'     SA53310 20340021
TABTPAL  EQU   X'08'                    ..LABEL EQUAL 'AL'      SA53310 20360021
TABTPNSL EQU   X'04'                    ..LABEL EQUAL 'NSL'     SA53310 20380021
TABTPSL  EQU   X'02'                    ..LABEL EQUAL 'SL'      SA53310 20400021
TABTPNL  EQU   X'01'                    ..LABEL EQUAL 'NL'      SA53310 20420021
*                                                               SA53310 20440021
TABFSQNO DS    CL1                      FILE SEQUENCE NO. (IF TAPE)     20460021
*                                                               SA53310 20480021
TABFLG2  DS    CL1                      FLAG BYTE NO. 2                 20500021
TABF2GT5 EQU   X'80'                    ..DATA SET HAS MORE     SA53310 20520021
*                                       ..THAN 5 VOLUMES        SA53310 20540021
TABF2POC EQU   X'40'                    ..CONCATENATED PARTI-   SA53310 20560021
*                                       ..TIONED DATA SETS      SA53310 20580021
*                                                               SA53310 20600021
TABFLG3  DS    CL1                      FLAG BYTE NUMBER 3              20620021
TABFLG4  DS    CL1                      FLAG BYTE NUMBER 4              20640021
TABFLG5  DS    CL1                      FLAG BYTE NUMBER 5              20660021
TABVLID1 DS    CL6                      VOLUME ID NUMBER ONE            20680021
TABVLID2 DS    CL6                      VOLUME ID NUMBER TWO            20700021
TABVLID3 DS    CL6                      VOLUME ID NUMBER THREE          20720021
TABVLID4 DS    CL6                      VOLUME ID NUMBER FOUR           20740021
TABVLID5 DS    CL6                      VOLUME ID NUMBER FIVE           20760021
TABLEND  EQU   *                                                SA53310 20780021
         EJECT                                                  SA53310 20800021
*********************************************************************** 20820021
*        RESTART WORK AREA SEGMENT DEFINITION                         * 20840021
*********************************************************************** 20860021
*                                                                       20880021
RSDSECT  DSECT                                                          20900021
*                                                                       20920021
*    DATA EXTENT BLOCK                                                  20940021
*                                                                       20960021
RSDEB    DS    0CL48                                                    20980021
RSDEBTCB DC    X'00000000'              TCB ADDRESS                     21000021
RSDEBDEB DC    X'00000000'              DEB ADDRESS                     21020021
*                                                                       21040021
*    DATA CONTROL BLOCK                                                 21060021
*                                                                       21080021
RSDEBOFL DS    0CL1                                                     21100021
RSDEBRER EQU   X'01'               REDUCED ERROR RECOVERY       SA59342 21110021
RSDEBIRB DC    X'00000000'              IRB ADDRESS                     21120021
RSDEBSYS DC    X'00000000'              1ST IOB ADDR IN SYS.PURGE CHAIN 21140021
RSDEBUSR DC    X'00000000'              1ST IOB ADDR IN USER PRGE CHAIN 21160021
RSDEBECB DC    X'00000000'              PARM.LIST ADDR TO PURGE ECB     21180021
RSDEBID  DS    0CL1                                                     21200021
RSDEBDCB DC    AL4(RSDCBREP)            DCB ADDR                        21220021
RSDEBAPP DS    CL4                      I/O APPENDAGE VECTOR TABLE      21240021
RSDEBMOD DS    0CL1                                                     21260021
RSDEBUCB DS    F                        UCB ADDRESS                     21280021
RSDEBBIN DS    H                        BIN NUMBER                      21300021
RSDEBSCC DS    H                        CYLINDER START ADDRESS          21320021
RSDEBSHH DS    H                        TRACK START ADDRESS             21340021
RSDEBECC DS    H                        CYLINDER END ADDRESS            21360021
RSDEBEHH DS    H                        TRACK END ADDRESS               21380021
RSDEBNTR DS    H                        NO. OF TRACKS IN THIS EXTENT    21400021
*                                                                       21420021
*    EVENT CONTROL BLOCK                                                21440021
*                                                                       21460021
RSECBAD  DS    CL4                      ECB ADDRESS                     21480021
RSDCBDEB DC    AL4(RSDEB)               DEB ADDRESS                     21500021
*                                                                       21520021
RSDCBREP EQU   RSDEB+8                  POINT TO RELATIVE BEGINNING DCB 21540021
*                                                                       21560021
*    INPUT OUTPUT BLOCK                                                 21580021
*                                                                       21600021
RSIOB    DS    0CL40                                                    21620021
RSIOBFG1 DC    X'00'                    I/O FLAGS BYTE 1                21640021
RSIOBFG2 DC    X'00'                    I/O FLAGS BYTE 2                21660021
RSIOBSN1 DS    CL1                      FIRST SENSE BYTE                21680021
RSIOBSN2 DS    CL1                      SECOND SENSE BYTE               21700021
RSIOBECB DC    AL4(RSECBAD)             ECB ADDRESS                     21720021
RSIOBCSW DS    D                        LAST CSW                        21740021
RSIOBCPA DS    AL4(RSCCW1)              CHANNEL PROGRAM ADDRESS         21760021
RSIOBDCB DS    AL4(RSDCBREP)            DCB ADDRESS                     21780021
RSIOBRCP DS    CL4                      RESTART ADDRESS FOR IOS         21800021
RSIOBINC DS    H                        INCREMENT BLOCK COUNT           21820021
RSIOBECT DS    H                        NO. OF ERROR ENTRIES            21840021
RSIOBDAD DS    D                        SEEK ADDRESS FOR DA             21860021
*                                                                       21880021
*    CHANNEL PROGRAM                                                    21900021
*                                                                       21920021
RSCCWLST DS    0CL24                                                    21940021
RSCCW1   DS    D                        CCW1                            21960021
RSCCW2   DS    D                        CCW2                            21980021
RSCCW3   DS    D                        CCW3                            22000021
*                                                                       22020021
*    BUFFER SEGMENT FOR EXTERNAL BLOCKS                                 22040021
*                                                                       22060021
RSBUFSEG DS    0CL176                                                   22080021
RSJFCB   EQU   RSBUFSEG                                                 22100021
*                                                               SA53310 22120021
         IEFJFCBN ,                     INVOKE JFCB DSECT MACRO SA53310 22140021
         SPACE 2                                                SA53310 22160021
*                                                               SA53310 22180021
*****    THE FOLLOWING SYMBOLS DEFINE THE VOLUME LABEL, WHICH   SA53310 22200021
*****    IS READ INTO A RESTART WORK AREA SEGMENT ONE WORD      SA53310 22220021
*****    BEYOND THE JFCB DATA SET NAME.                         SA53310 22240021
*                                                               SA53310 22260021
         ORG   JFCBELNM+4               LOCATE VOL LABEL AREA   SA53310 22280021
RSVOLLBL DS    0CL80                    VOLUME LABEL AREA       SA53310 22300021
RSVOLID  DS    CL4                      VOLUME LABEL IDENTIFIER SA53310 22320021
RSVOLSER DS    CL6                      VOLUME SERIAL NUMBER    SA53310 22340021
         SPACE 2                                                SA53310 22360021
*                                                               SA53310 22380021
*****    THE FOLLOWING SYMBOLS DEFINE A MESSAGE TO THE          SA53310 22400021
*****    OPERATOR, WHICH OVERLAYS ANOTHER PORTION OF THE JFCB   SA53310 22420021
*****    DATA AREA.                                             SA53310 22440021
*                                                               SA53310 22460021
         ORG   JFCEROPT                 LOCATE MESSAGE AREA     SA53310 22480021
RSMSG    DS    0CL73                    MESSAGE AREA            SA53310 22500021
RSMSGLNG DS    XL2                      MESSAGE LENGTH          SA53310 22520021
RSMSGMCS DS    XL2                      MESSAGE MCS FLAGS       SA53310 22540021
RSMSGBAS DS    CL10                     BASIC MESSAGE TEXT      SA53310 22560021
RSMSGUCB DS    CL3                      UNIT ADDRESS            SA53310 22580021
         DS    CL1                      UNIT/VOL SER DELIMITER  SA53310 22600021
RSMSGVOL DS    CL6                      VOLUME SERIAL NUMBER    SA53310 22620021
         DS    CL1                      VOL SER/DSN DELIMITER   SA53310 22640021
RSMSGDSN DS    CL44                     DATA SET NAME           SA53310 22660021
RSMSGEND DS    XL4                      END OF MESSAGE- ROUTING SA53310 22680021
*                                       AND DESCRIPTOR CODES    SA53310 22700021
*                                       ARE PLACED HERE         SA53310 22720021
         ORG   JFCBXPDT+1                                       SA53310 22740021
REPLYLTH DS    CL4                                              SA53310 22760021
REPLYECB DS    CL4                                              SA53310 22780021
REPLY    EQU   RSJFCB+142                                       SA53310 22800021
         EJECT                                                          22820021
*********************************************************************** 22840021
*        COMMUNICATIONS VECTOR TABLE (CVT) DEFINITION                 * 22860021
*********************************************************************** 22880021
*                                                               SA53310 22900021
CVT      DSECT                                                  SA53310 22920021
         CVT   ,                        INVOKE CVT DSECT MACRO  SA53310 22940021
         EJECT                                                  SA53310 22960021
*********************************************************************** 22980021
*        TASK CONTROL BLOCK (TCB) DEFINITION                          * 23000021
*********************************************************************** 23020021
*                                                               SA53310 23040021
         IKJTCB ,                       INVOKE TCB DSECT MACRO  SA53310 23060021
         EJECT                                                  SA53310 23080021
*********************************************************************** 23100021
*        TASK INPUT/OUTPUT TABLE (TIOT) DEFINITION                    * 23120021
*********************************************************************** 23140021
*                                                               SA53310 23160021
TIOT     DSECT                                                  SA53310 23180021
         IEFTIOT1 ,                     INVOKE TIOT DSECT MACRO SA53310 23200021
         EJECT                                                  SA53310 23220021
*********************************************************************** 23240021
*        UNIT CONTROL BLOCK (UCB) DEFINITION                          * 23260021
*********************************************************************** 23280021
*                                                               SA53310 23300021
UCB      DSECT                                                  SA53310 23320021
         IEFUCBOB ,                     INVOKE UCB DSECT MACRO  SA53310 23340021
         EJECT                                                  SA53310 23360021
*********************************************************************** 23380021
*        DATA CONTROL BLOCK (DCB) DEFINITION                          * 23400021
*********************************************************************** 23420021
*                                                               SA53310 23440021
         DCBD  DSORG=PS                 INVOKE DCB DSECT MACRO  SA53310 23460021
         EJECT                                                          23480021
*********************************************************************** 23500021
*        DATA EXTENT BLOCK (DEB) DEFINITION                           * 23520021
*********************************************************************** 23540021
*                                                                       23560021
         IEZDEB                                                         23580021
         SPACE 2                                                        23600021
         END                                                            23620021
