         TITLE 'IGG019BE OR IECBCNT3 CONTROL FOR MAGNETIC TAPE'         00020000
 COPY    LCGASMSW                                                       00020100
IGG019BE CSECT                                                          00020321
*                                                                       00020621
*          RELEASE 19 DELETIONS                                       * 00023018
*1027                                                            A28177 00023519
*          RELEASE 20 DELETIONS                                       * 00024018
*          RELEASE 21 DELETIONS                                       * 00025018
*0150005050-005150,015603,017672                                 M0163  00025121
*0150                                                            S21940 00025221
*0150006400                                                      S21040 00025521
*0150015606,017640                                               M0929  00025921
*0150017608-017688                                               M1358  00028721
*D027600                                                        SA53914 00030721
*                                                                     * 00048821
*STATUS CHANGE LEVEL 005                                                00051621
*                                                                     * 00054421
*FUNCTION/OPERATION   WILL POSITION THE TAPE BY EXECUTING A FORWARD   * 00057221
*      SPACE OR BACKSPACE COMMAND THE NUMBER OF TIMES SPECIFIED BY THE* 00060000
*      USER. CONTROL WILL ALSO POSITION THE TAPE AT THE BEGINNING OR  * 00080000
*      END OF A FILE BY EXECUTING A FORWARD SPACE FILE OR BACKSPACE   * 00100000
*      FILE                                                           * 00120000
*                                                                       00121021
*      CNTRL WILL POSITION TAPES CONTAINING DOS EMBEDDED CHECKPOINT     00122021
*      RCDS.  IF THE BYPASS EMBEDDED DOS CHKPT RCDS OPTION IS SPECIFIED 00123021
*      (DCBOPTCD BIT 3 SET TO ONE), IT WILL DO A GETMAIN FOR 24 BYTES,  00124021
*      PLACE THE ADDRESS OF THE OBTAINED CORE INTO THE CCW, SET THE     00125021
*      CCW BYTE COUNT TO 20, AND PLACE EITHER A READ FORWARD OR BACK-   00126021
*      WARD COMMAND IN THE CCW.  RECORD POSITIONING REQUIRES            00127021
*      THE READING OF THE FIRST 20 BYTES OF EACH BLOCK INTO THE         00128021
*      OBTAINED CORE.  THE BYPASSING OF ANY ENCOUNTERED EMBEDDED CHKPT  00129021
*      RCDS WILL BE PERFORMED BY THE APPROPRIATE CHANNEL END APPENDAGE  00130021
*      (IGG019EI OR IGG019EJ).                                          00131021
*                                                                       00132021
*      CNTRL NOT TO BE USED FOR BACKSPACING BLOCKS ON 7-TRACK TAPES     00133021
*      WRITTEN IN DATA CONVERT MODE.                                    00134021
*ENTRY POINTS  THE ADDRESS OF THE CONTROL ROUTINE IS LOCATED IN THE   * 00140000
*      USERS DCB WITH AN OFFSET OF 84. ENTRY IS BY MEANS OF THE CNTRL * 00160000
*      MACRO WHICH WILL PROVIDE ENTRY TO CONTROL FOR TAPE AND LINKAGE * 00180000
*      BACK TO THE USERS PROGRAM                                      * 00200000
*INPUT  THE USER MUST INDICATE TO THE CNTRL MACRO WHAT FUNCTION HE    * 00220000
*      WISHES TO EXECUTE AND THE NUMBER OF TIMES HE WANTS TO EXECUTE  * 00240000
*      IT. HE MUST ALSO SUPPLY THE CNTRL MACRO WITH THE DCB ADDRESS.  * 00260000
*OUTPUT NOT APPLICABLE                                                * 00280000
*EXTERNAL ROUTINES  NOT APPLICABLE                                    * 00300000
*                                                                     * 00320000
*EXITS NORMAL  RETURN TO USER WITH REG 15 = 0                         * 00340000
*              IF A TAPE MARK HAS BEEN SENSED BEFORE ALL BACKWARD OR  * 00360000
*              FORWARD SPACES HAVE BEEN COMPLETED REG 15 WILL CONTAIN * 00380000
*              THE REMAINING COUNT OF FORWARD OR BACKWARD SPACES      * 00400000
*ERROR EXIT  UNCORRECTABLE TAPE ERROR -- ROUTINE WILL ABEND OR EXIT   * 00420000
*      TO USERS SYNCHRONOUS ERROR EXIT IF PRESENT WITH THE RETURN     * 00440000
*      ADDRESS IN REGISTER 14, REGISTER 0 = ECB POINTER AND REGISTER  * 00460000
*      1 WILL CONTAIN AN ERROR FLAG IN THE HIGH ORDER BYTE AND THE DCB* 00480000
*      ADDRESS IN THE THREE LOW ORDER BYTES                           * 00500000
*TABLES/WORKAREAS  THE ONLY WORK AREA USED BY CONTROL IS THE 18 WORD  * 00520000
*      SAVEAREA SUPPLIED BY THE USER . THE USERS REGISTERS ARE STORED * 00540000
*      HERE AND ALSO SOME SWITCHES USED BY THE CONTROL ROUTINE ALL OF * 00560000
*      WHICH ARE RESTORED BEFORE CONTROL IS PASSED BACK TO THE USER.  * 00580000
*ATTRIBUTES REENTRANT                                                 * 00600000
*NOTES  THE CONTROL ROUTINE SAVES THE USERS CCW, BUILDS ITS OWN CCW   * 00620000
IGG019BE CSECT                                                          00660000
*                                                                       00662018
*                                                                       00664018
*                                                                       00666018
*                                                                       00668018
*                                                                       00670018
*                                                                       00672018
*                                                                       00674018
*                                                                       00676018
*                                                                       00678018
DECBR    EQU   0                                                        00680000
PARAMPAS EQU   0                                                        00700000
DCBPASAD EQU   1                                                        00720000
CONONE   EQU   1                                                        00740000
TWO      EQU   2                                                        00760000
DCBADDR  EQU   2                                                        00780000
PARAMCT  EQU   3                                                        00800000
IOBADDR  EQU   4                                                        00820000
FOUR     EQU   4                                                        00840000
CCWADDR  EQU   5                                                        00860000
CCWSAVEA EQU   6                                                        00880000
CCWSAVEB EQU   7                                                        00900000
INCRMNT  EQU   8                                                        00920000
EIGHT    EQU   8                                                        00940000
ONE      EQU   9                                                        00960000
ECBADDR  EQU   10                                                       00980000
BASERG   EQU   11                                                       01000000
TWELVE   EQU   12                                                       01020000
NEGONE   EQU   12                                                       01040000
SAVEAREA EQU   13                                                       01060000
RETRN    EQU   14                                                       01080000
COMNDBYT EQU   14                                                       01100000
RECORDCT EQU   15                                                       01120000
SYNADOUT EQU   15                                                       01140000
BSR      EQU   X'27'                                                    01160000
BSM      EQU   X'2F'                                                    01180000
FSR      EQU   X'37'                                                    01200000
FSM      EQU   X'3F'                                                    01220000
TWENTY   EQU   20                                                       01240000
THIR2    EQU   32                                                       01260000
TWENTY8  EQU   28                                                       01280000
SIXTY4   EQU   64                                                       01300000
TWENTY4  EQU   24                                                       01320000
THIR6    EQU   36                                                       01340000
THIR7    EQU   37                                                       01360000
UNITEXCP EQU   X'01'                                                    01380000
PERMERR  EQU   X'C0'                                                    01400000
NOP      EQU   X'03'                                                    01420000
RESTRSW  EQU   X'00'                                                    01440000
TAPEMKSW EQU   X'01'                                                    01460000
SILION   EQU   X'20'                                                    01480000
SIXTY8   EQU   68                                                       01500000
SIXTY    EQU   60                                                       01520000
ZEROBYTE EQU   X'00'                                                    01540000
CNTRLERR EQU   X'20'                                                    01560000
ECB      EQU   12                      OFFSET IN IOB TO ECB      M0929  01560621
*                                                                       01561021
COREADR  EQU   10                       REG TO SAVE CORE ADDR    S21040 01562021
D1       EQU   1                        DISPLACEMENT OF 1        S21040 01563021
D6       EQU   6                        DISPLACEMENT OF 6        S21040 01564021
D19      EQU   19                       DISPLACEMENT OF 19       S21040 01565021
CORADDR  EQU   1                        REG FOR GETMAIN/FREEMAIN S21040 01566021
BYPASS   EQU   X'10'                    BYPASS CHKPT RCDS MASK   S21040 01567021
RDBACK   EQU   X'0C'                    TAPE READ BACK COMMAND   S21040 01568021
CNTRLOFF EQU   X'F7'                    TURN OFF IOB CNTRL BIT   S21040 01569021
RDFWRD   EQU   X'02'                    TAPE READ FORWRD COMMAND S21040 01570021
CSWSTAT  EQU   20                       OFFSET IN IOB TO CSW    SA53914 01570421
*                                          STATUS BYTE                  01570821
*                                                                       01571021
         USING IHADCB,DCBADDR                                           01580000
         USING IGG019BE,BASERG                                          01600000
CNT3STRT STM   DCBPASAD,NEGONE,TWENTY(SAVEAREA)   SAVE USERS REGISTERS  01620000
         LR    DCBADDR,DCBPASAD                                         01640000
         LR    BASERG,15               INITALIZE BASE REGISTER          01660000
         MVI   69(SAVEAREA),RESTRSW    SET SWITCH FOR TESTING TO ZERO   01680000
*                                                                       01700000
*                            THIS SECTION SAVES THE INCREMENT COUNT,    01720000
*                             USERS CCW AND SETS UP DCB,IOB+ECB ADDRSES 01740000
         L     IOBADDR,DCBIOBA          LOAD IOB ADDRESS                01760000
         OI    0(IOBADDR),X'08'         SET THE CNTRL BIT IN IOB A28177 01770019
         LA    ECBADDR,FOUR(IOBADDR)    GET ADDRESS OF ECB              01780000
         ST    ECBADDR,TWELVE(IOBADDR)  STORE ECB ADDR IN ECB POINTER   01800000
         LR    PARAMCT,PARAMPAS         LOAD PARAMETER COUNT            01820000
         LH    INCRMNT,THIR6(0,IOBADDR) LOAD INCREMENT COUNT            01840000
         L     CCWADDR,TWENTY4(IOBADDR) LOAD CCW ADDRESS                01860000
         LM    CCWSAVEA,CCWSAVEB,0(CCWADDR)  LOAD USERS CCW             01880000
         LA    ONE,CONONE              SET UP A + 1                     01900000
         LNR   NEGONE,ONE              SET UP A - 1                     01920000
*                            THIS SECTION TESTS FOR THE TYPE OF OPERAT- 01940000
*                            ION TO BE PERFORMED AND SETS SILI FLAG ON  01960000
         MVI   FOUR(CCWADDR),SILION     SET SILI FLAG ON                01980000
         MVI   7(CCWADDR),X'01'        SET COUNT IN CCW                 02000000
         TM    1(COMNDBYT),FSM         Q---FORWARD SPACE TO TAPE MARK   02020000
         BO    FWDFILE                YES BRANCH                        02040000
         TM    1(COMNDBYT),BSM         Q---BACKSPACE TO LOAD POINT      02060000
         BO    BACKFILE               YES BRANCH                        02080000
*                                                                       02080621
*********************************************************************** 02081221
*                                                                       02081821
*    TEST FOR BYPASS DOS EMBEDDED CHKPT RCD OPTION - IF SPECIFIED DO    02082421
*    GETMAIN FOR 24 BYTES, PLACE OBTAINED CORE ADDR IN CCW, AND SET     02083021
*    CCW BYTE COUNT TO 20.                                              02083621
*                                                                       02084221
*********************************************************************** 02084821
*                                                                       02085421
         TM    DCBOPTCD,BYPASS          BYPASS DOS CHKPT RCDS    S21040 02086021
         BZ    CNTRL100                 BRANCH ON NO             S21040 02086621
*                                                                       02087221
         GETMAIN R,LV=24,SP=0           BUFFER TO READ FIRST 20  S21040 02087821
*                                       BYTES OF EACH BLOCK INTO        02088421
         LR    COREADR,CORADDR          SAVE CORE ADDRESS        S21040 02089021
*                                                                       02089621
         TM    D1(COMNDBYT),FSR         READ FORWARD REQUIRED    S21040 02090221
         BO    CNTRL050                 BRANCH YES               S21040 02090821
*                                                                       02091421
         LA    CORADDR,D19(CORADDR)     PUT DATA ADDR TO END OF  S21040 02092021
*                                       BUFFER FOR READ BACK            02092621
CNTRL050 EQU   *                                                 S21040 02093221
*                                                                       02093821
         ST    CORADDR,0(CCWADDR)       CORE ADDRESS TO CCW      S21040 02094421
         LA    CORADDR,TWENTY           CONSTANT OF 20           S21040 02095021
         STH   CORADDR,D6(CCWADDR)      SET CCW BYTE COUNT TO 20 S21040 02095621
*                                                                       02096221
CNTRL100 EQU   *                                                 S21040 02096821
         TM    1(COMNDBYT),FSR         Q---FORWARD SPACE RECORD         02100000
         BO    FWDSPACE               YES BRANCH-NO-PROC BKSPACE RECD   02120000
*                                                                       02140000
*                                                                       02160000
*                                                                       02180000
*                        THIS SECTION SETS UP THE CHANNEL PROGRAM FOR   02200000
*                        BACKSPACE RECORD UNDER COUNT CONTROL ASSUMING  02220000
*                        MACRO EXPANSION ROUTINE WILL ONLY COME TO THIS 02240000
*                        ROUTINE WITH COMMAND BYTES FOR FSR,BSR,FSM AND 02260000
*                        BSM                                            02280000
*                                                                       02300000
*                                                                       02320000
         STH   ONE,70(SAVEAREA)        STORE A +1 IN THE SAVEAREA       02340000
         MVI   68(SAVEAREA),FSR        STORE A FSR COMMAND IN SAVEAREA  02360000
BAKSPACE STH   NEGONE,THIR6(IOBADDR)   SET CCW INCREMENT COUNT TO -1    02380000
*                                                                       02381021
*********************************************************************** 02382021
*                                                                       02383021
*    TEST FOR BYPASS DOS CHKPT RCD OPTION - IF SPECIFIED PUT READ       02384021
*    BACKWARDS COMMAND IN CCW, OTHERWISE BACKSPACE RCD COMMAND.         02385021
*                                                                       02386021
*********************************************************************** 02387021
*                                                                       02388021
         TM    DCBOPTCD,BYPASS          BYPASS DOS CHKPT RCDS    S21040 02389021
         BZ    REVERSE                  BRANCH ON NO             S21040 02390021
*                                                                       02391021
         MVI   0(CCWADDR),RDBACK        READ BACKWARD COMMAND    S21040 02392021
*                                       TO CCW COMMAND CODE             02393021
         B     CHANPRG1                 EXECUTE CHANNEL PROGRAM  S21040 02394021
REVERSE  MVI   0(CCWADDR),BSR         PUT BKSPRCD COMMAND IN CCW CC     02400000
*                                                                       02420000
*                                                                       02440000
*                                                                       02460000
CHANPRG1 LA    DCBPASAD,EIGHT(IOBADDR) LOAD IOS IOB ADDRESS             02480000
         EXCP  (1)                                                      02500000
         L     DCBPASAD,TWELVE(IOBADDR)  LOAD ECB ADDRESS               02520000
         WAIT  ECB=(1)                                                  02540000
         TM    11(IOBADDR),X'08'       LOAD POINT REACHED               02560000
         BO    RESTOREA                YES BRANCH                       02580000
         TM    69(SAVEAREA),X'08'       COUNT  REACHED  ZERO            02600000
         BO    TPMKTST                  YES BRANCH TO TAPE MARK TEST    02620000
         TM    69(SAVEAREA),X'0F'       FIRST TIME THROUGH CHAN PROG    02640000
         BZ    FILEMARK                 YES BRANCH TO TEST FOR FSM BSM  02660000
REVCOMND MVC   0(1,CCWADDR),68(SAVEAREA)     SET COMMAND CODE IN CCW    02680000
         MVC   36(2,IOBADDR),70(SAVEAREA)    SET INCREMENT COUNT        02700000
         NI    DCBIFLGS,X'3F'                RESET DCBIFLAGS            02720000
         TM    20(IOBADDR),X'01'             UNIT EXCEPTION             02740000
         BZ    CHANPRG1                      GO EXCP            SA53914 02780021
         NI    CSWSTAT(IOBADDR),X'FE'  RESET UNIT EXCEPTION BIT SA53914 02790021
         B     RESTORE                 RETURN TO USER           SA53914 02792021
FILEMARK TM    1(COMNDBYT),BSM         IS THIS A FSM OR A BSM           02800000
         BO    SET1                          YES BRANCH                 02820000
         TM    20(IOBADDR),X'01'             UNIT EXCEPTION             02840000
         BO    RESET1                        YES BRANCH                 02860000
         TM    DCBIFLGS,PERMERR              PERMANENT ERROR            02880000
         BO    ERROROUT                      YES BRANCH                 02900000
         BCT   PARAMCT,CHANPRG1              COUNT = ZERO               02920000
         MVI   69(SAVEAREA),X'08'            YES - SET SAVEAREA +69 =08 02940000
NOPBUILD XC    36(2,IOBADDR),36(IOBADDR)     SET INCREMENT CT TO 0      02960000
         MVI   0(CCWADDR),NOP                PUT NOP COMMAND IN CCW     02980000
         B     CHANPRG1                                                 03000000
TPMKTST  TM    20(IOBADDR),X'01'        TAPE MARK PASSED                03020000
         BZ    RESTORE                  NO BRANCH TO RESTORE ROUTINE    03040000
RESET1   LA    PARAMCT,1(PARAMCT)      CORRECT THE RECORD COUNT         03060000
         MVI   20(IOBADDR),X'00'       RESET UNIT EXCEPTION             03080000
         MVI   69(SAVEAREA),X'01'       SET TO 01                       03100000
         B     REVCOMND                 GO SET UP TO REVERSE TAPE MOTIN 03120000
SET1     MVI   69(SAVEAREA),X'01'                                       03140000
         B     NOPBUILD                 GO BUILD AND EXECUTE NOP CH PRG 03160000
*                                                                       03180000
*                        THIS SECTION RESTORES USERS REGISTERS AND      03200000
*                        RETURNS TO HIM                                 03220000
*                                                                       03240000
*                                                                       03260000
SYNADRUT MVI   20(SAVEAREA),X'20'       SET CNTL ERROR FLAG             03280000
         L     DECBR,TWELVE(IOBADDR)    LOAD THE DECB ADDR INTO REG 0   03300000
         L     SYNADOUT,DCBSYNAD        LOAD SYNAD ADDR INTO REG 15     03320000
RESTORE  LA    RETRN,2(RETRN)                                           03340000
*                                                                       03341021
*********************************************************************** 03342021
*                                                                       03343021
*    DO FREEMAIN IF BYPASS EMBEDDED CHKPT RCDS OPTION WAS SPECIFIED -   03344021
*    CORE ADDRESS OBTAINED FROM REGISTER COREADR (REG 10)               03345021
*                                                                       03346021
*********************************************************************** 03347021
*                                                                       03348021
         TM    DCBOPTCD,BYPASS          BYPASS DOS CHKPT RCDS    S21040 03349021
         BZ    CNTRL200                 BRANCH ON NO             S21040 03350021
*                                                                       03351021
         LR    CORADDR,COREADR          OBTAINED CORE ADDRESS    S21040 03352021
*                                                                       03353021
         FREEMAIN R,LV=24,A=(1)         FREE OBTAINED CORE       S21040 03354021
*                                                                       03355021
CNTRL200 EQU   *                                                 S21040 03356021
         NI    0(IOBADDR),CNTRLOFF      TURN OFF IOB CNTRL BIT   S21040 03357021
         STM   CCWSAVEA,CCWSAVEB,0(CCWADDR)  RESTORE USERS CCW          03360000
         STH   INCRMNT,THIR6(0,IOBADDR)      RESTORE CCW INCREMENT CT   03380000
         NI    DCBIFLGS,X'3F'                RESET DCBIFLGS             03400000
         TM    20(SAVEAREA),X'20'            WAS THERE A PERMANENT ERR  03420000
         BO    ERRETURN                      YES BRANCH                 03440000
         LR    RECORDCT,PARAMCT              PUT # RCDS NOT SPCD IN R15 03460000
         LM    DCBPASAD,NEGONE,TWENTY(SAVEAREA) RESTORE USERS REGISTERS 03480000
         BR    RETRN                                                    03500000
ERRETURN LM    DCBPASAD,NEGONE,TWENTY(SAVEAREA) RESTORE USERS REGS      03520000
         BR    SYNADOUT                                                 03540000
FWDFILE  MVI   68(SAVEAREA),BSR        PUT BSR COMMAND IN SAVEAREA      03560000
         MVI   0(CCWADDR),FSM          PUT FSM IN CCW CC                03580000
         B     RESET                   GO CLEAR INCRCT,BLKCT,PARAMCT    03600000
BACKFILE MVI   68(SAVEAREA),FSR        PUT FSR COMMAND IN SAVEAREA      03620000
         MVI   0(CCWADDR),BSM          PUT BSM COMMAND IN CCW CC        03640000
RESET    SR    PARAMCT,PARAMCT         ZERO THE PARAMETER COUNT         03660000
         STH   PARAMCT,70(SAVEAREA)    STORE HALF WD OF 0 IN SAVEAREA   03680000
         ST    PARAMCT,DCBBLKCT        ZERO DCB BLOCK COUNT             03700000
         STH   PARAMCT,THIR6(0,IOBADDR) ZERO THE INCREMENT COUNT        03720000
         B     CHANPRG1                GO EXECUTE CHANNEL PROGRAM       03740000
FWDSPACE MVI   68(SAVEAREA),BSR        PUT BSR COMMAND IN SAVEAREA      03760000
         STH   NEGONE,70(SAVEAREA)     STORE -1 IN THE SAVEAREA         03780000
         STH   ONE,THIR6(0,IOBADDR)    SET INCREMENT COUNT TO +1        03800000
*                                                                       03801021
*********************************************************************** 03802021
*                                                                       03803021
*    IF BYPASS DOS EMBEDDED CHKPT RCD OPTION SPECIFIED PLACE READ       03804021
*    COMMAND IN CCW - OTHERWISE FORWARD SPACE RECORD (BLOCK).           03805021
*                                                                       03806021
*********************************************************************** 03807021
*                                                                       03808021
         TM    DCBOPTCD,BYPASS          BYPASS DOS CHKPT RCDS    S21040 03809021
         BZ    CNTRL300                 BRANCH ON NO             S21040 03810021
*                                                                       03811021
         MVI   0(CCWADDR),RDFWRD        READ FORWARD COMMAND     S21040 03812021
         B     CHANPRG1                 GO EXECUTE CHAN PROGRAM  S21040 03813021
*                                                                       03814021
CNTRL300 EQU   *                                                 S21040 03815021
         MVI   0(CCWADDR),FSR          PUT A FSR COMMAND IN CCW CC      03820000
         B     CHANPRG1                GO EXECUTE CHANNEL PROGRAM       03840000
RESTOREA LA    PARAMCT,1(PARAMCT)      CORRECT THE RECORD COUNT         03860000
         B     RESTORE                                                  03880000
*                                                                       03900000
*                        THIS SECTION IS EXECUTED FOR MACHINE ERROR     03920000
*                        CONDITIONS                                     03940000
ERROROUT TM    DCBSYNAD+3,UNITEXCP      TEST IF SYNAD PRESENT           03960000
         BZ    SYNADRUT                 YES BRANCH                      03980000
         LH    PARAMPAS,ABENDCON        SET ABEND CODE           I21042 04000021
         LR    DCBPASAD,DCBADDR         REG 1 POINTS TO DCB      I21042 04010021
         SVC   55                       ISSUE EOV FOR            I21042 04020021
*                                       WRITE-TO-PROG AND ABEND         04030021
ABENDCON DC    H'4096'                                                  04040000
PATCH    DC    10H'0'                   PATCH AREA              SA53914 04050021
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY   04060000
         CNOP  0,8                 PAD MODULE TO DOUBLE WORD MULTIPLE   04080000
         DCBD  DSORG=PS                                                 04100000
         END                                                            04120000
