         TITLE 'IGG019B0-BUILD BUFFER CONTROL BLOCK AND BUFFER POOL'    01400019
IGG019B0 CSECT                                                          01410019
*********************************************************************** 02100019
*                                                                       02800019
*         RELEASE 22 DELETIONS                                        * 02850021
*         RELEASE 21 DELETIONS                                          04200021
*     035000,042000,049000-070300,070400,399000,749000,756000,   M0946  04250021
*     763000,868000,875000,917000-924000,924100-924300,945000,   M0946  04260021
*     952000-966000                                              M0946  04270021
*                                                                       04310021
*         RELEASE 20 DELETIONS                                        * 04350021
*                                                                     * 07040021
*STATUS CHANGE LEVEL 001                                              * 07700021
*                                                                     * 08400019
*FUNCTION/OPERATION - THIS BUILDRCD ROUTINE IS ENTERED VIA A LINK SVC * 09100019
*                     WHEN THE USER ISSUES A BUILDRCD MACRO.  THIS    * 09800019
*                     ROUTINE THEN BUILDS THE BUFFER CONTROL BLOCK    * 10500019
*                     AND CHAINS TOGETHER THE BUFFERS.  IF A RECORD   * 11200019
*                     AREA LENGTH IS SPECIFIED, IT IS PLACED IN THE   * 11900019
*                     RECORD AREA.  IT THEN RETURNS CONTROL TO THE    * 12600019
*                     USER.                                           * 13300019
*                                                                     * 14000019
*                     BUFFER CONTROL BLOCK FORMAT -                   * 14700019
*                                                                     * 15400019
*                                                                     * 16100019
*                     -----------------------------                   * 16800019
*                                4 BYTES                              * 17500019
*                     -----------------------------                   * 18200019
*                                                                     * 18900019
*                     +++++++++++++++++++++++++++++                   * 19600019
*                     +                           +                   * 20300019
*                     +   FIRST BUFFER ADDRESS    +                   * 21000019
*                     +                           +                   * 21700019
*                     +++++++++++++++++++++++++++++                   * 22400019
*                     +      +      +             +                   * 23100019
*                     + FLAG +NUMBER+BUFFER LENGTH+                   * 23800019
*                     +      +      +             +                   * 24500019
*                     +++++++++++++++++++++++++++++                   * 25200019
*                     +                           +                   * 25900019
*                     +    RECORD AREA ADDRESS    +                   * 26600019
*                     +                           +                   * 27300019
*                     +++++++++++++++++++++++++++++                   * 28000019
*                                                                     * 28700019
*                                                                     * 29400019
*ENTRY POINTS - IECBBFML ENTRY IS VIA A LINK SVC IN THE USERS PROGRAM.* 30100019
*                                                                     * 30800019
*INPUT - THE FOLLOWING REGISTERS HAVE BEEN SET UP PRIOR TO ENTRY -    * 31500019
*         REGISTER 1  - ADDRESS OF BUILDRCD PARAMETER LIST            * 32200019
*         REGISTER 13 - ADDRESS OF USERS SAVE AREA                    * 32900019
*         REGISTER 14 - ADDRESS OF RETURN POINT IN USERS PROGRAM      * 33600019
*         REGISTER 15 - IECBBFML ENTRY POINT ADDRESS                  * 34300019
*                                                                     * 35000019
*OUTPUT - BUILT BUFFERS AT SPECIFIED ADDRESS WITH ASSOCIATED BUFFER   * 35700019
*          CONTROL BLOCK.                                             * 36400019
*                                                                     * 37100019
*EXTERNAL REFERENCES - NONE.                                          * 37800019
*                                                                     * 38500019
*EXITS - NORMAL - RETURN ON REGISTER 14 TO CALLER.                    * 39200019
*                                                                M0946  39300021
*EXITS - ERROR  - RETURN ON REGISTER 14 TO CALLER.               M0946  39900021
*               - BUFFERS ARE NOT BUILT                          M0946  40000021
*                                                                     * 40600019
*TABLES/WORKAREAS - N/A                                               * 41300019
*********************************************************************** 42000019
*                                                                     * 42700019
*                           REGISTER ASSIGNMENT                       * 43400019
*                                                                     * 44100019
PARMLIST EQU   1                        ADDRESS OF PASSED PARAMETER LST 44800019
WRKR     EQU   2                        WORK REGISTER                   45500019
RECARPTR EQU   3                        POINTER TO RECORD AREA          46200019
BUFADR   EQU   4                        POINTER TO BUFFER               46900019
BUFNO    EQU   5                        NUMBER OF BUFFERS               47600019
BUFLTH   EQU   6                        LENGTH OF BUFFERS               48300019
BUFPTR   EQU   7                        POINTER TO BUFFER AREA          49000019
BASR     EQU   11                       BASE REGISTER                   49700019
*                                                                     * 50400019
*                         OFFSET ASSIGNMENTS                          * 51100019
*                                                                     * 51800019
BUFAD    EQU   0                        OFFSET TO BEGINNING OF BUF AREA 52500019
CLEAR    EQU   0                        OFFSET TO CLEAR HIGH ORDER BYTE 53200019
REC      EQU   0                        OFFSET TO BEGINNING OF REC AREA 53900019
NOLTH    EQU   4                        OFFSET TO LENGTH AND NO OF BUFS 54600019
ROUND    EQU   3                        OFFSET TO ROUND LNTH TO FULL WD 55300019
NO       EQU   5                        OFFSET TO NUMBER OF BUFS IN BCB 56000019
LNT      EQU   6                        OFFSET TO LENGTH OF BUFS IN BCB 56700019
LTH      EQU   7                        OFFSET TO ROUND LNTH FIELD      57400019
RECAD    EQU   8                        OFFSET TO REC AREA ADDR IN BCB  58100019
FBUF     EQU   12                       OFFSET TO FIRST BUFFER ADDRESS  58800019
RECLTH   EQU   12                                                       59500019
C32      EQU   32                       SIZE OF REC AREA CONTROL FIELD  59510019
*                                                                     * 60200019
*                          MASK ASSIGNMENTS                           * 60900019
*                                                                     * 61600019
RECFLAG  EQU   X'80'                    END OF PARAMETER LIST FLAG      62300019
MASKRND  EQU   252                      ROUND LENGTH FIELD TO FULL WORD 63000019
*                                                                     * 63700019
*                           INITIALIZATION                            * 64400019
*                                                                     * 65100019
         SAVE  (14,12)                                                  65800019
         BALR  BASR,0                    ESTABLISH A BASE               66500019
         USING *,BASR                                                   67200019
*                                                                     * 67900019
*                  BUILDING THE BUFFER CONTROL BLOCK                  * 68600019
*                                                                     * 69300019
         L     BUFPTR,BUFAD(PARMLIST)   LOAD BUF POOL ADDRESS           70000019
         L     WRKR,NOLTH(PARMLIST)     LOAD BUF LENGTH AND NO          70700019
         L     RECARPTR,RECAD(PARMLIST) LOAD RECORD AREA ADDRESS        71400019
         LA    WRKR,ROUND(WRKR)         BEGIN ROUNDING THE LENGTH       72100019
         ST    WRKR,NOLTH(BUFPTR)       STORE NO AND LENGTH IN BCB      72800019
         NI    LTH(BUFPTR),MASKRND      END ROUNDING                    73500019
         OI    NOLTH(BUFPTR),RECFLAG    TURN ON BUFLG BYTE IN BCB       74200019
         L     WRKR,REC(RECARPTR)       LOAD RECORD LENGTH FROM  M0946  74210021
*                                       RECORD AREA              M0946  74220021
         LTR   RECARPTR,RECARPTR        REC LENGTH IN PARMLIST?  M0946  74900021
         BM    CLEARIT                  BRANCH IF NOT PRESENT    M0946  75600021
         L     WRKR,RECLTH(PARMLIST)    LOAD RECORD LENGTH FROM  M0946  76300021
*                                       PARM LIST                M0946  76302021
CLEARIT  EQU   *                                                        76310019
         LA    WRKR,CLEAR(WRKR)         CLEAR FLAG BYTE                 77000019
         XC    REC(C32,RECARPTR),REC(RECARPTR)                          77010019
*                                       CLEAR RECORD AREA CONTROL FIELD 77020019
         ST    WRKR,REC(RECARPTR)       STORE RECORD LENGTH IN REC AREA 77700019
         LA    RECARPTR,CLEAR(RECARPTR) CLEAR FLAG BYTE                 79100019
         ST    RECARPTR,RECAD(BUFPTR)   STORE RECORD ADDRESS IN BCB     79800019
*                                                                     * 80500019
*                      BUILDING THE BUFFER CHAIN                      * 81200019
*                                                                     * 81900019
         LA    BUFADR,FBUF(BUFPTR)      CALCULATE FIRST BUFFER ADDRESS  82600019
         CLI   NOLTH(BUFPTR),RECFLAG    BUFNO GREATER THAN 255   M0946  82800021
         BNE   RETURNA                  YES RETURN               M0946  82850021
         SR    BUFNO,BUFNO              CLEAR REGISTER                  83300019
         IC    BUFNO,NO(BUFPTR)         OBTAIN EXACT NO OF BUFFERS      84000019
         LH    BUFLTH,LNT(BUFPTR)       OBTAIN LENGTH OF EACH BUFFER    84700019
         LTR   BUFNO,BUFNO              ZERO BUFFERS REQESTED           85400019
         BZ    RETURNA                  YES RETURN                      86100019
         LTR   BUFLTH,BUFLTH            LENGTH LT OR EQUAL ZERO  M0946  86800021
         BNP   RETURNA                  YES RETURN               M0946  87500021
LOOP     EQU   *                                                        88200019
         ST    BUFADR,BUFAD(BUFPTR)     STORE BUFFER LINK ADDRESS       88900019
         LR    BUFPTR,BUFADR            UPDATE BUFFER ADDRESS POINTER   89600019
         AR    BUFADR,BUFLTH            CALCULATE NEXT BUFFER ADDRESS   90300019
         BCT   BUFNO,LOOP               ALL BUFFERS BUILT               91000019
RETURNA  EQU   *                                                        93100019
         SR    BUFNO,BUFNO              CLEAR REGISTER           M0946  93150021
         ST    BUFNO,BUFAD(BUFPTR)      CLEAR LAST BUFFER LINK ADDRESS  93800019
         RETURN (14,12)                                          M0946  94500021
         END   IGG019B0                                                 97300019
