         TITLE 'READ PAPER TAPE TYPE U TRANSLATE'                       00020000
IGG019BF CSECT                                                          00023021
*          RELEASE 19 DELETIONS                                         00044000
*          RELEASE 20 DELETIONS                                         00047000
*          RELEASE 21 DELETIONS                                         00050000
*0831                                                            A40652 00051021
*                                                               SA57186 00051421
* STATUS CHANGE LEVEL 004                                               00053021
*FUNCTION/OPERATION - SCHEDULES I/O FOR PAPER/TAPE READ, TYPE U,      * 00056000
*      TRANSLATE MODE. WAITS FOR COMPLETION OF THE SCHEDULED I/O AND  * 00060000
*      TRANSLATES THE INPUT CODE TO EBCDIC. IF TRANSLATION RESULTS IN * 00080000
*      COMPRESSION OF THE INPUT, MORE I/O IS SCHEDULED AND THE PROCESS* 00100000
*      REPEATED.                                                      * 00120000
*                                                                     * 00140000
*ENTRY POINT - IGG019BF                                               * 00160000
*      CALLING SEQUENCE - SEE DESCRIPTION OF CPS READ MACRO.          * 00180000
*                                                                     * 00200000
*EXTERNAL ROUTINES -                                                  * 00220000
*      IGG019CC - CALL 'EXCP' TO SCHEDULE I/O.                        * 00240000
*      EXCP - SCHEDULE I/O.                                           * 00260000
*      WAIT - WAIT FOR COMPLETION OF I/O.                             * 00280000
*                                                                     * 00300000
******** REGISTER DEFINITIONS ********                                  00320000
*        ALL REGISTERS ARE GIVEN SYMBOLIC DESIGNATIONS R0-R15.  ALL     00340000
*        REFERENCES TO A REGISTER ARE IN TERMS OF MNEMONIC NAMES WHICH  00360000
*        HAVE BEEN DEFINED BY MEANS OF THESE SYMBOLIC DESIGNATIONS.     00380000
*        FURTHERMORE, USES OF ONE REGISTER FOR DIFFERENT PURPOSES ARE   00400000
*        GIVEN DIFFERENT MNEMONIC NAMES. THESE CONVENTIONS WILL REDUCE  00420000
*        THE CHANGING OF REGISTER USAGE TO A MATTER OF CHANGING ONE EQU 00440000
*        STATEMENT PER CHANGE IN FUNCTIONAL USE OR TO CHANGE THE ACTUAL 00460000
*        REGISTER USED BY ALL FUNCTIONS SHARING ONE REGISTER. THE USER  00480000
*        IS CAUTIONED TO OBSERVE MACHINE DEPENDENT AND CONVENTION       00500000
*        DEPENDENT REGISTER USAGE.                                      00520000
R0       EQU   0                                                        00540000
R1       EQU   1                                                        00560000
R2       EQU   2                                                        00580000
R3       EQU   3                                                        00600000
R4       EQU   4                                                        00620000
R5       EQU   5                                                        00640000
R6       EQU   6                                                        00660000
R7       EQU   7                                                        00680000
R8       EQU   8                                                        00700000
R9       EQU   9                                                        00720000
R10      EQU   10                                                       00740000
R11      EQU   11                                                       00760000
R12      EQU   12                                                       00780000
R13      EQU   13                                                       00800000
R14      EQU   14                                                       00820000
R15      EQU   15                                                       00840000
         SPACE 2                                                        00860000
WRKR2    EQU   R0                  WORK                                 00880000
PAR1     EQU   R1                  PARAMETER REGISTER 1.                00900000
IOBR     EQU   R3                  ADDRESS OF IOB USED FOR CURRENT READ 00920000
CCWR     EQU   R4                  LOCATION OF CCW FOR THE READ.        00940000
NCHTBTR  EQU   R5                  NUMBER OF CHARACTERS REMAINING IN    00960000
*                                    THE INPUT STRING TO BE TRANSLATED. 00980000
TRTBR    EQU   R6                  LOC OF LOWER CASE TRANSLATE TABLE.   01000000
BASER    EQU   R7                  BASE REGISTER FOR THIS ROUTINE.      01020000
OSPR     EQU   R8                  CURRENT LOCATION IN THE OUTPUT       01040000
*                                    STRING.                            01060000
ISPR     EQU   R9                  CURRENT LOCATION IN THE INPUT STRING 01080000
DECBR    EQU   R10                                                      01100000
DCBR     EQU   R11                                                      01120000
SAVER    EQU   R13                 ADDRESS OF SAVE AREA SUPPLIED BY     01140000
*                                    THE USER.                          01160000
RETR     EQU   R14                 RETURN ADDRESS.                      01180000
ENTR     EQU   R15                      ENTRY REGISTER.                 01200000
CTRTBR   EQU   R15                 LOC OF CURRENT CASE TABLE            01220000
         SPACE 2                                                        01240000
*        IMMEDIATE OPERAND DEFINITIONS                                  01260000
         SPACE 1                                                        01280000
INVBIT   EQU   X'01'               BIT INDICATING INVALID CHAR FOUND.   01300000
CASBIT   EQU   X'02'               BIT INDICATING UPPER OR LOWER CASE.  01320000
CEOF     EQU   X'20'               END OF FILE BIT FOR CIND1.           01340000
EORBIT   EQU   X'04'               BIT FOR EOR ENCOUNTERED.             01360000
OKBITS   EQU   X'7F'               NO ERROR INDICATION                  01380000
EOFBIT   EQU   X'01'               BIT TO TEST CSW FOR EOF.             01400000
ILBIT    EQU   X'40'               USED TO TEST FOR WRONG LENGTH READ.  01420000
ECBERB   EQU   X'41'               INDICATES ERROR ON READ IN ECB.      01440000
OFFBIT   EQU   X'00'                                                    01460000
CHERR    EQU   X'01'               ERROR IND FOR CHECK.                 01480000
CHINV    EQU   X'02'               INVALID CHAR IND FOR CHECK.          01500000
FIRST    EQU   X'01'                    USED TO RESET I/O REQUEST TYPE. 01520000
READ     EQU   X'20'               USED TO SET I/O TYPE TO READ.        01540000
FORMATU  EQU   X'C0'               MASK FOR TYPE U RECORDS.             01560000
DATALNT  EQU   6                  OFFSET IN CCW FOR DATA LENGTH SA57186 01570021
         EJECT                                                          01580000
         USING IGG019BF,BASER                                           01620021
         USING IHADCB,DCBR                                              01640000
         USING DSAVE,SAVER                                              01660000
         USING DIOB,IOBR                                                01680000
         USING DDECB,DECBR                                              01700000
         STM   R2,R14,SR2          SAVE USER REGISTERS.                 01720000
         LR    BASER,R15           SET BASE REGISTER.                   01740000
         LR    DECBR,PAR1          SET DECB BASE.                       01760000
         L     DCBR,DECBDCB        ESTABLISH DCB BASE AND               01780000
         L     IOBR,DCBIOBA               OLD IOB BASE.                 01800000
*                                                                       01820000
         L     IOBR,0(IOBR)             LINK TO NEW IOB.                01840000
         ST    IOBR,DCBIOBA             STORE NEW IOB BASE IN DCB.      01860000
*                                                                       01880000
         L     OSPR,DECBAREA       SET OSP (OUTPUT STRING POINTER)      01900000
*                                    = UIA (USER INPUT AREA).           01920000
         TM    DCBCIND1,CEOF       WAS THERE AN EOF DURING LAST READ?   01940000
         BO    POSTEOF             YES.                                 01960000
*                                  NO,                                  01980000
         LA    WRKR2,IOBIOS        GET ADDR FOR IOS REFERENCE TO IOB.   02000000
         ST    WRKR2,DECBIOBP        PUT IT INTO DECB.                  02020000
         ST    DECBR,IOBECBPT           PUT DECB BASE IN IOB.           02040000
*                                                                       02060000
         SR    CCWR,CCWR                CALCULATE CCW ADDRESS.          02080000
         IC    CCWR,DCBOFFSR                                            02100000
         AR    CCWR,IOBR                                                02120000
*                                                                       02140000
         NI    IOB,FIRST                RESET TYPE BITS IN IOB.         02160000
         OI    IOB,READ            SET TYPE TO READ.                    02180000
*                                                                       02200000
         NI    DCBDEVT+2,X'FF'-EORBIT-INVBIT  SET INVALID CHAR AND      02220000
*                                               EOR FLAGS OFF.          02240000
         L     TRTBR,DCBLCTBL      GET ADDR OF TRANSLATION TABLES.      02260000
READMOR  EQU   *                                                        02280000
        LH    NCHTBTR,DECBLNG     GET LENGTH REQUESTED FROM DECB.       02300000
        TM    DCBRECFM,FORMATU    TYPE U RECORDS?                       02320000
         BC    12,DCBLN                NO, GET LENGTH FROM DCB     9544 02330013
         TM    4(DECBR),X'80'          WAS 'S' SPECIFIED           9544 02340013
         BC    8,TYPEU                 NO, USE DECB LENGTH         9544 02350013
DCBLN    LH    NCHTBTR,DCBBLKSI        GET LENGTH FROM DCB         9544 02360013
TYPEU   EQU   *                                                         02380000
         A     NCHTBTR,DECBAREA    CALCULATE NUMBER OF CHARACTERS LEFT  02400000
        SR    NCHTBTR,OSPR          TO BE READ AND TRANSLATED.          02420000
*                                                                       02440000
         STH   NCHTBTR,6(0,CCWR)   STORE LENGTH OF THIS READ IN CCW.    02460000
         LR    WRKR2,OSPR          STORE READ STARTING LOC IN CCW.      02480000
         STH   WRKR2,2(CCWR)                                            02500000
         SRL   WRKR2,16                                                 02520000
         STC   WRKR2,1(CCWR)                                            02540000
*                                                                       02560000
SETISP   EQU   *                                                        02580000
         LR    ISPR,OSPR           ISP AND OSP ARE NECESSARILY EQUAL    02600000
*                                     WHEN MORE DATA IS READ.           02620000
         LR    R2,DCBR             SET DCB BASE FOR EOB ROUTINE.        02640000
         L     ENTR,DCBEOBR        GET ADDR OF EOB ROUTINE.             02660000
         BALR  RETR,ENTR           GO THERE AND READ A RECORD.          02680000
*                                  WAIT FOR COMPLETION OF READ SO       02700000
*                                    TRANSLATION CAN BE DONE.           02720000
         LA    PAR1,0(DECBR)           SET DECB IN REG FOR WAIT    9026 02740013
         WAIT  ECB=(1)                                                  02760000
         LH    WRKR2,IOBCSW2+2     GET RESIDUAL COUNT                   02780000
         SR    CCWR,CCWR               CALCLUATE CCW ADDR       SA57186 02780421
         IC    CCWR,DCBOFFSR           GET OFFSET TO READ CCW   SA57186 02780821
         AR    CCWR,IOBR               ADDR OF READ CCW         SA57186 02781221
         LH    NCHTBTR,DATALNT(0,CCWR)  LENGTH OF DATA TO READ  SA57186 02781621
         CR    NCHTBTR,WRKR2           RETURN COUNT ZERO?        A40652 02782021
         BNE   NOTZERO                                           A40652 02784021
         TM    DECBPOST,OKBITS                                   A40652 02786021
         BL    NOTZERO                                           A40652 02788021
         B     SETISP                                            A40652 02790021
NOTZERO  EQU   *                                                 A40652 02792021
         SR    NCHTBTR,WRKR2       CALC NUMBER OF CHARS READ AND TO BE  02800000
*                                    TRANSLATED.                        02820000
         NI    IOBIOS+3,OFFBIT     CLEAR SENSE BYTE 2 (NEVER SENT BY    02840000
*                                    PAPER TAPE READER).                02860000
         TM    DECBPOST,OKBITS     WAS THERE AN ERROR INDICATION?       02880000
         BM    EXCEPT              YES, GO SEE WHAT IT WAS.             02900000
         LTR   WRKR2,WRKR2         NO, IS RESIDUAL COUNT ZERO.          02920000
         BC    7,SETEOR            NO, BRANCH.                          02940000
*                                                                       02960000
TESTVAL  EQU   *                                                        02980000
*                                                                       03000000
         SR    2,2                 CLEAR REG 2 FOR USE WITH TRT.        03020000
         TRT   0(1,ISPR),256(TRTBR) TEST ONE CHAR AT A TIME TO SEE      03040000
*                                    WHAT SHOULD BE DONE WITH IT.  THE  03060000
*                                  FUNCTION BYTE (AS DEFINED IN THE     03080000
*                                    DESCRIPTION OF TRT) WILL BE USED   03100000
*                                    AS THE DISPLACEMENT                03120000
*                                  IN A BRANCH LIST TO LOCATE THE       03140000
*                                  ROUTINE HANDLING THAT CLASS OF       03160000
*                                  CHARACTER.                           03180000
         BC    7,BRLIST(2)         DON'T GO IF FUNCTION BYTE WAS ZERO.  03200000
TRANSL   EQU   *                                                        03220000
         LR    CTRTBR,TRTBR        SET CURRENT CASE TABLE EQUAL LOWER.  03240000
         TM    DCBDEVT+2,CASBIT    WHICH CASE ARE WE IN?                03260000
         BZ    LOWER               LOWER CASE--ALREADY SET.             03280000
         LA    CTRTBR,512(0,CTRTBR) UPPER CASE.                         03300000
*                                                                       03320000
LOWER    EQU   *                                                        03340000
*                                                                       03360000
         TRT   0(1,ISPR),0(CTRTBR) TRANSLATE ONE CHARACTER.             03380000
         STC   2,0(0,OSPR)         PUT IT INTO OUTPUT STRING.           03400000
ADVOI    LA    OSPR,1(0,OSPR)      ADVANCE ONE POSITION IN OUTPUT STR.  03420000
ADVI     LA    ISPR,1(0,ISPR)      ADVANCE ONE IN INPUT STREAM.         03440000
         BCT   NCHTBTR,TESTVAL     RETURN FOR ANOTHER CHARACTER UNTIL   03460000
*                                  INPUT IS EXHAUSTED.                  03480000
         TM    DECBPOST,OKBITS     ERROR ON LAST READ?                  03500000
         BM    MVERRC              YES, BRANCH.                         03520000
*                                                                       03540000
         CR    ISPR,OSPR           NO, IS OUTPUT STRING FULL?           03560000
         BE    TESTINV             YES. ISPR AND OSPR WILL BE EQUAL     03580000
*                                    ONLY IF THE OUTPUT STRING IS       03600000
*                                    FULL(OR COMPLETELY EMPTY, IN WHICH 03620000
*                                    CASE WE CANNOT BE HERE, OR WHEN    03640000
*                                    A TAPE READ ERROR OCCURRED AND     03660000
*                                    ALL OF THE CHARACTERS READ WERE    03680000
*                                    TRANSLATABLE, IN WHICH CASE WE     03700000
*                                    CANNOT BE HERE).                   03720000
         TM    DCBDEVT+2,EORBIT    NO, HAS EOR BEEN ENCOUNTERED?        03740000
         BO    TESTINV             YES, NO MORE CHARS SHOULD BE READ.   03760000
         B     READMOR             NO, GO READ MORE CHARACTERS.         03780000
*                                                                       03800000
SETEOR   EQU   *                                                        03820000
*                                                                       03840000
         OI    DCBDEVT+2,EORBIT    SET EOR CHARACTER ENCOUNTERED.       03860000
*                                                                       03880000
         LTR   NCHTBTR,NCHTBTR     WAS EOR ONLY THING READ?             03900000
         BZ    TESTINV             YES, BRANCH.                         03920000
         B     TESTVAL             NO.                                  03940000
*                                                                       03960000
MVERRC   EQU   *                                                        03980000
         MVC   0(1,OSPR),0(ISPR)   MOVE ERROR CHARACTER TO OUTPUT       04000000
*                                    STRING.                            04020000
         LA    OSPR,1(0,OSPR)      INCREASE OUTPUT STRING POINTER.      04040000
*                                                                       04060000
TESTINV  EQU   *                                                        04080000
         TM    DCBDEVT+2,INVBIT    WAS THERE AN INVALID CHARACTER?      04100000
         BZ    RETURN              NO.                                  04120000
         OI    IOBIOS+3,CHINV      SET INVALID CHAR BIT FOR CHECK.      04140000
RETURN   EQU   *                                                        04160000
         S     OSPR,DECBAREA       GIVE USER LENGTH OF RECORD.          04180000
         STH   OSPR,DCBLRECL                                            04200000
         LM    R2,R14,SR2          RESTORE USER REGISTERS.              04220000
         BR    RETR                RETURN TO READ ROUTINE.              04240000
EXCEPT   EQU   *                                                        04260000
         TM    IOBCSW2,EOFBIT      IS THIS EOF?                         04280000
         BO    ANYTRAN             YES.                                 04300000
*                                  NO, IT IS A PARITY ERROR.            04320000
         OI    IOBIOS+3,CHERR      SET ERROR BIT FOR CHECK.             04340000
         LTR   NCHTBTR,NCHTBTR          IS THERE ANY CHARACTERS   13481 04346016
         BZ    RETURN                   NO                        13481 04352016
         BCT   NCHTBTR,TESTVAL     WE DO NOT WANT TO TRANSLATE THE      04360000
*                                    ERROR CHARACTER, SO WE MUST ADJUST 04380000
*                                    THE CHAR COUNT BY ONE. IF THE      04400000
*                                    RESULTANT COUNT IS ZERO, BYPASS    04420000
*                                    TRANSLATION LOOP.                  04440000
         B     MVERRC              COUNT IS ZERO.                       04460000
ANYTRAN  C     OSPR,DECBAREA       HAVE ANY CHARACTERS BEEN TRANSLATED? 04480000
         BE    RETURN              NO. RETURN TO USER THRU READ ROUTINE 04500000
         MVI   DECBPOST,OKBITS     YES, RESET ECB                       04520000
         NI    IOBCSW2,X'FF'-EOFBIT  AND UNIT EXCEPTION BIT IN CSW.     04540000
*                                    STATUS BYTE.                       04560000
         OI    DCBCIND1,CEOF       IND EOF FOR NEXT TIME THRU READ.     04580000
*                                    READ.                              04600000
         B     TESTINV             PREPARE TO RETURN TO USER.           04620000
POSTEOF  MVI   IOBCSW2,EOFBIT      SET UNIT EXCEPTION (EOF) IN CSW.     04640000
         MVI   DECBPOST,ECBERB     SET ERROR IND. IN ECB.               04660000
         B     RETURN              BACK TO USER WITH EOF IND.           04680000
*                                                                       04700000
BRLIST   EQU   *                                                        04720000
*                                                                       04740000
         B     TRANSL              OFFSET 0. (SHOULD NEVER GET HERE).   04760000
         B     TRANSL              OFFSET 4. DUMMY                      04780000
         B     UPCASE              OFFSET 8. SHIFT TO UPPER CASE.       04800000
         B     LOCASE              OFFSET C. SHIFT TO LOWER CASE.       04820000
         B     INVALID             OFFSET 10. INVALID IN BOTH CASES.    04840000
         B     DELETE              OFFSET 14. VALID, DELETE IN BOTH     04860000
*                                             CASES.                    04880000
         B     VLOIUP              OFFSET 18  VALID IN LOWER CASE,      04900000
*                                             INVALID IN UPPER CASE.    04920000
         B     VUPILO              OFFSET 1C  VALID IN UPPER CASE,      04940000
*                                             INVALID IN LOWER CASE.    04960000
         B     VDLOIUP             OFFSET 20  VALID, DELETE IN LOWER    04980000
*                                             CASE. INVALID IN UPPER.   05000000
         B     TRANSL              OFFSET 24. DUMMY                     05020000
         B     VDLOTUP             OFFSET 28. VALID, DELETE IN LOWER    05040000
*                                             CASE. TRANSLATE IN UPPER  05060000
         B     VDUPTLO             OFFSET 2C. VALID, DELETE IN UPPER    05080000
*                                             CASE. TRANSLATE IN LOWER. 05100000
         B     VDUPILO             OFFSET 30. VALID, DELETE IN UPPER    05120000
*                                             CASE, INVALID IN LOWER.   05140000
UPCASE   EQU   *                                                        05160000
         OI    DCBDEVT+2,CASBIT    SET UPPER CASE BIT.                  05180000
         B     ADVI                GET NEXT CHAR FROM INPUT STRING.     05200000
*                                                                       05220000
LOCASE   EQU   *                                                        05240000
         NI    DCBDEVT+2,X'FF'-CASBIT  SET LOWER CASE BIT.              05260000
         B     ADVI                GET NEXT CHAR FROM INPUT STRING.     05280000
*                                                                       05300000
INVALID  EQU   *                                                        05320000
         OI    DCBDEVT+2,INVBIT    SET INVALID CHAR FLAG ON.            05340000
         B     TRANSL              GO TRANSLATE IT (NORMALLY TO FF).    05360000
*                                                                       05380000
DELETE   EQU   *                                                        05400000
         B     ADVI                DON'T TRANSLATE--JUST GET NEXT CHAR  05420000
*                                    FROM INPUT STRING.                 05440000
VLOIUP   EQU   *                                                        05460000
         TM    DCBDEVT+2,CASBIT    ARE WE IN LOWER CASE?                05480000
         BZ    TRANSL              YES, TRANSLATE.                      05500000
         B     INVALID             NO, INVALID.                         05520000
*                                                                       05540000
VUPILO   EQU   *                                                        05560000
         TM    DCBDEVT+2,CASBIT    ARE WE IN UPPER CASE?                05580000
         BO    TRANSL              YES, TRANSLATE.                      05600000
         B     INVALID             NO, INVALID.                         05620000
*                                                                       05640000
VDLOIUP  EQU   *                                                        05660000
         TM    DCBDEVT+2,CASBIT    ARE WE IN LOWER CASE?                05680000
         BZ    ADVI                YES, DON'T TRANSLATE.                05700000
         B     INVALID             NO, INVALID.                         05720000
*                                                                       05740000
VDLOTUP  EQU   *                                                        05760000
         TM    DCBDEVT+2,CASBIT    ARE WE IN LOWER CASE?                05780000
         BZ    ADVI                YES, DON'T TRANSLATE.                05800000
         B     TRANSL              NO, TRANSLATE.                       05820000
*                                                                       05840000
VDUPTLO  EQU   *                                                        05860000
         TM    DCBDEVT+2,CASBIT    ARE WE IN UPPER CASE?                05880000
         BO    ADVI                YES, DON'T TRANSLATE.                05900000
         B     TRANSL              NO, TRANSLATE.                       05920000
*                                                                       05940000
VDUPILO  EQU   *                                                        05960000
         TM    DCBDEVT+2,CASBIT    ARE WE IN UPPER CASE?                05980000
         BO    ADVI                YES, DON'T TRANSLATE.                06000000
         B     INVALID             NO, INVALID.                         06020000
PATCH    DC    20H'0'              PATCH AREA                   SA57186 06030021
*                                                                       06040000
*   THE FOLLOWING CNOP MUST REMAIN ON A HALF WORD BOUNDARY.             06060000
         CNOP  0,8                 PAD MODULE TO DOUBLE WORD BOUNDARY.  06080000
         EJECT                                                          06100000
DSAVE    DSECT                     DESCRIPTION OF THE SAVE AREA.        06120000
         SPACE                                                          06140000
         DS    5F                                                       06160000
SR2      DS    F                                                        06180000
SR3      DS    F                                                        06200000
SR4      DS    F                                                        06220000
SR5      DS    F                                                        06240000
SR6      DS    F                                                        06260000
SR7      DS    F                                                        06280000
SR8      DS    F                                                        06300000
SR9      DS    F                                                        06320000
SR10     DS    F                                                        06340000
SR11     DS    F                                                        06360000
SR12     DS    F                                                        06380000
SR13     DS    F                                                        06400000
SR14     DS    F                                                        06420000
         SPACE 2                                                        06440000
DIOB     DSECT                     DESCRIPTION OF THE IOB.              06460000
         SPACE                                                          06480000
IOB      DS    0F                  BEGINNING OF IOB AS KNOWN TO SAM.    06500000
IOBLINK  DS    F                   POINTER TO NEXT IOB.                 06520000
IOBQECB  DS    F                   ECB FOR QSAM.                        06540000
IOBIOS   DS    F                   BEGINNING OF IOB AS KNOWN TO IOS.    06560000
IOBECBPT DS    F                   POINTER TO ECB FOR QSAM AND BSAM.    06580000
*                                  FOR BSAM THE ECB IS THE FIRST WORD   06600000
*                                  OF THE DECB.                         06620000
IOBCSW1  DS    F                   FIRST WORD OF CSW.                   06640000
IOBCSW2  DS    F                   SECOND WORD OF CSW.                  06660000
IOBCPPT  DS    F                   POINTER TO CHANNEL PROGRAM.          06680000
IOBDCBPT DS    F                   POINTER TO FIRST WORD OF THE DCB.    06700000
         DS    2F                                                       06720000
IOBCCW   DS    F                   CHANNEL PROGRAM FOR PAPER TAPE.      06740000
         SPACE 2                                                        06760000
DDECB    DSECT                     DESCRIPTION OF THE DECB.             06780000
         SPACE                                                          06800000
DECB     DS    0F                                                       06820000
DECBPOST DS    1C                  BYTE WHERE COMPLETION OF I/O IS      06840000
*                                  POSTED.                              06860000
         DS    CL3                                                      06880000
DECBTYPE DS    CL2                 SF OR SB FOR FORWARD OR BACKWARD.    06900000
DECBLNG  DS    CL2                 LENGTH OF READ/WRITE FOR U RECORDS.  06920000
DECBDCB  DS    F                   POINTER TO DCB.                      06940000
DECBAREA DS    F                   POINTER TO USER I/O AREA.            06960000
DECBIOBP DS    F                   POINTER TO IOB AS KNOWN TO IOS.      06980000
         SPACE 2                                                        07000000
         DCBD  DSORG=PS                                                 07020000
         END                                                            07040000
