         GBLC  &LIB                                                     00030020
&LIB     SETC  'LIB1'                   SET VARIABLE TO LIB1            00060020
         TITLE 'IGC0T05B  ACCESS METHOD PROCESSOR - DISPOSITION        *00100018
                      REPOSITION I/O  RESTART-SVC 52  OS/360'           00200018
IGC0T05B CSECT                                                          00300018
*          RELEASE 18 DELETIONS                                       * 00400018
*          RELEASE 19 DELETIONS                                       * 00500018
*2197418000                                                      A28676 00550019
*2197                                                            A27809 00570019
*          RELEASE 20 DELETIONS                                       * 00600018
*1123                                                            M3408  00650020
*          RELEASE 21 DELETIONS                                       * 00700018
*0791235000-236000                                               M0187  00750021
*          RELEASE 22 DELETIONS                                       * 00800018
*          RELEASE 23 DELETIONS                                       * 00900018
*          RELEASE 24 DELETIONS                                       * 01000018
*          RELEASE 25 DELETIONS                                       * 01100018
*          RELEASE 26 DELETIONS                                       * 01200018
* STATUS CHANGE LEVEL 004                                               01300021
*                                                                       01400018
*********************************************************************   01500018
*                                                                       01600018
*TITLE - ACCESS METHOD DISPOSITION                                      01700018
*                                                                       01800018
*STATUS - LEVEL 0                                                       01900018
*                                                                       02000018
*FUNCTION / OPERATION -  A.  FOR PARTITIONED DATA SETS, OPENED FOR      02100018
*                            OUTPUT, READ DIRECTORY TO DETERMINE IF     02200018
*                            ANY MEMBERS WERE ADDED AFTER THE CHECK-    02300018
*                            POINT WAS TAKEN.                           02400018
*                                                                       02500018
*                              IF MEMBERS WERE ADDED DELETE THEM WITH   02600018
*                              THE STOW FUNCTION .                      02700018
*                                                                       02800018
*                        B.  FOR ALL OPENED DATA SETS, IF I/O MUST BE   02900018
*                            REINITIATED, AS A RESULT OF CHKI/O PURGING 03000018
*                            ISSUE THE RESTORE MACRO TO RESCHEDULE THE  03100018
*                            REQUESTS.                                  03200018
*                                                                       03300018
*ENTRY POINT - IGC0T05B   CSECT                                         03400018
*                                                                       03500018
*INPUT -  REGISTER 1 -- WORKAREA                                        03600018
*         REGISTER 8 -- TABLE ENTRY                                     03700018
*                                                                       03800018
*         A TABLE CONSISTING OF 48 BYTE ENTRIES CONTAINING OPENED DATA  03900018
*         SET INFORMATION, ONE ENTRY PER DATA SET.                      04000018
*         REFERENCE DSECT AT END OF LISTING.                            04100018
*                                                                       04200018
*         AT LEAST TWO 304 BYTE BUFFER SEGMENTS CONTAINING THE CONTROL  04300018
*         BLOCKS AND THE WORKAREA TO PROCESS DIRECTORY BLOCKS.          04400018
*         REFERENCE DSECT AT END OF LISTING.                            04500018
*                                                                       04600018
*OUTPUT -  REGISTER 1  WORKAREA ADDRESS                                 04700018
*                                                                       04800018
*          ALL DATA SETS RE-INITIALIZED PROPERLY (AS THEY EXISTED AT    04900018
*          CHECKPOINT TIME)                                             05000018
*                                                                       05100018
*EXTERNAL ROUTINES - RESIDENT CONVERT ROUTINES VIA BALR                 05200018
*                                                                       05300018
*EXITS -  NORMAL  TO IGC0V05B VIA XCTL  RETURN CODE FIELD =0            05400018
*                                                                       05500018
*         ERROR   TO IGC0V05B VIA XCTL                                  05600018
*                    RETURN CODE FIELD = 92 - ERROR IN P. O. PROCESSING 05700018
*                    RETURN CODE FIELD = 96 - ERROR IN DELETION         05800018
*                                                                       05900018
*TABLES / WORKAREAS - REFERENCE DSECTS AT END OF LISTING                06000018
*                                                                       06100018
*********************************************************************** 06200018
*                                                                     * 06300018
*    THE FOLLOWING IS A DESCRIPTION OF THE 48 BYTE TABLE ENTRY THAT   * 06400018
*    IS USED IN THE RESTART PORTION OF CHECKPOINT/RESTART.  EACH      * 06500018
*    ENTRY IN THE TABLE (ONE FOR EACH OPEN DATA SET AT CHECKPOINT)    * 06600018
*    IS 48 BYTES LONG.                                                * 06700018
*                                                                     * 06800018
*********************************************************************** 06900018
*                                                                       07000018
*        ------------------- 4 BYTES -----------------                  07100018
*                                                                       07200018
*      0 +++++++++++++++++++++++++++++++++++++++++++++                  07300018
*        +DATA SET  +           DCB                  +                  07400018
*        + ORGN.    +         ADDRESS                +                  07500018
*        +++++++++++++++++++++++++++++++++++++++++++++ 4                07600018
*        +FLAG BYTE +    WORKAREA SEGMENT            +                  07700018
*        + NO. 1    +         ADDRESS                +                  07800018
*      8 +++++++++++++++++++++++++++++++++++++++++++++                  07900018
*        +NUMBER    +         JFCB TTR               +                  08000018
*        + OF VOLS  +         ADDRESS                +                  08100018
*        +++++++++++++++++++++++++++++++++++++++++++++ 12               08200018
*                                                                       08300018
*     12 +++++++++++++++++++++++                                        08400018
*        +TAPE LABL + FILE SEQ +        DEVICE = TAPE                   08500018
*        +INFO BYTE + NUMBER   +                                        08600018
*        +++++++++++++++++++++++                                        08700018
*                                                                       08800018
*     12 +++++++++++++++++++++++                                        08900018
*        +    OLD   TIOT       +        DA AND UNIT RECORD              09000018
*        +      OFFSET         +                                        09100018
*        +++++++++++++++++++++++                                        09200018
*                                                                       09300018
*                              +++++++++++++++++++++++                  09400018
*                              +FLAG BYTE +FLAG BYTE +                  09500018
*                              +  NO. 2   +  NO. 3   +                  09600018
*     16 +++++++++++++++++++++++++++++++++++++++++++++                  09700018
*        +FLAG BYTE +FLAG BYTE +                     +                  09800018
*        + NO. 4    + NO. 5    +   VOLUME ID NO. 1   +                  09900018
*        +++++++++++++++++++++++                     + 20               10000018
*        +                                           +                  10100018
*        +                                           +                  10200018
*     24 +++++++++++++++++++++++++++++++++++++++++++++                  10300018
*        +                                           +                  10400018
*        +   VOLUME &D NO. 2                         +                  10500018
*        +                     +++++++++++++++++++++++ 28               10600018
*        +                     +                     +                  10700018
*        +                     +   VOLUME ID NO. 3   +                  10800018
*     32 +++++++++++++++++++++++                     +                  10900018
*        +                                           +                  11000018
*        +                                           +                  11100018
*        +++++++++++++++++++++++++++++++++++++++++++++ 36               11200018
*        +                                           +                  11300018
*        +   VOLUME ID NO. 4                         +                  11400018
*     40 +                     +++++++++++++++++++++++                  11500018
*        +                     +                     +                  11600018
*        +                     +                     +                  11700018
*        +++++++++++++++++++++++   VOLUME ID NO. 5   + 44               11800018
*        +                                           +                  11900018
*        +                                           +                  12000018
*        +++++++++++++++++++++++++++++++++++++++++++++ 48               12100018
*                                                                       12200018
*                                                                       12300018
*ATTRIBUTES - RE-ENTRANT,REUSABLE,PRIVILEGED,ENABLED                    12400018
*                                                                       12500018
*********************************************************************   12600018
*                                                                       12700018
*    REGISTER CONVENTION TO BE USED THRU-OUT REPI/O PHASE               12800018
*                                                                       12900018
*********************************************************************** 13000018
*                                                                       13100018
WRKR1    EQU   0                                                        13200018
WRKR2    EQU   1                                                        13300018
DCBR     EQU   2                                                        13400018
BASER    EQU   3                                                        13500018
DEBR     EQU   4                                                        13600018
UCBR     EQU   5                                                        13700018
TIOTR    EQU   6                                                        13800018
TCBR     EQU   7                                                        13900018
TABLR    EQU   8                                                        14000018
CTABLR   EQU   9                                                        14100018
BUFR     EQU   10                                                       14200018
DSCNTR   EQU   11                                                       14300018
WRKR3    EQU   12                                                       14400018
WRKR4    EQU   13                                                       14500018
WRKR5    EQU   14                                                       14600018
WRKR6    EQU   15                                                       14700018
*                                                                       14800018
*********************************************************************** 14900018
*                                                                       15000018
*    OFFSETS TO BE USED IN REPI/O PHASE                                 15100018
*                                                                       15200018
*********************************************************************** 15300018
*                                                                       15400018
IS       EQU   X'80'                    INDEXED SEQUENCIAL              15402018
PS       EQU   X'40'                    PHYSICAL SEQUENCIAL             15404018
DA       EQU   X'20'                    DIRECT ACCESS                   15406018
PO       EQU   X'02'                    PARTITIONED ORGANIZATION        15408018
NULL     EQU   X'80'                    NULLFILE OR SYSCHECK            15410018
INOROUT  EQU   X'40'                    SYSIN OR SYSOUT DATA SET        15412018
DADEV    EQU   X'20'                    DA DEVICE                       15414018
TPDEV    EQU   X'10'                    TAPE DEVICE                     15416018
LASTENT  EQU   X'08'                    LAST ENTRY                      15418018
UNITREC  EQU   X'04'                    UNIT RECORD EQUIPMENT           15420018
ERRINNSL EQU   X'80'                    ERROR IN NSL ROUTINE            15422018
NSLMTSW  EQU   X'40'                    NSL MOUNT SWITCH                15424018
NSLCOMU  EQU   X'20'                    NSL COMMUNICATION BIT           15426018
BYPASS   EQU   X'10'                    BYPASS LABEL PROCESSING         15428018
NSL      EQU   X'04'                    NON-STANDARD LABEL              15430018
SL       EQU   X'02'                    STANDARD LABEL                  15432018
NL       EQU   X'01'                    NO LABEL                        15434018
GTR5VOL  EQU   X'80'                    GREATER THAN 5 VOLUMES          15436018
POCONCAT EQU   X'40'                    P.O. CONCATENATED               15438018
DAFLAG   EQU   X'80'                    DA DATA SET FLAG                15440018
NONDAFLG EQU   X'40'                    NON-DA DATA SET FLAG            15442018
NSLFLAG  EQU   X'10'                    NSL ROUTINE FLAG                15444018
TYPERST  EQU   X'80'                    IMMEDIATE RESTART               15446018
TABENT   EQU   48                       TABLE ENTRY LENGTH              15448018
WRITE    EQU   X'01'                    WRITE ON TAPE                   15450018
READ     EQU   X'02'                    READ FOR TAPE                   15452018
NOPOP    EQU   X'03'                    NOP                             15454018
SENSE    EQU   X'04'                    SENSE                           15456018
REWIND   EQU   X'07'                    REWIND                          15458018
READBACK EQU   X'0C'                    READBACK                        15460018
UNLOAD   EQU   X'0F'                    REWIND AND UNLOAD               15462018
WTM      EQU   X'1F'                    WRITE TAPE MARK                 15464018
BSFOP    EQU   X'2F'                    BACKWARD SPACE FILE             15466018
FSFOP    EQU   X'3F'                    FORWARD SPACE FILE              15468018
SEARCH   EQU   X'31'                    SEARCH                          15470018
SRCHCNT  EQU   X'05'                    COUNT FOR SEARCH ID             15472018
TIC      EQU   X'08'                    TIC                             15474018
READDA   EQU   X'06'                    READ FOR DA                     15476018
LENJFCB  EQU   X'B0'                    LENGTH OF JFCB                  15478018
LBLLEN   EQU   X'50'                    LENGTH OF LABEL                 15480018
PERMERR  EQU   X'7F'                    PERMANENT ERROR                 15482018
ERR92    EQU   92                       ERROR IN PO PROCESSING          15484018
ERR96    EQU   96                       ERROR IN DELETING MEMBER FROM   15486018
*                                           DIRECTORY                   15488018
*                                                                       15500018
*      MASKS USED TO MAKE TESTS                                         15600018
*                                                                       15700018
OUT      EQU   X'0F'                                                    15800018
DEBID    EQU   X'0F'                    DEB IDENTIFICATION              15830018
TCAMID1  EQU   X'C0'                    UNIQUE TCAM DEB CODE     M3408  15840020
TCAMID2  EQU   X'CF'                    UNIQUE TCAM DEB CODE     M3408  15850020
MAXEXT   EQU   X'CA'                    MAXIMUM NO. OF EXTENT           15860018
UNRELCC  EQU   X'42'                    UNRELATED FLAG, COMMAND CHAIN   15890018
UNITEX   EQU   X'01'                    UNIT EXCEPTION                  15920018
NORECORD EQU   X'08'                    NO RECORD FOUND                 15950018
NEXTTRK  EQU   X'00'                    NEXT TRACK, R=0                 15980018
NTPRGD   EQU   X'FF'                    NO PURGED                       16010018
*                                                                       16100018
*********************************************************************   16200018
*                                                                       16300018
         BALR  BASER,0                  ESTABLISH ADDRESSIBILITY        16400018
         USING *,BASER                                                  16500018
*                                                                       16600018
         USING IHADCB,DCBR                                              16700018
         USING DEB,DEBR                                                 16800018
         USING UCBOB,UCBR                                               16900018
         USING TCB,TCBR                                                 17000018
         USING TABL,CTABLR                                              17100018
         USING CVT,WRKR2                                                17200018
         USING RSDSECT,WRKR4                                            17300018
         USING RSTWA,BUFR                                               17400018
*                                                                       17500018
REPDCB00 EQU   *                                                        17600018
*                                                                       17700018
         LR    CTABLR,TABLR             INITIALIZE D.S. ENTRY LIST      17800018
         L     WRKR4,TABSEGAD-1         GET FIRST SEGMENT ADDRESS       17850018
*                                                                       17900018
REPDCB02 EQU   *                                                        18000018
         L     DCBR,TABDCBAD-1          GET DCB ADDRESS                 18200018
         L     DEBR,DCBDEBAD            GET DEB ADDRESS                 18300018
         LA    DEBR,0(DEBR)             HI BYTE CLEARED                 18400018
         L     UCBR,DEBUCBAD            GET USER UCB ADDRESS            18500018
*                                                                       18600018
         TM    TABDSORG,PO              DATA SET PARTITIONED            18700018
         BZ    REPDCB20                 NO BRANCH - NEXT ENTRY          18800018
*                                                                       18900018
*                                                                       19000018
         TM    DEBOPATB,OUT             D.S. PROCESSED IN OUTPUT MODE   19100018
         BZ    REPDCB20                 NO BRANCH - NEXT ENTRY          19200018
*                                                                       19300018
*********************************************************************   19400018
*                                                                       19500018
*      AT THIS POINT THE DATA SET DIRECTORY MUST BE READ TO DETERMINE   19600018
*      IF MEMBERS WERE ADDED AFTER THE CHECKPOINT WAS TAKEN ....        19700018
*                                                                       19800018
*      THIS WILL BE DONE BY READING A DIRECTORY BLOCK, EXAMINING THE    19900018
*      ENTRIES FOR A TTR (INDICATING THE BEGINNING OF WHERE THE MEMBER  20000018
*      PHYSICALLY RESIDES IN THE DATA SET), GREATER THAN THE TTR OF THE 20100018
*      MEMBER CURRENTLY BEING WRITTEN. IF ONE IS FOUND, THE MEMBER NAME 20200018
*      ASSOCIATED WITH THE TTR WILL BE USED TO DELETE THE MEMBER FROM   20300018
*      THE DIRECTORY VIA THE STOW MACRO.                                20400018
*                                                                       20500018
*      THIS PROCEDURE WILL BE CARRIED OUT FOR THE ENTIRE DATA SET       20600018
*      DIRECTORY ....                                                   20700018
*                                                                       20800018
*********************************************************************   20900018
*                                                                       21000018
REPDCB04 EQU   *                                                        21100018
*                                                                       21200018
REPDCB06 EQU   *                                                        21300018
*                                                                       21400018
*********************************************************************** 21500018
*                                                                       21600018
*     CONSTRUCT THE CONTROL BLOCKS NECESSARY TO READ DIRECTORY BLOCKS   21700018
*                                                                       21800018
*    FIRST 48 BYTES CONSIST OF SYSTEM DEB - WILL BE USED TO REFERENCE   21900018
*    ALL ALLOCATED DEVICES USED BY RESTARTED TASK ..                    22000018
*                                                                       22100018
*********************************************************************** 22200018
*                                                                       22300018
REPDCB08 EQU   *                                                        22400018
*                                                                       22500018
         L     WRKR2,CVTPTR             GET COMMUNICATION VECTOR TABLE  22600018
         L     DCBR,CVTJOB              GET SYSTEM JOB QUEUE DCB        22700018
         L     WRKR3,DCBDEBAD           GET SYSTEM JOB QUEUE DEB        22800018
         MVC   RSDEB(48),0(WRKR3)       COPY SYSTEM DEB INTO BUFFER     22900018
         LA    WRKR1,RSDCBREP           GET ADDRESS OF RESTART DCB      23000018
         ST    WRKR1,RSDEBDCB           STORE IN RESTART DEB            23100018
         ST    WRKR1,RSIOBDCB           STORE IN RESTART IOB            23200018
         MVI   RSDEBID,DEBID            STORE IDENTIFICATION FOR DEB    23300018
         ST    UCBR,RSDEBUCB            SAVE USER UCB ADDRESS IN DEB    23400018
*                                                                       23410021
* SET DEB EXTENTS TO COVER ENTIRE VOLUME--FROM CCHH=0 TO                23420021
* CCHH= HIGHEST POSSIBLE FOR THE DEVICE TYPE.                           23430021
*                                                                       23440021
         L     WRKR2,CVTZDTAB           ADDR OF DEVICE           M0187  23450021
*                                       CHARACTERISTICS TABLE           23460021
         DROP   WRKR2                                            M0187  23470021
         IC    WRKR3,UCBTBYT4           GET CLASS INDEX FROM UCB M0187  23480021
         N     WRKR3,MASK1              LO-ORDER 4 BITS          M0187  23490021
         IC    WRKR3,0(WRKR2,WRKR3)     DEVTAB INDEX, THIS       M0187  23500021
*                                       DEVTYPE                  M0187  23510021
         AR    WRKR2,WRKR3              POINT TO DEVTYPE ENTRY   M0187  23520021
         XC    RSDEBSCC(8),RSDEBSCC     CLEAR DEB EXTENTS        M0187  23530021
         MVC   RSDEBECC,0(WRKR2)        SET HI CC AS HIGHEST ON  M0187  23540021
*                                       VOLUME                   M0187  23550021
         MVC   RSDEBNTR(2),MAXTRKNO     STORE MAXIMUM NUMBER OF TRACKS  23700018
*                                                                       23800018
*********************************************************************** 23900018
*                                                                       24000018
*    THE NEXT FOUR BYTES WILL BE USED FOR THE DCB (S) DEB ADDRESS       24100018
*                                                                       24200018
         LA    WRKR1,RSDEB              GET DEB ADDRESS                 24300018
         ST    WRKR1,RSDCBDEB           STORE IN RESTART DCB            24400018
*                                                                       24500018
*    THE NEXT FOUR BYTES WILL BE USED FOR AN ECB                        24600018
*                                                                       24700018
         MVI   RSIOBFG1,UNRELCC         SET UNRELATED FLAG IN IOB       24800018
         LA    WRKR1,RSECBAD            GET ECB FOR IOB                 24900018
         ST    WRKR1,RSIOBECB           STORE ECBAD IN IOB              25000018
*                                                                       25100018
*    THE 40 BYTE SYSTEM IOB WILL BE NEXT IN BUFFER SEGMENT              25200018
*                                                                       25300018
         LA    WRKR1,RSCCWLST           GET CHANNEL PROGRAM ADDR.       25400018
         ST    WRKR1,RSIOBCPA           STORE ADDRESS IN IOB            25500018
         XC    RSIOBDAD(8),RSIOBDAD     CLEAR D A ADDRESS FIELD         25600018
         MVC   RSIOBDAD+1(6),DEBBINUM   STARTING SEARCH ARGUMENT        25700018
*                                                                       25800018
*    THE 24 BYTE CHANNEL PROGRAM WILL FOLLOW. SRCH - TIC - READ.        25900018
*                                                                       26000018
         XC    RSCCW1(24),RSCCW1        CLEAR  READ CCW                 26100018
         LA    WRKR1,RSIOBDAD+3         GET ADDRESS OF SRCH ARGUMENT    26200018
         ST    WRKR1,RSCCW1             STORE IN SRCH CCW               26300018
         LA    WRKR1,RSCCW1             GET ADDRESS OF SRCH CCW         26400018
         ST    WRKR1,RSCCW2             STORE IN TIC CCW                26500018
         LA    WRKR1,RSBUFSEG           GET BUFFER SEGMENT TO READ INTO 26600018
         ST    WRKR1,RSCCW3             STORE IN READ CCW               26700018
         OC    RSCCWLST,CCWLIST         CONSTANTS IN THE CHANNEL PROGRM 26800018
*                                                                       26900018
REPDCB10 EQU   *                                                        27000018
*                                                                       27100018
*********************************************************************** 27200018
*                                                                       27300018
*      AT THIS POINT ALL CONTROL BLOCKS HAVE BEEN ESTABLISHED           27400018
*                                                                       27500018
*********************************************************************** 27600018
*                                                                       27700018
         L     DCBR,TABDCBAD-1          REFRESH USER DCB ADDRESS        27800018
*                                                                       27900018
REPDCB12 EQU   *                                                        28000018
*                                                                       28100018
*********************************************************************** 28200018
*                                                                       28300018
*      SETUP READ-WAIT SUBROUTINE TO BRING DIRECTORY BLOCK INTO BUFFER  28400018
*                                                                       28500018
*********************************************************************** 28600018
*                                                                       28700018
         SR    TIOTR,TIOTR              INITIALIZE TO ZERO              28800018
         IC    TIOTR,RSIOBDAD+7         GET CURRENT R VALUE             28900018
         LA    TIOTR,1(TIOTR)           INCREMENT R BY ONE              29000018
         STC   TIOTR,RSIOBDAD+7         SAVE R IN SEARCH ARGUMENT       29100018
         LA    WRKR3,RSBUFSEG           POINT TO BEGINNING OF BUFFER    29200018
*                                                                       29300018
*********************************************************************** 29400018
*                                                                       29500018
         EXCP  RSIOB                    READ DIRECTORY BLOCK            29600018
*                                                                       29700018
*********************************************************************   29800018
*                                                                       29900018
         WAIT  ECB=RSECBAD              WAIT FOR RECORD TO COME IN      30000018
*                                                                       30100018
*********************************************************************** 30200018
*                                                                       30300018
         TM    RSECBAD,PERMERR          ERRORS ASSOCIATED WITH REQUEST  30400018
         BO    REPDCB13                 NO BRANCH                       30500018
*                                                                       30600018
         TM    RSIOBCSW+4,UNITEX        UNIT EXCEPTION ON IN CSW =FM    30700018
         BO    REPDCB20                 YES BRANCH NEXT ENTRY           30800018
*                                                                       30900018
         TM    RSIOBSN2,NORECORD        NO RECORD FOUND                 31000018
         BO    REPDCB18                 YES BRANCH TO NEXT TRACK        31100018
*                                                                       31200018
         B     REPDCB90                 SET UP ERROR RETURN CODE        31300018
*                                                                       31400018
REPDCB13 EQU   *                                                        31500018
*                                                                       31600018
         LH    WRKR2,0(WRKR3)           GET LEN OF USED DIR. BLOCK      31700018
         LA    TCBR,0(WRKR2,WRKR3)      POINT TO END OF BLOCK           31800018
         LA    WRKR3,2(WRKR3)           SLIP PAST LEN FIELD             31900018
*                                                                       32000018
*********************************************************************** 32100018
*                                                                       32200018
REPDCB14 EQU   *                                                        32300018
*                                                                       32400018
*      PROCESS DIRECTORY BLOCK - DETERMINE IF MEMBERS WERE ADDED        32500018
*                                                                       32600018
*                                                                       32607018
* DO NOT DELETE CHECKPOINT MEMBER THAT IS BEING USED FOR RESTART        32614018
*                                                                       32621018
*                                                                       32628018
         LA    DCBR,0(,DCBR)            CLEAR HI-ORDER BYTE      A27809 32631019
         C     DCBR,RSCKDCB             IS CURRENT DCB CHECKPOINT DCB   32635018
         BNE   REPDCB15                 BRANCH IF NO                    32642018
         CLC   DCBRELAD(3),8(WRKR3)     CURRENT TTR IN DCB = TTR IN     32649018
*                                           DIRECTORY                   32656018
         BE    REPDCB16                 BRANCH IF YES                   32663018
*                                                                       32670018
REPDCB15 EQU   *                                                        32677018
*                                                                       32684018
         CLC   DCBRELAD(3),8(WRKR3)     CURR TTR IN DCB GREATER THAN    32700018
*                                       EXISTING MEMBERS TTR IN DIR.    32800018
         BH    REPDCB16                 YES BRANCH                      32900018
*                                                                       33000018
*      MEMBER WAS ADDED AFTER CHECKPOINT ENTRY TAKEN - MUST DELETE      33100018
*                                                                       33200018
         MVC   TABNVOLS(12),0(WRKR3)    SETUP FOR DELETE FUNCTION       33300018
*                                                                       33400018
*********************************************************************   33500018
*                                                                       33600018
         STOW  (DCBR),TABNVOLS,D        DELETE MEMBER NAME FROM DIR.    33700018
*                                                                       33800018
*********************************************************************** 33900018
*                                                                       34000018
         LTR   WRKR6,WRKR6              ERRORS OCCUR DURING STOW        34100018
         BNZ   REPDCB80                 YES BRANCH TO SET ERR CODE      34200018
*                                                                       34300018
*********************************************************************** 34400018
*                                                                       34500018
REPDCB16 EQU   *                                                        34600018
*                                                                       34700018
         IC    TIOTR,11(WRKR3)          GET ENTRY LENGTH                34800018
         SLL   TIOTR,28                 MULTIPLY LAST FOUR BITS         34900018
         SRL   TIOTR,27                 BY TWO TO GIVE BYTE LENGTH      35000018
         LA    WRKR3,12(TIOTR,WRKR3)    POINT TO NEXT POSSIBLE ENTRY    35100018
*                                                                       35200018
         CR    WRKR3,TCBR               AT END OF DIRECTORY BLOCK       35300018
         BL    REPDCB14                 NO BRANCH - NEXT ENTRY          35400018
*                                                                       35500018
         B     REPDCB12                 LOOP BACK                       35600018
*                                                                       35700018
*********************************************************************** 35800018
*                                                                       35900018
*      SET UP TO ADJUST DIRECT ACCESS ADDRESS FOR NEXT TRACK. TO KEEP   36000018
*      DEVICE INDEPENDANT, ROUTINE WILL USE RESIDENT CONVERT ROUTINES.  36100018
*                                                                       36200018
*********************************************************************** 36300018
*                                                                       36400018
REPDCB18 EQU   *                                                        36500018
*                                                                       36600018
         MVI   RSIOBDAD+7,NEXTTRK       SET R=0, NEXT TRACK             36700018
*                                                                       36800018
         L     UCBR,CVTPTR              ADDRESS OF CVT                  36900018
         LA    DSCNTR,RSBUFSEG          ADDRESS OF TEMP SAVE AREA       37000018
         STM   WRKR1,WRKR6,0(DSCNTR)    SAVE ALL REGISTERS              37100018
         LR    TIOTR,DSCNTR             SAVE CONTENTS                   37200018
*                                                                       37300018
*      PREPARE TO CONVERT MBBCCHHR TO TTR VIA RESIDENT CONVERT RT.      37400018
*                                                                       37500018
         LR    WRKR2,DEBR               ADDRESS OF DEB - REG.1          37600018
         LA    DCBR,RSIOBDAD            ADDRESS OF MBB - REG.2          37700018
*                                                                       37800018
         L     WRKR6,CVTPRLTV-CVT(UCBR) RT. TO CONVERT TO TTRN          37900018
         BALR  WRKR5,WRKR6              TO ROUTINE                      38000018
*                                                                       38100018
         SRL   WRKR1,16                 RIGHT JUSTIFY TT                38200018
         LA    DSCNTR,1                 CONSTANT OF ONE                 38300018
         AR    WRKR1,DSCNTR             ADD TO TT                       38400018
         SLL   WRKR1,16                 LEFT JUSTIFY TT, R=0, N=0       38500018
*                                                                       38600018
         L     WRKR6,CVTPCNVT-CVT(UCBR) RT TO CONVERT TO MBBCCHHR       38700018
         BALR  WRKR5,WRKR6              TO ROUTINE                      38800018
*                                                                       38900018
         LTR   WRKR6,WRKR6              ERRORS IN CONVERTING            39000018
*                                                                       39100018
         LR    DSCNTR,TIOTR             RESTORE CONTENTS                39200018
         LM    WRKR1,WRKR6,0(DSCNTR)    RESTORE ALL REGISTERS           39300018
*                                                                       39400018
         BZ    REPDCB12                 NO BRANCH                       39500018
*                                                                       39600018
         B     REPDCB90                 TO ERROR RETURN                 39700018
*                                                                       39800018
*********************************************************************** 39900018
*                                                                       40000018
REPDCB20 EQU   *                                                        40100018
*                                                                       40200018
         TM    TABFLG1,LASTENT          WAS THIS LAST ENTRY IN TABLE    40300018
         BO    REPDCB22                 YES BRANCH                      40400018
*                                                                       40500018
         LA    CTABLR,TABENT(CTABLR)    TO NEXT ENTRY                   40600018
         B     REPDCB02                 RELOOP                          40700018
*                                                                       40800018
REPDCB22 EQU   *                                                        40900018
*                                                                       41000018
*********************************************************************** 41100018
*                                                                       41200018
*      RESTORE ALL I/O REQUESTS TO CHANNEL QUEUES VIA RESTORE MACRO     41300018
*                                                                       41400018
*********************************************************************** 41500018
*                                                                       41600018
         L     TCBR,RSTCBAD             GET TCB ADDRESS                 41700018
         L     DEBR,RSINT               GET 1ST DEB ADDR         A28676 41760019
         ST    DEBR,TCBDEB              SETUP TCB DEB CHAIN      A28676 41820019
*                                                                       41900018
REPDCB24 EQU   *                                                        42000018
*                                                                       42100018
         LTR   DEBR,DEBR                END OF DEB CHAIN                42200018
         BZ    REPDCB94                 YES BRANCH                      42300018
         CLI   DEBNMSUB,TCAMID1         Q - TCAM DEB (TYPE 1)    M3408  42320020
         BE    REPDCB28                 IF YES, SKIP THIS DEB    M3408  42340020
         CLI   DEBNMSUB,TCAMID2         Q - TCAM DEB (TYPE 2)    M3408  42360020
         BE    REPDCB28                 IF YES, SKIP THIS DEB    M3408  42380020
*                                                                       42400018
         TM    DEBUSRPG+3,NTPRGD        DID A PURGE TAKE PLACE          42500018
         BO    REPDCB28                 NO BRANCH                       42600018
*                                                                       42700018
         L     WRKR2,DEBUSRPG           GET ADDRESS OF POSSIBLE IOB     42800018
         LA    WRKR2,0(WRKR2)           HI BYTE CLEARED                 42900018
         LTR   WRKR2,WRKR2              VALID ADDRESS PRESENT           43000018
         BZ    REPDCB28                 NO BRANCH                       43100018
*                                                                       43200018
REPDCB26 EQU   *                                                        43300018
*                                                                       43400018
*********************************************************************   43500018
*                                                                       43600018
         RESTORE DEBUSRPG               RESTORE DEBS I/O REQUESTS       43700018
*                                                                       43800018
*********************************************************************** 43900018
*                                                                       44000018
REPDCB28 EQU   *                                                        44100018
*                                                                       44200018
         L     DEBR,DEBDEBAD            GET NEXT POSSIBLE DEB           44300018
         LA    DEBR,0(DEBR)             HI BYTE CLEARED                 44400018
         B     REPDCB24                 REPEAT TESTS                    44500018
*                                                                       44600018
REPDCB30 EQU   *                                                        44700018
*                                                                       44800018
*                                                                       44900018
REPDCB40 EQU   *                                                        45000018
*                                                                       45100018
REPDCB50 EQU   *                                                        45200018
*                                                                       45300018
REPDCB60 EQU   *                                                        45400018
*                                                                       45500018
REPDCB70 EQU   *                                                        45600018
*                                                                       45700018
REPDCB80 EQU   *                                                        45800018
*                                                                       45900018
         MVI   RSRETCOD+1,ERR96         ERROR IN DELETING MEMBER FROM   46000018
*                                            DIRECTORY                  46100018
         B     REPDCB94                 BRANCH TO SET UP FOR XCTL       46200018
*                                                                       46300018
REPDCB90 EQU   *                                                        46400018
*                                                                       46500018
*     MUST TERMINATE REPI/O DUE TO UNRECOVERABLE ERRORS IN PROCESSING   46600018
*                                                                       46700018
         MVI   RSRETCOD+1,ERR92         ERROR IN PO PROCESSING          46800018
*                                                                       46900018
REPDCB94 EQU   *                                                        47000018
*                                                                       47100018
*      SET UP FOR XCTL TO LAST PHASE OF RESTART FUNCTION                47200018
*                                                                       47300018
*********************************************************************** 47400018
*                                                                       47500018
         MVC   RSJFCB(8),RSTMODNM       NEXT PHASE OF RESTART           47600018
         LA    WRKR6,RSJFCB+8           SETUP FOR XCTL MACRO            47700018
*********************************************************************   47720018
         LR    WRKR2,BUFR               POINT REG 1 TO THE RESTART W/A  47740018
*********************************************************************   47760018
*                                                                       47800018
*********************************************************************   47900018
*                                                                       48000018
         XCTL  EPLOC=RSJFCB,SF=(E,(15))                                 48400018
*                                                                       48500018
*********************************************************************   48600018
*                                                                       48700018
*********************************************************************** 48800018
*                                                                       48900018
*     CONSTANTS USED IN REPI/O                                          49000018
*                                                                       49100018
*********************************************************************** 49200018
*                                                                       49300018
MAXTRKNO DC    X'7FFF'                  MAX. NO. OF TRACKS              49400018
MASK1    DC    F'15'                    MASK OF LO-ORDER 4 BITS  M0187  49450021
*                                                                       49500018
RSTMODNM DC    C'IGC0V05B'              RESTART EXIT MOD                49600018
*                                                                       49700018
*********************************************************************** 49800018
*                                                                       49900018
*     CHANNEL PROGRAM USED BY REPI/O                                    50000018
*                                                                       50100018
*********************************************************************** 50200018
*                                                                       50300018
CCWLIST  DC    X'3100000040000005'      SRCH ID EQUAL , 5 BYTES CCHHR   50400018
         DC    X'080000'                TIC                             50500018
ZERO     DC    X'0000000000'            ZERO                            50600018
         DC    X'0600000000000100'      READ DATA,256 BYTES DIRECTORY   50700018
         EJECT                                                          50800018
         IEEVRSWA                                                       50900018
         EJECT                                                          51000018
RSDSECT  DSECT                                                          51100018
*                                                                       51200018
*    DATA EXTENT BLOCK                                                  51300018
*                                                                       51400018
RSDEB    DS    0CL48                                                    51500018
RSDEBTCB DC    X'00000000'              TCB ADDRESS                     51600018
RSDEBDEB DC    X'00000000'              DEB ADDRESS                     51700018
*                                                                       51800018
*    DATA CONTROL BLOCK                                                 51900018
*                                                                       52000018
RSDEBOFL DS    0CL1                                                     52100018
RSDEBIRB DC    X'00000000'              IRB ADDRESS                     52200018
RSDEBSYS DC    X'00000000'              1ST IOB ADDR IN SYS.PURGE CHAIN 52300018
RSDEBUSR DC    X'00000000'              1ST IOB ADDR IN USER PRGE CHAIN 52400018
RSDEBECB DC    X'00000000'              PARM.LIST ADDR TO PURGE ECB     52500018
RSDEBID  DS    0CL1                                                     52600018
RSDEBDCB DC    AL4(RSDCBREP)            DCB ADDR                        52700018
RSDEBAPP DS    CL4                      I/O APPENDAGE VECTOR TABLE      52800018
RSDEBMOD DS    0CL1                                                     52900018
RSDEBUCB DS    F                        UCB ADDRESS                     53000018
RSDEBBIN DS    H                        BIN NUMBER                      53100018
RSDEBSCC DS    H                        CYLINDER START ADDRESS          53200018
RSDEBSHH DS    H                        TRACK START ADDRESS             53300018
RSDEBECC DS    H                        CYLINDER END ADDRESS            53400018
RSDEBEHH DS    H                        TRACK END ADDRESS               53500018
RSDEBNTR DS    H                        NO. OF TRACKS IN THIS EXTENT    53600018
*                                                                       53700018
*    EVENT CONTROL BLOCK                                                53800018
*                                                                       53900018
RSECBAD  DS    CL4                      ECB ADDRESS                     54000018
RSDCBDEB DC    AL4(RSDEB)               DEB ADDRESS                     54100018
*                                                                       54200018
RSDCBREP EQU   RSDEB+8                  POINT TO RELATIVE BEGINNING DCB 54300018
*                                                                       54400018
*    INPUT OUTPUT BLOCK                                                 54500018
*                                                                       54600018
RSIOB    DS    0CL40                                                    54700018
RSIOBFG1 DC    X'00'                    I/O FLAGS BYTE 1                54800018
RSIOBFG2 DC    X'00'                    I/O FLAGS BYTE 2                54900018
RSIOBSN1 DS    CL1                      FIRST SENSE BYTE                55000018
RSIOBSN2 DS    CL1                      SECOND SENSE BYTE               55100018
RSIOBECB DC    AL4(RSECBAD)             ECB ADDRESS                     55200018
RSIOBCSW DS    D                        LAST CSW                        55300018
RSIOBCPA DS    AL4(RSCCW1)              CHANNEL PROGRAM ADDRESS         55400018
RSIOBDCB DS    AL4(RSDCBREP)            DCB ADDRESS                     55500018
RSIOBRCP DS    CL4                      RESTART ADDRESS FOR IOS         55600018
RSIOBINC DS    H                        INCREMENT BLOCK COUNT           55700018
RSIOBECT DS    H                        NO. OF ERROR ENTRIES            55800018
RSIOBDAD DS    D                        SEEK ADDRESS FOR DA             55900018
*                                                                       56000018
*    CHANNEL PROGRAM                                                    56100018
*                                                                       56200018
RSCCWLST DS    0CL24                                                    56300018
RSCCW1   DS    D                        CCW1                            56400018
RSCCW2   DS    D                        CCW2                            56500018
RSCCW3   DS    D                        CCW3                            56600018
*                                                                       56700018
*    BUFFER SEGMENT FOR EXTERNAL BLOCKS                                 56800018
*                                                                       56900018
RSBUFSEG DS    0CL176                                                   57000018
RSJFCB   EQU   RSBUFSEG                                                 57100018
*                                                                       57200018
*********************************************************************** 57300018
*                                                                       57400018
*                  JFCB                                                 57500018
*                                                                       57600018
*********************************************************************** 57700018
*                                                                       57800018
JFCBDSNM DS    CL44                         DATA SET NAME               57900018
JFCBELNM DS    CL8                          ELEMENT NAME OR VERSION     58000018
JFCBTSDM DS    CL1                          TASK SCHEDULER - DATA       58100018
*                                            MANAGEMENT INTERFACE BYTE  58200018
JFCBSYSC DS    CL13                         SYSTEM CODE                 58300018
JFCBLTYP DS    CL1                          LABEL TYPE AND USER'S-LABEL 58400018
*                                            INDICATOR                  58500018
         DS    CL1                          NOT USED                    58600018
JFCBFLSQ DS    CL2                          FILE SEQUENCE NUMBER        58700018
JFCBVLSQ DS    CL2                          VOLUME SEQUENCE NUMBER      58800018
JFCBMASK DS    CL8                          DATA MANAGEMENT MASK        58900018
JFCBCRDT DS    CL3                          DATA SET CREATION DATE      59000018
JFCBXPDT DS    CL3                          DATA SET EXPIRATION DATE    59100018
JFCBIND1 DS    CL1                          INDICATOR BYTE 1            59200018
JFCBRLSE EQU   64                            BITS 0 AND 1 - EXTERNAL    59300018
*                                            STORAGE RELEASE INDICATOR  59400018
JFCBLOCT EQU   16                            BITS 2 AND 3 - DATA SET    59500018
*                                            HAS BEEN LOCATED           59600018
JFCBNEWV EQU   4                             BITS 4 AND 5 - NEW VOLUME  59700018
*                                            ADDED TO DATA SET          59800018
JFCBPMEM EQU   1                             BITS 6 AND 7 - DATA SET IS 59900018
*                                            A MEMBER OF A PODS OR GDG  60000018
JFCBIND2 DS    CL1                          INDICATOR BYTE 2            60100018
JFCBSTAT EQU   64                            BITS 0 AND 1 - DATA SET    60200018
*                                            STATUS (NEW, OLD, OR MOD)  60300018
JFCBSCTY EQU   16                            BITS 2 AND 3 - DATA SET    60400018
*                                            SECURITY INDICATOR         60500018
JFCBUFNO DS    0AL1                                                     60600018
JFCBUFRQ DS    AL1                      BUFFER REQUESTED                60700018
JFCBFTEK DS    0BL1                                                     60800018
JFCBFALN DS    BL1                      BUFFER ALIGNMENT                60900018
JFCBUFL  DS    AL2                      BUFFER LENGTH                   61000018
JFCEROPT DS    BL1                      ERROR ROUTINE                   61100018
JFCTRTCH DS    0BL1                                                     61200018
JFCKEYLE DS    0AL1                                                     61300018
JFCMODE  DS    0BL1                                                     61400018
JFCCODE  DS    0BL1                                                     61500018
JFCSTACK DS    0BL1                                                     61600018
JFCPRTSP DS    BL1                      PRINTER SPACING                 61700018
JFCDEN   DS    BL1                      TAPE DENSITY                    61800018
JFCLIMCT DS    AL3                      NO. OF TRKS.TO BE SEARCHED      61900018
JFCDSORG DS    BL2                      DATA SET ORGANIZATION           62000018
JFCRECFM DS    BL1                      RECORD FORMAT                   62100018
JFCOPTCD DS    BL1                      OPTION CODES                    62200018
JFCBLKSI DS    AL2                      BLOCK SIZE                      62300018
JFCLRECL DS    AL2                      LOGICAL RECORD LENGTH           62400018
JFCNCP   DS    AL1                      NO. OF CHANNEL PROGRAM          62500018
JFCNTM   DS    AL1                      NO. OF TRKS. FOR MASTER INDEX   62600018
JFCRKP   DS    AL2                      RELATIVE POSITION OF KEY        62700018
JFCCYLOF DS    AL1                      NO. OF TRKS FOR OVERFLOW        62800018
JFCDBUFN DS    AL1                      RESERVED                        62900018
JFCINTVL DS    AL1                      INTENTIONAL INTERVAL            63000018
JFCCPRI  DS    BL1                      PRIORITY                        63100018
JFCSOWA  DS    AL2                      SIZE OF WORKAREA                63200018
JFCBNTCS DS    CL1                          NUMBER OF OVERFLOW TRACKS   63300018
JFCBNVOL DS    CL1                          NUMBER OF VOLUME SERIAL     63400018
*                                            NUMBERS                    63500018
JFCBVOLS DS    CL30                         VOLUME SERIAL NUMBERS (THE  63600018
*                                            FIRST FIVE)                63700018
JFCBEXTL DS    CL1                          LENGTH OF BLOCK OF EXTRA    63800018
*                                            VOLUME SERIAL NUMBERS      63900018
*                                            (BEYOND FIVE)              64000018
JFCBEXAD DS    CL3                          TRACK ADDRESS OF BLOCK OF   64100018
*                                            EXTRA VOL SERIAL NUMBERS   64200018
JFCBPQTY DS    CL3                          PRIMARY QUANTITY OF D.A.    64300018
*                                            STORAGE REQUIRED           64400018
JFCBCTRI DS    CL1                          INDICATES WHETHER CYLINDERS 64500018
*                                            TRACKS, OR RECORDS ARE     64600018
*                                            SPECIFIED IN JFCBPQTY AND  64700018
*                                            JFCBSQTY                   64800018
JFCBSQTY DS    CL3                          SECONDARY QUANTITY OF D.A.  64900018
*                                            STORAGE REQUIRED           65000018
JFCBIND3 DS    CL1                          INDICATOR BYTE 3            65100018
JFCBCNTG EQU   64                            BITS 0 AND 1 - CONTIGUOUS  65200018
*                                            STORAGE INDICATOR          65300018
JFCBMXIG EQU   16                            BITS 2 AND 3 - MAXIMUM     65400018
*                                            AVAILABLE EXTENT INDICATOR 65500018
JFCBALXI EQU   4                             BITS 4 AND 5 - ALL EXTENTS 65600018
*                                            INDICATOR                  65700018
JFCBRNDC EQU   1                             BITS 6 AND 7 - ROUND       65800018
*                                            CYLINDER INDICATOR         65900018
JFCBDQTY DS    CL3                          QUANTITY OF D.A. STORAGE    66000018
*                                            REQUIRED FOR A DIRECTORY   66100018
JFCBSPNM DS    CL3                          CORE ADDRESS OF THE JFCB    66200018
*                                            WITH WHICH CYLINDERS ARE   66300018
*                                            SPLIT                      66400018
JFCBABST DS    CL2                          RELATIVE ADDRESS OF FIRST   66500018
*                                            TRACK TO BE ALLOCATED      66600018
JFCBSBNM DS    CL3                          CORE ADDRESS OF THE JFCB    66700018
*                                            FROM WHICH SPACE IS TO BE  66800018
*                                            SUBALLOCATED               66900018
JFCBDRLH DS    CL3                          AVERAGE DATA RECORD LENGTH  67000018
JFCBVLCT DS    CL1                          VOLUME COUNT                67100018
JFCBSPTN DS    CL1                          NUMBER OF TRACKS PER        67200018
*                                            CYLINDER TO BE USED BY     67300018
*                                            THIS DATA SET WHEN SPLIT   67400018
*                                            CYLINDER IS INDICATED      67500018
JFCBLGTH EQU   176                          LENGTH OF JFCB              67600018
JFCBEND  EQU   *                                                        67700018
*                                                                       67800018
         ORG   RSBUFSEG+176             ORG BACK TO BUFFER SEGMENT      68800018
RSSTATUS DS    0CL8                                                     69800018
RSSTAT1  DS    CL1                      STATUS BYTE 1                   70800018
RSSTAT2  DS    CL1                      STATUS BYTE 2                   71800018
RSSTAT3  DS    CL1                      STATUS BYTE 3                   72800018
RSSTAT4  DS    CL1                      STATUS BYTE 4                   73800018
         DS    F                        RESERVED FOR FUTURE USE         74800018
         EJECT                                                          79500018
CVT      DSECT                                                          79600018
         CVT                                                            79700018
         EJECT                                                          79800018
*                                                                       79900018
*                                                                       80000018
*   TASK CONTROL BLOCK                                                  80100018
*                                                                       80200018
*                                                                       80300018
         CNOP  0,4                                                      80400018
TCB      DSECT                                                          80500018
TCBRBP   DS    F                       POINTER TO EXECUTING RB          80600018
TCBPIE   DS    F                       POINTER TO PROG. INTERRUPT EL.   80700018
TCBDEB   DS    F                       POINTER TO DEB QUEUE             80800018
TCBTIO   DS    F                       POINTER TO TIOT                  80900018
TCBCMP   DS    F                       TASK COMPLETION CODE             81000018
TCBTRN   DS    F                       TESTRAN FIELD                    81100018
TCBMSS   DS    F                       DATA BLOCK QUEUE ELEMENT POINTER 81200018
TCBPRTK  DS    CL1                     PROTECTION TAG                   81300018
TCBFLGS  DS    FL5                     FLAG BYTES                       81400018
TCBLMP   DS    CL1                     LIMIT PRIORITY                   81500018
TCBDSP   DS    CL1                     DISPATCHING PRIORITY             81600018
TCBLLS   DS    F                       POINTER TO LOAD LIST             81700018
TCBJLB   DS    F                       POINTER TO JOBLIB DCB            81800018
TCBJSE   DS    F                       LIST OF INACTIVE PROGRAMS ADDR.  81900018
TCBGRS   DS    CL64                    GENERAL REGISTER SAVE AREA       82000018
TCBIDF   DS    CL1                     TCB IDENTIFIER FIELD             82100018
TCBFSA   DS    CL3                     POINTER TO 1ST PROB.PROG.SAVEAR  82200018
TCBTCB   DS    F                       NEXT TCB ON READY QUEUE POINTER  82300018
TCBTME   DS    F                       POINTER TO TIMER ELEMENT         82400018
         EJECT                                                          82500018
         DCBD  DSORG=PS                                                 82600018
         EJECT                                                          82700018
*                                                                       82800018
*                                                                       82900018
*   DATA EXTENT BLOCK  (UNTIL PROTIOS CHANGES)                          83000018
*                                                                       83100018
*                                                                       83200018
DEB      DSECT                                                          83300018
DEBNMSUB DS    0CL1                    NO. OF SUB RTNS                  83380018
DEBTCBAD DS    CL4                     TASK CONTROL BLOCK ADDR          83460018
DEBAMLNG DS    0CL1                    LENGTH OF ACCESS METHOD SEC      83540018
DEBDEBAD DS    CL4                     ADDR OF NEXT DEB IN DEB CHAIN    83620018
DEBOFLGS DS    0CL1                    DEB OPEN FLAGS                   83700018
DEBIRBAD DS    CL4                     ADDR OF THE IRB CONTROL BLOCK    83780018
DEBOPATB DS    0CL1                    OPEN ATRIBUTES                   83860018
DEBSYSPG DS    CL4                     SYSTEM PURGE FIELD               83940018
DEBNMEXT DS    0CL1                    NUMBER OF EXTENTS IN DEB         84020018
DEBUSRPG DS    CL4                     USER PURGE FIELD                 84100018
DEBPRIOR DS    0CL1                    INFO BYTE                        84180018
DEBECBAD DS    CL4                     EVENT CONTROL BLOCK ADDR         84260018
DEBPROTG DS    0CL1                    INFO BYTE                        84340018
DEBDEBID DS    0CL1                    INFO BYTE                        84420018
DEBDCBAD DS    CL4                     ADDR OF DCB                      84500018
DEBEXSCL DS    0CL1                    SCALING FACTOR OF DEB EXTENT     84580018
DEBAPPAD DS    CL4                     APPENDAGE TABLE ADDR             84660018
DEBDVMOD DS    0CL1                    DEVICE MODIFIER BYTE             84740018
DEBUCBAD DS    CL4                     UNIT CTL BLOCK ADDR              84820018
DEBTVLSQ DS    0CL2                VOL SEQ FOR TAPE                     84900018
DEBBINUM DS    CL2                     BIN NUMBER                       84980018
DEBTVLNM DS    0CL2                NO OF VOL FOR TAPE                   85060018
DEBSTRCC DS    CL2                     START CYLINDER NUMBER            85140018
DEBSTRHH DS    CL2                     START HEAD NUMBER                85220018
DEBENDCC DS    CL2                     END CYLINDER NUMBER              85300018
DEBENDHH DS    CL2                     END HEAD NUMBER                  85380018
DEBNMTRK DS    CL2                     NUMBER OF TRACKS                 85460018
*                                                                       85540018
*  FOR ADDITIONAL EXTENT ON DIRECT ACCESS THE FOLLOWING FIELDS          85620018
*  WILL HAVE TO BE OFFSET ANOTHER 16 BYTES                              85700018
*                                                                       85780018
DEBVOLSQ DS    H                       VOL SEQUENCE NUMBER              85860018
DEBVOLNM DS    H                       VOLUME NUMBER                    85940018
*                                                                       86020018
*  FOR EACH SUBROUTINE LOADED BUMP THIS OFFSET BY 2                     86100018
*                                                                       86180018
DEBSUBID DS    H                       SUBROUTINE ID ( 2 BYTES )        86260018
         EJECT                                                          86700018
TABL     DSECT           ***** AS OF 3 OCT 67 *****                     86800018
         DS    0CL48                                                    86900018
TABDSORG DS    CL1                      ORGN OF DATA SET                87000018
*                                         X'40' =  PS                   87100018
*                                         X'80' =  IS                   87200018
*                                         X'20' =  DA                   87300018
*                                         X'02' =  PO                   87400018
*                                         X'01' =  U                    87500018
TABDCBAD DS    CL3                      ADDR OF DCB FOR THIS ENTRY      87600018
TABFLG1  DS    CL1                      FLAG BYTE NO. 1                 87700018
*                                         X'80' = NULLFILE & SYSCHECK   87800018
*                                         X'40' = SYSIN OR SYSOUT D.S.  87900018
*                                         X'20' = DA DEVICE             88000018
*                                         X'10' = TAPE DEVICE           88100018
*                                         X'08' = END OF TABLE FLAG BIT 88200018
*                                         X'04' = UNIT RECORD OR OTHER  88300018
TABSEGAD DS    CL3                      ADDR OF W.A. SEG ASSIGNED       88400018
TABNVOLS DS    CL1                      TOTAL NO OF VOLUMES             88500018
TABJFCB  DS    CL3                      TTR ADDR OF JFCB - THIS DATASET 88600018
TABOTIOT DS    0CL2                     OLD USER TIOT OFFSET (DA ONLY)  88700018
TABTPLBL DS    CL1                      TAPE LABEL INFORMATION BYTE     88800018
*                                         X'80' = ERROR IN NSL PROC RTN 88900018
*                                         X'40' = NSL MOUNT SWITCH      89000018
*                                         X'20' = NSL COMMUNICATION BIT 89100018
*                                         X'10' = BYPASS LABEL PROSS.   89200018
*                                         X'04' = NONSTANDARD LABEL     89300018
*                                         X'02' = STANDARD LABEL        89400018
*                                         X'01' = NO LABEL              89500018
TABFSQNO DS    CL1                      FILE SEQUENCE NO. (IF TAPE)     89600018
TABFLG2  DS    CL1                      FLAG BYTE NO. 2                 89700018
*                                         X'80' = GREATER THAN 5 VOLS   89800018
*                                         X'40' = PO CONCATENATED       89900018
TABFLG3  DS    CL1                      FLAG BYTE NUMBER 3              90000018
TABFLG4  DS    CL1                      FLAG BYTE NUMBER 4              90100018
TABFLG5  DS    CL1                      FLAG BYTE NUMBER 5              90200018
TABVLID1 DS    CL6                      VOLUME ID NUMBER ONE            90300018
TABVLID2 DS    CL6                      VOLUME ID NUMBER TWO            90400018
TABVLID3 DS    CL6                      VOLUME ID NUMBER THREE          90500018
TABVLID4 DS    CL6                      VOLUME ID NUMBER FOUR           90600018
TABVLID5 DS    CL6                      VOLUME ID NUMBER FIVE           90700018
         EJECT                                                          90800018
TIOT     DSECT                                                          90900018
         IEFTIOT1                                                       91000018
         EJECT                                                          91100018
SRT      DSECT                                                          91200018
         IEFUCBOB                                                       91300018
*                                                                       91400018
*                                                                       91500018
*                                                                       91600018
         END                                                            91700018
