         TITLE 'IGG019AF UPDATE ERROR ROUTINE'                          00020000
         COPY  LCGASMSW                                                 00030003
*********************************************************************** 00040000
*                                                                       00060000
         AIF   ('&LIB' EQ 'LIB1').OSLIB   CHECK FOR OS SYSTEM   XA02375 00070003
*                                                                       00070403
*         VS1 RELEASE 03 DELETIONS                                      00070803
*                                                               XA02375 00071603
*                                                                       00071703
.OSLIB   ANOP                                                           00071803
*          RELEASE 19 DELETIONS                                         00072000
*2174032800-033400                                               I19116 00073019
*2174059000                                                      A28693 00074019
*          RELEASE 20 DELETIONS                                         00075000
*0216                                                            A31982 00076020
*0216                                                            20201  00077020
*          RELEASE 21 DELETIONS                                         00078000
*   (REFER TO CODE FLAGGED AS XA02375)                          SA65714 00080003
*                                                                       00081003
*STATUS CHANGE LEVEL 004                                                00095020
*                                                                       00100000
*MODULE TYPE- QSAM SUBROUTINE LOADED BY LINKAGE EDITOR                  00120000
*                                                                       00140000
*FUNCTION/OPERATION- THIS ROUTINE IS THE UPDATE BUFFER ACQUISTION AND   00160000
*      ERROR DETERMINATION ROUTINE.  IT ACQUIRES THE NEXT SEQUENTIAL    00180000
*      IOB AND WAITS FOR COMPLETION. IT TESTS THE PREVIOUS EXCP STATUS  00200000
*      FOR:  1)NORMAL COMPLETION RETURNS TO GET ROUTINE                 00220000
*            2)INCOMPLETION ISSUES SVC 1 TO WAIT                        00240000
*            3)ABNORMAL COMPLETION DETERMINES TYPE OF ERROR AND         00260000
*                  A)LINKS TO USERS SYNAD ROUTINE IF PRESENT            00280000
*                  B)PERFORMS ACCEPT, SKIP, OR TERMINATE OPTION AS      00300000
*                       SPECIFIED AND PREPARES IOB'S FOR RESCHEDULING.  00320000
*            IF END-OF-VOLUME CONDITION EXISTED, UPDATES ARE COMPLETED  00340000
*      ON THIS VOLUME PRIOR TO ISSUING SVC 55 TO SAM EOV EXECUTOR TO    00360000
*      PREPARE FOR VOLUME SWITCHING.                                    00380000
*                                                                       00400000
*OPTIONS SUPPLIED- 1) SKIP      - SELF EXPLANATORY                      00420000
*                  2) ACCEPT    - SELF EXPLANATORY                      00440000
*                  3) TERMINATE - IF NO SYNAD OR OPTIONS ARE SPECIFIED  00460000
*                                                                       00480000
*EXTERNAL REFERENCES- DCB, IOB, USERS SAVE AREA                         00500000
*                                                                       00520000
*SUPERVISOR FUNCTIONS- EOV (SVC55)                                      00540000
*                     ABEND (SVC 13)                                    00560000
*                     EXCP (SVC 0)                                      00580000
*                     WAIT (SVC 1)                                      00600000
*                                                                       00620000
*EXTERNAL ROUTINES- SAM DIAGNOSTIC ROUTINE FOR VOLUME SWITCHING         00640000
*                   UPDATE END-OF-BLOCK ROUTINE FOR BUFFER REINITIAL-   00660000
*                   IZATION                                             00680000
*                                                                       00700000
*ENTRY POINT- IGG019AF FROM GET ROUTINE (IGG019AE) VIA BALR 14,15       00720000
*      REGISTER 2  DCB ADDRESS                                          00740000
*      REGISTER 3  ERROR IOB ADDRESS                                    00760000
*      REGISTER 13 USER SAVE AREA ADDRESS                               00780000
*      REGISTER 14 RETURN ADDRESS WITHIN QSAM ROUTINE                   00800000
*      REGISTER 15 IGG019AF FIRST LOCATION ADDRESS                      00820000
*                                                                       00840000
*INPUT- SEE DESCRIPTION OF REGISTERS                                    00860000
*                                                                       00880000
*OUTPUT- SEE DESCRIPTION OF REGISTERS                                   00900000
*                                                                       00920000
*EXITS-NORMAL- WAIT BY SVC 1                                            00940000
*              QSAM BY BCR 15,14                                        00960000
*                                                                       00980000
*EXITS-ERROR- SAM DIAGNOSTIC BY SVC 55 FOR VOLUME SWITCHING             01000000
*             SYNAD BY BALR 14,15                                       01020000
*                                                                       01040000
*********************************************************************** 01060000
*                                                                       01080000
**                                                                      01100000
RPARA0   EQU   0                        PARAMETER REG 0                 01120000
R0       EQU   0                                                  17091 01130000
RPARA1   EQU   1                        PARAMETER REG 1 AND IOB         01140000
DCBR     EQU   2                        DCBR REG                        01160000
IOBAR    EQU   3                        IOB  REG                        01180000
WORKR1   EQU   4                        ERR IOB NEXT COMMAND ADDR       01200000
WORKR2   EQU   5                        ERR IOB READ CCW OFFSET         01220000
WORKR3   EQU   6                        ENDING IOB IN RESCHEDULING LOOP 01240000
WORKR4   EQU   7                        READ CHANNEL PROG. POINTER      01260000
BASR     EQU   8                        BASE REG                        01280000
SAVR     EQU   13                       USERS SAVE AREA ADDR REG        01300000
RETR     EQU   14                       RETURN REG                      01320000
ENTR     EQU   15                       ENTRY REG                       01340000
*                                                                       01360000
**                                                                      01380000
*                                                                       01400000
COMPERR  EQU   X'7F'                    COMPLETE WITH NO ERROR MASK     01420000
READONLY EQU   X'20'                    IOB READ ONLY INDICATOR         01440000
UNITEXCP EQU   X'01'                    END OF VOLUME                   01460000
ACCEPTOP EQU   X'80'                    ACCEPT OPTION                   01480000
SKIPOP   EQU   X'40'                    SKIP OPTION                     01500000
CLOSEB   EQU   X'20'                                                    01520000
NOT      EQU   X'FF'                                                    01540000
EOVB     EQU   X'40'                    END OF VOLUME FLAG              01560000
FEOVB    EQU   X'02'                    FORCE END OF VOLUME BIT         01580000
UPDATFLG EQU   X'50'                    UPDATE FLAG                     01600000
PUTXERR  EQU   X'50'                    PUTX ERROR FLAG                 01620000
CC       EQU   X'40'                    COMMAND CHAIN FLAG              01640000
*                                                                       01644020
*        RECORD READY CONSTANTS                                         01648020
RDSECTOR EQU   X'22'                    READ SECTOR COMMAND CODE 20201  01652020
EIGHT    EQU   8                        CONSTANT OF EIGHT        20201  01656020
*                                                                       01660000
**                                                                      01680000
*                                                                       01700000
         USING IGG019AF,BASR                                            01720000
         USING IHADCB,DCBR                                              01740000
*                                                                       01760000
IGG019AF CSECT                                                          01780000
*                                                                       01782000
*                                                                       01784000
*                                                                       01786000
*                                                                       01788000
*                                                                       01790000
*                                                                       01792000
*                                                                       01794000
*                                                                       01796000
*                                                                       01798000
         STM   RETR,ENTR,64(SAVR)       SAVE ENTRY AND RETURN TO GET    01800000
         LR    BASR,ENTR                ESTABLISH BASE                  01820000
         L     IOBAR,0(IOBAR)           GET NEXT IOB IN SEQUENCE        01840000
         LA    IOBAR,0(IOBAR)           CLEAR HI BYTE                   01860000
*                                                                       01880000
*********************************************************************** 01900000
*                                                                       01920000
*      TEST STATUS OF IOB - WAIT FOR COMPLETION - RETURN TO GET IF      01940000
*           COMPLETE WITHOUT ERROR - ANY OTHER CONDITION, CONTINUE      01960000
*                                                                       01980000
*********************************************************************** 02000000
*                                                                       02020000
TESTCOMP EQU   *                                                        02040000
         TM    4(IOBAR),COMPERR         TEST FOR COMPLETION AND ERROR   02060000
         BO    RETURN                   BRANCH COMPLETE WITHOUT ERROR   02080000
         BM    ERROR                    BRANCH ON ERROR                 02100000
         WAIT  ECB=4(IOBAR)             INCOMPLETE- WAIT TILL COMPLETE  02120000
         B     TESTCOMP                 TEST AGAIN                      02140000
*                                                                       02160000
RETURN0  EQU   *                                                        02180000
         NI    DCBCIND2,NOT-EOVB        TURN OFF VOL FULL INDICATOR     02200000
*                                                                       02220000
RETURN   EQU   *                                                        02240000
         ST    IOBAR,DCBIOBA            UPDATE DCB TO CURRENT IOB       02260000
*                                                                       02280000
RETURN1  EQU   *                                                        02300000
         L     BASR,24(SAVR)            RESTORE BASE OF GET ROUTINE     02320000
         L     RETR,64(SAVR)            GET ADDRESS OF GET ROUTINE      02340000
         BR    RETR                     RETURN TO GET                   02360000
*                                                                       02380000
ERROR    EQU   *                                                        02400000
         SR    WORKR4,WORKR4            CLEAR REG                       02420000
         SR    WORKR1,WORKR1            CLEAR REG                       02440000
         IC    WORKR4,DCBWCPO           GET WRITE CHANNEL PROG. OFFSET  02460000
         IC    WORKR1,DCBWCPL           GET WRITE CHANNEL PROG. LENGTH  02480000
         SLL   WORKR1,3                 CHANGE DB WDS TO BYTES          02500000
         AR    WORKR4,WORKR1            COMBINE AND ADD 8 TO POINT TO   02520000
         LA    WORKR4,8(WORKR4)            CHANNEL PROG READ SEQUENCE   02540000
         L     WORKR1,16(IOBAR)         GET NEXT COMMAND ADDR FROM CSW  02560000
         LA    WORKR1,0(WORKR1)         CLEAR HI BYTE                   02580000
*                                                                       02600000
         NI    DCBIFLGS,X'3F'           TURN OFF ERROR FLAGS IN DCB     02620000
         TM    0(IOBAR),READONLY        IS THIS 'ONLY READ' CP          02640000
         BZ    ERRDETER                 NO, BRANCH                      02660000
*                                                                       02680000
VOLFULL  EQU   *                                                        02700000
         AR    WORKR4,IOBAR             ADD IOB ADDR TO RD CP OFFSET    02720000
         TM    20(IOBAR),UNITEXCP       DOES CSW INDICATE VOLUME FULL   02740000
         BO    RESCHED                  YES, BRANCH TO RESCHEDULE WRITE 02760000
*                                                                       02780000
SYNAD    EQU   *                                                        02800000
         TM    DCBCIND2,CLOSEB          ARE WE IN CLOSE                 02820000
         BC    1,RETURN                 YES,RETURN                      02840000
         TM    DCBSYNAD+3,X'01'         SYNAD PRESENT IN DCB            02860000
         BC    14,SYNAD1                YES, BRANCH                     02880000
*                                                                       02900000
ACCEPT   EQU   *                                                        02920000
         CLI   DCBEROPT,ACCEPTOP        ACCEPT OPTION SPECIFIED         02940000
         BC    8,ACCEPT1                YES, BRANCH                     02960000
*                                                                       02980000
         CLI   DCBEROPT,SKIPOP          SKIP OPTION SPECIFIED           03000000
         BC    8,SKIP                   YES, BRANCH                     03020000
*                                                                       03040000
         TM    0(IOBAR),READONLY        SEQUENSE IN WHICH ERROR OCCURED 03060000
         BO    RESCHED1                 READ ERROR                      03080000
*                                       WRITE ERROR                     03100000
*********************************************************************** 03120000
*                                                                       03140000
*      TERMINATE ONLY AFTER ALL PENDING UPDATES ARE RESCHEDULED AND     03160000
*           WRITTEN CORRECTLY                                           03180000
*                                                                       03200000
*********************************************************************** 03220000
*                                                                       03240000
TERM     EQU   *                                                        03260000
         LA    R0,1                                              I19116 03280019
         SLL   R0,12                                             I19116 03300019
         LR    RPARA1,DCBR                                       I19116 03320019
         SVC   55                                                I19116 03340019
*                                                                       03360000
*********************************************************************** 03380000
*                                                                       03400000
*      DETERMINE IF ERROR OCCURRED IN READ OR WRITE SEQUENCE OF CHANNEL 03420000
*           PROGRAM AND FLAG IOB FOR READ ONLY IF READ ERROR            03440000
*                                                                       03460000
*********************************************************************** 03480000
*                                                                       03500000
ERRDETER EQU   *                                                        03520000
         LR    WORKR2,WORKR4            COPY READ CP OFFSET             03540000
         AR    WORKR2,IOBAR             BUILD READ CP ADDRESS           03560000
         LA    WORKR2,0(WORKR2)         CLEAR HI BYTE                   03580000
         CR    WORKR1,WORKR2            COMPARE CSW ADDR TO RD CP ADDR  03600000
         BL    VOLFULL                  CSW IS LESS - ERR IN WRITE SEQ  03620000
*                                       RD CP ADDR IS LESS - RD SEQ ERR 03640000
         OI    0(IOBAR),READONLY        FLAG IOB FOR 'READ ONLY'        03660000
         B     VOLFULL                                                  03680000
*                                                                       03700000
*********************************************************************** 03720000
*                                                                       03740000
*      VOLUME FULL CONDITION EXISTS.  RESCHEDULE ALL PENDING UPDATES TO 03760000
*           THIS VOLUME PRIOR TO ISSUEING SVC 55 TO SWITCH VOLUMES.     03780000
*                                                                       03800000
*********************************************************************** 03820000
*                                                                       03840000
RESCHED  EQU   *                                                        03860000
         OI    DCBCIND2,EOVB            TURN ON END OF VOLUME FLAG      03880000
         MVI   4(IOBAR),COMPERR         SET IOB COMPLETE WITH NO ERROR  03900000
*                                                                       03920000
RESCHED1 EQU   *                                                        03940000
         LR    WORKR3,IOBAR             SAVE ERROR IOB ADDRESS          03960000
*                                                                       03980000
RESCHED2 EQU   *                                                        04000000
         ST    WORKR4,24(IOBAR)         SET IOB CP START ADDR TO READ   04020000
         SR    WORKR4,IOBAR             RESTORE RD CP OFFSET            04040000
         OI    0(IOBAR),READONLY        TURN ON READ ONLY FLAG          04060000
RESCHED3 EQU   *                                                        04112000
         L     IOBAR,0(IOBAR)           LINK TO NEXT IOB IN SEQUENCE    04120000
         LA    IOBAR,0(IOBAR)           CLEAR HI BYTE                   04140000
         CR    WORKR3,IOBAR             HAS THIS IOB BEEN RESCHEDULED   04160000
         BC    8,RESCHED8               YES, BRANCH OUT                 04180000
*                                                                       04200000
         TM    0(IOBAR),READONLY        WHAT TYPE CP WAS TO BE EXECUTED 04220000
         BC    1,RESCHED3               READ ONLY                       04240000
*                                                                       04260000
         AR    WORKR4,IOBAR             CAL RD SEQ. START ADDR          04280000
         LA    WORKR1,16                SUBTRACT 16 TO POINT TO         04300000
         SR    WORKR4,WORKR1              WRITE CCW                     04320000
         NI    4(WORKR4),NOT-CC         TURN OFF COMMAND CHAIN BIT      04340000
*                                                                       04360000
         LA    RPARA1,8(IOBAR)          POINT TO IOS'S IOB              04380000
*                                                                       04400000
         EXCP  (1)                      RESCHEDULE WRITE IOB            04420000
*                                                                       04440000
*********************************************************************** 04460000
*                                                                       04480000
*      TEST EACH RESCHEDULED IOB FOR COMPLETION WITHOUT ERROR. IF AN    04500000
*           ERROR OCCURS GO TO USERS SYNAD ROUTINE.                     04520000
*                                                                       04540000
*********************************************************************** 04560000
*                                                                       04580000
RESCHED4 EQU   *                                                        04600000
         TM    4(IOBAR),COMPERR         TEST FOR COMPLETION AND ERROR   04620000
         BO    RESCHED5                 COMPLETE WITHOUT ERROR          04640000
         BM    RESCHED6                 ERROR                           04660000
         WAIT  ECB=4(IOBAR)             INCOMPLETE- WAIT TILL COMPLETE  04680000
         B     RESCHED4                 TEST AGAIN                      04700000
*                                                                       04720000
RESCHED5 EQU   *                                                        04740000
         OI    4(WORKR4),CC             RESET COMMAND CHAIN BIT         04760000
         AR    WORKR4,WORKR1            RESTORE READ CP OFFSET          04780000
         B     RESCHED2                                                 04800000
*                                                                       04820000
RESCHED6 EQU   *                                                        04840000
         TM    DCBSYNAD+3,X'01'         SYNAD USED                      04860000
         BO    RESCHED7                 NO, BRANCH                      04880000
*                                                                       04900000
         TM    DCBCIND2,CLOSEB          WERE WE IN CLOSE EXECUTOR       04920000
         BC    1,RETURN                 YES,RETURN                      04940000
         B     SYNAD1                   NO, BRANCH                      04960000
*                                                                       04980000
RESCHED7 EQU   *                                                        05000000
         CLI   DCBEROPT,ACCEPTOP        ACCEPT OPTION                   05020000
         BC    8,RESCHED5               YES, BRANCH                     05040000
*                                                                       05060000
         CLI   DCBEROPT,SKIPOP          SKIP OPTION                     05080000
         BC    8,RESCHED5               YES, BRANCH                     05100000
         B     TERM                     NO, TERMINATE                   05120000
*                                                                       05140000
RESCHED8 EQU   *                                                        05160000
         TM    DCBCIND2,FEOVB           FEOV SPECIFIED                  05180000
         BO    RETURN0                  YES, RETURN TO CALLER           05200000
*                                                                       05220000
         TM    DCBCIND2,CLOSEB          WERE WE IN CLOSE EXECUTOR       05240000
         BO    RETURN                   YES, BRANCH                     05260000
*                                                                       05280000
         TM    DCBCIND2,EOVB            RESCHEDULING WRITES FOR EOV     05300000
         BC    14,TERM                  NO, TERMINATE                   05320000
*                                                                       05340000
         LR    RPARA0,IOBAR             SET UP PARAMETERS FOR           05360000
         LR    RPARA1,DCBR                SVC ROUTINE                   05380000
*                                                                       05400000
         EOV   0(1)                     GO TO SWITCH VOLUMES            05420000
*                                                                       05440000
         B     TESTCOMP                                                 05460000
*                                                                       05480000
*********************************************************************** 05500000
*                                                                       05520000
*      PASS PARAMETERS TO USERS SYNAD ROUTINE.  IF USER RETURNS CONTROL 05540000
*           DETERMINE IF EOV CONDITION EXISTS AND COMPLETE RESCHEDULING 05560000
*           ALL PENDING UPDATES.  IF NOT EOV PERFORM USERS ERROR OPTION 05580000
*                                                                       05600000
*********************************************************************** 05620000
*                                                                       05640000
SYNAD1   EQU   *                                                        05660000
         L     ENTR,DCBSYNAD            GET SYNAD ADDRESS               05680000
         SR    WORKR1,WORKR1            CLEAR REG                       05700000
         SR    WORKR2,WORKR2            CLEAR REG                       05720000
         L     WORKR2,READERR          GET BIT FOR READ ERROR    A31982 05730020
         LR    RPARA1,DCBR              GET DCB ADDR FOR SYNAD PARAM    05740000
         OR    RPARA1,WORKR2           SET BIT FOR READ ERROR    A31982 05746020
         SR    WORKR2,WORKR2           CLEAR REG                 A31982 05752020
         TM    0(IOBAR),UPDATFLG        IOB BEING UPDATED               05760000
         BC    1,SYNAD2                 YES BRANCH                      05780000
*                                                                       05800000
         IC    WORKR1,DCBOFFSR          GET READ CCW OFFSET             05820000
         B     SYNAD3                                                   05840000
*                                                                       05860000
SYNAD2   EQU   *                                                        05880000
         LA    WORKR2,PUTXERR           GET PUTX ERROR INDICATOR A28693 05900019
         SLL   WORKR2,24                SHIFT TO HIGH ORDER BYTE        05920000
         OR    RPARA1,WORKR2            PLACE IN SAME REG AS DCB ADDR   05940000
         IC    WORKR1,DCBOFFSW          GET WRITE CCW OFFSET            05960000
*                                                                       05980000
SYNAD3   EQU   *                                                        06000000
         SLL   WORKR1,24                SHIFT TO HIGH ORDER BYTE        06020000
         LA    WORKR2,8(IOBAR)          PUT IOB ADDR IN SAME REG AS     06040000
         OR    WORKR1,WORKR2              OFFSET                        06060000
         LR    RPARA0,WORKR1            LOAD SYNAD PARAMETER REG        06080000
         LM    DCBR,BASR,36(SAVR)       RESTORE USERS REGS 2-8          06100000
**                                                                      06120000
         BALR  14,15                    TO USERS SYNAD ROUTINE          06140000
**                                                                      06160000
         STM   DCBR,BASR,36(SAVR)       SAVE USERS REGS 2-8             06180000
         L     BASR,68(SAVR)            REESTABLISH BASE                06200000
         LR    DCBR,RPARA1              RE-ESTABLISH DCB ADDR. AND      06220000
         L     IOBAR,DCBIOBA              IOB ADDR.                     06240000
         SR    WORKR4,WORKR4              CLEAR REGISTER        XA02375 06250003
         SR    WORKR1,WORKR1              CLEAR REGISTER        XA02375 06252003
         IC    WORKR4,DCBWCPO             GET WRITE CHAN PROG   XA02375 06254003
*                                           OFFSET                      06256003
         IC    WORKR1,DCBWCPL             GET WRITE CHAN PROG   XA02375 06258003
*                                           LENGTH                      06258403
         SLL   WORKR1,3                   CHANGE DB WDS TO      XA02375 06258803
*                                           BYTES                       06258903
         AR    WORKR4,WORKR1              COMBINE AND ADD 8 TO  XA02375 06259203
         LA    WORKR4,8(WORKR4)             POINT TO CHANNEL    XA02375 06259603
*                                           PROG READ SEQUENCE          06259703
         AR    WORKR4,IOBAR               OBTAIN ADDR OF READ   XA02375 06259803
*                                           CHAN PROG                   06259903
         TM    DCBCIND2,EOVB            WERE WE RESCHEDULING WRITES     06260000
         BO    RESCHED7                 YES, RETURN TO RESCHEDULING     06280000
         B     ACCEPT                   NO, CHECK USERS OPTIONS         06300000
*                                                                       06320000
*********************************************************************** 06340000
*                                                                       06360000
*      ACCEPT ERROR IOB AND RESCHEDULE PURGED IOB'S                     06380000
*                                                                       06400000
*********************************************************************** 06420000
*                                                                       06440000
ACCEPT1  EQU   *                                                        06460000
         ST    IOBAR,DCBIOBA            SAVE ERROR IOB FOR USER         06480000
         LR    WORKR3,IOBAR             SAVE ERROR IOB TO END LOOP      06500000
*                                                                       06520000
         TM    0(IOBAR),READONLY        ERROR REC. FROM RD. OR WRT. SEQ 06540000
         BO    ACCEPT2                  READ ERROR                      06560000
*                                       WRITE ERROR                     06580000
         ST    WORKR4,24(IOBAR)         SET IOB CP START ADDR TO READ   06600000
*                                                                       06620000
         MVC   40(8,IOBAR),40(WORKR4)   MOVE RD.SEQ. SEEK ADDR. TO IOS  06640000
         B     SCHED1                     IOB LOCATION                  06660000
*                                                                       06680000
ACCEPT2  EQU   *                                                        06700000
         MVI   4(IOBAR),COMPERR         FLAG IOB COMPLETE WITHOUT ERROR 06720000
         B     SCHED2                                                   06740000
*                                                                       06760000
SCHED1   EQU   *                                                        06780000
         LA    RPARA1,8(IOBAR)          POINT TO IOS'S IOB              06800000
*                                                                       06820000
         EXCP  (1)                      RESCHEDULE THIS IOB             06840000
*                                                                       06860000
SCHED2   EQU   *                                                        06880000
         L     IOBAR,0(IOBAR)           LINK TO NEXT IOB IN SEQUENCE    06900000
         LA    IOBAR,0(IOBAR)           CLEAR HI BYTE                   06920000
*                                                                       06940000
         CR    WORKR3,IOBAR             HAS THIS IOB BEEN RESCHEDULED   06960000
         BC    8,TESTCOMP               YES, TEST FOR COMPLETION        06980000
         B     SCHED1                   NO, RESCHEDULE IT               07000000
*                                                                       07020000
*********************************************************************** 07040000
*                                                                       07060000
*      SKIP ERROR IOB AND RESCHEDULE PURGED IOB'S                       07080000
*                                                                       07100000
*********************************************************************** 07120000
*                                                                       07140000
SKIP     EQU   *                                                        07160000
         TM    0(IOBAR),READONLY        ERROR REC. FROM READ OR WRITE   07180000
         BC    14,ACCEPT1               WRITE - SAME AS ACCEPT OPTION   07200000
*                                       READ - GO TO REINITIALIZE IOB   07220000
         OI    0(IOBAR),READONLY        FLAG IOB FOR 'READ ONLY'        07240000
         L     IOBAR,0(IOBAR)           LINK TO NEXT IOB IN SEQUENCE    07260000
         LA    IOBAR,0(IOBAR)           CLEAR HI BYTE                   07280000
         ST    IOBAR,DCBIOBA            SAVE FOR USER                   07300000
         LR    WORKR3,IOBAR             SAVE AS ENDING IOB IN LOOP      07320000
         CLI   DCBBUFNO,X'01'           ONE IOB ONLY USED               07340000
         BH    SCHED1                   NO, BRANCH                      07360000
         SR    WORKR2,WORKR2            CLEAR REG                       07380000
         IC    WORKR2,DCBOFFSR          GET OFFSET TO RD DATA CCW       07400000
         AR    WORKR2,IOBAR             POINT TO RD DATA CCW THIS IOB   07420000
         CLI   EIGHT(WORKR2),RDSECTOR   IS IT RECORD READY       20201  07424020
         BNE   LAB01                    NO, FORGET INCREMENTING  20201  07428020
         LA    WORKR2,EIGHT(WORKR2)     BUMP PAST READ SECTOR    20201  07432020
LAB01    EQU   *                                                 20201  07436020
         MVC   11(5,WORKR2),DCBFDAD+3   PLACE FDAD IN SPECIAL FDAD      07440000
         B     SCHED1                   RESCHEDULE                      07460000
         DS    0F                                                A31982 07466020
READERR  DC    X'90000000'             BITS FOR READ ERROR       A31982 07472020
*                                                                       07480000
*********************************************************************** 07500000
*                                                                       07520000
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY   07540000
*                                                                       07560000
*********************************************************************** 07580000
*                                                                       07600000
         CNOP  0,8                 PAD MODULE TO DOUBLE WORD MULTIPLE   07620000
*                                                                       07640000
*********************************************************************** 07660000
*                                                                       07680000
         DCBD  DSORG=PS                                                 07700000
         END                                                            07720000
