         TITLE 'IGG019BD / IECBNPT2 BSAM NOTE POINT FOR MAGNETIC TAPE'  00020000
         COPY  LCGASMSW                                                 00020101
IGG019BD CSECT                                                          00020321
*                                                                       00020621
*          RELEASE 18 DELETIONS                                       * 00021018
*1007013900                                                       8M629 00021518
*1007                                                             24042 00022018
*          RELEASE 19 DELETIONS                                       * 00023018
*          RELEASE 20 DELETIONS                                       * 00024018
*          RELEASE 21 DELETIONS                                       * 00025018
*1771004500-004700,012402,029310                                 M0163  00025121
*1771004600-004800,014200                                        S21940 00025221
*1771007800,014600-014800,025600                                 S21040 00025521
*1771012403,029270,029280                                        M0929  00025921
*1771014200,027840-027960,029210-029320                          M1358  00029321
*          RELEASE 22 DELETIONS                                       * 00032821
*          RELEASE 23 DELETIONS                                       * 00036221
*          RELEASE 24 DELETIONS                                       * 00039621
*          RELEASE 25 DELETIONS                                       * 00043021
*          RELEASE 26 DELETIONS                                       * 00046421
*          RELEASE 27 DELETIONS                                       * 00049821
*STATUS CHANGE LEVEL 002                                                00053221
*FUNCTION/OPERATION: NOTE PASSES THE CURRENT BLOCK OR RECORD COUNT TO * 00056621
*      THE USER IN REGISTER NO.1                                      * 00060000
*      POINT POSITIONS THE TAPE TO THE RECORD INDICATED IN THE        * 00080000
*      PARAMETER WHICH WAS PASSED TO THIS ROUTINE BY THE USER. THIS   * 00100000
*      IS ACCOMPLISHED BY FORWARD OR BACKSPACING THE TAPE.            * 00120000
*                                                                       00121021
*      POINT WILL POSITION TAPES CONTAINING DOS EMBEDDED CHECKPOINT     00122021
*      RCDS.  IF THE BYPASS EMBEDDED DOS CHKPT RCDS OPTION IS SPECIFIED 00123021
*      (DCBOPTCD BIT 3 SET TO ONE), IT WILL DO A GETMAIN FOR 24 BYTES,  00124021
*      PLACE THE OBTAINED CORES ADDRESS INTO THE CCW, TURN OFF THE SKIP 00125021
*      BIT, AND TURN ON THE NOTE/POINT BIT IN THE IOB.  POSITIONING     00126021
*      WITH THIS OPTION INVOLVES THE READING OF THE FIRST 20 BYTES OF   00127021
*      EACH BLOCK INTO THE OBTAINED CORE.  THE BYPASSING OF ANY         00128021
*      ENCOUNTERED EMBEDDED CHKPT RCDS WILL BR PERFORMED BY THE         00129021
*      APPROPRIATE CHAN END APPENDAGE (IGG019EI OR IGG019EJ)            00130021
*                                                                       00131021
*      NOTE/POINT NOT TO BE USED FOR BACKWARD POSITIONING OF 7-TRACK    00132021
*      TAPES WRITTEN IN DATA CONVERT MODE                               00133021
*                                                                       00134021
*ENTRY POINTS      NOTE MACRO EXPANSION             LA   14,DCBADDR   * 00140000
*                                                   L     15,84(14)   * 00160000
*                                                   BALR 14,15        * 00180000
*                                                                     * 00200000
*                  POINT MACRO EXPANSION            LA   14,DCBADDR   * 00220000
*                                                   L    15,84(14)    * 00240000
*                                                   BAL  14,4(15)     * 00260000
*                                                                     * 00280000
*INPUT: REGISTER 1 DCB ADDR--REGISTER 13 ADDR OF 18 WD SAVEAREA       * 00300000
*      REGISTER 0 BLOCK COUNT FOR POINT ONLY                          * 00320000
*OUTPUT: REGISTER 1 WILL CONTAIN THE BLOCK COUNT UPON RETURN FROM NOTE* 00340000
*EXTERNAL ROUTINES: POINT BUILDS A CHANNEL PROGRAM, EXECUTES AND WAITS* 00360000
*      ON IT                                                          * 00380000
*EXITS NORMAL  NOTE RETURNS TO USER WITH REG1 LOADED WITH BLOCK COUNT * 00400000
*      POINT RETURNS WITH REGISTER 15 EQUAL TO ZERO AND THE TAPE POS- * 00420000
*      ITIONED AT THE REQUESTED RECORD                                * 00440000
*TABLES/WORKAREAS: POINT USES THE DCB IOB ADDRESS TO GET TO AND SAVE  * 00500000
*      THE USERS CHANNEL PROG, TO SUPPLY IOS WITH THE ADDRESS OF THE  * 00520000
*      ECB WHICH IS USED TO POST COMPLETION OF THE CHANNEL PROG. WHICH* 00540000
*      POINT BUILDS,EXECUTES,AND WAITS ON. THE DCBBLKCT IS MODIFIED BY* 00560000
*      POINT. POINT USES THE 18WD SAVE AREA TO STORE USERS REGISTERS  * 00580000
*      2-12 AND TO STORE CHANNEL COMMAND CODES WITH THE APPROPRIATE   * 00600000
*      INCREMENT COUNT WHICH IS USED DURING EXECUTION OF POINT.       * 00620000
*ATTRIBUTES: REENTRANT                                                * 00640000
*NOTES: THE POINT ROUTINE SAVES AND RESTORES THE USERS REGISTERS 2-12,* 00660000
*       THE USERS CHANNEL PROGRAM,BUILDS AND EXECUTES ITS OWN CHANNEL * 00680000
*       PROGRAM AND MODIFIES BLOCK COUNT TO REFLECT THE CHANGE IN TAPE* 00700000
*       POSITIONING.                                                  * 00720000
*                    NOTE AND POINT ROUTINES FOR BSAM TAPE              00740000
*                                      STORED ON X & Y LIBRARAIES       00760000
*                                                                       00782018
*                                                                       00784018
*                                                                       00786018
*                                                                       00788018
*                                                                       00790018
*                                                                       00792018
*                                                                       00794018
*                                                                       00796018
*                                                                       00798018
RETR     EQU   14        * THE USER WILL PASS TO THIS ROUTINE THE       00800000
CCWSAVE1 EQU   10                                                       00820000
CCWSAVE2 EQU   11                                                       00840000
RECDCT   EQU   15                                                       00860000
SYNADDR  EQU   15                                                       00880000
DCBPASAD EQU   1                                                        00900000
BASR     EQU   4                                                        00920000
PARAMADR EQU   0           FOLLOWING PARAMETERS                         00940000
IOBADDR  EQU   3                                                        00960000
CTCNTROL EQU   2                                                        00980000
BLOCKCT  EQU   2           1.  REGISTER  ZERO WILL CONTAIN THE ADDR OF  01000000
*                              A 4 BYTE FIELD WHICH WILL CONTAIN THE    01020000
*                              NUMBER OF THE RECORD DESIRED             01040000
*                          2.  REGISTER  ONE  WILL CONTAIN THE DCB ADDR 01060000
ONE      EQU   6                                                        01080000
ECBADDR  EQU   7           3.  REGISTER  13 WILL CONTAIN THE ADDR OF    01100000
PARAM    EQU   8               AN 18 WORD SAVE AREA OF WHICH THE FIRST  01120000
CCWADDR  EQU   9               FIVE WORDS ARE NOT AVAILABLE TO THIS     01140000
*                              ROUTINE                                  01160000
DCBADDR  EQU   12                                                       01180000
*                                                                       01200000
*                          4.  REGISTER 14 WILL CONTAIN USER RETURN     01220000
SAVER    EQU   13              ADDRESS                                  01240000
WRKR5    EQU   5                       WORK REGISTER             S21940 01240121
ECB      EQU   12                       OFFSET IN IOB TO ECB     M0929  01240321
ACTIVE   EQU   X'00'                   HEX NOTATION FOR UNPOSTED S21940 01244821
*                                       ECB                             01247021
COREADR  EQU   5                        REG TO SAVE CORE ADDR    S21040 01249221
*                                                                       01251421
BYPASS   EQU   X'10'                    BYPASS DOS CHKPT RCDS    S21040 01253621
CONTROL  EQU   X'08'                    IOB NOTE/POINT FLAG      S21040 01255821
CORADDR  EQU   1                                                 S21040 01258021
D4       EQU   4                        DISPLACEMENT OF 4        S21040 01260221
D6       EQU   6                        DISPLACEMENT OF 6        S21040 01262421
D19      EQU   19                       DISPLACEMENT OF 19       S21040 01264621
TWENTY   EQU   20                       CONSTANT                 S21040 01266821
IOBOFF   EQU   X'F7'                    TURN OFF IOB POINT FLAG  S21040 01269021
SKIPOFF  EQU   X'EF'                    TURN OFF SKIP BIT        S21040 01271221
*                                                                       01273421
*                                                                       01275621
         USING IHADCB,DCBADDR           DCB ADDR FROM USER              01277821
         USING IGG019BD,15                                              01280000
         B     NOTE                                                     01300000
         DROP  15                                                       01320000
         USING IGG019BD,BASR                                            01340000
POINTAPE STM   DCBPASAD,DCBADDR,20(SAVER)     STORE USERS REGISTERS     01360000
         LR    BASR,15                 ESTABLISH BASE 7-9-65 LOPEZ      01380000
         MVI   70(SAVER),X'00'         SET SWITCH FOR TESTING TO ZERO   01400000
         LR    DCBADDR,DCBPASAD        PUT DCB ADDR INTO RDCB    M1358  01420021
         LA    ONE,1                                                    01440000
         LR    COREADR,PARAMADR                                  S21040 01460021
         L     PARAM,0(COREADR)         PUT RCD NO. IN PARAM REG S21040 01480021
         L     IOBADDR,DCBIOBA         PUT IOB ADDR IN REG IOBADDR      01500000
         MVC   68(2,SAVER),36(IOBADDR)  STORE THE INCREMENT COUNT       01520000
         L     BLOCKCT,DCBBLKCT         PUT BLOCK COUNT INTO A REGISTER 01540000
         LA    ECBADDR,4(IOBADDR)      GET ADDR OF ECB                  01560000
         ST    ECBADDR,12(IOBADDR)     STORE ADDR OF ECB IN ECB POINTER 01580000
         L     CCWADDR,24(0,IOBADDR)    PUT CCW ADDR INTO REG CCWADDR   01600000
         LM    10,11,0(CCWADDR)        STORE USERS CCW                  01620000
         MVI   4(CCWADDR),X'30'         SET SLI AND SKIP ON             01640000
         MVI   7(CCWADDR),X'14'         SET COUNT GT 18 MIN             01660000
         NI    DCBCIND1,X'CF'           TURN OFF VOL FULL BITS          01670021
*                                                                       01670221
*********************************************************************** 01670421
*                                                                       01670621
*    TEST FOR BYPASS DOS EMBEDDED CHKPT RCD OPTION - IF SPECIFIED       01670821
*    DO GETMAIN FOR 24 BYTES, TURN OFF SKIP BIT IN CCW, PLACE OBTAINED  01671021
*    CORES ADDRESS IN CCW DATA ADDRESS FIELD, AND TURN ON NOTE/POINT    01671221
*    FLAG IN IOB                                                        01671421
*                                                                       01671621
*********************************************************************** 01671821
*                                                                       01672021
         TM    DCBOPTCD,BYPASS          BYPASS CHKPT RCD OPTION  S21040 01672221
         BZ    POINT100                 BRANCH ON NO             S21040 01672421
*                                                                       01672621
         OI    0(IOBADDR),CONTROL       TURN ON NOTE/POINT FLAG  S21040 01672821
         GETMAIN R,LV=24,SP=0           BUFFER TO READ FIRST 20  S21040 01673021
*                                       BYTES OF EACH BLOCK INTO        01673221
*                                                                       01673421
         LR    COREADR,CORADDR          SAVE CORE ADDRESS        S21040 01673621
*                                                                       01673821
         CR    BLOCKCT,PARAM            IS BACKWARD POSIT NEED   S21040 01674021
         BL    POINT050                 BRANCH NO                S21040 01674221
*                                                                       01674421
         LA    CORADDR,D19(CORADDR)     YES - ADJUST DATA ADDR   S21040 01674621
*                                        FOR READ BACKWARDS             01674821
POINT050 EQU   *                                                 S21040 01675021
*                                                                       01675221
         ST    CORADDR,0(CCWADDR)       BUFFER ADDR TO CCW       S21040 01675421
         LA    CORADDR,TWENTY           CONSTANT  20             S21040 01675621
         STH   CORADDR,D6(CCWADDR)      SET READ COUNT TO 20     S21040 01675821
         NI    D4(CCWADDR),SKIPOFF      TURN OFF SKIP BIT        S21040 01676021
*                                                                       01676221
POINT100 EQU   *                                                 S21040 01676421
*                                                                       01676621
         CR    BLOCKCT,PARAM            COMPARE BLOCKCT TO REC REQUESTD 01680000
         BC    4,FORWARD                IF BLKCT LOW - GO SETUP RDFWD   01700000
         BC    2,BACKWARD               IF BLKCT HIGH  GO SETUR RDBKWD  01720000
         LR    CTCNTROL,ONE             BLKCT IS EQUAL INITLZ COUNT CTL 01740000
         B     RDBAKCTL                 GO TO READ BACKWARDS CONTROL    01760000
FORWARD  SR    PARAM,BLOCKCT                                            01780000
         SR    PARAM,ONE                                                01800000
         LR    CTCNTROL,PARAM           PUT # RCDS TO SPACE IN COUNTROL 01820000
         BC    8,RESTOREA              IF PARAM = 0 RESTORE + RETURN    01840000
SETUP    LA    ONE,1                   SET UP A +1                      01860000
         MVI   0(CCWADDR),X'02'         READ FORWARD ONE RECORD         01880000
         STH   ONE,36(0,IOBADDR)        PUT A +1 IN IOB INCREMENT COUNT 01900000
         B     CHANPROG                 GO EXECUTE CHANNEL PROGRAM      01920000
BACKWARD SR    BLOCKCT,PARAM                                            01940000
         AR    BLOCKCT,ONE                                              01960000
RDBAKCTL LNR   ONE,ONE                  SET REG ONE TO A NEGATIVE ONE   01980000
         STH   ONE,36(0,IOBADDR)        PUT A -1 IN IOB INCREMENT COUNT 02000000
REVERSE  MVI   0(CCWADDR),X'0C'         READ BACKWARD ONE RECORD        02020000
CHANPROG LA    1,8(IOBADDR)            LOAD THE IOS IOB ADDR            02040000
         EXCP  (1)                                                      02060000
         L     1,12(IOBADDR)           LOAD THE ECB POINTER             02080000
         WAIT  ECB=(1)                                                  02100000
         TM    11(IOBADDR),X'08'       LOAD POINT REACHED               02120000
         BO    RESTORE                  YES BRANCH                      02140000
         TM    70(SAVER),X'04'          WAS A TAPE MK PASSED PREVIOUSLY 02160000
         BO    RESTORE1                YES BRANCH                       02180000
         TM    20(IOBADDR),X'01'        UNIT EXCEPTION---TP MK          02200000
         BO    TMPASSED                 YES BRANCH                      02220000
         TM    DCBIFLGS,X'C0'           PERMANENT ERROR                 02240000
         BO    RESTORE                  YES BRANCH                      02260000
         TM    70(SAVER),X'02'         HAS A NOP CHAN PROG BEEN DONE    02280000
         BO    RESTOREA                 YES BRANCH                      02300000
         BCT   CTCNTROL,CHANPROG        COUNT NOT ZERO GO EXCP          02320000
DEVEND   EQU   *                                                        02340000
         XC    36(2,IOBADDR),36(IOBADDR)  ZERO INCREMENT COUNT          02360000
         OI    70(SAVER),X'02'         SET NOP SWITCH                   02380000
         MVI   0(CCWADDR),X'03'         PUT NOP COMMAND IN CCW          02400000
         B     CHANPROG                                                 02420000
RESTORE1 EQU   *                                                        02440000
         TM    70(SAVER),X'44'         TAPE MARK PASSED TWICE           02460000
         BC    1,RESTORE               YES BRANCH                       02480000
         OI    70(SAVER),X'40'         SET TAPE MARK PASSED TWICE       02500000
         B     DEVEND                  ISSUE NOP                        02520000
RESTORE  MVI   4(IOBADDR),X'FF'         SET ERROR FLAGS IN IOB ECB BYTE 02540000
RESTOREA EQU   *                                                 S21040 02542021
*                                                                       02544021
*********************************************************************** 02546021
*                                                                       02548021
*    DO FREEMAIN IF BYPASS EMBEDDED CHKPT RCDS OPTION WAS SPECIFIED     02550021
*                                                                       02552021
*********************************************************************** 02554021
*                                                                       02556021
         TM    DCBOPTCD,BYPASS          BYPASS CHKPT RCD OPTION  S21040 02558021
         BZ    POINT300                 BRANCH ON NO             S21040 02560021
*                                                                       02562021
         LR    CORADDR,COREADR          GET CORE ADDRESS         S21040 02564021
*                                                                       02566021
         FREEMAIN R,LV=24,A=(1)         FREE OBTAINED CORE       S21040 02568021
*                                                                       02570021
         NI    0(IOBADDR),IOBOFF        TURN OFF IOB POINT FLAG  S21040 02572021
POINT300 EQU   *                                                 S21040 02574021
         STM   CCWSAVE1,CCWSAVE2,0(CCWADDR)  RESTORE USERS CCW   S21040 02576021
         NI    20(IOBADDR),X'FE'       TURN OFF U.E. IN CSW             02580000
         MVC   36(2,IOBADDR),68(SAVER)         RESTORE INCREMENT COUNT  02600000
         LM    DCBPASAD,DCBADDR,20(SAVER)      RESTORE USERS REGISTERS  02620000
         SR    RECDCT,RECDCT            ZERO REG 15                     02640000
         BR    RETR                                                     02660000
TMPASSED MVI   70(SAVER),X'04'          SET TP MK PASSED SWITCH ON      02680000
         NI    DCBIFLGS,X'3F'           RESET DCBIFLGS                  02700000
         TM    0(CCWADDR),X'02'  WAS LAST COMMAND A RD FWD ONE RECORD   02720000
         BO    RDBAKCTL                 YES BRANCH                      02740000
         B     SETUP                    GO SET UP FOR A FWD SPACE RCD   02760000
NOTE     EQU   *                                                        02780000
         L     PARAMADR,12(0,DCBPASAD) GET BLOCK COUNT                  02800000
         L     DCBPASAD,68(0,DCBPASAD) GET IOB ADDRESS                  02820000
         TM    36(DCBPASAD),X'FF'      WAS LAST IO READ BACK            02840000
         LR    DCBPASAD,PARAMADR       BLOCK COUNT                      02860000
         BCR   14,RETR                 BRANCH NO                        02880000
         LA    DCBPASAD,1(0,DCBPASAD)  INCREMENT BY 1                   02900000
         BR    RETR                                                     02920000
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY   02940000
         CNOP  0,8                 PAD MODULE TO DOUBLE WORD MULTIPLE   02960000
         DCBD  DSORG=PS       DATA SET ORGANIZATION = PSY. SEQUENTIAL   02980000
         END                                                            03000000
         BR    RETRN                                                    03020000
         BR    SYNADOUT                                                 03040000
