         TITLE 'IGG0197M  WTO MESSAGE ROUTINE AND ABEND '               00800000
         START                                                          01600000
IGG0197M CSECT                                                          01610000
*********************************************************************** 01620000
*        RELEASE 21 DELETIONS                                           01630000
*        RELEASE 22 DELETIONS                                           01640000
*                                                                       01650000
*STATUS CHANGE LEVEL 000                                                01660000
*                                                                       01670000
*FUNCTION/OPERATION--THIS ROUTINE IS ENTERED FOR SAM USERS DURING       01680000
*                    OPEN WHEN:                                         01690000
*                             1) FORMAT CARD FOR OMR OR RCE IS          01700000
*                               INVALID.                                01710000
*                             2) INVALID DEVICE HAS BEEN SPECIFIED      01720000
*                                FOR OMR.                               01730000
*                                                                       01740000
*ENTRY POINT--       IGG0197M IS ENTERED FROM IGG0197L VIA XCTL.        01750000
*                                                                       01760000
*INPUT--             DCB ADDRESS                                        01770000
*                    WORK AREA ADDRESS                                  01780000
*                    WHERE-TO-GO TABLE                                  01790000
*                    PARAMETER LIST                                     01800000
*                    CURRENT ENTRY IN WHERE-TO-GO TABLE                 01810000
*                    CURRENT PARAMETER(DCB)                             01820000
*                                                                       01830000
*OUTPUT--            SEE DESCRIPTION OF REGISTERS.                      01840000
*                                                                       01850000
*EXTERNAL ROUTINES-- NONE                                               01860000
*                                                                       01870000
*EXIT NORMAL--       XCTL TO IGG0191I  OF BUFNO HAS BEEN SPECIFIED      01876000
*                    XCTL TO IGG0197N IF BUFNO HAS NOT BEEN SPECIFIED   01882000
*                                                                       01890000
*EXIT ERROR--        004 ABEND- INVALID OMR OR RCE FORMAT CARD OR       01900000
*                    INVALID DEVICE SPECIFIED FOR OMR. REG 15 WILL      01910000
*                    CONTAIN A RETURN CODE OF 5 TO INDICATE THIS        01920000
*                    CONDITION.                                         01930000
*                                                                       01940000
*TABLES/WORKAREAS--  WHERE-TO-GO TABLE                                  01950000
*                    BYTES  0- 7   NAME                                 01960000
*                    BYTES  8-10   RELATIVE DISK ADDRESS(TTR) OF        01970000
*                                  FIRST RECORD                         01980000
*                    BYTE     11   CONCATENATION NUMBER                 01990000
*                    BYTE     12   ZEROES                               02000000
*                    BYTE     13   ALIAS INDICATOR AND USER DATA        02010000
*                                  FIELD DESCRIPTOR:                    02020000
*                                      -ALIAS INDICATOR-- 1 BIT         02030000
*                                      -NUMBER OF TTRS IN USERS         02040000
*                                      DATA FIELD-- 2 BITS              02050000
*                    BYTES 14-16   TTR OF FIRST TEXT RECORD             02060000
*                    BYTE     17   ZEROES                               02070000
*                    BYTES 18-19   TTR OF NOTE LIST OR SCATTER LIST     02080000
*                    BYTE     20   TRANSLATION TABLE                    02090000
*                    BYTE     21   ZEROES OR NUMBER OF ENTRIES IN       02100000
*                                  THE NOTE LIST                        02110000
*                    BYTES 22-23   ATTRIBUTES                           02120000
*                    BYTES 24-26   TOTAL CONTIGUOUS MAIN STORAGE        02130000
*                                  REQUIRED FOR MODULE                  02140000
*                    BYTES 27-28   LENGTH OF FIRST TEXT RECORD          02150000
*                    BYTE     29   LENGTH OF WTG TABLE(IN DOUBLE        02160000
*                                  WORDS)                               02170000
*                    BYTES 30-31   PATH THROUGH LOADS OF ROUTINES       02180000
*                    BYTES 32-34   IDTTR OF EXECUTOR FOR FIRST DCB      02190000
*                    BYTE     35   ADDRESS OF STORAGE FOR DCB           02200000
*                    BYTES 36-39   TABLE OF IDTTR'S                     02210000
*                    BYTE  32+N(8)--                                    02220000
*                            IDTTR OF EXECUTOR FOR NTH DCB (3 BYTES)    02230000
*                            ADDRESS OF STORAGE FOR DCB    (1 BYTE )    02240000
*                            IDTTR OF LAST ROUTINE LOAD    (3 BYTES)    02250000
*                            NOT USED                      (1 BYTE )    02260000
*                    --------------                                     02270000
*                    WORKAREA-     SEE 'FORCORE DSECT'(IECDSECT)        02280000
*                                  IN THIS LISTING.                     02290000
*                                                                       02300000
*ATTRIBUTES--        REENTRANT AND REUSABLE.                            02310000
*                                                                       02320000
*********************************************************************** 02330000
*********************************************************************** 02400000
*                            REGISTER CONVENTIONS                       03200000
*********************************************************************** 04000000
RDCB     EQU   2                       DCB REGISTER                     04800000
RBASE    EQU   3                       BASE REGISTER                    05600000
RCORE    EQU   4                       DCB WORK AREA REGISTER           06400000
RPAR     EQU   5                       TOP OF PARAMETER LIST            07200000
RWTG     EQU   6                       TOP OF WHERE-TO-GO (WTG) TABLE   08000000
RPARC    EQU   7                       CURRENT PARAMETER                08800000
RWTGC    EQU   8                       CURRENT TRANS LOAD               09600000
RTIOT    EQU   9                       USED HERE AS WORK REGISTER       10400000
RUCB     EQU   10                      USED HERE AS WORK REGISTER       11200000
RDEB     EQU   11                      DEB REGISTER                     12000000
RB       EQU   12                      WORK REGISTER                    12800000
RC       EQU   13                      WORK REGISTER                    13600000
RD       EQU   14                      WORK REGISTER                    14400000
RJ       EQU   15                      WORK REGISTER                    15200000
RE       EQU   0                       WORK REGISTER                    16000000
RF       EQU   1                       WORK REGISTER                    16800000
*********************************************************************** 17600000
*                            DISPLACEMENTS AND MASKS                    18400000
*********************************************************************** 19200000
ZERO     EQU   X'00'                                                    20000000
FOUR     EQU   X'04'                                                    20800000
TWO      EQU   X'02'                                                    21600000
SIX      EQU   X'06'                                                    22400000
C14      EQU   X'0E'                                                    23200000
THRE     EQU   X'03'                                                    24000000
PW       EQU   X'30'                                                    24100000
ONE      EQU   1                                                        24200000
THREE    EQU   3                                                        24300000
D70      EQU   70                                                       24320000
SVC35    EQU   35                                                       24340000
FIVE     EQU   5                                                        24360000
INPUTMSK EQU   X'0F'                                                    24400000
QSAMFLG  EQU   X'01'                                                    24500000
*                                                                       24800000
*                                                                       26400000
**                                                                      27200000
*                                                                       28000000
         BALR  RBASE,RE                LOAD BASE ADDR IN BASE REG       28800000
         USING M1000,RBASE                                              29600000
         USING FORCORE,RCORE                                            30400000
         USING DEBBASIC,RDEB                                            30800000
         USING IHADCB,RDCB                                              31200000
*                                                                       32000000
M1000    EQU   *                                                        32800000
         L     RDCB,ZERO(RPARC)        GET DCB ADDRESS                  33600000
         LA    RDCB,ZERO(RDCB)         CLEAR HIGH ORDER BYTE            34400000
         L     RCORE,FOUR(RWTGC)       GET WORK AREA ADDRESS            35200000
         L     RDEB,DCBDEBAD           GET DEB ADDRESS                  35600000
*                                                                       36000000
         C     RB,ERROR                HAS AN ERROR CODE BEEN PASSED    36200000
         BNE   BYPASMSG                NO, BY PASS ERROR MESSAGE        36500000
**                                                                      36800000
*                                                                       37600000
         MVC   MESSAGEA(D70),WTO0045   MOVE IN WTO MESSAGE              38200000
         LA    RF,MESSAGEA              GET ADDRESS OF WTO MESSAGE      38800000
         SVC   SVC35                   ISSUE WTO MESSAGE                39300000
         LA    RJ,FIVE                 LOAD FORMAT ERROR CODE IN REG 15 39800000
         B     ABEN                    BRANCH TO ISSUE ABEND            40300000
LEVELID  DC    C'02'                   MODULE LEVEL CONTROL             40800000
*                                                                       41600000
BYPASMSG EQU   *                                                        41620000
         SR    RB,RB                                                    41640000
         IC    RB,DCBBUFNO             PICK UP BUFFER NUMBER            41660000
         TM    DCBCIND2,QSAMFLG        USING QSAM                       41680000
         BNO   TESTBSAM                NO, BRANCH TO CHECK BSAM         41700000
         LTR   RB,RB                   HAS A BUFFER NUMBER BEEN SPECIFD 41720000
         BNZ   CONTINUE                YES, BRANCH AND ASSUME CORRECT   41740000
*                                      BUFFER NUMBER.                   41760000
         TM    DEBOPATB,INPUTMSK       CHECK FOR INPUT DATA SET         41780000
         BO    CKOUT                   NO, BRANCH                       41800000
         BM    CKOUT                   NO, BRANCH                       41820000
         TM    DCBFUNC,PW              3525 PUNCH OR PRINT DATA SET     41840000
         BZ    READONLY                YES, BRANCH                      41860000
CKOUT    EQU   *                                                        41880000
         OI    DCBBUFNO,ONE            SET BUFFER NUMBER TO ONE         41900000
         B     CONTINUE                BRANCH                           41920000
READONLY EQU   *                                                        41940000
         OI    DCBBUFNO,TWO            DEFAULT TO TWO BUFFERS           41960000
CONTINUE EQU   *                                                        41980000
         TM    DCBBUFNO+THREE,ONE      BUFFER CONTROL BLOCK SPECIFIED   42000000
         BNO   LIDOF7N                 NO BRANCH                        42020000
TESTBSAM EQU   *                                                        42040000
         TM    DCBBUFNO+THREE,ONE      BUFFER CONTROL BLOCK SPECIFIED   42060000
         BNO   LIDOF7N                 NO, BRANCH                       42080000
         LTR   RB,RB                   HAS A BUFFER NO. BEEN SPECIFIED  42100000
         BZ    LIDOF7N                 NO, BRANCH TO LOAD ID OF 7N      42120000
LIDOF1I  EQU   *                                                        42140000
         LA    RF,SOP7                 LOAD ID OF IGG0191I              42160000
         B     XCTLGOGO                BRANCH TO XCTL ROUTINE           42180000
LIDOF7N  EQU   *                                                        42200000
         LA    RF,SOPN7N               LOAD ID OF IGG0197N              42220000
XCTLGOGO EQU   *                                                        42280000
         MVC   ZERO(FIVE,RWTGC),ZERO(RF) SAVE ID OF NEXT MODULE         42340000
RELOOP   EQU   *                                                        42400000
*                                                                       43200000
         LA    RWTGC,WGOFF(ZERO,RWTGC) INCREMENT CURRENT WTG ENTRY      44000000
         LA    RPARC,PLOFF(ZERO,RPARC) INCRE CURRENT DCB ENTRY POINTER  44800000
         CLC   ZERO(TWO,RWTGC),AMIDCNST THIS ROUTINE NEEDED AGAIN       45600000
         BCR   RWTGC,RBASE             BACK TO OPEN CONTROL ROUTINE     46400000
*                                                                       47200000
         CLC   ZERO(TWO,RWTGC),OPIDCNST END OF TABLE                    48000000
         BNE   RELOOP                  NO, CHECK NEXT ENTRY             48800000
*                                                                       49600000
         LR    RPARC,RPAR                                               50400000
         LA    RWTGC,WAOFF(ZERO,RWTG)  REINITIALIZE WTG LIST POINTER    51200000
ZCHEK    CLI   ZERO(RWTGC),ZERO        ENTRY COMPLETE                   52000000
         BNE   TCTLRTN                 IF NOT, TRANSFER CONTROL         52800000
*                                                                       53600000
         LA    RWTGC,WGOFF(ZERO,RWTGC) GET NEXT ENTRY                   54400000
         LA    RPARC,PLOFF(ZERO,RPARC) GET NEXT ENTRY                   55200000
         B     ZCHEK                   BRANCH TO ZERO CHECK             56000000
*                                                                       56800000
TCTLRTN  EQU   *                                                        57600000
*                                                                       58400000
         MVC   SIX(TWO,RWTG),0(RWTGC)  STORE ID IN WTG TABLE            59200000
         MVC   C14(THRE,RWTG),TWO(RWTGC) MOVE TTR INTO TABLE            60000000
*                                                                       60800000
         LA    RJ,DXCCW12              SET UP FOR XCTL                  61600000
*                                                                       62400000
         XCTL  DE=(RWTG),SF=(E,(15))   ISSUE XCTL                       63200000
*                                                                       64000000
**                                                                      64800000
***                                                                     65600000
**                                                                      66400000
*                                                                       67200000
ABEN     EQU   *                                                        68000000
*                                                                       68800000
         L     RF,ABEND4               LOAD ABEND CODE OF 4             69600000
         SLL   RF,12                                                    70400000
         ABEND (1),DUMP                                                 71200000
*                                                                       72000000
*********************************************************************** 72800000
*                                                                       73600000
WAOFF    EQU   32                                                       74400000
WGOFF    EQU   8                       OFFSET OF WTG ENTRIES            75200000
PLOFF    EQU   4                       OFFSET OF DCB ENTRIES            76000000
OPIDCNST DC    C'0S'                   ID                               76800000
AMIDCNST DC    C'7M'                   THIS MODULE'S ID                 77000000
         DS    0F                      ALIGN ON A FULLWORD BOUNDARY     77200000
ERROR    DC    X'00000005'             CONSTANT USED FOR COMPARES       77400000
ABEND4   DC    X'00000004'             ABEND CODE OF 4                  77600000
*                                                                       77800000
WTO0045  WTO   'IEC951I 004-5 INVALID FORMAT CARD OR INVALID DEVICE FOR*77900000
                OMR',MF=L,ROUTCDE=(11),DESC=4                           78000000
*                                                                       78100000
*********************************************************************** 78400000
*                                                                       79200000
         ORG   IGG0197M+1000           LEAVE MAINT SPACE AS REQ.        79600000
SOP7     DC    C'1I    '               ID OF IGG0191I                   80000000
SOPN7N   DC    C'7N    '               ID OF IGG0197N                   80400000
         DC    H'0'                    END OF TABLE MARKER              80800000
         DC    3H'0'                   FILLER                           81600000
         DC    C'019'                  OPEN SVC CODE                    82400000
EBL      DC    AL1(125)                DBL WD CNST TO TOP OF WTG        83200000
*********************************************************************** 84000000
*************************       DSECTS       ************************** 84800000
*********************************************************************** 85600000
*                                                                       86400000
*                                                                       87200000
         DCBD  DSORG=PS                                                 88000000
         IEZDEB                                                         88400000
FORCORE  DSECT                                                          88800000
         IECDSECT                                                       89600000
         END                                                            90400000
