         TITLE 'IGG0197L-TRANSLATES OMR OR RCE FORMAT CD--3505/3525'    00100000
         START                                                          00200000
IGG0197L CSECT                                                          00400000
*********************************************************************** 00402000
*        RELEASE 21 DELETIONS                                           00404000
*                                                                       00406000
*        RELEASE 22 DELETIONS                                           00408000
*                                                                       00410000
*STATUS CHANGE LEVEL 000                                                00412000
*                                                                       00414000
*FUNCTION/OPERATION--THIS ROUTINE IS ENTERED FOR SAM USERS DURING       00416000
*                    OPEN WHEN:                                         00418000
*                             -OMR OR RCE IS SPECIFIED FOR 3505 CARD    00420000
*                             READER.                                   00422000
*                             RCE IS SPECIFIED FOR A 3525 CARD          00424000
*                             PUNCH'S READ ONLY FILE.                   00426000
*                    IT TRANSLATES THE FORMAT CARD AND ISSUES AN        00428000
*                    OMR OR RCE COMMAND TO THE DEVICE TO PUT IT IN      00430000
*                    THE PROPER (OMR OR RCE) MODE.                      00432000
*                                                                       00434000
*ENTRY POINT--       ENTERED FROM IGG0196B BY USE OF THE XCTL MACRO     00436000
*                                                                       00438000
*INPUT--             SEE DESCRIPTION OF REGISTERS                       00440000
*                                                                       00442000
*OUTPUT--            SEE DESCRIPTION OF REGISTERS                       00444000
*                                                                       00446000
*EXTERNAL ROUTINES-- NONE                                               00448000
*                                                                       00450000
*EXITS NORMAL--      XCTL TO IGG0197M TO CONTINUE PROCESSING            00453000
*                                                                       00456000
*EXITS ERROR--       XCTL TO IGG0197M IF FORMAT CARD IS INVALID OR      00458000
*                    IF OMR HAS BEEN SPECIFIED FOR 3525 CARD PUNCH      00460000
*                                                                       00462000
*TABLES/WORKAREAS--  WHERE-TO-GO TABLE                                  00464000
*                    BYTES  0- 7   NAME                                 00466000
*                    BYTES  8-10   RELATIVE DISK ADDRESS(TTR) OF        00468000
*                                  FIRST RECORD                         00470000
*                    BYTE     11   CONCATENATION NUMBER                 00472000
*                    BYTE     12   ZEROES                               00474000
*                    BYTE     13   ALIAS INDICATOR AND USER DATA        00476000
*                                  FIELD DESCRIPTOR:                    00478000
*                                      -ALIAS INDICATOR-- 1 BIT         00480000
*                                      -NUMBER OF TTRS IN USERS         00482000
*                                      DATA FIELD-- 2 BITS              00484000
*                    BYTES 14-16   TTR OF FIRST TEXT RECORD             00486000
*                    BYTE     17   ZEROES                               00488000
*                    BYTES 18-19   TTR OF NOTE LIST OR SCATTER LIST     00490000
*                    BYTE     20   TRANSLATION TABLE                    00492000
*                    BYTE     21   ZEROES OR NUMBER OF ENTRIES IN       00494000
*                                  THE NOTE LIST                        00496000
*                    BYTES 22-23   ATTRIBUTES                           00498000
*                    BYTES 24-26   TOTAL CONTIGUOUS MAIN STORAGE        00500000
*                                  REQUIRED FOR MODULE                  00502000
*                    BYTES 27-28   LENGTH OF FIRST TEXT RECORD          00504000
*                    BYTE     29   LENGTH OF WTG TABLE(IN DOUBLE        00506000
*                                  WORDS)                               00508000
*                    BYTES 30-31   PATH THROUGH LOADS OF ROUTINES       00510000
*                    BYTES 32-34   IDTTR OF EXECUTOR FOR FIRST DCB      00512000
*                    BYTE     35   ADDRESS OF STORAGE FOR DCB           00514000
*                    BYTES 36-39   TABLE OF IDTTR'S                     00516000
*                    BYTE  32+N(8)--                                    00518000
*                            IDTTR OF EXECUTOR FOR NTH DCB (3 BYTES)    00520000
*                            ADDRESS OF STORAGE FOR DCB    (1 BYTE )    00522000
*                            IDTTR OF LAST ROUTINE LOAD    (3 BYTES)    00524000
*                            NOT USED                      (1 BYTE )    00526000
*                    --------------                                     00528000
*                    WORKAREA-     SEE 'FORCORE DSECT'(IECDSECT)        00530000
*                                  IN THIS LISTING.                     00532000
*                                                                       00534000
*ATTRIBUTES--        REENTRANT AND REUSABLE.                            00536000
*                                                                       00538000
*********************************************************************** 00540000
*********************************************************************** 00600000
*                        REGISTER  CONVENTIONS                          00800000
*********************************************************************** 01000000
*                                                                       01200000
RDCB     EQU   2                       DCB REGISTER                     01400000
RBASE    EQU   3                       BASE REGISTER                    01600000
RCORE    EQU   4                       DCB WORK AREA REGISTER           01800000
RPAR     EQU   5                       TOP OF PARAMETER LIST            02000000
RWTG     EQU   6                       TOP OF WHERE-TO-GO (WTG) TABLE   02200000
RPARC    EQU   7                       CURRENT PARAMETER                02400000
RWTGC    EQU   8                       CURRENT TRANS LOAD               02600000
RTIOT    EQU   9                       USED HERE AS WORK REGISTER       02800000
RUCB     EQU   10                      USED HERE AS WORK REGISTER       03000000
RDEB     EQU   11                      USED HERE AS FORMAT CARD POINTER 03200000
RB       EQU   12                      USED HERE AS WRK/SWITCH REGISTER 03400000
RC       EQU   13                      WORK REGISTER                    03600000
RD       EQU   14                      WORK REGISTER                    03800000
RJ       EQU   15                      WORK REGISTER                    04000000
RE       EQU   0                       WORK REGISTER                    04200000
RF       EQU   1                       WORK REGISTER                    04400000
*********************************************************************** 04600000
*                        DISPLACEMENTS AND MASKS                        04800000
*********************************************************************** 05000000
*                                                                       05200000
RCE      EQU   X'10'                                                    05400000
OMR      EQU   X'20'                                                    05600000
P3525    EQU   X'4C'                                                    05800000
R3505    EQU   X'46'                                                    06000000
FDSS     EQU   X'23'                    FEED SS COMMAND                 06060000
OMRCEFSS EQU   X'2B'                    FEED SS CMD WITH OMR/RCE FLAG   06080000
RDONLY   EQU   X'C2'                                                    06400000
OMRCMD   EQU   X'31'                                                    06600000
RCECMD   EQU   X'11'                                                    06800000
UNRELFLG EQU   X'02'                                                    07000000
SLI      EQU   X'20'                                                    07200000
BYTCNT80 EQU   X'50'                                                    07400000
FIVE     EQU   5                                                        07500000
FOUR     EQU   X'04'                                                    07600000
THRE     EQU   X'03'                                                    07800000
TWO      EQU   X'02'                                                    08000000
ONE      EQU   X'01'                                                    08200000
Z        EQU   X'E9'                                                    08400000
SUCCFLCC EQU   X'7F'                                                    08600000
NINE     EQU   X'09'                                                    08800000
EIGHT    EQU   X'08'                                                    09000000
TWELVE   EQU   X'0C'                                                    09200000
SEVENTY1 EQU   X'47'                                                    09400000
SIXTY8   EQU   X'44'                                                    09600000
BLANK    EQU   X'40'                                                    09800000
LFTPAREN EQU   X'4D'                                                    10000000
RGTPAREN EQU   X'5D'                                                    10200000
COMMA    EQU   X'6B'                                                    10400000
ZERO     EQU   X'00'                                                    10600000
SEVEN    EQU   X'07'                                                    10800000
TEN      EQU   10                                                       10820000
D72      EQU   72                                                       10840000
F9       EQU   X'F9'                                                    10860000
F0       EQU   X'F0'                                                    10880000
D15      EQU   15                                                       10900000
D80      EQU   80                                                       10920000
D71      EQU   71                                                       10940000
SIX      EQU   6                                                        10960000
D14      EQU   14                                                       10980000
*                                                                       11000000
**                                                                      11200000
***                                                                     11400000
**                                                                      11600000
*                                                                       11800000
         BALR  RBASE,RE                LOAD BASE ADDR IN BASE REG       12000000
         USING RCE1000,RBASE                                            12200000
         USING FORCORE,RCORE                                            12400000
         USING IHADCB,RDCB                                              12600000
RCE1000  EQU   *                                                        12800000
         L     RDCB,0(RPARC)           GET DCB ADDRESS                  13000000
         L     RCORE,FOUR(RWTGC)       GET WORK AREA ADDRESS            13100000
         MVC   DSCEXT1+NINE(EIGHT),DXDEBAPP SET UP FOR WORK AREA FIRST  13200000
         MVC   DSCEXT2+SEVEN(EIGHT),DXDEBSCC USAGE. SAVE CONTENTS       13300000
         ST    RPAR,DXDEBAPP           SAVE PARAMETER LIST              13600000
*                                                                       13800000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 14000000
*                                                                     * 14200000
*                                 BUILD IOB AND CCW                   * 14400000
*                                                                     * 14600000
         ST    RDCB,IOBWGHT            PUT DCB ADDR IN WORK IOB         14700000
         TM    DCBMODE,RCE             RCE SPECIFIED FOR THIS DEVICE    16000000
         BO    RCE1100                 YES, BRANCH                      16200000
         TM    DCBMODE,OMR             OMR SPECIFIED FOR THIS DEVICE    16400000
         BNO   RCE4300                 NO, BRANCH TO TRANSFER CONTROL   16600000
         TM    DCBDEVT,P3525           3525 CARD PUNCH DEVICE           16800000
         BO    RCE4500                 YES, BRANCH                      17000000
RCE1100  EQU   *                                                        17200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 17400000
*        SET UP SWITCH (RB) TO DETERMINE OPERATION TO BE PERFORMED      17600000
*             SWITCH(RB)                                                17800000
*                  0    FIRST FORMAT CARD JUST READ                     18000000
*                  1    READ ONLY CMD MUST BE ISSUED NOW                18200000
*                  2    TRANSLATION OF FORMAT CARD(S) COMPLETE          18400000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 18600000
         SR    RB,RB                   SET FIRST FORMAT CD SWITCH TO 0  18800000
RCE1200  EQU   *                                                        19000000
         MVI   DXCCW1,RDONLY           SET READ ONLY CMD IN CCW         19200000
RCE1250  EQU   *                                                        19400000
         LA    RF,DXCCW2               GET DATA ADDRESS FOR CCW         19600000
RCE1300  EQU   *                                                        19800000
         ST    RF,DXDEBUCB             PREPARE DATA ADR FOR CCW STORAGE 19860000
         MVC   DXCCW1+ONE(THRE),DXDEBUCB+ONE  PUT DATA ADDR IN CCW      19920000
         MVI   DXCCW1+FOUR,SLI         TURN ON SLI BIT IN CCW           20400000
         MVI   DXCCW1+SEVEN,BYTCNT80   SET BYTE COUNT TO 80 IN CCW      20600000
*                                                                     * 20800000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 21000000
         LA    RF,IOBFLAG1             GET IOB ADDRESS                  21200000
         EXCP  (1)                     EXECUTE CHANNEL PROGRAM          21400000
         LA    RF,DXECB                GET ECB ADDRESS FOR WAIT         21600000
         WAIT  ECB=(1)                                                  21800000
         TM    DXECB,SUCCFLCC          SUCCESSFUL COMPLETION (X'7F')    22000000
         BNO   RCE4500                 NO, BRANCH                       22200000
         XC    DXECB(FOUR),DXECB       ZERO OUT ECB AREA                22400000
         LA    RF,TWO                  SET MASK FOR TEST                22600000
         CLR   RB,RF                   IS TRANSLATION COMPLETE          22800000
         BE    RCE4300                 YES, BRANCH TO TRANSFER CONTROL  23000000
         TM    DXCCW1,FDSS             FEED, SS CMD                     23200000
         BO    RCE1200                 YES, GO BACK AN DO A RD ONLY CMD 23400000
         TM    DXCCW1,RDONLY           IS THIS A READ ONLY COMMAND      23600000
         BO    RCE1400                 YES,BRANCH                       23800000
         LA    RB,TWO                  SET TRANSLATION COMPLETE SWITCH  24000000
         MVI   DXCCW1,OMRCEFSS          SET TRANSLATION COMPLETE FLAG   24200000
         B     RCE1250                 BRANCH                           24300000
LEVELID  DC    C'01'                   MODULE LEVEL CONTROL             24400000
RCE1400  EQU   *                                                        24600000
         LTR   RB,RB                   SWITCH EQUALS ZERO               24800000
         BC    7,RCE3100               NO, BRANCH                       25000000
RCE1500  EQU   *                                                        25200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 25400000
*        CHECK FIRST NINE COLUMNS OF FIRST FORMAT CARD FOR VALIDITY     25600000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 25800000
         CLC   DXCCW2(NINE),MYFRMT     ARE FIRST 9 COL. OF FORMAT VALID 26000000
         BNE   RCE4500                 NO, BRANCH                       26200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 26400000
*        'COLUMN NUMBER' COUNTER (RC) SPECIFIES THE COLUMN THAT IS      26600000
*        CURRENTLY BEING DIAGNOSED ON THE USER'S FORMAT CARD.           26800000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 27000000
         LA    RC,TEN                  COLUMN NUMBER COUNTER            27200000
         LA    RDEB,DXCCW2+NINE        POINT TO FIRST DIGIT OF OPERAND  27400000
         SR    RD,RD                   ZERO OUT WORK REGISTER           27600000
RCE1600  EQU   *                                                        27800000
         L     RPAR,F000               SET UP FOR FIRST FORMAT COL. NO. 28000000
         LR    RJ,RPAR                 SET UP FOR NEXT FORMAT COL. NO.  28200000
RCE1650  EQU   *                                                        28400000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 28600000
*        IF THE 'COLUMN NUMBER' COUNTER IS POINTING AT COLUMN72 AND     28800000
*        A CONTINUATION MARK IS IN COLUMN 72, THEN SAVE LAST 3 CHARS    29000000
*        OF CARD FOR HELP IN DIAGNOSING THE NEXT CARD.                  29200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 29400000
         LA    RUCB,D72                LOAD NUMBER FOR COMPARE          29600000
         CLR   RC,RUCB                 IS COLUMN 72 BEING POINTED TO    29800000
         BL    RCE1700                 NO, BRANCH TO TRANSLATE COLUMN   30000000
         CLI   DXCCW2+SEVENTY1,BLANK   CONTINUATION MARK IN COL. 72     30200000
         BE    RCE1700                 NO, BRANCH TO TRANSLATE NEXT COL 30400000
         MVC   JFCBXPDT(THRE),DXCCW2+SIXTY8  SAVE LAST 3 BYTES OF CARD  30600000
RCE1680  EQU   *                                                        30800000
         LA    RB,ONE                  SET SWITCH TO ONE                31000000
         MVI   DXCCW1,FDSS             SET FD,SS CMD IN CCW             31200000
         ST    RJ,DXDEBEHH             SAVE LAST NUMBER OF OPERAND      31400000
         B     RCE1250                 BRANCH                           31600000
RCE1700  EQU   *                                                        31800000
         SR    RUCB,RUCB               ZERO OUT WORK REGISTER           32000000
         IC    RUCB,0(RDEB)            GET CHAR POINTED TO ON FORMAT CD 32200000
RCE1800  EQU   *                                                        32400000
         LA    RE,F9                   LOAD MASK TO CK FOR VALID CHAR   32600000
         CLR   RUCB,RE                 IS CHAR GREATER THAN A NUMBER    32800000
         BH    RCE4500                 YES, BRANCH                      33000000
         LR    RTIOT,RDEB              GET FORMAT POINTER               33200000
         LA    RE,TWO                  GET A VALUE OF 2                 33400000
         SR    RTIOT,RE                POINT BACK 2 COL. ON FORMAT CD   33600000
MOVE     MVC   DXDEBECC(FOUR),ZERO(RTIOT)  GET 4 CHAR OF FORMAT FOR TST 33800000
         LA    RF,F0                   GET MASK TO CK FOR SPECIAL CHAR  34000000
         CLR   RUCB,RF                 IS THIS CHAR A NUMBER            34200000
         BL    RCE2600                 NO, BR.--MUST BE SPECIAL CHAR    34400000
RCE1900  EQU   *                                                        34600000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 34800000
*        CONTINUE INTERROGATION OF OPERAND AND SAVE FIRST NUMBER        35000000
*        OF OPERAND IN REG. 5 (RPAR) AND LAST NUMBER IN REG.15 (RJ)     35200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 35400000
         CLI   DXDEBECC+ONE,LFTPAREN   IS LEFT PAREN IN THIS FORMAT COL 35600000
         BNE   RCE2200                 NO, BRANCH                       35800000
         CLI   DXDEBECC+THRE,COMMA     COMMA IN THIS FORMAT COLUMN      36000000
         BNE   RCE2100                 NO, BRANCH                       36200000
RCE2000  EQU   *                                                        36400000
         IC    RPAR,ZERO(RDEB)         SAVE CHAR BEING POINTED TO       36600000
         LA    RDEB,TWO(RDEB)          INCRE FORMAT SEARCH ADDR. BY 2   36800000
         LA    RC,TWO(RC)              INCRE 'COLUMN NO.' COUNTER BY 2  37000000
         B     RCE1650                 BRANCH TO CHECK NEXT COLUMN      37200000
RCE2100  EQU   *                                                        37400000
         SR    RPAR,RPAR               ZERO OUT REGISTER                37600000
         IC    RPAR,ZERO(RDEB)         SAVE CHAR BEING POINTED TO       37800000
         SLA   RPAR,8                  PREPARE FOR SECOND DIGIT OF NO.  38000000
RCE2150  EQU   *                                                        38200000
         LA    RDEB,ONE(RDEB)          INCRE FORMAT SEARCH ADDR. BY 1   38400000
         LA    RC,ONE(RC)              INCRE 'COLUMN NO.' COUNTER BY 1  38600000
         B     RCE1650                 BRANCH TO CHECK NEXT COLUMN      38800000
RCE2200  EQU   *                                                        39000000
         CLI   DXDEBECC,LFTPAREN       LEFT PAREN IN THIS FORMAT COLUMN 39200000
         BE    RCE2000                 YES, BRANCH                      39400000
         CLI   DXDEBECC+ONE,COMMA      COMMA IN THIS FORMAT COLUMN      39600000
         BNE   RCE4450                  NO BRANCH TO ABEND              39800000
         CLI   DXDEBECC+THRE,RGTPAREN  RGT. PAREN IN THIS FORMAT COLUMN 40000000
         BNE   RCE2400                 NO, BRANCH                       40200000
RCE2300  EQU   *                                                        40400000
         IC    RJ,ZERO(RDEB)           GET NUMBER BEING POINTED TO      40600000
         LA    RDEB,TWO(RDEB)          INCRE FORMAT CARD POINTER BY 2   40800000
         LA    RC,TWO(RC)              INCRE 'COLUMN NO.' COUNTER BY 2  41000000
         CLI   ZERO(RDEB),BLANK        IS FORMAT COMPLETED YET          41200000
         BE    RCE3350                  YES GO CK COLUMN 72             42000000
RCE2350  EQU   *                                                        42800000
         CLI   ZERO(RDEB),COMMA        IS THERE STILL ANOTHER OPERAND   43000000
         BNE   RCE2375                 NO, BRANCH                       43200000
         CLI   ONE(RDEB),BLANK         IS NEXT COLUMN BLANK             43400000
         BNE   RCE3400                 NO, BRANCH                       43600000
RCE2375  EQU   *                                                        43800000
         CLI   DXCCW2+SEVENTY1,BLANK   IS COLUMN 72 BLANK               44000000
         BE    RCE4500                 YES, BRANCH                      44200000
         B     RCE3400                 BRANCH TO PROCESS THIS OPERAND   44400000
RCE2400  EQU   *                                                        44600000
         SR    RJ,RJ                   ZERO OUT REG. 15                 44800000
         IC    RJ,ZERO(RDEB)           GET NUMBER BEING POINTED TO      45000000
         SLA   RJ,8                    PREPARE FOR SECOND DIGIT OF NO.  45200000
         B     RCE2150                 BRANCH TO GET SECOND DIGIT       45400000
RCE2600  EQU   *                                                        47400000
         CLI   DXDEBECC+TWO,COMMA      COMMA IN THIS COLUMN             47600000
         BE    RCE2800                  YES BRANCH                      47800000
         CLI   DXDEBECC+TWO,RGTPAREN   RIGHT PAREN IN THIS COLUMN       48000000
         BNE   RCE2950                  NO BRANCH                       48100000
         CLI   DXDEBECC+THRE,BLANK     END OF FORMAT CARD               48200000
         BE    SETEXCP                 YES GO SET UP OMR/RCE CCW        48300000
         B     RCE2150                 BRANCH                           48600000
*                                                                       48900000
RCE2800  EQU   *                                                        49200000
*                                                                       49500000
*                                                                       49800000
         CLI   DXDEBECC+ONE,RGTPAREN    RIGHT PAREN IN THIS COLUMN      50100000
         BE    RCE2150                  GO INCREMENT COUNTERS BY ONE    50400000
RCE2900  EQU   *                                                        51000000
         CLI   DXDEBECC+ONE,LFTPAREN   LEFT PAREN IN THIS COLUMN        51200000
         BE    RCE4500                 YES, BRANCH                      51400000
         B     RCE2150                 NO, BRANCH                       51600000
RCE2950  EQU   *                                                        51620000
*                                                                       51640000
*                                                                       51660000
         CLI   ZERO(RDEB),LFTPAREN      LEFT PAREN IN THIS COLUMN       51680000
         BE    RCE2150                  YES BRANCH                      51700000
         CLI   ZERO(RDEB),BLANK         BLANK IN THIS COLUMN            51720000
         BNE   RCE4500                  NO GO SET UP TO ABEND           51740000
RCE3000  EQU   *                                                        51800000
         CLI   DXCCW2+SEVENTY1,BLANK   COLUMN 72 BLANK                  52000000
         BE    SETEXCP                 YES, GO TO SET UP OMR/RCE CCW    52200000
         LA    RUCB,THRE               LOAD VALUE OF 3 IN WORK REGISTER 52400000
         SR    RDEB,RUCB               PT. BACK 3 COL. ON FORMAT CARD   52600000
         MVC   JFCBXPDT(THRE),ZERO(RDEB)  SAVE LAST 3 CHAR OF THIS CD.  52800000
         B     RCE1680                 BRANCH                           53000000
RCE3100  EQU   *                                                        53200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 53400000
*        TEST FIRST 15 COLUMNS OF CONTINUATION CARDS.  IF OTHER THAN    53600000
*        BLANK(X'40'), THE FORMAT IS INVALID.  IF COLUMNS ARE BLANK     53800000
*        THEN MOVE INTO COLUMNS 13,14 AND 15 OF THIS FORMAT CARD        54000000
*        THE 3 CHARS. SAVED FROM PREVIOUS CARD.                         54200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 54400000
         LA    RC,ONE                  SET REGISTER TO ONE              54600000
         LA    RDEB,DXCCW2                                              54800000
         LA    RUCB,D15                SET UP TO TEST 1ST 15 COL. OF CD 55000000
RCE3200  EQU   *                                                        55200000
         CLI   ZERO(RDEB),BLANK        IS THIS COL. OF FORMAT CD BLANK  55400000
         BNE   RCE4500                 NO, BRANCH                       55600000
         CLR   RC,RUCB                 POINTING AT COL. 15 YET          55800000
         BL    RCE3300                 NO, BRANCH                       56000000
         MVC   DXCCW2+TWELVE(THRE),JFCBXPDT  PUT SAVED CHARS. IN 13-15  56200000
         L     RJ,DXDEBEHH             RELOAD LAST NUMBER               56400000
         B     RCE2150                 BRANCH                           56600000
RCE3300  EQU   *                                                        56800000
         LA    RDEB,ONE(RDEB)          INCRE FORMAT POINTER BY 1        57000000
         LA    RC,ONE(RC)              INCREMENT COUNTER BY ONE         57200000
         B     RCE3200                 BR TO CHECK FOR BLANK COLUMN     57400000
RCE3350  EQU   *                                                        57420000
*                                                                       57440000
*                                                                       57460000
         CLI   DXCCW2+SEVENTY1,BLANK    IS COLUMN 72 BLANK              57480000
         BE    RCE3400                  IF SO GO CONVERT IT TO BINARY   57500000
         LA    RUCB,D72                SET UP TO TEST FOR COLUMN 72     57520000
         CLR   RC,RUCB                  IS THIS COLUMN 72 OR LOWER      57540000
         BNH   RCE4500                  IN NOT GO SET UP TO ABEND       57560000
RCE3400  EQU   *                       IS NO. SAVED FROM LAST OPERAND   57600000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 57800000
*        TEST LAST NO. OF PREVIOUS OPERAND AGAINST FIRST NO. OF         58000000
*        CURRENT OPERAND.  IF LAST NO. IS LESS THAN FIRST NO., THE      58200000
*        FORMAT IS INVALID.                                             58400000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 58600000
         CLR   RD,RPAR                 < FIRST NO. OF THIS OPERAND      58800000
         BNL   RCE4500                 NO, BRANCH                       59000000
         STH   RPAR,DXDEBSHH           GET FIRST NUMBER OF OPERAND      59200000
EXPACK   PACK  DXCCW12(EIGHT),DXDEBSHH(TWO) PACK THE NUMBER             59400000
         CVB   RPAR,DXCCW12            PUT NO. IN ARITHMETIC FORM       59600000
         ST    RJ,DXDEBEHH             GET LAST NUMBER  OF OPERAND      59800000
         PACK  DXCCW12(EIGHT),DXDEBEHH(FOUR)     PACK THE NUMBER        60000000
         CVB   RJ,DXCCW12              PUT NO. IN ARITHMETIC FORM       60200000
         LTR   RD,RD                   IS THIS THE FIRST FORMAT OPERAND 60400000
         BZ    EEEE                    YES, BRANCH                      60600000
         STH   RD,DXDEBSHH             GET NO. SAVED FROM LAST OPERAND  60800000
         EX    RE,EXPACK               GO TO PACK THE NUMBER            61000000
         CVB   RD,DXCCW12              PUT NO. IN ARITHMETIC FORM       61200000
EEEE     EQU   *                                                        61400000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 61600000
*        IF NUMBER IS GREATER THAN 80 OR EQUAL TO 0, THEN THE FORMAT    61800000
*        IS INVALID.                                                    62000000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 62200000
         LA    RTIOT,D80               SET WORK REG TO 80               62400000
         CLR   RPAR,RTIOT              IS FIRST NO. MORE THAN 80        62600000
         BH    RCE4500                 YES, BRANCH                      62800000
         CLR   RJ,RTIOT                IS LAST FIELD OF OPERAND > 80    63000000
         BH    RCE4500                 YES, BRANCH                      63200000
         LTR   RPAR,RPAR               IS FIRST NO. = 0                 63400000
         BZ    RCE4500                 YES, BRANCH                      63600000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 63800000
*        FOR VALID USE OF OMR, THE DIFFERENCE BETWEEN THE LAST NO.      64000000
*        OF THE PREVIOUS OPERAND AND FIRST NO. OF CURRENT OPERAND       64200000
*        MUST EQUAL TO 2 OR MORE.                                       64400000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 64600000
         TM    DCBMODE,OMR             OMR SPECIFIED                    64800000
         BNO   RCE3600                 NO, BRANCH                       65000000
         LTR   RD,RD                   IS THIS THE 1ST COMPLETE OPERAND 65200000
         BC    8,RCE3500               YES, BRANCH                      65400000
         LA    RD,TWO(RD)              INCREMENT SAVED NUMBER BY 2      65600000
         SR    RD,RPAR                 SUB. 1ST NO. OF CURR OPERAND TO  65800000
         LTR   RD,RD                   VALID SPACE PROVIDED FOR OMR USE 66000000
         BP    RCE4500                 NO, BRANCH                       66200000
RCE3500  EQU   *                                                        66400000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 66600000
*        IF THE  TWO NUMBERS OF THIS OPERAND ARE NOT BOTH EVEN OR       66800000
*        BOTH ODD, THEN THE FORMAT IS INVALID FOR OMR.                  67000000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 67200000
         STH   RC,DXDEBSCC                                              67400000
         SR    RB,RB                                                    67600000
         LR    RC,RPAR                 LOAD FIRST NO. OF OPERAND IN R13 67800000
         LA    RUCB,TWO                SET DIVISOR TO TWO               68000000
         DR    RB,RUCB                 DIVIDE FIRST NO. TO GET REMAINDR 68200000
         LR    RTIOT,RB                SAVE REMAINDER FOR NEXT TEST     68400000
         SR    RB,RB                                                    68600000
         LR    RC,RJ                   PUT LAST NO. OF OPERAND IN REG13 68800000
         DR    RB,RUCB                 DIVIDE LAST NO. TO GET REMAINDER 69000000
         CLR   RB,RTIOT                ARE BOTH NO. EITHER EVEN OR ODD  69200000
         BNE   RCE4500                 NO, BRANCH                       69400000
         SR    RC,RC                                                    69600000
         LH    RC,DXDEBSCC                                              69800000
RCE3600  EQU   *                                                        70000000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 70200000
*        BUILD FORMAT TRANSLATION FOR THE DEVICE AS FOLLOWS:  PLACE     70400000
*        CHARACTER IN EACH OMR OR RCE COLUMN AS SPECIFIED VIA THE       70600000
*        USER'S FORMAT CARD(S).                                         70800000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 71000000
         LA    RB,DXLBL                GET @ OF AREA USED FOR TRANSLATN 71200000
         LA    RUCB,ONE                SET WORK REG TO 1                71400000
         SR    RB,RUCB                                                  71600000
         AR    RB,RPAR                 POINT TO COL. SPEC. ON FORMAT CD 71800000
         TM    DCBMODE,OMR             OMR SPECIFIED                    72000000
         BNO   RCE3700                 NO, RCE ASSUMED, BRANCH          72200000
         LA    RUCB,TWO                SET WORK REG TO 2                72400000
RCE3700  EQU   *                                                        72600000
         MVI   ZERO(RB),Z              PUT CHAR IN COL. TO BE RD IN OMR 72800000
         CLR   RPAR,RJ                 HAVE CHAR BEEN PLACED IN ALL COL 73000000
         BE    RCE3900                 YES, BRANCH                      73200000
         AR    RPAR,RUCB               POINT TO NEXT FORMAT COLUMN      73400000
         AR    RB,RUCB                 INCREMENT FORMAT AREA ADDRESS    73600000
         B     RCE3700                 BR TO PLACE CHAR IN THIS COLUMN  73800000
RCE3900  EQU   *                                                        74000000
         L     RD,DXDEBEHH             SAVE LAST NO. IN THIS OPERAND    74200000
         LA    RUCB,D80                SET UP TO TEST FOR FORMAT CD IND 74400000
         CLR   RJ,RUCB                 LAST NUMBER = 80                 74600000
         BNE   RCE1600                 NO, BRANCH                       74800000
         CLI   ZERO(RDEB),BLANK        IS NEXT COL OF FORMAT CARD BLANK 75000000
         BNE   RCE4500                 NO, BRANCH                       75200000
         CLI   DXCCW2+SEVENTY1,BLANK   YES, THEN IS CONTINUATION SPEC   75400000
         BNE   RCE4500                  YES BRANCH TO ABEND             75700000
SETEXCP  EQU   *                                                        76000000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 76200000
*        LOAD PROPER OP CODE (X'11' FOR RCE OR X'31' FOR OMR) AND       76400000
*        DATA ADDRESS INTO CCW.                                         76600000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 76800000
*                                                                       77000000
         MVI   DXCCW1,OMRCMD            SET OMR COMMAND IN CCW          77100000
         TM    DCBMODE,OMR             OMR SPECIFIED                    77200000
         BO    RCE4200                  BRANCH TO PUT DATA ADDR. IN CCW 77700000
         MVI   DXCCW1,RCECMD           SET RCE CMD IN CCW               78200000
RCE4200  EQU   *                                                        78400000
         LA    RF,DXLBL                GET DATA ADDRESS                 78600000
         B     RCE1300                 BR TO CONTINUE CONSTRUCTION CCW  78800000
RCE4300  EQU   *                                                        79000000
         SR    RB,RB                    SET ENTRY FOR BUFFER CHECKING   79040000
         B     RCE4600                  GO LOAD ID OF IGG0197M          79080000
RCE4450  EQU   *                                                        79083000
*                                                                       79086000
*                                                                       79089000
         CLI   DXDEBECC,COMMA           COMMA IN THIS COLUMN            79092000
         BNE   RCE4500                  IF NOT GO SET UP TO ABEND       79095000
         CLI   DXDEBECC+THRE,RGTPAREN   RIGHT PAREN IN THIS COLUMN      79098000
         BE    RCE2300                  YES GO INCREMENT COUNTERS       79101000
         LA    RUCB,D71                SET UP TO CHECK FOR COLUMN 71    79104000
         CLR   RC,RUCB                  IS THIS COLUMN 71               79107000
         BE    RCE2300                  IF SO GO INCREMENT COUNTERS     79110000
RCE4500  EQU   *                                                        79120000
         LA    RB,FIVE                 LOAD REG. WITH ERROR PARAMETER   79160000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 79200000
*        GET IDTTRL OF NEXT EXECUTOR FROM WTG TABLE.                    79400000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 79600000
*                                                                       79630000
*                                                                       79660000
RCE4600  EQU   *                                                        79690000
*                                                                       79720000
*                                                                       79750000
         LA    RF,SOPN7M               GET ID OF NEXT MODULE            81600000
XCTLGOGO EQU   *                                                        81800000
         L     RPAR,DXDEBAPP           RESTORE PARAMETER LIST           82000000
         LA    RJ,DXDCB                                                 82040000
         ST    RJ,IOBWGHT                                               82080000
         MVC   DXDEBAPP(EIGHT),DSCEXT1+NINE RESTORE WORK                82160000
         MVC   DXDEBSCC(EIGHT),DSCEXT2+SEVEN AREA AFTER USAGE           82240000
         MVC   ZERO(FIVE,RWTGC),ZERO(RF)                                82320000
RELOOP   EQU   *                                                        82400000
         LA    RWTGC,WGOFF(ZERO,RWTGC)                                  82600000
         LA    RPARC,PLOFF(ZERO,RPARC)                                  82800000
         CLC   ZERO(TWO,RWTGC),AMIDCNST                                 83000000
         BCR   8,RBASE                 BRANCH IF EQUAL                  83200000
         CLC   ZERO(TWO,RWTGC),OPIDCNST                                 83400000
         BC    7,RELOOP                BRANCH IF NOT EQUAL              83600000
         LR    RPARC,RPAR                                               83800000
         LA    RWTGC,WAOFF(ZERO,RWTG)                                   84000000
ZCHEK    CLI   ZERO(RWTGC),ZERO                                         84200000
         BC    7,TCTLRTN               BRANCH IF NOT EQUAL              84400000
         LA    RWTGC,WGOFF(ZERO,RWTGC)                                  84600000
         LA    RPARC,PLOFF(ZERO,RPARC)                                  84800000
         BC    15,ZCHEK                BRANCH                           85000000
TCTLRTN  EQU   *                                                        85200000
         MVC   SIX(TWO,RWTG),ZERO(RWTGC)                                85400000
         MVC   D14(THRE,RWTG),TWO(RWTGC)                                85600000
         LA    RJ,DXCCW12                                               85800000
         XCTL  DE=(RWTG),SF=(E,(15))                                    86000000
*********************************************************************** 86200000
*                      DECLARE WTG OFFSETS                              86400000
WAOFF    EQU   32                                                       86600000
WGOFF    EQU   8                                                        86800000
PLOFF    EQU   4                                                        87000000
OPIDCNST DC    C'0S'                   ID                               87200000
AMIDCNST DC    C'7L'                   THIS MODULE'S ID                 87400000
MYFRMT   DC    C' FORMAT ('            FIRST NINE COL. OF FORMAT CD     87600000
         DS    0F                                                       87800000
F000     DC    XL4'0000F000'           WORK DC TO BE LOADED IN REG      88000000
*********************************************************************** 88200000
*                                                                       88400000
         ORG   IGG0197L+1008           LEAVE MAINT SPACE AS REQUIRED    88800000
SOPN7M   DC    C'7M    '               IDTTRL                           89200000
         DC    H'0'                    END OF TABLE MARKER              89600000
         DC    F'0'                    PAD TABLE TO DBL WORD BOUNDRY    89700000
         DC    C'019'                  OPEN SVC CODE                    89800000
         DC    AL1(126)                DBL WD CNST TO TOP OF WTG TABLE  90000000
*********************************************************************** 90200000
*                                                                       90400000
*                                   DSECTS                              90600000
*                                                                       90800000
         DCBD  DSORG=PS                                                 91000000
*                                                                       91200000
**                                                                      91400000
***                                                                     91600000
****                                                                    91800000
**                                                                      92000000
***                                                                     92200000
**                                                                      92400000
FORCORE  DSECT                                                          92600000
         IECDSECT                                                       92800000
         END                                                            93000000
