         TITLE 'IGG0197D  LOAD MICR MODULES'                            01000000
IGG0197D CSECT                                                          02000000
*          RELEASE 22 DELETIONS                                         02600021
*          RELEASE 21 DELETIONS                                         03200021
*0000274000,380000                                              A41426  03500021
*0000250000,706000                                              A48612  03550021
*********************************************************************** 03800000
*                                                                     * 04000000
*FUNCTION/OPERATION-  THIS ROUTINE SUPPLEMENTS THE INITIAL OPEN       * 04200000
*      ROUTINE BY PERFORMING SPECIFIC FUNCTIONS FOR THE MAGNETIC      * 04400000
*      INK CHARACTER READER.                                          * 04600000
*      THIS ROUTINE WILL LOAD ALL NECESSARY I/O MODULES.              * 04800000
*      IT WILL PLACE THE ADDRESS OF THE LOADED MODULES IN THE         * 05000000
*      APPROPRIATE DCB FIELDS AND THE MODULE ID'S IN THE DEB.         * 05200000
*      THE USER CODED STACKER SELECT ROUTINE IS LOADED FROM ONE       * 05400000
*      OF THESE LIBRARIES; SVCLIB, JOBLIB, LINKLIB, OR STEPLIB.       * 05600000
*      IF THE STACKER SELECT ROUTINE IS LOCATED IN THE SVCLIB THEN    * 05800000
*      THE ROUTINE IS CONSIDERED TO BE OPERATING IN THE PRODUCTION    * 06000000
*      MODE AND THE STACKER SELECT ROUTINE IS LINKED TO DIRECTLY.     * 06200000
*      IF THE STACKER SELECT ROUTINE IS LOCATED IN THE JOB, LINK,     * 06400000
*      OR STEP LIBRARY, THE ROUTINE IS CONSIDERED TO BE OPERATING     * 06600000
*      IN THE DEBUG MODE AND IT IS SCHEDULED AS AN ASYNCHRONOUS       * 06800000
*      EXIT ROUTINE BY THE PCI APPENDAGE.                             * 07000000
*      THIS ROUTINE WILL ALSO LOAD THE APPENDAGES REQUIRED TO         * 07200000
*      PROCESS THE MICR DEVICES AND PLACE THEIR ADDRESSES IN          * 07400000
*      THE DEB.                                                       * 07600000
*      IF THE DD STATEMENT CONTAINED A VOLUME NUMBER A MESSAGE WILL   * 07800000
*      BE PUT OUT INSTRUCTING THE OPERATOR TO MOUNT THE               * 08000000
*      REQUIRED VOLUME ON THE SPECIFIED MICR DEVICE.                  * 08200000
*                                                                     * 08400000
*                                                                     * 08600000
*ENTRY POINT-  THIS ROUTINE IS ENTERED AT THE CSECT  IGG0197D         * 08800000
*        VIA XCTL FROM IGG0197C.                                      * 09000000
*                                                                     * 09200000
*                                                                     * 09400000
*INPUT-  THE INPUT CONSISTS OF A PARAMETER LIST CONTAINING ADDRESSES  * 09600000
*      OF DCB'S TO BE OPENED.  IN ADDITION,  SEVERAL REGISTERS        * 09800000
*      CONTAIN ADDRESSES OF SEVERAL CONTROL BLOCKS  .                 * 10000000
*                                                                     * 10200000
*                                                                     * 10400000
*OUTPUT-  OUTPUT IS AS FOLLOWS:                                       * 10600000
*                                                                     * 10800000
*      1. UPDATED IOB'S, DEB'S                                        * 11000000
*                                                                     * 11200000
*      2. ALL REQUIRED I/O MODULES FOR MICR PROCESSING                * 11400000
*                                                                     * 11600000
*      3. USER'S STACKER SELECT ROUTINE                               * 11800000
*                                                                     * 12000000
*      4. AN IRB AND ONE IQE IF STACKER SELECT ROUTINE IS LOCATED     * 12200000
*         IN THE JOB, LINK, OR STEP LIBRARY.                          * 12400000
*                                                                     * 12600000
*      5. A MOUNT MESSAGE IF A VOLUME WAS SPECIFIED ON JCL CARD       * 12800000
*                                                                     * 13000000
*                                                                     * 13200000
*EXTERNAL ROUTINES-  NONE                                             * 13400000
*                                                                     * 13600000
*                                                                     * 13800000
*EXITS -  NORMAL    TO NEXT OPEN EXECUTOR VIA THE WTG TABLE           * 14000000
*                                                                     * 14200000
*         ERROR     N/A                                                 14400000
*                                                                     * 14600000
*                                                                     * 14800000
*TABLES/WORK AREAS-  NONE                                             * 15000000
*                                                                     * 15200000
*                                                                     * 15400000
*ATTRIBUTES-   REENTRANT, REUSABLE                                    * 15600000
*                                                                     * 15800000
*                                                                     * 16000000
*                                                                     * 16200000
*                                                                     * 16400000
*********************************************************************** 16600000
         EJECT                                                          16800000
*                                                                       17000000
*              REGISTER CONVENTIONS                                     17200000
*                                                                       17400000
R0       EQU   0         WORK/PARAMETER REG                             17600000
R1       EQU   1         WORK/PARAMETER REG                             17800000
DCBREG   EQU   2                   ADDRESS OF DCB                       18000000
RDCB     EQU   2         DCB REG                                        18200000
RBASE    EQU   3         BASE REG                                       18400000
RCORE    EQU   4         WORK AREA REG                                  18600000
RPAR     EQU   5         TOP OF PARAMETER LIST                          18800000
RWTG     EQU   6         TOP OF WTG TABLE                               19000000
RPARC    EQU   7         CURRENT PARAMETER                              19200000
RWTGC    EQU   8         CURRENT TRANS LOAD                             19400000
RTIOT    EQU   9         WORK REG AND CVT REG                           19600000
RUCB     EQU   10        UCB REG                                        19800000
RDEB     EQU   11        WORK REG                                       20000000
RB       EQU   12        WORK REG                                       20200000
RC       EQU   13        WORK REG                                       20400000
RD       EQU   14        WORK REG                                       20600000
RJ       EQU   15        WORK REG                                       20800000
DEBREG   EQU   RDEB                                                     21000000
R12      EQU   12                  WORK REG                             21200000
R13      EQU   13                  WORK REG                             21400000
R15      EQU   15                  WORK REG                             21600000
RIOB     EQU   12        IOB ADDR                                       22000000
IOBREG   EQU   12        IOB ADDR                                       22200000
UCBREG   EQU   10        UCB ADDR                                       22400000
TCBREG   EQU   15        TCB ADDR                                       22600000
BASEREG  EQU   3         MODULE ADDR                                    22800000
IDDEB    EQU   56                  DISP TO SUBRTN ID'S                  23000000
UNIT     EQU   14        DISP TO UNIT IN WTO MESSAGE                    23400000
IQELINK  EQU   X'64'     DISP TO IQE LINK ADDR                          23800000
DEBNMSUB EQU   0                   DISP TO NUM SUBRTN'S LOADED          24400000
DEBIRBAD EQU   9                   DISP TO IRB ADDR                     24600000
DEBAPPAD EQU   28                  DISP TO APPENDAGE VECTOR TABLE       24800000
DEBSUBID EQU   X'30'                     DISP TO STACKER NAME    A48612 25000021
LBLDL    EQU   64                  LENGTH OF BLDL LIST                  25200000
DEBUCBAD EQU   32                  DISP TO UCB ADDR                     25600000
SIOADDR  EQU   4             DISP TO START I/O ADDR IN THE AVT   41426  25700021
PCIADDR  EQU   8    DISP TO PCI ADDR IN APPENDAGE VECTOR TABLE          25900000
ENTRYDSP EQU   4    LENGTH OF APPENDAGE BRANCH TABLE ENTRIES            26200000
CEADDR   EQU   12   DISP TO CHAN END ADDR IN APPEND VECTOR TABLE        26500000
ABENDAD  EQU   16        DISP TO ABNORMAL END ADDR IN DEB               26800000
EOEADDR  EQU   0         DISP TO END-OF-EXTENT ADDR IN DEB              27100000
APPADDR  EQU   4         DISP TO APPENDAGES IN IOB                      27700000
DEBIRBA  EQU   109       DISP TO IRB ADDR IN DEB                        28000000
IQETCBAD EQU   112       DISP TO TCB ADDR IN IQE                        28300000
IQEDCBAD EQU   104       DISP TO DCB ADDR IN IQE                        28600000
SUBID    EQU   0         DISP TO ID IN WTG TABLE                        29000000
IQEIRBAD EQU   108       DISP TO IRB ADDR IN IQE                        29040000
ONE      EQU   1         FOR GENERAL USE                                29080000
VOLID    EQU   18        DISP TO VOLUME ID IN WTO MESSAGE               29120000
WTOSIZE  EQU   X'18'     LENGTH OF WTO MESSAGE                          29160000
BLANK    EQU   X'40'     EBCDIC BLANK                                   29200000
BYTECONV EQU   3    CONVERSION FACTOR DWORD TO BYTES                    29240000
DCBADDR  EQU   0    DISP TO DCB ADDR IN DCB LIST                        29280000
WORKADDR EQU   4    DISP TO WORK AREA ADDR IN WTG TABLE                 29320000
CURRID   EQU   0    DISP TO CURRENT ID IN WTG TABLE                     29360000
X00      EQU   X'00'     HEX ZERO                                       29400000
EPADDR   EQU   24   DISP TO ENTRY POINT ADDR IN WTG TABLE               29440000
ADDRL    EQU   3    LENGTH OF ADDR IN BYTES                             29480000
EPADDRP1 EQU   25   DISP TO ENTRY POINT ADDR IN WTG TABLE               29520000
NEBLDL   EQU   0    DISP TO NUM ENTRIES IN A BLDL LIST                  29560000
BLDLL    EQU   58   LENGTH OF BLDL ENTRY                                29600000
ELBLDL   EQU   2    DISP TO BLDL LIST ENTRY LENGTH                      29640000
NBLDL    EQU   4    DISP TO BLDL LIST MODULE NAME                       29680000
MLENGTH  EQU   8    LENGTH OF MODULE NAME                               29720000
MODDISP  EQU   0    DISP TO MODULE NAME                                 29760000
ASYEXADR EQU   4    DISP TO ASYNCH EXIT ADDR IN IOB                     29800000
WTODISP  EQU   0    DISP TO WTO MESSAGE                                 29840000
UNITL    EQU   3    LENGTH OF UNIT IN WTO MESSAGE                       29880000
VOLL     EQU   6    LENGTH OF VOLID IN WTO MESSAGE                      29920000
IDL      EQU   2    LENGTH OF ID IN WTG TABLE                           29960000
WTGID    EQU   6    DISP TO ID IN WTG TABLE                             30000000
WTGL     EQU   5    WTG LENGTH                                          30040000
WTGTTR   EQU   14    DISP TO TTR IN WTG TABLE                           30080000
TTRL     EQU   3    LENGTH OF TTR                                       30120000
MODLEN   EQU   5    DISP INTO BLDL LIST TO MODULE LENGTH                30160000
EPADDRP3 EQU   27    DISP TO TEXT IN WTG TABLE                          30200000
DEBTCBAD EQU   0         DISP TO TCB ADDR IN DEB                        30400000
WAOFF    EQU   32             OFFSET OF FIRST ENTRY IN WTG TABLE        30600000
PLOFF    EQU   4              OFFSET OF DCB ENTRIES                     30800000
WGOFF    EQU   8              OFFSET OF WTG ENTRIES                     31000000
XBF      EQU   X'BF'     MASK TO SET DEVICE READY IN UCB                31050000
DEBBINUM EQU   X'24'     DISP TO SCU UCB ADDR IN DEB                    31100000
DELWTO   EQU   X'02'          INDICATE A WTO WAS ISSUED                 31150000
         EJECT                                                          31200000
*                                                                       31400000
*        LOAD REGS WITH CONTROL BLOCK ADDRESSES                         31600000
*                                                                       31800000
*                                                                       32200000
         BALR  RBASE,0                                                  32400000
         USING *,RBASE                                                  32600000
         USING IHADCB,RDCB                                              32800000
         USING DSECT,RCORE                                              33000000
         USING CVT,RTIOT                                                33200000
         USING UCB,RUCB                                                 33400000
         L     RDCB,DCBADDR(RPARC)      GET DCB ADDR                    33600000
         L     RDEB,DCBDEBAD       GET DEB ADDR                         33800000
         L     RTIOT,CVTPTR(0,0)   LOAD CVT ADDR                        34000000
         L     RCORE,WORKADDR(RWTGC)    GET WORK AREA ADDR              34200000
*                                                                       34400000
         MVI   CURRID(RWTGC),X00        ZERO CURRENT ID ENTRY           34600000
*                                                                       34630000
         L     RUCB,DEBUCBAD(DEBREG)  LOAD PCU UCB ADDR                 34660000
         NI    UCBFL2,XBF               SET UCB TO DEVICE READY         34690000
         L     RUCB,DEBBINUM(DEBREG)    LOAD SCU UCB ADDR               34720000
         NI    UCBFL2,XBF               SET UCB TO DEVICE READY         34750000
*                                                                       34800000
*                                                                       34860000
*        LOAD THE APPENDAGES FOR MICR SUPPORT                           34920000
*                                                                       34980000
         LA    RB,IGG019V5                                              35040000
         L     RJ,CVTSVDCB         LOAD ADDR SVCLIB DCB                 35100000
         LOAD  EPLOC=(RB),DCB=(RJ)      LOAD APPENDAGES                 35160000
         LA    RB,APPENDID         LOAD ADDR OF APPENDAGE ID            35220000
         BAL   RC,ADDV5       INCLUDE APPENDAGE ID IN DEB               35280000
*                                                                       35400000
         L     R1,EPADDR(RWTG)     LOAD ADDR OF APPENDAGES              35600000
         L     RC,DEBAPPAD(RDEB)   LOAD ADDR OF APPENDAGE VECTOR TABLE  35800000
         ST    R1,CEADDR(RC)       PLACE CHANNEL END ENTRY ADDR         36000000
         LA    R1,ENTRYDSP(R1)                                          36200000
         ST    R1,ABENDAD(RC)      PLACE ABEND ENTRY ADDR               36400000
         LA    R1,ENTRYDSP(R1)                                          36600000
         L     RIOB,DCBIOBAD       GET IOB ADDR                         36800000
         ST    R1,APPADDR(IOBREG)  PLACE APPEND ENTRY ADDR              37000000
         LA    R1,ENTRYDSP(R1)     INCREMENT POINTER             41426  37060021
         ST    R1,SIOADDR(RC)      PLACE START I/O ENTRY IN AVT  41426  37120021
         LA    R1,ENTRYDSP(R1)                                          37200000
         ST    R1,PCIADDR(RC)      PLACE PCI ENTRY ADDR                 37400000
         LA    R1,CVTBRET                                               37600000
         ST    R1,EOEADDR(RC)      PLACE DUMMY E-O-E ADDR               37800000
         LA    RB,READID           POINT TO READ ID                     38200000
         BAL   RC,LOADMOD          LOAD READ                            38400000
*                                                                       38600000
         MVC   DCBREAD+1(ADDRL),EPADDRP1(RWTG) PLACE ADDR IN DCB        38800000
*                                                                       39000000
*                                                                       39200000
         LA    RB,EOBID            POINT TO EOB ID                      39400000
         BAL   RC,LOADMOD          LOAD EOB                             39600000
*                                                                       39800000
         MVC   DCBEOBR+1(ADDRL),EPADDRP1(RWTG) PLACE ADDR IN DCB        40000000
*                                                                       40200000
*                                                                       40400000
         LA    RB,CHECKID          POINT TO CHECK ID                    40600000
         BAL   RC,LOADMOD          LOAD CHECK                           40800000
*                                                                       41000000
         MVC   DCBCHECK+1(ADDRL),EPADDRP1(RWTG) PLACE ADDR IN DCB       41200000
*                                                                       41400000
*                                                                       41600000
         LA    RB,CNTRLID          POINT TO CONTROL ID                  41800000
         BAL   RC,LOADMOD          LOAD CONTROL                         42000000
*                                                                       42200000
         MVC   DCBCNTRL+1(3),25(RWTG) PLACE ADDR IN DCB                 42400000
*                                                                       42600000
*                                                                       42800000
         LA    RC,LBLDL       LOAD LENGTH OF LIST                       43000000
         BAL   RB,GETMAIN     GET CORE                                  43200000
         LR    RD,R1          SAVE REG                                  43400000
         LA    R12,DEBSUBID(DEBREG)  LOAD ADDR OF STACKER NAME          43600000
*                                                                       43800000
         LA    R13,ONE        LOAD NUM ENTRIES                          44000000
         STH   R13,NEBLDL(RD)      PLACE IN BLDL LIST                   44200000
         LA    R13,BLDLL           LOAD LENGTH OF ENTRY                 44400000
         STH   R13,ELBLDL(RD)      PLACE IN BLDL LIST                   44600000
         MVC   NBLDL(MLENGTH,RD),MODDISP(R12) PLACE MODULE NAME IN LIST 44800000
         L     R12,CVTSVDCB   LOAD ADDR SVCLIB DCB                      45000000
         BLDL  (R12),(RD)     BUILD LIST                                45200000
         LA    R12,DEBSUBID(DEBREG) GET ADDR OF STACKER NAME            45400000
         LTR   R15,R15                                                  45600000
         BNZ   SCHEDULE            INDICATE SS ROUTINE TO BE SCHEDULED  45800000
         L     RJ,CVTSVDCB         LOAD ADDR SVCLIB DCB                 46000000
         LOAD  EPLOC=(R12),DCB=(RJ) LOAD STACKER ROUTINE FROM SVCLIB    46200000
LOADED   ST    R0,DCBSSAD          PLACE ENTRY POINT IN DCB             46400000
         FREEMAIN R,LV=LBLDL,A=(RD),SP=250   FREE CORE                  46600000
         TM    DCBMRFLG,X'40'      SS TO BE SCHEDULED ?                 46800000
         BZ    RDJFCB              DO NOT BUILD IRB AND IQE'S           47000000
*                                                                       47200000
*        BUILD AN IRB AND    IQE                                        47400000
*                                                                       47600000
         L     RIOB,DCBIOBAD  LOAD IOB ADDR                             47800000
         L     R0,ASYEXADR(IOBREG) LOAD ASYNCH EXIT ADDR                48000000
*        CIRB  EP=(R0),KEY=PP,MODE=PP,STAB=RE,SVAREA=NO,WKAREA=3        48200000
         L     R1,CIRBPARM         LOAD CIRB PARAMETERS                 48400000
         SVC   43                  CREATE IRB AND IQE                   48600000
         ST    R1,IQEIRBAD(R1)          PLACE IRB ADDR IN IQE           48800000
         MVC   DEBIRBAD(3,DEBREG),DEBIRBA(R1) PLACE IRB ADDR IN DEB     49000000
         L     TCBREG,DEBTCBAD(DEBREG)  LOAD TCB ADDR                   49200000
         LA    TCBREG,0(TCBREG)    CLEAR HI ORDER BYTE                  49300000
         ST    TCBREG,IQETCBAD(R1)      PLACE TCB ADDR IN IQE           49400000
         ST    DCBREG,IQEDCBAD(R1)      PLACE DCB ADDR IN IQE           49600000
RDJFCB   EQU   *                                                        49800000
         CLI   JFCBVOLS,BLANK      IS VOLID SPECIFIED                   50000000
         BE    RELOOP              NO,BRANCH                            50200000
*                                                                       50400000
         LA    RC,WTOSIZE                                               50600000
         BAL   RB,GETMAIN          GET CORE FOR MOUNT MESSAGE           50800000
*                                                                       51000000
         MVC   WTODISP(WTOSIZE,R1),WTO  BUILD MESSAGE                   51200000
*                                                                       51400000
         L     UCBREG,DEBUCBAD(DEBREG)  LOAD ADDR OF UCB                51600000
         MVC   UNIT(UNITL,R1),UCBNAME   PLACE UNIT IN MESSAGE           51800000
         MVC   VOLID(VOLL,R1),JFCBVOLS  PLACE VOLID IN MESSAGE          52000000
         LR    RUCB,R1               SAVE REG                           52200000
         WTO   MF=(E,(R1))         ISSUE MESSAGE                        52400000
*                                                                       52600000
*                                                                       52800000
         OI    DCBMRFLG,DELWTO     INDICATE WTO WAS ISSUED              53000000
         ST    R1,DCBWTOID         PLACE MESSAGE ID                     53200000
         LR    R1,RUCB             RESTORE REG                          53400000
*                                                                       53600000
*                                                                       53800000
         FREEMAIN R,LV=WTOSIZE,A=(R1),SP=250   FREE CORE                54000000
*                                                                       54200000
*                                                                       54400000
*                                                                       54600000
*                                                                       54800000
*                                                                       55000000
*                                                                       55200000
*                                                                       55400000
RELOOP   EQU   *                                                        55600000
         LA    RWTGC,WGOFF(0,RWTGC) INCR CURRENT WTG ENTRY              55800000
         LA    RPARC,PLOFF(0,RPARC) INCR CURRENT DCB ENTRY              56000000
         CLC   CURRID(IDL,RWTGC),AMIDCNST THIS RTN NEEDED AGAIN         56200000
         BCR   8,BASEREG            YES, BRANCH                         56400000
*                                                                       56600000
*                                                                       56800000
*                                                                       57000000
         CLC   CURRID(IDL,RWTGC),OPIDCNST END OF TABLE                  57200000
         BC    7,RELOOP             NO, BRANCH                          57400000
*                                                                       57600000
*                                                                       57800000
         LR    RPARC,RPAR          REINITIALIZE DCB LIST PTR            58000000
         LA    RWTGC,WAOFF(0,RWTG) REINITIALIZE WTG LIST PTR            58200000
*                                                                       58400000
*                                                                       58600000
RELOOP1  EQU   *                                                        58800000
         CLI   CURRID(RWTGC),X00   IS THIS ENTRY COMPLETE               59000000
         BC    7,XCTLRTN           NO, BRANCH                           59200000
*                                                                       59400000
*                                                                       59600000
         LA    RWTGC,WGOFF(0,RWTGC) GET NEXT WTG ENTRY                  59800000
         LA    RPARC,PLOFF(0,RPARC) GET NEXT DCB ENTRY                  60000000
         B     RELOOP1              BR TO CHK NEXT ENTRY                60200000
*                                                                       60400000
*                                                                       60600000
XCTLRTN  EQU   *                                                        60800000
         MVC   WTGID(IDL,RWTG),CURRID(RWTGC) STORE ID IN WTG TABLE      60900000
         MVC   WTGTTR(TTRL,RWTG),ELBLDL(RWTGC) PLACE TTR IN WTG TABLE   61000000
         MVC   EPADDR(WTGL,RWTG),XCTLCON     RESET WTG LENGTH           61100000
         LA    R15,DXCCW12         SET UP FOR XCTL                      61400000
*                                                                       61600000
*                                                                       61800000
         XCTL  DE=(RWTG),SF=(E,(15)) TRANSFER CONTROL TO NEXT EXECUTOR  62000000
*                                                                       62200000
*                                                                       62400000
SCHEDULE OI    DCBMRFLG,X'40'      INDICATE SS TO BE SCHEDULED          62600000
         LOAD  EPLOC=(R12)         LOAD STACKER ROUTINE FROM LINK LIB   62800000
         B     LOADED              CONTINUE PROCESSING                  63000000
GETMAIN  GETMAIN R,LV=(R13),SP=250 GET REQUESTED AMOUNT OF CORE         63200000
         BR    R12                 RETURN TO CALLER                     63400000
         EJECT                                                          63600000
         DS    0F                                                       63800000
CIRBPARM DC    B'01000110'    CIRB PARAMETERS                           64000000
         DC    B'00010000'    CIRB PARAMETERS                           64200000
         DC    AL2(3)         CIRB PARAMETERS                           64400000
WTO      WTO   'IEC001A M UNT,VOLUME',MF=L                              64600000
AMIDCNST DC    C'7D'     CURRENT MODULE ID                              64800000
OPIDCNST DC    C'0S'     END OF TABLE ID                                64880000
XCTLCON  DC    X'0004000400'       WTG TABLE LENGTH                     64960000
         DS    0H                                                       65040000
IGG019V5 DC    C'IGG019V5'                                              65120000
         EJECT                                                          65200000
*                                                                       65400000
*                                                                       65600000
*                                                                       65800000
*                                                                       66000000
*                                                                       66200000
         DS    0H                                                       66300000
LOADMOD  EQU   *                                                        66400000
*                                                                       66600000
         MVC   WTGTTR(TTRL,RWTG),ELBLDL(RB)  PLACE TTR IN WTG TABLE     66800000
         MVC   WTGID(IDL,RWTG),CURRID(RB)    PLACE ID IN WTG TABLE      67000000
         SR    R1,R1     CLEAR REG                                      67200000
         IC    R1,MODLEN(RB)       LOAD MODULE LENGTH                   67400000
         SLL   R1,BYTECONV    GET LENGTH IN BYTES                       67600000
         ST    R1,EPADDR(RWTG)     PLACE LENGTH IN WTG TABLE            67800000
         MVC   EPADDR(TTRL,RWTG),EPADDRP1(RWTG) PLACE TOTAL LENGTH      68000000
         MVC   EPADDRP3(IDL,RWTG),EPADDRP1(RWTG)  PLACE TEXT            68200000
         L     R1,CVTSVDCB              GET SVC LIB DCB ADDR            68600000
*                                                                       68800000
*                                                                       69000000
         LOAD  DE=(RWTG),DCB=(R1)       LOAD MODULE                     69200000
*                                                                       69400000
*                                                                       69600000
ADDV5    EQU   *         ENTER HERE TO INCLUDE IGG019V5 ID IN DEB       69660000
         ST    R0,EPADDR(RWTG)     SAVE LOAD ADDR                       69720000
*                                                                       69800000
         SR    RJ,RJ                                                    70000000
         IC    RJ,DEBNMSUB(DEBREG)      GET NUM SUBROUTINES             70200000
         LR    RD,RJ                    GET NUM SUBROUTINES             70400000
         SLL   RD,1                     GET DISP TO ID IN DEB           70800000
         AR    RD,DEBREG                                                71000000
         MVC   IDDEB(IDL,RD),SUBID(RB)  PLACE ID IN DEB                 71200000
         LA    RJ,ONE(RJ)    INCR NUM SUBROUTINES                       71400000
         STC   RJ,DEBNMSUB(DEBREG)      PLACE NEW NUM SUBRTNS           71600000
         BR    RC                       RETURN                          71800000
*                                                                       72000000
*                                                                       72200000
*                                                                       72400000
*                                                                       72600000
*                                                                       72800000
         ORG   IGG0197D+984                                             73000000
*                                                                       73200000
*                                                                       73400000
APPENDID DC    C'V5    '      IDTTRL                                    73600000
READID   DC    C'V1    '      IDTTRL                                    73800000
EOBID    DC    C'V2    '      IDTTRL                                    74000000
CHECKID  DC    C'V3    '      IDTTRL                                    74200000
CNTRLID  DC    C'V4    '      IDTTRL                                    74400000
         DC    H'0'           END OF TABLE                              74600000
         DC   2H'0'           FILLER                                    74800000
         DC    C'019'         OPEN SVC                                  75000000
         DC    AL1(123)       DBL WORDS TO START OF TABLE               75200000
*                                                                       75400000
*                                                                       75600000
*                                                                       75800000
CVT      DSECT                                                          76000000
         CVT                                                            76200000
UCB      DSECT                                                          76400000
         IEFUCBOB                                                       76600000
DCB      DCBD  DSORG=BS,DEVD=MR                                         76800000
DSECT    DSECT                                                          77000000
         IECDSECT                                                       77200000
         END                                                            77400000
