         TITLE  'IGG0191Y - SAM USER TOTALING FACILITY '                00100018
         COPY  LCGASMSW                                          Y01021 00150000
IGG0191Y CSECT                                                          00200018
*          RELEASE 19 DELETIONS                                       * 00300018
*          RELEASE 20 DELETIONS                                       * 00400018
*1753226000                                                      A30539 00450020
*1753345000,374000                                               M0653  00470020
*          RELEASE 21 DELETIONS                                       * 00500018
*A283500-283700,288500-288700                                   SA66735 00510021
*3021164000-166000,335000,372000                                 A44122 00550021
*          RELEASE 22 DELETIONS                                       * 00600018
*          RELEASE 23 DELETIONS                                       * 00700018
*          RELEASE 24 DELETIONS                                       * 00800018
*          RELEASE 25 DELETIONS                                       * 00900018
*          RELEASE 26 DELETIONS                                       * 01000018
*          RELEASE 27 DELETIONS                                       * 01100018
* STATUS CHANGE LEVEL 004                                               01200001
*********************************************************************** 01300018
* FUNCTION                                                              01400018
*                                                                       01500018
* THE MODULE PERFORMS TWO FUNCTIONS FOR DATA SETS REQUIRING SUPPORT     01600018
* FROM THE SAM USER TOTALING FACILITY: FIRST IT CALCULATES THE SIZE OF  01700018
* THE WORK AREA REQUIRED TO SAVE THE USER'S HASH TOTALING AREA AND PRO- 01800018
* VIDES A GETMAIN FOR THIS SPACE AND SECONDLY IS ISSUED A LOAD FOR THE  01900018
* RESIDENT SAVE ROUTINE, IGG019AX.                                      02000018
*                                                                       02100018
*                                                                       02200018
* INPUT                                                                 02300018
*                                                                       02400018
* THE INPUT TO THIS MODULE IS THE SAME AS TO ALL OTHER SAM OPEN EXEC-   02500018
* CUTORS:                                                               02600018
*                                                                       02700018
*      REG 5 - THE ADDRESS OF THE WHERE-TO-GO TABLE                     02800018
*                                                                       02900018
*      REG 6 - THE ADDRESS OF THE (DCB) PARAMETER LIST                  03000018
*                                                                       03100018
*      REG 7 - THE CURRENT ENTRY IN THE WTG TABLE                       03200018
*                                                                       03300018
*      REG 8 - THE CURRENT DCB ADDRESS                                  03400018
*                                                                       03500018
*                                                                       03600018
* OUTPUT                                                                03700018
*                                                                       03800018
* SAME AS INPUT PLUS A POINTER IN THE USER'S DEB TO THE FORMATTED USER  03900018
* TOTALING SAVE AREA, WHICH IN TURN POINTS TO THE LOADED RESIDENT SAVE  04000018
* ROUTINE.                                                              04100018
*                                                                       04200018
*                                                                       04300018
* GENERAL FLOW                                                          04400018
*                                                                       04500018
* THIS MODULE IS ENTERED VIA AN XCTL FROM IGG0191A WHENEVER A DCB IS    04600018
* ENCOUNTERED WHICH HAS SPECIFIED USER TOTALING.  AFTER DETERMINING     04700018
* THAT THERE IS AN ENTRY FOR USER TOTALING IN THE DCB EXIT LIST (IF NOT 04800018
* FOUND, THE DCB IS SET AS NOT OPERABLE AND AN XCTL TO NEXT MODULE IS   04900018
* ACCOMPLISHED) THE SIZE OF THE AREA REQUIRED TO SAVE THE USER'S TOTAL- 05000018
* ING AREAS (PLUS CONTROL BLOCKS) IS CALCULATED AND A GETMAIN FOR THIS  05100018
* SPACE IS ISSUED.  AFTER THE GETMAIN THE CONTROL BLOCKS FOR THE WORK   05200018
* AREA ARE CONSTRUCTED AND THE ADDRESS OF THE SAVE AREA IS PLACED IN    05300018
* THE ACCESS METHOD PORTION OF THE DEB.  NEXT A LOAD IS ISSUED FOR THE  05400018
* RESIDENT SAVE ROUTINE (IGG019AX) AND THE ADDRESS OF THE SAVE ROUTINE  05500018
* IS PLACED IN THE SAVE AREA.  AN XCTL TO THE NEXT MODULE OF OPEN IS    05600018
* THEN ACCOMPLISHED.                                                    05700018
*                                                                       05800018
*                                                                       05900018
* SPECIAL CONDITIONS                                                    06000018
* 1.  IF THERE IS INSUFFICIENT FREE CORE TO SATISFY THE GETMAIN AN      06100018
*     ABEND OCCURS.                                                     06200018
*                                                                       06300018
* 2.  IF THERE IS NO USER LABEL ENTRY IN THE DCB EXIT, LIST THE DCB IS  06400018
*     SET TO 'NOT OPENABLE' AND OPEN CONTINUES ON ALL OTHER DCB ASSOC-  06500018
*     IATED WITH TASK.                                                  06600018
*                                                                       06700018
*                                                                       06800018
* EXITS                                                                 06900018
*                                                                       07000018
* THIS MODULE XCTL'S TO THE NEXT OPEN EXECUTOR AS SPECIFIED IN THE WTG  07100018
* TABLE.  FOR NORMAL EXIT THE NEXT MODULE SELECTED FOR DATA SETS SUCC-  07200018
* ESSFULLY PROCESSED IS IGG0191B.                                       07300018
*                                                                     * 07400018
*FUNCTION      THIS EXECUTOR IS ENTERED FROM IGG0191A IF THE OPTION   * 07500018
*              CODE SPECIFIES THAT THE USER REQUIRES SUPPORT OF HIS   * 07600018
*              TATALING FEATURE AT END OF VOLUME (OPTCD=T).  IT       * 07700018
*              ISSUES A GETMAIN FOR THE WORKAREA REQUIRED TO SAVE     * 07800018
*              THE USER'S TOTALING FIELDS AND THE NECESSARY CONTROL   * 07900018
*              BLOCKS TO ENABLE THE EOV ROUTINE TO PRESENT THE        * 08000018
*              CORRECT FIELD TO HIM AT EOV TIME                       * 08100018
*                                                                     * 08200018
*ENTRY POINT - IGG0191Y                                               * 08300018
*                                                                     * 08400018
*              ENTERED FROM IGG0191A OR IGG0191N VIA AN XCTL          * 08500018
*                                                                     * 08600018
*INPUT                                                                * 08700018
*                                                                     * 08800018
*              WHERE-TO-GO (WTG) TABLE            REG 5 = RPAR        * 08900018
*              PARAMETER LIST                     REG 6 = RWTG        * 09000018
*              CURRENT ENTRY IN WTG TABLE         REG 7 = RPARC       * 09100018
*              CURRENT PARAMETER (DCB)            REG 8 = RWTGC       * 09200018
*                                                                     * 09300018
*OUTPUT        THE OUTPUT IS A FORMATTED SAVE AREA FOR THE USER       * 09400018
*              TOTALING FIELDS ASSOCIATED WITH PHYSICAL BLOCKS OF     * 09500018
*              DATA.  THE ADDR OF THIS AREA IS PLACED IN THE DEB      * 09600018
*                                                                     * 09700018
*EXITS         NORMAL - BALR TO SAM TOTALING ROUTINE - IGG019YY       * 09800018
*                       XCTL TO SAM EXECUTOR - IGG0191B               * 09900018
*              ABNORMAL - DCB IS SET AS NOT OPENABLE, DEB IS            10000018
*                         FREEMAINED AND IGG0190S IS NEXT               10100018
*                         MODULE TO GAIN CONTROL                        10200018
*                                                                     * 10300018
*TABLES/WORKAREAS                                                     * 10400018
*                                                                     * 10500018
*              THE DSECTS USED ARE AT THE END OF THIS MODULE          * 10600018
*              THE WORKAREA IS SECURED VIA A GETMAIN, IS FORMATTED    * 10700018
*              AND IT IS DESCRIBED IN TOTSAVWA DSECT                    10800018
*                                                                     * 10900018
*                                                                     * 11000018
*********************************************************************** 11100018
*  REGISTER CONVENTIONS USED THRUOUT OPEN                             * 11200018
*                                                                     * 11300018
*********************************************************************** 11400018
RE       EQU   0                        WORK REG/PARM REG               11500018
RF       EQU   1                        WORK REG/PARM REG               11600018
RDCB     EQU   2                        DCB BASE REG                    11700018
RBASE    EQU   3                        BASE REG FOR CSECT              11800018
RCORE    EQU   4                        WORK AREA BASE REG              11900018
RPAR     EQU   5                        START OF PARM LIST              12000018
RWTG     EQU   6                        START OF WTG TABLE              12100018
RPARC    EQU   7                        CURRENT ENTRY IN PARM LIST      12200018
RWTGC    EQU   8                        CURRENT ENTRY IN WTG TABLE      12300018
RTIOT    EQU   9                        BASE REG FOR TIOT               12400018
RUCB     EQU   10                       BASE REG FOR UCB                12500018
RDEB     EQU   11                       BASE REG FOR DEB                12600018
RB       EQU   12                       WORK REG                        12700018
RC       EQU   13                       WORK REG                        12800018
RD       EQU   14                       WORK REG                        12900018
RJ       EQU   15                       WORK REG                        13000018
*                                                                     * 13100018
*********************************************************************** 13200018
*                                                                     * 13300018
         BALR  RBASE,0                  ESTABLISH ADDRESSABILITY        13400018
         USING SUTF000,RBASE            ESTAB BASE REG                  13500018
         USING IHADCB,RDCB              ESTAB BASE REG                  13600018
         USING FORCORE,RCORE            ESTAB BASE REG FOR WRK AREA     13700018
         USING DEBB,RDEB                ESTAB DEB BASE REG              13800018
         USING TCB,RD                   ESTAB TCB BASE REG              13900018
         USING TIOT,RTIOT               ESTAB TIOT BASE REG             14000018
         USING UCBOB,RUCB               ESTAB UCB BASE REG              14100018
         USING TOTSAVWA,RF              ESTAB BASE FOR THIS DSECT     * 14200018
*********************************************************************** 14300018
*                                                                     * 14400018
SUTF000  EQU   *                                                        14500018
*                                                                     * 14600018
         TM    0(RPARC),X'04'           TEST FOR UPDATE            UT18 14700018
         BZ    SUTF003                  NOT UPDAT,BRANCH           UT18 14800018
         TM    0(RPARC),X'0B'           MAY BE UPDAT,TEST FURTHER  UT18 14900018
         BZ    TURNOFF                  IF UPDAT,SKIP TOLTALING    UT18 15000018
SUTF003  EQU   *                                                   UT18 15100018
         L     RDCB,0(RPARC)            GET DCB ADDR                    15200018
         LA    RDCB,0(RDCB)             CLEAR HI ORDER BYTE             15300018
         AIF   ('&LIB' NE 'LIB1').DEBCK10  TEST FOR LIB1(OS)     YM0890 15350001
         L     RDEB,DCBDEBAD            GET DEB ADDR                    15400018
.DEBCK10 ANOP                                                    Y01021 15450000
         L     RCORE,FOUR(RWTGC)        GET WORK AREA ADDR              15500018
         AIF   ('&LIB' EQ 'LIB1').DEBCK20  TEST FOR LIB1(OS)     Y01021 15550000
         L     RDEB,DXPDEBAD            LOAD PROTECTED DEB ADDR  Y01021 15560000
.DEBCK20 ANOP                                                    Y01021 15570000
         MVI   TWENTY2(RWTG),LOADMASK   SET CODE IN WTG TO LOAD ONLY    15600018
LOADMASK EQU   X'CB'                    MASK FOR ONLY LOADABLE          15700018
*                                                                     * 15800018
         SR    RUCB,RUCB                CLEAR REG                       15900018
         SR    RF,RF                    CLEAR REG                       16000018
         IC    RUCB,DEBNMEXT            GET NUMBER OF EXTENTS FROM DEB  16100018
         IC    RF,DEBEXSCL              GET SCALING FACTOR FROM DEB     16200018
         SLL   RUCB,0(RF)               SHIFT (MULT) PER EXTENT SIZE    16300018
         LA    RUCB,DEBBASI(RUCB,RDEB)  ADD BASIC DEB SIZE AND   A44122 16350021
*                                       DEB ADDR                        16400021
*                                                                       16450021
*        RUCB NOW POINTS TO ACCESS METHOD DEPENDENT SECTION             16500021
*        OF THE DEB                                                     16550021
*                                                                       16600021
*********************************************************************** 16700018
*  THE FOLLOWING SBRTN CHECKS THE USERS DCB EXIT LIST FOR A POINTER   * 16800018
*        TO HIS HASH TOTALING SAVE AREA                               * 16900018
*********************************************************************** 17000018
*                                                                     * 17100018
SUTF010  EQU   *                        SYMBOLIC ADDR                   17200018
*                                                                       17300018
         L     RB,DCBEXLST              GET ADDR OF EXIT LIST           17400018
         LA    RB,ZERO(RB)              CLEAR HI BYTE                   17500018
         LTR   RB,RB                    TEST FOR EXITLIST               17600018
         BZ    SUTF036                  BR IF ZERO - NO EXIT LIST       17700018
*                                                                       17800018
SUTF011  EQU   *                        SYMBOLIC ADDR                   17900018
*                                                                       18000018
         CLI   ZERO(RB),UTENTRY         TEST FOR TOTALING ENTRY         18100018
         BE    SUTF049                  YES, BRANCH                     18200018
         CLI   ZERO(RB),UTENTRY+ENDOLIST TEST FOR TOTALING ENTRY        18300018
         BE    SUTF049                  YES, BRANCH                     18400018
*                                                                       18500018
         TM    ZERO(RB),ENDOLIST        TEST FOR LAST ENTRY             18600018
         BO    SUTF036                  BRANCH IF LAST ENTRY            18700018
*                                                                       18800018
         LA    RB,FOUR(RB)              POINT TO NEXT ENTRY             18900018
         B     SUTF011                  UNCONDIT9ONAL BRANCH            19000018
*                                                                       19100018
*                                                                       19200018
SUTF036  EQU   *                        SYMBOLIC ADDR                   19300018
*                                                                       19400018
*  THE DCB IS UNOPENABLE DUE TO TOTALING BEING SPECIFIED AND NO         19500018
*              TOTALING ENTRY IN THE DCB EXIT LIST, A ZERO TOTALING     19560018
*              AREA ADDRESS, OR A ZERO TOTALING AREA LENGTH.  IT IS     19620018
*              NECESSARY TO UNCHAIN THE DEB FROM THE TCB, TO            19700018
*              FREEMAIN THE DEB,    TO CLEAR THE DCBDEBAD FIELD.        19800018
*              AND TO SET THE DCBOFLGS FIELD AS UNOPENABLE              19900018
*                                                                       20000018
         NI    DCBOFLGS,SETOFF          MARK DCB AS UNOPENABLE          20100018
*                                                                       20200018
         AIF   ('&LIB' EQ 'LIB1').DEBCK30  TEST FOR LIB1(OS)     Y01021 20250000
         DEBCHK (RDCB),TYPE=DELETE      DELETE DEB FROM DEBTABLE Y01021 20260000
.DEBCK30 ANOP                                                    Y01021 20270000
         L     RB,DEBTCBAD              GET THE TCB ADDR                20300018
         L     RC,EIGHT(RB)             GET THE FIRST DEB ADDR          20400018
         LR    RJ,RB                    SAVE TCB ADDR                   20500018
         LA    RDEB,ZERO(RDEB)          CLEAR HI-ORDER BYTE             20600018
         LA    RC,ZERO(RC)              CLEAR HI-ORDER BYTE             20700018
SUTF037  EQU   *                        SYMBOLIC ADDR                   20800018
*                                                                       20900018
         CR    RC,RDEB                  COMPARE DEB ADDRESSES           21000018
         BE    SUTF038                  BR IF EQUAL                     21100018
         LR    RJ,RC                    SAVE ADDR OF LAST DEB           21200018
         L     RC,FOUR(RC)              GET ADDR OF NEXT DEB            21300018
         LA    RC,ZERO(RC)              CLEAR HI-ORDER BYTE             21400018
         B     SUTF037                  UNCONDITIONAL BRANCH            21500018
*                                                                       21600018
SUTF038  EQU   *                        SYMBOLIC ADDR                   21700018
*                                                                       21800018
         CR    RJ,RB                    TEST FOR FIRST DEB              21900018
         BE    SUTF039                  BR IF FIRST                     22000018
*                                                                       22100018
         MVC   FIVE(3,RJ),FIVE(RC)      RESTORE DEB CHAIN               22200018
         B     SUTF040                  UNCONDITIONAL BRANCH            22300018
*                                                                       22400018
SUTF039  EQU   *                                                        22500018
         MVC   NINE(3,RB),FIVE(RC)      MOVE OLD DEB ADDR TO TCB A30539 22600020
*                                                                       22700018
SUTF040  EQU   *                        SYMBOLIC ADDR                   22800018
*                                                                       22900018
*                                                                       23000018
*  CALCULATE DEB SIZE AND ISSUE FREEMAIN FROM SUBPOOL 254               23100018
*                                                                       23200018
         LA    RB,THREE6                LOAD VALUE OF 36                23300018
         LR    RC,RDEB                  GET DEB ADDR                    23400018
         LA    RC,ZERO(RC)              CLEAR HI-ORDER BYTE             23500018
         SR    RC,RB                    POINT TO APPENDAGE START        23600018
         SR    RB,RB                    CLEAR,REG                       23700018
         IC    RB,THREE2(RC)            PICK UP DEB LEN IN DBC WDS      23800018
         SR    RD,RD                    CLEAR REG                       23900018
         SLL   RB,THREE                 GET LEN IN BYTES                24000018
*                                                                       24100018
*  REGISTER RB CONTAINS LENGTH TO BE RELEASED, RC CONTAINS ADDR         24200018
*              SO ISSUE FREEMAIN ON SUB POOL 254                        24300018
*                                                                       24400018
         FREEMAIN R,LV=(RB),A=(RC),SP=254                               24500018
*                                                                       24600018
*                                                                       24700018
         SR    RB,RB                    CLEAR REG                       24800018
         ST    RB,DCBDEBAD              STORE ZEROS IN DCBS DEB ADDR    24900018
*                                                                       25000018
         MVC   ZERO(2,RWTGC),ZEROHW     ZERO WTG ENTRY                  25100018
         B     RELOOP                                                   25200018
*                                                                       25300018
SUTF049  EQU   *                        SYMBOLIC ADDR                   25400018
*                                                                     * 25500018
*********************************************************************** 25600018
*  AT THIS POINT REGISTER 12 (RB) POINTS TO THE FULL WORD WHICH CON-  * 25700018
*        TAINS THE ADDRESS OF THE USERS TOTALING SAVE AREA.  THE FIRST* 25800018
*        TWO BYTES OF THIS AREA CONTAIN ITS LENGTH IN BYTES           * 25900018
*        IF THIS LENGTH IS AN ODD NUMBER OF BYTES, IT IS ROUNDED UP   * 26000018
*        TO AN EVEN NUMBER FOR THE IMAGE SEGMENT LENGTH SO THAT EACH  * 26100018
*        SEGMENT WILL START ON A HALF-WORD BOUNDARY.  HOWEVER, ONLY   * 26200018
*        THE NUMBER OF BYTES INDICATED IN THE USER'S AREA WILL BE     * 26300018
*        MOVED TO THE IMAGE SEGMENT.                                  * 26400018
*********************************************************************** 26500018
*                                                                     * 26600018
         L     RB,ZERO(RB)              GET IMAGE AREA ADDR             26700018
         LA    RB,ZERO(RB)              CLEAR HI BYTE                   26720018
         LTR   RB,RB                    CHECK FOR ZERO ADDR             26740018
         BZ    SUTF036                  BR,NO ADDRESS SPECIFIED         26760018
         LH    RC,ZERO(RB)              GET LENGTH ATTRIBUTE            26800018
         LTR   RC,RC                    CHECK FOR ZERO LENGTH           26830018
         BZ    SUTF036                  BR IF LENGTH IS ZERO            26860018
         TM    1(RB),X'01'              TEST FOR EVEN LENGTH            26900018
         BZ    SUTF050A                 BRANCH IF ALREADY EVEN          27000018
         LA    RC,ONE(RC)               ROUND UP TO EVEN LENGTH         27100018
*                                                                     * 27200018
*********************************************************************** 27300018
*  NOTE -- COMPUTE THE NUMBER OF BYTES REQUIRED FOR SAM SAVE AREA     * 27400018
*********************************************************************** 27500018
*                                                                     * 27600018
SUTF050A EQU   *                                                        27700018
         SR    RD,RD                    CLEAR THIS REG                  27800018
         SR    RJ,RJ                    CLEAR THIS REGISTER             27900018
         TM    DCBCIND2,QSAMTEST        TEST FOR QSAM                   28000018
         BO    SUTF050                  IT IS QSAM                      28100018
*                                                                     * 28200018
         IC    RJ,DCBNCP                GET NO. OF CHAN PROG'S          28300018
         LTR   RJ,RJ                    CHECK FOR ZERO          SA66735 28350021
         BNZ   SUTF060                  NOT ZERO, USE VALUE     SA66735 28360021
         LA    RJ,1                     ZERO, DEFAULT TO ONE    SA66735 28370021
         B     SUTF060                  UNCONDITIONAL BRANCH            28400018
*                                                                     * 28500018
SUTF050  EQU   *                        SYMBOLIC ADDR                   28600018
*                                                                     * 28700018
         IC    RJ,DCBBUFNO              GET NO. OF BUFFERS              28800018
         LTR   RJ,RJ                    CHECK VALUE OF BUFNO    SA66735 28850021
         BNZ   SUTF060                  IF NOT 0, USE IT        SA66735 28860021
         LA    RJ,2                     DEFAULT BUFNO TO TWO    SA66735 28870021
*                                                                       28900018
SUTF060  EQU   *                        SYMBOLIC ADDR                   29000018
*                                                                       29100018
         LA    RJ,ONE(RJ)               ADD ONE IMAGE AREA TO TOT       29200018
         MR    RD,RC                    MULT TO GET SAVE ELNGTH         29300018
*                                                                       29400018
*********************************************************************** 29500018
*   THE RESULT IS IN RJ - SO ADD ENOUGH BYTES FOR CONTROL BLOCKS - THEN 29600018
*        ISSUE A GETMAIN FOR THE SAM SAVE AREA                        * 29700018
*********************************************************************** 29800018
*                                                                       29900018
         AH    RJ,FORTY8                ADD 48 BYTES FOR CB'S           30000018
*                                                                     * 30400018
         LR    RTIOT,RJ                 SAVE GETMAIN LENGTH             30500018
*                                                                       30600018
         GETMAIN   R,LV=(RJ),SP=250                                     30700018
*                                                                     * 30800018
*********************************************************************** 30900018
*  PICK UP THE POINTER TO THE WORKAREA FROM RF (REGISTER 1) AND CLEAR * 31000018
*        THE WORKAREAS FIRST 48 BYTES                                 * 31100018
*********************************************************************** 31200018
*                                                                       31300018
*                                                                       31400018
         XC    ZERO(48,RF),ZERO(RF)     CLEAR FIRST 48 BYTES            31500018
*                                                                       31600018
*********************************************************************** 31700018
*  FORMAT THE CONTROL BLOCKS IN SAVE AREA - CURRENT REG VALUES ARE      31800018
*********************************************************************** 31900018
*        RJ =  LENGTH OF GETMAIN                                        32000018
*        RB =  POINTER TO USER'S IMAGE AREA                             32100018
*        RC =  LENGTH OF IMAGE AREA AND ALSO SEG SAVE LENGTH            32200018
*        RD =  VOLATILE - MAY BE USED FOR ANY PURPUSE                   32300018
*        RJ =  NO. OF CHAN PROG'S OR NO. OF BUFFERS (+1)                32400018
*        RF =  ADDRESS OF GETMAIN AREA                                  32500018
*        RUCB= POINTER TO DEB ACCESS METHOD SEC + 4                     32600018
*        RDCB= POINTER TO DCB                                           32700018
*        RBASE=BASE REG                                                 32800018
*        RCORE THRU RWTGC CONTAIN XCTL CONTROL POINTERS                 32900018
*        RTIOT = NUMBER OF BYTES IN GETMAIN                             33000018
*        RE =   VOLATILE                                                33100018
*********************************************************************** 33200018
         ST    RB,TOTUSRWA              STORE POINTER TO USER IMAGE     33300018
         ST    RTIOT,TOTTOTLN           SAVE LENGTH OF GETMAIN          33400018
         ST    RF,FOUR(RUCB)            SAVE WA IN DEB AM        A44122 33460021
*                                       SECTION                  A44122 33520021
         ST    RC,TOTSVLNG              STORE IMAGE AND SV LENGTH       33600018
         LA    RD,FOUR8(RF)             GET ADDR OF FIRST SEG           33700018
         ST    RD,TOTSTART              STORE IT IN TABLE               33800018
         LA    RD,ZERO(RTIOT,RF)        GET END ADDR OF TABLE           33900018
         SR    RD,RC                    SUBTRACT 1 SEG LENGTH           34000018
*                                                                       34100018
*  RD NOW CONTAINS ADDR OF LAST SEGMENT OF THE SAVE AREA                34200018
*                                                                       34300018
         ST    RD,TOTENDAD              STORE IT IN CONTROL BLOCK       34400018
         LR    RC,RF                    SAVE WA POINTER          M0653  34500020
*                                                                     * 34600018
*********************************************************************** 34700018
*  IT IS NOW NECESSARY TO SETUP FOR THE LOADING OF THE RESIDENT SAVE  * 34800018
*        ROUTINE WHICH WILL BE BALR'D TO BY THE END OF BLOCK ROUTINES * 34900018
*********************************************************************** 35000018
*                                                                     * 35100018
         LA    RB,SAVMOD                POINT TO SAVE MOD IDTTRL        35200018
         MVC   FOURTEEN(THREE,RWTG),TWO(RB) MOVE TTR TO XCTL TABLE      35300018
         MVC   SIX(TWO,RWTG),ZERO(RB)   MOVE 2 BYTE ID TO TABLE         35400018
         SR    RF,RF                    CLEAR THIS REGISTER             35500018
         IC    RF,FIVE(RB)              GET DOUBLE WRD LEN OF MOD       35600018
         SLL   RF,THREE                 MULT LEN BY 8 TO GET BYTE LEN   35700018
         ST    RF,TWENTY4(RWTG)         STORE BYTE LEN IN TABLE         35800018
         MVC   TWENTY4(THREE,RWTG),TWENTY5(RWTG) STORE TOT LEN          35900018
         MVC   TWENTY7(TWO,RWTG),TWENTY5(RWTG) STORE TEXT LEN           36000018
         L     RF,CVTPTR(0,0)           GET COMM VECTOR TABL ADDR       36100018
         USING CVTTCBP,RF               ESTABLISH DSECT BASE            36200018
         L     RF,CVTSVDCB              GET SVC LIB'S DCB ADDR          36300018
*********************************************************************** 36400018
         LOAD  DE=(RWTG),DCB=(RF)       LOAD SAVE RTN                   36500018
*********************************************************************** 36600018
*                                                                     * 36700018
*********************************************************************** 36800018
*  THE ADDR OF THE LOADED ROUTINE IS RETURNED IN RE (REG 0)           * 36900018
*                                                                       36910021
*  RUCB POINTS TO DEB AT ACCESS METHOD DEPENDENT SECTION.  ADD          36920021
*  SIZE OF ACCESS METHOD DEPENDENT SECTION TO POINT TO DEB              36930021
*  SUBROUTINE ID SECTION.                                               36940021
*                                                                       36950021
*********************************************************************** 37000018
*                                                                       37100018
         SR    RF,RF                                             A44122 37140021
         IC    RF,DEBAMLNG              GET LENGTH               A44122 37180021
         AR    RUCB,RF                  POINT TO SUBROUTINE ID   A44122 37220021
*                                       SECTION OF DEB                  37260021
         MVC   ZERO(TWO,RUCB),ZERO(RB)  MOVE ID TO DEB                  37300018
         LR    RF,RC                    RESTORE WA POINTER       M0653  37400020
         USING TOTSAVWA,RF              ESTABLISH BASE THIS DSECT       37500018
         SR    RD,RD                    CLEAR REGISTER                  37600018
         IC    RD,DEBNMSUB              PICK UP DEB SUBRTN COUNT        37700018
         LA    RD,ONE(RD)               BUMP COUNT BY ONE               37800018
         STC   RD,DEBNMSUB              STORE IT BACK IN DEB            37900018
         ST    RE,TOTSVPTR              STORE SAVE RTN ADDR             38000018
*                                                                     * 38100018
* IT IS NOW NECESSARY TO SAVE THE USERS IMAGE AREA INITIALLY          * 38200018
*                                                                     * 38300018
         L     RB,TOTUSRWA              GET PTR TO USERS IMAGE AREA     38400018
         L     RC,TOTSTART              GET FIRST IMAGE SAVE SEG        38500018
         ST    RC,TOTCURNT              INITIALIZE TOTCURNT POINTER     38600018
         ST    RC,TOTEOVPT              INITIALIZE EOV POINTER          38700018
         LA    RJ,KON256                LOAD VALUE OF 256               38800018
         LH    RD,0(RB)                 GET USER'S LENGTH               38900018
SUTF070  EQU   *                                                        39000018
         CR    RD,RJ                    COMPARE SEG LENGTH TO 256       39100018
         BNH   SUTF080                  BR IF LEN NOT HIGH              39200018
*                                                                     * 39300018
*                                                                     * 39400018
         BCTR  RJ,0                     DECR LNGTH TO 255 FOR MOVE      39500018
         EX    RJ,MOVIMAGE              MOVE 256 BYTES                  39600018
         LA    RJ,1(RJ)                 RESTORE TO 256                  39700018
         AR    RC,RJ                    BUMP ADDR BY 256                39800018
         AR    RB,RJ                    BUMP ADDR BY 256                39900018
         SR    RD,RJ                    SUB 256 FROM IMAGE LEN          40000018
         B     SUTF070                  BR TO MOVE MORE BYTES           40100018
SUTF080  EQU   *                        SYMBOLIC ADDR                   40200018
*                                                                     * 40300018
         BCTR  RD,0                     DECR LNGTH FOR MOVE INSTR       40400018
         EX    RD,MOVIMAGE              MOVE REMAINING BYTES            40500018
*                                                                     * 40600018
*  THE USER'S IMAGE AREA HAS NOW BEEN STORED IN THE FIRST SAVE SEG    * 40700018
*                                                                     * 40800018
*                                                                     * 40900018
*********************************************************************** 41000018
*  AT THIS POINT THE SAVE ROUTINE HAS BEEN LOADED, THE ID HAS BEEN    * 41100018
*        PLACED IN THE DEB, AND THE SUBROUTINE COUNT HAS BEEN UP-     * 41200018
*        DATED.  ALSO THE GETMAIN FOR THE SAVE AREAS HAS BEEN MADE    * 41300018
*********************************************************************** 41400018
*                                                                     * 41500018
RELOOPA  EQU   *                                                   UT18 41600018
         MVC   ZERO(5,RWTGC),SOP1B      SETUP FOR XCTL TO NEXT MOD      41700018
*                                                                     * 41800018
*                                                                       41900018
RELOOP   LA    RWTGC,WGOFF(0,RWTGC)     INCREMENT CURR WTG ENTRY        42000018
         LA    RPARC,PLOFF(0,RPARC)     INCR CURRENT DCB ENTRY PRTR     42100018
         CLC   0(2,RWTGC),AMIDCNST      THIS RT NEEDED AGAIN            42200018
         BC    8,SUTF000                YES, THIS MODULE REQD AGAIN     42300018
*                                                                       42400018
         CLC   0(2,RWTGC),OPIDCNST      END OF TABLE                    42500018
         BC    7,RELOOP                 NO,CHECK NEXT ENTRY             42600018
*                                                                       42700018
         LR    RPARC,RPAR                                               42800018
         LA    RWTGC,WAOFF(0,RWTG)      REINITIALIZE WTG LIST PTR       42900018
ZCHEK    CLI   0(RWTGC),X'00'          IS THIS ENTRY COMPLETE           43000018
         BC    7,TCTLRTN                IF NOT TRANSFER CONTROL         43100018
*                                                                       43200018
         LA    RWTGC,WGOFF(0,RWTGC)     GET NEXT ENTRY                  43300018
         LA    RPARC,PLOFF(0,RPARC)                                     43400018
         BC    15,ZCHEK                                                 43500018
TURNOFF  EQU   *                                                   UT18 43600018
         NI    DCBOPTCD,X'FD'           TURN OFF TOTALING BIT      UT18 43700018
         B     RELOOPA                  BRANCH TO SET UP XCTL      UT18 43800018
*                                                                       43900018
TCTLRTN  EQU   *                                                        44000018
         MVC   22(7,RWTG),XCTLCON      RESTORE ATTR.,LENGTH OF XCTL     44100018
         MVC   14(3,RWTG),2(RWTGC)     MOVE TTR FROM WTGC TO DE         44200018
         LA    RJ,DXCCW12              LOAD 15 WITH ADDR. OF PAR. LIST  44300018
         MVC   6(2,RWTG),0(RWTGC)       STR NEXT EXEC NAME              44400018
*                                                                       44500018
         XCTL  DE=(RWTG),SF=(E,(15))   TRANS. CONTROL                   44600018
*                                                                       44700018
*                                                                       44800018
*                                                                       44900018
WAOFF    EQU   32                       PARAMETRIC 32                   45000018
PLOFF    EQU   4                        OFFSET OF DCB ENTRIES           45100018
WGOFF    EQU   8                        OFFSET OF WTG ENTRIES           45200018
DEBBASI  EQU   32                       SIZE OF DEB BASIC        A44122 45230021
*                                       SECTION                  A44122 45260021
ZERO     EQU   0                        PARAMETRIC 0                    45300018
ONE      EQU   1                        PARAMETRIC 1                    45400018
TWO      EQU   2                        PARA2                           45500018
THREE    EQU   3                        PARA 3                          45600018
FOUR     EQU   4                        PARA 4                          45700018
FIVE     EQU   5                        PARA 5                          45800018
SIX      EQU   6                        PARA 6                          45900018
EIGHT    EQU   8                        PARA 8                          46000018
FOURTEEN EQU   14                       PARA 14                         46100018
TWENTY2  EQU   22                       PARA 22                         46200018
TWENTY4  EQU   24                       PARA  24                        46300018
TWENTY5  EQU   25                       PARA 25                         46400018
TWENTY7  EQU   27                       PARA 27                         46500018
THREE2   EQU   32                       OFFSET TO DEB LENGTH            46600018
THREE6   EQU   36                       PARAMETRIC 36                   46700018
FOUR8    EQU   48                       PARAMETRIC 48                   46800018
KON256   EQU   256                      LENGTH FOR MOVE INSTRUCTION     47000018
QSAMTEST EQU   X'01'                    MASK FOR QSAM TEST              47100018
SETOFF   EQU   X'FE'                    MASK FOR DCBOFLGS               47200018
NINE     EQU   9                        PARAMETRIC 9                    47300018
OPIDCNST DC    C'0S'                    CONSTANT FOR OS TEST            47400018
XCTLCON  DC    X'C378'                 XCTL ATTR.-REENT.,REUSEABLE      47500018
*                                        NOT IN OV'LAY,NOT TEST,NOT     47600018
*                                        ONLY LOADABLE,BLOCK FORMAT,    47700018
*                                        EXECUTABLE,1 TEXT,COMPAT.,     47800018
*                                        ORIGIN AT 0,ENTRY PT.0,NO RLD  47900018
*                                        NO ESD,NO SYMBOL CARDS         48000018
         DC    X'000400'               TOTAL LENGTH                     48100018
         DC    X'0400'                 TEXT LENGTH                      48200018
AMIDCNST DC    C'1Y'                    ID FOR THIS MODUEL              48300018
*                                                                       48400018
MOVIMAGE MVC   ZERO(0,RC),ZERO(RB)      VARIABLE MOVE INSTRUCTION       48500018
*                                                                       48600018
*                                                                       48700018
         DS    0H                                                       48800018
*********************************************************************** 48900018
*  THE FOLLOWING ARE ALL OF THE EQUATE STATEMENTS FOR THIS MODULE     * 49000018
*********************************************************************** 49100018
*                                                                     * 49200018
UTENTRY  EQU   X'0A'                    MASK FOR TOTALING ENTRY         49300018
ENDOLIST EQU   X'80'                    MASK FOR END OF LIST            49400018
CNTLBLKS EQU   16                       ABSOLUTE OFFSET OF CVT          49500018
*                                                                     * 49600018
*********************************************************************** 49700018
*  THE FOLLOWING ARE THE CONSTANTS REQUIRED IN THIS MODULE            * 49800018
*********************************************************************** 49900018
*                                                                     * 50000018
FORTY8   DC    H'48'                    CONSTANT OF 48                  50100018
ZEROHW   DC    H'0'                                                     50200018
*********************************************************************** 50300018
*  THE SECTION IS USED BY IEHIOSUP TO RECEIVE THE TTR'S OF THE        * 50400018
*        VARIOUS MODULES TO BE CALLED SO THAT THEY CAN BE IN TURN     * 50500018
*        PLACED IN THE WTG TABLE FOR XCTL'ING BY TTR                  * 50600018
*********************************************************************** 50700018
         ORG   IGG0191Y+1000            ESTABLISH TABLE BASE            50800018
SAVMOD   DC    C'AX    '                IDTTR FOR SAVE MOD              50900018
SOP1B    DC    C'1B    '                     IDTTR FOR NEXT MOD         51000018
EOTBLMKR DC    H'0'                          END OF TABLE MARKER        51100018
         DC    3H'0'                         FILLER OF HALF WORDS       51200018
         DC    C'019'                        OPEN SVC CODE              51300018
         DC    AL1(125)                      LENGTH TO TABLESTART IN    51400018
*                                            DOUBLE WORDS               51500018
*                                                                     * 51600018
SRT      DSECT                                                          51700018
         IEFUCBOB                                                       51800018
*                                                                       51900018
         EJECT                                                          52000018
           DCBD  DSORG=PS                                               52100018
CVT      DSECT                                                          52200018
         CVT                                                            52300018
*   TASK CONTROL BLOCK                                                  52400018
         CNOP  0,4                                                      52500018
TCB      DSECT                                                          52600018
TCBRBP   DS    F                       PO9NTER TO EXECUTING RB          52700018
TCBPIE   DS    F                       POINTER TO PROG. INTERRUPT EL.   52800018
TCBDEB   DS    F                       POINTER TO DEB QUEUE             52900018
TCBTIO   DS    F                       POINTER TO TIOT                  53000018
TCBCMP   DS    F                       TASK COMPLETION CODE             53100018
TCBTRN   DS    F                       TESTRAN FIELD                    53200018
TCBMSS   DS    F                       DATA BLOCK QUEUE ELEMENT POINTER 53300018
TCBPKF   DS    CL1                     RESERVED FOR FUTURE USE          53400018
TCBFLGS  DS    FL5                     FLAG BYTES                       53500018
TCBLMP   DS    CL1                     RESERVED FOR FUTURE USE          53600018
TCBDSP   DS    CL1                     RESERVED FOR FUTURE USE          53700018
TCBLLS   DS    F                       POINTER TO LOAD LIST             53800018
TCBJLB   DS    F                       POINTER TO JOBLIB DCB            53900018
TCBJSE   DS    F                       LIST OF INACTIVE PROGRAMS ADDR.  54000018
TCBGRS   DS    CL64                    GENERAL REGISTER SAVE AREA       54100018
TCBIDF   DS    CL1                     TCB IDENTIFIER FIELD             54200018
TCBFSA   DS    CL3                     POINTER TO 1ST PROB.PROG.SAVEAR  54300018
TCBTCB   DS    F                       RESERVED FOR FUTURE USE          54400018
TCBTME   DS    F                       POINTER TO TIMER ELEMENT         54500018
         DS    CL24                                                     54600018
TIOT     DSECT                                                          54700018
TIOELNGH DS    CL1                           LENGTH OF THIS ENTRY       54800018
TIOESTTA DS    CL1                           STATUS -A-                 54900018
TIOERLOC DS    CL2                           REL. LOC OF POOL           55000018
TIOEDDNM DS    2F                            DDNAME                     55100018
TIOEJFCB DS    1F                            JFCB DISK ADDR             55200018
TIOESTTB DS    0CL1                                                     55300018
TIOEFSRT DS    CL4                                                      55400018
         DS    CL1                                                      55500018
*        TIOT POOL ENTRY                                                55600018
TIOPNSLT DS    XL1                           NR.OF SLOTS FOR POOL       55700018
         DS    CL1                                                      55800018
TIOPNSRT DS    XL1                           NR.OF DEVICES (FILLED      55900018
*                                             SLOTS)                    56000018
TIOPPOOL DS    CL8                           POOL NAME                  56100018
TIOPSTTB DS    XL1                           STATUS OF SLOT             56200018
TIOPSLOT DS    XL3                           SRT ADDRESS OR EMPTY SLOT  56300018
TIOTFEND DS    1F                            FINAL END OF AN ENTRY      56400018
         SPACE 1                                                        56500018
*   DATA EXTENT BLOCK  (UNTIL PROTIOS CHANGES)                          56600018
FORCORE  DSECT                                                          56700018
         IECDSECT                                                       56800018
CCWOFSET EQU   DXCCW12-FORCORE     CCW RELOCATABLE OFF SET FOR DXCCW12  56900018
DCBOFSET EQU   DCBDEBAD-IHADCB     DEB RLCATBL OFFSET IN DCB            57000018
DEBB     DSECT                         THIS DSECT DESCRIBES THE DEB     57100018
DEBNMSUB DS    0CL1                    NO. OF SUB RTNS                  57200018
DEBTCBAD DS    CL4                     TASK CONTROL BLOCK ADDR          57300018
DEBAMLNG DS    0CL1                    LENGTH OF ACCESS METHOD SEC      57400018
DEBDEBAD DS    CL4                     ADDR OF NEXT DEB IN DEB CHAIN    57500018
DEBOFLGS DS    0CL1                    DEB OPEN FLAGS                   57600018
DEBIRBAD DS    CL4                     ADDR OF THE IRB CONTROL BLOCK    57700018
DEBOPATB DS    0CL1                    OPEN ATRIBUTES                   57800018
DEBSYSPG DS    CL4                     SYSTEM PURGE FIELD               57900018
DEBNMEXT DS    0CL1                    NUMBER OF EXTENTS IN DEB         58000018
DEBUSRPG DS    CL4                     USER PURGE FIELD                 58100018
DEBPRIOR DS    0CL1                    INFO BYTE                        58200018
DEBECBAD DS    CL4                     EVENT CONTROL BLOCK ADDR         58300018
DEBPROTG DS    0CL1                    INFO BYTE                        58400018
DEBDEBID DS    0CL1                    INFO BYTE                        58500018
DEBDCBAD DS    CL4                     ADDR OF DCB                      58600018
DEBEXSCL DS    0CL1                    SCALING FACTOR OF DEB EXTENT     58700018
DEBAPPAD DS    CL4                     APPENDAGE TABLE ADDR             58800018
DEBDVMOD DS    0CL1                    DEVICE MODIFIER BYTE             58900018
DEBUCBAD DS    CL4                     UNIT CTL BLOCK ADDR              59000018
DEBTVLSQ DS    0CL2                     VOL SEQ FOR TAPE                59100018
DEBBINUM DS    CL2                     BIN NUMBER                       59200018
DEBTVLNM DS    0CL2                     NO OF VOL FOR TAPE              59300018
DEBSTRCC DS    CL2                     START CYLINDER NUMBER            59400018
DEBSTRHH DS    CL2                     START HEAD NUMBER                59500018
DEBENDCC DS    CL2                     END CYLINDER NUMBER              59600018
DEBENDHH DS    CL2                     END HEAD NUMBER                  59700018
DEBNMTRK DS    CL2                     NUMBER OF TRACKS                 59800018
*  FOR ADDITIONAL EXTENT ON DIRECT ACCESS THE FOLLOWING FIELDS          59900018
*  WILL HAVE TO BE OFFSET ANOTHER 16 BYTES                              60000018
DEBVOLSQ DS    H                       VOL SEQUENCE NUMBER              60100018
DEBVOLNM DS    H                       VOLUME NUMBER                    60200018
*  FOR EACH SUBROUTINE LOADED BUMP THIS OFFSET BY 2                     60300018
DEBSUBID DS    H                       SUBROUTINE ID ( 2 BYTES )        60400018
TOTSAVWA DSECT                                                          60500018
*                                                                     * 60600018
*********************************************************************** 60700018
*  THIS DSECT ESTABLISHES THE SYMBOLIC REFERENCES FOR THE USER TOTAL- * 60800018
*        ING FACILITY SAVE WORKAREA.                                  * 60900018
*********************************************************************** 61000018
TOTFLGBT DS    0CL1                     X'80' = NO SAVE FOR UTF    UT18 61100018
TOTSVPTR DS    F                        ADDR OF THE SAVE RTN            61200018
TOTCURNT DS    F                        ADDR OF CURRENT SAVE SEGMENT    61300018
TOTSTART DS    F                        BEGINNING ADDR OF SAVE SEGMENTS 61400018
TOTENDAD DS    F                        ADDR OF LAST SAVE SEGMENT       61500018
TOTSVLNG DS    F                        LENGTH OF THE USER'S SAVE AREA  61600018
TOTUSRWA DS    F                        ADDR OF THE USERS TOT AREA      61700018
TOTTOTLN DS    F                       TOTAL LEN OF GETMAIN             61800018
TOTEOVPT DS    F                        POINTER TO EOV SEG              61900018
TOTREGSV DS    D                        SAVE AREA FOR R11 & R12         62000018
         DS    D                       SAV AREA  FOR REG'S              62100018
*********************************************************************** 62200018
           END                                                          62300018
