         TITLE 'IGG0197C - IOB-MICB-CCW CONSTRUCTION'                   00100000
IGG0197C CSECT                                                          01100000
*          RELEASE 22 DELETIONS                                         01900021
*          RELEASE 21.8 CHANGES                                         01950021
*A651620-651900                                 OX03121/0Y02817/SA61601 02000021
*          RELEASE 21 DELETIONS                                         02700021
*0000384000                                                      A41426 03100021
*0000232000                                                      A48612 03150021
*********************************************************************** 03600000
*                                                                     * 03800000
*FUNCTION/OPERATION-  THIS ROUTINE SUPPLEMENTS THE INITIAL OPEN       * 04000000
*      ROUTINE BY PERFORMING SPECIFIC FUNCTIONS FOR THE MAGNETIC      * 04200000
*      INK CHARACTER READER PROCESSING.                               * 04400000
*      IT DETERMINES THE AMOUNT OF SPACE REQUIRED FOR THE IOB'S AND   * 04600000
*      MAGNETIC CHARACTER READER INTERRUPT CONTROL BLOCKS (MICB) AND  * 04800000
*      ISSUES A GETMAIN FOR THE MAIN STORAGE.  THE IOB'S AND MICB'S   * 05000000
*      ARE INITIALIZED WITH AS MUCH INFORMATION AS AVAILABLE.         * 05200000
*      THE AMOUNT OF SPACE REQUIRED FOR THE CCW'S, WRITE DELAY        * 05400000
*      BUFFERS, AND AN ECB PARAMETER LIST IS DETERMINED AND A         * 05600000
*      GETMAIN ISSUED FOR THE SPACE. THESE FIELDS ARE INITIALIZED     * 05800000
*      OR BUILT WITH THEIR REQUIRED DATA.                             * 06000000
*      THE PROCESSING OF THIS ROUTINE IS REPEATED UNTIL ALL THE       * 06200000
*      DCB'S IN THE PARAMETER LIST IS EXHAUSTED.                      * 06400000
*                                                                     * 06600000
*                                                                     * 06800000
*                                                                     * 07000000
*ENTRY POINT-  THIS ROUTINE IS ENTERED AT THE CSECT IGG0197C          * 07200000
*                                                                     * 07400000
*                                                                     * 07600000
*INPUT-  THE INPUT CONSISTS OF A PARAMETER LIST CONTAINING ADDRESSES  * 07800000
*      OF DCB'S TO BE OPENED.  IN ADDITION, SEVERAL REGISTERS         * 08000000
*      CONTAIN ADDRESSES OF SEVERAL CONTROL BLOCKS                    * 08200000
*                                                                     * 08400000
*                                                                     * 08600000
*OUTPUT-  OUTPUT IS AS FOLLOWS:                                       * 08800000
*                                                                     * 09000000
*                                                                     * 09200000
*      1. IOB'S, MICB'S, CCW'S, WRITE DELAY BUFFERS, AND ECB LIST.    * 09400000
*                                                                     * 09600000
*      2. THE BLOCKS AND FIELDS LISTED ABOVE ARE INITIALIZED.         * 09800000
*                                                                     * 10000000
*                                                                     * 10200000
*EXTERNAL ROUTINES-   NONE                                            * 10400000
*                                                                     * 10600000
*EXITS -  NORMAL    XTCL TO  IGG0197D                                 * 10800000
*                                                                     * 11000000
*        ERROR      N/A                                               * 11200000
*                                                                     * 11400000
*                                                                     * 11600000
*TABLES/WORK AREAS-    NONE                                           * 11800000
*                                                                     * 12000000
*ATTRIBUTES-   REENTRANT, REUSABLE                                    * 12200000
*                                                                     * 12400000
*                                                                     * 12600000
*                                                                     * 12800000
*                                                                     * 13000000
*********************************************************************** 13200000
         EJECT                                                          13400000
*                                                                       13600000
*        REGISTER CONVENTIONS                                           13800000
*                                                                       14000000
R0       EQU   0         WORK/PARAMETER  REGISTER                       14200000
R1       EQU   1         WORK/PARAMETER  REGISTER                       14400000
DCBREG   EQU   2         ADDR OF DCB                                    14600000
BASEREG  EQU   3         BASE REGISTER                                  14800000
RCORE    EQU   4         WORK AREA ADDRESS                              15000000
DCBLREG  EQU   5         ADDR OF DCB LIST                               15200000
DEBREG   EQU   12        ADDR OF DEB                                    15400000
RPAR     EQU   5         TOP OF PARAMETER LIST                          15600000
RWTG     EQU   6         TOP OF WTG TABLE                               15800000
RPARC    EQU   7         CURRENT PARAMETER                              16000000
RWTGC    EQU   8         CURRENT TRANS LOAD                             16200000
R9       EQU   9         WORK REG                                       16600000
R8       EQU   9         WORK REG                                       16800000
R10      EQU   10        WORK REG                                       17000000
IOBREG   EQU   11        ADDR OF IOB                                    17200000
R12      EQU   12        WORK REG                                       17400000
R13      EQU   13        WORK REG                                       17600000
R14      EQU   14        WORK REG                                       17700000
R11      EQU   15        WORK REG                                       17800000
R15      EQU   15        WORK/PARAMETER REGISTER                        18000000
*                                                                       18200000
TWO      EQU   2         VALUE OF 2                                     18400000
ECBLEN   EQU   64        LENGTH OF ECB'S                                18600000
WDBUFL   EQU   64        LENGTH OF WRITE DELAY BUFFER                   18800000
POCKETL  EQU   X'F7'     POCKET LITE COMMAND                            19000000
WD       EQU   X'E1'     WRITE DELAY COMMAND                            19200000
TIC      EQU   X'08'     TIC                                            19400000
MODRD    EQU   X'4C'     MODIFIED READ COMMAND                          19600000
MODS     EQU   X'24'     MODIFIED SENSE COMMAND                         19800000
CCPCI    EQU   X'68'     CMD CHN AND PCI FLAGS                          20000000
ONE      EQU   1         FOR GENERAL USE                                20200000
CC       EQU   X'60'     COMMAND CHAIN FLAG                             20400000
SLI      EQU   X'20'               SUPPRESS WRONG LENGTH FLAG           20600000
NOP      EQU   X'03'     NOP COMMAND                                    20800000
DELAYL   EQU   128       LENGTH OF WRITE DELAY BUFFERS                  21000000
CCWLENGS EQU   8*10+8*9  LENGTH OF CCW'S                                21200000
LENIOB   EQU   48+48                   LENGTH OF PCU AND SCU IOBS       21400000
LENTRACE EQU   136                 TRACE TABLE LENGTH            41426  21500021
MICBLEN  EQU   28        LENGTH OF MICB                                 21600000
CCUNREL  EQU   X'42'               IOB FLAGS                            22800000
DEBSUBID EQU   X'30'                     DISP TO STACKER NAME    A48612 23200000
DEBUCBAD EQU   X'20'                     DISP TO PUC UCB ADDRESS A61601 23250000
SCUIOBXT EQU   88   EXTENT NUM FOR SCU IOB                              24000000
PIOBFLG  EQU   8    DISP TO PCU IOB FLAGS                               24500000
SIOBFLG  EQU   56   DISP TO SCU IOB FLAGS                               24800000
PIOBDCB  EQU   20   DISP TO PCU IOB DCB ADDR                            25200000
SIOBDCB  EQU   68   DISP TO SCU IOB  DCB ADDR                           25600000
PIOBLEN  EQU   40        LENGTH OF IOB                                  25800000
SIOBLEN  EQU   48   LENGTH OF SCU IOB+PREFIX                            26000000
FLAGMICB EQU   8         DISP TO MICB FLAGS                             26200000
NM1MICB  EQU   20   DISP IN MICB TO ADDR OF PREVIOUS MICB               26400000
MICBM7AD EQU   16   DISP IN MICB TO N-7 MICB                            26600000
PIOBCCW  EQU   16   DISP TO PCU CCW CHAIN ADDR IN PCU IOB               26800000
PCCWAD   EQU   17   DISP TO PCU CCW CHAIN ADDR IN PCU IOB               27000000
SIOBCCW  EQU   64   DISP TO SCU CCW CHAIN ADDR IN SCU IOB               27200000
SCCWLEN  EQU   8*9       LENGTH OF SCU CCW CHAIN                        27400000
SCCWAD   EQU   65        DISP TO SCU CCW ADDR                           27600000
SUREA    EQU   72        SAVE AREA LENGTH                               27660000
COMND    EQU   0    DISP TO COMMAND IN CCW                              27720000
CHAIN    EQU   4    DISP TO COMMAND CHAIN IN CCW                        27780000
COUNT    EQU   7    DISP TO COUNT IN CCW                                27840000
CCWL     EQU   8    CCW LENGTH                                          27900000
COUNT1   EQU   6    DISP TO COUNT IN CCW                                27960000
ADDR     EQU   1    DIAP TO DATA ADDR IN CCW                            28020000
ADDRL    EQU   3    LENGTH OF ADDR IN BYTES                             28080000
XFF      EQU   X'FF'     X'FF'                                          28140000
BUFF     EQU   0         DISP TO START OF WRITE DELAY BUFFERS           28200000
IDTTR    EQU   0    DISP TO IDTTRL IN WTG RABLE                         28260000
IDTTRL   EQU   5    LENGTH IF IDTTR                                     28320000
EQ       EQU   8    BRANCH EQUAL VALUE                                  28380000
ID       EQU   0    DISP TO ID IN WTG TABLE                             28440000
IDL      EQU   2    LENGTH OF ID                                        28500000
NEQ      EQU   7    BRANCH NOT EQUAL VALUE                              28560000
X00      EQU   X'00' HEX ZERO                                           28620000
WTGID    EQU   6    DISP TO ID IN WTG TABLE                             28680000
WTGTTR   EQU   14    DISP TO TTR IN WTG                                 28740000
TTRL     EQU   3    LENGTH OF TTR                                       28800000
DCBADDR  EQU   0    DISP TO DCB ADDR IN DCB LIST                        28860000
WORKADDR EQU   4    DISP TO WORK ADDR IN WTG TABLE                      28920000
SSLEN    EQU   8    NUM CHAR IN STACKER SELECT NAME                     28980000
IOBSTRT  EQU   0    DISP TO START OF IOB'S                              29040000
ECBADR   EQU   4    DISP TO ECB ADDR IN IOB                             29100000
ECBADDR  EQU   12   DISP TO ECB ADDR IN IOB                             29160000
MICBSTRT EQU   0    DISP TO NEXT MICB ADDR IN A MICB                    29220000
CCWLOOP  EQU   3    CCW LOOP COUNTER                                    29280000
CCWSTRT  EQU   0    DISP TO START OF CCW                                29340000
WAOFF    EQU   32             OFFSET OF FIRST ENTRY IN WTG TABLE        29600000
PLOFF    EQU   4              OFFSET OF DCB ENTRIES                     29800000
WGOFF    EQU   8              OFFSET OF WTG ENTRIES                     30000000
         EJECT                                                          30200000
*                                                                       30600000
*                                                                       30800000
*                                                                       31000000
*                                                                       31200000
OPENM2   BALR  BASEREG,R0     SET BASE                                  31400000
         USING *,BASEREG                                                31600000
         USING DSECT,RCORE                                              31800000
         USING MICBENTR,R1                                              32000000
         USING IHADCB,DCBREG                                            32200000
         L     DCBREG,DCBADDR(RPARC)    LOAD DCB ADDR                   32260000
         L     RCORE,WORKADDR(RWTGC)    LOAD WORK AREA ADDR             32320000
         EJECT                                                          32400000
*********************************************************************** 32440000
*                                                                     * 32480000
*        GET CORE FOR 2 IOB'S.  THERE IS 1 IOB FOR THE PCU AND        * 32520000
*        1 IOB FOR THE SCU.  EACH IOB IS 48 BYTES LONG.               * 32560000
*        AN 8 BYTE PREFIX AND 40 BYTE BASIC SECTION.                  * 32600000
*                                                                     * 32640000
*        THERE IS 1 MICB FOR EACH BUFFER.  EACH MICB IS 28 BYTES LONG.* 32680000
*                                                                     * 32720000
         L     DEBREG,DCBDEBAD     LOAD DEB ADDR                        32800000
         MVC   DEBSUBID(SSLEN,DEBREG),DCBSSID PLACE STACKER S IN DEB    33000000
*        GET CORE FOR MICBS AND IOBS                                    33200000
         SR    R12,R12             LOAD NUM OF BUFFERS                  33400000
         IC    R12,DCBBUFNO                                             33600000
         LA    R13,MICBLEN         LOAD LENGTH OF MICB                  33800000
         MR    R12,R12             GET LENGTH OF MICBS                  34000000
         LA    R13,SUREA(R13)                                           34200000
         MVI   DCBIOBL,PIOBLEN                                          34400000
         LA    R13,LENIOB(R13)     ADD LENGTH OF PCU AND SCU IOBS       34600000
         LA    R13,LENTRACE(R13)   ADD TRACE TABLE LENGTH        41426  34700021
         BAL   R12,GETMAIN         GET CORE FOR MICBS AND IOBS          34800000
         LR    R8,R1                                                    35000000
         XC    IOBSTRT(LENIOB,R8),IOBSTRT(R8)  ZERO IOB'S               35200000
         OI    SCUIOBXT(R1),X'01'  SET EXTENT NUMBER                    35400000
         OI    PIOBFLG(R1),CCUNREL    SET COMMAND CHAIN AND UNRELATED   35600000
         OI    SIOBFLG(R1),CCUNREL      SET COMMAND CHAIN AND UNRELATED 35800000
         ST    R8,DCBIOBAD         PLACE ADDR OF IOB IN PCU DCB         36000000
         ST    R8,IOBSTRT(R1)      PLACE PREFIX ADDR IN PREFIX          36200000
         LA    R8,ECBADR(R8)       INC TO ECB ADDR                      36400000
         ST    R8,ECBADDR(R1)      PLACE ECB ADDR IN PCU IOB            36600000
         LA    R8,ECBADR(R8)       INCR PAST PREFIX                     36800000
         LR    IOBREG,R8           LOAD IOB  REG                        37200000
         ST    DCBREG,PIOBDCB(IOBREG)  PLACE DCB ADDR IN IOB            37400000
         ST    DCBREG,SIOBDCB(IOBREG)  PLACE DCB ADDR IN IOB            37600000
         LA    R8,PIOBLEN(R8)      INCR TO ADDR OF SCU IOB              37800000
         ST    R8,IOBSTRT(R8)      PLACE PREFIX ADDR IN SCU IOB PREFIX  37900000
         LA    R13,ECBADR(R8)      LOAD SCU ECB ADDR                    38000000
         ST    R13,ECBADDR(R8)     PLACE SCU ECB ADDR IN SCU IOB        38100000
         LA    R8,SUREA(R8)                                             38200000
         LA    R8,SIOBLEN(R8)      INCR TO TRACE TABLE           41426  38300021
         XC    0(LENTRACE,R8),0(R8) ZERO TRACE TABLE             41426  38400021
         LA    R8,LENTRACE(R8)     INCR TO FIRST MICB            41426  38500021
         LR    R1,R8                                                    38600000
         ST    R8,DCBIOBA              INSERT IN DCB                    38800000
         SR    R13,R13                                                  39000000
         IC    R13,DCBBUFNO        LOAD COUNTER                         39200000
         LA    R12,MICBLEN         LOAD LENGTH OF MICB                  39400000
         EX    R12,CLEARBUF        ZERO FIRST MICB                      39600000
         OI    FLAGMICB(R8),X'80'      SET BUFFER REFERENCED            39800000
         LR    R15,R13             LOAD N-6 COUNTER                     40000000
         SH    R15,NUMMIN7                                              40200000
         LA    R15,ONE(R15)                                             40400000
CLRMICB  AR    R8,R12              INCR TO NEXT MICB                    40600000
         ST    R8,MICBNEXT         PLACE ADDR  NEXT    MICB IN PRESENT  40800000
         BCTR  R15,R0              DECR N-7 CNTR                        41000000
         BCTR  R12,0     GET MACHINE LENGTH                             41200000
         BCT   R13,X                   DECREMENT LOOP COUNTER           41400000
         B     XSR                     CNTR ZERO-GET OUT                41600000
X        EQU   *                                                        41800000
         EX    R12,CLEARBUF        ZERO A MICB                          42000000
         LA    R12,ONE(R12)        RESTORE LENGTH                       42200000
         ST    R1,NM1MICB(R8)       PLACE ADDR PREVIOUS MICB IN PRESENT 42400000
         LTR   R15,R15             IS THIS THE N-7 MICB FROM START      42600000
         BNZ   SETDISEN            NO, DO NOT SET DISEN SWITCH          42800000
         OI    FLAGMICB(R8),X'40'         SET DISEN BIT IN MICB         43000000
SETDISEN AR    R1,R12              INCR N-1                             43200000
         B     CLRMICB                 LOOP TILL ALL MICB CLEARED       43400000
XSR      EQU   *                                                        43600000
         LA    R12,ONE(R12)        INCR TO MICB LENGTH                  43800000
         SR    R8,R12              GET ADDR LAST MICB                   44000000
         L     R1,DCBIOBA              GET ADDR FIRST MICB              44200000
         ST    R1,MICBSTRT(R8)     PLACE NEXT MICB ADDR IN LAST MICB    44400000
         ST    R8,MICBNM1  PLACE ADDR PREVIOUS MICB IN FIRST MICB       44600000
         EJECT                                                          44800000
*                                                                       45000000
*        PLACE ADDR OF N-7 MICB IN EACH MICB AND ZERO THE BUFFER        45200000
*                                                                       45400000
         LA    R12,MICBLEN         LOAD LENGTH OF MICB                  45600000
         LR    R13,R12                                                  45800000
         LH    R11,DCBBUFL         LOAD BUFFER LENGTH FOR EX            46000000
         BCTR  R11,0     GET MACHINE LENGTH                             46200000
         LR    R10,R8              PLACE ADDR LAST MICB IN REG          46400000
         MH    R13,NUMMIN7         CALC DISP TO 7TH MICB                46600000
         AR    R13,R1              GET ADDR OF 7TH MICB                 46800000
GETBUF   LR     R0,R1         SAVE REG 1                                47000000
         GETBUF (DCBREG),R8        GET A BUFFER                         47200000
         LTR   R8,R8               LAST BUFFER                          47400000
         BZ    BUFDONE             YES, GET OUT                         47600000
         LR    R1,R0     RESTORE REG 1                                  47800000
         EX    R11,CLEARBUF        SET BUFFER TO ZERO                   48000000
         ST    R8,MICBDATA         PLACE BUFFER ADDR IN MICB            48200000
         ST    R1,MICBM7AD(R13)    PLACE ADDR OF  MICB  7 BACK FROM     48400000
*                                  PRESENT MICB                         48600000
         AR    R1,R12              INCR TO NEXT MICB                    48800000
         AR    R13,R12             INCR TO NEXT MICB                    49000000
         CR    R13,R10             IS THIS HIGHEST MICB                 49200000
         BH    RESETR13            YES, RESET TO FIRST MICB             49400000
         B     GETBUF              NO, PROCESS NEXT MICB                49600000
RESETR13 L     R13,MICBSTRT(R10)   LOAD ADDR FIRST MICB                 49800000
         B     GETBUF              PROCESS NEXT MICB                    50000000
         EJECT                                                          50200000
*********************************************************************** 50230000
*                                                                     * 50260000
*        GET CORE FOR PCU AND SCU CCW CHAINS.                         * 50290000
*                                                                     * 50320000
*        GET CORE FOR 2 WRITE DELAY BUFFERS.                          * 50350000
*                                                                     * 50380000
*        GET CORE FOR AN ECB LIST.                                    * 50410000
*                                                                     * 50440000
*********************************************************************** 50470000
*                                                                       50500000
BUFDONE  EQU   *                                                        50530000
         LA    R13,CCWLENGS        LOAD LENGTH OF CCW                   50600000
         LA    R13,DELAYL(R13)     ADD LENGTH OF WRITE DELAY BUFFERS    50800000
         LA    R13,ECBLEN(R13)                                          51000000
         BAL   R12,GETMAIN         GET CORE FOR CCW'S                   51200000
         LA    R15,CCWLOOP         LOAD LOOP CNTR FOR PCU CCW'S         51400000
         ST    R1,PIOBCCW(IOBREG)       PLACE ADDR CCW IN IOB           51600000
         XC    CCWSTRT(CCWLENGS,R1),CCWSTRT(R1)   ZERO CCWS             51800000
         LH    R8,DCBLRECL         LOAD RECORD SIZE                     52000000
*    BUILD NOP                                                          52200000
BUILDCCW MVI   COMND(R1),NOP       SET COMMAND                          52400000
         MVI   CHAIN(R1),CC        SET COMMAND CHAIN                    52600000
         MVI   COUNT(R1),ONE       SET COUNT                            52800000
         LA    R1,CCWL(R1)         UPDATE CCW ADDR                      53000000
*       BUILD MODIFIED READ                                             53200000
         MVI   COMND(R1),MODRD     SET COMMAND                          53400000
         MVI   CHAIN(R1),CC        SET COMMAND CHAIN                    53600000
         STH   R8,COUNT1(R1)       SET CONUT                            53800000
         LA    R1,CCWL(R1)         UPDATE CCW ADDR                      54000000
*       BUILD MODIFIED SENSE                                            54200000
         MVI   COMND(R1),MODS      SET COMMAND                          54400000
         MVI   CHAIN(R1),CC        SET COMMAND CHAIN                    54600000
         MVI   COUNT(R1),TWO       SET COUNT                            54800000
         LA    R1,CCWL(R1)         UPDATE CCW ADDR                      55000000
         BCT   R15,BUILDCCW        LOOP TILL DONE                       55200000
*       BUILD TIC                                                       55400000
         MVI   COMND(R1),TIC       SET COMMAND                          55600000
         MVI   COUNT(R1),ONE       SET COUNT                            55800000
         MVC   ADDR(ADDRL,R1),PCCWAD(IOBREG)  SET DATA ADDR             56000000
         LA    R1,CCWL(R1)         UPDATE CCW ADDR                      56200000
*                                                                       56400000
*        PLACE SCU CCW ADDR IN IOB AND BUILD SCU CCW'S                  56600000
*                                                                       56800000
         LA    R13,TWO             LOOP COUNTER FOR SCU CCWS            57000000
         ST    R1,SIOBCCW(IOBREG)       PLACE SCU CCW ADDR IN SCU IOB   57200000
         LR    R15,R1                                                   57400000
         LA    R15,SCCWLEN(R15)     POINT TO FIRST WRITE DELAY BUFFER   57600000
*    BUILD MODIFIED SENSE                                               57800000
BUILDSCW MVI   COMND(R1),MODS      SET COMMAND                          58000000
         MVI   CHAIN(R1),CC        SET COMMAND CHAIN                    58200000
         MVI   COUNT(R1),ONE       SET COUNT                            58400000
         LA    R1,CCWL(R1)         UPDATE CCW ADDR                      58600000
*       BUILD WRITE DELAY COMMAND                                       58800000
         ST    R15,COMND(R1)       SET DATA ADDR                        59000000
         MVI   COMND(R1),WD        SET COMMAND                          59200000
         MVI   CHAIN(R1),CCPCI     SET COMMAND CHAIN AND PCI FLAGS      59400000
         MVI   COUNT(R1),WDBUFL    SET COUNT                            59600000
         LA    R1,CCWL(R1)         UPDATE CCW ADDR                      59800000
         LA    R15,WDBUFL(R15)     UPDATE TO SECOND WRITE DELAY BUFFER  60000000
*       BUILD NOP                                                       60200000
         MVI   COMND(R1),NOP       SET COMMAND                          60400000
         MVI   CHAIN(R1),CC        SET COMMAND CHAIN                    60600000
         MVI   COUNT(R1),ONE       SET COUNT                            60800000
         LA    R1,CCWL(R1)         UPDATE CCW ADDR                      61000000
         BCT   R13,BUILDSCW        BUILD SECOND SWT OF CCW'S            61200000
*       BUILD TIC                                                       61400000
         MVI   COMND(R1),TIC       SET COMMAND                          61600000
         MVI   COUNT(R1),ONE       SET COUNT                            61800000
         MVC   ADDR(ADDRL,R1),SCCWAD(IOBREG) SET DATA ADDR              62000000
         LA    R1,CCWL(R1)         UPDATE CCW ADDR                      62200000
*       BUILD POCKET LITE COMMAND                                       62400000
         MVI   COMND(R1),POCKETL   SET COMMAND                          62600000
         MVI   CHAIN(R1),CC        SET COMMAND CHAIN                    62800000
         MVI   COUNT(R1),ONE       SET COUNT                            63000000
         LA    R1,CCWL(R1)         UPDATE CCW ADDR                      63200000
*       BUILD STACKER SELECT COMMAND                                    63400000
         MVI   COUNT(R1),ONE       SET COUNT                            63600000
         MVI   CHAIN(R1),SLI       SET SUPPRESS WRONG LENGTH            63800000
         LA    R1,CCWL(R1)         UPDATE CCW ADDDR                     64000000
*       SET WRITE DELAY BUFFERS TO X'FF'                                64200000
         OI    BUFF(R1),XFF        SET X'FF'                            64400000
         MVC   BUFF+1(DELAYL-1,R1),BUFF(R1)  PROPAGATE FF'S             64600000
         LA    R1,DELAYL(R1)       UPDATE TO ECB'S                      64800000
         ST    R1,DCBECBLT         PLACE ADDR OF ECB LIST IN DCB        65000000
*********************************************************************** 65050021
*                                                                       65100021
* INSURE THAT THE SECONDARY CONTROL UNIT HAS THE SAME PATH MASK AS      65150021
*  THE PRIMARY CONTROL UNIT.                                            65160021
         L     DEBREG,DCBDEBAD          GET DEB ADDRESS         SA61601 65162021
         L     R10,DEBUCBAD(0,DEBREG)   GET ADDRESS OF PRI UNIT SA61601 65170021
         L     R9,DEBUCBAD+4(0,DEBREG)  GET ADDRESS OF SEC UNIT SA61601 65180021
         MVN   UCBWGT-UCBOB(ONE,R9),UCBWGT-UCBOB(R10) COPY PATH SA61601 65190021
*                                                                       65200021
*                                                                       65400021
*********************************************************************** 65450021
         MVC   IDTTR(IDTTRL,RWTGC),SOP7D SET ID FOR NEXT LOAD USED BY   65600000
*                                  THIS DCB.  IDTTR GOES TO BYTES       65800000
*                                  0-5 OF 8 BYTE FIELD IN WTG TABLE     66000000
*                                                                       66200000
*                                                                       66400000
RELOOP   EQU   *                                                        66600000
         LA    RWTGC,WGOFF(0,RWTGC) INCR CURRENT WTG ENTRY              66800000
         LA    RPARC,PLOFF(0,RPARC) INCR CURRENT DCB ENTRY              67000000
         CLC   ID(IDL,RWTGC),AMIDCNST  IS THIS RTN NEEDED AGAIN         67200000
         BCR   EQ,BASEREG     YES, BRANCH                               67400000
*                                                                       67600000
*                                                                       67800000
*                                                                       68000000
         CLC   ID(IDL,RWTGC),OPIDCNST    END OF TABLE                   68200000
         BC    NEQ,RELOOP     NO, BRANCH                                68400000
*                                                                       68600000
*                                                                       68800000
         LR    RPARC,RPAR          REINITIALIZE DCB LIST PTR            69000000
         LA    RWTGC,WAOFF(0,RWTG) REINITIALIZE WTG LIST PTR            69200000
*                                                                       69400000
*                                                                       69600000
RELOOP1  EQU   *                                                        69800000
         CLI   ID(RWTGC),X00       IS THIS ENTRY COMPLETE               70000000
         BC    NEQ,XCTLRTN         NO, BRANCH                           70200000
*                                                                       70400000
*                                                                       70600000
         LA    RWTGC,WGOFF(0,RWTGC) GET NEXT WTG ENTRY                  70800000
         LA    RPARC,PLOFF(0,RPARC) GET NEXT DCB ENTRY                  71000000
         B     RELOOP1              BR TO CHK NEXT ENTRY                71200000
*                                                                       71400000
*                                                                       71600000
XCTLRTN  EQU   *                                                        71800000
         MVC   WTGID(IDL,RWTG),ID(RWTGC)     STORE ID IN WTG TABLE      72000000
         MVC   WTGTTR(TTRL,RWTG),IDL(RWTGC)  STORE TTR IN WTG TABLE     72200000
         LA    R15,DXCCW12         SET UP FOR XCTL                      72400000
*                                                                       72600000
*                                                                       72800000
         XCTL  DE=(RWTG),SF=(E,(15)) TRANSFER CONTROL TO NEXT EXECUTOR  73000000
*                                                                       73200000
*                                                                       73400000
         EJECT                                                          73600000
         DS    0H                                                       73800000
NUMMIN7  DC    AL2(7)    CONSTANT OF 7                                  74000000
IOBPREFX DC    AL2(8)    LENGTH OF IOB PREFIX                           74200000
CLEARBUF XC    0(0,R8),0(R8)       CLEAR BUFFER TO ZERO                 74400000
OPIDCNST DC    C'0S'     END OF TABLE ID                                74600000
AMIDCNST DC    C'7C'          CURRENT MODULE ID                         74800000
*                                                                       75000000
*        GETMAIN SUBROUTINE                                             75200000
*                                                                       75400000
GETMAIN  GETMAIN R,LV=(R13),SP=250 GET REQUESTED AMOUNT OF CORE         75600000
         BR    R12                 RETURN TO CALLER                     75800000
*                                                                       76000000
*                                                                       76200000
*                                                                       76400000
*                                                                       76600000
         ORG   IGG0197C+1008                                            76800000
SOP7D    DC    C'7D    '      IDTTRL                                    77000000
         DC    H'0'           END OF TABLE                              77200000
         DC    2H'0'          FILLER                                    77400000
         DC    C'019'         OPEN SVC CODE                             77600000
         DC    AL1(126)       DBL WRDS TO XCTL TABLE                    77800000
*        MICBD - DUMMY SECTION FOR THE MICB                             77830000
MICBENTR DSECT                                                          77860000
MICBNEXT DS    A                                                        77890000
MICBECB  DS    A                                                        77920000
MICBFLAG DS    AL1                                                      77950000
MICBSENS DS    AL3                                                      77980000
MICBECBA DS    A                                                        78010000
MICBNM7  DS    A                                                        78040000
MICBNM1  DS    A                                                        78070000
MICBDATA DS    A                                                        78100000
DSECT    DSECT                                                          78200000
         IECDSECT                                                       78400000
*                                                                       78600000
*                                                                       78800000
*                                                                       79000000
DCB      DCBD  DSORG=BS,DEVD=MR                                         79200000
*                                                                       79400000
*                                                                       79600000
*                                                                       79800000
UCB      DSECT                                                          80000000
         IEFUCBOB                                                       80200000
*                                                                       80400000
CVT      DSECT                                                          80600000
         CVT                                                            80800000
*                                                                       81000000
         END                                                            81200000
