         TITLE 'IGG019BG - PAPER TAPE CHECK ROUTINE'                    00020000
*          RELEASE 18 DELETIONS                                       * 00021018
*9004                                                             22858 00022018
*          RELEASE 19 DELETIONS                                       * 00023018
*1027013000,025400-025800                                        M4870  00023519
*          RELEASE 20 DELETIONS                                       * 00024018
*          RELEASE 21 DELETIONS                                       * 00025018
*          RELEASE 22 DELETIONS                                       * 00026018
*          VS1 RELEASE 2 DELETIONS                                      00028002
*                                                              OY00199  00030002
*                                                                     * 00032018
*STATUS CHANGE LEVEL 002                                                00033019
*                                                                     * 00034018
*FUNCTION/OPERATION - THIS IS A SPECIAL CHECK ROUTINE FOR PAPER TAPE  * 00040000
*      ONLY. IT WILL:                                                 * 00060000
*                                                                     * 00080000
*              1. WAIT FOR COMPLETION OF DECB SPECIFIED,              * 00100000
*              2. CALCULATE RECORD LENGTH IF TRANSLATION WAS NOT DONE,* 00120000
*              3. TEST FOR ERROR AND:                                 * 00140000
*                    A. EXIT IF NO ERROR.                             * 00160000
*                    B. IF ERROR, IT WILL GO TO SYNAD OR ABEND IF     * 00180000
*                       THERE IS NO SYNAD.                            * 00200000
*                       IF RETURN IS MADE FROM SYNAD, AND INVALID     * 00220000
*                       INPUT CODE FOR TRANSLATION WAS NOT THE ONLY   * 00240000
*                       ERROR, ALL PURGED BUFFERS WILL BE RESCHEDULED.* 00260000
*                       IT WILL THEN EXIT.                            * 00280000
*                    C. IF ERROR WAS REALLY END OF FILE, IT WILL GO TO* 00300000
*                       THE EOV ROUTINE.                              * 00320000
*                       IF RETURN IS MADE FROM EOV, CHECK WILL PERFORM* 00340000
*                       ALL FUNCTIONS AGAIN ON THE BUFFER SCHEDULED BY* 00360000
*                       EOV.                                          * 00380000
*                                                                     * 00400000
*ENTRY POINT - IGG019BG - CHECK MACRO EXPANSION    LA     1,DCBADDR   * 00420000
*                                                  L      15,52(1)    * 00440000
*                                                  BALR   14,15       * 00460000
*                                                                       00480000
*INPUT -                                                              * 00500000
*   1.DECB                                                            * 00520000
*     DECB+1   ECB CHECKED FOR COMPLETE W/WO ERROR                    * 00540000
*     DECB+8   ADDRESS OF DCB                                         * 00560000
*     DECB+16  ADDRESS OF CURRENT IOS IOB (BSAM IOB+8)                * 00580000
*   2.DCB                                                             * 00600000
*     DCBCODE - TRANSLATION CODE SPECIFIED (IF ANY).                  * 00620000
*     DCBIOBA  ADDRESS OF LAST SCHEDULED IOB,USED WHEN RESCHEDULING   * 00640000
*     DCBSYNAD ADDRESS OF USER SYNAD ROUTINE                          * 00660000
*   3.IOB (BSAM IOB IS IOS IOB WITH 8 BYTES APPENDED)                 * 00680000
*     IOB+0    ADDRESS OF NEXT IOB IN CHAIN - USED TO RESCHEDULE      * 00700000
*     IOB+11   USED TO PASS INVALID CHARACTER INDICATION AND PERM     * 00720000
*              ERROR INDICATION FROM READ TO CHECK                    * 00740000
*     IOB+20   CSW STATUS BYTE - X'02' IS UNIT CHECK                  * 00760000
*                                X'01' IS EXCEPTIONAL COND.(FILE MARK)* 00780000
*                                                                     * 00800000
*OUTPUT -                                                             * 00820000
*   1.DECB                                                            * 00840000
*     DECB+0   ECB SET TO X'7F'(COMP/NO ERROR) BEFORE EOV             * 00860000
*   2.DCB                                                             * 00880000
*     DCBIFLGS IOS ERROR FLAGS(X'CO') RESET BEFORE SYNAD AND EOV.     * 00900000
*     DCBOFLGS FILE MARK IND(X'04') SET BEFORE EOV.                   * 00920000
*   3.IOB (LAST SCHEDULED,FROM DCBIOBA)                               * 00940000
*     IOB+4    LOADED WITH CURRENT IOB(WITH EOV IND) ADDRESS FOR EOV  * 00960000
*              RESCHEDULING                                           * 00980000
*                                                                     * 01000000
*EXTERNAL ROUTINES - NONE                                             * 01020000
*                                                                     * 01040000
*EXITS/NORMAL - RETURN TO CALLING ROUTINE ON REG.14. REGS.2-13 RESTORE* 01060000
*                                                                     * 01080000
*EXITS/ERROR -                                                        * 01100000
*   1.SYNAD REG.0 DECB ADDRESS                                        * 01120000
*           REG.1 DCB ADDRESS + HIGH BYTE X'80' - READ ERROR          * 01140000
*           REG.14 RETURN ADDRESS IN CHECK                            * 01160000
*           REG.15 SYNAD                                              * 01180000
*           REG.2-13 - RESTORED                                       * 01200000
*   NOTE: SAVE AREA (REG.13) CAN NOT BE USED IF RETURN TO CHECK IS TO * 01220000
*         BE MADE FROM SYNAD.                                         * 01240000
*   2.EOV - ENTERED ON EOV INDICATION. ALL USER                       * 01260000
*         REGS EXCEPT 15,0,1 RESTORED. REG.1 CONTAINS DCB ADDR.       * 01280000
*         ENTERED ON PERM. ERROR AND NO SYNAD IN DCB.                   01300019
*                                                                     * 01320000
*TABLES/WORKAREAS - SAVE AREA POINTED TO BY REG.13                    * 01340000
*   SAVE+20 - REG.2                                                   * 01360000
*   SAVE+24   REG.3                                                   * 01380000
*   SAVE+28   REG.4                                                   * 01400000
*   SAVE+32   REG.5                                                   * 01420000
*   SAVE+36   REG.6                                                   * 01440000
*   SAVE+40   BASE OF CHECK UPON ENTRY TO SYNAD                       * 01460000
*                                                                     * 01480000
*ATTRIBUTES - REENTRANT,REUSABLE                                      * 01500000
*NOTES - INSTRUCTIONS LABELED *** ARE USED AS CONSTANTS               * 01520000
*                                                                     * 01540000
*                                                                     * 01560000
SAVR     EQU   13                      ADDRESS OF USER SAVE AREA        01580000
RETR     EQU   14                      RETURN ADDR. OF CALLING ROUTINE  01600000
ENTR     EQU   15                      ENTRY POINT - LOADED FROM DCB+52 01620000
SYNADR   EQU   0                       CONTAINS DECB ADDR. FOR SYNAD RT 01640000
PARR     EQU   1                       CONTAINS DECB ADDR. FOR CHECK    01660000
DCBR     EQU   2                       DCB ADDRESS                      01680000
IOBR     EQU   3                       IOB ADDRESS (IOS IOB - 8)        01700000
DECBR    EQU   4                       DECB ADDRESS                     01720000
BASR     EQU   5                       BASE FOR CHECK                   01740000
WRKR1    EQU   6                       WORK REGISTER                    01760000
COMP     EQU   X'7F'                                                    01780000
EXCEPT   EQU   X'01'                   TEST UNIT EXCEPTION IN CSW       01800000
ONE      EQU   X'01'                   TEST SYNAD VECTOR FOR X'XXXXX1'  01820000
NOERROR  EQU   X'3F'                   RESET DCB ERROR IND.             01840000
FILEMARK EQU   X'04'                   SET FILE MARK BIT IN DCB         01860000
INVBIT   EQU   X'02'               INVALID CHAR INDICATOR IN IOB.    PT 01880000
ERRBIT   EQU   X'01'               PARITY OR WRONG LENGTH IND IN IOB.PT 01900000
REGINV   EQU   X'04'               INVALID CHAR IND IN REG 1 FOR SYNAD. 01920000
TRANS    EQU   X'7E'               BITS TO TEST FOR TRANSLATE MODE.  PT 01940000
         SPACE 1                                                        01960000
IGG019BG CSECT                                                          01980000
*                                                                       01982018
*                                                                       01984018
*                                                                       01986018
*                                                                       01988018
*                                                                       01990018
*                                                                       01992018
*                                                                       01994018
*                                                                       01996018
*                                                                       01998018
         USING IGG019BG,BASR                                            02000000
         USING IHADCB,DCBR                                              02020000
         SPACE                                                          02040000
         STM   PARR,WRKR1,20(SAVR)     SAVE USER REGISTERS              02060000
         LR    BASR,ENTR               SET UP BASE REG.                 02080000
CONST8   L     DCBR,8(PARR)         ***LOAD DCB ADDR. FROM DECB     *** 02100000
         LA    DCBR,0(DCBR)            CLEAR HIGH BYTE          OY00199 02110002
         L     IOBR,16(PARR)           LOAD IOS IOB ADDR. FROM DECB     02120000
         SH    IOBR,CONST8+2        ***SUBTRACT 8 FROM IOS IOB ADDR *** 02140000
         LR    DECBR,PARR              LOAD DECB ADDR                   02160000
         SPACE                                                          02180000
         WAIT  ECB=(1)             BE SURE ECB IS COMPLETE.          PT 02200000
         TM    DCBCODE,TRANS       IS FILE IN TRANSLATE MODE?        PT 02220000
         BM    TESTCOMP            YES, REC LENGTH ALREADY CALCULATED.T 02240000
*                                  NO.                                  02260000
         L     WRKR1,24(IOBR)      GET CCW POINTER.                     02280000
         LH    WRKR1,6(WRKR1)      GET COUNT FROM LAST READ.            02300000
         SH    WRKR1,22(IOBR)      SUBTRACT RESIDUAL COUNT.             02320000
         STH   WRKR1,DCBLRECL      STORE RECORD LENGTH IN DCB.          02340000
TESTCOMP TM    0(DECBR),COMP           IS IOB COMPLETE WITH NO ERROR    02360000
         BO    TINV                YES, BRANCH.                      PT 02380000
*                                        CONTINUE IF COMPLETE IN ERROR  02400000
         TM    20(IOBR),EXCEPT         IS EXCEPT.COND. ON IN CSW        02420000
         BO    EOF1                    YES BRANCH                       02440000
         SPACE                                                          02460000
ERROR    TM    DCBSYNAD+3,ONE          IS SYNAD ROUTINE PRESENT         02480000
         BZ    SYNAD1                  YES BRANCH                       02500000
         SPACE                                                          02520000
         LA    SYNADR,1                                          M4870  02530019
         SLL   SYNADR,12                                         M4870  02540019
         LR    PARR,DCBR                                         M4870  02550019
         EOV   (1)        GO TO EOV TO ABEND AND ISSUE WTP.      M4870  02560019
         SPACE                                                          02600000
SYNAD1   EQU   *                                                     PT 02620000
         MVI   8(DECBR),X'80'          SET READ BIT ON                  02640000
         TM    11(IOBR),INVBIT     WAS THERE AN INVALID CHARACTER?   PT 02660000
         BZ    SYNAD3              NO, BRANCH.                       PT 02680000
         OI    8(DECBR),REGINV     SET BIT FOR INVALID CHARACTER.    PT 02700000
         SPACE                                                          02720000
SYNAD3   NI    DCBIFLGS,NOERROR        RESET DCB ERROR INDICATOR        02740000
         LR    SYNADR,DECBR            LOAD DECB ADDR IN REG 0          02760000
         L     PARR,8(DECBR)           LOAD INDICATORS AND DCB ADDR.    02780000
         L     ENTR,DCBSYNAD           LOAD SYNAD                       02800000
         LR    WRKR1,RETR              SAVE RETURN ADDRESS              02820000
         STM   DCBR,WRKR1,44(SAVR)     SAVE CHECK REGISTERS             02840000
         LM    DCBR,WRKR1,24(SAVR)     RESTORE USER REGS                02860000
         BALR  RETR,ENTR               BRANCH TO USER SYNCH. ERROR RT.  02880000
         SPACE                                                          02900000
         LM    DCBR,WRKR1,44(SAVR)     RESTORE CHECK REGS.              02920000
         LR    RETR,WRKR1               RESTORE RETURN REG              02940000
         SPACE                                                          02960000
* ALL IOBS FROM THE ONE FOLLOWING ERROR IOB TO DCBIOBA ARE PLACED BACK  02980000
*    ON IOS QUEUE FOR EXECUTION UNLESS THE ONLY ERROR WAS AN INVALID PT 03000000
*    CHARACTER.                                                      PT 03020000
         SPACE                                                          03040000
         TM    DCBCODE,TRANS       IS FILE IN TRANSLATE MODE?        PT 03060000
         BC    11,QUEUE            NO, BRANCH.                       PT 03080000
         TM    11(IOBR),ERRBIT     WAS THERE ANY ERROR EXCEPT INVALID?P 03100000
         BZ    RETURN              NO, BRANCH--BUFFERS WERE NOT PURGED. 03120000
         SPACE 1                                                        03140000
QUEUE    EQU   *                                                     PT 03160000
         L     WRKR1,DCBIOBA           LOAD ADDR. OF LAST IOB SCHED.    03180000
         LA    WRKR1,0(WRKR1)          ZERO HIGH ORDER BYTE             03200000
LOOP     LA    IOBR,0(IOBR)            ZERO HIGH ORDER BYTE             03220000
         CR    IOBR,WRKR1              COMPARE FIRST REG TO LAST REG    03240000
         BE    RETURN                  BRANCH TO RETURN IF EQUAL        03260000
         L     IOBR,0(IOBR)            LOAD ADDR OF NEXT IOB            03280000
         LA    PARR,8(IOBR)            LOAD ADDR OF IOS IOB             03300000
         EXCP  (1)                     SCHEDULE IOB                     03320000
         B     LOOP                    TEST FOR LAST IOB                03340000
         SPACE                                                          03360000
EOF1     EQU   *                                                     PT 03380000
EOF2     OI    DCBOFLGS,FILEMARK       SET FILE MARK IND IN DCB         03400000
EOF2A    MVI   0(DECBR),COMP           SET ECB COMP NO ERROR            03420000
         L     WRKR1,DCBIOBA           LOAD ADDR OF LAST SCHED IOB      03440000
         ST    IOBR,4(WRKR1)           STORE EOV IOB ADDR. IN LAST IOB  03460000
         LR    PARR,DCBR               LOAD DCB ADDR IN REG 1           03480000
         ST    BASR,44(SAVR)           SAVE CHECK ENTRY AND BASE        03500000
         LM    DCBR,WRKR1,24(SAVR)     RESTORE USER REGS                03520000
         SPACE                                                          03540000
* EOV MAY RETURN TO CHECK UNDER THREE CONDITIONS:                       03560000
*   1. A NEW VOLUME HAS BEEN MOUNTED.                                   03580000
*      INPUT - THIS IOB HAS BEEN SCHEDULED TO READ FIRST RECORD AND     03600000
*              MUST BE WAITED UPON                                      03620000
*      OUTPUT - DISK - THIS IOB SCHEDULED TO WRITE FIRST RECORD ON NEW  03640000
*              EXTENT OR VOLUME AND MUST BE WAITED ON.                  03660000
*      OUTPUT - TAPE - THIS IOB WROTE ON LAST VOLUME. NOT SCHEDULED ON  03680000
*              NEW VOLUME BUT ECB HAS BEEN POSTED COMPLETE NO ERROR SO  03700000
*              WAIT IS OK.                                              03720000
*   2. CONCATONATION -UNLIKE ATTRIBUTES-                                03740000
*   3. CONCATONATION -LIKE ATTRIBUTES- ALL OUTSTANDING IOBS ARE         03760000
*              RESCHEDULE AND THE FIRST ONE IS CHECKED UPON RETURN      03780000
         SPACE                                                          03800000
         EOV   (PARR)                                                   03820000
         L     PARR,20(SAVR)           RESTORE DCB REG.                 03840000
         L     ENTR,44(SAVR)           RESTORE ENTRY POINT              03860000
         BR    ENTR                    RETURN TO START OF CHECK ROUTINE 03880000
TINV     EQU   *                                                     PT 03900000
         TM    11(IOBR),INVBIT     WAS THERE AN INVALID CHARACTER?   PT 03920000
         BO    ERROR               YES, GO TO SYNAD.                 PT 03940000
         SPACE 1                                                     PT 03960000
RETURN   LM    DCBR,WRKR1,24(SAVR)     RESTORE USER REGS                03980000
         BR    RETR                                                     04000000
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY   04020000
         CNOP  0,8                 PAD MODULE TO DOUBLE WORD MULTIPLE   04040000
         SPACE                                                          04060000
         DCBD  DSORG=PS                                                 04080000
         END                                                            04100000
