         TITLE 'IECQSPLF PUT LOCATE SIMPLE BUFFER - F,FB,U RECORDS'     00020000
*FUNCTION-TO PROVIDE THE ADDRESS OF AN AREA WITHIN AN OUTPUT BUFFER   * 00040000
*      LARGE ENOUGH TO HOLD AN OUTPUT RECORD AND TO REGARD THE BUFFER * 00060000
*      AS FULL WHEN A PUT CAN NO LONGER SATISFY THE REQUEST.          * 00080000
*      -TRUNC CAUSES THE CURRENT OUTPUT BUFFER TO BE REGARDED AS FULL.* 00100000
*ENTRY POINTS                                                         * 00120000
*        ENTRY 1 (PUT)                 ENTRY 2 (TRUN)                   00140000
*        LA    1,DCB                   LA    1,DCB                      00160000
*        L     15,48(15)               L     15,48(15)                  00180000
*        BALR  14,15                   BAL   14,8(15)                   00200000
*INPUT-FROM PROBLEM PROGRAM AS ADDRESSES IN REGISTERS                 * 00220000
*        REG   13                                                       00240000
*        REG   14                                                       00260000
*        REG   15                                                       00280000
*        REG   1                                                        00300000
*OUTPUT                                                                 00320000
*        REG   1   ADDRESS OF 'AREA' LOCATED                            00340000
*      -RECORD LENGTH IN CCW FOR DEV.DEP.EOB ROUTINE                  * 00360000
*      -DCB,IOB ADDRESSES IN REGISTERS FOR EOB AND ERROR ROUTINES     * 00380000
*EXTERNAL ROUTINES                                                    * 00400000
*      -DEVICE DEPENDENT END OF BLOCK ROUTINE-SETS PARAMETERS FOR IOS * 00420000
*      -IECQPERR ERROR ROUTINE-PROCESSES ERRORS                       * 00440000
*EXIT  -TO USER BY UNCONDITIONAL BRANCH                               * 00460000
*      -TO ERROR ROUTINE BY BRANCH AND LINK                           * 00480000
*      -TO EOB ROUTINE BY BRANCH AND LINK                             * 00500000
*TABLES/WORKAREAS                                                     * 00520000
*      -DCB,IOB,SAVE AREA                                             * 00540000
*ATTRIBUTES-REENTRANT,PROBLEM PROGRAM MODE                            * 00560000
*NOTES-ONLY FOR 'F','FB'OR 'U' RECORDS                                * 00580000
*     -ALL REGISTER EQUATES HAVE AN 'R' AT BEGINNING OR END OF SYMBOL * 00600000
SAVR     EQU   13                                                       00620000
RETR     EQU   14                                                       00640000
ENTRYR   EQU   15                                                       00660000
RPARA0   EQU   0                                                        00680000
RPARA1   EQU   1                                                        00700000
DCBR     EQU   2                                                        00720000
IOBAR    EQU   3                                                        00740000
EOBADR   EQU   4                                                        00760000
RECADR   EQU   5                                                        00780000
LRECLR   EQU   6                                                        00800000
WORKR    EQU   7                                                        00820000
BASR     EQU   8                                                        00840000
COMPLETE EQU   X'60'                                                    00860000
BLOCKBIT EQU   X'10'                                                    00880000
WBIT     EQU   X'40'                                                    00900000
TRUNCBIT EQU   X'01'                                                    00920000
*                                                                     * 00940000
*                                                                     * 00960000
IGG019AI CSECT                                                          00980000
*20800158                                                         10040 00990013
         USING IGG019AI,ENTRYR                                          01000000
         USING IHADCB,RPARA1                                            01020000
*                                                                     * 01040000
*                                                                     * 01060000
ENTRY1   EQU   *                                                        01080000
         B     START-TRUNC+8(ENTRYR)   BRANCH AROUND TRUNC              01100000
         DC    X'00000000'                                              01120000
ENTRY2   EQU   *                                                        01140000
TRUNC    EQU   *                                                        01160000
         MVC   73(3,RPARA1),77(RPARA1) PLACE RECAD IN EOBAD             01180000
         BCR   15,RETR                 RETURN TO USER                   01200000
START    EQU   *                                                        01220000
         DROP ENTRYR                                                    01240000
         DROP RPARA1                                                    01260000
         USING IGG019AI,BASR                                            01280000
         USING IHADCB,DCBR                                              01300000
         STM   RETR,BASR,20(SAVR)      SAVE USER REGS                   01320000
         LR    DCBR,RPARA1             DCB  REGISTER                    01340000
         LR    BASR,ENTRYR             BASE REGISTER                    01360000
         LM    IOBAR,LRECLR,DCBIOBA    LOAD WORK REGS                   01380000
         CR    EOBADR,RECADR           TEST FOR END OF BLOCK            01400000
         BH    IECQSPL5                BRANCH NO                        01420000
*                                                                     * 01440000
*                                                                     * 01460000
         SR    WORKR,WORKR             CLEAR REG                        01480000
         IC    WORKR,DCBOFFSW          CCW OFFSET                       01500000
         L     EOBADR,0(WORKR,IOBAR)   BUFFER ADDRESS                   01520000
         LA    EOBADR,0(EOBADR)        CLEAR BYTE ZERO                  01540000
         SR    RECADR,EOBADR           RECORD LENGTH                    01560000
         BZ    IECQSPL3          ZERO LENGTH INDICATES            10040 01580013
*                                      PREVIOUS OUTPUT                * 01600000
         LR    LRECLR,RECADR           COPY PHYSICAL LENGTH             01620000
URCD     EQU   *                                                        01640000
         STH   LRECLR,6(WORKR,IOBAR)   LENGTH TO CCW                    01660000
         OI    0(IOBAR),WBIT           TURN ON WRITE BIT                01680000
         OI    DCBOFLGS,X'80'          INDICATE OUTPUT IN DCB           01700000
         L     ENTRYR,DCBEOB           END OF BLOCK ROUTINE ADDRESS     01720000
EXIT2    EQU   *                                                        01740000
         BALR  RETR,ENTRYR             TO EOB ROUTINE                   01760000
IECQSPL1 EQU   *                                                        01780000
         L     ENTRYR,DCBPERR          ADDRESS ERROR ROUTINE            01800000
EXIT3    EQU   *                                                        01820000
         BALR  RETR,ENTRYR             TO ERROR ROUTINE                 01840000
IECQSPL3 EQU   *                                                        01860000
         L     RECADR,0(WORKR,IOBAR)   BUFFER ADDRESS                   01880000
         LA    RECADR,0(RECADR)        CLEAR BYTE ZERO                  01900000
         LR    EOBADR,RECADR           COPY ADDRESS                     01920000
*        TM    DCBRECFM,X'10'          BLOCKED RECORD                 * 01940000
*        BZ    NOTBLOCK                                               * 01960000
* ABOVE 2 INSTRUCTIONS REMOVED AS EXECUTOR MAKES LRECL AND BLKSIZE    * 01980000
* THE SAME FOR 'U' RECORDS ALSO INST AT LOCATION NOTBLOCK             * 02000000
*                                                                     * 02020000
*                                                                     * 02040000
         AH    EOBADR,DCBBLKSI         ADD BUFFER LENGTH                02060000
IECQSPL5 EQU   *                                                        02080000
         LR    RPARA1,RECADR           COPY RECAD FOR USER              02100000
         AH    RECADR,DCBLRECL         DETERMINE NEXT RECORD ADDRESS    02120000
         TM    DCBRECFM,X'C0'          TEST FOR U-FORM RECORDS          02140000
         BM    IECQSPL4                 NO, BRANCH AND CONTINUE         02160000
         LR    EOBADR,RECADR            YES, INDICATE END OF BUFFER     02180000
IECQSPL4 EQU   *                                                        02200000
         STM   IOBAR,RECADR,DCBIOBA    REINITILIZE DCB                  02220000
EOB      EQU   *                                                        02240000
         LM    DCBR,BASR,36(SAVR)      RESTORE REGS                     02260000
         L     RETR,20(SAVR)           RESTORE  RETURN                  02280000
EXIT1    EQU   *                                                        02300000
         BCR   15,RETR                 RETURN TO USER                   02320000
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY   02340000
         CNOP  0,8                 PAD MODULE TO DOUBLE WORD MULTIPLE   02360000
*NOTBLOCK  AH  EOBADR,DCBLRECL                                        * 02380000
*        B     IECQSPL5                                               * 02400000
* ABOVE 2 INSTRUCTIONS REMOVED AS ABOVE                               * 02420000
*                                                                     * 02440000
         DCBD  DSORG=PS                                                 02460000
         END                                                            02480000
