         GBLC  &LIB                                                     00030020
&LIB     SETC  'LIB1'                   SET VARIABLE TO LIB1            00060020
         TITLE 'IGC0R05B  DATA SET PROCESSOR - DA DATA SET POSITIONING *00100018
                      REPOSITION I/O  RESTART-SVC 52  OS/360'           00200018
IGC0R05B CSECT                                                          00300018
*          RELEASE 18 DELETIONS                                         00400018
*0000239000-241000,263000-264000,340000,345000,348000,406000-     M3251 00430018
*0000407000,521000,544000-546000,565000                           M3251 00460018
*          RELEASE 19 DELETIONS                                         00500018
*2555050000,188000-189000,606000-607000,609000-612000,682000,    A25984 00530019
*2555686000-687000,746000                                        A25984 00560019
*          RELEASE 20 DELETIONS                                         00600018
*3523050000,187600                                               A30552 00620020
*3523218000,243000,250700-252000,877200-877400                   A29797 00650020
*          RELEASE 21 DELETIONS                                         00700018
*0790165000,187300-187900,447000,468000,487000-490000,508000-    M0187  00720021
*0790509000,515000,516000,520000,521000-521500,526000,557000-    M0187  00740021
*0790558000,568000-569000,680000-682000,686000,712000-713000,    M0187  00760021
*0790736000-737000,747000-749000,750000                          M0187  00780021
*          RELEASE 21.7 DELETIONS                                       00790021
*0000269000,463000-489000,738000                                SA54549 00792021
*          RELEASE 22 DELETIONS                                         00800018
*          RELEASE 23 DELETIONS                                         00900018
*          RELEASE 24 DELETIONS                                         01000018
*          RELEASE 25 DELETIONS                                         01100018
*          RELEASE 26 DELETIONS                                         01200018
* STATUS CHANGE LEVEL 004                                               01300021
*                                                                       01400018
*TITLE-        DA DATA SET POSITIONING                                  01500018
*                                                                       01600018
*STATUS-       INITIAL CODE                                             01700018
*                                                                       01800018
*FUNCTION-     CONTROL IS PASSED FROM IGC0M05B, IGC0P05B OR FROM THE    01900018
*              PARTIAL RLSE FUNCTION OF CLOSE. THIS MODULE EXAMINES THE 02000018
*              DEB'S AND DSCB'S OF DA SEQUENTIAL OR PARTITIONED DATA    02100018
*              SETS TO DETERMINE IF THE DATA SET HAS BEEN ALTERED SINCE 02200018
*              THE CHECKPOINT OCCURRED.                                 02300018
*                                                                       02400018
*              IF AN ENTRY IN THE TABLE INDICATES THAT A PS OR PO DATA  02500018
*              SET IS RESIDENT ON A DA DEVICE A 464 BYTE WORKAREA JUST  02600018
*              LIKE CLOSE'S IS FORMATTED IN THE RESTART WORKAREA.  THIS 02700018
*              CONTAINS THE CONTROL BLOCKS REQUIRED TO READ THE FORMAT  02800018
*              1 AND, IF NECESSARY, THE FORMAT 3 DSCB'S.                02900018
*                                                                       03000018
*              AFTER THIS THE FORMAT 1 DSCB, AND IF MORE THAN 3 EXTENTS 03100018
*              THE FORMAT 3 DSCB, IS READ.  NEXT THE DEB AND DSCB SPACE 03200018
*              ALLOCATION PARAMETERS ARE COMPARED.  IF THE DEB IS       03300018
*              GREATER THAN THE DSCB  (INDICATING A CLOSE WITH PARTIAL  03400018
*              RLSE) THE DEB IS COMPRESSED.  IF THE DSCB IS GREATER     03500018
*              THAN THE DEB A PARTIAL RELEASE IS EFFECTED VIA THE       03600018
*              PARTIAL RELEASE MODULES OF CLOSE.  BOTH OF THE FOREGOING 03700018
*              APPLY ONLY TO OUTPUT DATA SETS, FOR INPUT DATA SETS AN   03800018
*              ERROR CODE IS SET IF A DISCREPANCY IS ENCOUNTERED AND    03900018
*              CONTROL IS PASSED TO IGC0V05B. AT END-OF-TABLE, IF NO    04000018
*              ERROR IS ENCOUNTERED CONTROL IS PASSED TO IGC0T05B.      04100018
*                                                                       04200018
*INPUT-        REGISTER  1    ADDR OF REPI/O'S WORKAREA                 04300018
*              REGISTER  8    ADDR OF FIRST TABLE ENTRY                 04400018
*              REGISTER  1    PARTIAL RELEASE ERROR RETURN CODE         04500018
*                                                                       04600018
*OUTPUT-       SAME AS REGISTER 1 AND 8 ABOVE                           04700018
*                                                                       04800018
*EXTERNAL REFERENCES -                                                * 04810020
*   SVC 25  -  IGC0002E  -  BSAM TRACK BALANCE ROUTINE.               * 04820020
*      USED FOR D.A. CHECKPOINT DATA SET TO RESTORE DCBTRBAL,         * 04830020
*      AND TO ERASE THE REMAINDER OF THE TRACK.                       * 04840020
*                                                                     * 04850020
*EXITS-        TO PARTIAL RELEASE (IGG020P1)                            04900018
*              NORMAL TO IGC0T05B OR, IF ISAM OR BDAM, TO IGC0W05B      05000020
*              ERROR  TO IGC0V05B                                       05100018
*                                                                       05200018
*TABLES/WORKAREAS-                                                      05300018
*                                                                       05400018
*********************************************************************** 05500018
*                                                                     * 05600018
*    THE FOLLOWING IS A DESCRIPTION OF THE 48 BYTE TABLE ENTRY THAT   * 05700018
*    IS USED IN THE RESTART PORTION OF CHECKPOINT/RESTART.  EACH      * 05800018
*    ENTRY IN THE TABLE (ONE FOR EACH OPEN DATA SET AT CHECKPOINT)    * 05900018
*    IS 48 BYTES LONG.                                                * 06000018
*                                                                     * 06100018
*********************************************************************** 06200018
*                                                                       06300018
*        ------------------- 4 BYTES -----------------                  06400018
*                                                                       06500018
*      0 +++++++++++++++++++++++++++++++++++++++++++++                  06600018
*        +DATA SET  +           DCB                  +                  06700018
*        + O-GN.    +         ADDRESS                +                  06800018
*        +++++++++++++++++++++++++++++++++++++++++++++ 4                06900018
*        +FLAG BYTE +    WORKAREA SEGMENT            +                  07000018
*        + NO. 1    +         ADDRESS                +                  07100018
*      8 +++++++++++++++++++++++++++++++++++++++++++++                  07200018
*        +NUMBER    +         JFCB TTR               +                  07300018
*        + OF VOLS  +         ADDRESS                +                  07400018
*        +++++++++++++++++++++++++++++++++++++++++++++ 12               07500018
*                                                                       07600018
*     12 +++++++++++++++++++++++                                        07700018
*        +TAPE LABL + FILE SEQ +        DEVICE = TAPE                   07800018
*        +INFO BYTE + NUMBER   +                                        07900018
*        +++++++++++++++++++++++                                        08000018
*                                                                       08100018
*     12 +++++++++++++++++++++++                                        08200018
*        +    OLD   TIOT       +        DA AND UNIT RECORD              08300018
*        +      OFFSET         +                                        08400018
*        +++++++++++++++++++++++                                        08500018
*                                                                       08600018
*                              +++++++++++++++++++++++                  08700018
*                              +FLAG BYTE +FLAG BYTE +                  08800018
*                              +  NO. 2   +  NO. 3   +                  08900018
*     16 +++++++++++++++++++++++++++++++++++++++++++++                  09000018
*        +FLAG BYTE +FLAG BYTE +                     +                  09100018
*        + NO. 4    + NO. 5    +   VOLUME ID NO. 1   +                  09200018
*        +++++++++++++++++++++++                     + 20               09300018
*        +                                           +                  09400018
*        +                                           +                  09500018
*     24 +++++++++++++++++++++++++++++++++++++++++++++                  09600018
*        +                                           +                  09700018
*        +   VOLUME ID NO. 2                         +                  09800018
*        +                     +++++++++++++++++++++++ 28               09900018
*        +                     +                     +                  10000018
*        +                     +   VOLUME ID NO. 3   +                  10100018
*     32 +++++++++++++++++++++++                     +                  10200018
*        +                                           +                  10300018
*        +                                           +                  10400018
*        +++++++++++++++++++++++++++++++++++++++++++++ 36               10500018
*        +                                           +                  10600018
*        +   VOLUME ID NO. 4                         +                  10700018
*     40 +                     +++++++++++++++++++++++                  10800018
*        +                     +                     +                  10900018
*        +                     +                     +                  11000018
*        +++++++++++++++++++++++   VOLUME ID NO. 5   + 44               11100018
*        +                                           +                  11200018
*        +                                           +                  11300018
*        +++++++++++++++++++++++++++++++++++++++++++++ 48               11400018
*                                                                       11500018
*                                                                       11600018
*ATTRIBUTES-   RE-ENTRANT                                               11700018
*              RE-USABLE                                                11800018
*              ENABLED                                                  11900018
*              PRIVILEGED                                               12000018
*                                                                       12100018
*********************************************************************** 12200018
*                                                                       12300018
*    REGISTER CONVENTION TO BE USED THRU-OUT REPI/O PHASE               12400018
*                                                                       12500018
*********************************************************************** 12600018
*                                                                       12700018
WRKR1    EQU   0                        WDRK/PARAMETER REGISTER         12800018
WRKR2    EQU   1                        WDRK/PARAMETER REGISTER         12900018
DCBR     EQU   2                        CURRENT DCB REGISTER            13000018
BASER    EQU   3                        BASE REGISTER                   13100018
DEBR     EQU   4                        CURRENT DEB REGISTER            13200018
UCBR     EQU   5                        CURRENT UCB REGISTER            13300018
TIOTR    EQU   6                        NEW TIOT REGISTER               13400018
TCBR     EQU   7                        TCB REGISTER                    13500018
TABLR    EQU   8                        BEGINNING TO DCB TABLE REG      13600018
CTABLR   EQU   9                        CURRENT ENTRY IN DCB TABLE      13700018
BUFR     EQU   10                       USER BUFFER AREA                13800018
DSCNTR   EQU   11                       WORK REGISTER                   13900018
WRKR3    EQU   12                       WORK REGISTER                   14000018
WRKR4    EQU   13                       WORK REGISTER                   14100018
WRKR5    EQU   14                       WORK/PARAMETER REGISTER         14200018
WRKR6    EQU   15                       WORK/PARAMETER REGISTER         14300018
*                                                                       14400018
*********************************************************************** 14500018
*                                                                       14600018
*    OFFSETS TO BE USED IN REPI/O PHASE                                 14700018
*                                                                       14800018
*********************************************************************** 14900018
*                                                                       15000018
IS       EQU   X'80'                    INDEXED SEQUENCIAL              15003018
PS       EQU   X'40'                    PHYSICAL SEQUENCIAL             15006018
DA       EQU   X'20'                    DIRECT ACCESS                   15009018
PO       EQU   X'02'                    PARTITIONED ORGANIZATION        15012018
NULL     EQU   X'80'                    NULLFILE OR SYSCHECK            15015018
INOROUT  EQU   X'40'                    SYSIN OR SYSOUT DATA SET        15018018
DADEV    EQU   X'20'                    DA DEVICE                       15021018
TPDEV    EQU   X'10'                    TAPE DEVICE                     15024018
LASTENT  EQU   X'08'                    LAST ENTRY                      15027018
UNITREC  EQU   X'04'                    UNIT RECORD EQUIPMENT           15030018
ERRINNSL EQU   X'80'                    ERROR IN NSL ROUTINE            15033018
NSLMTSW  EQU   X'40'                    NSL MOUNT SWITCH                15036018
NSLCOMU  EQU   X'20'                    NSL COMMUNICATION BIT           15039018
BYPASS   EQU   X'10'                    BYPASS LABEL PROCESSING         15042018
NSL      EQU   X'04'                    NON-STANDARD LABEL              15045018
SL       EQU   X'02'                    STANDARD LABEL                  15048018
NL       EQU   X'01'                    NO LABEL                        15051018
GTR5VOL  EQU   X'80'                    GREATER THAN 5 VOLUMES          15054018
POCONCAT EQU   X'40'                    P.O. CONCATENATED               15057018
DAFLAG   EQU   X'80'                    DA DATA SET FLAG                15060018
NONDAFLG EQU   X'40'                    NON-DA DATA SET FLAG            15063018
NSLFLAG  EQU   X'10'                    NSL ROUTINE FLAG                15066018
TYPERST  EQU   X'80'                    IMMEDIATE RESTART               15069018
TABENT   EQU   48                       TABLE ENTRY LENGTH              15072018
WRITE    EQU   X'01'                    WRITE ON TAPE                   15075018
READ     EQU   X'02'                    READ FOR TAPE                   15078018
NOPOP    EQU   X'03'                    NOP                             15081018
SENSE    EQU   X'04'                    SENSE                           15084018
REWIND   EQU   X'07'                    REWIND                          15087018
READBACK EQU   X'0C'                    READBACK                        15090018
UNLOAD   EQU   X'0F'                    REWIND AND UNLOAD               15093018
WTM      EQU   X'1F'                    WRITE TAPE MARK                 15096018
BSFOP    EQU   X'2F'                    BACKWARD SPACE FILE             15099018
FSFOP    EQU   X'3F'                    FORWARD SPACE FILE              15102018
SEARCH   EQU   X'31'                    SEARCH                          15105018
SRCHCNT  EQU   X'05'                    COUNT FOR SEARCH ID             15108018
TIC      EQU   X'08'                    TIC                             15111018
READDA   EQU   X'06'                    READ FOR DA                     15114018
LENJFCB  EQU   X'B0'                    LENGTH OF JFCB                  15117018
LBLLEN   EQU   X'50'                    LENGTH OF LABEL                 15120018
PERMERR  EQU   X'7F'                    PERMANENT ERROR                 15123018
ERR72    EQU   72                       I/O ERROR FOR READING IN DSCB   15126018
ERR76    EQU   76                       XTENTS OR LAST TTR'S UNEQUAL    15129018
*                                           DEB VS DSCB                 15132018
ISORDA   EQU   IS+DA                    IS OR DA                        15135018
IOERROR  EQU   X'20'                    PERMANENT I/O ERROR             15138018
FILETYPE EQU   X'00'                    FILE TYPE BYTE                  15141018
THREE    EQU   X'03'                    TEST IF DSCB EXTN IS TO BE READ 15144018
READKND  EQU   X'0E'                    READ KEY AND DATA               15147018
LENGTH   EQU   X'8C'                    LENGTH OF KEY AND DATA          15150018
OUTP     EQU   X'0F'                    OUTPUT (DEBOPATB)               15153018
EXCHPGM  EQU   X'80'                    EXCP                            15156018
DADEVDPT EQU   X'0C'                    DA DEVICE DEPENDENT SECTION     15159018
WRITEDA  EQU   X'05'                    WRITE FOR DA                    15162018
SEVEN    EQU   X'07'                    TEST FOR GETTING UPPER LIMIT    15165018
LENDSCB  EQU   X'60'                    LENGTH OF DSCB                  15168018
DEBID    EQU   X'0F'                    DEB IDENTIFICATION              15171018
MAXEXT   EQU   X'CA'                    MAXIMUM NO. OF EXTENT           15174018
UNREL    EQU   X'02'                    UNRELATED FLAG                  15177018
TKBAL    EQU   25                       TRACK BALANCE SVC ROUTINE       15180018
CIND2PCI EQU   X'04'                    DCBCIND2 PCI CHAIN SCHED A29797 15190020
*                                                                       15200018
*                                                                       15260018
*********************************************************************** 15320018
*                                                                       15400018
         BALR  BASER,0                  ESTABLISH ADDRESSIBILITY        15500018
         USING REPDCB00,BASER                                           15600018
*                                                                       15700018
         USING RSTWA,BUFR                                               15800018
         USING IHADCB,DCBR                                              15900018
         USING TABL,CTABLR                                              16000018
         USING FORECORE,UCBR                                            16100018
         USING TCB,TCBR                                                 16200018
         USING DEB,DEBR                                                 16300018
         USING CVT,WRKR2                                                16400018
*                                                                       16600018
REPDCB00 EQU   *                                                        16700018
*                                                                       16800018
         TM    TABFLG2-TABL(TABLR),NSLCOMU TEST FOR RETURN FROM PAR REL 16900018
         BO    REPDCB54                 YES - BRANCH                    17000018
*                                                                       17100018
         LR    CTABLR,TABLR             INITIALIZE CTABLR               17200018
         L     UCBR,TABSEGAD-1          INITIALIZE FORECORE DSECT REG   17300018
         B     REPDCB02                 BRANCH TO TEST FOR TYPE OF D.S. 17400018
*                                                                       17500018
*********************************************************************   17600018
*                                                                       17700018
******** TEST FOR PS, PO, OR EXCP DATA SET                              17800018
*                                                                       17900018
*********************************************************************   18000018
*                                                                       18100018
REPDCB01 EQU   *                                                        18200018
*                                                                       18300018
         LA    CTABLR,TABENT(CTABLR)    POINT TO NEXT TABL ENTRY        18400018
*                                                                       18500018
REPDCB02 EQU   *                                                        18600018
*                                                                       18700018
         TM    TABDSORG,DA+IS           BDAM OR ISAM DATA SET    M0187  18760021
         BZ    REPDCB03                 BRANCH IF NOT            A25984 18820019
REPDCB05 EQU   *                                                 A30552 18830020
         MVI   RSRETCOD+1,X'FF'         SET ISAM FLAG            A25984 18850019
         B     REPDCB04                 GET NEXT DCB             A25984 18880019
REPDCB03 EQU   *                                                 A25984 18910019
         TM    TABFLG2,POCONCAT         TEST FOR PO CONCATENATION       19000018
         BO    REPDCB04                 YES - BRANCH                    19100018
         TM    TABFLG1,DADEV            TEST FOR A DA DEVICE            19200018
         BO    REPDCB10                 YES - BRANCH                    19300018
*                                                                       19400018
REPDCB04 EQU   *                                                        19500018
*                                                                       19600018
         TM    TABFLG1,LASTENT          TEST FOR LAST ENTRY             19700018
         BO    ENDUP                    YES - BRANCH                    19800018
*                                                                       19900018
         B     REPDCB01                 GO TEST TABL ENTRY              20000018
*                                                                       20100018
REPDCB10 EQU   *                                                        20200018
*                                                                       20300018
*********************************************************************   20400018
*                                                                     * 20500018
******** DEVICE = DA, ORGN = PS, PO, OR EXCP                          * 20600018
*                                                                     * 20700018
******** THIS SECTION OF CODE BUILDS THE 464 BYTE WORKAREA FOR READING* 20800018
*        IN THE DSCB FOR DATA SETS WHICH MIGHT REQUIRE A PARTIAL      * 20900018
*        RELEASE                                                      * 21000018
*                                                                     * 21100018
*********************************************************************   21200018
*                                                                       21300018
         XC    0(232,UCBR),0(UCBR)      CLEAR 1ST 232 BYTES             21400018
         XC    232(232,UCBR),232(UCBR)  CLEAR NEXT 232 BYTES            21500018
         BAL   WRKR5,BLDCCWS            BRANCH TO BUILD CCW LIST SBRTN  21600018
*                                                                       21700018
         LA    WRKR5,REPDCB22           SET UP FOR BYPASS        A29797 21800020
*                                                                       21900018
REPDCB20 EQU   *                                                        22000018
*                                                                       22100018
*********************************************************************   22200018
*                                                                       22300018
******** READ THE DSCB                                                  22400018
*                                                                       22500018
*********************************************************************   22600018
*                                                                       22700018
         EXCP  DXIOB                                                    22800018
*                                                                       22900018
*********************************************************************   23000018
*                                                                       23100018
******** WAIT FOR COMPLETION OF READ                                    23200018
*                                                                       23300018
*********************************************************************   23400018
*                                                                       23500018
         WAIT  ,ECB=DXECB                                               23600018
*                                                                       23700018
         TM    DXECB,IOERROR            TEST FOR PERM I/O ERROR         23800018
         BZ    REPDCB68                 BRANCH IF ERROR           M3251 24000018
*                                                                       24200018
         BR    WRKR5                    BRANCH BACK TO CALLER    A29797 24300020
*                                                                       24400018
*********************************************************************   24500018
*                                                                       24600018
******** THE DSCB HAS BEEN SUCCESSFULLY READ                            24700018
*                                                                       24800018
*********************************************************************   24900018
*                                                                       25000018
******** ******     ***** *****  ********  ************     *********** 25007018
*                   -UPDATE PP CHECKPOINT DCB-                        * 25014018
*                                                                     * 25021018
* AT RESTART THE FULL DISK ADDR AND TRK BALANCE IN THE PP DCB MUST BE * 25028018
* UPDATED.THE FULL DISK ADDR FROM THE CHKPT DCB IN THE RESTART WKAREA * 25035018
* AND THE TRK BALANCE FROM THE DSCB.                                  * 25042018
******** ******     ***** *****  ********  ************     *********** 25049018
*                                                                       25056018
REPDCB22 EQU   *                                                 A29797 25059020
         MVC   DXCCW4(44),DXDSCB        SAVE KEY PORTION OF F1  SA54549 25061021
*                                       FOR PARTIAL RELEASE     SA54549 25061421
         MVC   DXDSCB,DXDSCB+44         REPOSITION DATA         SA54549 25061821
*                                       PORTION OF F1           SA54549 25062221
         CLC   1(3,CTABLR),RSCKDCB+1    IS THIS THE CHKPT DCB           25063018
         BNE   REPDCB24                 BRANCH IF NO             A29797 25072020
*                                                                       25081020
         MVC   DCBFDAD,RSBDCB+DCBFDAD-IHADCB UPDATE PP DISK ADDR A29797 25090020
*                                                                       25099020
*              SET UP ECB TO BE POSTED BY SVC 25'S EXCP.                25108020
*              THE IOB, LAST USED DURING CHECKPOINT, POINTS TO THE OLD  25117020
*              CHECKPOINT DECB, WHICH IS NOT THE DECB FOR RESTART.      25126020
*                                                                       25135020
         L     WRKR6,DCBIOBA            ADDR NORMAL IOB PREFIX   A29797 25144020
*                                                                       25153020
         TM    DCBCIND2,CIND2PCI        TEST IF CHAINED SCHEDULE A29797 25162020
         BZ    REPDCB23                 BRANCH IF NO             A29797 25171020
*                                                                       25180020
         L     WRKR6,DCBIOBAD           ADDR CH SCHD IOB PREFIX  A29797 25189020
         LA    WRKR6,8(WRKR6)           ADJUST TO NORMAL IOB PFX A29797 25198020
*                                                                       25207020
REPDCB23 EQU   *                                                 A29797 25216020
         LA    WRKR1,RSECB1             ADDR OF ECB TO BE POSTED A29797 25225020
         ST    WRKR1,IOBECBPT-IOBFLAG1+8(WRKR6)  PUT ADDR IN IOB A29797 25234020
*                                                                       25243020
         LA    WRKR2,0(DCBR)            LOAD PP DCB ADDR FOR SVC A29797 25252020
         SVC   TKBAL                    ISSUE TRACK BALANCE SVC  A29797 25261020
*                                                                       25270020
REPDCB24 EQU   *                                                        25300018
*                                                                       25400018
         CLI   DSCFILTY,FILETYPE        IS FILE TYPE BYTE EQ ZEROS      25500018
         BE    REPDCB2A                 YES - BRANCH                    25600018
*                                                                       25700018
         MVC   TABDSORG(1),DSCFILTY     OVERLAY TABL DS ORGN BYTE       25800018
*                                                                       25900018
REPDCB2A EQU   *                                                        26000018
*                                                                       26100018
         L     DEBR,DCBDEBAD            POINT TO DEB                    26200018
         IC    DSCNTR,DSCNOEXT          GET NUMBER OF DSCB EXTS   M3251 26240018
         CLI   DSCEXTYP,X'40'           USER LABELS PRESENT       M3251 26280018
         BNE   REPDCB2B                 NO, BRANCH                M3251 26320018
         LA    DSCNTR,1(0,DSCNTR)       ALLOW FOR USER LABEL EXT  M3251 26360018
REPDCB2B CLI   DSCNEXT+4,X'00'          IS A DSCB EXTN PRESENT    M3251 26400018
         BE    REPDCB25                 NO, BRANCH                M3251 26440018
*                                                                       26500018
         LA    WRKR6,DXJBF              POINT TO THE JFCB READ AREA     26600018
         ST    WRKR6,DXCCW3             STORE IN CCW 3                  26700018
         MVI   DXCCW3,READKND           SET CCW TO READ KEY AND DATA    26800018
         MVC   DXDAADDR+3(5),DSCNEXT    MOVE CCHHR OF F3 DSCB TO IOB    27000018
*                                                                       27100018
         BAL   WRKR5,REPDCB20           BRANCH (WITH LINK) TO READ F3   27200018
*                                                                       27300018
REPDCB25 EQU   *                                                        27400018
*                                                                       27500018
         STC   DSCNTR,EXTNO             SAVE NO. OF DSCB EXTENTS  M3251 27550018
         CLC   DSCNOEXT(1),DEBNMEXT     ARE NO. OF EXTENTS EQUAL        27600018
         BE    REPDCB60                 YES - BRANCH                    27700018
*                                                                       27800018
*********************************************************************   27900018
*                                                                     * 28000018
******** THIS PORTION OF THIS MODULE TESTS TO DETERMINE IF A PARTIAL  * 28100018
*        RELEASE IS NECESSARY, AND IF IT IS IT SETS UP FOR THE XCTL   * 28200018
*        TO THE PARTIAL RELEASE MODULES.  IT ALSO CONTAINS CODE TO    * 28300018
*        ALTER THE DEB SO THAT IT IS IN AGREEMENT WITH THE FOREMAT 1  * 28400018
*        DSCB WHEN THE TASK IS RESTARTED.                             * 28500018
*                                                                     * 28600018
*********************************************************************   28700018
*                                                                       28800018
REPDCB26 EQU   *                                                        28900018
*                                                                       29000018
*********************************************************************   29100018
*                                                                     * 29200018
******** NUMBER OF EXTENTS IN DEB AND DSCB ARE UNEQUAL                * 29300018
*                                                                     * 29400018
*********************************************************************   29500018
*                                                                       29600018
         BH    REPDCB50                 BRANCH - DSCB XTNT GREATER DEB  29700018
*                                                                       29800018
*********************************************************************   29900018
*                                                                     * 30000018
******** A PARTIAL RELEASE HAS OCCURED SINCE CHECKPOINT SINCE DEB NO. * 30100018
*        OF EXTENTS IS GREATER.                                       * 30200018
*                                                                     * 30300018
*********************************************************************   30400018
*                                                                       30500018
         BAL   WRKR5,REPDCB76           BRANCH  DEB XTNT GREATER DSCB   30600018
*                                                                       30700018
*********************************************************************   30800018
*                                                                       30900018
******** NOW COMPRESS AND UPDATE THE DEB                                31000018
*                                                                       31100018
*********************************************************************   31200018
*                                                                       31300018
         SR    WRKR4,WRKR4              CLEAR WRKR4                     31400018
         SR    WRKR6,WRKR6              CLEAR WRKR6                     31500018
         IC    WRKR4,DSCNOEXT           INSERT DSCB NO. OF EXTENTS      31600018
         IC    WRKR6,DEBNMEXT           INSERT DEB NO. OF EXTENTS       31700018
         LR    TCBR,WRKR6               SAVE DEB NMEXTNTS               31800018
         SR    TCBR,WRKR4               SUB DSCNOEXT FROM DEBNMEXT      31900018
         SLL   TCBR,1                   MULT DIFF BY 2 (LNTH IN DBLWDS) 32000018
*                                                                       32100018
*********************************************************************   32200018
*                                                                     * 32300018
******** TCBR  NOW CONTAINS THE NO. DBL WRDS TO BE DELETED FROM THE   * 32400018
*        DEB IN QUESTION                                              * 32500018
*                                                                     * 32600018
*********************************************************************   32700018
*                                                                       32800018
         LA    WRKR2,4                  LOAD A '4' INTO WRKR2           32900018
         LR    WRKR3,DEBR               GET THE DEB ADDR                33000018
         SR    WRKR3,WRKR2              SUB 4 FROM DEB ADDR             33100018
*                                                                       33200018
*********************************************************************   33300018
*                                                                     * 33400018
******** WRKR3 NOW POINTS TO THE 1-BYTE LENGTH OF DEB (IN DBL WORDS)  * 33500018
*                                                                     * 33600018
*********************************************************************   33700018
*                                                                       33800018
         IC    TIOTR,0(WRKR3)           LOAD LENGTH IN TIOTR            33900018
         SR    TIOTR,TCBR               AMT OF DOUBLE WDS TO DELETE     34100018
         STC   TIOTR,0(WRKR3)           STORE LENGTH BACK IN DEB PREFIX 34200018
         STC   WRKR4,DEBNMEXT           UPDATE NO. EXTS. IN DEB         34300018
*                                                                       34400018
         SLL   WRKR4,4                  GET DSCNOEXT IN BYTES           34600018
         SLL   WRKR6,4                  GET DEBNMEXT IN BYTES           34700018
*                                                                       34900018
*********************************************************************   35000018
*                                                                     * 35100018
******** GET LENGTH OF THE ACCESS METHOD PORTION OF THE DEB SO THAT IT* 35200018
*        CAN OVERLAY THE EXTENTS TO BE DELETED, THUS COMPRESSING THE  * 35300018
*        DEB                                                          * 35400018
*                                                                     * 35500018
******** WRKR3 NOW CONTAINS LENGTH TO BE MOVED                        * 35600018
*                                                                     * 35700018
*********************************************************************   35800018
*                                                                       35900018
         LA    WRKR2,DEBDVMOD           GET ADDR OF START OF DEVDP SEC  36000018
         LA    WRKR6,0(WRKR2,WRKR6)     POINT WRKR6 TO START OF AM SEC  36100018
         LA    WRKR2,0(WRKR4,WRKR2)     POINT TO NEW AM START ADDR      36200018
         SR    WRKR3,WRKR3              CLEAR WRKR3                     36300018
         IC    WRKR3,DEBAMLNG           INSERT ACC METHOD SEC LENGTH    36400018
         LA    WRKR3,20(WRKR3)          ADD 20 BYTES                    36500018
         EX    WRKR3,CLOSEUP            EXECUTE THE MOVE                36600018
*                                                                       36700018
*********************************************************************   36800018
*                                                                       36900018
******** END OF DEB COMPEESSION AND RE-FORMATTING                       37000018
*                                                                       37100018
*********************************************************************   37200018
*                                                                       37300018
         B     REPDCB04                 BRANCH TO PROCESS NEXT ENTRY    37400018
*                                                                       37500018
*********************************************************************   37600018
*                                                                     * 37700018
******** THE FOLLOWING ROUTINE IS ENTERED IF THE NO. OF EXTENTS IN    * 37800018
*        THE DSCB IS GREATER THAN THE NO. OF EXTENTS IN THE DEB.      * 37900018
*        THIS MEANS THAT ADDITIONAL DA SPACE WAS DYNAMICALLY ALLOCATED* 38000018
*        AFTER THE CHECKPOINT OCCURRED AND HENCE A PARTIAL RELEASE    * 38100018
*        OF THIS ADDITIONAL SPACE IS NECESSARY.                       * 38200018
*                                                                     * 38300018
*********************************************************************   38400018
*                                                                       38500018
REPDCB50 EQU   *                                                        38600018
*                                                                       38700018
         TM    DEBOPATB,OUTP            IS DATA SET OPEN FOR INPUT      38800018
         BZ    REPDCB70                 YES - BR OUT                    38900018
*                                                                       39000018
         TM    DCBMACRF,EXCHPGM         IS THIS DATA SET EXCP           39100018
         BZ    REPDCB52                 NO - BRANCH                     39200018
*                                                                       39300018
         TM    DCBMACRF+1,DADEVDPT      TEST FOR DA DEVICE DEPNDT SEC   39400018
         BZ    REPDCB70                 BRANCH IF NOT PRESENT           39500018
*                                                                       39600018
REPDCB52 EQU   *                                                        39700018
*                                                                       39800018
*********************************************************************   39900018
*                                                                     * 40000018
******** CONVERT RTN INTERFACE (CCHHR TO TTR) FOLLOWS                 * 40100018
*                                                                     * 40200018
*********************************************************************   40300018
*                                                                       40400018
         STM   WRKR2,WRKR6,DXDSCB+480   SAVE REGISTERS 1-15             40500018
         L     WRKR2,CVTPTR             INITIALIZE CVT REGISTER   M3251 40600018
         L     WRKR6,CVTPRLTV           POINT TO CONVERT RTN            40800018
         L     WRKR2,DCBDEBAD           POINT TO DEB                    40900018
         LA    DCBR,DCBFDAD             POINT TO FULL DISK ADDR         41000018
         BALR  WRKR5,WRKR6              BR AND LINK TO CONVERT RTN      41100018
*                                                                       41200018
         LM    WRKR2,WRKR6,DXDSCB+480   RESTORE REGISTERS 1-15 (NOT 0)  41300018
         ST    WRKR1,DXDAADDR           STORE TTR IN WORKAREA           41400018
*                                                                       41500018
*********************************************************************   41600018
*                                                                     * 41700018
******** MODIFY LAST TRACK USED FIELD IN DSCB                         * 41800018
*                                                                     * 41900018
*********************************************************************   42000018
*                                                                       42100018
         MVC   DSCLSTAR(3),DXDAADDR     MOVE IN TTR                     42200018
         MVC   DSCLSTAR+3(2),DCBTRBAL   MOVE IN REMAINING BYTES-LASTTRK 42300018
         MVC   DXDSCB+500(8),DCBFDAD    SAVE FULL DISK ADDR             42400018
*                                                                       42500018
         SR    WRKR3,WRKR3              CLEAR WRKR3                     42600018
         IC    WRKR3,DEBNMEXT           INSERT NO. OF EXTENTS           42700018
         BCTR  WRKR3,0                  DECREMENT COUNT BY 1            42800018
         STC   WRKR3,DCBFDAD            STORE NO. XTNTS-1 IN 'M'        42900018
         SLL   WRKR3,4                  MULT BY 16                      43000018
         LA    WRKR6,DEBENDCC(WRKR3)    POINT TO ENDING CCHH IN LST EXT 43100018
         MVC   DCBFDAD+3(4),0(WRKR6)    MOVE IN CORRECT CCHH            43200018
*                                                                       43300018
*********************************************************************   43400018
*                                                                     * 43500018
******** THE NEXT 2 INSTRUCTIONS SET ON THE HIGH ORDER BIT IN DEBR SO * 43600018
*        THAT THE PARTIAL RELEASE MODULES WILL RETURN CONTROL         * 43700018
*        BACK TO THIS MODULE AND NOT RETURN TO CLOSE.  DEBR IS THEN   * 43800018
*        POINTED AT THE CLOSE-TYPE WORKAREA EXPECTED BY PARTIAL REL.  * 43900018
*                                                                     * 44000018
*********************************************************************   44100018
*                                                                       44200018
         LA    DEBR,1                   TURN ON LOW ORDER BIT           44300018
         SLL   DEBR,31                  SHIFT TO HIGH ORDER POSITION    44400018
         OR    DEBR,UCBR                POINT DEBR AT CLOSE WORKAREA    44500018
         MVC   JFCBDSNM,DXCCW4          PARTIAL RELEASE EXPECTS SA54549 44550021
*                                       THE KEY PORTION OF THE  SA54549 44560021
*                                       F1 AT THIS POSITION IN  SA54549 44570021
*                                       THE WORKAREA            SA54549 44580021
         OI    TABFLG2-TABL(TABLR),NSLCOMU SET ON PAR RLSE SWITCH       44600018
         L     TCBR,RSTCBAD             LOAD TCB ADDRESS                44710018
         L     WRKR2,TCBTIO             LOAD TIOT ADDRESS               44720018
         LH    TIOTR,DCBTIOT            LOAD TIOT OFFSET                44730018
         LR    TCBR,BUFR                SAVE CONTENTS OF BUFR           44740018
         L     BUFR,16(WRKR2,TIOTR)     LOAD SUB UCB ADDRESS            44750018
         B     XCTL                     BRANCH TO XCTL RTN              44800018
*                                                                       44900018
REPDCB54 EQU   *                                                        45000018
*                                                                       45100018
*********************************************************************   45200018
*                                                                     * 45300018
******** UPON RE-ENTRY OF THIS MOD FROM THE PARTIAL RELEASE ROUTINE   * 45400018
*        CONTROL IS PASSED TO THIS ROUTINE FOR POST-PARTIAL RELEASE   * 45500018
*        PROCESSING.                                                  * 45600018
*                                                                     * 45700018
*********************************************************************   45800018
*                                                                       45900018
         LR    BUFR,TCBR                RESTORE BUFR                    45960018
         NI    TABFLG2-TABL(TABLR),X'DF' TURN OFF PAR. REL SWITCH       46020018
         MVC   DCBFDAD(8),DXDSCB+500    RESTORE FULL DISK ADDR          46100018
         LTR   WRKR2,WRKR2              IS THERE AN ERROR RETURN CODE   46200018
         BNZ   REPDCB68                 BR IF ERR CODE PRESENT  SA54549 46300021
*                                                                       46400018
         B     REPDCB04                 BR IF ERROR CODE        SA54549 46420021
*                                       NOT PRESENT             SA54549 46430021
*                                                                       49100018
REPDCB60 EQU   *                                                        49200018
*                                                                       49300018
         BAL   WRKR5,REPDCB76           BRANCH TO DEB UPDATE SUBRTN     49400018
*                                                                       49500018
         B     REPDCB04                 GET NEXT TABL ENTRY             49600018
*                                                                       49700018
REPDCB68 EQU   *                                                        49800018
*                                                                       49900018
*********************************************************************** 50000018
*                                                                     * 50100018
******** THIS ROUTINE IS ENTERED FOR ANY I/O ERROR FOR DSCB (FORMAT   * 50200018
*        1 OR FORMAT 3 ).                                             * 50300018
*                                                                     * 50400018
*********************************************************************** 50500018
*                                                                       50600018
         MVI   RSRETCOD+1,ERR72         SET I/O ERROR RETURN CODE       50700018
         B     SETV05B                  SET UP TO XCTL TO V05B   M0187  50800021
*                                                                       51000018
REPDCB70 EQU   *                                                        51100018
*                                                                       51200018
         MVI   RSRETCOD+1,ERR76         SET ERR CODE - XTENTS OR LAST   51300018
*                                       TTR'S UNEQUAL - DEB VS DSCB     51400018
*                                                                       51450021
SETV05B  EQU   *                                                 M0187  51500021
         LA    WRKR3,C'V'               SET XCTL TO V05B         M0187  51550021
         B     PREXCTL                  GO SET FOR XCTL          M0187  51620021
*                                                                       51700018
ENDUP    EQU   *                                                        51800018
*                                                                       51900018
         LA    WRKR3,C'T'               SET UP TO XCTL TO T05B   M0187  51970021
         CLI   RSRETCOD+1,X'FF'         SHOULD ISAM BE ENTERED   A25984 52050019
         BNE   PREXCTL                  GO SET IGC XCTL          M0187  52060021
         LA    WRKR3,C'W'               SET XCTL TO W05B         M0187  52070021
*                                                                       52080021
PREXCTL  EQU   *                                                 M0187  52090021
         LA    TIOTR,DXDSCB+464         SET WORK AREA FOR XCTL   M0187  52100021
         MVC   0(8,TIOTR),IGC           MOVE IGC MODULE FOR XCTL M0187  52110021
FOUR     EQU   *+2                                               M0187  52120021
         STC   WRKR3,4(TIOTR)           ADJUST TO T, W, OR V05B  M0187  52130021
         B     NOWXCTL                  GO XCTL                  M0187  52140021
*                                                                       52200018
XCTL     EQU   *                                                        52300018
*                                                                       52400018
         LA    TIOTR,DXDSCB+464         SETUP WORKAREA FOR XCTL         52500018
         MVC   0(8,TIOTR),IGG           SET XCTL TO IGG MODULE   M0187  52540021
*                                                                       52580021
NOWXCTL  EQU   *                                                 M0187  52620021
EIGHT    EQU   *+2                                               M0187  52660021
         LA    WRKR6,8(TIOTR)           INITIALIZE WRKR6 (REG 15)       52700018
*                                                                       52800018
*********************************************************************   52900018
         LR    WRKR2,BUFR               POINT REG 1 TO THE RESTART W/A  53000018
*********************************************************************   53100018
*                                                                       53150018
         XCTL  EPLOC=(TIOTR),SF=(E,(15))                                53200018
*                                                                       53300018
*********************************************************************   53400018
*                                                                       53500018
******** THIS IS THE START OF THE DEB COMPRESSION AND MODIFICATION      53600018
*        SUBROUTINE                                                     53700018
*                                                                       53800018
*********************************************************************   53900018
*                                                                       54000018
REPDCB76 EQU   *                                                        54100018
*                                                                       54200018
         SR    WRKR3,WRKR3              CLEAR WRKR3                     54300018
         IC    WRKR3,EXTNO              GET NO. OF EXTENTS        M3251 54400018
         CLI   EXTNO,THREE              TEST IF GREATER THAN 3    M3251 54500018
         BH    REPDCB80                 YES BRANCH                      54700018
*                                                                       54800018
         BCTR  WRKR3,0                  SUBT 1 FROM NO. OF EXTENTS      54900018
         MH    WRKR3,TEN                MULTIPLY BY 10                  55000018
         LA    WRKR4,DSCUPPLM(WRKR3)    GET ADDR OF UPPER LIM 1ST XTNT  55100018
*                                       TO BE MOVED TO DEB              55200018
         B     REPDCB82                 BRANCH TO CALCULATE DEB XT ADDR 55300018
*                                                                       55400018
REPDCB78 EQU   *                                                        55500018
*                                                                       55600018
         SH    WRKR3,FOUR                                        M0187  55700021
         MH    WRKR3,TEN                MULTIPLY DIFF BY 10             55900018
         LA    WRKR4,110(UCBR,WRKR3)    GET ADDR OF UP LIM 4TH XTNT     56000018
         B     REPDCB82                 BRANCH TO CALCULATE DEB XT ADDR 56100018
*                                                                       56200018
REPDCB80 EQU   *                                                        56300018
*                                                                       56400018
         CLI   EXTNO,SEVEN              TEST FOR LESS THAN 7      M3251 56500018
         BNH   REPDCB78                 BR IF LESS                      56600018
*                                                                       56700018
         SH    WRKR3,EIGHT    SUB 8 FROM NO OF EXTENTS           M0187  56800021
         MH    WRKR3,TEN                MULT BY 10                      57000018
         LA    WRKR4,151(UCBR,WRKR3)    LOAD ADDR OF 8TH CCHH (UP LIM)  57100018
*                                       CCHH TO BE PLACED IN DEB        57200018
REPDCB82 EQU   *                                                        57300018
*                                                                       57400018
         LR    WRKR3,WRKR4              PUT ADDR IN WRKR3               57500018
*                                                                       57600018
*********************************************************************   57700018
*                                                                     * 57800018
******** WRKR3 CONTAINS THE ADDR OF THE UPPER LIMIT CCHH WHICH IS TO  * 57900018
*        BE PLACED INTO THE DEB.  NOW CALCULATE DEB EXTENT ADDR WHICH * 58000018
*        IS TO BE UPDATED.                                            * 58100018
*                                                                     * 58200018
*********************************************************************   58300018
*                                                                       58400018
         SR    WRKR4,WRKR4              CLEAR WRKR4                     58500018
         IC    WRKR4,DEBNMEXT           INSERT NO OF EXTENTS INTO WRKR4 58600018
         BCTR  WRKR4,0                  DECREMENT COUNT BY 1            58700018
         STC   WRKR4,DXDSCB+464         STORE M IN WORKAREA      A25984 58750019
         SLL   WRKR4,4                  MULTIPLY BY 16                  58800018
         LA    WRKR4,DEBENDCC(WRKR4)    ADD BASE PLUS OFFSET            58900018
*                                                                       59000018
*********************************************************************** 59100018
*                                                                     * 59200018
******** THE NEXT ROUTINE CONVERTS BOTH MBBCCHHR'S TO TTR'S AND       * 59300018
*        COMPARES TO SEE IF DEBENDCC IS GREATER THAN DSCB ENDING CCHH * 59400018
*        IF IT IS AND DS IS OPEN FOR INPUT AN ERROR CONDITION EXISTS  * 59500018
*                                                                     * 59600018
*********************************************************************** 59700018
*                                                                       59800018
         STM   WRKR1,WRKR6,DXDSCB+480   SAVE ALL REGISTERS              59900018
*                                                                       60000018
         L     WRKR2,CVTPTR             GET CVT ADDRESS                 60100018
         L     WRKR6,CVTPRLTV           GET CONVERT (MBB TO TTR) RTN AD 60200018
         LR    WRKR2,DEBR               POINT WRKR2 TO DEB              60300018
         LA    DCBR,DXDSCB+464          POINT TO DEB MBBCCHHR           60400018
*                                                                       60500018
         MVC   DXDSCB+467(4),0(WRKR4)   MOVE CCHH TO WORKAREA           60800018
         LR    DEBR,WRKR6               SAVE CONVERT RTN ADDR           61300018
         BALR  WRKR5,WRKR6              GO TO CONVERT RTN               61400018
*                                                                       61500018
         LR    TCBR,WRKR1               SAVE DEB XTN TTR                61600018
         L     WRKR3,DXDSCB+528         REINITIALIZE WRKR3              61700018
         MVC   DXDSCB+467(4),0(WRKR3)   MOVE DSCB 'CCHH' TO WORKAREA    61800018
*                                                                       61900018
         LR    WRKR6,DEBR               RESTORE CONVERT RTN ADDR        62000018
         BALR  WRKR5,WRKR6              GO TO CONVERT RTN               62100018
*                                                                       62200018
         SRL   TCBR,16                  GET  NUMBER OF TRKS  DSCB       62300018
         SRL   WRKR1,16                 GET  NUMBER OF TRKS  DEB        62400018
         SR    TCBR,WRKR1               SUB DSCB TTR FROM DEB TTR       62500018
*                                                                       62600018
         LR    WRKR1,TCBR               PUT DIFF IN WRKR1 (REG 0)       62700018
         LM    WRKR2,WRKR6,DXDSCB+484   ALL BUT REG 0                   62800018
*                                                                       62900018
         BZ    CONTINUE                 BR IF EQ TO CONTINUE            63000018
*                                                                       63100018
         TM    DEBOPATB,OUTP            TEST FOR OPEN FOR INPUT         63200018
         BZ    REPDCB70                 YES - BR TO ERROR RTN           63300018
*                                                                       63400018
CONTINUE EQU   *                                                        63500018
*                                                                       63600018
*********************************************************************   63700018
*                                                                       63800018
******** DIFFERENCE IN TTRS BETWEEN DSCB AND DCB IN WRKR1 (R0)          63900018
******** DEB  ENDCCHH IS POINTED TO BY WRKR4 (RD)                       64000018
******** DSCB ENDCCHH IS POINTED TO BY WRKR3 (RC)                       64100018
*                                                                       64200018
*********************************************************************   64300018
*                                                                       64400018
         MVC   0(4,WRKR4),0(WRKR3)      UPDATE ENDING CCHH IN LAST DEB  64500018
*                                       EXTENT FIELD                    64600018
         LH    WRKR6,4(WRKR4)           OLD NO. TRKS IN EXT             64700018
         SR    WRKR6,WRKR1              COMPUTE NEW AMT OF TRKS IN EXT  64800018
         STH   WRKR6,4(WRKR4)           SAVE BACK IN DEB EXT FLD        64900018
*                                                                       65000018
         BR    WRKR5                    EXIT FROM SBRTN TO REPDCB63 OR  65100018
*                                       REPDCB26 BAL+4                  65200018
*                                                                       65300018
*********************************************************************   65400018
*                                                                       65500018
******** END OF UPDATE DEB SUBROUTINE                                   65600018
*                                                                       65700018
*********************************************************************** 65800018
*                                                                       65900018
BLDCCWS  EQU   *                                                        66000018
*                                                                       66100018
*********************************************************************** 66200018
*                                                                     * 66300018
***** THIS SUBRTN GETS THE DISK ADDR OF THE DSCB AND PUTS IT INTO THE * 66400018
*     WORKAREA AND THEN FINISHES CONSTRUCTING THE CCW LIST            * 66500018
*                                                                     * 66600018
******** WORKAREA IS CLEAR, SO BUILD CONTROL BLOCKS FOR READING DSCB'S* 66700018
*                                                                     * 66800018
*********************************************************************** 66900018
*                                                                       67000018
         L     WRKR2,CVTPTR             GET COMM VECTOR TABLE           67100018
         L     DCBR,CVTJOB              GET SYS JOB QUE DCB             67200018
         L     WRKR2,DCBDEBAD           GET SYS JOB QUE DEB             67300018
*                                                                       67400018
         MVC   DXDEB(48),0(WRKR2)       COPY SYS JOB QUE DEB INTO BUFR  67500018
         MVI   DXDEBNTR,X'7F'                                    M0187  67550021
*                                                                       67600018
         LA    WRKR1,DXDCB              GET ADDR OF RESTART DCB         67700018
         ST    WRKR1,DXDEBDCB           STORE IT IN DEB                 67800018
         MVI   DXDEBID,DEBID            STORE ID FOR DEB                67900018
*                                                                       68300018
         L     DCBR,TABDCBAD-1          GET USER'S DCB ADDR             68400018
         L     DEBR,DCBDEBAD            POINT TO USER'S DEB             68500018
         L     WRKR3,DEBUCBAD      LOAD USER'S UCB ADDRESS       M0187  68580021
         ST    WRKR3,DXDEBUCB      STORE USER'S UCB ADDRESS      M0187  68660021
         MVC   DXDEBBIN(2),DEBBINUM     BIN NUMBER TO DEB               68750018
*                                                                       68800018
         LA    WRKR2,DXDEB              GET DEB ADDR                    68900018
         ST    WRKR2,DXDCBDEB           STORE IN DCB                    69000018
*                                                                       69005021
* TO READ VOLUME LABEL AND CONVERT VTOC ADDRESS TO TTR, DEB EXTENTS     69010021
* MUST BE SET TO COVER ENTIRE VOLUME.  LOW CCHH IS ZERO, AND HIGH       69015021
* CC+1 IS OBTAINED FROM SYSTEM DEVICE CHARACTERISTICS TABLE.            69020021
*                                                                       69025021
         USING SRT,WRKR3                                         M0187  69030021
         L     WRKR2,CVTPTR        LOAD CVT POINTER              M0187  69035021
         L     WRKR2,CVTZDTAB      LOAD DEVTAB POINTER           M0187  69040021
         DROP  WRKR2                                             M0187  69045021
         IC    WRKR6,UCBTBYT4      GET DEVICE TYPE BYTE          M0187  69050021
         LA    WRKR1,X'0F'         GENERATE MASK                 M0187  69055021
         NR    WRKR6,WRKR1         USE LOW ORDER BITS FOR INDEX  M0187  69060021
         IC    WRKR6,0(WRKR6,WRKR2) PICK UP NEXT INDEX           M0187  69065021
         AR    WRKR2,WRKR6         POINT TO DEVTAB ENTRY         M0187  69070021
         XC    DXDEBSCC(8),DXDEBSCC CLEAR DEB EXTENTS            M0187  69075021
         MVC   DXDEBECC,0(WRKR2)   SET HIGH CYL ADDRESS          M0187  69080021
*                                                                       69085021
*                                                                       69100018
*********************************************************************   69200018
*                                                                     * 69300018
******** COMPLETE IOB                                                 * 69400018
*                                                                     * 69500018
*********************************************************************   69600018
*                                                                       69700018
         MVI   IOBFLAG1,UNREL           MAKE I/O UNRELATED              69800018
         LA    WRKR2,DXDCB              GET DCB ADDR                    69900018
         ST    WRKR2,IOBWGHT            STORE IN IOB                    70000018
         LA    WRKR2,DXECB              GET ECB ADDR                    70100018
         ST    WRKR2,IOBECBPT           STORE IN IOB                    70200018
         LA    WRKR2,DXCCW              GET CCW STRING ADDR             70300018
         ST    WRKR2,IOBSIOCC           STORE IN IOB                    70400018
*                                                                       70500018
*********************************************************************   70600018
*                                                                     * 70700018
******** GET THE DSCB ADDR AND PUT IT INTO THE CCW STRING             * 70800018
*                                                                     * 70900018
*********************************************************************   71000018
*                                                                       71100018
         SH    DEBR,SIXTEEN   POINT TO BBCCHHR, FRONT OF DEB     M0187  71200021
         MVC   DXDAADDR+1(7),1(DEBR)    MOVE DA ADDR TO WORKAREA        71400018
*                                                                       71500018
         XC    DXCCW(24),DXCCW          CLEAR THE CHAN PROG AREA        71600018
         LA    WRKR6,DXDAADDR+3         POINT TO CCHHR                  71700018
         ST    WRKR6,DXCCW1             STORE IN SEARCH INSTRUCTION     71800018
         LA    WRKR6,DXCCW1             POINT TO SEARCH INSTRUCTION     71900018
         ST    WRKR6,DXCCW2             STORE IT IN TIC INSTRUCTION     72000018
         LA    WRKR6,DXDSCB             POINT TO TO-ADDR OF DSCB        72100018
         ST    WRKR6,DXCCW3             STORE IT IN READ DATA INSTR.    72200018
         OC    DXCCW(24),CCWLIST        OR IN CHANNEL PROGRAM           72300018
         BR    WRKR5                    BRANCH OUT OF SBRTN VIA WRKR5   72400018
*                                                                       72500018
CLOSEUP  MVC   0(0,WRKR2),0(WRKR6)      MOVE UP THE ACC METH SEC        72600018
*                                                                     * 72700018
*********************************************************************   72800018
*                                                                     * 72900018
*     CHANNEL PROGRAM USED BY REPI/O                                    73000018
*                                                                     * 73100018
*********************************************************************   73200018
*                                                                     * 73300018
         DS    0H                                                M0187  73350021
CCWLIST  DS    0CL24                                                    73400018
         DC    X'3100000040000005'      SEARCH.                         73500018
         DC    X'08000000'                                       M0187  73570021
SIXTEEN  DC    H'16'                                             M0187  73640021
TEN      DC    H'10'                                             M0187  73710021
         DC    X'0E0000000000008C'      READ KEY AND DATA       SA54549 73800021
*                                                                     * 73900018
*********************************************************************   74000018
*                                                                     * 74100018
*     CONSTANTS USED IN REPI/O                                          74200018
*                                                                     * 74300018
*********************************************************************   74400018
*                                                                     * 74500018
IGC      DC    CL8'IGC0V05B'            RESTART XCTL MODULE      M0187  74600021
IGG      DC    CL8'IGG020P1'            PARTIAL RELEASE MODULE   M0187  74700021
         EJECT                                                          75100018
FORECORE DSECT                                                          75200018
         IECDSECT                                                       75300018
         EJECT                                                          75400018
CVT      DSECT                                                          75500018
         CVT                                                            75600018
         EJECT                                                          75700018
*                                                                       75800018
*                                                                       75900018
*   TASK CONTROL BLOCK                                                  76000018
*                                                                       76100018
*                                                                       76200018
         CNOP  0,4                                                      76300018
TCB      DSECT                                                          76400018
TCBRBP   DS    F                       POINTER TO EXECUTING RB          76500018
TCBPIE   DS    F                       POINTER TO PROG. INTERRUPT EL.   76600018
TCBDEB   DS    F                       POINTER TO DEB QUEUE             76700018
TCBTIO   DS    F                       POINTER TO TIOT                  76800018
TCBCMP   DS    F                       TASK COMPLETION CODE             76900018
TCBTRN   DS    F                       TESTRAN FIELD                    77000018
TCBMSS   DS    F                       DATA BLOCK QUEUE ELEMENT POINTER 77100018
TCBPRTK  DS    CL1                     PROTECTION TAG                   77200018
TCBFLGS  DS    FL5                     FLAG BYTES                       77300018
TCBLMP   DS    CL1                     LIMIT PRIORITY                   77400018
TCBDSP   DS    CL1                     DISPATCHING PRIORITY             77500018
TCBLLS   DS    F                       POINTER TO LOAD LIST             77600018
TCBJLB   DS    F                       POINTER TO JOBLIB DCB            77700018
TCBJSE   DS    F                       LIST OF INACTIVE PROGRAMS ADDR.  77800018
TCBGRS   DS    CL64                    GENERAL REGISTER SAVE AREA       77900018
TCBIDF   DS    CL1                     TCB IDENTIFIER FIELD             78000018
TCBFSA   DS    CL3                     POINTER TO 1ST PROB.PROG.SAVEAR  78100018
TCBTCB   DS    F                       NEXT TCB ON READY QUEUE POINTER  78200018
TCBTME   DS    F                       POINTER TO TIMER ELEMENT         78300018
         EJECT                                                          78400018
         DCBD  DSORG=PS                                                 78500018
         EJECT                                                          78600018
*                                                                       78700018
*                                                                       78800018
*   DATA EXTENT BLOCK  (UNTIL PROTIOS CHANGES)                          78900018
*                                                                       79000018
*                                                                       79100018
DEB      DSECT                                                          79200018
DEBNMSUB DS    0CL1                    NO. OF SUB RTNS                  79280018
DEBTCBAD DS    CL4                     TASK CONTROL BLOCK ADDR          79360018
DEBAMLNG DS    0CL1                    LENGTH OF ACCESS METHOD SEC      79440018
DEBDEBAD DS    CL4                     ADDR OF NEXT DEB IN DEB CHAIN    79520018
DEBOFLGS DS    0CL1                    DEB OPEN FLAGS                   79600018
DEBIRBAD DS    CL4                     ADDR OF THE IRB CONTROL BLOCK    79680018
DEBOPATB DS    0CL1                    OPEN ATRIBUTES                   79760018
DEBSYSPG DS    CL4                     SYSTEM PURGE FIELD               79840018
DEBNMEXT DS    0CL1                    NUMBER OF EXTENTS IN DEB         79920018
DEBUSRPG DS    CL4                     USER PURGE FIELD                 80000018
DEBPRIOR DS    0CL1                    INFO BYTE                        80080018
DEBECBAD DS    CL4                     EVENT CONTROL BLOCK ADDR         80160018
DEBPROTG DS    0CL1                    INFO BYTE                        80240018
DEBDEBID DS    0CL1                    INFO BYTE                        80320018
DEBDCBAD DS    CL4                     ADDR OF DCB                      80400018
DEBEXSCL DS    0CL1                    SCALING FACTOR OF DEB EXTENT     80480018
DEBAPPAD DS    CL4                     APPENDAGE TABLE ADDR             80560018
DEBDVMOD DS    0CL1                    DEVICE MODIFIER BYTE             80640018
DEBUCBAD DS    CL4                     UNIT CTL BLOCK ADDR              80720018
DEBTVLSQ DS    0CL2                VOL SEQ FOR TAPE                     80800018
DEBBINUM DS    CL2                     BIN NUMBER                       80880018
DEBTVLNM DS    0CL2                NO OF VOL FOR TAPE                   80960018
DEBSTRCC DS    CL2                     START CYLINDER NUMBER            81040018
DEBSTRHH DS    CL2                     START HEAD NUMBER                81120018
DEBENDCC DS    CL2                     END CYLINDER NUMBER              81200018
DEBENDHH DS    CL2                     END HEAD NUMBER                  81280018
DEBNMTRK DS    CL2                     NUMBER OF TRACKS                 81360018
*                                                                       81440018
*  FOR ADDITIONAL EXTENT ON DIRECT ACCESS THE FOLLOWING FIELDS          81520018
*  WILL HAVE TO BE OFFSET ANOTHER 16 BYTES                              81600018
*                                                                       81680018
DEBVOLSQ DS    H                       VOL SEQUENCE NUMBER              81760018
DEBVOLNM DS    H                       VOLUME NUMBER                    81840018
*                                                                       81920018
*  FOR EACH SUBROUTINE LOADED BUMP THIS OFFSET BY 2                     82000018
*                                                                       82080018
DEBSUBID DS    H                       SUBROUTINE ID ( 2 BYTES )        82160018
         EJECT                                                          82600018
TIOT     DSECT                                                          82700018
         IEFTIOT1                                                       82800018
         EJECT                                                          82900018
SRT      DSECT                                                          83000018
         IEFUCBOB                                                       83100018
         EJECT                                                          83200018
         IEEVRSWA                                                       83300018
         EJECT                                                          83400018
TABL     DSECT           ***** AS OF 3 OCT 67 *****                     83500018
         DS    0CL48                                                    83600018
TABDSORG DS    CL1                      ORGN OF DATA SET                83700018
*                                         X'40' =  PS                   83800018
*                                         X'80' =  IS                   83900018
*                                         X'20' =  DA                   84000018
*                                         X'02' =  PO                   84100018
*                                         X'01' =  U                    84200018
TABDCBAD DS    CL3                      ADDR OF DCB FOR THIS ENTRY      84300018
TABFLG1  DS    CL1                      FLAG BYTE NO. 1                 84400018
*                                         X'80' = NULLFILE & SYSCHECK   84500018
*                                         X'40' = SYSIN OR SYSOUT D.S.  84600018
*                                         X'20' = DA DEVICE             84700018
*                                         X'10' = TAPE DEVICE           84800018
*                                         X'08' = END OF TABLE FLAG BIT 84900018
*                                         X'04' = UNIT RECORD OR OTHER  85000018
TABSEGAD DS    CL3                      ADDR OF W.A. SEG ASSIGNED       85100018
TABNVOLS DS    CL1                      TOTAL NO OF VOLUMES             85200018
TABJFCB  DS    CL3                      TTR ADDR OF JFCB - THIS DATASET 85300018
TABOTIOT DS    0CL2                     OLD USER TIOT OFFSET (DA ONLY)  85400018
TABTPLBL DS    CL1                      TAPE LABEL INFORMATION BYTE     85500018
*                                         X'80' = ERROR IN NSL PROC RTN 85600018
*                                         X'40' = NSL MOUNT SWITCH      85700018
*                                         X'20' = NSL COMMUNICATION BIT 85800018
*                                         X'10' = BYPASS LABEL PROSS.   85900018
*                                         X'04' = NONSTANDARD LABEL     86000018
*                                         X'02' = STANDARD LABEL        86100018
*                                         X'01' = NO LABEL              86200018
TABFSQNO DS    CL1                      FILE SEQUENCE NO. (IF TAPE)     86300018
TABFLG2  DS    CL1                      FLAG BYTE NO. 2                 86400018
*                                         X'80' = GREATER THAN 5 VOLS   86500018
*                                         X'40' = PO CONCATENATED       86600018
*                                         X'20' = EXTERNAL RTN SW       86650019
TABFLG3  DS    CL1                      FLAG BYTE NUMBER 3              86700018
TABFLG4  DS    CL1                      FLAG BYTE NUMBER 4              86800018
TABFLG5  DS    CL1                      FLAG BYTE NUMBER 5              86900018
TABVLID1 DS    CL6                      VOLUME ID NUMBER ONE            87000018
TABVLID2 DS    CL6                      VOLUME ID NUMBER TWO            87100018
TABVLID3 DS    CL6                      VOLUME ID NUMBER THREE          87200018
TABVLID4 DS    CL6                      VOLUME ID NUMBER FOUR           87300018
TABVLID5 DS    CL6                      VOLUME ID NUMBER FIVE           87400018
*                                                                       87500018
*                                                                       87600018
*                                                                       87700018
EXTNO    EQU   TABFLG5                                            M3251 87770018
         END                                                            87800018
