197U TITLE 'IGG0197U - UCS PROCESSING.  CONTINUATION OF IGG0191V'       00100021
 COPY LCGASMSW                                                          00120001
*                                                                       00140001
*                                                                       00180001
IGG0197U CSECT                                                          00200020
*0000365000-366000,370000,375000-377000,379000,383000,386000,    M5143  00230020
*0000389000,392000,593000-595000                                 M5143  00260020
*          RELEASE 21 DELETIONS                                         00300020
*0791115000,607000,621000                                        M1803  00310021
*0791106000-107000,451000,466000,521000-525000,747000,795000-    M0099  00330021
*0791804000,820000-821000                                        M0099  00360021
*        RELEASE 21.8 CHANGES                                           00360221
*C771000                                                        SA69293 00360421
*        VS1 RELEASE 3.1 CHANGES                                        00362021
* XA04505 IS FLAGGED AS SA69293.                                XA04505 00362221
*A691220-691240                                                 XA04946 00362421
*C022000,691350-691400                                          XA04946 00362621
*D108200-108600                                                 XA04946 00362821
*A035500                                                         X03962 00363121
*C001000,771000,816000                                           X03962 00363221
*D105000,137000,156000,159000-160000,164000,169000,171000        X03962 00363421
*D336000-341000,394000-399000,481000-485000,544000-548000        X03962 00363621
*D763000,777000,787000                                           X03962 00363821
* STATUS CHANGE LEVEL 005                                               00800021
*FUNCTION/OPERATION - WHEN VERIFICATION IS REQUIRED DISPLAY THE IMAGE   00900020
*                     RETRIEVED FOR VISUAL VERIFICATION                 01000020
*                   - DISPLAY MESSAGE IEC121 TO REQUEST OPERATOR VERIFY 01100020
*                     THE IMAGE PRINTED                                 01200020
*                   - ANALYZE REPLY MADE BY AN OPERATOR                 01300021
*                   - UPDATE UCB TO REFRECT THE STATUS OF UCS IMAGE IN  01400020
*                     THE BUFFER.                                       01500020
*                   - CLOSE SYS1.IMAGELIB DCB IF PRINTER IS 1403.       01600021
*                   - DETERMINE NEXT OPEN EXECUTOR TO XCTL TO AND       01700020
*                     IF NECESSARY ISSUE IEC129 MESSAGE TO OPERATOR     01800020
*                                                                       01900020
*ENTRY POINT -ENTERED FROM IGG0191V BY USE OF XCTL MACRO                02000020
*                                                                       02100020
*INPUT - DCB ADDRESS.  FOR VS1 JES ACCESS METHOD, THIS IS AN ACB.       02200021
*      - OPEN WORK AREA ADDRESS                                         02300020
*      - WHERE-TO-GO TABLE                                              02400020
*      - PARAMETER LIST                                                 02500020
*      - CURRENT ENTRY IN W-T-G TABLE                                   02600020
*      - CURRENT PARAMETER(DCB)                                         02700020
*      - THE ADDRESS OF UCS IMAGE RETRIEVED                             02800020
*                                                                       02900020
*OUTPUT - PRINT OUT UCS IMAGE WHEN VERIFY IS SPECIFIED                  03000020
*       - TO REQUEST AN OPERATOR VERIFY THE IMAGE ,                     03100020
*         'IEC121D V XXX,YYYY' MESSAGE IS DISPLAYED                     03200020
*       - UPDATED UCB TO REFRECT THE STATUS OF UCS BUFFER               03300020
*       - ISSUE REQUEST FOR OPERATOR TO SPECIFY FCB IMAGE               03400020
*         'IEC129D XXX,SPECIFY FCB PARAMETERS' MESSAGE                  03500020
*       - ADDRESS OF SYS1.IMAGELIB IN OPEN WORKAREA(DXCCW8)             03550021
*                                                                       03600020
*EXTERNAL ROUTINES - NONE.                                              03700020
*                                                                       03800020
*EXIT - NORMAL - XCTL TO ONE OF THE FOLLOWINGS.                         03900020
*               *IGG0197E IF AN FCB IMAGE IS TO BE LOADED               04000020
*               *IGG0197F IF ALIGNMENT OF FORMS IS SPECIFIED            04100020
*               *THE LAST LOAD OF OPEN ROUTINE IF DCB IS EXCP OR ACB.   04200021
*               *IGG0191I IF BUFFER CNTRL BLOCK IS SPECIFIED.           04300020
*               *IGG0191G IF NORMAL SCHEDULING IS SPECIFIED.            04400020
*               *IGG0191Q IF CHAINED SCHEDULING IS SPECIFIED.           04500020
*                                                                       04600020
*EXIT - ERROR - ABEND SVC (SVC 13) IS ISSUED WHEN ONE OF THE FOLLOWINGS 04700020
*               OCCURS.COMPLETION CODE=B13 AND RETURN CODE IN REG.15.   04800020
*              *PERMANENT I/O ERROR OCCURED DURING VERIFICATION         04900020
*               RETURN CODE=10                                          05000020
*              *OPERATOR ISSUED CANCEL FOR MESSAGE IEC121.              05100020
*               RETURN CODE=14                                          05200020
*                                                                       05300020
*TABLES/WORK AREAS - WHERE-TO-GO TABLE (SEE LISTING OF EXECUTOR         05400020
*                                       IGG0191B)                       05500020
*                  - OPEN WORK AREA (SEE IECDSECT IN THIS LISTING)      05600020
*                                                                       05700020
*ATTRIBUTES - REENTRANT,REUSABLE,REFRESHABLE,SUPERVISOR MODE            05800021
*                                                                       05900020
*NOTES - EXCP/WAIT SVCS ARE USED TO WRITE IMAGES ON PRINTER FOR VERFY   06000020
*      - DELETE SVC IS USED TO DELETE THE RETRIEVED IMAGE.              06100020
*      - WTOR SVC IS USED TO REQUEST OPERATOR REPLY                     06200020
*      - IOB/ECB IN OPEN WORK AREA IS USED FOR EXCP                     06300020
*      - THE REPLY IS ORED TO ALLOW LOWER CASE ALPHA                    06400020
*                                                                       06500020
*********************************************************************** 06600020
*                                                                       06700020
         EJECT                                                          06800020
*                                                                       06900020
*********************************************************************** 07000020
*                                                                       07100020
*   REGISTER CONVENTIONS USED THROUGH OUT ALL OPEN PASSES               07200020
*                                                                       07300020
*********************************************************************** 07400020
*                                                                       07500020
*                                                                       07600020
RE       EQU   0                        WORK/PARAMETER REGISTER         07700020
RF       EQU   1                        WORK/PARAMETER REGISTER         07800020
RDCB     EQU   2                        ADDR OF USER'S DCB              07900020
RBASE    EQU   3                        BASE REGISTER                   08000020
RCORE    EQU   4                        ADDR OF OPEN WORK AREA          08100020
RPAR     EQU   5                        PARAMETER LIST                  08200020
RWTG     EQU   6                        START OF WTG                    08300020
RPARC    EQU   7                        CURRENT ENTRY IN PARAMETER LIST 08400020
RWTGC    EQU   8                        CURRENT ENTRY IN WTG TABLE      08500020
RTIOT    EQU   9                        TIOT ADDR/WORK REGISTER         08600020
RUCB     EQU   10                       UCB ADDR/WORK REGISTER          08700020
RDEB     EQU   11                       DEB ADDR                        08800020
RB       EQU   12                       WORK REGISTER/BREG FOR DSECT    08900020
RC       EQU   13                       WORK REGISTER                   09000020
RD       EQU   14                       WORK/PARAMETER REGISTER         09100020
RJ       EQU   15                       WORK/PARAMETER REGISTER         09200020
*                                                                       09300020
*********************************************************************** 09400020
*                                                                       09500020
*                                                                       09600020
*   EQUATE WTG OFFSET                                                   09700020
*                                                                       09800020
WGOFF    EQU   8                        OFFSET OF CURRENT WTG ENTRIES   09900020
PLOFF    EQU   4                        OFFSET OF CURRENT DCB ENTRIES   10000020
WAOFF    EQU   32                       OFFSET OF 1ST ENTRY IN WTG TBL  10100020
*                                                                       10200020
*   EQUATES FOR INTERNAL ABEND CODES                                    10300021
*                                                                       10400020
OABD067  EQU   67                       OPEN INTERNAL CODE 67    M0099  10600021
OABD068  EQU   68                       OPEN INTERNAL CODE 68    M0099  10700021
*                                                                       10800020
PCIMASK  EQU   X'20'                    OPTCD=PCI SPECIFIED             10900020
BFCNTRL  EQU   X'01'                    BUFFER CNTRL BLOCK SPECIFIED    11000020
EXCPMASK EQU   X'80'                   OPEN FOR EXCP MASK               11100020
NULL     EQU   X'00'                    X'00'                           11200020
SILIMASK EQU   X'60'                    C.C. AND SILI ON                11300020
ONEMASK  EQU   X'01'                    X'01'                           11400020
STGETWO EQU   X'C7'                     ENTRY FLAG FOR 197F       M1803 11500021
PRTM3211 EQU   X'09'                    MASK FOR 3211 PRINTER           11600020
IEC129RQ EQU   X'02'                    MESSAGE IECU29D REQUIRED MASK   11700020
UCSIDOFS EQU   X'00'                    UCS OFFSET FROM START UCB WK AR 11800020
UCSOPOFS EQU   X'04'                    UCS OPTIONS OFFSET              11900020
FCBALIGN EQU   X'04'                    ENTRY FOR ALIGNY ONLY MASK      12000020
NOFCB    EQU   X'F0'                    NO FCB LOAD REQUIRED            12100020
RETRYMSK EQU   X'80'                   MASK FOR COMMAND RETRY ON        12200020
BUFPARMK EQU   X'04'                    BUFFER PARITY ERROR MASK        12300020
SNSBYTE1 EQU   X'01'                    OFFSET TO SENSE BYTE1           12400020
SNSBYTE0 EQU   X'00'                    OFFSET TO SENSE BYTE0           12500020
BUFPARER EQU   X'01'                    UCS OPTION BIT FOR PARITY ERR   12600020
CMDSKP0  EQU   X'83'                    SKIP TO CH 0 COMMAND CODE       12700020
TWOMASK  EQU   X'02'                    X'02'                           12800020
FOLDMASK EQU   X'40'                    LOAD MODE = FOLD                12900020
RESETMSK EQU   X'CF'                    RESET VERIFY                    13000020
SKIPCCW  EQU   X'8B'                    CCW = SKIP TO CH 1              13100020
CNLNGTH  EQU   X'3B'                    LENGTH OF HEADING LINE          13200020
SILLCCW  EQU   X'20'                    SILI BIT ON                     13300020
WRITECCW EQU   X'11'                    CCW = WRITE 2 SPACE             13400020
UNRLBMSK EQU   X'02'                    IOB IS UNRELATED                13500020
MSSG27   EQU   X'1B'                    MESSAGE LENGTH                  13600020
COREMASK EQU   X'04'                    CORE TRANSFER                   13800020
BLANKS   EQU   X'40'                    C' '                            13900020
ABENDBIT EQU   X'80'                    ABEND ROUTINE IN PROCESS        14000020
IMCLOSED EQU   X'FF'                    FLAG SET FOR IMAGELIB NOT OPEN  14100020
*                                                                  DM0Q 14200020
*    EQUATES FOR CONSTANTS                                         DM0Q 14300020
*                                                                  DM0Q 14400020
X7F      EQU   X'7F'                    COMPLETION CODE FLAG            14500020
K0       EQU   0                        CONSTANT EQUATED TO 0           14600020
K1       EQU   1                        CONSTANT EQUATED TO 1           14700020
K2       EQU   2                        CONSTANT EQUATED TO 2           14800020
K3       EQU   3                        CONSTANT EQUATED TO 3           14900020
K4       EQU   4                        CONSTANT EQUATED TO 4           15000020
K5       EQU   5                        CONSTANT EQUATED TO 5           15100020
K6       EQU   6                        CONSTANT EQUATED TO 6           15200020
K7       EQU   7                        CONSTANT EQUATED TO 7           15300020
K8       EQU   8                        CONSTANT EQUATED TO 8           15400020
K10      EQU   10                       CONSTANT EQUATED TO 10          15500020
K14      EQU   14                       CONSTANT EQUATED TO 14          15700020
K15      EQU   15                       CONSTANT EQUATED TO 15          15800020
K25      EQU   25                       CONSTANT EQUATED TO 25          16100020
K27      EQU   27                       CONSTANT EQUATED TO 27          16200020
K31      EQU   31                       CONSTANT EQUATED TO 31          16300020
K32      EQU   32                       CONSTANT EQUATED TO 32          16500020
K35      EQU   35                       CONSTANT EQUATED TO 35          16600020
K36      EQU   36                       CONSTANT EQUATED TO 36          16700020
K37      EQU   37                       CONSTANT EQUATED TO 37          16800020
K58      EQU   58                       CONSTANT EQUATED TO 58          17000020
*                                                                       17200020
*********************************************************************** 17300020
*                                                                       17400020
*                                                                       17500020
*                                                                       17600020
*********************************************************************** 17700020
*                                                                       17800020
*   HOUSE KEEPING                                                       17900020
*                                                                       18000020
*********************************************************************** 18100020
*                                                                       18200020
         BALR  RBASE,K0                 SET UP BASE REGISTER            18300020
         USING GOGOGO,RBASE                                             18400020
         USING IHADCB,RDCB                                              18500020
         USING FORCORE,RCORE                                            18600020
         USING DEB,RDEB                                                 18700020
         USING UCBOB,RUCB                                               18800020
*                                                                       18900020
*********************************************************************** 19000020
*                                                                       19100020
GOGOGO   EQU   *                                                        19200020
*                                                                       19300020
*********************************************************************** 19400020
*                                                                       19500020
*   INITIALIZE REGISTERS                                                19600020
*                                                                       19700020
*********************************************************************** 19800020
*                                                                       19900020
         L     RDCB,K0(RPARC)           LOAD CURRENT DCB ADDR           20000020
         L     RCORE,K4(RWTGC)          LOAD CURRENT WORK AREA ADDR     20100020
         AIF   ('&LIB' NE 'LIB1').DEBCK10                        YM0890 20150001
         L     RDEB,DCBDEBAD            LOAD DEB ADDR                   20200020
.DEBCK10 ANOP                                                    Y01021 20250000
         AIF   ('&LIB' EQ 'LIB1').DEBCK20                        YM0890 20260001
         L     RDEB,DXPDEBAD            LOAD PROTECTED DEB ADDR  Y01021 20270000
.DEBCK20 ANOP                                                    Y01021 20280000
         L     RUCB,DEBUCBAD            LOAD UCB ADDR                   20300020
*                                                                       20400020
*                                                                       20500020
*                                                                       20600020
*                                                                       20700020
*********************************************************************** 20800020
*                                                                       20900020
VRFYUCS  EQU   *                                                        21000020
*                                                                       21100020
*********************************************************************** 21200020
*                                                                       21300020
*   INITIALIZE REGISTERS FOR VERIFICATION                               21400020
*                                                                       21500020
*********************************************************************** 21600020
*                                                                       21700020
         SR    RTIOT,RTIOT              RESET REGISTER                  21800020
         IC    RTIOT,ONEMASK(RB)        INSERT NO. OF LINES             21900020
*                                                                       22000020
         LTR   RTIOT,RTIOT              TEST IF NO VERIFICATION         22100020
         BC    K8,UPDTUCB               IF NOT,GOTO UPDATE UCB ROUTINE  22200020
*                                                                       22300020
         LA    RC,TWOMASK(RB)           OBTAIN 1ST NO. OF CHAR/LINE     22400020
         LR    RD,RC                    OBTAIN UCS IMAGE ADDR           22500020
         AR    RD,RTIOT                 ADD NO. OF LINES TO GET IMAGE   22600020
*                                                                       22700020
*********************************************************************** 22800020
*                                                                       22900020
*   EXCP TO DISPLAY HEADING 'UCS IMAGE VERIFICATION - YYYY'             23000020
*                                                                       23100020
*********************************************************************** 23200020
*                                                                       23300020
*   CONSTRUCT CCW  TO SKIP TO NEW LINE                                  23400020
*                                                                       23500020
         MVI   DXCCW1+K7,ONEMASK        MOVE LENGTH=1                   23600020
         MVI   DXCCW1+K4,SILIMASK       SET SILI AND CC ON              23700020
         MVI   DXCCW1,SKIPCCW           SET COMMAND CODE=SKIP TO CH 1   23800020
*                                                                       23900020
*   CONSTRUCT CCW TO PRINT HEADING                                      24000020
*                                                                       24100020
         MVI   DXCCW2+K7,CNLNGTH        STORE LENGTH OF HEADING LINE    24200020
         MVI   DXCCW2+K4,SILLCCW        SET SILI FLAG ON                24300020
*                                                                       24400020
         LA    RE,MESSAGEA              LOAD PRINT AREA ADDR            24500020
         ST    RE,DXCCW2                STORE DATA ADDR=MESSAGE         24600020
         MVI   DXCCW2,WRITECCW          PRINT A LINE - 2 SPACES AFTER   24700020
*                                                                       24800020
*   MOVE UCS NAME TO BE PRINTED                                         24900020
*                                                                       25000020
         MVI   MESSAGEA,BLANKS          MOVE C' '                       25100020
         MVC   MESSAGEA+K1(K58),MESSAGEA RESET TO C' 'S                 25200020
         MVC   MESSAGEA+K5(K25),HEADING OVE HEADING TO WORK AREA        25300020
         MVC   MESSAGEA+K31(K4),DXCCW11+K4 MOVE UCS IMAGE ID TO DISPLAY 25400020
         LA    RDEB,PRTEXCP1            GET ADDRESS OF PRTEXCP1         25500020
         DROP  RDEB                                                     25550001
*                                                                       25600020
*   TEST IF FOLD MODE                                                   25700020
*                                                                       25800020
         TM    DXCCW11+K3,FOLDMASK      TEST IF FOLD MODE IS SPECIFIED  25900020
         BC    K14,WRITEGO              IF NOT,GOTO WRITEGO ROUTINE     26000020
*                                                                       26100020
         MVC   MESSAGEA+K36(K5),FOLDMODE MOVE ',FOLD' TO HEADING        26200020
*                                                                       26300020
*                                                                       26400020
WRITEGO  EQU   *                                                        26500020
*                                                                       26600020
*                                                                       26700020
*   EXCP/WAIT                                                           26800020
*                                                                       26900020
         LA    RF,DXIOB                 LOAD IOB ADDR                   27000020
         EXCP  (1)                      EXCP ON PRINT HEADING           27100020
*                                                                       27200020
         LA    RF,DXECB                 LOAD ECB ADDR                   27300020
         WAIT  ECB=(1)                  WAIT ON ABOVE EXCP              27400020
*                                                                       27500020
*   TEST COMP.CODE.IF THERE IS I/O ERROR GOTO ABEND.                    27600020
*                                                                       27700020
         TM    DXECB,X7F                TEST IF COMP.CODE=X7F           27800020
         BNO   CKRTYERR                 IF NOT GO CK FOR RETRYABLE ERR  27900020
*                                                                       28000020
*                                                                       28100020
         BR    RDEB                     BRANCH TO ADDRESS IN REG 11     28200020
*                                                                       28300020
*********************************************************************** 28400020
*                                                                       28500020
PRTEXCP1 EQU   *                                                        28600020
*                                                                       28700020
*********************************************************************** 28800020
*                                                                       28900020
*   EXCP ON PRINTER TO PRINT UCS SET                                    29000020
*                                                                       29100020
*********************************************************************** 29200020
*                                                                       29300020
*   CONSTRUCT CCW TO EXCP                                               29400020
*                                                                       29500020
         MVI   IOBFLAG1,UNRLBMSK        SET UNRELATED BIT ON            29600020
         SR    RDEB,RDEB                ZERO OUT REG 11                 29700020
         IC    RDEB,NULL(RC)            INSERT # CHARACTER PER LINE     29800020
*                                                                       29900020
WRITEUCS EQU   *                                                        30000020
*                                                                       30100020
         ST    RD,DXCCW1                STORE UCS WORK AREA ADDR IN CCW 30200020
         ST    RDEB,DXCCW1+K4           STORE RECORD LENGTH IN CCW      30300020
         MVI   DXCCW1+K4,SILLCCW        SET SILI ON                     30400020
         MVI   DXCCW1,WRITECCW          SET COMMAND CODE=PRINT/2 SPACE  30500020
*                                                                       30600020
*   GO ISSUE EXCP TO WRITE A LINE                                       30700020
*                                                                       30800020
         BAL   RDEB,WRITEGO             GO ISSUE EXCP                   30900020
*                                                                       31000020
         SR    RDEB,RDEB                ZERO OUT REG UU                 31100020
         IC    RDEB,NULL(RC)            INSERT = CHARACTERS/LINE        31200020
*                                                                       31300020
         AR    RD,RDEB                  MODIFY UCSWORK AREA             31400020
         LA    RC,ONEMASK(RC)           INCREMENT REG. BY 1             31500020
         IC    RDEB,NULL(RC)            INSERT NO. OF CHAR/LINE         31600020
*                                                                       31700020
         BCT   RTIOT,WRITEUCS           REPEAT N=RTIOT TIMES.           31800020
*                                                                       31900020
*                                                                       32000020
*********************************************************************** 32100020
*                                                                       32200020
*   SKIP TO NEW PAGE                                                    32300020
*                                                                       32400020
*********************************************************************** 32500020
*                                                                       32600020
         MVI   DXCCW1+K7,ONEMASK        MOVE LENGTH = 1                 32700020
         MVI   DXCCW1,SKIPCCW           SET COMMAND CODE  = SKIP        32800020
*                                                                       32900020
*   GO ISSUE EXCP TO SKIP TO CHANNEL 1                                  33000020
*                                                                       33100020
         BAL   RDEB,WRITEGO             GO ISSUE SKIP TO CH 1 CCW       33200020
*                                                                       33300020
*                                                                       33400020
*********************************************************************** 33500020
*   WTOR 'IEC121D V XXX,YYYY' TO REQUEST OPERATOR REPLY                 34200020
*                                                                       34300020
*********************************************************************** 34400020
*                                                                       34500020
*                                                                       34600020
*                                                                       34700020
         MVC   MSGLSTSZ(K27),DSPLY121   MOVE MESSAGE TEXT               34800020
         MVC   MESSAGEA+K10(K3),UCBNAME MOVE DEV. NAME                  34900020
         MVC   MESSAGEA+K14(K4),DXCCW11+K4 MOVE UCS IMAGE ID TO DISPLAY 35000020
*                                                                       35100020
         TM    DXCCW11+K3,FOLDMASK      TEST IF LOAD MODE IS FOLD       35200020
         BC    K14,MSGGOGO              IF NOT,GOTO MESSAGE ROUTINE     35300020
*                                                                       35400020
         MVI   MSGLSTSZ+K1,MSSG27       SET MESSAGE LENGTH = 27         35500020
*                                                                       35600020
MSGGOGO  EQU   *                                                        35700020
*                                                                       35800020
         SR    RF,RF                                               DM0Q 35900020
         IC    RF,MSGLSTSZ+K1           INSERT MESSAGE LENGTH      DM0Q 36000020
         LA    RF,MSGLSTSZ(RF)                                     DM0Q 36100020
         MVC   K0(K4,RF),CODE121D       MOVE IN DESC, ROUT CODES   DM0Q 36200020
MESSAGO  EQU   *                                                   DM0Q 36300020
         LA    RF,REPLYLTH              LOAD ADDR OF PARM LIST          36400020
         XC    RPLY(24),RPLY            CLEAR REPLY AREA AND ECB M5143  36500020
*                                                                       36700020
         SVC   K35                      ISSUE WTO SVC                   36800020
*                                                                       36900020
         LA    RF,RPLYECB               GET ADDRESS OF REPLY ECB M5143  37000020
         WAIT  ECB=(1)                  WAIT FOR WTOR                   37100020
*                                                                       37200020
*   REPLY ANALYSIS                                                      37300020
*                                                                       37400020
         OC    RPLY(K8),LOMASK          OR TO ALLOW LOWER CASE   M5143  37500020
*                                       ALPHA                    M5143  37600020
         CLC   RPLY(K5),RETRYCN         TEST IF REPLY='RETRY '   M5143  37700020
         BC    K8,VRFYUCS               IF YES GO BACK TO RE-VERIFY     37800020
         CLC   RPLY(K6),CANCELCN        TEST IF REPLY='CANCEL '  M5143  37900020
         BC    K8,ABEND04               IF YES,GO ABEND                 38000020
*                                                                       38100020
*                                                                       38200020
         CLC   RPLY(K8),OKCN            TEST IF REPLY='VERIFIED  M5143  38260020
*                                       '                        M5143  38320020
         BC    K8,UPDTUCB               IF YES GO UPDATE UCB            38400020
*                                                                       38500020
         CLC   RPLY(K2),RBLANK          TEST IF REPLY='R '       M5143  38600020
         BC    K8,VRFYUCS               IF YES GO VERIFY UCS IMAGE      38700020
*                                                                       38800020
         CLC   RPLY(K2),CBLANK          TEST IF REPLY='C '       M5143  38900020
         BC    K8,ABEND04               IF YES GOTO ABEND ROUTINE       39000020
*                                                                       39100020
         CLC   RPLY(K2),VBLANK          TEST IF REPLY='V '       M5143  39200020
         BC    K8,UPDTUCB               IF YES GO UPDATE UCB            39300020
*********************************************************************** 40000020
*                                                                       40100020
*   WTO 'IEC706I ERROR - REPEAT REPLY'                                  40200020
*                                                                       40300020
*********************************************************************** 40400020
*                                                                       40500020
         MVC   MSGLSTSZ(K32),DSPLY125   MOVE MESSAGE TEXT TO WORK AREA  40600020
         MVC   MSGLSTSZ+K32(K4),CODE125I MOVE IN DESC, ROUT CODES  DM0Q 40700020
*                                                                       40800020
         B     MESSAGO                  GO BACK TO WTOR ROUTINE    DM0Q 40900020
*                                                                       41000020
*********************************************************************   41100020
*                                                                       41200020
*   ROUTINE TO CHECK FOR RETRYABLE ERROR AND SKIP TO 0 TO RESET         41300020
*   THE CONTROL UNIT 2811                                               41400020
*                                                                       41500020
*********************************************************************   41600020
*                                                                       41700020
CKRTYERR EQU   *                                                        41800020
*                                                                       41900020
         CLI   UCBTBYT4,PRTM3211        CK IF DCB BEING OPENED FOR 3211 42000020
         BNE   ABEND10                  NO GO SET RC=10 AND ABEND       42100020
         L     RJ,UCBNBRSN              GET ADDR OF SENSE BYTES         42200020
         TM    SNSBYTE1(RJ),RETRYMSK    CK FOR RETRYABLE ERROR          42400020
         BNO   ABEND10                  NO GO SET RC=10 AND ABEND       42500020
         TM    SNSBYTE0(RJ),BUFPARMK    CK FOR BUFFER PARITY ERROR      42600020
         BNO   SKIPCH0                  NO GO SKIP CH 0                 42700020
         L     RJ,UCBXTADR              YES GET ADDR OF UCB EXTENTION   42800020
         OI    UCSOPOFS(RJ),BUFPARER    SET UCS BUF PARITY ERR BIT      42900020
*                                                                       43000020
SKIPCH0 EQU    *                                                        43100020
*                                                                       43200020
         MVI   DXCCW1+K7,ONEMASK        SET LENGTH FIELD TO 1           43300020
         MVI   DXCCW1+K4,SILLCCW        SET SILI                        43400020
         MVI   DXCCW1,CMDSKP0           MOVE IN SKIP TO 0 COMMAND CODE  43500020
         LA    RF,DXIOB                 GET ADDR FOR EXCP               43600020
         EXCP  (1)                      ISSUE EXCP TO SKIP TO CH 0      43700020
*                                                                       43800020
*********************************************************************** 43900020
*                                                                       44000020
ABEND10  EQU   *                                                        44100020
*                                                                       44200020
*********************************************************************** 44300020
*                                                                       44400020
*   PERMANENT I/O ERROR DURING PRINTING VERIFICATION LINES.             44500020
*   RETURN CODE = X'10' IN REG. 15                                      44600020
*   IF THE I/O ERROR PERSISTS,RUN C.E. DIAGNOSTICS ON THE PRINTER       44700020
*                                                                       44800020
*********************************************************************** 44900020
*                                                                       45000020
         LA    RB,OABD067               LOAD INTERNAL CODE 67    M0099  45100021
         BC    K15,UPUCBEND             GOTO UPDATE UCB AND EXIT        45200020
*                                                                       45300020
*********************************************************************** 45400020
*                                                                       45500020
ABEND04  EQU   *                                                        45600020
*                                                                       45700020
*********************************************************************** 45800020
*                                                                       45900020
*   REQUESTED CHAIN SET WAS NOT AVAILABLE. JOB STEP WAS CANCELLED BY    46000020
*   AN OPERATOR. RETURN CODE = X'14' IN REG.15                          46100020
*   RERUN THE JOB WITH THE CORRECT CHAIN/TRAIN                          46200020
*                                                                       46300020
*********************************************************************** 46400020
*                                                                       46500020
         LA    RB,OABD068               LOAD INTERNAL CODE 68    M0099  46600021
*                                                                       46700020
*********************************************************************** 46800020
*                                                                       46900020
UPUCBEND EQU   *                                                        47000020
*                                                                       47100020
*********************************************************************** 47200020
*                                                                       47300020
*   UPDATE THE UCB WITH X'00' TO INDICATE THAT THE IMAGE IN THE BUFFER  47400020
*   IS NOT USABLE                                                       47500020
*                                                                       47600020
*********************************************************************** 47700020
*                                                                       47800020
         L     RJ,UCBXTADR              GET ADDRESS OF UCB EXTENTION    47900020
         XC    NULL(K5,RJ),NULL(RJ)     RESET UCS ID/OPT IN UCB         48000020
*********************************************************************** 48600020
*                                                                       48700020
*   TEST IF UCS IMAGE IS CORE TRANSFERED                                48800020
*                                                                       48900020
*********************************************************************** 49000020
*                                                                       49100020
         TM    DXCCW11,COREMASK         TEST IF CORE TRANSFER IS ON     49200020
         BC    K1,ABENDRTN              IF YES,GOTO ABEND ROUTINE       49300020
*                                                                       49400020
*********************************************************************** 49500020
*                                                                       49600020
DELETE   EQU   *                                                        49700020
*                                                                       49800020
*********************************************************************** 49900020
*                                                                       50000020
*   DELETE THE UCS IMAGE LOADED                                         50100020
*                                                                       50200020
*********************************************************************** 50300020
*                                                                       50400020
         LA    RE,DXCCW6                LOAD ADDR OF IMAGE ID LOADED    50500020
         DELETE EPLOC=(0)                                               50600020
*                                                                       50700020
*********************************************************************** 50800020
*                                                                       50900020
ABENDRTN EQU   *                                                        51000020
*                                                                       51100020
*********************************************************************** 51200020
*                                                                       51300020
*   ABEND ROUTINE.COMPLETION CODE=B13.RETURN CODE IS IN REG15.          51400020
*                                                                       51500020
*********************************************************************** 51600020
*                                                                       51700020
         TM    DXCCW11+K2,ABENDBIT      TEST IF ABEND IS IN PROCESS     51800020
         BC    K1,UCSEXIT               IF YES,GOTO EXIT ROUTINE        51900020
*                                                                       52000020
         DMABCOND (RB),PDLOAD,RETURN=NONE,RES=NO,REGSAVE=YES     M0099  52200021
         B     TCTLRTN                                           M0099  52400021
*                                                                       52600020
*********************************************************************** 52700020
*                                                                       52800020
*********************************************************************** 52900020
*                                                                       53000020
UPDTUCB  EQU   *                                                        53100020
*                                                                       53200020
*********************************************************************** 53300020
*                                                                       53400020
*   UPDATE UCB - UCS FIELDS                                             53500020
*                                                                       53600020
*********************************************************************** 53700020
*                                                                       53800020
         L     RJ,UCBXTADR              GET ADDRESS OF UCB EXTENTION    53900020
         MVC   UCSIDOFS(K4,RJ),DXCCW11+K4 MOVE UCS IMAGE ID INTO UCB    54000020
         MVC   UCSOPOFS(K1,RJ),DXCCW11+K3 MOVE UCS OPTION BITS TO UCB   54100020
         OC    UCSOPOFS(K1,RJ),NULL(RB) SET DEFAULT BIT IF ANY          54200020
         NI    UCSOPOFS(RJ),RESETMSK    RESET VERIFY IF ANY             54300020
*********************************************************************** 54900020
*                                                                       55000020
*   TEST IF UCS IMAGE IS CORE TRANSFERED                                55100020
*                                                                       55200020
*********************************************************************** 55300020
*                                                                       55400020
         MVI   DXCCW10+K1,NULL          RESET FCB SWITCH                55500020
         TM    DXCCW11,COREMASK         TEST IF CORE TRANSFER IS ON     55600020
         BC    K1,UCSEXIT               IF YES,GOTO EXIT ROUTINE        55700020
*                                                                       55800020
*********************************************************************** 55900020
*                                                                       56000020
*   DELETE UCS IMAGE                                                    56100020
*                                                                       56200020
*********************************************************************** 56300020
*                                                                       56400020
         LA    RE,DXCCW6                LOAD ADDR OF ENTRY POINT - UCS  56500020
*                                                                       56600020
         DELETE EPLOC=(0)               DELETE UCS IMAGE                56700020
*                                                                       56800020
*********************************************************************** 56900020
*                                                                       57000020
*********************************************************************** 57100020
*                                                                       57200020
UCSEXIT  EQU   *                                                        57300020
*                                                                       57400020
         TM    DXCCW10,NOFCB            CK IF FCB LOAD REQUIRED         57500020
         BO    RESTERPT                 NO GO RESET EROPT               57600020
         TM    DXCCW10,IEC129RQ         CK IF IEC129 MESSAGE REQUIRED   57700020
         BO    ISSUE129                 YES GO ISSUE IEC129 MESSAGE     57800020
         TM    DXCCW10,FCBALIGN         CK IF ALIGN FORMS SPECIFIED     57900020
         BO    XCTL197F                 YES GO ALIGN FORMS IN IGG0197F  58000020
         B     XCTL197E                 NO GO LOAD FCBIN IGG0197)       58100020
*                                                                       58200020
**********************************************************************  58300020
*                                                                       58400020
*        ISSUE MESSAGE IEC129 AND XCTL TOIGG0197E                       58500020
*                                                                       58600020
**********************************************************************  58700020
*                                                                       58800020
ISSUE129 EQU   *                                                        58900020
*                                                                       59000020
         MVC   MSGLSTSZ(K37),MESAG129   MOVE MESSAGE TEXT INTO DISPLAY  59100020
         MVC   MESSAGEA+K8(K3),UCBNAME  MOVE DEVICE NAME INTO DISPLAY   59200020
         MVC   MSGLSTSZ+37(K4),CODE121D MOVE IN DESC AND ROUT    M5143  59280020
*                                       CODES                    M5143  59360020
         XC    RPLY(24),RPLY            ZERO OUT REPLY AREA AND  M5143  59440020
*                                       ECB                      M5143  59520020
         LA    RF,REPLYLTH              GET ADDR FOR WTOR               59600020
         SVC   K35                      ISSUE WTOR IEC129               59700020
*                                                                       59800020
XCTL197E EQU   *                                                        59900020
*                                                                       60000020
         LA    RF,MODNM7E               GET IDTTR ADDR OF IGG0197E      60100021
         B     MVEIDTTR                 GO TO WTG SEQ                   60200020
*                                                                       60300020
*                                                                       60400020
SETGETM  EQU   *                                                        60500020
*                                                                       60600020
         MVI   DXCCW10+K2,STGETWO       TURN ON FLAG FOR IGG0197F M1803 60700021
XCTL197F EQU   *                                                        60800020
*                                                                       60900020
         LA    RF,MODNM7F               GET ADDR OF IDTTR OF IGG0197F   61000020
         B     MVEIDTTR                 GO TO WTG SEQ                   61100020
*********************************************************************** 61200020
*                                                                       61300020
*   RESTORE DCB EROPT                                                   61400020
*                                                                       61500020
*********************************************************************** 61600020
*                                                                       61700020
RESTERPT EQU   *                                                        61800020
*                                                                       61900020
         CLI   UCBTBYT4,PRTM3211        CK IF DCB BEING OPENED FOR 3211 62000020
         BE    SETGETM                  IF SO SET ENTRY SWITCH    M1803 62100021
         MVC   DXCCW6(K1),DXCCW11+K1    MOVE IN DCB EROPT               62200020
*                                                                       62300020
*   SEE IF SYS1.IMAGELIB HAS BEEN OPENED IF YES CLOSE IT                62400020
         CLI   DXCCW8,IMCLOSED          CK IF IMAGEDLIB CLOSED          62500020
         BE    TSTEXCP                  IF NOT GO TEST IF EXCP SPECIFED 62600020
         L     RF,DXCCW8                GET ADDRESS OF IMAGELIB DCB     62700020
         SVC   105                      ISSUE SVC TO CLOSE SYS1.IMAGELI 62800020
*                                                                       62900020
*                                                                       63000020
*********************************************************************** 63100020
*                                                                       63200020
*   DETERMINE THE NEXT STAGE 2 EXECUTOR TO BE XCTLED                    63300020
*                                                                       63400020
*********************************************************************** 63500020
*                                                                       63600020
TSTEXCP  EQU   *                                                        63700020
*                                                                       63800020
*********************************************************************** 63900020
*                                                                       64000020
*   TEST IF EXCP IS SPECIFIED.IF YES,XCTL TO THE LAST OPEN EXECUTOR     64100020
*                                                                       64200020
*********************************************************************** 64300020
*                                                                       64400020
         TM    DCBMACRF,EXCPMASK        TEST IF EXCP IS SPECIFIED       64500020
         BC    K14,TSTBLKBF             IF NOT,GOTO BUFFER CNTRL BLK    64600020
*                                                                       64700020
         MVI   K0(RWTGC),NULL           IF YES,ZERO NAME FIELD          64800020
         BC    K15,RELOOP               GOTO WTG TABLE UPDATE           64900020
*                                                                       65000020
*********************************************************************** 65100020
*                                                                       65200020
TSTBLKBF EQU   *                                                        65300020
*                                                                       65400020
*********************************************************************** 65500020
*                                                                       65600020
*   TEST IS BUFFER CONTROL BLOCK IS SPECIFIED.IF YES,XCTL TO IGG0911I   65700020
*                                                                       65800020
*********************************************************************** 65900020
*                                                                       66000020
         TM    DCBBUFNO+K3,BFCNTRL      BUFFER CONTROL BLOCK SPECIFIED  66100020
         BC    K14,TSTPCI               IF YES,GOTO TEST PCI ROUTINE    66200020
*                                                                       66300020
         SR    RE,RE                    RESET REGISTER                  66400020
         IC    RE,DCBBUFNO              GET THE NO OF BUFFER SPECIFIED  66500020
         LTR   RE,RE                    TEST IF DCBBUFNO='0'            66600020
         BC    K8,TSTPCI                IF YES,GOTO TEST PCI            66700020
*                                                                       66800020
         LA    RF,MODNM1I               LOAD ADDR OF IDTTR OF IGG0191I  66900020
         BC    K15,MVEIDTTR             GOTO MOVE IDTTR ROUTINE         67000020
*                                                                       67100020
*********************************************************************** 67200020
*                                                                       67300020
TSTPCI   EQU   *                                                        67400020
*                                                                       67500020
         AIF   ('&LIB' EQ 'LIB1').LIB1AA                                67505001
*********************************************************************** 67510001
*                                                                       67515001
*    TEST FOR VIRTUAL=REAL.  PCI IS ONLY HONORED FOR V=R.               67520001
*                                                                       67525001
*********************************************************************** 67530001
*                                                                       67535001
         L     RDEB,DXPDEBAD            LOAD PROTECTED DEB ADDR  Y01021 67540000
         USING DEB,RDEB                                                 67545001
         L     RF,DEBTCBAD              GET TCB POINTER                 67550001
         USING TCB,RF                                                   67555001
         TM    TCBFLGS6,TCBRV           TEST FOR REAL PARTITION         67560001
         BZ    BQSAMOUT                 BRANCH IF VIRTUAL               67565001
         DROP  RF                                                       67570001
*                                                                       67575001
.LIB1AA  ANOP                                                           67580001
*********************************************************************** 67600020
*                                                                       67700020
*   TEST IF PCI IS SPECIFIED.IF YES,XCTL TO IGG0191Q                    67800020
*                                                                       67900020
*********************************************************************** 68000020
*                                                                       68100020
         TM    DCBOPTCD,PCIMASK         TEST IF PCI SPECIFIED           68200020
         BC    K14,BQSAMOUT             IF NOT,GOTO BSAM/QSAM ROUTINEED 68300020
*                                                                       68400020
         LA    RF,MODNM1Q               LOAD ADDR OF IDTTR OF IGG0191Q  68500020
         BC    K15,MVEIDTTR             GOTO MOVE IDTTR ROUTINE         68600020
*                                                                       68700020
*********************************************************************** 68800020
*                                                                       68900020
BQSAMOUT EQU   *                                                        69000020
*                                                                       69100020
         AIF   ('&LIB' EQ 'LIB1').LIB101                         SM1830 69105021
*********************************************************************** 69110001
*                                                                     * 69115001
*   TEST FOR JES DATA MANAGEMENT * IF YES, XCTL TO OPEN.              * 69120021
*   IF JAM EVER CHANGES ITS BUFFER INTERFACE OR USES THE CHAINED      * 69122021
*   SCHEDULING BIT IN ACBOPTCD, THE FOLLOWING CODE MAY HAVE TO BE     * 69124021
*   CHANGED OR MOVED TO AN EARLIER POINT.                             * 69124421
*                                                                     * 69125001
*********************************************************************** 69130001
         TM    DCBDSRG2,DCBACBM         IS CONTROL BLOCK AN ACB XA04946 69135021
         BZ    JESOUT                   BR IF DCB TO BSAM/QSAM  XA04946 69140021
         MVI   0(RWTGC),NULL            YES * ZERO ID IN WTG TABLE      69145001
         B     RELOOP                   GO TO XCTL TO OPEN              69150001
JESOUT   EQU   *                                                        69155001
.LIB101  ANOP                                                           69160001
*********************************************************************** 69200020
*                                                                       69300020
*   BSAM/QSAM EXIT.XCTL TO IGG0191G                                     69400020
*                                                                       69500020
*********************************************************************** 69600020
*                                                                       69700020
         LA    RF,MODNM1G               LOAD ADDR OF IDTTR IF IGG0191G  69800020
*                                                                       69900020
*********************************************************************** 70000020
*                                                                       70100020
MVEIDTTR EQU   *                                                        70200020
*                                                                       70300020
*********************************************************************** 70400020
*                                                                       70500020
*   MOVE IDTTR TO XCTL WTG TABLE                                        70600020
*                                                                       70700020
*********************************************************************** 70800020
*                                                                       70900020
         MVC   K0(K5,RWTGC),K0(RF)      STORE NEXT MODULE ID IN WTG     71000020
*                                                                       71100020
*********************************************************************** 71200020
*                                                                       71300020
RELOOP   EQU   *                                                        71400020
*                                                                       71500020
*********************************************************************** 71600020
*                                                                       71700020
*   UPDATE WTG TABLE AND XCTL TO NEXT MODULE                            71800020
*                                                                       71900020
*********************************************************************** 72000020
*                                                                       72100020
         LA    RWTGC,WGOFF(K0,RWTGC)    INCREMENT CURRENT WTG ENTRY     72200020
         LA    RPARC,PLOFF(K0,RPARC)    INCREMENT CURRENT DCB ENTRY     72300020
         CLC   K0(K2,RWTGC),AMIDCNST    IS THE RTN NEEDED AGAIN         72400020
         BCR   K8,RBASE                 IF YES,RETURN TO PROCESS        72500020
*                                                                       72600020
         CLC   K0(K2,RWTGC),OPIDCNST    TEST END OF WTG TABLE           72700020
         BC    K7,RELOOP                IF NOT,CHECK NEXT ENTRY         72800020
*                                                                       72900020
         LR    RPARC,RPAR               RESET REG TO '0'                73000020
         LA    RWTGC,WAOFF(K0,RWTG)     RESET WTG REG TO POINT +32(WTG) 73100020
*                                                                       73200020
ZCHECK   EQU   *                                                        73300020
*                                                                       73400020
         CLI   K0(RWTGC),K0             TEST IF THIS ENTRY COMPLETE     73500020
         BC    K7,TCTLRTN               IF NOT,XCTL                     73600020
*                                                                       73700020
         LA    RWTGC,WGOFF(K0,RWTGC)    GET NEXT ENTRY OF WTG TABLE     73800020
         LA    RPARC,PLOFF(K0,RPARC)    GET NEXT ENTRY OF DCB           73900020
         BC    K15,ZCHECK               GOTO TEST COMPLETION            74000020
*                                                                       74100020
TCTLRTN  EQU   *                                                        74200020
*                                                                       74300020
         MVC   K6(K2,RWTG),K0(RWTGC)    STORE ID IN WTG TABLE           74400020
         MVC   K14(K3,RWTG),K2(RWTGC)   MOVE TTR INTO TABLE             74500020
         AIF   ('&LIB' EQ 'LIB1').LIB1BB                         XM5403 74550001
         MVC   24(5,RWTG),XCTLCON+2                                     74560001
.LIB1BB  ANOP                                                           74570001
*                                                                       74600020
         LA    RJ,DXXCTL                SET UP FOR XCTL          M0099  74700021
*                                                                       74800020
         XCTL  DE=(RWTG),SF=(E,(15))                                    74900020
*                                                                       75000020
*********************************************************************** 75100020
*                                                                       75200020
*********************************************************************** 75300020
*                                                                       75400020
*   CONSTANTS                                                           75500020
*                                                                       75600020
*********************************************************************** 75700020
*                                                                       75800020
*   FOR WTG TABLE                                                       75900020
*                                                                       76000020
OPIDCNST DC    C'0S'                    END OF WTG TABLE ID             76100020
XCTLCON  DC    X'C378'                  XCTL ATTR.-REENT.,REUSEABLE     76150001
*                                         NOT IN OV'LAY,NOT TEST,NOT    76160001
*                                         ONLY LOADABLE,BLOCK FORMAT,   76170001
*                                         EXECUTABLE,1 TEXT,COMPAT.,    76180001
*                                         ORIGIN AT 0,ENTRY PT.0,NO RLD 76190001
         DC    X'000400'                TOTAL LENGTH                    76192001
         DC    X'0400'                  TEXT LENGTH                     76194001
AMIDCNST DC    C'7U'                    MODULE CONSTANT                 76200021
*                                                                       76400020
*   WTO MESSAGE TEXT AND VERIFICATION HEADING                           76500020
*                                                                       76600020
DSPLY121 DC    X'00168000'              VERIFY UCS MESSAGE         DM0Q 76700020
         DC    C'IEC121D V    ,    ,FOLD'                               76800020
DSPLY125 DC    X'00208000'              ERROR REPEAT RETRY         DM0Q 76900020
         DC    C'IEC125I ERROR - REPEAT REPLY'                          77000020
MESAG129 DC    X'00258000'              FCB PARAMETER           SA69293 77100000
         DC    C'IEC129D     SPECIFY FCB PARAMETER'                     77200020
HEADING  DC    C'UCS IMAGE VERIFICATION - '                             77300020
FOLDMODE DC    C',FOLD'                                                 77400020
CODE121D DC    X'40000200'              DESCRIPTOR, ROUTING CODES  DM0Q 77500020
CODE125I DC    X'10000200'              DESC AND ROUT CODES        DM0Q 77600020
*                                                                       77800020
*   REPLY CONSTANT                                                      77900020
*                                                                       78000020
RETRYCN  DC    C'RETRY '                REPLY = 'RETRY '                78100020
CANCELCN DC    C'CANCEL '               REPLY = 'CANCEL '               78200020
OKCN     DC    C'VERIFIED '             REPLY = 'VERIFIED '             78300020
CBLANK   DC    C'C '                    REPLY = 'C'                     78400020
RBLANK   DC    C'R '                    REPLY = 'R'                     78500020
VBLANK   DC    C'V '                    REPLY = 'V'                     78600020
*                                                                       78800020
*********************************************************************** 78900020
*                                                                       79000020
*   XCTL TABLE                                                          79100020
*                                                                       79200020
*********************************************************************** 79300020
*                                                                       79400020
         AIF   ('&LIB' EQ 'LIB1').LIBXCT1                               79450021
         XCTLTABL ID=(MODNM1G,1G,MODNM1I,1I,MODNM1Q,1Q,MODNM7E,  M0099 ,79600021
               7E,                                               M0099 ,79800021
               MODNM7F,7F,PDLOAD,6M),SVC=019,LENGTH=1120        XM5403  80000001
.LIBXCT1 ANOP                                                           80010021
         AIF   ('&LIB' NE 'LIB1').LIBXCT2                               80020021
         XCTLTABL ID=(MODNM1G,1G,MODNM1I,1I,MODNM1Q,1Q,MODNM7E, SM1830 ,80050021
               7E,                                              SM1830 ,80100021
               MODNM7F,7F,PDLOAD,6M),SVC=019,LENGTH=1024        SM1830  80150021
.LIBXCT2 ANOP                                                           80200021
*                                                                       80500020
*                                                                       80600020
*********************************************************************** 80700020
*                                                                       80800020
*********************************************************************** 80900020
*                                                                       81000020
*   DSECT                                                               81100020
*                                                                       81200020
*********************************************************************** 81300020
*                                                                       81400020
*                                                                       81500020
         DCBD  DSORG=PS,DEVD=PR         EXPAND DSECT FOR PRINTER DCB    81600021
*                                                                       81700020
*********************************************************************** 81800020
*                                                                       81900020
         IECDSECS MAIN,EXPAND=YES                                M0099  82000021
         ORG   REPLYLTH+52                                       M5143  82110020
RPLY     DS    20C                                               M5143  82120020
RPLYECB  DS    F                                                 M5143  82130020
MCSMASK  DS    H                                                 M5143  82140020
LOMASK   DS    8C                                                M5143  82150020
UCSID    DS    4C                                                M5143  82160020
*                                                                       82200020
*********************************************************************** 82300020
*                                                                       82400020
SRT      DSECT                                                          82500020
         IEFUCBOB                                                       82600020
*                                                                       82700020
*********************************************************************** 82800020
*                                                                       82900020
*   DATA EXTENT BLOCK  (UNTIL PROTIOS CHANGES)                          83000020
DEB      DSECT                                                          83100020
DEBNMSUB DS    0CL1                                                     83200020
DEBTCBAD DS    CL4                                                      83300020
DEBAMLNG DS    0CL1                                                     83400020
DEBDEBAD DS    CL4                                                      83500020
DEBOFLGS DS    0CL1                                                     83600020
DEBIRBAD DS    CL4                                                      83700020
DEBOPATB DS    0CL1                                                     83800020
DEBSYSPG DS    CL4                                                      83900020
DEBNMEXT DS    0CL1                                                     84000020
DEBUSRPG DS    CL4                                                      84100020
DEBPRIOR DS    0CL1                                                     84200020
DEBECBAD DS    CL4                                                      84300020
DEBPROTG DS    0CL1                                                     84400020
DEBDEBID DS    0CL1                                                     84500020
DEBDCBAD DS    CL4                                                      84600020
DEBEXSCL DS    0CL1                                                     84700020
DEBAPPAD DS    CL4                                                      84800020
DEBDVMOD DS    0CL1                                                     84900020
DEBUCBAD DS    CL4                                                      85000020
DEBTVLSQ DS    0CL2                VOL SEQ FOR TAPE                     85100020
DEBBINUM DS    CL2                                                      85200020
DEBTVLNM DS    0CL2                NO OF VOL FOR TAPE                   85300020
DEBSTRCC DS    CL2                                                      85400020
DEBSTRHH DS    CL2                                                      85500020
DEBENDCC DS    CL2                                                      85600020
DEBENDHH DS    CL2                                                      85700020
DEBNMTRK DS    CL2                                                      85800020
*  FOR ADDITIONAL EXTENT ON DIRECT ACCESS THE FOLLOWING FIELDS          85900020
*  WILL HAVE TO BE OFFSET ANOTHER 16 BYTES                              86000020
DEBVOLSQ DS    H                                                        86100020
DEBVOLNM DS    H                                                        86200020
*  FOR EACH SUBROUTINE LOADED BUMP THIS OFFSET BY 2                     86300020
DEBSUBID DS    H                                                        86400020
*                                                                       86500020
         IKJTCB                                                         86550001
*********************************************************************** 86600020
*                                                                       86700020
         END                                                            86800020
