         TITLE 'IGG019BI-CHECK BSAM I/O BUFFER ACQUISITION'             00020000
IGG019BI CSECT                                                          00030021
*                                                                       00040000
*2074                                                            A37192 00050020
*        RELEASE 21 DELETIONS                                           00052021
*                                                                       00064021
*        RELEASE 21.8 CHANGES                                           00074021
*A012340-012360,025820-025840,027100-027180                     SA63306 00074421
*C015800                                                        SA67221 00076021
*A011300-011500,024500-024860,024868-025040,027600              SA67221 00080021
*                                                                       00100000
*                                                                       00160000
*FUNCTION- TO ACQUIRE NEXT SEQUENTIAL IOB AND WAIT FOR COMPLETION.      00180000
*          TO TEST PREVIOUS EXCP STATUS FOR-                            00200000
*      1)NORMAL COMPLETION RETURNS TO USER                              00220021
*      2)ABNORMAL COMPLETION ISSUES SVC 55 TO SAM DIAGNOSTIC ROUTINE    00240000
*      3)INCOMPLETION ISSUES SVC 1 TO WAIT                              00260000
*                                                                       00280000
*        IF CONDITION NUMBER TWO EXISTS, THE DIAGNOSTIC ROUTINE WILL    00300000
*          RETURN WITH PARAMETERS SET UP FOR A SYNAD ENTRY (SEE CPS     00320000
*          PUBLICATION)                                                 00340000
*        IF AN END OF FILE CONDITION EXISTED, THE SAM DIAGNOSTIC        00360000
*          ROUTINE WILL AGAIN TEST STATUS OF CURRENT IOB.               00380000
*                                                                       00390021
*EXTERNAL REFERENCES- DCB, DECB, IOB, USER SAVE AREA                    00400021
*                                                                       00440021
*ENTRY POINT- IGG019BI VIA CHECK MACRO EXPANSION:                       00460021
*        LA    1,DECB DECB ADDR                                         00480021
*        L     14,8(0,1) DCB ADDR                                       00500021
*        L     15,52(0,14) CHECK ROUTINE ADDR                           00510021
*        BALR  14,15                                                    00512021
*                                                                       00520000
*INPUT-  REGISTER  1  DECB ADDRESS                                      00540021
*        REGISTER 13  USER SAVE AREA ADDRESS                            00560000
*        REGISTER 14  RETURN ADDRESS WITHIN USER ROUTINE                00580021
*        REGISTER 15  IGG019BI FIRST LOCATION ADDRESS                   00600021
*                                                                       00620021
*EXTERNAL ROUTINES- SEE ROUTINES LISTED UNDER 'EXITS'                   00640021
*                                                                       00680000
*EXITS-  SYNAD BY BALR 14,15                                            00700021
*        SAM DIAGNOSTIC BY SVC 55                                       00740000
*        WAIT BY SVC 1                                                  00760000
*        USER BY BCR 15,14                                              00800021
*                                                                       00820021
*ATTRIBUTES- REENTRANT,REUSABLE                                         00840021
*                                                                       00850021
*NOTES-                                                                 00860021
*                                                                       00880021
*                                                                       00900021
         EJECT                                                          00910021
**********************************************************************  00912021
*                                                                       00914021
*        EQUATES                                                        00916021
*                                                                       00918021
**********************************************************************  00918421
SAVR     EQU   13                      ADDRESS OF USER SAVE AREA        00920000
RETR     EQU   14                      RETURN ADDR. OF CALLING ROUTINE  00940000
ENTR     EQU   15                      ENTRY POINT - LOADED FROM DCB+52 00960000
SYNADR   EQU   0                       CONTAINS DECB ADDR. FOR SYNAD RT 00980000
PARR     EQU   1                       CONTAINS DECB ADDR. FOR CHECK    01000000
DCBR     EQU   2                       DCB ADDRESS                      01020000
IOBR     EQU   3                       IOB ADDRESS (IOS IOB - 8)        01040000
DECBR    EQU   4                       DECB ADDRESS                     01060000
BASR     EQU   5                       BASE FOR CHECK                   01080000
RWORK    EQU   6                       WORK REGISTER                    01100021
WRKR3    EQU   8                                                        01120000
         SPACE 3                                                        01122021
CCWDATAL EQU   6                       OFFSET TO DATA LNG IN CCW A67221 01130021
IOBRESID EQU   14                      OFFSET TO CSW RESIDUAL   SA67221 01140021
*                                      COUNT IN IOB             SA67221 01142021
READREQ  EQU   X'C0'                   SF OR SB READ REQUEST    SA67221 01150021
NOERROR  EQU   X'7F'                    INDICATES I/O COMPLETE WITH NO  01160000
UNITEXCP EQU   X'01'                    CSW UNIT EXCEPTION BIT.         01180000
CHECKEOD EQU   X'80'                    FLAG EODAD ENTRY FROM CHECK.    01200000
ZERO     EQU   X'00'                   DCBIFLGS INDICATOR FOR NO A37192 01226020
*                                       PERMANENT ERROR                 01232020
NULLADDR EQU   X'01'                   MEANS NO ROUTINE PRESENT SA63306 01234021
AB337    EQU   174                     INTERNAL ABEND CODE      SA63306 01236021
         EJECT                                                          01238021
**********************************************************************  01250021
*                                                                       01252021
*        SET UP                                                         01254021
*                                                                       01256021
**********************************************************************  01258021
         USING IGG019BI,BASR                                            01260000
         USING IHADCB,DCBR                                              01280000
         USING DECB,DECBR                                               01300000
START    EQU   *                                                        01340000
         STM   RETR,WRKR3,20(SAVR)      SAVE REGS 14-8                  01380000
         LR    BASR,ENTR                ESTABLISH BASE REG              01400000
         LR    DECBR,PARR               ESTABLISH BASE OF DECB.         01420000
*                                                                       01440000
         L     DCBR,DECBDCB             GET DCB ADDRESS FROM DECB.      01460000
         L     IOBR,DECBIOB             GET IOB ADDRESS FROM DECB.      01480000
         SPACE 3                                                        01500021
**********************************************************************  01510021
*                                                                       01512021
*        CHECK ECB - IF NOT COMPLETE, ISSUE WAIT AND THEN RETEST        01514021
*                                                                       01516021
**********************************************************************  01518021
STATUS   EQU   *                                                        01520000
         TM    DECBECB,NOERROR          TEST ECB STATUS.                01560000
         BO    CHKCALC                  BR-COMPL WITH NO ERROR  SA67221 01580021
         BM    ERROR                    BRANCH COMPLETE WITH EXCEPTIONS 01600000
*                                                                       01620021
         LR    PARR,DECBR               GET DECB FOR CHECK WAIT         01680000
         WAIT  ECB=(1)                  WAIT ON ECB                     01700000
         B     STATUS                   RE-TEST STATUS INDICATORS       01760000
         SPACE 3                                                        01800021
**********************************************************************  01820000
*                                                                       01840000
*        CHECK FOR EOV INDICATION...IF NOT, HANDLE ERROR CONDITION      01850021
*                                                                       01852021
**********************************************************************  01854021
ERROR    EQU   *                                                        01860000
         TM    12(IOBR),UNITEXCP        IS THE ERROR ACTUALLY EOV?      01900000
         BO    EOV                      IF SO, BRANCH.                  01920000
*                                                                       01940000
         LR    PARR,DCBR                SET UP DCB PARAMETER FOR SVC    01960000
         LR    SYNADR,IOBR              SET UP IOB PARAMETER FOR SVC    01980000
         LA    WRKR3,8                                                  02000000
         SR    SYNADR,WRKR3             POINT TO SAM IOB.               02020000
         STM   SYNADR,PARR,64(SAVR)     SAVE SVC PARAMETERS             02040000
*                                                                       02060000
         EOV   0(1)                                                     02080000
         SPACE 3                                                        02100021
**********************************************************************  02120000
*                                                                       02140000
*        GO TO USERS SYNAD ROUTINE...REGISTERS ARE ALREADY SET UP       02160021
*                                                                       02180000
**********************************************************************  02190021
         BALR  RETR,ENTR                TO SYNAD ROUTINE                02200000
         SPACE 3                                                        02220021
**********************************************************************  02240000
*                                                                       02260000
*        IF SYNAD ROUTINE RETURNS, GO TO SAM RESCHEDULING ROUTINE       02280021
*                                                                       02300000
**********************************************************************  02320000
         LM    SYNADR,PARR,64(SAVR)     RESTORE SVC PARAMETERS          02360000
*                                                                       02380000
         EOV   0(1)                                                     02400000
         SPACE 3                                                        02440021
**********************************************************************  02450021
*                                                                       02452021
*        CHECK IF MUST CALCULATE LENGTH OF RECORD READ FOR FORMAT U     02454021
*                                                                       02456021
**********************************************************************  02458021
CHKCALC  EQU   *                                                SA67221 02460021
         TM    DECBTYP1,READREQ         READ REQUEST            SA67221 02468021
         BZ    RETURN                   NO - SKIP LENGTH CALC   SA67221 02470021
         TM    DCBRECFM,DCBRECU         U TYPE RECORDS          SA67221 02472021
         BNO   RETURN                   NO - SKIP LENGTH CALC   SA67221 02474021
*                                                                       02476021
         TM    DCBCIND2,DCBCNCHS        CHAINED SCHEDULING      SA67221 02478021
         BZ    CALCSIZE                 NO - CALC EXACTLY       SA67221 02480021
         MVC   DCBLRECL,DCBBLKSI        DEFAULT TO BLKSIZE SINCE A67221 02482021
*                                       RESID CNT UNPREDICTABLE SA67221 02484021
         B     RETURN                   ALL DONE - GOODBYE      SA67221 02486021
         SPACE 3                                                        02486421
**********************************************************************  02486821
*                                                                       02487221
*        CALCULATE LENGTH OF RECORD READ FOR FORMAT U RECORDS           02487621
*                                                                       02487721
**********************************************************************  02487821
CALCSIZE EQU   *                                                SA67221 02488021
         SR    RWORK,RWORK              ZERO REG FOR IC         SA67221 02490021
         IC    RWORK,DCBOFFSR           GET OFFSET TO READ CCW  SA67221 02492021
         AR    RWORK,IOBR               ADD IOB (NOT PREFIX) ADDR 67221 02494021
         SH    RWORK,PRFSIZE            POINT AT IOB PREFIX     SA67221 02496021
         LH    RWORK,CCWDATAL(0,RWORK)  GET DATA LNG FR READ CCW A67221 02498021
         SH    RWORK,IOBRESID(0,IOBR)   SUB CSW RESID CNT TO GET A67221 02500021
*                                       DATA LNG ACTUALLY READ  SA67221 02500421
         STH   RWORK,DCBLRECL           PUT LNG IN DCBLRECL     SA67221 02502021
         B     RETURN                   ALL DONE - GOODBYE      SA67221 02504021
         SPACE 3                                                        02510021
**********************************************************************  02520021
*                                                                       02530021
*        SEE IF MUST INVOKE EODAD ROUTINE                               02540021
*                                                                       02550021
**********************************************************************  02560021
EOV      EQU   *                                                        02580021
         TM    DCBEODAD+3,NULLADDR     EODAD SPECIFIED ?        SA63306 02582021
         BO    ERROR1                  NO - ABEND 337           SA63306 02584021
         MVI   DCBIFLGS,ZERO           INDICATE NO PERMANENT     A37192 02586020
*                                       ERROR                    A37192 02592020
         MVI   32(SAVR),CHECKEOD        SET UP HIGH BYTE OF REG 1 TO    02600000
*                                         INDICATE THIS ENTRY TO EODAD  02620000
*                                         IS FROM CHECK.                02640000
         L     RETR,DCBEODAD            GET ADDR OF EODAD ROUTINE.      02660000
         LM    PARR,WRKR3,32(SAVR)      RESTORE USER REGISTERS.         02680000
         BR    RETR                     GO TO IT.                       02700000
ERROR1   EQU   *                                                SA63306 02710021
         LA    DCBR,0(DCBR)            CLEAR HI-ORDER BYTE      SA63306 02712021
         LNR   PARR,DCBR               LOAD EOV PARMETER        SA63306 02714021
         LA    SYNADR,AB337            LOAD INTERNAL ABEND CODE SA63306 02716021
         SVC   55                      ISSUE EOV                SA63306 02718021
         SPACE 3                                                        02719021
**********************************************************************  02719121
*                                                                       02719421
*        RETURN TO INVOKER                                              02720021
*                                                                       02720421
**********************************************************************  02720821
RETURN   EQU    *                                                       02722021
         LM    RETR,WRKR3,20(SAVR)     RESTORE REGS 14-8                02730021
         BR    RETR                     RETURN TO USER                  02732021
         EJECT                                                          02734021
**********************************************************************  02750021
*                                                                       02752021
*        CONSTANT AND WORK AREA                                         02754021
*                                                                       02756021
**********************************************************************  02758021
PRFSIZE  DC    H'8'                     IOB PREFIX SIZE         SA67221 02760021
         EJECT                                                          02780021
DECB     DSECT                     DATA EVENT CONTROL BLOCK             02800000
DECBECB  DS    0BL1                    ECB                              02820000
         DS    F                                                        02840000
DECBTYP0 DS    BL1                      FIRST BYTE OF TYPE FIELD.       02860000
DECBTYP1 DS    BL1                      SECOND BYTE OF TYPE FIELD.      02880000
DECBLNG  DS    BL2                      PHYSICAL RECORD LENGTH.         02900000
DECBDCB  DS    F                        DCB ADDRESS.                    02920000
DECBAREA DS    F                        LOCATION OF INPUT OR OUTPUT     02940000
*                                         AREA.                         02960000
DECBIOB  DS    F                        ADDRESS OF IOS IOB.             02980000
*                                                                       03000000
*                                                                       03020000
*                                                                       03040000
         SPACE                                                          03060000
         DCBD  DSORG=PS                                                 03080000
         END                                                            03100000
