         TITLE 'IGG019BO - QSAM GET/LOCATE VARIABLE LENGTH RECORD EXTEN*00200019
               TION LOGICAL RECORD INTERFACE'                           00400019
IGG019BO CSECT                                                          00600019
*                                                                       00800019
*        RELEASE 20 DELETIONS                                           01000019
*3572                                                            A33650 01100020
*        RELEASE 21 DELETIONS                                           01200019
* A594500-5959606                                               XA02723 01250003
*        RELEASE 22 DELETIONS                                           01400019
*        RELEASE 23 DELETIONS                                           01600019
*        RELEASE 24 DELETIONS                                           01800019
*        RELEASE 25 DELETIONS                                           02000019
*        RELEASE 26 DELETIONS                                           02200019
*        RELEASE 27 DELETIONS                                           02400019
*        RELEASE 28 DELETIONS                                           02600019
*                                                                       02800019
*STATUS CHANGE LEVEL 002                                                03000020
*                                                                       03200019
*FUNCTION/OPERATION- THIS ROUTINE WILL PROCESS VARIABLE SPANNED RECORDS 03400019
*        GET ROUTINE LOCATES THE NEXT SEQUENTIAL LOGICAL RECORD TO BE   03600019
*        PROCESSED.                                                     03800019
*        RELEASE ROUTINE CAUSES THE REMAINING CONTENTS OF THE CURRENT   04000019
*        BUFFER TO BE IGNORED.                                          04200019
*                                                                       04600019
*ENTRY POINTS- ENTRY 1  GET        ENTRY2  RELEASE                      04800019
*                LA  1,DCB           LA  1,DCB                          05000019
*                L   15,48(1)        L   15,48(1)                       05200019
*                BALR 14,15          BAL 14,8(15)                       05400019
*                                                                       05600019
*INPUT- FROM USERS PROBLEM PROGRAM                                      05800019
*       REGISTER 13 SAVE AREA ADDRESS                                   06000019
*                14 PROBLEM PROGRAM RETURN ADDRESS                      06200019
*                15 GET ROUTINE INITIAL BASE ADDRESS                    06400019
*                1  DCB ADDRESS                                         06600019
*                                                                       06800019
*OUTPUT- REGISTER  1  LOCATED RECORD ADDRESS                            07000019
*                                                                       07200019
*EXTERNAL ROUTINES - IECQGERR GET ERROR ROUTINE DETECTS SYNCHRONOUS     07400019
*                             ERRORS FOR USER AND ACCESSES NEW IOB      07600019
*                    END OF BLOCK ROUTINE -DEVICE DEPENDENT- SCHEDULES  07800019
*                             INPUT                                     08000019
*                                                                       08200019
*EXITS- NORMAL                                                          08400019
*              EXIT1               EXIT2               EXIT3            08600019
*                NORMAL              EOB ROUTINE         ERROR ROUTINE  08800019
*                  BCR  15,14          BALR  14,15         BALR  14,15  09000019
*                                                                       09200019
*       ABNORMAL-                                                       09240020
*               EXIT4                                                   09280020
*                  ABEND 002                                            09320020
*                                                                       09360020
*TABLES/WORKAREAS- REGISTER SAVEAREA                                    09400019
*                  IOB                                                  09600019
*                   DCB  USING BLKSI, EOB, EOBAD, RECAD, GERR, IOBA,    09800019
*                              LRECL, OFLGS, RECFM                      10000019
*                  RECORD AREA - SEE DSECT AT THE END OF LISTING        10200019
*                                                                       10400019
*ATTRIBUTES- REENTRANT, PROBLEM PROGRAM MODE                            10600019
*                                                                       10800019
*********************************************************************** 11000019
*                                                                       11200019
RPARA0   EQU   0                        0 PARAMETER REG                 11400019
RPARA1   EQU   1                        1 PARAMETER REG                 11600019
DCBR     EQU   2                        DCB REG                         11800019
IOBAR    EQU   3                        IOB REG                         12000019
EOBADR   EQU   4                        END OF BUFFER REG               12200019
RECADR   EQU   5                        RECORD ADDRESS REG              12400019
LRECLR   EQU   6                        LOGICAL LENGTH REG              12600019
WORKR    EQU   7                        WORK REG                        12800019
BASR     EQU   8                        BASE REG                        13000019
SAVR     EQU   13                       SAVE REG                        13200019
AWORKR   EQU   14                       WORK REG                        13400019
RETR     EQU   14                       RETURN REG                      13600019
BWORKR   EQU   15                       WORK REG                        13800019
ENTRYR   EQU   15                       ENTRY REG                       14000019
*                                                                       14200019
NOT      EQU   X'FF'                    MASK                            14400019
SPANFLG  EQU   X'04'                    SPANNED RECORD FLAG IN IOB      14600019
RELFLAG  EQU   X'F0'                    RELEASE BIT                     14800019
FLGOFST  EQU   2                        CONTROL CODE OFFSET             15000019
FIRSTSEG EQU   X'01'                    FIRST SEGMENT OF RECORD         15200019
LASTSEG  EQU   X'02'                    LAST SEGMENT OF SPANNED RECORD  15400019
MIDSEG   EQU   X'03'                    MIDDLE SEGMENT OF RECORD        15600019
NULLSEG  EQU   X'80'                    NULL SEGMENT                    15800019
ASSEMBLE EQU   X'01'                    ASSEMBLING IN PROCESS           16000019
SEGMENT  EQU   X'10'                    SEGMENTATION IN PROCESS         16200019
HASH     EQU   X'07'                    HASHING FACTOR                  16400019
SAOFF    EQU   20                       SAVE AREA OFFSET                16600019
REG1     EQU   32                       REGESTER 1 OFFSET FROM SAVEAREA 16800019
NULL     EQU   0                        ZERO DISPLACEMENT               17000019
BYTE     EQU   1                        ONE BYTE DISPLACEMENT           17200019
WORD     EQU   4                        WORD DISPLACEMENT               17400019
DBLWD    EQU   8                        DOUBLE WORD DISPLACEMENT        17600019
ADLEN    EQU   3                        LENGTH OF ADDRESS               17800019
CNTLEN   EQU   2                        LENGTH OF COUNT FIELD           18000019
FFF      EQU   256                      256                             18200019
*                                                                       18250019
COBOL    EQU   X'40'                    COBOL BIT IN R. A.              18300019
NONSPAN  EQU   X'04'                    NON SPANNED RECORD IN R. A.     18350019
*                                                                       18400019
*********************************************************************** 18600019
*                                                                       18800019
         USING IGG019BO,ENTRYR          SET BASE REGISTER               19000019
         USING IHADCB,RPARA1            ESTABLISH ADDRESSIBILITY        19200019
*                                                                       19400019
ENTRY1   EQU   *                                                        19600019
*                                                                       19800019
         B     START                    BRANCH TO GET                   20000019
         DC    X'00000000'              CONSTANT ZERO                   20200019
*                                                                       20400019
ENTRY2   EQU   *                                                        20600019
*                                                                       20800019
*********************************************************************** 21000019
*                                                                       21200019
*    SIMULATE END OF BLOCK CONDITION.  MAKE REC ADDR EQUAL EOB ADDR     21400019
*                                                                       21600019
*********************************************************************** 21800019
*                                                                       22000019
         MVC   DCBRECAD+BYTE(ADLEN),DCBEOBAD+BYTE INITIALIZE FOR RELSE  22200019
         OI    DCBRECAD,RELFLAG         SET RELEASE BIT IN DCB          22400019
         BR    RETR                     RETURN TO USER                  22600019
*                                                                       22800019
*********************************************************************** 23000019
*                                                                       23200019
START    EQU   *                                                        23400019
*                                                                       23600019
         STM   RETR,BASR,SAOFF(SAVR)    SAVE REGISTERS                  23800019
*                                                                       24000019
         DROP  ENTRYR                                                   24200019
         DROP  RPARA1                                                   24400019
*                                                                       24600019
         USING IGG019BO,BASR            SET BASE REGISTER               24800019
         USING IHADCB,DCBR                                              25000019
         USING RCDAREA,WORKR            ESTABLISH BASE FOR RECORD AREA  25200019
*                                                                       25400019
         LR    DCBR,RPARA1              MAKE DCB ADDRESSABLE            25600019
         LR    BASR,ENTRYR              LOAD BASE REG                   25800019
         LM    IOBAR,RECADR,DCBIOBA     LOAD WORK REGS.                 26000019
*                                                                       26200019
         TM    NULL(IOBAR),SPANFLG      SPANNED RECORD FLAG ON          26400019
         BZ    VREGL010                 BRANCH IF NOT TO GET LRECL      26600019
*                                                                       26800019
         NI    NULL(IOBAR),NOT-SPANFLG  TURN OFF SPANNED FLAG           27000019
         L     WORKR,DCBBUFCB           GET BUFCB ADDR                  27050019
         LA    WORKR,NULL(WORKR)        CLEAR HI ORDER BYTE             27100019
         L     WORKR,DBLWD(WORKR)       OFFSET TO RECORD AREA ADDR      27150019
         XC    RAFLG(CNTLEN),RAFLG      CLEAR FLAG AND INDEX            27200019
*                                                                       27400019
         SR    LRECLR,LRECLR            CLEAR REG                       27480019
         IC    LRECLR,NULL(RECADR)      GET 1ST BYTE OF LL              27560019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   27640019
         IC    LRECLR,BYTE(RECADR)      LRECLR = 00LL                   27720019
         B     VREGL020                 BRANCH TO TEST EOB              27800019
*                                                                       28000019
VREGL070 EQU   *                                                        28200019
*                                                                       28400019
         LR    RECADR,EOBADR            FORCE EOB CONDITION             28600019
         B     VREGL030                 BRANCH TO GET NEXT BLOCK        28800019
*                                                                       29000019
VREGL010 EQU   *                                                        29200019
*                                                                       29400019
         LH    LRECLR,DCBLRECL          GET LENGTH OF RECORD            29600019
*                                                                       29800019
VREGL020 EQU  *                                                         30000019
*                                                                       30200019
         LA    RECADR,NULL(RECADR)      CLEAR HIGH ORDER BYTE           30300019
         AR    RECADR,LRECLR            UPDATE RECORD ADDRESS           30400019
*                                                                       30600019
VREGL030 EQU   *                                                        30800019
*                                                                       31000019
         CR    EOBADR,RECADR            EOB CONDITION                   31200019
         BH    VREGL040                 NO, BRANCH                      31400019
*                                                                       31600019
         SR    WORKR,WORKR              CLEAR REG                       31800019
         IC    WORKR,DCBOFFSR           GET CCW TO FIND BUFFER ADDR.    32000019
*                                                                       32200019
*********************************************************************** 32400019
*                                                                       32600019
EXIT2    EQU   *                                                        32800019
*                                                                       33000019
         L     ENTRYR,DCBEOB            END OF BLOCK ROUTINE ADDRESS    33200019
         BALR  RETR,ENTRYR              TO EOB ROUTINE                  33400019
*                                                                       33600019
*********************************************************************** 33800019
*                                                                       34000019
EXIT3    EQU   *                                                        34200019
*                                                                       34400019
         L     ENTRYR,DCBGERR           ERROR ROUTINE ADDRESS           34600019
         BALR  RETR,ENTRYR              TO ERROR ROUTINE                34800019
*                                                                       35000019
*********************************************************************** 35200019
*                                                                       35400019
         L     RECADR,NULL(WORKR,IOBAR) OBTAIN BUFFER ADDR              35600019
         LA    RECADR,NULL(RECADR)      CLEAR HIGH ORDER BYTE           35800019
*                                                                       36000019
         LH    EOBADR,NULL(RECADR)      PHYSICAL RECORD LENGTH          36200019
         AR    EOBADR,RECADR            NEW EOB ADDR                    36400019
         LA    RECADR,WORD(RECADR)      GET FIRST LOGICAL RECORD ADDR   36600019
         LH    LRECLR,NULL(RECADR)      GET LENGTH FROM RECORD          36800019
*                                                                       37000019
VREGL040 EQU   *                                                        37200019
*                                                                       37400019
         CLC   0(2,RECADR),RDWLT4      RDW LT 4?                 A33650 37460020
         BL    EXIT4                   YES, ABEND '002'          A33650 37520020
         CLI   DCBRECAD,RELFLAG         IS RELEASE BIT SET              37600019
         BNE   VREGL050                 NO, BRANCH FOR NORMAL GET PROC. 37800019
*                                                                       38000019
         TM    FLGOFST(RECADR),LASTSEG  TEST BIT 6 OF BYTE 2 RECORD     38200019
         BZ    VREGL060                      CONTROL WORD, IF NOT ON,   38400019
*                                            RELEASE DONE, EXIT         38600019
         SR    LRECLR,LRECLR            CLEAR REG                       38680019
         IC    LRECLR,NULL(RECADR)      GET 1ST BYTE OF LL              38760019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   38840019
         IC    LRECLR,BYTE(RECADR)      LRECLR = 00LL                   38920019
         ST    RECADR,DCBRECAD          STORE NEW RECORD ADDRESS        39000019
         OI    DCBRECAD,RELFLAG         SET RELEASE BITS                39200019
         B     VREGL020                 GO TO POSITION TO NEXT RECORD   39400019
*                                                                       39600019
VREGL050 EQU   *                                                        39800019
*                                                                       40000019
         TM    NULL(RECADR),NULLSEG     NULL SEGMENT                    40200019
         BO    VREGL070                 BRANCH YES TO FORCE EOB         40400019
*                                                                       40600019
         SR    LRECLR,LRECLR            CLEAR REG                       40630019
         IC    LRECLR,NULL(RECADR)      GET 1ST BYTE OF LL              40660019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   40690019
         IC    LRECLR,BYTE(RECADR)      LRECLR = 00LL                   40720019
*                                                                       40750019
         TM    FLGOFST(RECADR),LASTSEG  IS THIS FOLLOWING ANY SEGMENT   40800019
         BO    ASSEM2                   YES,BRANCH TO SPANNED RECORD    41000019
*                                            PROCESSING                 41200019
VREGL060 EQU   *                                                        41400019
*                                                                       41600019
         SR    LRECLR,LRECLR            CLEAR REG                       41630019
         IC    LRECLR,NULL(RECADR)      GET 1ST BYTE OF LL              41660019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   41690019
         IC    LRECLR,BYTE(RECADR)      LRECLR = 00LL                   41720019
*                                                                       41750019
         TM    FLGOFST(RECADR),FIRSTSEG IS THIS FIRST SEGMENT           41800019
         BO    ASSEM1                   YES BRANCH TO SAVE INFO         42000019
*                                                                       42200019
         L     WORKR,DCBBUFCB           GET BUFCB ADDR                  42250019
         LA    WORKR,NULL(WORKR)        CLEAR HIGH ORDER BYTE           42300019
         L     WORKR,DBLWD(WORKR)       OFFSET TO RECORD AREA ADDR      42350019
         TM    RALNG,COBOL              COBOL BIT ON                    42400019
         BO    ASSEM1                   BRANCH YES TO MOVE RECORD       42450019
*                                                                       42500019
         ST    RECADR,REG1(SAVR)        PARAMETER FOR USER              42600019
*                                                                       42800019
RETURN   EQU   *                                                        43000019
*                                                                       43200019
         STH   LRECLR,DCBLRECL          UPDATE DCB LRECL                43400019
         STM   IOBAR,RECADR,DCBIOBA     INITIALIZE DCB                  43600019
*                                                                       43800019
EXIT1    EQU   *                                                        44000019
*                                                                       44200019
         LM    RETR,BASR,SAOFF(SAVR)    RESTORE USER REGS               44400019
         BR    RETR                     RETURN TO USER                  44600019
*                                                                       44800019
EXIT4    EQU   *                                                 A33650 44820020
         LA    1,002                                             A33650 44840020
         SLL   1,12                                              A33650 44860020
         ABEND (1),DUMP                                          A33650 44880020
RDWLT4   DC    X'0004'                                           A33650 44900020
*                                                                       44920020
*********************************************************************** 45000019
*                                                                       45200019
ASSEM1  EQU   *                                                         45400019
*                                                                       45600019
* A SPANNED RECORD IS ENCOUNTERED. NEED TO SAVE TRACK ADDRESS OF THIS   45800019
* BLOCK, DISPLACEMENT OF RECORD ADDRESS FROM BEGINNING OF BUFFER, AND   46000019
* ALIGNMENT OF THE BEGINNING SEGMENT                                    46200019
*                                                                       46400019
         L     WORKR,DCBBUFCB           GET BUFCB ADDR                  46600019
         LA    WORKR,NULL(WORKR)        CLEAR HI ORDER BYTE             46800019
         L     WORKR,DBLWD(WORKR)       OFFSET TO RECORD AREA ADDR      47000019
*                                                                       47200019
* REGISTER USAGE -  WORKR - BASE REG FOR RECORD AREA                    47400019
*                   RECADR - ADDR OF RECORD IN BUFFER                   47600019
*                   RPARA1 - ADDR OF RECORD IN RECORD AREA              47800019
*                   AWORKR - WORK REG                                   48000019
*                   BWORKR - WORK REG                                   48200019
*                                                                       48400019
         TM    RALNG,COBOL              COBOL BIT ON                    48420019
         BZ    ASSEM4                   BRANCH NO TO SET ALIGNMENT      48440019
         MVC   RAINDEX,CONST4+BYTE      SET INDEX TO FOUR               48460019
         B     ASSEM5                   BRANCH TO MOVE RECORD TO R.A.   48480019
*                                                                       48500019
ASSEM4   EQU   *                                                        48520019
*                                                                       48540019
         STC   RECADR,RAINDEX           LOW ORDER BYTE USED AS INDEX    48600019
         NI    RAINDEX,HASH             HASH OF INDEX                   48800019
*                                                                       48850019
ASSEM5   EQU   *                                                        48900019
*                                                                       48950019
         OI    RAFLG,ASSEMBLE           SET FLAG TO INDICATE ASSEMBLING 49000019
*                                            IN PROCESS                 49200019
         SR    AWORKR,AWORKR            CLEAR REG                       49400019
         IC    AWORKR,RAINDEX           GET INDEX TO RECORD IN R.A.     49600019
         LA    RPARA1,RAALIGN           GET ADDR OF ALIGNMENT AREA      49800019
         AR    RPARA1,AWORKR            POINT TO BEGINNING OF DATA      50000019
         ST    RECADR,DCBRECAD          SAVE RECADR IN DCB              50300019
*                                                                       50600019
         BAL   RETR,MOVERTN             BRANCH TO MOVE ROUTINE          50800019
*                                                                       51000019
         L     RECADR,DCBRECAD          RELOAD RECADR                   51100019
         SR    AWORKR,AWORKR            CLEAR REG                       51200019
         IC    AWORKR,RAINDEX           GET OFFSET TO RECORD            51400019
         LA    RPARA0,RAALIGN           POINT TO ALIGNMENT AREA         51600019
         AR    AWORKR,RPARA0            GET ADDR OF RECORD              51800019
*                                                                       51840019
         CLC   CNTLEN(CNTLEN,AWORKR),ZERO CONTROL CODE ZERO             51880019
         BE    ASSEM6                   BRANCH YES TO SET NON SPANNED   51920019
*                                            BIT                        51960019
         XC    CNTLEN(CNTLEN,AWORKR),CNTLEN(AWORKR) CLEAR CONTROL CODE  52000019
*                                                                       52200019
         LR    RECADR,EOBADR            FORCE END OF BLOCK CONDITION    52400019
         B     VREGL030                 BRANCH TO GET NEXT SEGMENT,     52600019
*                                            THIS WILL CAUSE EOB.       52800019
ASSEM6   EQU   *                                                        52840019
*                                                                       52880019
         OI    RAFLG,NONSPAN            SET NON SPANNED RECORD BIT      52920019
         B     ASSEM3                   SET UP TO RETURN TO USER        52960019
*********************************************************************** 53000019
*                                                                       53200019
ASSEM2   EQU   *                                                        53400019
*                                                                       53600019
* AT THIS POINT, EOBADR - NEW EOB ADDR                                  53800019
*                RECADR - ADDR OF FIRST SEGMENT IN BLOCK                54000019
*                LRECLR - LENGTH OF THIS SEGMENT                        54200019
*                                                                       54400019
* REGS FREE TO BE USED ARE - RPARA0, RPARA1, WORKR, AWORKR, AND BWORKR  54600019
*                                                                       54800019
         L     WORKR,DCBBUFCB           GET BUFCB ADDR                  55000019
         LA    WORKR,NULL(WORKR)        CLEAR HI ORDER BYTE             55200019
         L     WORKR,DBLWD(WORKR)       OFFSET TO RECORD AREA ADDR      55400019
*                                                                       55600019
* REGISTER USAGE -  WORKR - BASE REG FOR RECORD AREA                    55800019
*                   RECADR - ADDR OF RECORD IN BUFFER                   56000019
*                   RPARA1 - ADDR OF RECORD IN RECORD AREA              56200019
*                   AWORKR - WORK REG                                   56400019
*                   BWORKR - WORK REG                                   56600019
*                                                                       56800019
         SR    AWORKR,AWORKR            CLEAR REG                       57000019
         IC    AWORKR,RAINDEX           GET OFFSET TO RECORD            57200019
         LA    BWORKR,RAALIGN           POINT TO ALIGNMENT AREA         57400019
         AR    BWORKR,AWORKR            GET ADDR OF RECORD              57600019
*                                                                       57800019
         IC    AWORKR,NULL(BWORKR)      GET 1ST BYTE OF LL              57900019
         SLL   AWORKR,DBLWD             AWORKR = 00L0                   58000019
         IC    AWORKR,BYTE(BWORKR)      AWORKR = 00LL                   58100019
         LA    RPARA1,NULL(AWORKR,BWORKR) GET TO END OF RECORD SEGMENT  58200019
         LA    RPARA0,WORD(RECADR)      GET ADDR OF DATA                58400019
*                                                                       58600019
         SH    LRECLR,CONST4            NUMBER OF BYTES OF DATA TO MOVE 58800019
         AR    AWORKR,LRECLR            INCREMENT LL IN R.A.            59000019
         STC   AWORKR,BYTE(BWORKR)      STORE UPDATED 000L IN R. A.     59080019
         SRL   AWORKR,DBLWD             AWORKR = 000L                   59160019
         STC   AWORKR,NULL(BWORKR)      STORE UPDATED 00LL IN R. A.     59240019
         ST    RECADR,DCBRECAD          SAVE RECADR IN DCB              59320019
         LR    RECADR,RPARA0            LOAD ADDR OF RECORD IN RECADR   59360019
*                                                                       59400019
*        THE FOLLOWING CHECK WILL INSURE THAT THE RECORD BEING          59450003
*        ASSEMBLED WILL FIT WITHIN THE RECORD AREA BEFORE ANY MOVE      59500003
*        IS DONE. IF NOT A S002 ABEND WILL RESULT.                      59550003
*                                                                       59560003
         SR    AWORKR,AWORKR            CLEAR WORK REG          XA02723 59570003
         IC    AWORKR,RAINDEX           GET OFFSET TO RECORD    XA02723 59580003
         LA    AWORKR,RAALIGN-RCDAREA(AWORKR) ADD ALIGN LENGTH  XA02723 59590003
         AH    AWORKR,NULL(BWORKR)      ADD CURRENT RECORD LNGTHXA02723 59592003
         C     AWORKR,RALNG             IS IT LONGER THAN AREA  XA02723 59594003
         BH    EXIT4                    YES ABEND S002          XA02723 59596003
         BAL   RETR,MOVERTN             BRANCH TO MOVE ROUTINE          59600019
*                                                                       59800019
         L     RECADR,DCBRECAD          RELOAD RECADR                   59900019
         TM    FLGOFST(RECADR),FIRSTSEG ANY SEGMENT FOLLOWING           60000019
         BZ    ASSEM3                   BRANCH NO TO SET UP FOR RETURN  60200019
*                                                                       60400019
         SR    LRECLR,LRECLR            CLEAR REG                       60480019
         IC    LRECLR,NULL(RECADR)      GET 1ST BYTE OF LL              60560019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   60640019
         IC    LRECLR,BYTE(RECADR)      LRECLR = 00LL                   60720019
         B     VREGL020                 BRANCH TO GET NEXT SEGMENT      60800019
*                                                                       61000019
ASSEM3   EQU   *                                                        61200019
*                                                                       61400019
         SR    AWORKR,AWORKR            CLEAR REG                       61600019
         IC    AWORKR,RAINDEX           GET OFFSET TO RECORD            61800019
         LA    BWORKR,RAALIGN           POINT TO ALIGNMENT AREA         62000019
         AR    BWORKR,AWORKR            GET ADDR OF RECORD              62200019
*                                                                       62400019
         SR    LRECLR,LRECLR            CLEAR REG                       62480019
         IC    LRECLR,NULL(BWORKR)      GET 1ST BYTE OF LL              62560019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   62640019
         IC    LRECLR,BYTE(BWORKR)      LRECLR = 00LL                   62720019
         ST    BWORKR,REG1(SAVR)        SET PARAMETER FOR USER          62800019
*                                                                       63000019
         OI    NULL(IOBAR),SPANFLG      SET SPANNED FLAG ON             63200019
         B     RETURN                   BRANCH TO RETURN TO USER        63400019
*                                                                       63600019
*********************************************************************** 63800019
*                                                                       64000019
* RECADR - ADDR OF DATA TO BE MOVED                                     64200019
* RPARA1 - ADDR OF AREA TO WHICH DATA IS MOVED                          64400019
* LRECLR - LENGTH OF DATA TO BE MOVED                                   64600019
*                                                                       64800019
MOVERTN  EQU   *                                                        65000019
*                                                                       65200019
         B     SMOVE                    BRANCH TO MOVE                  65400019
*                                                                       65600019
MOVE     MVC   NULL(NULL,RPARA1),NULL(RECADR) MOVE LESS THAN 256 BYTES  65800019
*                                                                       66000019
MOVE256  MVC   NULL(FFF,RPARA1),NULL(RECADR) MOVE 256 BYTES             66200019
*                                                                       66400019
         LA    RECADR,FFF(RECADR)       ADD 256 TO ADDR OF DATA         66600019
         LA    RPARA1,FFF(RPARA1)       ADD 256 TO ADDR OF AREA         66800019
*                                                                       67000019
SMOVE    EQU   *                                                        67100019
*                                                                       67200019
         SH    LRECLR,CONST256          SUBTRACT 256                    67300019
         BH    MOVE256                  LOOP IF MORE THAN 256           67400019
*                                                                       67600019
         AH    LRECLR,CONST255          CORRECT TO ORIGINAL LENGTH      67800019
         EX    LRECLR,MOVE              MOVE REST OF BYTES              68000019
*                                                                       68200019
         BR    RETR                     RETURN TO MAIN LINE             68400019
*                                                                       68600019
*********************************************************************** 68800019
*                                                                       69000019
CONST4   DC    H'4'                     CONSTANT 4                      69200019
CONST255 DC    X'00FF'                  255 IN HEX                      69400019
CONST256 DC    X'0100'                  256 IN HEX                      69600019
ZERO     DC    X'00'                    ZERO CONSTANT                   69700019
*                                                                       69800019
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF WORD BOUNDARY   70000019
         CNOP  0,8                      FORCE ALIGNMENT                 70200019
*                                                                       70400019
*                                                                       70600019
         DCBD  DSORG=PS                                                 70800019
*                                                                       71000019
         DS    0D                       FORCE DOUBLE WORD BOUNDARY      71200019
RCDAREA  DSECT                          FORMAT OF RECORD AREA           71400019
RALNG    DS    CL4                      LENGTH OF RECORD AREA           71600019
RAFLG    DS    CL1                      FLAG BYTE                       71800019
RAINDEX  DS    CL1                      INDEX TO BEGINNING OF DATA      72000019
RADISPL  DS    CL2                      POSITION OF RECORD IN BLOCK     72200019
RATRKAD  DS    0CL8                     TRACK ADDRESS OF BEGINNING      72400019
*                                            SEGMENT OF RECORD          72600019
RAMBBCC  DS    CL5                      MBBCC OF TRACK ADDR (NOT USED   72800019
*                                            IF DCB IS FOR OUTPUT)      73000019
RARECAD  DS    CL3                      RECAD WHEN RECORD TO BE WRITTEN 73200019
*                                            REQUIRES SEGMENTATION      73400019
RANXTIOB DS    CL4                      NEXT IOB ADDRESS                73452019
RACOUNT  DS    CL2                      COUNT FIELD OF NUMBER OF BYTES  73460019
*                                            MOVED                      73470019
         DS    CL2                      RESERVED                        73480019
RAALIGN  DS    0CL8                     FLOATING ALIGNMENT AREA         73600019
RADATA   EQU   RAALIGN                  DATA                            73800019
         END                                                            74000019
