         TITLE 'IGG019BN - QSAM UPDATE/LOCATE VARIABLE LENGTH RECORD EX*00100019
               TENTION'                                                 00200019
IGG019BN CSECT                                                          00300019
*                                                                       00400019
*                                                                M4563  00450019
*        RELEASE 20 DELETIONS                                           00500019
*1332047000-049000                                               A33650 00550020
*1332345500,576600-576700,617000,635000                          20201  00570020
*        RELEASE 21 DELETIONS                                           00600019
*D646000-647000                                                  XM6069 00650001
*                                                                       00700000
*        VS2 RELEASE 1.6 DELETIONS                                      00750000
*A                                                              XA00856 01400000
*STATUS CHANGE LEVEL 004                                                01500000
*                                                                       01600019
*FUNCTION/OPERATION- THIS ROUTINE WILL PROCESS VARIABLE SPANNED RECORDS 01700019
*        UPDATE GET ROUTINE LOCATES THE NEXT SEQUENTIAL LOGICAL RECORD  01800019
*        TO BE PROCESSED.                                               01900019
*        RELEASE ROUTINE CAUSES THE REMAINING CONTENTS OF THE CURRENT   02000019
*        BUFFER TO BE IGNORED.                                          02100019
*        PUTX ROUTINE SETS FLAG IN IOB FOR A SUBSEQUENT UPDATE WRITE.   02200019
*                                                                       02300019
*ENTRY POINTS- ENTRY1  GET         ENTRY2  PUTX        ENTRY3  RELEASE  02400019
*                LA  1,DCB           LA  1,DCB           LA  1,DCB      02500019
*                L   15,48(1)        L   15,48(1)        L   15,48(1)   02600019
*                BALR 14,15          BAL 14,4(15)        BAL 14,8(15)   02700019
*                                                                       02800019
*INPUT- FROM USERS PROBLEM PROGRAM                                      02900019
*       REGISTER 13 SAVE AREA ADDRESS                                   03000019
*                14 PROBLEM PROGRAM RETURN ADDRESS                      03100019
*                15 GET ROUTINE INITIAL BASE ADDRESS                    03200019
*                1  DCB ADDRESS                                         03300019
*                                                                       03400019
*OUTPUT- REGISTER  1  LOCATED RECORD ADDRESS                            03500019
*                                                                       03600019
*EXTERNAL ROUTINES- IGG019BQ UPDATE SYNCHRONIZING AND ERROR PROCESSING  03700019
*                            ROUTINE FOR VARIABLE SPANNED RECORDS       03800019
*                   IGG019CC STANDARD D/A EOB ROUTINE                   03900019
*                                                                       04000019
*EXITS- NORMAL                                                          04100019
*              EXIT1               EXIT2               EXIT3            04200019
*                NORMAL              EOB ROUTINE         ERROR ROUTINE  04300019
*                  BCR  15,14          BALR  14,15         BALR  14,15  04400019
*                                                                       04500019
*       ABNORMAL                                                        04600019
*                EXIT                   EXIT4                           04700020
*                  FEOV ROUTINE           ABEND 002                     04800020
*                    SVC 31                                             04900020
*                                                                       05000019
*TABLES/WORKAREAS- REGISTER SAVEAREA                                    05100019
*                  IOB                                                  05200019
*                  DCB  USING IOBA, LRECL, RECFM, IOBL, WCPO, WCPL,     05300019
*                             EOBAD, RECAD, GERR, EOB                   05400019
*                  RECORD AREA - SEE DSECT AT THE END OF LISTING        05500019
*                                                                       05600019
*ATTRIBUTES- REENTRANT, PROBLEM PROGRAM MODE                            05700019
*                                                                       05800019
*********************************************************************** 05900019
*                                                                       06000019
RPARA0   EQU   0                        0 PARAMETER REG                 06100019
RPARA1   EQU   1                        1 PARAMETER REG                 06200019
DCBR     EQU   2                        DCB REG                         06300019
IOBAR    EQU   3                        IOB REG                         06400019
EOBADR   EQU   4                        END OF BUFFER REG               06500019
RECADR   EQU   5                        RECORD ADDRESS REG              06600019
LRECLR   EQU   6                        LOGICAL LENGTH REG              06700019
WORKR    EQU   7                        WORK REG                        06800019
BASR     EQU   8                        BASE REG                        06900019
SAVR     EQU   13                       SAVE REG                        07000019
AWORKR   EQU   14                       WORK REG                        07100019
RETR     EQU   14                       RETURN REG                      07200019
BWORKR   EQU   15                       WORK REG                        07300019
ENTRYR   EQU   15                       ENTRY REG                       07400019
*                                                                       07500019
CLOSEB   EQU   X'20'                    CLOSE IN PROCESS                07600019
WRTCK    EQU   X'80'                    WRITE CHECK                     07700019
UPDATFLG EQU   X'50'                    UPDATE FLAG                     07800019
READONLY EQU   X'20'                    IOB READ ONLY INDICATOR         07900019
FIRSTIOB EQU   X'01'                    FIRST IOB INDICATOR             08000019
NOT      EQU   X'FF'                    MASK                            08100019
SRCHOP   EQU   X'31'                    SEARCH OP CODE                  08200019
RDC      EQU   X'92'                    READ COUNT OP CODE              08300019
TIC      EQU   X'08'                    TIC OP CODE                     08400019
CC       EQU   X'40'                    COMMAND CHAIN BIT               08450019
WCKCT    EQU   54                       OFFSET OF COUNT FIELD OF WRITE  08500019
*                                       CHECK CCW FROM START OF THE     08600019
*                                       WRITE SEQUENCE CHANNEL PROGRAM  08700019
WRTCT    EQU   22                       OFFSET OF COUNT FIELD OF WRITE  08800019
*                                       CCW FROM START OF THE WRITE     08900019
*                                       SEQUENCE CHANNEL PROGRAM        09000019
SPANFLG  EQU   X'04'                    SPANNED RECORD FLAG IN IOB      09100019
RELFLAG  EQU   X'F0'                    RELEASE BIT                     09200019
FLGOFST  EQU   2                        CONTROL CODE OFFSET             09300019
FIRSTSEG EQU   X'01'                    FIRST SEGMENT OF RECORD         09400019
LASTSEG  EQU   X'02'                    LAST SEGMENT OF SPANNED RECORD  09500019
MIDSEG   EQU   X'03'                    MIDDLE SEGMENT OF RECORD        09600019
NULLSEG  EQU   X'80'                    NULL SEGMENT                    09700019
ASSEMBLE EQU   X'01'                    ASSEMBLING IN PROCESS           09800019
SEGMENT  EQU   X'10'                    SEGMENTATION IN PROCESS         09900019
FREEBIT  EQU   X'40'                    FREE DEB INDICATOR              10000019
SPRELSE  EQU   X'40'                    RELEASE AFTER SPANNED RECORD IS 10010019
*                                            GOTTEN                     10020019
EOD      EQU   X'80'                    EOV OR EOF FLAG                 10050019
EOFATEOV EQU   X'20'                    EOF OCCURRED AFTER 1ST EOV      10060019
HASH     EQU   X'07'                    HASHING FACTOR                  10100019
SAOFF    EQU   20                       SAVE AREA OFFSET                10200019
REG1     EQU   32                       REGESTER 1 OFFSET FROM SAVEAREA 10300019
REG3     EQU   40                       REGISTER 3 OFFSET FROM SAVEAREA 10350019
STARTCP  EQU   24                       START OF CHANNEL PROGRAM OFFSET 10400019
SPFDAD   EQU   11                       OFFSET TO SPECIAL FDAD IN CP    10500019
IOSFDAD  EQU   43                       IOS FDAD OFFSET          XM6069 10600001
MBB      EQU   3                        NUMBER OF BYTES FOR MBB         10700019
CCHHR    EQU   5                        NUMBER OF BYTES FOR CCHHR       10800019
BBCCHHR  EQU   7                        NUMBER OF BYTES FOR BBCCHHR     10900019
CNTLEN   EQU   2                        LENGTH OF COUNT FIELD           11000019
WRTLEN   EQU   6                        WRITE CCW COUNT FIELD           11100019
DEBSTRCC EQU   38                       OFFSET TO DEB PLUS START CCHH   11150019
DEBENDCC EQU   42                       OFFSET TO DEB PLUS ENDING CCHH  11180019
CNTRLLEN EQU   20                       CONTROL INFORMATION LENGTH      11210019
CNT8     EQU   8                        LNG OF RD CNT FOR UPDT   XM6069 11260001
NULL     EQU   0                        ZERO DISPLACEMENT               11300019
BYTE     EQU   1                        ONE BYTE DISPLACEMENT           11400019
WORD     EQU   4                        WORD DISPLACEMENT               11500019
DBLWD    EQU   8                        DOUBLE WORD DISPLACEMENT        11600019
ADLEN    EQU   3                        LENGTH OF ADDRESS               11700019
FIVE     EQU   5                        DISPLACEMENT TO DEB LINK FIELD  11800019
MTP3     EQU   3                        MULTIPLY FACTOR                 11900019
FFF      EQU   256                      256                             12000019
RPS16    EQU   16                       SIXTEEN BYTE             20201  12002020
*                                       DISPLACEMENT             20201  12004020
RDSECT   EQU   X'22'                    READ SECTOR COMMAND TO   20201  12006020
*                                        TO TEST FOR RPS                12008020
SETSECT  EQU   X'23'                    SET SECTOR COMMAND TO    20201  12010020
*                                         TO TEST FOR RPS               12012020
*                                                                       12020019
COBOL    EQU   X'40'                    COBOL BIT IN R. A.              12040019
NONSPAN  EQU   X'04'                    NON SPANNED RECORD IN R. A.     12060019
COMPERR  EQU   X'7F'                    I/O COMPLETE WITHOUT ERROR      12080019
WRTCKCP  EQU   32                       WRITE CHECK C. P. LENGTH        12090019
IOBSEEK  EQU   X'28'                    IOBSEEK FROM IOB PREFIX         12095019
*                                                                       12100019
*********************************************************************** 12200019
*                                                                       12300019
         USING IGG019BN,ENTRYR          SET BASE REGISTER               12400019
         USING IHADCB,RPARA1            ESTABLISH ADRESSIBILITY         12500019
*                                                                       12600019
ENTRY1   EQU   *                                                        12700019
*                                                                       12800019
         B     START                    BRANCH TO GET                   12900019
*                                                                       13000019
ENTRY2   EQU   *                                                        13100019
*                                                                       13200019
         B     PUTX                     BRANCH TO PUTX                  13300019
*                                                                       13400019
ENTRY3   EQU   *                                                        13500019
*                                                                       13600019
*********************************************************************** 13700019
*                                                                       13800019
*    SIMULATE END OF BLOCK CONDITION.  MAKE REC ADDR EQUAL EOB ADDR     13900019
*                                                                       14000019
*********************************************************************** 14100019
*                                                                       14200019
         ST    IOBAR,REG3(SAVR)         SAVE REG. 3                     14204019
         L     IOBAR,DCBIOBA            GET IOB ADDR                    14208019
         TM    NULL(IOBAR),SPANFLG+UPDATFLG SPANNED RECORD BEING        14212019
*                                            UPDATED                    14216019
         L     IOBAR,REG3(SAVR)         RESTORE REG 3                   14218019
         BNO   RELSE2                   BRANCH IF NOT TO NORMAL RELSE   14220019
*                                                                       14224019
         STM   RETR,BASR,SAOFF(SAVR)    SAVE REGISTERS                  14228019
         LR    BASR,ENTRYR              LOAD BASE REG                   14232019
         LR    DCBR,RPARA1              DCB ADDRESSIBILITY              14236019
         LM    IOBAR,RECADR,DCBIOBA     LOAD WORK REGS                  14240019
         OI    DCBRECAD,RELFLAG         SET RELEASE BIT IN DCB          14244019
         B     RESTORE                  BRANCH TO UPDATE LAST RECORD    14248019
*                                                                       14252019
RELSE1   EQU   *                                                        14256019
*                                                                       14260019
         LR    ENTRYR,BASR              RESTORE BASE REG                14264019
         LR    RPARA1,DCBR              RESTORE BASE FOR DCB            14268019
         LM    RETR,BASR,SAOFF(SAVR)    RESTORE USER REGS               14272019
*                                                                       14276019
RELSE2   EQU   *                                                        14280019
*                                                                       14284019
         MVC   DCBRECAD+BYTE(ADLEN),DCBEOBAD+BYTE INITIALIZE FOR RELSE  14300019
         OI    DCBRECAD,RELFLAG         SET RELEASE BIT IN DCB          14400019
         BR    RETR                     RETURN TO USER                  14500019
*                                                                       14600019
*********************************************************************** 14700019
*                                                                       14800019
START    EQU   *                                                        14900019
*                                                                       15000019
         STM   RETR,BASR,SAOFF(SAVR)    SAVE REGISTERS                  15100019
*                                                                       15200019
         DROP  ENTRYR                   DROP BASE                       15300019
         DROP  RPARA1                   DROP BASE                       15400019
*                                                                       15500019
         USING IGG019BN,BASR            SET BASE REGISTER               15600019
         USING IHADCB,DCBR              ESTABLISH BASE FOR DCB          15700019
         USING RCDAREA,WORKR            ESTABLISH BASE FOR RECORD AREA  15800019
*                                                                       15900019
         LR    DCBR,RPARA1              MAKE DCB ADDRESSABLE            16000019
         LR    BASR,ENTRYR              LOAD BASE REG                   16100019
         LM    IOBAR,RECADR,DCBIOBA     LOAD WORK REGS                  16200019
*                                                                       16300019
         CLI   DCBIOBAD+ADLEN,BYTE      DOES IOBAD FIELD HAS AN ADDR    16400019
         BE    UPDATE0I                 BRANCH IF NOT TO NORMAL PROCESS 16500019
*                                                                       16600019
         TM    NULL(IOBAR),SPANFLG+UPDATFLG IS SPAN RECORD BEING        16610019
*                                            UPDATED                    16620019
         BO    RESTORE                  BRANCH YES TO RESTORE BEGIN     16630019
*                                            SEGMENT TRACK ADDR         16640019
         OI    DCBIOBAD,FREEBIT         SET BIT TO INDICATE THAT DEB    16650019
*                                            CAN BE FREED               16660019
         FEOV  (DCBR)                   ISSUE FEOV TO RESET DATA        17160019
*                                            MANAGEMENT COUNT           17660019
*                                                                       18400019
UPDATE0I EQU   *                                                        18500019
*                                                                       18600019
         TM    NULL(IOBAR),SPANFLG+UPDATFLG IS SPAN RECORD BEING        18700019
*                                            UPDATED                    18800019
         BO    RESTORE                  BRANCH YES TO RESTORE BEGIN     18900019
*                                            SEGMENT TRACK ADDR         19000019
         TM    NULL(IOBAR),SPANFLG      SPANNED RECORD FLAG ON          19100019
         BZ    UPDATE0C                 BRANCH IF NOT TO GET LRECL      19200019
*                                                                       19300019
         NI    NULL(IOBAR),NOT-SPANFLG  TURN OFF SPANNED FLAG           19400019
*                                                                       19500019
         L     WORKR,DCBBUFCB           GET BUFCB ADDR                  19600019
         LA    WORKR,NULL(WORKR)        CLEAR HI ORDER BYTE             19700019
         L     WORKR,DBLWD(WORKR)       OFFSET TO RECORD AREA ADDR      19800019
*                                                                       19900019
         XC    RAFLG(CNTRLLEN),RAFLG    CLEAR CONTROL INFO IN RA        20000019
*                                                                       20200019
         SR    LRECLR,LRECLR            CLEAR REG                       20240019
         IC    LRECLR,NULL(RECADR)      GET 1ST BYTE OF LL              20280019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   20320019
         IC    LRECLR,BYTE(RECADR)      LRECLR = 00LL                   20360019
         B     UPDATE0A                 BRANCH TO TEST EOB              20400019
*                                                                       21100019
UPDATE0H EQU   *                                                        21200019
*                                                                       21300019
         LR    RECADR,EOBADR            FORCE EOB CONDITION             21400019
         B     UPDATE0B                 BRANCH TO GET NEXT BLOCK        21500019
*                                                                       21600019
UPDATE0C EQU   *                                                        21700019
*                                                                       21800019
         LH    LRECLR,DCBLRECL          GET RECORD LENGTH               21900019
*                                                                       22000019
UPDATE0A EQU   *                                                        22100019
*                                                                       22200019
         LA    RECADR,NULL(RECADR)      CLEAR HIGH ORDER BYTE           22250019
         AR    RECADR,LRECLR            UPDATE RECORD ADDRESS           22300019
*                                                                       22400019
UPDATE0B EQU   *                                                        22500019
*                                                                       22600019
         CR    EOBADR,RECADR            EOB CONDITION                   22700019
         BH    UPDATE0D                 NO, BRANCH                      22800019
*                                                                       22820019
         L     WORKR,DCBBUFCB           GET BUFCB ADDR                  22840019
         LA    WORKR,NULL(WORKR)        CLEAR HI ORDER BYTE             22860019
         L     WORKR,DBLWD(WORKR)       OFFSET TO RECORD AREA ADDR      22880019
*                                                                       22900019
         TM    RALNG,EOD                HAS EOF OCCURRED                22910019
         BZ    UPDATE0J                 BRANCH IF NOT                   22920019
         TM    DCBCIND2,CLOSEB          ARE WE FROM CLOSE               22924019
         BO    UPDATE0J                 BRANCH YES TO EXCP              22925019
*                                                                       22926019
         TM    NULL(IOBAR),UPDATFLG     UPDATE REQUIRED                 22930019
         BZ    EXIT3                    BRANCH NO TO SKIP EXCP          22940019
*                                                                       22950019
UPDATE0J EQU   *                                                        22960019
*                                                                       22970019
         BAL   RETR,CHANPROG            BRANCH TO SET UP C.P.           23000019
*                                                                       23100019
*********************************************************************** 23200019
*                                                                       23300019
*    TO UPDATE EOB ROUTINE TO SCHEDULE BUFFER                           23400019
*                                                                       23500019
*********************************************************************** 23600019
*                                                                       23700019
EXIT2    EQU   *                                                        23800019
*                                                                       23900019
         L     ENTRYR,DCBEOB            END OF BLOCK ROUTINE ADDRESS    24000019
         BALR  RETR,ENTRYR              TO EOB ROUTINE                  24100019
*                                                                       24200019
*********************************************************************** 24300019
*                                                                       24400019
*    DCBIOBA INITIALIZED TO NEW IOB ADDRESS IN ERROR ROUTINE            24500019
*                                                                       24600019
*********************************************************************** 24700019
*                                                                       24800019
EXIT3    EQU   *                                                        24900019
*                                                                       25000019
         L     ENTRYR,DCBGERR           ERROR ROUTINE ADDRESS           25100019
         BALR  RETR,ENTRYR              TO ERROR ROUTINE                25200019
*                                                                       25300019
*********************************************************************** 25400019
*                                                                       25500019
*    PREPARE TO INITIALIZE NEW IOB                                      25600019
*                                                                       25700019
*********************************************************************** 25800019
*                                                                       25900019
         NI    NULL(IOBAR),FIRSTIOB     INITIALIZE NEW IOB              26000019
         OI    NULL(IOBAR),READONLY     RESET IOB TO READ ONLY          26100019
*                                                                       26200019
         SR    WORKR,WORKR              CLEAR REG                       26300019
         IC    WORKR,DCBOFFSR           GET CCW TO FIND BUFFER ADDR.    26400019
         L     RECADR,NULL(WORKR,IOBAR) OBTAIN BUFFER ADDR              26500019
         LA    RECADR,NULL(RECADR)      CLEAR HIGH ORDER BYTE           26600019
*                                                                       26700019
         LH    EOBADR,NULL(RECADR)      PHYSICAL RECORD LENGTH          26800019
         IC    WORKR,DCBOFFSW           POINT TO WRITE CCW.             26900019
         STH   EOBADR,WRTLEN(WORKR,IOBAR) SAVE LENGTH OF RECORD IN WCCW 27000019
         AR    EOBADR,RECADR            NEW EOB ADDR                    27100019
         LA    RECADR,WORD(RECADR)      GET FIRST LOGICAL RECORD ADDR   27200019
         LH    LRECLR,NULL(RECADR)      GET LENGTH FROM RECORD          27300019
*                                                                       27400019
UPDATE0D EQU   *                                                        27500019
*                                                                       27600019
         CLC   0(2,RECADR),RDWLT4      RDW LT 4?                 A33650 27630020
         BL    EXIT4                   YES,  ABEND '002'         A33650 27660020
         CLI   DCBRECAD,RELFLAG         IS RELEASE BIT SET              27700019
         BNE   UPDATE0E                 NO, BRANCH FOR NORMAL GET PROC. 27800019
*                                                                       27900019
         TM    FLGOFST(RECADR),LASTSEG  TEST BIT 6 OF BYTE 2 RECORD     28000019
         BZ    UPDATE0F                      CONTROL WORD, IF NOT ON,   28100019
*                                            RELEASE DONE, EXIT         28200019
         SR    LRECLR,LRECLR            CLEAR REG                       28240019
         IC    LRECLR,NULL(RECADR)      GET 1ST BYTE OF LL              28280019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   28320019
         IC    LRECLR,BYTE(RECADR)      LRECLR = 00LL                   28360019
         ST    RECADR,DCBRECAD          STORE NEW RECORD ADDRESS        28400019
         OI    DCBRECAD,RELFLAG         SET RELEASE BITS                28500019
         B     UPDATE0A                 GO TO POSITION TO NEXT RECORD   28600019
*                                                                       28700019
UPDATE0E EQU   *                                                        28800019
*                                                                       28900019
         TM    NULL(RECADR),NULLSEG     NULL SEGMENT                    29000019
         BO    UPDATE0H                 BRANCH YES TO FORCE EOB         29100019
*                                                                       29200019
         SR    LRECLR,LRECLR            CLEAR REG                       29210019
         IC    LRECLR,NULL(RECADR)      GET 1ST BYTE OF LL              29220019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   29230019
         IC    LRECLR,BYTE(RECADR)      LRECLR = 00LL                   29240019
*                                                                       29250019
         TM    FLGOFST(RECADR),LASTSEG  IS THIS FOLLOWING ANY SEGMENT   29300019
         BO    UPDATE2                  YES,BRANCH TO SPANNED RECORD    29400019
*                                            PROCESSING                 29500019
UPDATE0F EQU   *                                                        29600019
*                                                                       29700019
         SR    LRECLR,LRECLR            CLEAR REG                       29710019
         IC    LRECLR,NULL(RECADR)      GET 1ST BYTE OF LL              29720019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   29730019
         IC    LRECLR,BYTE(RECADR)      LRECLR = 00LL                   29740019
*                                                                       29750019
         TM    FLGOFST(RECADR),FIRSTSEG IS THIS FIRST SEGMENT           29800019
         BO    UPDATE1                  YES BRANCH TO SAVE INFO         29900019
*                                                                       30000019
         L     WORKR,DCBBUFCB           GET BUFCB ADDR                  30020019
         LA    WORKR,NULL(WORKR)        CLEAR HIGH ORDER BYTE           30040019
         L     WORKR,DBLWD(WORKR)       OFFSET TO RECORD AREA ADDR      30060019
         TM    RALNG,COBOL              COBOL BIT ON                    30080019
         BO    UPDATE1                  BRANCH YES TO MOVE RECORD       30100019
*                                                                       30120019
         ST    RECADR,REG1(SAVR)        PARAMETER FOR USER              30200019
*                                                                       30300019
RETURN   EQU   *                                                        30400019
*                                                                       30500019
         STH   LRECLR,DCBLRECL          UPDATE DCB LRECL                30600019
         STM   IOBAR,RECADR,DCBIOBA     INITIALIZE DCB                  30700019
*                                                                       30800019
EXIT1    EQU   *                                                        30900019
*                                                                       31000019
         LM    RETR,BASR,SAOFF(SAVR)    RESTORE USER REGS               31100019
         BR    RETR                     RETURN TO USER                  31200019
EXIT4    EQU   *                                                 A33650 31210020
         LA    1,002                                             A33650 31220020
         SLL   1,12                                              A33650 31230020
         ABEND (1),DUMP                                          A33650 31240020
RDWLT4   DC    X'0004'                                           A33650 31250020
*                                                                       31300019
*********************************************************************** 31400019
*                                                                       31500019
RESTORE  EQU   *                                                        31600019
*                                                                       31700019
* A SPANNED RECORD IS TO BE UPDATED. MUST RESTORE TRACK ADDRESS TO READ 31800019
* BACK THE BLOCK THAT CONTAINS THE BEGINNING SEGMENT OF THE RECORD.     31900019
* ONLY CURRENT IOB WILL BE USED. CHANNEL PROGRAM WILL BE CHANGED TO     32000019
* FUNCTION AS IF ONLY ONE IOB EXISTS.                                   32100019
*                                                                       32110019
         L     WORKR,DCBBUFCB           GET BUFCB ADDR                  32110919
         LA    WORKR,NULL(WORKR)        CLEAR HIGH ORDER BYTE           32111819
         L     WORKR,DBLWD(WORKR)       OFFSET TO RECORD AREA ADDR      32111919
         NI    RAFLG,NOT-ASSEMBLE       CLEAR FLAG BYTE                 32112019
         TM    DCBRECAD,RELFLAG         RELSE ISSUED AFTER SPANNED      32112219
*                                            RECORD IS GOTTEN           32112419
         BNO   UPDATE0G                 BRANCH NO TO NORMAL UPDATE      32112619
         OI    RAFLG,SPRELSE            SET FLAG IN R.A. FOR RELSE      32112819
         NI    DCBRECAD,NOT-RELFLAG     TURN OFF RELEASE FLAG IN DCB SO 32113019
*                                            NOT TO CONFUSE WITH READ   32113219
*                                            ERROR SKIP OPTION          32113419
UPDATE0G EQU   *                                                        32113619
*                                                                       32113819
         TM    RALNG,COBOL              TEST IF COBOL BIT IS ON         32114119
         BZ    UPDATE                   BRANCH NO TO NORMAL UPDATE      32114519
         TM    RAFLG,NONSPAN            NON SPANNED RECORD IN R. A.     32115419
         BO    UPDATE11                 BRANCH YES TO MOVE RECORD BACK  32116319
*                                            TO BUFFER                  32117219
UPDATE   EQU   *                                                        32118119
         NI    NULL(IOBAR),NOT-UPDATFLG TURN OFF UPDATE FLAG            32118519
*                                                                       32119019
         OI    RAFLG,SEGMENT            SET FLAG TO INDICATE SEGMENTING 32119319
*                                            IN PROCESS                 32119619
* MUST WAIT FOR PREVIOUS I/O OPERATION TO COMPLETE BEFORE MODIFYING THE 32120019
* CURRENT IOB.                                                          32130019
*                                                                       32140019
         LR    WORKR,IOBAR              COPY CURRENT IOB                32165019
*                                                                       32170019
GETNEXT  EQU   *                                                        32180019
*                                                                       32190019
         L     AWORKR,NULL(WORKR)       GET NEXT IOB IN SEQUENCE        32194019
         LA    AWORKR,NULL(AWORKR)      CLEAR HIGH ORDER BYTE           32198019
TESTCOMP EQU   *                                                        32202019
         TM    WORD(AWORKR),COMPERR     I/O COMPLETE WITHOUT ERROR      32206019
         BO    NEXTONE                  BRANCH TO CHECK NEXT IOB        32210019
         BM    ERROR                    BRANCH NO TO GO TO SYNCH        32216019
         WAIT  ECB=WORD(AWORKR)         WAIT FOR I/O TO COMPLETE        32218019
         B     TESTCOMP                 BRANCH TO TEST COMPLETION       32220019
NEXTONE  EQU   *                                                        32222019
         CR    AWORKR,IOBAR             IS THIS SAME AS CURRENT IOB     32224019
         BE    RESTORE1                 SET UP CHANNEL PROGRAM          32230019
         LR    WORKR,AWORKR             SAVE CURRENT IOB                32250019
         B     GETNEXT                  BRANCH TO GET NEXT IOB          32270019
*                                                                       32280019
ERROR    EQU   *                                                        32290019
*                                                                       32300019
         LR    IOBAR,WORKR              SET UP IOBAR TO POINT TO PROPER 32310019
*                                           IOB FOR SYNCH ROUTINE       32320019
*                                                                       33407019
         L     ENTRYR,DCBGERR           ERROR ROUTINE ADDRESS           33414019
         BALR  RETR,ENTRYR              TO ERROR ROUTINE                33421019
*                                                                       33428019
RESTORE1 EQU   *                                                        33438019
*                                                                       33456019
         CLI   DCBIOBAD+ADLEN,BYTE      DOES IOBAD FIELD HAS AN ADDR    33456519
         BE    UPDATE00                 BRANCH IF NOT TO ISSUE I/O, EOV 33457019
*                                            DID NOT OCCUR              33457519
         L     WORKR,DCBBUFCB           GET BUFCB ADDR                  33457619
         LA    WORKR,NULL(WORKR)        CLEAR HIGH ORDER BYTE           33457719
         L     WORKR,DBLWD(WORKR)       OFFSET TO RECORD AREA ADDR      33457819
*                                                                       33457919
         TM    RALNG,EOD                HAS EOF OCCURED                 33458219
         BZ    EXIT                     BRANCH NO TO ISSUE FEOV         33458319
         OI    RALNG,EOFATEOV           TURN ON INDICATOR FOR EOF AFTER 33458419
*                                            FIRST EOV                  33458619
EXIT     EQU   *                                                        33458919
*                                                                       33459119
         FEOV  (DCBR)                   ISSUE FEOV TO RESET DATA        33459319
*                                            MANAGEMENT COUNT           33459519
*********************************************************************** 33460019
*                                                                       33460519
UPDATE00 EQU   *                                                        33461019
*                                                                       33461519
         L     WORKR,DCBBUFCB           GET BUFCB ADDR                  33463019
         LA    WORKR,NULL(WORKR)        CLEAR HI ORDER BYTE             33470019
         L     WORKR,DBLWD(WORKR)       OFFSET TO RECORD AREA ADDR      33477019
*                                                                       33484019
         SR    BWORKR,BWORKR            CLEAR REG                       33500019
         IC    BWORKR,DCBOFFSR          GET OFFSET TO RD DATA CCW       33600019
         AR    BWORKR,IOBAR             POINT TO RD DATA CCW            33700019
         LA    AWORKR,DBLWD             PREPARE TO INCREMENT ADDR       33800019
         CLI   DBLWD(BWORKR),RDSECT     IS THIS RPS CHAN PGM     20201  33820020
         BNE   NOTRPS                   IF NOT DONT INCREMENT    20201  33840020
         AR    AWORKR,AWORKR            IF SO, INCREMENT         20201  33860020
NOTRPS   EQU   *                                                 20201  33880020
         MVC   DCBFDAD,RATRKAD          MOVE TRACK ADDR FROM RECORD     33900019
*                                            AREA TO DCBFDAD            34000019
         AR    AWORKR,BWORKR            POINT TO SPECIAL FDAD           34030019
         MVC   RANXTIOB,NULL(IOBAR)     SAVE NEXT IOB IN RA             34060019
         MVC   RATRKAD,NULL(AWORKR)     SAVE SPECIAL FDAD IN RA         34090019
         MVC   NULL(DBLWD,AWORKR),DCBFDAD PLACE FDAD IN SPECIAL FDAD    34120019
*                                                                       34121019
RESTORE2 EQU   *                                                        34122019
*                                                                       34123019
         L     RPARA1,DCBDEBAD          GET DEB ADDR                    34124019
         LA    RPARA1,NULL(RPARA1)      CLEAR HIGH ORDER BYTE           34125019
*                                                                       34126019
         SR    RPARA0,RPARA0            CLEAR REG                       34127019
         IC    RPARA0,NULL(AWORKR)      GET M FROM SPECIAL FDAD FIELD   34128019
         SLL   RPARA0,WORD              POINT TO BEGINNING OF DEB PLUS  34129019
         AR    RPARA1,RPARA0                 SPACE USED BY THE EXTENT   34130019
*                                            ENTRY                      34131019
         CLC   MBB(WORD,AWORKR),DEBSTRCC(RPARA1) IS CCHH LOWER THAN     34132019
*                                            START CCHH IN DEB          34133019
         BL    RESTORE4                 BRANCH IF LOW                   34133219
         CLC   MBB(WORD,AWORKR),DEBENDCC(RPARA1) IS CCHH HIGHER THAN    34133419
*                                            ENDING CCHH IN DEB         34133619
         BNH   RESTORE3                 BRANCH IF NOT HIGH              34133819
*                                                                       34134019
RESTORE4 EQU   *                                                        34134219
*                                                                       34135019
         SRL   RPARA0,WORD              DECREMENT M OF SPECIAL FDAD     34136019
         BCTR  RPARA0,NULL                   BY ONE                     34137019
         STC   RPARA0,NULL(AWORKR)      STORE IN SPECIAL FDAD FIELD     34138019
         B     RESTORE2                 BRANCH TO TEST PREVIOUS EXTENT  34139019
*                                                                       34140019
RESTORE3 EQU   *                                                        34141019
*                                                                       34142019
         MVC   IOBSEEK(DBLWD,IOBAR),NULL(AWORKR) INITIALIZE IOBSEEK     34144019
*                                       FROM SPECIAL FDAD               34146019
         LA    AWORKR,DBLWD             PREPARE TO DECREMENT            34150019
         SR    BWORKR,AWORKR            POINT TO RD CT CCW              34200019
         CLI   RPS16(BWORKR),RDSECT     IS RPS FEATURED          20201  34300020
         BE    RPS0                     IF YES, LEAVE CP AS IS   20201  34400020
         LA    RPARA0,DCBFDAD+MBB       GET ADDR OF CCHHR FIELD IN DCB  34600019
         ST    RPARA0,NULL(BWORKR)      STORE IN RD CT CCW              34700019
         MVI   NULL(BWORKR),RDC         STORE RD CT COMMAND CODE        34800019
RPS0     EQU   *                                                 20201  34850020
         SR    BWORKR,AWORKR            POINT TO TIC CCW                34900019
         L     RPARA1,NULL(BWORKR)      GET CCW TRANSFER CONTROL TO     35000019
         LA    RPARA1,DBLWD(RPARA1)     ADD 8 TO GET TO RD DATA CCW     35100019
         ST    RPARA1,NULL(BWORKR)      STORE RD DATA CCW ADDR IN TIC   35200019
         MVI   NULL(BWORKR),TIC         STORE TIC OP CODE               35300019
         MVI   8(BWORKR),NOT            FLAG FOR C.E. APPENDAGE  XM6069 35360001
*                                       READ COUNT NOT ACTIVE    XM6069 35370001
         L     WORKR,8(BWORKR)          POINT TO SPECIAL FDAD   XA00856 35380000
         MVC   0(5,WORKR),IOBSEEK+3(IOBAR)  SAVE CCHHR          XA00856 35390000
*                                                                       35400019
* SET UP FOR READ ONLY                                                  40400019
*                                                                       40500019
         SR    WORKR,WORKR              CLEAR REG                       40600019
         SR    AWORKR,AWORKR            CLEAR REG                       40700019
         IC    WORKR,DCBWCPO            GET WRITE CHANNEL PROG. OFFSET  40800019
         IC    AWORKR,DCBWCPL             AND ADD TO                    40900019
         SLL   AWORKR,MTP3                  DBL WORDS TO BYTES          41000019
         AR    WORKR,AWORKR               WRITE CHANNEL PROG. LENGTH    41100019
         ALR   WORKR,IOBAR              POINT TO IOB                    41200019
         LA    WORKR,DBLWD(WORKR)         READ SEQUENCE ADDRESS         41300019
*                                                                       41400019
         ST    WORKR,STARTCP(IOBAR)     PLACE IN CP POINTER             41500019
         MVC   BYTE(ADLEN,IOBAR),DCBIOBA+BYTE SET NEXT IOB ADDR TO      41560019
*                                            ITSELF                     41620019
         OI    NULL(IOBAR),READONLY     TURN ON ONLY READ FLAG          41700019
*                                                                       41800019
*********************************************************************** 41900019
*                                                                       42000019
*    TO UPDATE EOB ROUTINE TO SCHEDULE BUFFER                           42100019
*                                                                       42200019
*********************************************************************** 42300019
*                                                                       42400019
         L     ENTRYR,DCBEOB            END OF BLOCK ROUTINE ADDRESS    42500019
         BALR  RETR,ENTRYR              TO EOB ROUTINE                  42600019
*                                                                       42700019
*********************************************************************** 42800019
*                                                                       42900019
*    DCBIOBA INITIALIZED TO NEW IOB ADDRESS IN ERROR ROUTINE            43000019
*                                                                       43100019
*********************************************************************** 43200019
*                                                                       43300019
         L     ENTRYR,DCBGERR           ERROR ROUTINE ADDRESS           43400019
         BALR  RETR,ENTRYR              TO ERROR ROUTINE                43500019
*                                                                       43600019
         NI    NULL(IOBAR),FIRSTIOB     INITIALIZE NEW IOB              43700019
         OI    NULL(IOBAR),READONLY     RESET IOB TO READ ONLY          43800019
*                                                                       43900019
         SR    WORKR,WORKR              CLEAR REG                       44000019
         IC    WORKR,DCBOFFSR           GET CCW TO FIND BUFFER ADDR     44100019
         L     RECADR,NULL(WORKR,IOBAR) OBTAIN BUFFER ADDR              44200019
         LA    RECADR,NULL(RECADR)      CLEAR HI ORDER BYTE             44300019
*                                                                       44400019
         LH    EOBADR,NULL(RECADR)      PHYSICAL RECORD LENGTH          44500019
         IC    WORKR,DCBOFFSW           POINT TO WRITE CCW              44600019
         STH   EOBADR,WRTLEN(WORKR,IOBAR) SAVE LENGTH OF RECORD IN WCCW 44700019
         AR    EOBADR,RECADR            NEW EOB ADDR                    44800019
*                                                                       44900019
         IC    WORKR,DCBOFFSR           GET OFFSET TO RD DATA CCW       45000019
         AR    WORKR,IOBAR              POINT TO RD DATA CCW            45100019
         LA    AWORKR,DBLWD             PREPARE TO DECREMENT ADDR       45200019
         SR    WORKR,AWORKR             POINT TO RD CT CCW              45300019
         LR    BWORKR,WORKR             SAVE ADDR OF RD CT CCW          45400019
         SR    WORKR,AWORKR             POINT TO TIC CCW                45500019
         ST    BWORKR,NULL(WORKR)       STORE RD CT CCW ADDR IN TIC     45600019
         MVI   NULL(WORKR),TIC          STORE TIC OP CODE               45700019
         MVI   8(WORKR),RDC             RESTORE READ COUNT CCW   XM6069 45800001
         L     WORKR,DCBBUFCB           GET BUFCB ADDR                  45900019
         LA    WORKR,NULL(WORKR)        CLEAR HI ORDER BYTE             46000019
         L     WORKR,DBLWD(WORKR)       OFFSET TO RECORD AREA ADDR      46100019
*                                                                       46200019
         LH    AWORKR,RADISPL           GET DISPLACEMENT OF RECORD FROM 46300019
*                                            BEGINNING OF BUFFER        46400019
         AR    RECADR,AWORKR            GET ADDR OF FIRST SEGMENT OF    46500019
*                                            SPANNED RECORD TO BE       46600019
*                                            UPDATED                    46700019
         CLI   DCBRECAD,RELFLAG         ERROR IN READ CHANNEL PROG. AND 46720019
*                                            SKIP OPTION IS SPECIFIED   46740019
         BE    UPDATE09                 RELEASE ENTIRE LOGICAL RECORD   46760019
*                                                                       46780019
UPDATE11 EQU   *                                                        46786019
*                                                                       46792019
         SR    AWORKR,AWORKR            CLEAR REG                       46800019
         IC    AWORKR,RAINDEX           OBTAIN OFFSET TO RECORD         46900019
         LA    RPARA0,RAALIGN           POINT TO ALIGNMENT AREA         47000019
         AR    AWORKR,RPARA0            GET ADDR OF RECORD              47100019
         LA    AWORKR,WORD(AWORKR)      GET ADDR OF DATA IN R.A.        47200019
         LA    RPARA1,WORD(RECADR)      POINT TO ADDR OF DATA IN BUFFER 47300019
*                                                                       47400019
         SR    LRECLR,LRECLR            CLEAR REG                       47440019
         IC    LRECLR,NULL(RECADR)      GET 1ST BYTE OF LL              47480019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   47520019
         IC    LRECLR,BYTE(RECADR)      LRECLR = 00LL                   47560019
         SH    LRECLR,CONST4            NUMBER OF BYTES OF DATA TO MOVE 47600019
         ST    RECADR,DCBRECAD          SAVE RECADR IN DCB              47640019
         LR    RECADR,AWORKR            LOAD ADDR OF RECORD IN RECADR   47660019
*                                                                       47700019
         BAL   RETR,MOVERTN             BRANCH TO MOVE ROUTINE          47800019
*                                                                       47900019
         L     RECADR,DCBRECAD          RELOAD RECADR                   47950019
         SR    AWORKR,AWORKR            CLEAR REG                       48000019
         IC    AWORKR,RAINDEX           GET OFFSET TO RECORD            48100019
         LA    RPARA0,RAALIGN           POINT TO ALIGNMENT AREA         48200019
         AR    AWORKR,RPARA0            GET ADDR OF RECORD              48300019
*                                                                       48400019
         SR    LRECLR,LRECLR            CLEAR REG                       48440019
         IC    LRECLR,NULL(RECADR)      GET 1ST BYTE OF LL              48480019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   48520019
         IC    LRECLR,BYTE(RECADR)      LRECLR = 00LL                   48560019
*                                                                       48600019
UPDATE02 EQU   *                                                        48700019
*                                                                       48800019
         SR    BWORKR,BWORKR            CLEAR REG                       48840019
         IC    BWORKR,NULL(AWORKR)      GET 1ST BYTE OF LL              48880019
         SLL   BWORKR,DBLWD             LRECLR = 00L0                   48920019
         IC    BWORKR,BYTE(AWORKR)      LRECLR = 00LL                   48960019
         SR    BWORKR,LRECLR            DECREMENT LL OF RECORD          49000019
         BZ    UPDATE06                 BRANCH IF REMAINDER IS ZERO     49100019
*                                                                       49200019
         LR    BWORKR,LRECLR            COPY LRECLR                     49300019
         SH    BWORKR,CONST4            GET TOTAL DATA MOVED            49400019
         STH   BWORKR,RACOUNT           SAVE IN COUNT FIELD             49500019
*                                                                       49600019
         SR    LRECLR,LRECLR            CLEAR REG                       49620019
         IC    LRECLR,NULL(RECADR)      GET 1ST BYTE OF LL              49640019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   49660019
         IC    LRECLR,BYTE(RECADR)      LRECLR = 00LL                   49680019
*                                                                       49720019
UPDATE07 EQU   *                                                        49740019
*                                                                       49760019
         AR    RECADR,LRECLR            UPDATE RECORD ADDRESS           49800019
         CR    EOBADR,RECADR            EOB CONDITION                   49900019
         BH    UPDATE04                 NO, BRANCH TO MOVE REST OF DATA 50000019
*                                                                       50100019
UPDATE08 EQU   *                                                        50200019
*                                                                       50300019
         OI    NULL(IOBAR),UPDATFLG     SET UPDATE FLAG ON              50400019
*                                                                       50500019
         BAL   RETR,CHANPROG            BRANCH TO SET UP C.P.           50600019
*                                                                       50700019
*********************************************************************** 50800019
*                                                                       50900019
*    TO UPDATE EOB ROUTINE TO SCHEDULE BUFFER                           51000019
*                                                                       51100019
*********************************************************************** 51200019
*                                                                       51300019
         L     ENTRYR,DCBEOB            END OF BLOCK ROUTINE ADDRESS    51400019
         BALR  RETR,ENTRYR              TO EOB ROUTINE                  51500019
*                                                                       51600019
*********************************************************************** 51700019
*                                                                       51800019
*    DCBIOBA INITIALIZED TO NEW IOB ADDRESS IN ERROR ROUTINE            51900019
*                                                                       52000019
*********************************************************************** 52100019
*                                                                       52200019
         L     ENTRYR,DCBGERR           ERROR ROUTINE ADDRESS           52300019
         BALR  RETR,ENTRYR              TO ERROR ROUTINE                52400019
*                                                                       52500019
         NI    NULL(IOBAR),FIRSTIOB     INITIALIZE NEW IOB              52600019
         OI    NULL(IOBAR),READONLY     RESET IOB TO READ ONLY          52700019
*                                                                       52800019
         SR    WORKR,WORKR              CLEAR REG                       52900019
         IC    WORKR,DCBOFFSR           GET CCW TO FIND BUFFER ADDR     53000019
         L     RECADR,NULL(WORKR,IOBAR) OBTAIN BUFFER ADDR              53100019
         LA    RECADR,NULL(RECADR)      CLEAR HIGH ORDER BYTE           53200019
*                                                                       53300019
         LH    EOBADR,NULL(RECADR)      PHYSICAL RECORD LENGTH          53400019
         IC    WORKR,DCBOFFSW           POINT TO WRITE CCW              53500019
         STH   EOBADR,WRTLEN(WORKR,IOBAR) SAVE LENGTH OF RECORD IN WCCW 53600019
         AR    EOBADR,RECADR            NEW EOB ADDR                    53700019
         LA    RECADR,WORD(RECADR)      GET FIRST LOGICAL RECORD ADDR   53800019
*                                                                       53900019
         L     WORKR,DCBBUFCB           GET BUFCB ADDR                  54000019
         LA    WORKR,NULL(WORKR)        CLEAR HIGH ORDER BYTE           54100019
         L     WORKR,DBLWD(WORKR)       OFFSET TO RECORD AREA ADDR      54200019
*                                                                       54300019
         SR    AWORKR,AWORKR            CLEAR REG                       54400019
         IC    AWORKR,RAINDEX           OBTAIN OFFSET TO RECORD         54500019
         LA    RPARA0,RAALIGN           POINT TO ALIGNMENT AREA         54600019
         AR    AWORKR,RPARA0            GET ADDR OF RECORD              54700019
*                                                                       54800019
UPDATE04 EQU   *                                                        54810019
*                                                                       55000019
         LH    BWORKR,RACOUNT           GET NUMBER OF BYTES MOVED       55100019
         LA    AWORKR,WORD(BWORKR,AWORKR) GET ADDR OF DATA IN R.A.      55200019
         LA    RPARA1,WORD(RECADR)      POINT TO ADDR OF DATA IN BUFFER 55300019
*                                                                       55400019
         TM    NULL(RECADR),NULLSEG     NULL SEGMENT                    55500019
         BO    UPDATE08                 BRANCH YES TO GET NEXT BLOCK    55600019
*                                                                       55610019
         CLI   DCBRECAD,RELFLAG         ERROR IN READ CHANNEL PROG. AND 55620019
*                                            SKIP OPTION IS SPECIFIED   55630019
         BNE   UPDATE05                 NO. BRANCH TO CONTINUE UPDATE   55640019
*                                                                       55650019
         TM    FLGOFST(RECADR),LASTSEG  IS THIS FOLLOWING ANY SEGMENT   55660019
         BZ    UPDATE06                 NO. RELEASE DONE                55670019
*                                                                       55680019
UPDATE09 EQU   *                                                        55690019
*                                                                       55700019
         SR    LRECLR,LRECLR            CLEAR REG                       55704019
         IC    LRECLR,NULL(RECADR)      GET 1ST BYTE OF LL              55708019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   55712019
         IC    LRECLR,BYTE(RECADR)      LRECLR = 00LL                   55716019
         ST    RECADR,DCBRECAD          STORE NEW RECORD ADDRESS        55720019
         OI    DCBRECAD,RELFLAG         SET RELEASE BIT                 55730019
         B     UPDATE07                 GO TO POSITION TO NEXT RECORD   55740019
*                                                                       55750019
UPDATE05 EQU   *                                                        55760019
*                                                                       55770019
         SR    LRECLR,LRECLR            CLEAR REG                       55790019
         IC    LRECLR,NULL(RECADR)      GET 1ST BYTE OF LL              55810019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   55830019
         IC    LRECLR,BYTE(RECADR)      LRECLR = 00LL                   55850019
         SH    LRECLR,CONST4            NUMBER OF BYTES OF DATA TO MOVE 55900019
*                                                                       55920019
         ST    RECADR,DCBRECAD          SAVE RECADR IN DCB              55960019
         LR    RECADR,AWORKR            LOAD ADDR OF RECORD IN RECADR   55980019
*                                                                       56000019
         BAL   RETR,MOVERTN             BRANCH TO MOVE ROUTINE          56100019
*                                                                       56200019
         L     RECADR,DCBRECAD          RELOAD RECADR                   56250019
         SR    AWORKR,AWORKR            CLEAR REG                       56300019
         IC    AWORKR,RAINDEX           GET OFFSET TO RECORD            56400019
         LA    RPARA0,RAALIGN           POINT TO ALIGNMENT AREA         56500019
         AR    AWORKR,RPARA0            GET ADDR OF RECORD              56600019
*                                                                       56700019
         LH    BWORKR,RACOUNT           GET NUMBER OF BYTES MOVED       56800019
         SR    LRECLR,LRECLR            CLEAR REG                       56840019
         IC    LRECLR,NULL(RECADR)      GET 1ST BYTE OF LL              56880019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   56920019
         IC    LRECLR,BYTE(RECADR)      LRECLR = 00LL                   56960019
         AR    LRECLR,BWORKR            UPDATE NUMBER OF BYTES MOVED    57000019
         B     UPDATE02                 BRANCH TO CHECK IF ALL SEGMENTS 57100019
*                                            HAVE BEEN MOVED            57200019
UPDATE06 EQU   *                                                        57300019
*                                                                       57400019
         NI    NULL(IOBAR),NOT-SPANFLG  TURN OFF SPANNED FLAG           57500019
         OI    NULL(IOBAR),UPDATFLG     SET UPDATE FLAG ON              57510019
*                                                                       57512019
         TM    RAFLG,NONSPAN            NON SPANNED RECORD IN R. A.     57513019
         BO    UPDATE12                 BRANCH TO CLEAR OUT CONTROL     57516019
*                                            FIELD                      57518019
*                                                                       57520019
         MVC   BYTE(ADLEN,IOBAR),RANXTIOB+BYTE RESET NEXT IOB ADDR      57530019
*                                                                       57540019
         L     AWORKR,NULL(IOBAR)       GET NEXT IOB IN SEQUENCE        57550019
         LA    AWORKR,NULL(AWORKR)      CLEAR HIGH ORDER BYTE           57560019
         CR    AWORKR,IOBAR             ONE IOB ONLY                    57570019
         BE    UPDATE10                 BRANCH IF YES                   57580019
*                                                                       57590019
         SR    BWORKR,BWORKR            CLEAR REG                       57600019
         IC    BWORKR,DCBOFFSR          OFFSET TO RD DATA CCW           57610019
         LA    RPARA1,SPFDAD(BWORKR,AWORKR) POINT TO NEXT IOB'S         57620019
*                                            SPECIAL FDAD               57630019
         LA    AWORKR,DBLWD             PREPARE TO DECREMENT            57640019
         AR    BWORKR,IOBAR             POINT TO RD DATA         20201  57642020
         CLI   DBLWD(BWORKR),RDSECT     IS RPS FEATURED          20201  57644020
         BE    UPDATE10                 IF SO, LEAVE C.P. AS IS  20201  57646020
         SR    BWORKR,AWORKR            OFFSET TO RD COUNT CCW          57650019
        ST    RPARA1,NULL(BWORKR)      PUT SPEC FDAD ADDR IN CP  20201  57660020
         MVI   NULL(BWORKR),RDC         STORE RD COUNT COMMAND CODE     57680019
*                                                                       57690019
UPDATE10 EQU   *                                                        57700019
*                                                                       57710019
         SR    BWORKR,BWORKR            CLEAR REG                       57800019
         IC    BWORKR,DCBOFFSR          GET OFFSET TO RD DATA CCW       57900019
         AR    BWORKR,IOBAR             POINT TO RD DATA CCW            58000019
         CLI   DBLWD(BWORKR),RDSECT     RECORD READY             20201  58040020
         BNE   NOTRPS2                  NO, THEN DONT INCREMENT  20201  58080020
         LA    BWORKR,DBLWD(BWORKR)     YES, INCREMENT           20201  58120020
NOTRPS2  EQU   *                                                 20201  58160020
         MVC   DBLWD(DBLWD,BWORKR),RATRKAD RESTORE SPECIAL FDAD         58200019
*                                                                       58500019
UPDATE12 EQU   *                                                        58530019
*                                                                       58560019
         SR    LRECLR,LRECLR            CLEAR REG                       58840019
         IC    LRECLR,NULL(RECADR)      GET 1ST BYTE OF LL              58880019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   58920019
         IC    LRECLR,BYTE(RECADR)      LRECLR = 00LL                   58960019
*                                                                       58964019
         TM    RALNG,EOD                HAS EOF OCCURED                 58968019
         BNO   UPDATE15                 BRANCH NO TO NORMAL PROCESSING  58970019
*                                                                       58973019
         SR    BWORKR,BWORKR            CLEAR REG                       58980019
         IC    BWORKR,DCBOFFSW          GET WRITE CCW OFFSET            58984019
         AR    BWORKR,IOBAR             POINT TO WRITE CCW              58988019
         TM    DCBOPTCD,WRTCK           WRITE CHECK USED                58988819
         BNO   UPDATE14                 NO, BRANCH                      58989619
         CLI   DBLWD(BWORKR),SETSECT    IS RECORD READY FEATURED 20201  58989720
         BNE   NOTRPS1                  IF NOT, DONT INCREMENT   20201  58989820
         LA    BWORKR,DBLWD(BWORKR)     ADD 8 BYTES FOR RPS      20201  58989920
NOTRPS1  EQU   *                                                 20201  58990020
         LA    BWORKR,WRTCKCP(BWORKR)   ADD WRITE CHECK CP LENGTH       58990419
UPDATE14 EQU   *                                                        58991219
         NI    WORD(BWORKR),NOT-CC      TURN OFF COMMAND CHAIN BIT      58992019
*                                                                       58993019
UPDATE15 EQU   *                                                        58994019
*                                                                       58995019
         TM    RAFLG,SPRELSE            RELSE ISSUED AFTER SPANNED      58996019
*                                            RECORD IS GOTTEN           58997019
         BO    UPDATE13                 BRANCH YES TO RETURN TO RELSE   58998019
         XC    RAFLG(CNTRLLEN),RAFLG    CLEAR CONTROL INFO IN RA        58999019
         B     UPDATE0A                 BRANCH TO NORMAL PROCESSING     59000019
*                                                                       59010019
UPDATE13 EQU   *                                                        59020019
*                                                                       59030019
         XC    RAFLG(CNTRLLEN),RAFLG    CLEAR CONTROL INFO IN RA        59040019
         B     RELSE1                   RETURN TO RELSE                 59050019
*                                                                       59100019
*********************************************************************** 59200019
*                                                                       59300019
CHANPROG EQU   *                                                        59400019
*                                                                       59500019
         LR    RPARA0,RETR              SAVE RETURN ADDR                59600019
*                                                                       59700019
         SR    BWORKR,BWORKR            CLEAR REG                       59800019
         IC    BWORKR,DCBOFFSR          GET OFFSET TO RD DATA CCW       59900019
         AR    BWORKR,IOBAR             POINT TO RD DATA CCW THIS IOB   60000019
*                                                                       60100019
         SR    RPARA1,RPARA1            PRIME FOR NON REC READY  20201  60110020
         CLI   DBLWD(BWORKR),RDSECT     BUT IS IT REC READY      20201  60120020
         BNE   NOTRPS3                  IF NOT DONT MAKE ADJUST  20201  60130020
         LA    RPARA1,DBLWD             IF SO, THEN MAKE THE     20201  60140020
         AR    BWORKR,RPARA1             NECESSARY ADJUSTMENTS   20201  60150020
NOTRPS3  EQU   *                                                 20201  60160020
         CLC   DCBIOBA+BYTE(ADLEN),BYTE(IOBAR) COMPARE CURRENT IOB TO   60200019
*                                            NEXT IOB                   60300019
         BNE   UPDATE0                  BRANCH IF MORE THAN ONE IOB     60400019
*                                                                       60500019
         MVC   SPFDAD(CCHHR,BWORKR),DCBFDAD+MBB PLACE FDAD IN SPECIAL   60600019
*                                            FDAD                       60700019
UPDATE0  EQU   *                                                        60800019
*                                                                       60900019
         SR    WORKR,WORKR              CLEAR REG                       61000019
         SR    AWORKR,AWORKR            CLEAR REG                       61100019
         IC    WORKR,DCBWCPO            GET WRITE CHANNEL PROG. OFFSET  61200019
         IC    AWORKR,DCBWCPL             AND ADD TO                    61300019
         SLL   AWORKR,MTP3                  DBL WORDS TO BYTES          61400019
         AR    WORKR,AWORKR               WRITE CHANNEL PROG. LENGTH    61500019
         ALR   WORKR,IOBAR              POINT TO IOB                    61600019
         LA    WORKR,DBLWD(RPARA1,WORKR) PT TO SCH CCW           20201  61700020
*                                                                       61800019
         TM    NULL(IOBAR),UPDATFLG     UPDATE FLAG ON                  61900019
         BZ    UPDATE03                 NO, BRANCH                      62000019
*                                                                       62100019
         LA    BWORKR,SPFDAD(BWORKR)    GET ADDR OF SPECIAL FDAD        62200019
         ST    BWORKR,NULL(WORKR)       PLACE IN SEARCH CCW             62300019
         MVI   NULL(WORKR),SRCHOP       REPLACE SEARCH OP IN CCW WHICH  62400019
*                                            WAS MODIFIED IN EOE APP.   62500019
         NI    NULL(IOBAR),NOT-UPDATFLG-READONLY TURN OFF UPDATE AND    62600019
*                                            ONLY READ FLAGS            62700019
         SR    WORKR,WORKR              CLEAR REG                       62800019
         IC    WORKR,DCBWCPO            GET WRITE SEQUENCE OFFSET       62900019
         AR    WORKR,IOBAR                FOR THIS IOB                  63000019
         ST    WORKR,STARTCP(IOBAR)     PLACE IN CP POINTER             63100019
         TM    DCBOPTCD,WRTCK           WRITE CHECK USED                63200019
         BNO   UPDATE01                 NO, BRANCH                      63300019
*                                                                       63400019
         AR    WORKR,RPARA1             PT TO WRT DATA CNT FLD   20201  63450020
         LA    BWORKR,NULL(WORKR,RPARA1) PT TO RD DATA CNT FLD   20201  63500020
         MVC   WCKCT(CNTLEN,BWORKR),WRTCT(WORKR) PUT CNT IN WRT  20201  63550020
*                                            CHECK CCW                  63600019
UPDATE01 EQU   *                                                        63700019
*                                                                       63800019
         SR    WORKR,WORKR              CLEAR REG                       63900019
         IC    WORKR,DCBOFFSR           GET OFFSET TO READ DATA CCW     64000019
         LA    BWORKR,DBLWD             PREPARE TO REDUCE ADDR TO       64100019
         SR    WORKR,BWORKR             GET OFFSET TO READ COUNT CCW    64200019
         L     BWORKR,NULL(WORKR,IOBAR) GET ADDRESS OF NEXT IOB'S       64300019
*                                         SPECIAL WRITE ARGUMENT        64400019
         LA    BWORKR,NULL(BWORKR)      CLEAR HI ORDER BYTE             64500019
         MVC   IOSFDAD(CCHHR,IOBAR),0(BWORKR) PLACE IN FDAD      XM6069 64800001
*                                                                       64900019
         LR    RETR,RPARA0              RESTORE RETURN ADDR             65000019
         BR    RETR                     RETURN TO MAIN LINE             65100019
*                                                                       65200019
*********************************************************************** 65300019
*                                                                       65400019
UPDATE03 EQU   *                                                        65500019
*                                                                       65600019
         TM    DCBCIND2,CLOSEB          ARE WE IN CLOSE                 65700019
         BO    EXIT1                    YES,RETURN                      65800019
*                                                                       65900019
         ST    WORKR,STARTCP(IOBAR)     PLACE IN CP POINTER             66000019
         B     EXIT2                    BRANCH TO GO TO EOB RTN         66200019
*                                                                       66300019
*********************************************************************** 66400019
*                                                                       66500019
UPDATE1  EQU   *                                                        66600019
*                                                                       66700019
* A SPANNED RECORD IS ENCOUNTERED. NEED TO SAVE TRACK ADDRESS OF THIS   66800019
* BLOCK, DISPLACEMENT OF RECORD ADDRESS FROM BEGINNING OF BUFFER, AND   66900019
* ALIGNMENT OF THE BEGINNING SEGMENT                                    67000019
*                                                                       67100019
         L     WORKR,DCBBUFCB           GET BUFCB ADDR                  67200019
         LA    WORKR,NULL(WORKR)        CLEAR HI ORDER BYTE             67300019
         L     WORKR,DBLWD(WORKR)       OFFSET TO RECORD AREA ADDR      67400019
*                                                                       67500019
* REGISTER USAGE -  WORKR - BASE REG FOR RECORD AREA                    67600019
*                   RECADR - ADDR OF RECORD IN BUFFER                   67700019
*                   RPARA1 - ADDR OF RECORD IN RECORD AREA              67800019
*                   AWORKR - WORK REG                                   67900019
*                   BWORKR - WORK REG                                   68000019
*                                                                       68100019
         TM    RALNG,COBOL              COBOL BIT ON                    68110019
         BZ    UPDATE4                  BRANCH NO TO SET ALIGNMENT      68120019
         MVC   RAINDEX,CONST4+BYTE      SET INDEX TO FOUR               68130019
         B     UPDATE5                  BRANCH TO MOVE RECORD TO R.A.   68140019
*                                                                       68150019
UPDATE4  EQU   *                                                        68160019
*                                                                       68170019
         STC   RECADR,RAINDEX           LOW ORDER BYTE USED AS INDEX    68200019
         NI    RAINDEX,HASH             HASH OF INDEX                   68300019
*                                                                       68320019
UPDATE5  EQU   *                                                        68340019
*                                                                       68360019
         MVI   RAFLG,ASSEMBLE           SET FLAG TO INDICATE ASSEMBLING 68430019
*                                            IN PROCESS                 68500019
         SR    AWORKR,AWORKR            CLEAR REG                       68600019
         IC    AWORKR,DCBOFFSR          GET OFFSET TO RD DATA CCW       68700019
         LA    AWORKR,NULL(AWORKR,IOBAR) ADDR OF READ DATA CCW   XM6069 68750001
         L     BWORKR,NULL(AWORKR)       GET ADDR OF BUFFER      XM6069 68800001
         LA    BWORKR,NULL(BWORKR)      CLEAR HIGH ORDER BYTE           68900019
         LR    RPARA0,RECADR            COPY RECADR                     69000019
         SR    RPARA0,BWORKR            SUBTRACT RECAD FROM BUFAD TO    69100019
         STH   RPARA0,RADISPL                GET DISPLACEMENT FOR R.A.  69200019
*                                                                       69300019
         LA    BWORKR,DBLWD             PREPARE TO REDUCE ADDR          69400019
         SR    AWORKR,BWORKR            OFFSET TO RD COUNT CCW          69500019
         L     BWORKR,NULL(AWORKR)      GET ADDR NXT SPEC FDAD   XM6069 69600001
         LA    BWORKR,NULL(BWORKR)      CLEAR HIGH ORDER BYTE           69700019
         CLI   7(AWORKR),CNT8           COUNT OF 8               XM6069 69750001
         BNE   UPDATE5A                 NO MBBCCHHR ALL TOGETHER XM6069 69760001
         MVC   RATRKAD+MBB(CCHHR),NULL(BWORKR) MOVE IN CCHHR     XM6069 69770001
         LA    AWORKR,DBLWD              PREPARE TO REDUCE PTR   XM6069 69780001
         SR    BWORKR,AWORKR             POINT TO SPECIAL FDAD   XM6069 69790001
         MVC   RATRKAD(MBB),NULL(BWORKR)   MOVE IN MBB           XM6069 69792001
         B     UPDATE5B                  CONTINUE                XM6069 69794001
UPDATE5A EQU   *                                                 XM6069 69796001
         LA    AWORKR,MBB               POINT TO FULL DISK ADDRESS      69800019
         SR    BWORKR,AWORKR                 FOR THIS IOB               69900019
         MVC   RATRKAD,NULL(BWORKR)     MOVE FDAD TO R.A.               70000019
UPDATE5B EQU   *                                                 XM6069 70100001
         IC    AWORKR,RAINDEX           GET INDEX TO RECORD IN R.A.     70200019
         LA    RPARA1,RAALIGN           GET ADDR OF ALIGNMENT AREA      70300019
         AR    RPARA1,AWORKR            POINT TO BEGINNING OF DATA      70400019
         ST    RECADR,DCBRECAD          SAVE RECADR IN DCB              70610019
*                                                                       70700019
         BAL   RETR,MOVERTN             BRANCH TO MOVE ROUTINE          70800019
*                                                                       70900019
         L     RECADR,DCBRECAD          RELOAD RECADR                   70950019
         SR    AWORKR,AWORKR            CLEAR REG                       71000019
         IC    AWORKR,RAINDEX           GET OFFSET TO RECORD            71100019
         LA    RPARA0,RAALIGN           POINT TO ALIGNMENT AREA         71200019
         AR    AWORKR,RPARA0            GET ADDR OF RECORD              71300019
*                                                                       71320019
         CLC   CNTLEN(CNTLEN,AWORKR),ZERO CONTROL CODE ZERO             71340019
         BE    UPDATE6                  BRANCH YES TO SET NON SPANNED   71360019
*                                            BIT                        71380019
         XC    CNTLEN(CNTLEN,AWORKR),CNTLEN(AWORKR) CLEAR CONTROL CODE  71400019
*                                                                       71500019
         LR    RECADR,EOBADR            FORCE END OF BLOCK CONDITION    71600019
         B     UPDATE0B                 BRANCH TO GET NEXT SEGMENT,     71700019
*                                            THIS WILL CAUSE EOB.       71800019
UPDATE6  EQU   *                                                        71820019
*                                                                       71840019
         OI    RAFLG,NONSPAN            SET NON SPANNED RECORD BIT      71860019
         B     UPDATE3                  SET UP TO RETURN TO USER        71880019
*********************************************************************** 71900019
*                                                                       72000019
UPDATE2  EQU   *                                                        72100019
*                                                                       72200019
* AT THIS POINT, EOBADR - NEW EOB ADDR                                  72300019
*                RECADR - ADDR OF FIRST SEGMENT IN BLOCK                72400019
*                LRECLR - LENGTH OF THIS SEGMENT                        72500019
*                                                                       72600019
* REGS FREE TO BE USED ARE - RPARA0, RPARA1, WORKR, AWORKR, AND BWORKR  72700019
*                                                                       72800019
         L     WORKR,DCBBUFCB           GET BUFCB ADDR                  72900019
         LA    WORKR,NULL(WORKR)        CLEAR HI ORDER BYTE             73000019
         L     WORKR,DBLWD(WORKR)       OFFSET TO RECORD AREA ADDR      73100019
*                                                                       73200019
* REGISTER USAGE -  WORKR - BASE REG FOR RECORD AREA                    73300019
*                   RECADR - ADDR OF RECORD IN BUFFER                   73400019
*                   RPARA1 - ADDR OF RECORD IN RECORD AREA              73500019
*                   AWORKR - WORK REG                                   73600019
*                   BWORKR - WORK REG                                   73700019
*                                                                       73800019
         SR    AWORKR,AWORKR            CLEAR REG                       73900019
         IC    AWORKR,RAINDEX           GET OFFSET TO RECORD            74000019
         LA    BWORKR,RAALIGN           POINT TO ALIGNMENT AREA         74100019
         AR    BWORKR,AWORKR            GET ADDR OF RECORD              74200019
*                                                                       74300019
         IC    AWORKR,NULL(BWORKR)      GET 1ST BYTE OF LL              74350019
         SLL   AWORKR,DBLWD             LRECLR = 00L0                   74400019
         IC    AWORKR,BYTE(BWORKR)      LRECLR = 00LL                   74450019
         LA    RPARA1,NULL(AWORKR,BWORKR) GET TO END OF RECORD SEGMENT  74500019
         LA    RPARA0,WORD(RECADR)      GET ADDR OF DATA                74600019
*                                                                       74700019
         SH    LRECLR,CONST4            NUMBER OF BYTES OF DATA TO MOVE 74800019
         AR    AWORKR,LRECLR            INCREMENT LL IN R.A.            74900019
         STC   AWORKR,BYTE(BWORKR)      STORE UPDATED 000L IN R. A.     74930019
         SRL   AWORKR,DBLWD             AWORKR = 000L                   74960019
         STC   AWORKR,NULL(BWORKR)      STORE UPDATED 00LL IN R. A.     74990019
*                                                                       75020019
         ST    RECADR,DCBRECAD          SAVE RECADR IN DCB              75060019
         LR    RECADR,RPARA0            LOAD ADDR OF RECORD IN RECADR   75080019
*                                                                       75100019
         BAL   RETR,MOVERTN             BRANCH TO MOVE ROUTINE          75200019
*                                                                       75300019
         L     RECADR,DCBRECAD          RELOAD RECADR                   75350019
         TM    FLGOFST(RECADR),FIRSTSEG ANY SEGMENT FOLLOWING           75400019
         BZ    UPDATE3                  BRANCH NO TO SET UP FOR RETURN  75500019
*                                                                       75600019
         SR    LRECLR,LRECLR            CLEAR REG                       75640019
         IC    LRECLR,NULL(RECADR)      GET 1ST BYTE OF LL              75680019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   75720019
         IC    LRECLR,BYTE(RECADR)      LRECLR = 00LL                   75760019
         B     UPDATE0A                 BRANCH TO GET NEXT SEGMENT      75800019
*                                                                       75900019
UPDATE3  EQU   *                                                        76000019
*                                                                       76100019
         SR    AWORKR,AWORKR            CLEAR REG                       76200019
         IC    AWORKR,RAINDEX           GET OFFSET TO RECORD            76300019
         LA    BWORKR,RAALIGN           POINT TO ALIGNMENT AREA         76400019
         AR    BWORKR,AWORKR            GET ADDR OF RECORD              76500019
*                                                                       76600019
         SR    LRECLR,LRECLR            CLEAR REG                       76640019
         IC    LRECLR,NULL(BWORKR)      GET 1ST BYTE OF LL              76680019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   76720019
         IC    LRECLR,BYTE(BWORKR)      LRECLR = 00LL                   76760019
         ST    BWORKR,REG1(SAVR)        SET PARAMETER FOR USER          76800019
*                                                                       76900019
         OI    NULL(IOBAR),SPANFLG      SET SPANNED FLAG ON             77000019
         B     RETURN                   BRANCH TO RETURN TO USER        77100019
*                                                                       77200019
*********************************************************************** 77300019
*                                                                       77400019
* RECADR - ADDR OF DATA TO BE MOVED                                     77500019
* RPARA1 - ADDR OF AREA TO WHICH DATA IS MOVED                          77600019
* LRECLR - LENGTH OF DATA TO BE MOVED                                   77700019
*                                                                       77800019
MOVERTN  EQU   *                                                        77900019
*                                                                       78000019
         B     SMOVE                    BRANCH TO MOVE                  78100019
*                                                                       78200019
MOVE     MVC   NULL(NULL,RPARA1),NULL(RECADR) MOVE LESS THAN 256 BYTES  78300019
*                                                                       78400019
MOVE256  MVC   NULL(FFF,RPARA1),NULL(RECADR) MOVE 256 BYTES             78500019
*                                                                       78600019
         LA    RECADR,FFF(RECADR)       ADD 256 TO ADDR OF DATA         78700019
         LA    RPARA1,FFF(RPARA1)       ADD 256 TO ADDR OF AREA         78800019
*                                                                       78900019
SMOVE    EQU   *                                                        78950019
*                                                                       79000019
         SH    LRECLR,CONST256          SUBTRACT 256                    79050019
         BH    MOVE256                  LOOP IF MORE THAN 256           79100019
*                                                                       79200019
         AH    LRECLR,CONST255          CORRECT TO ORIGINAL LENGTH      79300019
         EX    LRECLR,MOVE              MOVE REST OF BYTES              79400019
*                                                                       79500019
         BR    RETR                     RETURN TO MAIN LINE             79600019
*                                                                       79700019
*********************************************************************** 79800019
*                                                                       79900019
PUTX     EQU   *                                                        80000019
*                                                                       80100019
         DROP  WORKR                    DROP BASE REGISTER              80200019
         DROP  BASR                                                     80300019
         DROP  DCBR                                                     80400019
*                                                                       80500019
         USING IGG019BN,ENTRYR          SET BASE REGISTER               80600019
         USING IHADCB,RPARA1            ESTABLISH ADDRESSIBILITY        80700019
*                                                                       80800019
         L     BWORKR,DCBIOBA           GET IOB ADDRESS.                80900019
         OI    NULL(BWORKR),UPDATFLG    SET UPDATE FLAG ON.             81000019
         BR    RETR                     RETURN TO USER                  81100019
*                                                                       81200019
*********************************************************************** 81300019
*                                                                       81400019
CONST4   DC    H'4'                     CONSTANT 4                      81500019
CONST36  DC    H'36'                    CONSTANT 36                     81600019
CONST255 DC    X'00FF'                  255 IN HEX                      81700019
CONST256 DC    X'0100'                  256 IN HEX                      81800019
ZERO     DC    X'00'                    ZERO CONSTANT                   81850019
*                                                                       81900019
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF WORD BOUNDARY   82000019
         CNOP  0,8                      FORCE ALIGNMENT                 82100019
*                                                                       82200019
*                                                                       82300019
         DCBD  DSORG=PS                                                 82400019
*                                                                       82500019
         DS    0D                       FORCE DOUBLE WORD BOUNDARY      82600019
RCDAREA  DSECT                          FORMAT OF RECORD AREA           82700019
RALNG    DS    CL4                      LENGTH OF RECORD AREA           82800019
RAFLG    DS    CL1                      FLAG BYTE                       82900019
RAINDEX  DS    CL1                      INDEX TO BEGINNING OF DATA      83000019
RADISPL  DS    CL2                      POSITION OF RECORD IN BLOCK     83100019
RATRKAD  DS    0CL8                     TRACK ADDRESS OF BEGINNING      83200019
*                                            SEGMENT OF RECORD          83300019
RAMBBCC  DS    CL5                      MBBCC OF TRACK ADDR (NOT USED   83400019
*                                            IF DCB IS FOR OUTPUT)      83500019
RARECAD  DS    CL3                      RECAD WHEN RECORD TO BE WRITTEN 83600019
*                                            REQUIRES SEGMENTATION      83700019
RANXTIOB DS    CL4                      NEXT IOB ADDRESS                83710019
RACOUNT  DS    CL2                      COUNT FIELD OF NUMBER OF BYTES  83720019
*                                            MOVED                      83750019
         DS    CL2                      RESERVED                        83760019
RAALIGN  DS    0CL8                     FLOATING ALIGNMENT AREA         83800019
RADATA   EQU   RAALIGN                  DATA                            83900019
         END                                                            84000019
