         MACRO                                                          00020020
&NAME    IF    &A,&IS=,&ISNOT=,&GOTO=                                   00040020
         LCLB  &NOERR                                                   00060020
&NOERR   SETB  1                                                        00080020
         AIF   ('&A' NE '').SKIP                                        00100020
         MNOTE 'TEST  ADDRESS NOT SPECIFIED.'                           00120020
&NOERR   SETB  0                                                        00140020
.SKIP    AIF   ('&GOTO' NE '').SKIP2                                    00160020
         MNOTE 'BRANCH ADDRESS MISSING.'                                00180020
&NOERR   SETB  0                                                        00200020
.SKIP2   AIF   ('&IS' NE '' OR '&ISNOT' NE '').SKIP3                    00220020
         MNOTE 'TEST CONDITION NOT SPECIFIED.'                          00240020
&NOERR   SETB  0                                                        00260020
.SKIP3   AIF   (&NOERR).SKIP4                                           00280020
         MEXIT                                                          00300020
.SKIP4   AIF   ('&IS' EQ '').NOIS                                       00320020
***                                                                     00340020
&NAME    TM    &A,&IS                                                   00360020
         BO    &GOTO                                                    00380020
***                                                                     00400020
         MEXIT                                                          00420020
.NOIS    ANOP                                                           00440021
***                                                                     00460020
&NAME    TM    &A,&ISNOT                                                00480020
         BZ    &GOTO                                                    00500020
***                                                                     00520020
         MEND                                                           00540020
IGG0199K CSECT                                                          00560020
*                                                                       00580020
         TITLE 'IGG0199K  DA, SEARCH DIRECT AND TRK OVFLOW EXEC'        00600020
* SOP6 D.A. LEVEL 2 EXECUTOR FOR BSAM/QSAM OUTPUT WITH TRACK OVFLO.     00620020
*          RELEASE 20 DELETIONS                                       * 00629020
*                                                                S20201 00629520
*          RELEASE 21 DELETIONS                                       * 00630020
*0340043000,075680,110330,120000,125000,127600-128000,132900-    S21042 00630321
*0340134000,158400-158600                                        S21042 00630621
*0000127600                                                      M1821  00630721
*D105200-105400,105800-106000                                   SA51532 00630821
*          RELEASE 22 DELETIONS                                       * 00631020
*          RELEASE 23 DELETIONS                                       * 00632020
*          RELEASE 24 DELETIONS                                       * 00633020
*STATUS CHANGE LEVEL 001                                                00636021
*                                                                       00640020
*                                                                       00660020
* THIS EXECUTOR RUNS IN TANDEM WITH IGG0191S, WHICH COMPLETES DCB       00680020
* FIELDS THAT ARE KNOWN PRIOR TO GETTING CORE FOR THE IOB/CP'S.         00700020
*                                                                       00720020
* THE MAJOR FUNCTIONS OF THIS EXEC ARE-                                 00740020
*                                                                       00760020
* 1. COMPLETE CALCULATIONS FOR THE CORE REQ'D FOR ALL IOB/CP'S.         00780020
*     GET AND CLEAR THE CORE.                                           00800020
* 2. STRUCTURE EACH IOB/CP WITH THE ADDRESSES AND FLAGS THAT ARE        00820020
*    KNOWN AT OPEN TIME.                                                00840020
* 3. COMPLETE THE RELATED DCB FIELDS.                                   00860020
* 4. REPEAT FOR EACH DCB BEING OPENED.                                  00880020
*                                                                       00900020
* ENTRY POINTS- FROM IGG0191S BY XCTL.                                  00920020
* EXITS- TO IGG01913 BY XCTL.                                           00940020
*                                                                       00960020
*                                                                       00980020
*INPUT-REGISTERS WITH THE ADDRESSES OF THE FOLLOWING-                   01000020
*   THE PARAMETER LIST  (POINTERS TO TOP AND CURRENT ENTRY).            01020020
*   THE WHERE-TO-GO TABLE (WTG) (POINTERS TO TOP AND CURRENT).          01040020
* EXTERNAL ROUTINES- NONE.                                              01060020
* ATTRIBUTES- REENTRANT AND REUSABLE.                                   01080020
* TABLES/WORKAREAS-                                                     01100020
*                                                                       01120020
*TABLES/WORKAREAS- WHERE TO GO TABLE (WTG)                              01140020
*      BYTE  0-7  NAME                                                  01160020
*      BYTE  8-10 RELATIVE DISK ADDRESS(TTR) OF FIRST RECORD            01180020
*      BYTE 11    CONCATENATION NUMBER                                  01200020
*      BYTE 12    ZERO                                                  01220020
*      BYTE 13    ALIAS INDICATOR AND USER DATA FIELD DESCRIPTOR.       01240020
*                        ALIAS INDICATOR 1 BIT                          01260020
*                        NUMBER OF TTRS IN USERS DATA FIELD 2 BITS      01280020
*      BYTE 14-16 TTR OF FIRST TEXT RECORD                              01300020
*      BYTE 17    ZERO                                                  01320020
*      BYTE 18-19 TTR OF NOTE LIST OR SCATTER LIST                      01340020
*      BYTE 20    TRANSLATION TABLE                                     01360020
*      BYTE 21    ZERO OR NUMBER OF ENTRIES IN THE NOTE LIST            01380020
*      BYTE 22-23 ATTRIBUTES                                            01400020
*      BYTE 24-26 TOTAL CONTIGUOUS MAIN STORAGE REQUIRED FOR MODULE     01420020
*      BYTE 27-28 LENGTH OF FIRST TEXT RECORD                           01440020
*      BYTE 29    LENGTH OF WTG TABLE (IN DOUBLE WORDS)                 01460020
*      BYTE 30-31 PATH THROUGH LOADS OF ROUTINES                        01480020
*      BYTE 32-34 IDTTR OF EXECUTOR FOR FIRST DCB                       01500020
*      BYTE 35    WORKAREA ADDRESS FOR FIRST DCB                        01520020
*      BYTE 36-39 TABLE OF IDTTR'S                                      01540020
*      BYTE 32+N(8) IDTTR OF EXECUTOR FOR  N TH DCB  (3 BYTES)          01560020
*                   WORKAREA ADDRESS FOR N TH DCB    (1 BYTE )          01580020
*                   IDTTR OF LAST ROUTINE LOAD       (3 BYTES)          01600020
*                   NOT USED                         (1 BYTE)           01620020
*                                                                       01640020
*    WORKAREA- SEE 'FORCORE DSECT' (IECDSECT) IN THIS LISTING           01660020
*                                                                       01680020
*TABLES/WORKAREAS- PARAMETER LIST                                       01700020
*                                                                       01720020
*WORD ZERO                                                              01740020
*      BYTE  0    OPEN ATTRIBUTE  (INPUT, OUTPUT, UPDATE, IN/OUT,       01760020
*                                  OUT/IN, READ BACKWD, LEAVE , REREAD) 01780020
*      BYTES 1-3  DCB ADDRESS FOR FIRST DCB BEING OPENED.               01800020
*                                                                       01820020
*THE PARAMETER LIST HAS A ONE WORD ENTRY FOR EACH DCB BEING OPENED. THE 01840020
*FORMAT IS THE SAME AS WORD ZERO.                                       01860020
*END PARAMETER LIST.                                                    01880020
*                                                                       01900020
* REGISTER CONVENTIONS USED IN ALL OF OPEN-                             01920020
*                                                                       01940020
RDCB     EQU   2                        DCB REGISTER                    01960020
RBASE    EQU   3                        BASE REGISTER                   01980020
RCORE    EQU   4                        I/O SUPPORT WORK AREA           02000020
RPAR     EQU   5                        TOP OF PARAMETER LIST           02100020
RWTG     EQU   6                        TOP OF WTG TABLE                02120020
RPARC    EQU   7                        CURRENT PARAMETER               02140020
RWTGC    EQU   8                        CURRENT LOAD IN TRANSIENT AREA  02160020
RTIOT    EQU   9                        USED AS A WORK REG              02180020
RIOB     EQU   RTIOT                    USED AS IOB BASE REG WITH THE   02200020
*                                       IOB OVERLAY FROM FORECORE.      02220020
RUCB     EQU   10                       USED AS A WORK REG              02240020
RCPSIZE  EQU   RUCB                     USED TO CALCULATE AND HOLD THE  02260020
*                                       CHANNEL PGM SIZE.               02280020
RDEB     EQU   11                       DEB BASE REG.                   02300020
RB       EQU   12                       WORK REG.                       02320020
RCPBASE  EQU   RB                       CHANNEL PGM BASE REG USED WITH  02340020
*                                       'CPSEGMAP' DUMMY SECTION.       02360020
RC       EQU   13                       WORK REG.                       02380020
RSTEPPER EQU   RC                       POINTS TO THE CURRENT SEARCH    02400020
*                                       ADDRESS OR COUNT FIELD BEING    02420020
*                                       USED FOR CP CONSTRUCTION. WHEN  02440020
*                                       POINTING TO A COUNT FLD THE     02460020
*                                       'COUNTFLD' DUMMY SECTION IS     02480020
*                                       USED BASED ON THIS REG.         02500020
*                                                                       02520020
RE       EQU   0                        WORK REG. VOLATILE ACCROSS SVC. 02540020
RF       EQU   1                        WORK REG. VOLATILE ACCROSS SVC. 02560020
RD       EQU   14                       WORK REG. VOLATILE ACCROSS SVC. 02580020
RJ       EQU   15                       WORK REG. VOLATILE ACCROSS SVC. 02600020
RA       EQU   RJ                       USED AS WORK REG                02605020
RVALCHK  EQU   RA                       VALIDITY CHK CP BASEREG,        02610020
*                                       USES 'VCMAP' DSECT.             02615020
*                                                                       02620020
*                                                                       02640020
* MASK CONFIGURATIONS FOR TESTING THE HI ORDER BYTE OF EACH PARAMETER   02660020
* LIST ENTRY. SIGNIFICANCE IS THE SAME AS THE DEB OPEN ATTRIBUTE FIELD. 02680020
*                                                                       02700020
INPUT    EQU   X'0F'                    TEST MASKED BITS FOR ZEROS.     02720020
OUTPUT   EQU   X'0F'                    TEST MASKED BITS FOR ONES.      02740020
INOUT    EQU   X'03'                                                    02760020
OUTIN    EQU   X'07'                                                    02780020
RDBACK   EQU   X'01'                                                    02800020
UPDAT    EQU   X'04'                                                    02820020
LEAVE    EQU   X'10'                                                    02840020
REREAD   EQU   X'30'                                                    02860020
*                                                                       02880020
* COMMAND CODES FOR THE 2841 CONTROL UNIT.                              02900020
*                                                                       02920020
SRCHEQ   EQU   X'31'                    SEARCH EQUAL ID.                02940020
SRCHEQMT EQU   X'B1'                    SEARCH EQUAL ID IN MULTI-TRACK. 02960020
TIC      EQU   X'08'                    TRANSFER IN CHANNEL.            02980020
WCKD     EQU   X'1D'                    WRITE COUNT, KEY, AND DATA.     03000020
WSCKD    EQU   X'01'                    WRITE SPECIAL, COUNT,KEY,DATA.  03020020
SEEKCYL  EQU   X'0B'                    SEEK CYLINDER.                  03040020
READDATA EQU   X'06'                    READ DATA SINGLE TRACK.         03060020
RDDATAMT EQU   86                       MULTI-TRACK READ DATA.          03080020
READKD   EQU   14                       READ KEY AND DATA.              03100020
READCT   EQU   X'92'                    READ COUNT M/T MODE.            03120020
RDSC     EQU   X'22'                    SET THETA CCW COMMAND           03125020
SETSC    EQU   X'23'                    READ THETA CCW COMMAND          03130020
SDTIC    EQU   X'40'                    SCH DIR TIC                     03135020
*                                                                       03140020
* CHANNEL COMMAND WORD FLAGS.                                           03160020
*                                                                       03180020
SKIP     EQU   X'10'                    SKIP FLAG.                      03200020
SILI     EQU   X'20'                    SUPPRESS INCORRECT LENGTH IND.  03220020
CC       EQU   X'40'                    COMMAND CHAIN.                  03240020
DC       EQU   X'80'                    DATA CHAIN.                     03260020
SILICC   EQU   X'60'                    SILI AND CC TOGETHER            03280020
SILICCSK EQU   X'70'                    SILI, CC, AND SKIP.             03300020
* END CCW FLAGS.                                                        03320020
*                                                                       03340020
* DISPLACEMENTS  AS EQUATES                                             03341020
*                                                                       03342020
D0       EQU   0                        DISPLACEMENT OF ZERO            03343020
D1       EQU   1                        DISPLACEMENT OF ONE             03344020
D2       EQU   2                        DISPLACEMENT OF TWO             03345020
D4       EQU   4                        DISPLACEMENT OF FOUR            03346020
D6       EQU   6                        DISPLACEMENT OF SIX             03347020
D8       EQU   8                        DISPLACEMENT OF EIGHT           03348020
D12      EQU   12                       DISPLACEMENT OF TWELVE          03349020
D15      EQU   15                       DISPLACEMENT OF FIFTEEN         03350020
D16      EQU   16                  DISPLACEMENT OF 16                   03351020
CNTOFF   EQU   7                        CCW COUNT FIELD OFFSET          03352020
SXTN     EQU   16                       ADDITIONAL CHP LENGTH FOR       03353020
*                                       RECORD READY FEATURE            03354020
*                                                                       03360020
* MISCELLANEOUS ITEMS.                                                  03380020
*                                                                       03400020
COMPNOER EQU   X'7F'                   USED TO INIT. ECB.               03420020
DCANDCC  EQU   X'C0'                    USED TO SET IOBFLAG1.           03440020
IDLENGTH EQU   X'05'                    NMBR OF BYTES IN A 'CCHHR'.     03460020
POINT    EQU   X'04'                    DCBMACRF IF NOTE/POINT USED.    03480020
QSAM     EQU   X'01'                    QSAM BIT IN DCBIND2.            03500020
*                                                                       03520020
NPD2     EQU   5                        NOTE/POINT FOR PCI,UPD,T.O.     03540020
EPDT     EQU   9                        EOB FOR T.O.                    03560020
EGP2     EQU   8                        EOB FOR D.A. INPUT.             03580020
*                                                                       03600020
*                                                                       03620020
VALCHK   EQU   X'80'                    MASK TO DETERMINE IF WRITE      03640020
*                                       VALIDITY CHECK OPTION CALLED.   03660020
IOBSIZE  EQU   48                       LENGTH OF A STANDARD IOB WITH   03680020
*                                       BSAM/QSAM/BPAM EXTENSION.       03700020
IOBDBLWD EQU   6                        NMBR OF DBL WDS IN IOB.         03720020
OFFSW    EQU   24                       OFFSET OF CCW THAT WRITES DATA. 03740020
OFFSR    EQU   32                       OFFSET OF THE READ CCW THAT     03760020
*                                       RECEIVES THE BLOCK LENGTH TO    03780020
*                                       BE READ.                        03800020
CPSEGLEN EQU   32                       LENGTH OF ONE CP SEGMENT.       03820020
NOTZERO  EQU   7                        CONDITION MASK USED AFTER       03840020
*                                       ARITHMETIC INSTRUCTIONS FOR THE 03860020
*                                       NOT-ZERO TEST.                  03880020
BBCCHH   EQU   6                        MIN. SEEK LENGTH.               03900020
*                                                                       03920020
ZERO     EQU   X'00'                    AN IMMEDIATE BYTE OF ZERO'S.    03940020
B1       EQU   1                        BYTE COUNT OF ONE               03941020
ONE      EQU   1                        CONSTANT OF ONE                 03942020
TWO      EQU   2                        CONSTANT OF TWO                 03943020
B5       EQU   5                        BYTE COUNT OF FIVE              03944020
*                                                                       03945020
NORCDRY  EQU   X'20'                    NO RECORD READY MASK            03946020
RCDRYSL  EQU   48                       SEG LENGTH WHEN USING RCD       03947020
*                                       READY FEATURE                   03948020
*                                                                       03949020
*                                                                       03950020
*                                                                       03951020
VRCDS    EQU   X'40'                    V TYPE RCD MSK                  03952020
*                                                                       03953020
*                                                                       03954020
EIGHT    EQU   8                        LENGTH OF A COUNT FIELD.        03960020
ANYZERO  EQU   14                       MASK FOR MIXED OR ZEROS.        03980020
FIRST    EQU   X'01'                    USED TO SET IOB FLAG IN FIRST   04000020
*                                       IOB AND INIT. 'R'.              04020020
READCPL  EQU   40                       NMBR OF BYTES IN READ CP.       04040020
RCPDBLWD EQU   5                        NMBR OF DBL WDS IN RCP.         04060020
REMNANT  EQU   READCPL-OFFSR            OFFSR+REMNANT=READCPL.          04080020
OPCODE   EQU   0                        OFFSET OF CCW OPCODE(IN CCW).   04100020
ADDRESS  EQU   0                        OFFSET OF ADDRESS IN CCW        04120020
*                                       (IMPLIES THAT THE ADDRESS MUST  04140020
*                                       BE PUT IN BEFORE THE OP CODE)   04160020
FLAGS    EQU   4                        CCW FLAG BYTE.                  04180020
LENFLD   EQU   6                        START OF LENGTH FLD IN CCW.     04200020
U        EQU   X'C0'                    CODE FOR DCBRECFM=U             04220020
OABD062  EQU   62                                                S21042 04230021
*                                                                       04240020
         BALR  RBASE,0                  ESTABLISH ADDRESSABILITY.       04260020
         USING SOP6,RBASE                                               04280020
         USING FORCORE,RCORE            OPEN WKAREA              S21042 04300021
         USING IHADCB,RDCB              DCB ADDRESSABILITY.             04320020
*                                                                       04340020
*                                                                       04360020
SOP6     EQU   *                                                        04380020
*                                                                       04400020
         L     RDCB,0(RPARC)            GET DCB ADDRESS FROM PARM. LIST 04420020
         L     RDEB,DCBDEBAD            DEB ADDRESSABILITY.             04440020
         L     RCORE,D4(RWTGC)          GET WORK AREA ADDR              04450020
         LA    RDCB,0(RDCB)             HOUSEKEEP HI BYTE.              04480020
         SR    RUCB,RUCB                CLEAR REG                       04680020
         IC    RUCB,DCBNCP              GET NO. OF IOBS REQUIRED        04880020
         IF    DCBCIND2,ISNOT=QSAM,GOTO=SOP6L12                         05080020
         IC    RUCB,DCBBUFNO            IF QSAM USE BUFNO               05280020
SOP6L12  EQU   *                                                        05480020
         L     RIOB,DCBIOBA             GET FIRST IOB ADDRESS.          06000020
         L     RF,D0(RIOB)              RETRIEVE THETA ADDR             06003020
         ST    RF,DXCCW11               PUT IN TEMP STORAGE             06006020
         LA    RF,D1(RF)                OBTAIN READ THETA ADDR          06009020
         ST    RF,DXCCW12               TEMP STORE                      06012020
         XC    D0(D4,RIOB),D0(RIOB)     CLEAR WORD OF IOB               06015020
         USING SAMSIOB,RIOB            IOB ADDRESSABILITY READY.        06020020
         MVI   FLAG,FIRST               FLAG FIRST IOB             DM0I 06030020
*                                                                       06040020
BUILDIOB EQU   *                                                        06060020
*                                                                       06080020
* RIOB POINTS TO START OF AN IOB. USING THIS AS A BASE, GET THE CP      06100020
* START ADDRESS AND THE ADDRESS OF THE COUNT FIELDS AND S.A.'S.         06120020
*                                                                       06140020
*                                                                       06160020
         MVI   ECB,COMPNOER            INIT. ECB FOR QSAM.              06180020
         LA    RF,ECB                   INITIALIZE THE                  06200020
         ST    RF,IOBECBPT              ECB POINTER.                    06220020
*                                                                       06240020
         OI    IOBFLAG1,DCANDCC         INDICATE COMMAND AND DATA CHAIN 06260020
         ST    RDCB,IOBDCBPT-1          INIT DCB PT IN IOB.             06280020
         MVC   IOBSEEK(8),DCBFDAD       INIT. ALL IOB FDAD'S. SUPPORTS  06286020
*                                       EVERYBODY INCLUDING 2321.       06292020
         LA    RCPBASE,CHANPGM          GET CHP ADDR                    06296020
         ST    RCPBASE,IOBSTART-D1      PUT IN IOB                      06300020
*                                                                       06304020
* TEST FOR INPUT ONLY                                                   06308020
*                                                                       06312020
         USING DEB,RDEB                 DEB ADDRESSABILITY              06316020
         IF    DEBOPATB,ISNOT=OUTPUT,GOTO=RCPREQD                       06320020
         DROP  RDEB                                                     06330020
BUILDWCP EQU   *                                                        06340020
         SR    RCPBASE,RCPBASE         NEEDED ON 2ND PASS.              06360020
         IC    RCPBASE,DCBWCPO          NEED OFFSET TO BUILD            06380020
         AR    RCPBASE,RIOB             WRITE CP BASE ADDRESS.          06400020
         USING WCPMAP,RCPBASE                                           06440020
         SR    RSTEPPER,RSTEPPER       NEEDED ON 2ND PASS.              06460020
         IC    RSTEPPER,DCBWCPL         BUILD ADDRESS OF COUNT FIELDS   06480020
         SLL   RSTEPPER,3               APPENDED TO WCP.                06500020
         AR    RSTEPPER,RCPBASE         ADDRESS OF FIRST COUNT FIELD.   06520020
*                                                                       06530020
         USING COUNTFLD,RSTEPPER                                        06540020
*                                                                       06560020
*   RIOB = IOB ADDRESS.                                                 06580020
*   RCPBASE = CHANNEL PROGRAM ADDRESS.                                  06600020
*   RSTEPPER = COUNT FIELD AND S.A. ADDRESS.                            06620020
*                                                                       06640020
* IOB INITIALIZED EXCEPT FOR LINK FIELD.                                06660020
*                                                                       06680020
* BUILD WRITE CHANNEL PROGRAMS.  THE CORRECT NUMBER OF CP SEGMENTS IS   06700020
* THAT WHICH CAN BE BUILT UP TO THE FIRST COUNT FIELD APPENDED TO THIS  06720020
* IOB.                                                                  06740020
*                                                                       06760020
*                                                                       06770020
* CHECK FOR RCD READY FEATURE AND SET UP SET THETA COMMAND IF           06780020
* THE FEATURE IS ON ALL THE DATA SETS DEVICES                           06790020
*                                                                       06800020
*                                                                       06805020
         TM    JFCBMASK+D6,NORCDRY      ANY DEVICES W/O RCD READY       06810020
         BO    NOFET3                   BRANCH IF YES                   06815020
         BAL   RD,SOP6STA               GO BUILD SET SECTOR CCW         06820020
         AH    RCPBASE,DBLWDLEN         INCR BASE FOR SET SECTOR        06825020
NOFET3   EQU   *                                                        06830020
CCW1     EQU   *                                                        06840020
         LA    RD,IOBSEEK+3             GET ADDRESS OF CCHHR IN IOB.    06860020
         ST    RD,SRCHADDR              PUT IN FIRST SEARCH COMMAND.    06880020
         MVI   SRCHOPCD,SRCHEQ          SET OP CODE = SEARCH.           06900020
*                                                                       06940020
* BUILD  FIRST  TIC CCW.                                                06960020
*                                                                       06980020
CCW2     EQU   *                                                        07000020
         ST    RCPBASE,TICADDR          STORE ADDRESS OF PREVIOUS SRCH. 07020020
         MVC   SRCHFLAG(B5),FLAGLEN     FLAGS, LEN, TIC OP CODE         07040020
*                                                                       07060020
*                                                                       07080020
         LR    RVALCHK,RSTEPPER         COPY PTR TO BEGINNING OF COUNTS 07100020
*                                       AND S.A.'S. WILL BE USED FOR    07120020
*                                       VAL CHK CP ADDRESSABILITY (IF   07140020
*                                       NEEDED) AND TO FLAG THE LAST    07160020
*                                       CCW OF THE WRITE SEGMENTS.      07180020
*                                                                       07200020
         IF    DCBOPTCD,ISNOT=VALCHK,GOTO=FLAGLAST                      07220020
*                                                                       07240020
* VALIDITY CHECK IS CALLED. BUILD THE VAL CHK CP SEGMENT WHILE ADDR-    07260020
* ESSABILITY IS AVAILABLE. CCW'S TO BE BUILT ARE A SEEK (CCW7), SEARCH  07280020
* (CCW8), TIC (CCW9) AND READ DATA (CCW10).                             07300020
*                                                                       07320020
         SH    RVALCHK,VALCKLEN         BACK UP TO BEGINNING OF VAL CHK 07340020
*                                       CP.                             07360020
         TM    JFCBMASK+D6,NORCDRY      ANY DEVICES W/O RCD READY       07362020
         BO    FEAT7                    BRANCH IF YES                   07364020
         SH    RVALCHK,DBLWDLEN         DECREMENT ADDITIONAL CCW        07366020
*                                       SINCE FEATURES WRITE CHK        07368020
*                                       CHP LARGER                      07370020
FEAT7    EQU   *                                                        07372020
         USING VCMAP,RVALCHK            VAL CHK SEGMENT ADDRESSABILITY. 07380020
*                                                                       07400020
CCW7     EQU   *                        BUILD SEEK COMMAND. SEEK        07420020
*                                       ADDRESS SAME AS CCHH IN FIRST   07440020
*                                       COUNT FIELD.                    07460020
         LA    RD,IOBSEEK+1             POINTS TO IOB SEEK ADDR.        07480020
         ST    RD,SEEKADDR                                              07500020
         MVI   SEEKOPCD,SEEKCYL                                         07520020
         MVI   SEEKFLAG,CC              COMMAND CHAIN.                  07540020
         MVI   SEEKLEN,BBCCHH           LENGTH OF A 'BBCCHH'.           07560020
         TM    JFCBMASK+D6,NORCDRY      ANY DEVICES W/O RCD READY       07562020
         BO    NOFET9                   BRANCH IF YES                   07564020
         DROP  RIOB                                                     07566020
         USING FORCORE,RCORE            OPEN WKAREA              S21042 07568021
         L     RD,DXCCW12               GET SECTOR ADDR                 07570020
         USING SAMSIOB,RIOB                                             07572020
         ST    RD,D8(RVALCHK)           PUT IN CCW                      07574020
         OI    D12(RVALCHK),CC          TURN ON COMMAND CHAIN           07576020
         MVI  D15(RVALCHK),B1           SET BYTE COUNT TO ONE           07578020
         MVI   D8(RVALCHK),SETSC        PUT IN CCW CMND                 07580020
         AH    RVALCHK,DBLWDLEN         INCREMENT RVALCHK BASE REG      07582020
*                                       TO ELIMINATE SET SECTOR         07584020
*                                       OFFSETS IN DSECT                07586020
NOFET9   EQU   *                                                        07588020
CCW8     EQU   *                        BUILD SEARCH ID EQUAL WITH SAME 07600020
*                                       CCHH AS THE SEEK.               07620020
         ST    RSTEPPER,VCSRCHAD        ADDRESS OF FIRST COUNT FIELD.   07640020
         MVI   VCSRCHOP,SRCHEQ          OP CODE.                        07660020
*                                                                       07700020
CCW9     EQU   *                        BUILD A TIC BACK TO CCW8.       07720020
         LA    RD,VCSRCH                ADDRESS OF SEARCH.              07740020
         ST    RD,VCTICAD               PUT IN TIC ADDRESS.             07760020
         MVC   VCSRCHFL(B5),FLAGLEN     FLAGS, LEN, TIC OP CODE         07780020
* TIC COMPLETE. NO FLAGS REQ'D.                                         07800020
*                                                                       07820020
CCW10    EQU   *                        BUILD READ DATA WITH SKIP.      07840020
         MVI   VCRDOP,READKD            TO READ DATA + KEYS (IF ANY).   07860020
         MVI   VCRDFLAG,SKIP            SKIP FLAG.                      07880020
* SKIP ON MAKES ADDRESS IMMATERIAL, LENGTH WILL BE SET AT EOB TIME.     07900020
*                                                                       07920020
* VALIDITY CHECK CP IS BUILT.                                           07940020
*                                                                       07944020
         TM    JFCBMASK+D6,NORCDRY      ANY DEVICES W/O RCD READY       07948020
         BO    FEATL17                  BRANCH IF YES                   07952020
         SH    RVALCHK,DBLWDLEN         IF YES RVALCHK WAS INCR         07956020
*                                       TO WRT CHK PGM PLUS  8  TO      07960020
*                                       ELIMINATE SET SECTOR OFF-       07964020
*                                       SETS AND NOW MUST BE RE-        07968020
*                                       STORED                          07972020
FEATL17  EQU   *                                                        07976020
         ST    RVALCHK,PARASITE         PUT VAL CHK CP ADDRESS IN       07980020
*                                       R.H. OF CCW2.                   08000020
         MVI   PARASITE,TIC             PUT IN TIC OP CODE, OK BECAUSE  08020020
*                                       BITS 37-39=0.                   08040020
*                                                                       08060020
* PARASITE TIC IN CCW2 WILL BE USED TO TRANSFER-IN-CHANNEL AROUND ANY   08080020
* UNUSED CP SEGMENTS WHEN WRITE CHECK IS CALLED.                        08100020
*                                                                       08120020
         DROP  RVALCHK                  RELINQUISH VC CP ADDRESS.       08140020
*                                                                       08160020
FLAGLAST EQU   *                                                        08180020
*                                                                       08200020
         SH    RVALCHK,DBLWDLEN         THE CCW BEFOR THE VAL CHK CP    08220020
*                                       (OR THE S.A.'S AND COUNT FLDS)  08240020
*                                       IS THE END OF THE WRITE SEGMENT 08260020
*                                       CP'S. POINT TO IT.              08280020
         TM    JFCBMASK+D6,NORCDRY      ANY DEVICES W/O RCD READY       08282020
         BO    NOFETFLG                 BRANCH IF YES                   08284020
         ST    RVALCHK,PARASITE         PUT RD SECT ADDR IN PARASIT     08286020
         MVI   PARASITE,TIC             PUT IN TIC CMND                 08288020
         SH    RVALCHK,DBLWDLEN         BACK UP TO NULL OP CD           08290020
NOFETFLG EQU   *                                                        08292020
         MVI   0(RVALCHK),WSCKD         FLAG LAST CCW4 OP CODE BYTE     08300020
*                                       WITH A NON-ZERO VALUE.          08320020
*                                                                       08340020
         LA    RF,NULLOPCD              ADDRESS OF CCW WHICH RECEIVES   08360020
         BAL   RE,GETBUFAD              BUFFER ADDRESS.                 08380020
*                                                                       08400020
         MVC   KEYLENTH(1),DCBKEYLE     KEY WILL BE WRITTEN ON FIRST    08420020
*                                       RECORD SEGMENT ONLY.            08440020
*                                                                       08460020
CCW3     EQU   *                        ALL FIRST TIME LOGIC IS DONE.   08480020
*                                       BEGIN HERE WITH A LOOP TO BUILD 08500020
*                                       THE REST OF CP SEG 1 (CCW'S 3   08520020
*                                       AND 4) AND ALL REMAINING SEG-   08540020
*                                       MENTS (MADE UP OF CCW'S 5,6,3,4 08560020
*                                       IN THAT ORDER.)                 08580020
*                                                                       08600020
         ST    RSTEPPER,COUNTADR        FILL IN COUNT FIELD ADDRESS.    08620020
         MVI   COUNTLEN,EIGHT           LENGTH OF A COUNT FIELD.        08640020
         MVI   WRTFLAG,DC               DATA CHAIN TO NEXT CCW.         08660020
*                                                                       08680020
CCW4     EQU   *                        THIS IS THE CCW THAT WRITES THE 08700020
*                                       DATA. NOTHING IS KNOWN AT OPEN  08720020
*                                       TIME EXCEPT THAT IT IS COMMAND  08740020
*                                       CHAINED, AND THE FIRST CCW4     08760020
*                                       WILL HAVE THE BUFFER ADDRESS IF 08780020
*                                       QSAM IS USED                    08800020
*                                       IF IT IS THE LAST CCW4, THE OP  08820020
*                                       CODE BYTE HAS BEEN SET TO NON-  08840020
*                                       ZERO.                           08860020
*                                                                       08880020
         MVI   RECORD,FIRST             INIT. 'R' TO 1.                 08900020
         CLI   NULLOPCD,ZERO            IS THIS THE LAST CP SEGMENT?    08940020
         BNE   THRULOOP                 YES. BRANCH TO DO FINAL LOGIC.  08960020
*                                                                       08980020
* PREPARE TO BUILD NEXT CP SEGMENT. ADVANCE THE CP ADDR REG TO NEXT CP, 09000020
* AND MOVE THE COUNT FIELD AND S.A. POINTER TO NEXT S.A.                09020020
*                                                                       09040020
         LA    RCPBASE,CPSEGLEN(RCPBASE)   POINT TO NEXT SEGMENT.       09060020
         LA    R13,EIGHT(R13)           POINT TO NEXT S.A.         DM0I 09070020
R13      EQU   13                       13                         DM0I 09080020
*                                       THE COUNT FIELD OVERLAY IS NOT  09100020
*                                       VALID UNTIL RSTEPPER IS BUMPED  09120020
*                                       8 MORE.                         09140020
*                                                                       09160020
CCW5     EQU   *                        SEARCH                          09180020
*                                                                       09200020
         ST    RSTEPPER,SRCHADDR        PUT IN POINTER TO SEARCH ADDR.  09220020
*                                                                       09260020
CCW6     EQU   *                        TIC                             09280020
*                                                                       09300020
         ST    RCPBASE,TICADDR          STORE ADDRESS OF CCW5.          09320020
         MVC   SRCHFLAG(B5),FLAGLEN     FLAGS, LEN, AND TIC OP CODE     09340020
*                                                                       09360020
         TM    JFCBMASK+D6,NORCDRY      ANY DEVICES W/O RCD READY       09366020
         BNO   FEATAX                   BRANCH IF NO                    09372020
         IF    DCBOPTCD,ISNOT=VALCHK,GOTO=PTRUPBY8                      09380020
*                                                                       09400020
* VAL CHK CALLED. NEED A PARASITE SEARCH ADDRESS IN CCW6 (TIC) TO BE    09420020
* USED FOR RECONSTRUCTION OF CCW5 AT EOB TIME.                          09440020
FEATAX   EQU   *                                                        09450020
*                                                                       09460020
         ST    RSTEPPER,PARASITE        PUT IN SEARCH ADDRESS.          09480020
*                                       SEARCH OP CODE IS IMPLIED, AND  09500020
*                                       FILLED IN AT EOB.               09520020
*                                                                       09540020
PTRUPBY8 EQU   *                                                        09560020
         LA    R13,EIGHT(R13)           POINT TO NEXT COUNT FIELD  DM0I 09580020
*                                       OVERLAY NOW APPLIES.            09600020
*                                                                       09620020
         B     CCW3                     CLOSE THE LOOP FOR BUILDING     09640020
*                                       CCW'S.                          09660020
*                                                                       09680020
THRULOOP EQU   *                        CCW'S ARE BUILT. FINAL LOGIC TO 09700020
         TM    JFCBMASK+D6,NORCDRY      ANY DEVICES W/O RCD READY       09706020
         BO    NOFET19                  BRANCH IF YES                   09712020
         BAL   RD,SOP6RTA               GO BUILD READ SECTOR CCW        09718020
NOFET19  EQU   *                                                        09724020
         USING DEB,RDEB                                                 09730020
*                                                                       09740020
*                                                                       09760020
*                                                                       09780020
         IF    DEBOPATB,IS=OUTPUT,GOTO=NEXTIOB                          09800020
*  MUST DROP RDEB BECAUSE  THE FORECORE DSECT LAYOUT PRODUCES A         09820020
* SMALLER OFFSET WITH RDEB FOR 'CHANPGM'. RIOB IS THE DESIRED REG.      09840020
         DROP  RDEB                                                     09860020
         B     BUILDRCP                 TO BUILD  RECORD READ CHAN.DM0I 09880020
RCPREQD  EQU   *                                                        09900020
         USING RCPOVLAY,RCPBASE                                         09940020
         LA    RSTEPPER,CNTFLD          PT TO LAST S.D. COUNT FDL       09945020
         TM    JFCBMASK+D6,NORCDRY      ANY DEVICES W/O RCD READY       09950020
         BO    NOFET25                  BRANCH IF YES                   09955020
         LA    RSTEPPER,D16(RSTEPPER)   INCR OVER RPS COMMANDS          09960020
*                                       IF RPS IS SPECIFIED             09965020
NOFET25  EQU   *                                                        09970020
BUILDRCP EQU   *                                                        09980020
         LA    RCPBASE,CHANPGM          READ CP CONTIG. TO IOB.         10000020
         USING RCPOVLAY,RCPBASE                                         10020020
         USING DEB,RDEB                                                 10040020
         ST    RCPBASE,IOBSTART-1                                       10060020
         TM    JFCBMASK+D6,NORCDRY      ANY DEVICESW/O RCD READY        10063020
         BO    NOTRR2A                  BRANCH IF YES                   10066020
         BAL   RD,SOP6STA               GO BUILD SET SECTOR CCW         10069020
         AH    RCPBASE,DBLWDLEN         INCR BASE FOR SET SECTOR        10072020
NOTRR2A  EQU   *                                                        10075020
CCWA     EQU   *                                                        10080020
         LA    RD,IOBSEEK+3             SEARCH ON IOB FDAD.             10100020
         ST    RD,SRCHCCW+ADDRESS       FILL IN SEARCH ADDRESS.         10120020
         MVI   SRCHCCW+OPCODE,SRCHEQ    SEARCH OP CODE .                10140020
CCWB     EQU   *                                                        10200020
         LA    RD,SRCHCCW               GET SEARCH CCW ADDR             10210020
         ST    RD,TICCCW+ADDRESS        PUT IN TIC CCW                  10220020
         MVC   SRCHCCW+FLAGS(B5),FLAGLEN FLAGS,LEN TIC OP CODE          10230020
         OI    TICCCW,SDTIC             TURN SRCH DIR FLAG              10240020
CCWC     EQU   *                                                        10260020
         LA    RD,RKDCCW                ADDR OF READ CCW                10270020
         ST    RD,SECNDTIC              PUT IN SECOND TIC               10280020
         MVI   SECNDTIC,TIC             MOVE IN COMMAND                 10290020
         MVI   SECNDTIC+FLAGS,CC        SET CC FOR RD CNT LATER         10300020
         MVI   SECNDTIC+CNTOFF,EIGHT    AND MOVE IN COUNT               10310020
CCWD     EQU   *                                                        10340020
         IF    DCBCIND2,IS=QSAM,GOTO=TESTBUF                            10360020
         MVI   RKDCCW+OPCODE,READKD     CCWE, USING THE QSAM DECISION.  10380020
         B     IOBAREQD                 GO AROUND NEXT                  10410020
TESTBUF  MVI   RDCCW+OPCODE,READDATA    CCWE, USING THE QSAM DECISION.  10440020
*                                                                       10460020
IOBAREQD EQU   *                                                        10480020
*                                                                       10500020
         OI    RDCCW+FLAGS,SILI         SET SILI FLAG           SA51532 10560021
         LA    RD,CNTFLD                GET CNT FLD ADDR                10620020
         TM    JFCBMASK+D6,NORCDRY      ANY NON RPS DEVICES             10640020
         BNO   OKADDR                   BRANCH IF NO                    10660020
         SH    RD,DBLWDLEN              BACK UP DW                      10680020
OKADDR   EQU   *                                                        10700020
         ST    RD,RDCTCCW               PUT ADDR IN CCW                 10720020
         MVI   RDCTCCW,READCT           READ COUNT                      10740020
         MVI   RDCTCNT,EIGHT            BYTE COUNT EQS EIGHT            10760020
*                                                                       10780020
*                                                                       10800020
         CLI   DCBKEYLE,ZERO                                            10840020
         BNE   OPCODEOK                 OP CODE OK                 DM0I 10860020
         MVI   RDCCW+OPCODE,READDATA                                    10880020
OPCODEOK EQU   *                                                        10900020
*                                                                       10920020
*                                                                       10940020
*                                                                       10960020
         LA    RF,RDCCW                 POINT TO CCW WHICH RECEIVES     11000020
         BAL   RE,GETBUFAD              BUFFER ADDRESS.                 11020020
*                                                                       11021020
* IF RCD READY FEATURE USED BUILD A READ SECTOR COMMAND                 11022020
*                                                                       11023020
         OI    RDCCW+FLAGS,CC           TURN ON COMMAND CHAIN           11024020
NOSILIX  EQU   *                                                        11025020
*                                                                       11026020
* MUST DROP RIOB AND RDEB TO USE RCORE                                  11027020
         DROP  RIOB                                                     11028020
         DROP  RDEB                                                     11029020
*                                                                       11030020
         TM    JFCBMASK+D6,NORCDRY      DONT BUILD A RD SECT COM        11031020
         BO    NOFET29                   IF RPS IS NOT FEATURED         11032020
         USING FORCORE,RCORE            OPEN WKAREA              S21042 11033021
         L     RD,DXCCW12               GET THETA ADDR                  11034020
         ST    RD,RRRDSEC               PUT IN CCW                      11035020
         OI    RDCTFLGS,CC              CMND CHAIN                      11036020
         MVI   RRRDSCNT,ONE             SET BYTE COUNT TO ONE           11037020
         MVI   RRRDSEC,RDSC             PUT IN CCW CMND                 11038020
         DROP  RCORE                                                    11039020
NOFET29  EQU   *                                                        11040020
         USING SAMSIOB,RIOB                                             11041020
NEXTIOB  EQU   *                        TEST FOR ANOTHER IOB TO BE      11060020
*                                       BUILT.                          11080020
         BCTR  RUCB,RE                  DECR IOB COUNT                  11090020
         LTR   RUCB,RUCB                HAVE ALL IOBS BEEN BUILT        11100020
*                                       FLAGGED.                        11120020
         BNP   ALLBUILT                 YES BRANCH TO CLOSE IOB         11150020
*                                      CHAIN AND THEN DO WTG LOGIC.     11180020
* MORE IOB'S TO BE BUILT.                                               11200020
         LA    RD,EIGHT(RSTEPPER)       NEXT IOB STARTS AFTER LAST      11220020
*                                       COUNT FLD OF THE PREVIOUS.      11240020
         O     RD,LINK                  FORWARD CHAIN TO NEXT IOB.      11260020
*                                       OR'ING PRESERVES THE FLAG.      11280020
         ST    RD,LINK                  STORE THE PREPARED LINK FIELD.  11300020
*                                                                       11320020
         LR    RIOB,RD                  NOW HAVE ADDRESSABILITY FOR THE 11340020
*                                       NEXT IOB.                       11360020
*                                                                       11380020
         B     BUILDIOB                 GO BACK AND BUILD IT.           11400020
*                                                                       11420020
ALLBUILT EQU   *                                                        11440020
         MVC   LINK+1(3),DCBIOBA+1      LINK LAST IOB TO THE FIRST.     11460020
*                                                                       11700020
*                                                                       11860020
         DROP  RIOB                                                     11880020
*******************  WTG LOGIC GOES HERE. **********************        11900020
*                                                                       11920020
STOPSOP6 EQU   *                                                        11940020
         L     RCORE,4(RWTGC)           GET WORK AREA ADDRESSABILITY.   11980020
         USING FORCORE,RCORE            OPEN WKAREA              S21042 12000021
         MVC   0(5,RWTGC),LOADEXEC      GET LOAD EXEC ID.               12020020
         TM    DCBRECFM,X'80'           VARIABLE RECORD FORMAT    22688 12025020
         BO    RELOOP                   NO,BRANCH                 22688 12030020
         MVC   0(5,RWTGC),OPENVREC     YES LOAD IGG01916           DM0I 12035020
*                                                                       12040020
RELOOP   LA    RWTGC,WGOFF(0,RWTGC)     INCREMENT CURRENT WTG ENTRY.    12060020
         LA    RPARC,PLOFF(0,RPARC)     INCREMENT CURRENT DCB ENTRY PTR 12080020
         CLC   0(2,RWTGC),AMIDCNST      IS THIS RTN NEEDED AGAIN?       12100020
         BCR   EGP2,RBASE               RETURN TO OPEN             DM0I 12120020
*                                                                       12140020
         CLC   0(2,RWTGC),OPIDCNST      END OF TABLE?                   12160020
         BC    7,RELOOP                 NO, CHECK NEXT ENTRY.           12180020
*                                                                       12200020
         LR    RPARC,RPAR                                               12220020
         LA    RWTGC,WAOFF(0,RWTG)      REINIT. WTG LIST PTR.           12240020
ZCHEK    CLI   0(RWTGC),X'00'           IS THIS ENTRY COMPLETE?         12260020
         BC    7,TCTLRTN                IF NOT TRANSFER CONTROL.        12280020
*                                                                       12300020
         LA    RWTGC,WGOFF(0,RWTGC)     GET NEXT ENTRY.                 12320020
         LA    RPARC,PLOFF(0,RPARC)                                     12340020
         B     ZCHEK                    ZERO CHECK                 DM0I 12360020
*                                                                       12380020
TCTLRTN  EQU   *                                                        12400020
         MVC   6(2,RWTG),0(RWTGC)       STORE ID IN WTG TABLE.          12420020
         MVC   14(3,RWTG),2(RWTGC)      MOVE TTR INTO TABLE.            12440020
*                                                                       12460020
*                                                                       12480020
         LA    RJ,DXXCTL                XCTL WKAREA              S21042 12500021
*                                                                       12520020
         XCTL  DE=(RWTG),SF=(E,(15))                                    12540020
*                                                                       12544020
* END WTG LOGIC                                                         12548020
*                                                                       12552020
* SET SECTOR BUILD RTN                                                  12556020
*                                                                       12560020
SOP6STA  EQU   *                                                        12564020
*                                                                       12568020
         L     RE,DXCCW11               GET THETA ADDR                  12572020
         ST    RE,D0(RCPBASE)           PUT IN CCW                      12576020
         OI    FLAGS(RCPBASE),CC        TURN ON CMND CHAIN              12580020
         MVI   CNTOFF(RCPBASE),B1       SET BYTE COUNT TO ONE           12584020
         MVI   D0(RCPBASE),SETSC        PUT IN SET SECT CMND            12588020
         BR    RD                       RETURN                          12592020
*                                                                       12594020
* READ SECTOR BUILD ROUTINE                                             12596020
*                                                                       12598020
         USING WCPMAP,RCPBASE                                           12600020
SOP6RTA  EQU   *                                                        12602020
         L     RE,DXCCW12               GET THETA ADDR                  12604020
         ST    RE,WRSADDR               PUT IN CCW                      12606020
*                                                                       12608020
         OI    NULLFLAG,CC              TURN ON PREVIOUS CCW CMND       12610020
*                                       CHAIN                           12612020
         MVI   WRSCNT,B1                SET BYTE COUNT TO ONE           12614020
         MVI   WRSCMND,RDSC             PUT IN CCW CMND                 12616020
         BR    RD                       RETURN                          12618020
         DROP  RCPBASE                                                  12620020
*                                                                       12622020
GETBUFAD EQU   *                                                        12624020
         IF    DCBCIND2,ISNOT=QSAM,GOTO=RETURN                          12640020
         L     RD,DCBBUFCB              GET BUFF CB ADDR.               12660020
         L     RJ,0(RD)                 GET ADDR OF CURRENT BUFF.       12680020
         LA    RJ,0(RJ)                 CLEAR HI BYTE.                  12700020
         LTR   RJ,RJ                    TEST FOR BUFFER AVAIL.          12720020
         BC    NOTZERO,AVAIL            BRANCH IF BUFF AD NOT 0.        12740020
         DMABCOND OABD062,PDLOAD,RETURN=NONE,RES=NO,REGSAVE=YES  S21042X12750021
                                        CALL PROBLEM DETERMINATION     X12770021
                                        TO ISSUE 013 ABEND              12780021
         B     TCTLRTN                  GO XCTL                  S21042 12790021
AVAIL    MVC   1(3,RF),1(RD)            MOVE CURRENT AVAIL TO CCW RCVR. 12820020
         MVC   1(3,RD),1(RJ)            MOVE NEXT AVAIL TO BUFF CB.     12840020
         MVC   6(2,RF),DCBBLKSI         INIT CCW LENGTH                 12860020
RETURN   LR    RF,RE                                                    12880020
         BR    RF                       EXIT                       DM0I 12900020
*                                                                       12920020
TWOCON   DC    H'2'                     CONSTANT OF TWO                 12940020
DBLWDLEN DC    H'8'                     LENGTH OF A DOUBLE WORD.        12960020
VALCKLEN DC    H'32'                    VALIDITY CHK CP LENGTH.         12980020
FLAGLEN  DC    X'40'                    COMMAND CHAIN FLAG.             13000020
         DC    X'00'                    SPACER                          13020020
         DC    H'5'                     LENGTH OF A 'CCHHR'.            13040020
         DC    X'08'                    TIC COMMAND CODE                13050020
*                                                                       13060020
*                                                                       13080020
* WTG CONSTANTS AND EQUATES.                                            13100020
*                                                                       13120020
WAOFF    EQU   32                                                       13140020
PLOFF    EQU   4                                                        13160020
WGOFF    EQU   8                                                        13180020
OPIDCNST DC    C'0S'                    ID                         DM0I 13200020
AMIDCNST DC    C'9K'                    THIS ID                         13220020
*                                                                       13240020
* END WTG CONSTANTS.                                                    13260020
*                                                                       13280020
         XCTLTABL ID=(LOADEXEC,13,OPENVREC,16,PDLOAD,6M),SVC=019 S21042 13350021
*                                                                       13420020
* READ CHANNEL PROGRAM OVERLAY.  CCW FIELDS ARE ACCESSED BY ABSOLUTE    13440020
* OFFSETS FROM THE CCW NAME.                                            13460020
*                                                                       13480020
RCPOVLAY DSECT                                                          13500020
SRCHCCW  DS    D                        SEARCH CCW                 DM0I 13540020
*        TIC    (CCWB)                                                  13560020
TICCCW   DS    D                        TIC                        DM0I 13580020
*        READ DATA WITH SKIP  (CCWC)                                    13600020
SECNDTIC DS    D                        CCWD                            13610020
*        SECOND TIC CCW                                                 13620020
RDCCW    DS    D                        READ CCW                        13630020
*        READ KEY AND DATA CCW                                          13640020
RKDCCW   EQU   RDCCW                    (ALTERNATE ADDR)                13650020
*                                                                       13660020
RDCTCCW  DS    F                        FIRST WORD OF RD CNT            13670020
RDCTFLGS DS    XL1                      FLAG FIELD                      13680020
         DS    CL2                      FILLER                          13690020
RDCTCNT  DS    XL1                      BYTE CNT                        13700020
*                                                                       13710020
RRRDSEC  DS    F                        READ SECT CCW                   13720020
RRRDSFLG DS    XL1                      FLAG FIELD                      13730020
         DS    CL2                      FILLER                          13740020
RRRDSCNT DS    XL1                      COUNT FIELD                     13750020
*                                                                       13760020
CNTFLD   DS    D                        COUNT FIELD                     13770020
* FOLLOWING IS A MAP OF A WRITE CHANNEL PROGRAM (WCP) SEGMENT.          13780020
*                                                                       13800020
WCPMAP   DSECT                                                          13820020
*                                                                       13840020
*        SEARCH  (CCW1 OR 5)                                            13860020
*                                                                       13880020
SRCHADDR DS    F                        SEARCH                     DM0I 13900020
SRCHOPCD EQU   SRCHADDR                 OP CODE IS HI ORDER BYTE.       13920020
SRCHFLAG DS    XL1                      SEARCH FLAG                DM0I 13940020
         DS    CL2                      FLAG                       DM0I 13960020
SRCHLEN  DS    XL1                      LENGTHS NORMALLY FIT IN 1 BYTE. 13980020
*                                                                       14000020
*        TIC   (CCW2 OR 6)                                              14020020
*                                                                       14040020
TICADDR  DS    F                        TIC                        DM0I 14060020
TICOPCD  EQU   TICADDR                  TIC  OP                    DM0I 14080020
UNUSED   DS    F                        ONLY REQUIRES BITS 37-39 = 0.   14100020
PARASITE EQU   UNUSED                   MAY BE USED TO STORE AN ADDRESS 14120020
*                                       BUT THE ABOVE RESTRICTION       14140020
*                                       LIMITS THE OP CODES THAT MAY    14160020
*                                       BE STORED IN THE HI BYTE.       14180020
*                                                                       14200020
*        WRITE  (CCW3)                                                  14220020
*                                                                       14240020
COUNTADR DS    F                        COUNT FIELD ADDRESS.            14260020
WRTOPCD  EQU   COUNTADR                                                 14280020
WRTFLAG  DS    XL1                      FLAG FIELD.                     14300020
         DS    CL2                      SPACER.                         14320020
COUNTLEN DS    XL1                      COUNT FIELD LENGTH (NORMALLY 8) 14340020
*                                                                       14360020
*        NULL OP CODE  (CCW4)           OP PROPAGATED FROM WRITE CCW.   14380020
*                                                                       14400020
DATAADDR DS    F                        ADDRESS OF BLOCK OF DATA TO BE  14420020
*                                       WRITTEN.                        14440020
NULLOPCD EQU   DATAADDR                 USED AS A FLAG TO SIGNAL LAST   14460020
*                                       SEGMENT.                        14480020
NULLFLAG DS    XL1                      NULL FLAG                  DM0I 14500020
         DS    XL1                      SPACER.                         14520020
DATALEN  DS    H                        2 BYTES HOLDS DATA LENGTH.      14540020
*                                                                       14544020
* READ SECTOR COMMAND IF NEEDED                                         14548020
*                                                                       14552020
WRSCMND  DS    F                        READ SECTOR COMMAND             14556020
WRSADDR  EQU   WRSCMND                  SECTOR ADDR                     14560020
WRSFLAG  DS    XL1                      FLAG BYTE                       14564020
FILLER   DS    CL2                      FILLER                          14568020
WRSCNT   DS    XL1                      COUNT FIELD                     14572020
*                                                                       14576020
*                                                                       14580020
* FOLLOWING IS THE VALIDITY CHECK CHANNEL PROGRAM OVERLAY.              14600020
*                                                                       14620020
VCMAP    DSECT                                                          14640020
*        SEEK  (CCW7)                                                   14660020
SEEKADDR DS    F                        SEEK ADDRESS               DM0I 14680020
SEEKOPCD EQU   SEEKADDR                                                 14700020
SEEKFLAG DS    XL1                      FLAG                       DM0I 14720020
         DS    CL2                      COUNT                      DM0I 14740020
SEEKLEN  DS    XL1                      SEEK LENGTH                DM0I 14760020
*                                                                       14780020
*        SEARCH (CCW8)                  LABELS PREFIXED BY 'VC' (VAL    14800020
VCSRCH   EQU   *                        CHECK).                         14820020
VCSRCHAD DS    F                        SEARCH ADDRESS             DM0I 14840020
VCSRCHOP EQU   VCSRCHAD                 SEARCH OP                  DM0I 14860020
VCSRCHFL DS    XL1                      FLAGS.                          14880020
         DS    CL2                      COUNT                      DM0I 14900020
VCSRCHLE DS    XL1                      LENGTH.                         14920020
*                                                                       14940020
*        TIC   (CCW9)                                                   14960020
VCTICAD  DS    F                        TIC                        DM0I 14980020
VCTICOP  EQU   VCTICAD                  TIC ADDRESS                DM0I 15000020
NOTUSED  DS    F                        NOT USED                   DM0I 15020020
*                                                                       15040020
*        READ DATA (CCW10)                                              15060020
VCRDAD   DS    F                        RECORD ADDRESS             DM0I 15080020
VCRDOP   EQU   VCRDAD                   RECORD ADDR.               DM0I 15100020
VCRDFLAG DS    XL1                      NORMALLY SKIP.                  15120020
VCRDLEN  DS    FL3                      RECORD LENGTH              DM0I 15140020
*                                                                       15160020
* FOLLOWING IS AN OVERLAY OF THE COUNT FIELD.                           15180020
*                                                                       15200020
COUNTFLD DSECT                                                          15220020
*                                                                       15240020
CYLINDER DS    H                        CYLINDER ADDRESS (CC).          15260020
HEAD     DS    H                        HEAD ADDRESS     (HH).          15280020
RECORD   DS    XL1                      RECORD NUMBER    (R).           15300020
KEYLENTH DS    XL1                      KEY LENGTH       (KL).          15320020
DLDL     DS    H                        DATA LENGTH      (DLDL).        15340020
*                                                                       15360020
* END COUNT FIELD. (CCHHRKDD)                                           15380020
*                                                                       15400020
*                                                                       15420020
* DIRECT ACCESS DEVICE TABLE OVERLAY                                    15440020
*                                                                       15460020
DEVTAB   DSECT                                                          15480020
DEVSIZE  DS    F                       MAX SIZ FOR DEVICE.              15500020
TRKCAP   DS    H                       TRACK CAPACITY.                  15520020
OVERI    DS    XL1                     OVERHEAD FOR NOT-LAST RECORD.    15540020
OVERL    DS    XL1                     OVERHEAD FOR LAST RECORD.        15560020
OVERK    DS    XL1                     OVERHEAD REDUCTION FOR NON-KEY   15580020
*                                      RECORDS.                         15600020
DEVFLAG  DS    XL1                      DEVICE FLAG                DM0I 15620020
TOLER    DS    H                       TOLERANCE/512 USED FOR VARIABLE  15640020
*                                       GAP LENGTH CALCULATIONS.        15660020
* END DEVTAB OVERLAY.                                                   15680020
*                                                                       15700020
*                                                                       15720020
         DCBD  DSORG=PS                                                 15740020
*                                                                       15760020
*                                                                       15780020
*                                                                       15800020
*                                                                       15820020
         IECDSECS MAIN,EXPAND=YES                                S21042 15850021
*                                                                       15880020
* IOB OVERLAY                                                           15900020
* THE FORECORE DSECT IOB OVERLAY IS USED WITH THE FOLOWING ADDITIONS-   15920020
*                                                                       15940020
* BSAM/BPAM/QSAM IOB EXTENSION-                                         15960020
SAMSIOB  EQU   DXIOB-8                  START OF SAM'S IOB.             15980020
LINK     EQU   SAMSIOB                  FORWARD CHAIN FIELD (TO NEXT    16000020
*                                       IOB).                           16020020
FLAG     EQU   LINK                     HI BYTE OF LINK USED AS FLAG.   16040020
ECB      EQU   DXIOB-4                  ECB                        DM0I 16060020
* END EXTENSION DEFINITIONS                                             16080020
*                                                                       16100020
IOBSEEK  EQU   DXDAADDR                 SEEK ADDRESS               DM0I 16120020
CHANPGM  EQU   DXDAADDR+8               START OF CHANNEL PROGRAM.       16140020
*                                       LENGTH MAY VARY.                16160020
* END IOB DEFINITIONS.                                                  16180020
*                                                                       16200020
DEB      EQU   DXDEB                                                    16220020
DEBOPATB EQU   DXDEBSYS                 DEB ADDRESS                DM0I 16240020
         END                                                            16260020
