         TITLE 'IGC0N06C  RESCHEDULE I/O PHASE                         *00500018
                       RESUME I/O  CHECKPOINT-SVC 63  OS/360'           01000018
IGC0N06C CSECT                                                          01500018
*          RELEASE 18 DELETIONS                                       * 02000018
*          RELEASE 19 DELETIONS                                       * 02500018
*          RELEASE 20 DELETIONS                                       * 03000018
*3255                                                            M3408  03200020
*          RELEASE 21 DELETIONS                                       * 03500018
*          RELEASE 22 DELETIONS                                       * 04000018
*          RELEASE 23 DELETIONS                                       * 04500018
*          RELEASE 24 DELETIONS                                       * 05000018
*          RELEASE 25 DELETIONS                                       * 05500018
*          RELEASE 26 DELETIONS                                       * 06000018
*STATUS CHANGE LEVEL 003                                                06200020
*********************************************************************** 06500018
*                                                                     * 07000018
*                                                                     * 07500018
*FUNCTION/OPERATION- THE RESUME I/O ROUTINE CHECKS EACH OPEN DCB      * 08000018
*     REFLECTED IN THE DEB CHAIN AND REINITIATES ANY ACTIVITY         * 08500018
*     THAT WAS QUIESED.                                               * 09000018
*                                                                     * 09500018
*ENTRY POINTS- FROM THE CHECKMAIN ROUTINE OF CHECKPOINT               * 10000018
*                                                                     * 10500018
*INPUT- WORK AREA ADDRESS IN REGISTER 1                               * 11000018
*     TASK CONTROL BLOCK ADDRESS IN WORKAREA FIELD 'CKTCBAD'          * 11500018
*                                                                     * 12000018
*OUTPUT- WORK AREA ADDRESS IN REGISTER 1                              * 12500018
*     TASK CONTROL BLOCK ADDRESS IN WORKAREA FIELD 'CKTCBAD'          * 13000018
*                                                                     * 13500018
*EXTERNAL ROUTINES- NONE                                              * 14000018
*                                                                     * 14500018
*EXITS-NORMAL- TO THE EXIT ROUTINE OF CHECKPOINT                      * 14800018
*                                                                     * 15100018
*     -ERRORS- NONE                                                   * 15400018
*                                                                     * 16000018
*TABLES/WORKAREAS- SEE DEB, TCB AND IEEVCHWA DSECTS AT END OF LISTING * 16500018
*                                                                     * 17000018
*ATTRIBUTES- READ ONLY, REENTERABLE AND PRIVILEGED                    * 17500018
*                                                                     * 18000018
*  REGISTERS USED                                                     * 18500018
*                                                                     * 19000018
RPM0     EQU   0                        PARAMETER REGISTER            * 19500018
RTCB     EQU   1                        ADDRESS OF TCB/WORK REGISTER  * 20000018
RBASE    EQU   2                        BASE REGISTER                 * 20500018
RDEB     EQU   3                        ADDRESS OF DEB                * 21000018
RDCB     EQU   4                                                      * 21500018
RIOB     EQU   5                        ADDRESS OF IOB                * 22000018
RWRK     EQU   6                        ADDRESS OF WORKAREA           * 22500018
RSVI     EQU   7                                                      * 23000018
RTPG     EQU   8                                                      * 23500018
RWK9     EQU   9                                                      * 24000018
RWKA     EQU   10                                                     * 24500018
RWKB     EQU   11                       WORK REGISTER                 * 25000018
RWKC     EQU   12                                                     * 25500018
REG13    EQU   13                       SAVE AREA POINTER             * 26000018
RET14    EQU   14                       RETURN REGISTER               * 26500018
RPM15    EQU   15                       PARAMETER REGISTER            * 27000018
*                                                                     * 27500018
*        MASKS                                                        * 28000018
*                                                                     * 28500018
NTPRGD   EQU   X'FF'                    TEST DEBUSRPG FOR NOT PURGED  * 29000018
TCAMID1  EQU   X'C0'                    UNIQUE TCAM DEB CODE     M3408  29100020
TCAMID2  EQU   X'CF'                    UNIQUE TCAM DEB CODE     M3408  29200020
*                                                                     * 29500018
*********************************************************************** 30000018
         EJECT                                                          30500018
         BALR  RBASE,0                  ESTABLISH BASE                  31000018
         USING RESUMEIO,RBASE                                           31500018
         USING TCB,RTCB                                                 32000018
         USING DEB,RDEB                                                 32500018
         USING CHKWA,RWRK                                               33000018
         USING CHKIOWA,RWKB                                             33500018
*                                                                     * 34000018
RESUMEIO EQU   *                                                        34500018
         LR    RWRK,RTCB                SAVE ADDRESS OF WORK AREA       35000018
         LR    RWKB,RTCB                GET MY WORK AREA                35500018
         A     RWKB,CKWAOFST            ADD OFFSET TO RESUME I/O'S      36000018
*                                         WORK AREA                     36500018
*                                                                     * 37000018
*  OBTAIN CHAIN OF DEB'S FROM TCB                                     * 37500018
*                                                                     * 38000018
         L     RTCB,CKTCBAD             GET ADDR OF TCB FROM WORK AREA  38500018
         L     RDEB,TCBDEB              GET ADDR OF FIRST DEB FROM TCB  39000018
RESIO010 LTR   RDEB,RDEB                TEST FOR END OF DEB CHAIN       39500018
         BZ    RESIO030                 IF AT END GO SET UP RETURN      40000018
         CLI   DEBNMSUB,TCAMID1         Q - TCAM DEB (TYPE 1)    M3408  40100020
         BE    RESIO020                 IF YES, SKIP THIS DEB    M3408  40200020
         CLI   DEBNMSUB,TCAMID2         Q - TCAM DEB (TYPE 2)    M3408  40300020
         BE    RESIO020                 IF YES, SKIP THIS DEB    M3408  40400020
*                                                                     * 40500018
         TM    DEBUSRPG+3,NTPRGD        TEST IF PURGE TOOK PLACE        41000018
         BO    RESIO020                 IF NOT PURGED GO GET NEXT DEB   41500018
*                                                                     * 42000018
         L     RIOB,DEBUSRPG            ADDR OF 1ST IOB IN PURGE CHAIN  42500018
         LA    RIOB,0(0,RIOB)           CLEAR HIGH ORDER BITS           43000018
         LTR   RIOB,RIOB                TEST IF PURGE ISSUED AT ALL     43500018
         BZ    RESIO020                 IF NO PURGE GO GET NEXT DEB     44000018
*                                                                     * 44500018
*                                                                     * 45000018
*  SET UP FOR RESTORE                                                 * 45500018
*                                                                     * 46000018
         RESTORE DEBUSRPG                                               46500018
*                                                                     * 47000018
***                                                                 *** 47500018
*                                                                     * 48000018
*  GET NEXT DEB FROM CHAIN                                            * 48500018
*                                                                     * 49000018
RESIO020 L     RDEB,DEBDEBAD            GET ADDRESS OF PREVIOUS DEB     49500018
         LA    RDEB,0(0,RDEB)           CLEAR HIGH ORDER BITS           50000018
         B     RESIO010                 GO GET NEXT DEB                 50500018
*                                                                     * 51000018
***                                                                 *** 51500018
*                                                                     * 52000018
RESIO030 EQU   *                                                        52500018
         LR    RTCB,RWRK                RELOAD ADDR OF PASSED WORK AREA 53000018
         MVC   LIST(8),XADDR            PUT ADDRESS OF NEXT MODULE IN   53500018
*                                         WORK AREA                     54000018
         LA    RPM15,LIST+8             TELL XCTL WHERE TO GO           54500018
*                                                                     * 55000018
         XCTL  EPLOC=(RWKB),SF=(E,(15)) TO CHECKPOINT ROUTINE           55500018
*                                                                     * 56000018
***                                                                 *** 56500018
*                                                                     * 57000018
XADDR    DC    CL8'IGC0Q06C'            CHECKPOINT EXIT ROUTINE         57500018
*                                                                     * 58000018
         ORG   IGC0N06C+1024            MAKE MODULE PROPER LENGTH       58500018
*                                                                     * 59000018
*********************************************************************** 59500018
*********************************************************************** 60000018
         EJECT                                                          60500018
DEB      DSECT      DATA EXTENT BLOCK                                   61000018
*                                                                       61500018
DEBNMSUB DS    0CL1                    NO. OF SUB RTNS                  62000018
DEBTCBAD DS    CL4                     TASK CONTROL BLOCK ADDR          62500018
DEBAMLNG DS    0CL1                    LENGTH OF ACCESS METHOD SEC      63000018
DEBDEBAD DS    CL4                     ADDR OF NEXT DEB IN DEB CHAIN    63500018
DEBOFLGS DS    0CL1                    DEB OPEN FLAGS                   64000018
DEBIRBAD DS    CL4                     ADDR OF THE IRB CONTROL BLOCK    64500018
DEBOPATB DS    0CL1                    OPEN ATRIBUTES                   65000018
DEBSYSPG DS    CL4                     SYSTEM PURGE FIELD               65500018
DEBNMEXT DS    0CL1                    NUMBER OF EXTENTS IN DEB         66000018
DEBUSRPG DS    CL4                     USER PURGE FIELD                 66500018
DEBPRIOR DS    0CL1                    INFO BYTE                        67000018
DEBECBAD DS    CL4                     EVENT CONTROL BLOCK ADDR         67500018
DEBPROTG DS    0CL1                    INFO BYTE                        68000018
DEBDEBID DS    0CL1                    INFO BYTE                        68500018
DEBDCBAD DS    CL4                     ADDR OF DCB                      69000018
DEBEXSCL DS    0CL1                    SCALING FACTOR OF DEB EXTENT     69500018
DEBAPPAD DS    CL4                     APPENDAGE TABLE ADDR             70000018
DEBDVMOD DS    0CL1                    DEVICE MODIFIER BYTE             70500018
DEBUCBAD DS    CL4                     UNIT CTL BLOCK ADDR              71000018
DEBTVLSQ DS    0CL2                VOL SEQ FOR TAPE                     71500018
DEBBINUM DS    CL2                     BIN NUMBER                       72000018
DEBTVLNM DS    0CL2                NO OF VOL FOR TAPE                   72500018
DEBSTRCC DS    CL2                     START CYLINDER NUMBER            73000018
DEBSTRHH DS    CL2                     START HEAD NUMBER                73500018
DEBENDCC DS    CL2                     END CYLINDER NUMBER              74000018
DEBENDHH DS    CL2                     END HEAD NUMBER                  74500018
DEBNMTRK DS    CL2                     NUMBER OF TRACKS                 75000018
*                                                                     * 75500018
*  FOR ADDITIONAL EXTENT ON DIRECT ACCESS THE FOLLOWING FIELDS          76000018
*  WILL HAVE TO BE OFFSET ANOTHER 16 BYTES                              76500018
*                                                                     * 77000018
DEBVOLSQ DS    H                       VOL SEQUENCE NUMBER              77500018
DEBVOLNM DS    H                       VOLUME NUMBER                    78000018
*                                                                     * 78500018
*  FOR EACH SUBROUTINE LOADED BUMP THIS OFFSET BY 2                     79000018
*                                                                     * 79500018
DEBSUBID DS    H                       SUBROUTINE ID ( 2 BYTES )        80000018
         EJECT                                                          80500018
TCB      DSECT      TASK CONTROL BLOCK                                  81000018
*                                                                       81500018
TCBRBP   DS    A                       POINTER TO EXECUTING RB          82000018
TCBPIE   DS    A                       POINTER TO PROG. INTERRUPT EL.   82500018
TCBDEB   DS    A                       POINTER TO DEB QUEUE             83000018
TCBTIO   DS    A                       POINTER TO TIOT                  83500018
TCBCMP   DS    F                       TASK COMPLETION CODE             84000018
TCBTRN   DS    A                       TESTRAN FIELD                    84500018
TCBMSS   DS    A                       DATA BLOCK QUEUE ELEMENT POINTER 85000018
TCBPRTK  DS    BL1                     PROTECTION TAG                   85500018
TCBFLGS  DS    BL5                     FLAG BYTES                       86000018
TCBLMP   DS    BL1                     LIMIT PRIORITY                   86500018
TCBDSP   DS    BL1                     DISPATCHING PRIORITY             87000018
TCBLLS   DS    A                       POINTER TO LOAD LIST             87500018
TCBJLB   DS    A                       POINTER TO JOBLIB DCB            88000018
TCBJSE   DS    A                       LIST OF INACTIVE PROGRAMS ADDR.  88500018
TCBGRS   DS    16F                     GENERAL REGISTER SAVE AREA       89000018
TCBIDF   DS    0BL1                    TCB IDENTIFIER FIELD             89500018
TCBFSA   DS    A                       POINTER TO 1ST PROB.PROG.SAVEAR  90000018
TCBTCB   DS    A                       NEXT TCB ON READY QUEUE POINTER  90500018
TCBTME   DS    A                       POINTER TO TIMER ELEMENT         91000018
*                                                                       91500018
*                                                                       92000018
*                                                                       92500018
*                                                                       93000018
CHKIOWA  DSECT      CHECKIO'S WORK AREA                                 93500018
*                                                                       94000018
LIST     DS    3F   AREA WHERE ENTRY POINT NAME IS STORED               94500018
         EJECT                                                          95000018
         IEEVCHWA                                                       95500018
*                                                                       96000018
**********************************************************************  96500018
         END   IGC0N06C                                                 97500018
