         TITLE 'IGG019AT - PAPER TAPE GET TRANSLATE'                    00020000
IGG019AT CSECT                                                          00023000
*          RELEASE 19 DELETIONS                                         00044000
*1782083960                                                      A26737 00044519
*1782085000-085200                                               I19116 00045019
*          RELEASE 20 DELETIONS                                         00047000
*3520                                                            A38818 00047220
*3520083400-083880                                               A31186 00047520
*3520075800-076200                                               A32500 00048020
*3520                                                            A35769 00049020
*3520098600                                                      A38817 00049520
*          RELEASE 21 DELETIONS                                         00050000
*STATUS CHANGE LEVEL 009                                                00055021
*FUNCTION/OPERATION - THIS ROUTINE WILL TRANSLATE CHARACTERS FROM THE * 00060000
*      INPUT BUFFER(S) AND SEND THE TRANSLATIONS TO THE WORK AREA.    * 00080000
*      TRANSLATION WILL CEASE WHEN THE AMOUNT SPECIFIED IN DCBBLKSI   * 00100000
*      HAS BEEN SENT TO THE WORK AREA, THE INPUT FROM THE CURRENT TAPE* 00120000
*      HAS BEEN EXHAUSTED, ALL CHARACTERS UP TO,BUT NOT INCLUDING,THE * 00140000
*      LAST CHARACTER OF AN INPUT RECORD FOR WHICH HARDWARE SIGNALED  * 00160000
*      A DATA CHECK HAVE BEEN TRANSLATED, OR ALL CHARACTERS PRECEDING * 00180000
*      AN EOR HAVE BEEN TRANSLATED.                                   * 00200000
*                                                                     * 00220000
*ENTRY POINTS - IGG019AT   GET,    L     15,DCBGET                    * 00240000
*                                  BALR  14,15                        * 00260000
*                                                                     * 00280000
*INPUT - REGISTER 0 - WORK AREA ADDRESS.                              * 00300000
*        REGISTER 1 - DCB ADDRESS.                                    * 00320000
*        DCBCIND1 - EOF INDICATION.                                   * 00340000
*        DCBRECAD - CURRENT ADDRESS IN INPUT BUFFER.                  * 00360000
*        DCBLCTBL - ADDRESS OF LOWER CASE TRANSLATION TABLE.          * 00380000
*        DCBEOBAD - ADDRESS+1 OF END OF CURRENT INPUT BUFFER.         * 00400000
*        DCBBLKSI - NUMBER OF TRANSLATED CHARACTERS REQUESTED.        * 00420000
*        DCBIOBA  - IOB ADDRESS.                                      * 00440000
*        DCBEOB   - END OF BUFFER ROUTINE ADDRESS.                    * 00460000
*        DCBOFFSR - LOCATION OF CHANNEL PROGRAM IN IOB.               * 00480000
*        DCBSYNAD - LOCATION OF SYNCHRONOUS ERROR ROUTINE.            * 00500000
*        DCBEROPT - ERROR OPTION.                                     * 00520000
*        DCBEODAD - END OF DATA ROUTINE ADDRESS.                      * 00540000
*OUTPUT - WORK AREA - STRING OF TRANSLATED CHARACTERS.                * 00560000
*        DCBLRECL - NUMBER OF CHARACTERS IN STRING.                   * 00580000
*                                                                     * 00600000
*EXTERNAL ROUTINES - IGG019CC - END OF BUFFER ROUTINE                 * 00620000
*      IGG019CS - WRONG LENGTH RECORD CHECKING APPENDAGE              * 00640000
*      IGG019CM -   TELETYPE TRANSLATION TABLES                       * 00660000
*      IGG019CN -      ASCII TRANSLATION TABLES                       * 00680000
*      IGG019CO -  BURROUGHS TRANSLATION TABLES                       * 00700000
*      IGG019CP -     FRIDEN TRANSLATION TABLES                       * 00720000
*      IGG019CQ - IBM PTTC/8 TRANSLATION TABLES                       * 00740000
*      IGG019CR -        NCR TRANSLATION TABLES                       * 00760000
*                                                                     * 00780000
*EXITS-NORMAL - TRANSLATION REQUEST HAS BEEN SATISIFED,  BR    14     * 00800000
*             - END OF FILE ON PAPER TAPE READER,   L     15,DCBEODAD * 00820000
*                                                   BR    15          * 00840000
*     -ERROR - PARITY ERROR OR WRONG LENGTH RECORD, L     15,DCBSYNAD * 00860000
*              SEE CPS MANUAL FOR ERROR CODES.      BALR  14,15       * 00880000
*            - NO ERROR OPTION ON RETURN FROM SYNAD,     SVC   ABEND  * 00900000
*              REGISTER 1 SET TO 00001000.                            * 00920000
*                                                                     * 00940000
*ATTRIBUTES - REENTRANT.                                              * 00960000
*                                                                     * 00980000
*NOTES- NO TAPE POSITIONING WILL TAKE PLACE AFTER AN ERROR.             01000000
*      EOR SWITCHES MUST NOT BE USED WITH TYPE F RECORDS.             * 01020000
*REGISTER USAGE-                                                        01040000
*                                                                       01060000
*                                                                       01080000
*                                                                       01100000
R0       EQU   0         INITIALLY CONTAINS THE WORK AREA ADDRESS       01120000
R1       EQU   1         INITIALLY CONTAINS THE DCB ADDRESS             01140000
R2       EQU   2                                                        01160000
R3       EQU   3                                                        01180000
R4       EQU   4                                                        01200000
R5       EQU   5                                                        01220000
R6       EQU   6                                                        01240000
R7       EQU   7                                                        01260000
R8       EQU   8                                                        01280000
R13      EQU   13        USERS SAVEAREA(18 WORDS)                       01300000
R14      EQU   14        USERS RETURN ADDRESS                           01320000
R15      EQU   15        THIS MODULES BEGINING LOCATION                 01340000
*                                                                       01360000
PAR0     EQU   R0                  PARAMETER REGISTER 0.                01380000
CTR      EQU   R0                  COUNT OF CHARACTERS TRANSLATED.      01400000
PAR1     EQU   R1                  PARAMETER REGISTER 1.                01420000
RSIZR    EQU   R1                  RECORD SIZE.                         01440000
IOBR     EQU   R3                  IOB BASE ADDRESS REGISTER.           01460000
CCWR     EQU   R4                  CCW ADDRESS.                         01480000
CTRTR    EQU   R4                  CURRENT TRANSLATION TABLE ADDRESS.   01500000
WORK     EQU   R4                  WORK REGISTER.                       01520000
WAR      EQU   R5                  WORK AREA ADDRESS.                   01540000
DCBR     EQU   R6                  DCB BASE ADDRESS REGISTER.           01560000
BASER    EQU   R7                  ROUTINE BASE ADDRESS.                01580000
RECR     EQU   R8                  ADDRESS OF NEXT CHAR IN INPUT.       01600000
SAVR     EQU   R13                 SAVE AREA BASE ADDRESS.              01620000
RETR     EQU   R14                 CONTAINS RETURN ADDRESS.             01640000
ENTR     EQU   R15                 CONTAINS BASE ON ENTRY.              01660000
TRTBR    EQU   R15                 LOWER CASE TRANSLATION TABLE ADDRESS 01680000
*                                                                       01700000
* THE EOF EXIT IS TAKEN BY THE GET FOLLOWING THE ONE WHICH PROVIDES THE 01720000
* USER WITH THE LAST CHARACTER OF THE DATA.                             01740000
*                                                                       01760000
* ONLY THE GET DCB,AREA(MOVE MODE) MACRO CAN BE USED.                   01780000
*                                                                       01800000
* TRANSLATION WILL BE PERFORMED AT THE TIME THE DATA IS MOVED FROM THE  01820000
* INPUT BUFFER TO THE WORK AREA.                                        01840000
*                                                                       01860000
*                                                                       01880000
* TAPE CODE TRANSLATION- THE IBM 2671 PAPER TAPE READER IS CAPABLE OF   01900000
*        READING ANY TAPE CODE THAT CAN BE PUNCHED IN 5, 6, 7, OR 8     01920000
*        TRACK TAPE. THIS IS POSSIBLE BECAUSE THE TRANSLATION OF THE    01940000
*        CODE PUNCHED IN THE TAPE IS PERFORMED BY THE SYSTEM/360. THE   01960000
*        EIGHT TRACKS OF THE PAPER TAPE READER ARE CONNECTED TO THE     01980000
*        SYSTEM I/O CHANNEL BY BUS-IN-LINES IN THE FOLLOWING MANNER:    02000000
*                                                                       02020000
*        TRACK NUMBER  8  7  6  5  4  3  2  1  GENERATED-ODD-PARITY     02040000
*                      V  V  V  V  V  V  V  V  V                        02060000
*        BUS-IN-LINE   0  1  2  3  4  5  6  7  P                        02080000
*                                                                       02100000
*                                                                       02120000
*        WHEN THE WIDTH OF THE TAPE IS SUCH THAT A TRACK DOES NOT       02140000
*        EXIST, A ZERO BIT IS TRANSMITTED FOR THAT TRACK POSITION.      02160000
*                                                                       02180000
*        THE EIGHT BUS-IN-LINES CONNECTED TO THE 8 BITS OF A CORE       02200000
*        STORAGE BYTE IN THE SYSTEM/360 IN THE FOLLOWING MANNER:        02220000
*                                                                       02240000
*        BUS-IN-LINES  0  1  2  3  4  5  6  7                           02260000
*                      V  V  V  V  V  V  V  V                           02280000
*        CORE STORAGE  0  1  2  3  4  5  6  7                           02300000
*                                                                       02320000
*                                                                       02340000
*        A HOLE PUNCHED IN A TRACK OF PAPER TAPE IS REPRESENTED AS A 1  02360000
*        BIT IN ITS RESPECTIVE POSITION OF CORE STORAGE. A BLANK IN A   02380000
*        TRACK OF PAPER TAPE IS REPRESENTED AS A ZERO BIT IN ITS        02400000
*        RESPECTIVE POSITION OF CORE STORAGE.                           02420000
*                                                                       02440000
*        TRACKS (1-8) RUN FROM THE BOTTOM OF THE TAPE TO THE TOP.       02460000
*                                                                       02480000
*                                                                       02500000
*                                                                       02520000
*        IMMEDIATE OPERAND DEFINITIONS                                  02540000
         SPACE 1                                                        02560000
OKBITS   EQU   X'7F'               ECB FLAGS FOR COMPLETE, NO ERROR.    02580000
CASBIT   EQU   X'02'               BIT INDICATING UPPER OR LOWER CASE.  02600000
RCASBIT  EQU   X'FD'               BITS TO RESET CASBIT (TO LOWER CASE) 02620000
INVBIT   EQU   X'10'               INVALID CHARACTER FOUND.             02640000
RINVBIT  EQU   X'FE'               BITS TO RESET INVBIT.                02660000
EOFBIT   EQU   X'01'               BIT TO TEST CSW FOR EOF.             02680000
SKIP     EQU   X'40'               DCB FLAG FOR SKIP OPTION ON PERM     02700000
*                                    ERROR.                             02720000
ACCEPT   EQU   X'80'               DCB FLAG FOR ACCEPT OPTION ON PERM   02740000
*                                    ERROR.                             02760000
CEOF     EQU   X'20'               END OF FILE INDICATOR IN CIND1.      02780000
CHERR    EQU   X'01'               ERROR ENCOUNTERED IN CURRENT IOB.    02800000
CHEOR    EQU   X'04'               EOR ENCOUNTERED IN CURRENT IOB.      02820000
EORHIT   EQU   X'08'               EOR REACHED IN TRANSLATION.          02840000
SYNINV   EQU   X'84'               HIGH ORDER BYTE OF REG 1 FOR   24610 02850018
*                                       SYNAD                     24610 02860018
*                                  INPUT BIT X'80', INVALID BIT X'04'   02870018
ADSYNAD  EQU   X'01'               SYNAD NOT PRESENT FLAG.              02880000
RESET    EQU   X'00'                                                    02900000
DATACHK  EQU   X'08'               DATA CHECK BIT IN SENSE BYTE.        02920000
FMU      EQU   X'C0'               FORMAT U MASK.                       02940000
ILBIT    EQU   X'40'               INCORRECT LENGTH BIT IN CSW2.        02960000
         SPACE 1                                                        02980000
*                                                                       03000000
*                                                                       03020000
*                                                                       03080000
         USING IGG019AT,BASER      BASE REGISTER ESTABLISHED.           03100000
         USING IHADCB,DCBR         DCB BASE ESTABLISHED.                03120000
*                                                                       03140000
         STM   R14,R8,20(SAVR)     SAVE USER REGISTERS.                 03160000
*                                                                       03180000
         LR    BASER,ENTR          LOAD BASE REGISTER AND               03200000
         LR    DCBR,PAR1           DCB BASE REG.                        03220000
         TM    DCBCIND1,CEOF       WAS EOF ENCOUNTERED DURING LAST GET? 03240000
         BO    GPTFEOF             YES, GO TO END OF VOLUME.            03260000
         L     RECR,DCBRECAD       SET UP RECORD ADDRESS AND            03280000
         LA    RECR,0(RECR)          SEE IF IT IS ZERO. IF SO,          03300000
         LTR   RECR,RECR             INITIALIZE FOR FIRST GET           03320000
         BZ    GPTFINIT              ON THIS DATA SET.                  03340000
*                                                                       03360000
GPTFINRT EQU   *                                                        03380000
*                                                                       03400000
         L     WAR,28(SAVR)        LOAD WORK AREA BASE.                 03420000
GPTFSTRT SR    CTR,CTR             ZERO CHARACTER COUNT.                03440000
GPTFGO   L     TRTBR,DCBLCTBL      GET ADDR OF LOWER CASE TRANS-        03460000
*                                    LATION TABLE.                      03480000
         L     RECR,DCBRECAD       SET INPUT STREAM POINTER.            03500000
         LA    RECR,0(RECR)                                             03520000
         L     IOBR,DCBIOBA                 LOAD IOB ADDRESS       8868 03540000
         SR    2,2                 CLEAR REGISTER FOR TRT FUNCTION BYTE 03560000
*                                                                       03580000
GPTFMORE EQU   *                                                        03600000
         C     RECR,DCBEOBAD       HAVE ALL CHARS BEEN TRANSLATED?      03620000
         BNL   GPTFBUFD            YES.                                 03640000
*                                  NO                                   03660000
*                                                                       03680000
         TRT   0(1,RECR),256(TRTBR) THE TEST TABLE IS ALWAYS OFFSET     03700000
*                                    256 CHARS FROM THE BEGINNING       03720000
*                                    OF THE LOWER CASE TRANSLATION      03740000
*                                    TABLE.                             03760000
*                                                                       03780000
*  THE ABOVE INSTRUCTION(TRT) IS USED TO CHECK FOR INVALID OR CONTROL   03800000
*   CHARACTERS IN THE INPUT. THE TEST TABLE IS SET UP SO THAT ALL VALID 03820000
*   CHARACTERS WILL HAVE A FUNCTION BYTE OF ZEROS. ALL OTHER CHARACTERS 03840000
*   WILL HAVE A NONZERO FUNCTION BYTE. THIS BYTE WILL CONTAIN CODES     03860000
*   (INCREMENTS OF 4) WHICH WILL CAUSE THE ROUTINE TO GO TO THE         03880000
*   APPROPRIATE BRANCH INSTRUCTION IN THE LIST. THIS WILL THEN CAUSE    03900000
*   EXECUTION OF A SPECIAL SUBROUTINE FOR THE HANDLING OF THE           03920000
*   CHARACTER.                                                          03940000
*                                                                       03960000
*                                                                       03980000
         BC    7,GPTFLIST(2)       THE CHARACTER REQUIRES SPECIAL       04000000
*                                  HANDLING, GO TO THE APPROPRIATE      04020000
*                                  SUBROUTINE.                          04040000
*  AFTER A TRT THE NON-ZERO FUNCTION BYTE IS PLACED IN REGISTER 2.      04060000
*                                                                       04080000
GPTFGOOD EQU   *                                                        04100000
*                                                                       04120000
         L     CTRTR,DCBLCTBL      GET ADDR OF LOWER CASE TABLE.        04140000
*                                                                       04160000
         TM    DCBDEVT+2,CASBIT    IS CASE LOWER?                       04180000
         BZ    GPTFLOWK            USE LOWER CASE TABLE                 04200000
*                                                                       04220000
*                                  USE UPPER CASE                       04240000
         LA    CTRTR,512(CTRTR)    ADD UPPER CASE DISPLACEMENT.         04260000
*********************************************************************** 04280000
*  THE SET UP OF THE TABLES IS SUCH THAT THEY RESIDE IN MEMORY IN THE   04300000
*    FOLLOWING MANNER:                                                  04320000
*                   +0   ***************                                04340000
*                        *  LOWER CASE *                                04360000
*                        *    TABLE    *                                04380000
*                   +256 ***************                                04400000
*                        *    TEST     *                                04420000
*                        *    TABLE    *                                04440000
*                   +512 ***************                                04460000
*                        *  UPPER CASE *                                04480000
*                        *    TABLE    *                                04500000
*                        ***************                                04520000
*                                                                       04540000
*                                                                       04560000
*  IF THE CODE TO BE CONVERTED HAS ONLY ONE CASE TABLE THE TABLES       04580000
*    WILL START AT THE LOWER CASE POSITION. THUS IF NO UPPER CASE       04600000
*    TABLE NO VALID SHIFT TO UPPER CASE.                                04620000
*                                                                       04640000
*********************************************************************** 04660000
*                                                                       04680000
GPTFLOWK EQU   *                                                        04700000
*                                                                       04720000
GPTFTRAN TRT   0(1,RECR),0(CTRTR)  TRANSLATE.                           04740000
*                                                                       04760000
*  AFTER EXECUTION THE FUNCTION CHARACTER IS IN REGISTER 2              04780000
*                                                                       04800000
         LR    CTRTR,CTR           MOVE COUNT INTO USEABLE REG.         04820000
         STC   2,0(CTRTR,WAR)      MOVE THE TRANSLATED CHARACTER TO THE 04840000
*                                    USER'S WORK AREA.                  04860000
GPTFBCK  A     CTR,GPTFONE         INCR CHARACTER COUNT.                04880000
GPTFBACK A     RECR,GPTFONE        INCR INPUT STREAM POINTER.           04900000
*                                                                       04920000
         ST    RECR,DCBRECAD       SAVE INPUT STREAM POINTER.           04940000
*                                                                       04960000
         CH    CTR,DCBBLKSI        SEE IF ENOUGH CHARACTERS HAVE BEEN   04980000
         BL    GPTFMORE            TRANSLATED.  NO, KEEP TRANSLATING.   05000000
*                                  YES                                  05020000
GPTFOUT  EQU   *                                                        05040000
         STH   CTR,DCBLRECL        STORE NUMBER OF CHARS TRANSLATED.    05060000
         MVI   32(SAVR),RESET      RESET ERROR TYPE FOR SYNAD.          05080000
         MVI   10(IOBR),RESET      RESET SENSE BYTE.                    05100000
         MVI   21(IOBR),RESET      RESET STATUS WORD TWO.               05120000
*                                                                       05140000
         TM    DCBDEVT+2,INVBIT    WAS AT LEAST ONE INVALID CHAR FOUND? 05160000
         BZ    GPTFERT             NO, BRANCH.                          05180000
         MVI   32(SAVR),SYNINV     YES, SET CODE FOR SYNAD.             05200000
         SPACE 1                                                        05220000
GPTFERT  EQU   *                                                        05240000
         TM    DCBDEVT+2,CHERR     DID ERROR TERMINATE THIS BLOCK?      05260000
         BZ    GPTFTYPT            NO, BRANCH.                          05280000
         OI    10(IOBR),DATACHK    YES, SET DATA CHECK IN SENSE BYTE.   05300000
         SPACE 1                                                        05320000
GPTFTYPT EQU   *                                                        05340000
         TM    DCBRECFM,FMU        ARE RECORDS TYPE U?                  05360000
         BC    14,GPTFLEQT         NO, BRANCH.                          05380000
*                                  YES, WAS THERE EITHER AN INVALID     05400000
         TM    DCBDEVT+2,CHERR+INVBIT   CHAR OR AN ERROR CHAR?          05420000
         BC    7,GPTFTSYN          YES, BRANCH.                         05440000
*                                  NO.                                  05460000
GPTFRET  EQU   *                                                        05480000
         LM    R14,R8,20(SAVR)     RESTORE USER REGISTERS.              05500000
         LR    PAR1,PAR0               LOAD USERS WORK AREA ADDR A35769 05506020
*                                       IN R1                    A35769 05512020
         BR    RETR                RETURN.                              05520000
*                                                                       05540000
*                                                                       05560000
*                                                                       05580000
GPTFIEOF LTR   CTR,CTR             WERE ANY CHARACTERS TRANSLATED?      05600000
         BZ    GPTFEOF             NONE DONE GO TO EOF EXIT             05620000
         OI    DCBCIND1,CEOF       SET EOF FLAG FOR NEXT ENTRY TO GET.  05640000
         B     GPTFOUT             REQUEST IS COMPLETED.                05660000
*                                                                       05680000
GPTFEOF  EQU   *                                                        05700000
*                                                                       05720000
         L     ENTR,DCBEODAD       SET ADDR OF END-OF-DATA ROUTINE.     05740000
         LM    R0,R8,28(SAVR)      RESTORE USER REGS.                   05760000
         BR    ENTR                                                     05780000
*                                                                       05800000
GPTFBUFD EQU   *                                                        05820000
*                                                                       05840000
         L     IOBR,DCBIOBA        SET IOB ADDRESS.                     05860000
         TM    DCBDEVT+2,CHERR     WAS THERE AN ERROR READING THIS      05880000
*                                    INPUT BLOCK?                       05900000
*                                  IF SO, THE ERROR CHARACTER IS STILL  05920000
*                                    IN THE INPUT BUFFER.               05940000
         BO    GPTFMVER            YES. GO MOVE THE ERROR CHARACTER TO  05960000
*                                    THE TRANSLATED STRING.             05980000
*                                  NO.                                  06000000
         TM    DCBDEVT+2,CHEOR     DID EOR TERMINATE THIS BUFFER?       06020000
         BC    14,GPTFNEOR         NO, BRANCH                           06040000
*                                  YES                                  06060000
         OI    DCBDEVT+2,EORHIT    SET EOR REACHED IN TRANSLATION.  NO  06080000
*                                    MORE CHARACTERS ARE TO BE TRANS-   06100000
*                                    LATED FOR THIS REQUEST.            06120000
         NI    DCBDEVT+2,X'FF'-CHEOR  RESET EOR FLAG FOR THIS IOB.      06140000
GPTFNEOR EQU   *                                                        06160000
         LR    CTRTR,CTR           SAVE CHARACTER COUNT.                06180000
         LR    R2,DCBR             SET DCB ADDRESS FOR EOB.             06200000
         L     ENTR,DCBEOB         GET ADDR OF EOB ROUTINE.             06220000
         BALR  RETR,ENTR           GO THERE AND RESCHEDULE BUFFER.      06240000
*                                                                       06260000
         LR    CTR,CTRTR           RESTORE CHARACTER COUNT.             06280000
GPTFIOB  EQU   *                                                        06300000
         L     IOBR,DCBIOBA        GET NEXT IOB ADDRESS.                06320000
         MVC   DCBIOBA+1(3),1(IOBR) PUT IT INTO DCB.                    06340000
*                                                                       06360000
GPTFWTLP EQU   *                                                        06380000
         L     IOBR,DCBIOBA        GET IOB ADDRESS.                     06400000
         USING IOB,IOBR                 MAPPING DSECT FOR IOB   SA51553 06410021
         TM    IOBECB,OKBITS            IS IOB AVAILABLE        SA51553 06440021
         LH    WORK,IOBCCWRC            GET RESIDUAL COUNT      SA51553 06450021
         BO    GPTFOK              ALL OK, NEGATIVE LOGIC               06460000
*                                                                       06480000
         BZ    GPTFWAIT            NOT DONE YET, WAIT                   06500000
*                                                                       06520000
*                               ***ERROR***                             06540000
*                                                                       06560000
         TM    20(IOBR),EOFBIT     SEE IF ERROR ACTUALLY MEANS EOF.     06580000
         BZ    GPTFEROR            NO,IT IS TRUE ERROR                  06600000
*                                                                       06620000
*                                  EOF                                  06640000
         B     GPTFIEOF                                                 06660000
*                                                                       06680000
GPTFWAIT EQU   *                                                        06700000
         L     PAR1,12(IOBR)       GET ECB ADDRESS.                     06720000
         LR    CTRTR,CTR           SAVE CHARACTER COUNT.                06740000
         WAIT  ECB=(1)                                                  06760000
         LR    CTR,CTRTR           RESTORE CHARACTER COUNT.             06780000
         B     GPTFWTLP                                                 06800000
*                                                                       06820000
GPTFOK   EQU   *                                                        06840000
*                                                                       06860000
         LTR   WORK,WORK           IS IT ZERO?                          06880000
         BZ    GPTFA               YES, BRANCH                          06900000
*                                  NO.                                  06920000
         OI    DCBDEVT+2,CHEOR     SET EOR ENCOUNTERED.                 06940000
*                                                                       06960000
GPTFA    EQU   *                                                        06980000
         LH    RSIZR,DCBBLKSI      CALC RECORD SIZE.                    07000000
         SR    RSIZR,WORK                                               07020000
*                                                                       07040000
GPTFOKTO EQU   *                                                        07060000
*                                                                       07080000
         SR    CCWR,CCWR           CALC LOCATION OF THE CCW.            07100000
         IC    CCWR,DCBOFFSR                                            07120000
         LA    CCWR,0(CCWR,IOBR)                                        07140000
*                                                                       07160000
         MVC   DCBRECAD+1(3),1(CCWR) MOVE DATA ADDRESS TO DCB.          07180000
         A     RSIZR,DCBRECAD      CALC ADDRESS OF LAST BYTE + 1        07200000
         ST    RSIZR,DCBEOBAD        AND PUT IN DCB.                    07220000
*                                                                       07240000
         TM    DCBDEVT+2,EORHIT    WAS EOR REACHED DURING TRANSLATION?  07260000
         BC    14,GPTFGO               NO BRANCH                  14759 07280016
         NI    DCBDEVT+2,X'FF'-EORHIT  YES, RESET EOR REACHED FLAG.     07300000
         SPACE 1                                                        07320000
GPTFB    EQU   *                                                        07340000
         LTR   CTR,CTR             ARE THERE ANY CHARS FOR THE USER?    07360000
         BZ    GPTFGO                  NO BRANCH ONLY EOR         14759 07380016
*                                    OR ALL CHARS READ WERE DELETED.    07400000
         B     GPTFOUT             YES, REQUEST IS FILLED.              07420000
*                                                                       07440000
GPTFMVER EQU   *                                                        07460000
         AR    WAR,CTR             CALC CURRENT ADDR IN OUTPUT STRING.  07480000
         MVC   0(1,WAR),0(RECR)    MOVE THE ERROR CHARACTER THERE.      07500000
         A     CTR,GPTFONE         INCREASE CHARACTER COUNT.            07520000
         B     GPTFOUT             GO TREAT REQUEST AS COMPLETED.       07540000
GPTFLEQT EQU   *                                                        07560000
*   THE NEXT 3 LINES OF CODE WERE DELETED BY APAR 32500. THEY SHOULD    07561020
*   HAVE BEEN LEFT IN THE MODULE.                                       07562020
         CH    CTR,DCBBLKSI           IS LOGICAL RECORD A        A38818 07563020
*                                       COMPLETE BLK             A38818 07564020
         BE    COMPLBLK               YES, BRANCH                A38818 07565020
         OI    21(IOBR),ILBIT         NO, SET INCORRECT LENGTH   A38818 07566020
         B     GPTFTSYN               GO TO TEST FOR SYNAD       A38818 07567020
COMPLBLK EQU   *                                                 A38818 07568020
         TM    DCBDEVT+2,CHERR+INVBIT  WAS EITHER AN INVALID     A32500 07570020
*                                       CHAR OR                  A32500 07580020
*                                           AN ERROR CHAR FOUND?        07590020
         BC    8,GPTFRET               NO,  RETURN TO USER       A32500 07600020
*                                      YES,  TEST FOR SYNAD             07610020
GPTFTSYN EQU   *                                                        07640000
         NI    DCBIFLGS,X'3F'           RESET DCB ERROR FLAGS           07660000
         TM    DCBSYNAD+3,ADSYNAD  IS THERE A SYNAD?                    07680000
         BO    GPTFNSYN            NO, GO CHECK OPTIONS.                07700000
*                                  YES, SET UP REGISTERS FOR SYNAD      07720000
*                                                                       07740000
         SR    PAR0,PAR0           CLEAR REGISTER.                      07760000
         IC    PAR0,DCBOFFSR       ADJUST CCW OFFSET TO GIVE OFFSET     07780000
         LA    IOBR,8                FROM IOS IOB RATHER THAN SAM IOB.  07800000
         SR    PAR0,IOBR                                                07820000
         SLL   PAR0,24             PUT IN HIGH BYTE OF PARAM REG 0.     07840000
*                                                                       07860000
         L     IOBR,DCBIOBA        PUT IOS IOB ADDR IN LOW ORDER        07880000
         LA    IOBR,8(IOBR)          THREE BYTES.                       07900000
         OR    PAR0,IOBR                                                07920000
*                                                                       07940000
         L     PAR1,32(SAVR)       GET DCB ADDRESS AND SYNAD ERROR BYTE 07960000
*                                                                       07980000
         L     ENTR,DCBSYNAD       GET SYNAD.                           08000000
         LM    R2,R8,36(SAVR)      RESTORE USER REGS.                   08020000
         BALR  RETR,ENTR           GO TO SYNAD.                         08040000
*                                                                       08060000
         L     BASER,24(SAVR)      RESTORE BASE REGISTER AND            08080000
         L     DCBR,32(SAVR)         DCB BASE.                          08100000
GPTFNSYN EQU   *                                                        08120000
         L     IOBR,DCBIOBA        GET IOB BASE.                        08140000
         LA    WORK,0(IOBR)        ZERO HIGH BYTE AND PUT IN WORK REG.  08160000
*                                                                       08180000
*                                                                       08200000
         TM    DCBDEVT+2,CHERR     WAS THERE A HARDWARE ERROR OR JUST   08220000
*                                    AN INVALID CODE?                   08240000
         BO    GPTFRESC            ERROR, BRANCH.                       08260000
*                                  INVALID ONLY.                        08280000
GPTFTACC EQU   *                                                        08300000
         TM    DCBEROPT,ACCEPT     WHAT IS ERROR OPTION?                08320000
         BC    14,GPTFTACD   NOT ACCEPT - BRANCH TO TEST FOR     A31186 08327020
*                                       SKIP                     A31186 08334020
         NI    DCBDEVT+2,X'FF'-(CHERR+INVBIT)   RESET ERROR FLAG A31186 08341020
         BC    15,GPTFRET   BRANCH TO RETURN                     A31186 08348020
*                                                                       08355020
GPTFTACD EQU   *                                                 A31186 08362020
         TM    DCBEROPT,SKIP   IS IT SKIP                        A31186 08369020
         BC    12,GPTFNOPT   NOT SKIP - BRANCH                   A31186 08376020
         NI    DCBDEVT+2,X'FF'-(CHERR+INVBIT)  RESET ERROR FLAG  A31186 08383020
         L     WAR,28(SAVR)             LOAD WORK AREA BASE      A26737 08396019
         SR    CTR,CTR                 ZERO CHAR, COUNT           14759 08404016
         B     GPTFNEOR                                           14759 08412016
*                                  NO.                                  08420000
*                                                                       08440000
GPTFNOPT EQU   *                                                        08460000
*                                                                       08480000
         LH    PAR0,GPTFABCD                                     I19116 08490019
         LR    PAR1,DCBR                                         I19116 08500019
         SVC   55                                                I19116 08510019
*                                                                       08540000
GPTFRESC EQU   *                                                        08560000
         NI    DCBDEVT+2,X'FF'-(CHERR+INVBIT)    RESET ERROR FLAG  9261 08580013
         L     IOBR,0(IOBR)             LOAD ADDR OF NEXT IOB           08600000
         LA    IOBR,0(IOBR)        ZERO OUT HIGH BYTE.                  08620000
         CR    IOBR,WORK           IS THIS THE IOB WITH THE ERROR?      08640000
         BE    GPTFTACC            YES, FINISHED RESCHEDULING.          08660000
         LA    PAR1,8(IOBR)        LOAD ADDR OF IOS IOB.                08680000
         EXCP  (1)                 RESCHEDULE IOB.                      08700000
         B     GPTFRESC            TEST FOR LAST IOB.                   08720000
*                                                                       08740000
GPTFEROR EQU   *                                                        08760000
*                                                                       08780000
         OI    DCBDEVT+2,CHERR     SET ERROR DETECTED.                  08800000
         MVI   4(IOBR),OKBITS           SET ECB COMPLETE, NO ERROR      08820000
         LA    WORK,1(WORK)        INCREASE RESIDUAL COUNT BY ONE SO    08840000
*                                    REC SIZE WILL BE CALC ONE SHORT.   08860000
         B     GPTFA                                                    08880000
*                                                                       08900000
GPTFLIST B     GPTFGOOD            OK (SHOULD NEVER GETHERE) (0)        08920000
*                                                                       08940000
         B     GPTFDELP            DUMMY.                               08960000
*                                                                       08980000
         B     GPTFUCSE            SHIFT TO UPPER CASE       (8)        09000000
*                                                                       09020000
         B     GPTFLCSE            SHIFT TO LOWER CASE       (C)        09040000
*                                                                       09060000
         B     GPTFNVLD            INVALID CHARACTER         (10)       09080000
*                                                                       09100000
         B     GPTFBACK            VALID, NON-TRANSLATABLE   (14)       09120000
*                                                                       09140000
         B     GPTFVLCO            VALID IN LOWER CASE ONLY  (18)       09160000
*                                                                       09180000
         B     GPTFVUCO            VALID IN UPPER CASE ONLY  (1C)       09200000
*                                                                       09220000
         B     GPTFVNLO            VALID, NONTRANSLATABLE IN            09240000
*                                  LOWER CASE ONLY, OTHERS              09260000
*                                  INVALID                   (20)       09280000
*                                                                       09300000
         B     GPTFBACK            DELETE THIS CHARACTER (24)           09320000
*                                                                       09340000
         B     GPTFVLVU            VALID NON-TRANSLATE IN LOWER CASE,   09360000
*                                  VALID TRANSLATABLE IN UPPER CASE(28) 09380000
*                                                                       09400000
         B     GPTFVUVL            VALID NON-TRANSLATE IN UPPER CASE,   09420000
*                                  VALID TRANSLATABLE IN LOWER CASE(2C) 09440000
*                                                                       09460000
         B     GPTFVNUP            VALID, NONTRANSLATABLE IN UPPER      09480000
*                                  CASE ONLY, INVALID IN LOWER. (30)    09500000
*                                                                       09520000
GPTFDELP EQU   *                   DUMMY--RETURN DOING NOTHING.         09540000
         B     GPTFBACK            RETURN TO MAINSTREAM                 09560000
*                                                                       09580000
*                ***UPPER CASE ROUTINE***                               09600000
GPTFUCSE EQU   *                                                        09620000
         OI    DCBDEVT+2,CASBIT    SET UPPER CASE ON.                   09640000
         B     GPTFBACK                                                 09660000
*                                                                       09680000
*                ***LOWER CASE ROUTINE***                               09700000
GPTFLCSE EQU   *                                                        09720000
         NI    DCBDEVT+2,X'FF'-CASBIT  SET LOWER CASE ON.               09740000
         B     GPTFBACK                                                 09760000
*                                                                       09780000
*                ***INVALID CHARACTER ROUTINE***                        09800000
GPTFNVLD EQU   *                                                        09820000
         OI    DCBDEVT+2,INVBIT    SET INVALID ON.                      09840000
         B     GPTFGOOD               BR TO 2ND TRT INST TO      A38817 09850020
*                                       TRANS                    A38817 09860020
*                                           AS X'FF'                    09870020
*                                                                       09880000
GPTFVLCO EQU   *              ***VALID IN LOWER CASE ONLY***            09900000
         TM    DCBDEVT+2,CASBIT    IS CHAR LOWER CASE?                  09920000
         BZ    GPTFGOOD            YES,GO TRANSLATE.                    09940000
         B     GPTFNVLD            NO, TREAT AS INVALID                 09960000
*                                                                       09980000
GPTFVUCO EQU   *              ***VALID IN UPPER CASE ONLY***            10000000
         TM    DCBDEVT+2,CASBIT    IS CHAR UPPER CASE?                  10020000
         BO    GPTFGOOD            YES, GO TRANSLATE.                   10040000
         B     GPTFNVLD            NO,TREAT AS INVALID                  10060000
*                                                                       10080000
GPTFVNLO EQU   *              ***VALID, NONTRANSLATABLE IN LOWER CASE   10100000
*                                ONLY***                                10120000
         TM    DCBDEVT+2,CASBIT    IS CHAR LOWER CASE?                  10140000
         BZ    GPTFBACK            YES, RETURN BUT DONT TRANSLATE       10160000
         B     GPTFNVLD            NO, TREAT AS INVALID                 10180000
*                                                                       10200000
*                                                                       10220000
GPTFVLVU EQU   *         ***VALID, NON-TRANSLLATE IN LOWER CASE, VALID  10240000
*                           TRANSLATABLE IN UPPER CASE***               10260000
         TM    DCBDEVT+2,CASBIT    SEE IF LOWER CASE.                   10280000
         BZ    GPTFBACK            YES                                  10300000
         B     GPTFGOOD            NO.                                  10320000
*                                                                       10340000
GPTFVUVL EQU   *         ***VALID NON-TRANSLATE IN UPPER CASE, VALID    10360000
*                           TRANSLATABLE IN LOWER CASE***               10380000
         TM    DCBDEVT+2,CASBIT    SEE IF UPPER CASE.                   10400000
         BO    GPTFBACK            YES                                  10420000
         B     GPTFGOOD            NO.                                  10440000
*                                                                       10460000
GPTFVNUP EQU   *         ***VALID IN UPPER CASE ONLY. NONTRANSLATABLE.  10480000
         TM    DCBDEVT+2,CASBIT    SEE IF UPPER CASE.                   10500000
         BO    GPTFBACK            YES, RETURN BUT DON'T TRANSLATE.     10520000
         B     GPTFNVLD            NO, TREAT AS INVALID.                10540000
*                                                                       10560000
GPTFINIT EQU   *                                                        10580000
         LR    WAR,PAR0            SET WORK AREA ADDRESS.               10600000
         SR    CTR,CTR             ZERO CHARACTER COUNT.                10620000
         B     GPTFIOB                                                  10640000
*                                                                       10660000
GPTFABCD DC    X'1000'            ABEND CODE FOR NO ERROR OPTION.       10680000
         DS    0F                                                       10700000
GPTFONE  DC    X'00000001'                                              10720000
GPTF512  DC    X'00000200'                                              10740000
*   THE FOLLOWING CNOP MUST REMAIN ON A HALF WORD BOUNDARY.             10760000
         CNOP  0,8                 PAD MODULE TO DOUBLE WORD BOUNDARY.  10780000
*                                                                       10800000
IOB      DSECT                                                          10820000
*                                                                       10840000
IOBLINK  DS    F              POINTER TO NEXT IOB                       10860000
IOBBSAM  EQU   IOB            BSAM FLAGS                                10880000
IOBECB   DS    F              ECB FOR QSAM                              10900000
IOBFLAG1 DS    CL1            IOS FLAG 1                                10920000
IOBFLAG2 DS    CL1            IOS FLAG 2                                10940000
IOBSENSE DS    CL2            SENSE BYTES                               10960000
IOBECBPT DS    CL4            ECB POINTER                               10980000
IOBCSW   DS    0CL8           CHANNEL STATUS WORD               SA51553 11000021
IOBCCWAD DS    CL4                      CCW STOP ADDRESS        SA51553 11010021
IOBSTAT  DS    CL2                      CHAN/DEV STATUS         SA51553 11012021
IOBCCWRC DS    CL2                      CCW RESIDUAL COUNT      SA51553 11014021
IOBSTART DS    F              START CCW POINTER                         11020000
IOBSIOCC EQU   IOBSTART       SIO CONDITION CODE                        11040000
IOBDCBPT DS    F              DCB POINTER(DCBAD)                        11060000
IOBWHGT  EQU   IOBDCBPT       CHANNEL WEIGHT                            11080000
IOBRESTR DS    CL4            RESTART CCW POINTER                       11100000
IOBINCAM DS    CL2            BLOCK COUNT INCREMENT                     11120000
IOBERRCT DS    CL2            ERROR COUNTER                             11140000
IOBSEEK  DS    CL8            MBBCCHHR                                  11160000
         DS    0F                                                       11180000
*********************************************************************** 11200000
         DCBD  DSORG=PS                                                 11220000
*********************************************************************** 11240000
*                                                                       11260000
         END   IGG019AT                                                 11280000
