         TITLE 'IGG019BP - QSAM PUT/LOCATE VARIABLE LENGTH RECORD EXTEN*00200019
               TION LOGICAL RECORD INTERFACE'                           00400019
IGG019BP CSECT                                                          00600019
*                                                                       00800019
*********************************************************************** 01000019
*                                                                       01200019
*          RELEASE 20 DELETIONS                                       * 01400019
*3572                                                            A35349 01500020
*          RELEASE 21 DELETIONS                                       * 01600019
*0933276990,277530,277710                                        A37512 01700021
*09332400-333400                                                 A46886 01750021
*D276000,277170                                                 SA51137 01760021
*          RELEASE 22 DELETIONS                                       * 01800019
*          RELEASE 23 DELETIONS                                       * 02000019
*          RELEASE 24 DELETIONS                                       * 02200019
*          RELEASE 25 DELETIONS                                       * 02400019
*          RELEASE 26 DELETIONS                                       * 02600019
*          RELEASE 27 DELETIONS                                       * 02800019
*          RELEASE 28 DELETIONS                                       * 03000019
*                                                                       03200019
*STATUS CHANGE LEVEL 003                                                03400021
*                                                                       03600019
*FUNCTION/OPERATION - THIS ROUTINE WILL PROCESS VARIABLE SPANNED        03800019
*        RECORDS.                                                       04000019
*        PUT ROUTINE PROVIDES THE ADDRESS OF AN AREA LARGE ENOUGH TO    04200019
*        CONTAIN THE NEXT OUTPUT RECORD.                                04400019
*        TRUNC ROUTINE CAUSES THE CURRENT OUTPUT BUFFER TO BE REGARDED  04600019
*        AS FULL.                                                       04800019
*                                                                       05000019
*ENTRY POINTS                                                           05200019
*        ENTRY 1         ENTRY 2                                        05400019
*        PUT             TRUNC                                          05600019
*        LA    1,DCB     LA   1,DCB                                     05800019
*        L     15,48(1)  L    15,48(1)                                  06000019
*        BALR  14,15     BAL  14,8(15)                                  06200019
*                                                                       06400019
*INPUT   FROM PROBLEM PROGRAM                                           06600019
*        REG   13   USER WORK-SAVE AREA ADDRESS                         06800019
*        REG   14   RETURN ADDRESS OF USER                              07000019
*        REG   15   THIS ROUTINE INITIAL BASE REG                       07200019
*        REG   1    DCB ADDRESS                                         07400019
*                                                                       07600019
*OUTPUT                                                                 07800019
*        REG   1    ADDRESS OF NEXT FREE SPACE WITHIN BUFFER            08000019
*                   ADDRESS OF RECORD AREA IF OUTPUT RECORD NEEDS       08200019
*                   SEGMENTATION                                        08400019
*                                                                       08600019
*EXTERNAL ROUTINES                                                      08800019
*        IECQPERR-OUTPUT ERROR ROUTINE DETECTS SYNCHRONOUS ERRORS FOR   09000019
*        USER,ACCESSES NEW BUFFERS                                      09200019
*        DEVICE DEPENDENT END-OF-BLOCK ROUTINE SCHEDULES OUTPUT         09400019
*                                                                       09600019
*EXITS   EXIT 1 NORMAL RETURN TO USER BY BCR 15,14                      09800019
*        EXIT 2 ENTERS EOB ROUTINE BY BALR 14,15                        10000019
*        EXIT 3 ENTERS ERROR ROUTINE BY BALR 14,15                      10200019
*                                                                       10400019
*TABLES/WORKAREAS                                                       10600019
*        IOB, USER WORK-SAVE AREA, RECORD AREA                          10800019
*        DCB-FIELDS USED ARE BLKSI,EOB,EOBAD,IOBA,LRECL,OFFSW,PERR,     11000019
*        RECAD,RECFM                                                    11200019
*                                                                       11400019
*ATTRIBUTES                                                             11600019
*         REENTRANT,PROBLEM PROGRAM MODE                                11800019
*                                                                       12000019
*********************************************************************** 12200019
*                                                                       12400019
RPARA0   EQU   0                        WORK AREA                       12600019
RPARA1   EQU   1                        SLOT POINTER                    12800019
DCBR     EQU   2                        DCB                             13000019
IOBAR    EQU   3                        IOB                             13200019
EOBADR   EQU   4                        EOB                             13400019
RECADR   EQU   5                        RECORD                          13600019
LRECLR   EQU   6                        SIX                             13800019
WORKR    EQU   7                        SEVEN                           14000019
BASR     EQU   8                        BASE REG.                       14200019
AWORKR   EQU   9                        WORK REG                        14400019
BWORKR   EQU   10                       WORK REG                        14600019
SAVR     EQU   13                       SAVE AREA                       14800019
RETR     EQU   14                       RETURN POINTER                  15000019
ENTRYR   EQU   15                       ENTRY POINTER                   15200019
*                                                                       15400019
SPTRUNC  EQU   X'80'                    TRUNC ON SPANNED RECORD FLAG    15500019
SPANFLG  EQU   X'04'                    SPANNED RECORD FLAG IN IOB      15600019
PRIME    EQU   X'40'                    FIRST ENTRY FROM OPEN           15700019
FLGOFST  EQU   2                        CONTROL CODE OFFSET             15800019
FIRSTSEG EQU   X'01'                    FIRST SEGMENT OF RECORD         16000019
LASTSEG  EQU   X'02'                    LAST SEGMENT OF SPANNED RECORD  16200019
MIDSEG   EQU   X'03'                    MIDDLE SEGMENT OF RECORD        16400019
ASSEMBLE EQU   X'01'                    ASSEMBLING IN PROCESS           16600019
SEGMENT  EQU   X'10'                    SEGMENTATION IN PROCESS         16800019
HASH     EQU   X'07'                    HASHING FACTOR                  17000019
SAOFF    EQU   20                       SAVE AREA OFFSET                17200019
REG1     EQU   32                       REGISTER 1 OFFSET FROM SAVEAREA 17400019
REG3     EQU   8                        REG 3 OFFSET FROM SAVEAREA      17460019
REG5     EQU   48                       REG 5 OFFSET FROM SAVEAREA      17520019
REG9OFST EQU   64                       REG 9 OFFSET FROM SAVE AREA     17600019
CNTLEN   EQU   2                        LENGTH OF COUNT FIELD           17800019
WRTLEN   EQU   6                        WRITE CCW COUNT FIELD           18000019
CNTRLLEN EQU   20                       CONTROL INFORMATION LENGTH      18010019
NULL     EQU   0                        ZERO DISPLACEMENT               18200019
BYTE     EQU   1                        ONE BYTE DISPLACEMENT           18400019
WORD     EQU   4                        WORD DISPLACEMENT               18600019
DBLWD    EQU   8                        DOUBLE WORD DISPLACEMENT        18800019
ADLEN    EQU   3                        ADDRESS LENGTH                  19000019
FFF      EQU   256                      256                             19200019
TWOBYTE  EQU   16                       SHIFT CONSTANT                  19300019
ASAMCC   EQU   X'06'                    MASK, CONTROL CHARACTER  A35349 19350020
NOT      EQU   X'FF'                    MASK                            19400019
NEWBUF   EQU   X'80'                    NEW BUFFER INDICATOR            19600019
BLOCKBIT EQU   X'10'                    BLOCKED RECORD                  19800019
WBIT     EQU   X'40'                    WRITE BIT                       20000019
COMPLETE EQU   X'60'                    COMPLETION                      20200019
OUTPUT   EQU   X'80'                    OUTPUT BIT                      20400019
CLOSEB   EQU   X'20'                    CLOSE IN PROCESS                20500019
*                                                                       20520019
COBOL    EQU   X'40'                    COBOL BIT IN R. A.              20540019
NONSPAN  EQU   X'04'                    NON SPANNED RECORD IN R. A.     20560019
*                                                                       20600019
         USING IGG019BP,ENTRYR          ESTABLISH BASE REG              20800019
         USING IHADCB,RPARA1            ADDRESSIBILITY FOR DCB          21000019
*                                                                       21200019
ENTRY1   B     START                    TO START THE PUT PROCESS        21400019
         DC    X'00000000'              CONSTANT ZERO                   21600019
*                                                                       21800019
ENTRY2   EQU   *                                                        22000019
*                                                                       22200019
         ST    IOBAR,REG3(SAVR)         SAVE REG. 3                     22209019
         L     IOBAR,DCBIOBA            GET IOB ADDR                    22218019
         TM    NULL(IOBAR),SPANFLG      SPANNED RECORD WRITTEN          22227019
         BNO   TRUNC2                   BRANCH IF NOT TO NORMAL TRUNC   22236019
*                                                                       22245019
         STM   RETR,BWORKR,SAOFF(SAVR)  SAVE REGS                       22254019
         LR    BASR,ENTRYR              LOAD BASE REG                   22263019
         LR    DCBR,RPARA1              DCB ADDRESSIBILITY              22272019
         LM    IOBAR,RECADR,DCBIOBA     LOAD WORK REGS                  22281019
         MVC   DCBPRECL,NULL(RECADR)    SAVE LL OF SPANNED RECORD       22290019
         OI    DCBRECAD,SPTRUNC         SET SPANNED RECORD TRUNC FLAG   22299019
         SR    WORKR,WORKR              CLEAR REG                       22300019
         IC    WORKR,DCBOFFSW           CCW OFFSET                      22301019
         B     VREPL070                 BRANCH TO SEGMENT SPAN RECORD   22308019
*                                                                       22317019
TRUNC3   EQU   *                                                        22326019
*                                                                       22335019
         LR    ENTRYR,BASR              RESTORE BASE REG                22344019
         LR    RPARA1,DCBR              RESTORE BASE FOR DCB            22353019
         ST    RECADR,DCBRECAD          RECORD ADDR IN DCB              22362019
         LM    RETR,BWORKR,SAOFF(SAVR)  RESTORE USER REGS               22371019
*                                                                       22380019
TRUNC2   L     IOBAR,REG3(SAVR)         RESTROE REG 3                   22389019
TRUNC    MVC   DCBEOBAD+BYTE(ADLEN),DCBRECAD+BYTE FORCE EOB ON NEXT PUT 22400019
         BR    RETR                     RETURN                          22600019
*                                                                       22800019
START    EQU   *                                                        23000019
*                                                                       23200019
         DROP  ENTRYR                   DROP BASE                       23400019
         DROP  RPARA1                   DROP BASE                       23600019
*                                                                       23800019
         USING IGG019BP,BASR            ESTABLISH BASE REG              24000019
         USING IHADCB,DCBR              ADDRESSIBILITY FOR DCB          24200019
         USING RCDAREA,WORKR            ADDRESSIBILITY FOR RECORD AREA  24400019
*                                                                       24600019
         STM   RETR,BWORKR,SAOFF(SAVR)  SAVE REGS                       24800019
         LR    BASR,ENTRYR              LOAD BASE REG                   25000019
         LR    DCBR,RPARA1              DCB ADDRESSIBILITY              25200019
         LM    IOBAR,RECADR,DCBIOBA     LOAD WORK REGS                  25400019
*                                                                       25600019
VREPL010 EQU   *                                                        25800019
*                                                                       26000019
         SR    WORKR,WORKR              CLEAR REG                       26200019
         IC    WORKR,DCBOFFSW           CCW OFFSET                      26400019
*                                                                       26600019
         MVC   DCBPRECL,NULL(RECADR)    SAVE LL OF LAST RECORD IN DCB   26800019
*                                                                       27000019
         TM    NULL(IOBAR),SPANFLG      LAST PUT NEEDS SEGMENTATION     27200019
         BO    VREPL070                 BRANCH IF YES TO SEGMENT        27400019
*                                                                       27600021
* EDIT USER LL. ALLOW ONLY IF ZERO OR AT LEAST FOUR BYTES. TAKE         27609021
* ASA/MCC CONTROL INTO CONSIDERATION.                                   27618020
* ALLOW:       -- LL GREATER THAN 4 IF ASA/MCC                  SA51137 27627021
*              -- LL EQUAL OR GREATER THAN 4 IF NO ASA/MCC      SA51137 27636021
* ABEND IF LL FAILS TESTS.                                              27645021
*                                                                       27654020
         LH    LRECLR,DCBPRECL          PERFORM TEST IN REGISTER A35349 27663020
         LTR   LRECLR,LRECLR            TEST LL IN REGISTER      A35349 27672020
         BP    LLTSTDTA                 TEST FOR DATA BYTES      A35349 27681020
         BZ    LLTESTOV                 IF ZERO, ACCEPT          A35349 27690020
         BM    ERREXIT                  GT 32,767 - ABEND        A37512 27699021
LLTSTDTA EQU   *                                                        27708021
         CH    LRECLR,RDWLEN            IS LL GREATER THAN 4    SA51137 27726021
         BH    LLTESTOV                 YES - ACCEPT             A35349 27735020
         TM    DCBRECFM,ASAMCC          IS CONTROL CHARACTER ON  A35349 27744020
         BM    ERREXIT                  NOT GT 4, ASA/MCC -     SA51137 27750021
*                                       ABEND                    A37512 27756021
         CH    LRECLR,CONST4            IS LL EQUAL 4           SA51137 27762021
         BNE   ERREXIT                  NOT EQ 4 - ABEND        SA51137 27771021
LLTESTOV EQU   *                        LL TESTS COMPLETED       A35349 27780020
         L     AWORKR,NULL(WORKR,IOBAR) GET BUFFER ADDRESS              27800019
         LH    BWORKR,NULL(AWORKR)      TOTAL LL OF BDW                 28000019
         AH    BWORKR,DCBPRECL          NEW TOTAL LL OF BDW             28200019
         STH   BWORKR,NULL(AWORKR)      UPDATE LL OF BDW                28400019
*                                                                       28600019
         LA    RECADR,NULL(BWORKR,AWORKR) GET POSSIBLE NEXT RECORD ADDR 28800019
*                                                                       29000019
         LR    RPARA0,RECADR            COPY RECADR                     29200019
         AH    RPARA0,MINSEG            ADD MIN. SEG. LENGTH            29400019
         CR    EOBADR,RPARA0            ENOUGH FOR MIN. SEG.            29600019
         BL    FULL                     BRANCH NO TO WRITE OUT BUFFER   29800019
*                                                                       30000019
         LR    RPARA0,RECADR            RELOAD ORIGINAL ADDR            30200019
         LH    LRECLR,DCBLRECL          ESTIMATED LENGTH TO PUT         30400019
         AR    RPARA0,LRECLR            ESTIMATED ENDING OF RECORD      30600019
         CR    EOBADR,RPARA0            WILL RECORD FIT IN BUFFER       30800019
         BL    VREPL030                 BRANCH IF NOT FIT               31000019
*                                                                       31200019
         TM    DCBRECFM,BLOCKBIT        IS IT BLOCKED RECORD            31400019
         BZ    FULL                     BRANCH IF UNBLOCKED             31600019
*                                                                       31800019
VREPL015 EQU   *                                                        32000019
*                                                                       32200019
         L     WORKR,DCBBUFCB           GET BUFCB ADDR                  32220019
         LA    WORKR,NULL(WORKR)        CLEAR HIGH ORDER BYTE           32240019
         L     WORKR,DBLWD(WORKR)       OFFSET TO RECORD AREA ADDR      32260019
         TM    RALNG,COBOL              COBOL BIT ON                    32280019
         MVI   RAFLG,NONSPAN            SET NON SPANNED RECORD BIT      32290019
         BO    VREPL050                 BRANCH YES TO PRESENT R. A.     32300019
*                                            ADDR                       32320019
         NI    RAFLG,NOT-NONSPAN        TURN OFF NON SPANNED RECORD BIT 32323019
*                                                                       32326019
EXIT1    EQU   *                                                        32330019
*                                                                       32340019
         NI    REG1(SAVR),NOT-NEWBUF    TURN OFF NEW BUFFER INDICATOR   32400019
         ST    RECADR,REG1(SAVR)        RECORD ADDR IN REG 1            32600019
         ST    RECADR,DCBRECAD          RECORD ADDR IN DCB              32800019
         MVC   NULL(WORD,RECADR),CONST0 INITIALIZE NEXT RDW      A35349 32900020
         LM    RETR,BWORKR,SAOFF(SAVR)  RESTORE USER REGS               33000019
         BR    RETR                     RETURN                          33200019
ERREXIT  EQU   *                                                 A37512 33220021
ABEND    L     RPARA1,CODE                                       A37512 33360021
         ABEND (1),DUMP                 ABEND CODE 002           A37512 33380021
*                                                                       33400019
*********************************************************************** 33600019
*                                                                       33800019
VREPL030 EQU   *                                                        34000019
*                                                                       34200019
         CLI   DCBRECAD,PRIME           FIRST ENTRY FROM OPEN           34220019
         BNE   VREPL035                 BRANCH TO CONTINUE PROCESSING   34240019
*                                                                       34260019
         OI    REG1(SAVR),NEWBUF        SET NEW BUFFER INDICATOR        34280019
*                                                                       34300019
VREPL035 EQU   *                                                        34320019
*                                                                       34340019
         TM    REG1(SAVR),NEWBUF        IS THIS A NEW BUFFER            34400019
         BO    VREPL050                 BRANCH IF YES TO SAVE RECAD     34600019
*                                                                       34800019
         TM    DCBRECFM,BLOCKBIT        IS IT BLOCKED RECORD            35000019
         BO    VREPL050                 BRANCH IF YES TO SAVE RECAD     35200019
*                                                                       35400019
FULL     EQU   *                                                        35600019
*                                                                       35800019
         CLC   NULL(CNTLEN,AWORKR),CONST4 LL GREATER THAN FOUR          36000019
         BNH   VREPL015                 UNBLOCKED RECORD EXIT HERE      36200019
*                                                                       36400019
         STH   BWORKR,WRTLEN(WORKR,IOBAR) TOTAL LL TO CCW               36600019
*                                                                       36800019
**********************************************************************  37000019
*                                                                       37200019
EXIT2    L     ENTRYR,DCBEOB            EOB ADDR                        37400019
         OI    NULL(IOBAR),WBIT         TURN ON WRITE BIT               37600019
         OI    DCBOFLGS,OUTPUT          INDICATE OUTPUT IN DCB          37800019
         LM    AWORKR,BWORKR,REG9OFST(SAVR) RESTORE REGISTERS           38000019
         BALR  RETR,ENTRYR              TO EOB ROUTINE                  38200019
*                                                                       38400019
*********************************************************************   38600019
*                                                                       38800019
EXIT3    L     ENTRYR,DCBPERR           ERROR ROUTINE ADDR              39000019
         BALR  RETR,ENTRYR              TO ERROR ROUTINE                39200019
*                                                                       39400019
*********************************************************************** 39600019
*                                                                       39800019
*                          REINITILIZE DCB                            * 40000019
*                                                                       40200019
*********************************************************************** 40400019
*                                                                       40600019
         STM   AWORKR,BWORKR,REG9OFST(SAVR) SAVE USER REGISTERS         40800019
*                                                                       41000019
         XC    NULL(DBLWD,RECADR),NULL(RECADR) ZERO BDW AND FIRST SDW   41200019
         MVC   NULL(CNTLEN,RECADR),CONST4 SET NEW BDW TO FOUR           41210019
         LH    EOBADR,DCBBLKSI          MAX. PHYSICAL RECORD LENGTH     41600019
         AR    EOBADR,RECADR            NEW EOB ADDRESS                 41800019
         LA    RECADR,WORD(RECADR)      NEW RECORD ADDR                 42000019
         OI    REG1(SAVR),NEWBUF        SET NEW BUFFER INDICATOR        42200019
         STM   IOBAR,RECADR,DCBIOBA     REINITIALIZE DCB                42400019
         B     VREPL010                 BRANCH BACK TO RE-COMPARE       42600019
*                                                                       42800019
VREPL050 EQU   *                                                        43000019
*                                                                       43200019
*********************************************************************** 43400019
*                                                                       43600019
* ESTIMATED RECORD REQUIRES SEGMENTATION.                               43800019
* NEED TO SAVE PRESENT RECORD ADDRESS.                                  44000019
* RETURN ADDRESS OF RECORD AREA IN REGISTER 1 TO USER                   44200019
*                                                                       44400019
*********************************************************************   44600019
*                                                                       44800019
         L     WORKR,DCBBUFCB           GET BUFCB ADDR                  45000019
         LA    WORKR,NULL(WORKR)        CLEAR HI ORDER BYTE             45200019
         L     WORKR,DBLWD(WORKR)       OFFSET TO RECORD AREA ADDR      45400019
*                                                                       45600019
         TM    RALNG,COBOL              COBOL BIT ON                    45620019
         BZ    VREPL055                 BRANCH NO TO SET ALIGNMENT      45640019
         MVC   RAINDEX,CONST4+BYTE      SET INDEX TO FOUR               45660019
         B     VREPL060                 BRANCH TO SET UP FOR RETURN     45700019
*                                                                       45720019
VREPL055 EQU   *                                                        45740019
*                                                                       45760019
         STC   RECADR,RAINDEX           LOW ORDER BYTE USED AS INDEX    45800019
         NI    RAINDEX,HASH             HASH OF INDEX                   46000019
*                                                                       46060019
VREPL060 EQU   *                                                        46120019
*                                                                       46200019
         ST    RECADR,RARECAD-BYTE      SAVE RECAD IN R.A. FOR NEXT PUT 46400019
         SR    RPARA0,RPARA0            CLEAR REG                       46600019
         IC    RPARA0,RAINDEX           GET INDEX TO RECORD IN R.A.     46800019
         LA    RECADR,RAALIGN           GET ADDR OF ALIGNMENT AREA      47000019
         AR    RECADR,RPARA0            POINT TO BEGINNING OF RECORD    47200019
         OI    NULL(IOBAR),SPANFLG      SET SPANNED FLAG ON             47400019
         B     EXIT1                    BRANCH TO RETURN TO USER        47600019
*                                                                       47800019
VREPL070 EQU   *                                                        48000019
*                                                                       48200019
*********************************************************************** 48400019
*                                                                       48600019
* A RECORD REQUIRED SEGMENTATION.                                       48800019
* NEED TO RESTORE RECORD ADDRESS.                                       49000019
*                                                                       49200019
*********************************************************************** 49400019
*                                                                       49600019
         NI    NULL(IOBAR),NOT-SPANFLG  TURN OFF SPANNED FLAG           49800019
         LR    RPARA0,RECADR            LOAD RECORD AREA ADDR IN WORK   50000019
*                                            REG                        50200019
         L     RECADR,NULL(WORKR,IOBAR) RESTORE RECORD ADDR IN BUFFER   50210019
         LA    RECADR,NULL(RECADR)                                      50220019
         AH    RECADR,NULL(RECADR)                                      50230019
         L     WORKR,DCBBUFCB           GET BUFCB ADDR                  50400019
         LA    WORKR,NULL(WORKR)        CLEAR HI ORDER BYTE             50600019
         L     WORKR,DBLWD(WORKR)       OFFSET TO RECORD AREA ADDR      50800019
*                                                                       51000019
         MVI   RAFLG,SEGMENT            SET FLAG TO INDICATE SEGMENTING 51200019
*                                            IN PROCESS                 51400019
*                                                                       51800019
         TM    DCBRECAD,SPTRUNC         SPANNED RECORD BEING TRUNC      51820019
         BNO   VREPL075                 BRANCH IF NOT TO NORMAL PROCESS 51840019
*                                                                       51860019
         OI    RAFLG,SPTRUNC            SET FLAG IN R. A. FOR TRUNC     51880019
*                                                                       51900019
VREPL075 EQU   *                                                        51920019
*                                                                       51940019
         TM    RAFLG,NONSPAN            NON SPANNED RECORD IN R. A.     51960019
         BO    VREPL130                 BRANCH YES TO MOVE RECORD BACK  51970019
*                                            TO BUFFER                  51980019
         LR    LRECLR,EOBADR            COPY EOBADR                     52000019
         SR    LRECLR,RECADR            GET AVAILABLE LENGTH IN BUFFER  52200019
         CH    LRECLR,DCBPRECL          DOES ACTUAL RECORD WRITTEN FIT  52210019
         BNL   VREPL130                 BRANCH IF YES                   52220019
*                                                                       52230019
         LR    RPARA1,LRECLR            SAVE LRECLR                     52231019
         STC   LRECLR,BYTE(RECADR)      STORE 000L IN SDW               52240019
         SRL   LRECLR,DBLWD             LRECLR = 000L                   52250019
         STC   LRECLR,NULL(RECADR)      STORE 00LL IN SDW               52260019
         XC    CNTLEN(CNTLEN,RECADR),CNTLEN(RECADR) ZERO NEXT TWO BYTES 52270019
*                                            IN SDW                     52280019
         MVI   FLGOFST(RECADR),FIRSTSEG SET FIRST SEGMENT FLAG          52600019
*                                                                       52800019
VREPL080 EQU   *                                                        52860019
*                                                                       52920019
         LR    LRECLR,RPARA1            RESTORE LRECLR                  52930019
         LA    RPARA1,WORD(RECADR)      POINT TO ADDR OF DATA IN BUFFER 53200019
*                                                                       53220019
         ST    RECADR,DCBRECAD          SAVE RECADR IN DCB              53260019
         LR    RECADR,RPARA0            LOAD ADDR OF RECORD IN RECADR   53280019
         LA    RECADR,WORD(RECADR)      GET ADDR OF DATA IN R.A.        53300019
         SH    LRECLR,CONST4            NUMBER OF BYTES OF DATA TO MOVE 53400019
*                                                                       53600019
         BAL   RETR,MOVERTN             BRANCH TO MOVE ROUTINE          53800019
*                                                                       54000019
         L     RECADR,DCBRECAD          RELOAD RECADR                   54100019
         SR    LRECLR,LRECLR            CLEAR REG                       54110019
         IC    LRECLR,NULL(RECADR)      GET 1ST BYTE OF LL              54120019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   54130019
         IC    LRECLR,BYTE(RECADR)      LRECLR =00LL                    54140019
*                                                                       54400019
VREPL090 EQU   *                                                        54600019
*                                                                       54800019
         LH    BWORKR,DCBPRECL          GET LL OF RECORD IN R.A.        55000019
         SR    BWORKR,LRECLR            DECREMENT LL OF RECORD          55200019
         BZ    VREPL120                 BRANCH IF REMAINDER IS ZERO     55400019
*                                                                       55600019
         LR    BWORKR,LRECLR            COPY LRECLR                     55800019
         SH    BWORKR,CONST4            GET TOTAL DATA MOVED            56000019
         STH   BWORKR,RACOUNT           SAVE TOTAL DATA MOVED IN        56200019
*                                            RACOUNT FIELD              56400019
         SR    LRECLR,LRECLR            CLEAR REG                       56610019
         IC    LRECLR,NULL(RECADR)      GET 1ST BYTE OF LL              56620019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   56630019
         IC    LRECLR,BYTE(RECADR)      LRECLR =00LL                    56650019
*                                                                       56800019
         SR    RPARA1,RPARA1            CLEAR REG                       57000019
         IC    RPARA1,DCBOFFSW          CCW OFFSET                      57200019
         L     AWORKR,NULL(RPARA1,IOBAR) GET BUFFER ADDRESS             57400019
         LH    BWORKR,NULL(AWORKR)      TOTAL LL OF BDW                 57600019
         AR    BWORKR,LRECLR            NEW TOTAL LL OF BDW             57800019
         STH   BWORKR,NULL(AWORKR)      UPDATE LL OF BDW                58000019
         STH   BWORKR,WRTLEN(RPARA1,IOBAR) TOTAL LL TO CCW              58200019
*                                                                       58400019
         L     ENTRYR,DCBEOB            EOB ADDR                        58600019
         OI    NULL(IOBAR),WBIT         TURN ON WRITE BIT               58800019
         OI    DCBOFLGS,OUTPUT          INDICATE OUTPUT IN DCB          59000019
         LM    AWORKR,BWORKR,REG9OFST(SAVR) RESTORE REGS                59200019
*                                                                       59210019
         SR    WORKR,WORKR              CLEAR REG                       59220019
         IC    WORKR,DCBOFFSW           CCW OFFSET                      59230019
         BALR  RETR,ENTRYR              TO EOB ROUTINE                  59400019
*                                                                       59600019
         L     ENTRYR,DCBPERR           ERROR ROUTINE ADDR              59800019
         BALR  RETR,ENTRYR              TO ERROR ROUTINE                60000019
*                                                                       60200019
         STM   AWORKR,BWORKR,REG9OFST(SAVR) SAVE USER REGS              60400019
*                                                                       60600019
         L     WORKR,DCBBUFCB           GET BUFCB ADDR                  60610019
         LA    WORKR,NULL(WORKR)        CLEAR HIGH ORDER BYTE           60620019
         L     WORKR,DBLWD(WORKR)       OFFSET TO RECORD AREA ADDR      60630019
*                                                                       60640019
         XC    NULL(DBLWD,RECADR),NULL(RECADR) ZERO BDW AND FIRST SDW   60800019
         MVC   NULL(CNTLEN,RECADR),CONST4 SET NEW BDW TO FOUR           61000019
         LH    EOBADR,DCBBLKSI          MAX. PHYSICAL RECORD LENGTH     61200019
         AR    EOBADR,RECADR            NEW EOB ADDR                    61400019
         LA    RECADR,WORD(RECADR)      NEW RECORD ADDR                 61600019
         STM   IOBAR,RECADR,DCBIOBA     REINITIALIZE DCB                61800019
*                                                                       62000019
         SR    AWORKR,AWORKR            CLEAR REG                       62200019
         IC    AWORKR,RAINDEX           OBTAIN OFFSET TO RECORD         62400019
         LA    RPARA0,RAALIGN           POINT TO ALIGNMENT AREA         62600019
         AR    AWORKR,RPARA0            GET ADDR OF RECORD              62800019
         LH    BWORKR,RACOUNT           GET NUMBER OF BYTES MOVED       63000019
         LA    AWORKR,WORD(BWORKR,AWORKR) GET ADDR OF DATA IN R.A.      63200019
*                                                                       63400019
         LR    RPARA1,RECADR            COPY RECADR                     63600019
         LH    LRECLR,DCBPRECL          GET TOTAL LL OF RECORD          63800019
         SR    LRECLR,BWORKR            SUBTRACT DATA MOVED             64000019
         AR    RPARA1,LRECLR            ESTIMATED ENDING OF SEGMENT     64200019
         CR    EOBADR,RPARA1            WILL SEGMENT FIT IN BUFFER      64400019
         BNL   VREPL110                 BRANCH IF SEGMENT FIT           64600019
*                                                                       64800019
         LH    LRECLR,DCBBLKSI          SET LL TO BLKSIZE               65000019
         SH    LRECLR,CONST4                 MINUS FOUR                 65200019
*                                                                       65400019
         LR    RPARA1,LRECLR            SAVE LRECLR                     65410019
         STC   LRECLR,BYTE(RECADR)      STORE 000L IN SDW               65500019
         SRL   LRECLR,DBLWD             LRECLR = 000L                   65510019
         STC   LRECLR,NULL(RECADR)      STORE 00LL IN SDW               65511019
         XC    CNTLEN(CNTLEN,RECADR),CNTLEN(RECADR) ZERO NEXT TWO BYTES 65512019
*                                            IN SDW                     65513019
         MVI   FLGOFST(RECADR),MIDSEG   SET MIDDLE SEGMENT FLAG         65520019
*                                                                       65550019
VREPL100 EQU   *                                                        65600019
*                                                                       65800019
         LR    LRECLR,RPARA1            RESTORE LRECLR                  65810019
         SH    LRECLR,CONST4            NUMBER OF DATA TO BE MOVED      66600019
         LA    RPARA1,WORD(RECADR)      POINT TO ADDR OF DATA IN BUFFER 66800019
*                                                                       66840019
         ST    RECADR,DCBRECAD          SAVE RECADR IN DCB              66920019
         LR    RECADR,AWORKR            LOAD ADDR OF RECORD IN RECADR   66960019
*                                                                       67000019
         BAL   RETR,MOVERTN             BRANCH TO MOVE ROUTINE          67200019
*                                                                       67400019
         L     RECADR,DCBRECAD          RELOAD RECADR                   67600019
         LH    BWORKR,RACOUNT           GET NUMBER OF BYTES MOVED       67800019
         SR    LRECLR,LRECLR            CLEAR REG                       68010019
         IC    LRECLR,NULL(RECADR)      GET 1ST BYTE OF LL              68020019
         SLL   LRECLR,DBLWD             LRECLR = 00L0                   68030019
         IC    LRECLR,BYTE(RECADR)      LRECLR =00LL                    68040019
         AR    LRECLR,BWORKR            UPDATE NUMBER OF BYTES MOVED    68200019
         B     VREPL090                 BRANCH TO CHECK IF ALL SEGMENTS 68400019
*                                            HAVE BEEN MOVED            68600019
*                                                                       68800019
VREPL110 EQU   *                                                        69000019
*                                                                       69200019
         LR    RPARA1,LRECLR            SAVE LRECLR                     69201019
         STC   LRECLR,BYTE(RECADR)      STORE 000L IN SDW               69210019
         SRL   LRECLR,DBLWD             LRECLR = 000L                   69220019
         STC   LRECLR,NULL(RECADR)      STORE 00LL IN SDW               69230019
         XC    CNTLEN(CNTLEN,RECADR),CNTLEN(RECADR) ZERO NEXT TWO BYTES 69240019
*                                            IN SDW                     69250019
         MVI   FLGOFST(RECADR),LASTSEG  SET LAST SEGMENT FLAG           69400019
         B     VREPL100                 BRANCH TO MOVE RECORD           69600019
*                                                                       69620019
VREPL120 EQU   *                                                        69640019
*                                                                       69660019
         TM    RAFLG,SPTRUNC            SPANNED RECORD BEING TRUNC      69685019
         BO    VREPL125                 BRANCH YES TO RETURN TO TRUNC   69690019
*                                                                       69695019
         XC    RAFLG(CNTRLLEN),RAFLG    CLEAR CONTROL INFO IN RA        69701019
         B     VREPL010                 BRANCH TO UPDATE BDW            69720019
*                                                                       69726019
VREPL125 EQU   *                                                        69732019
*                                                                       69738019
         XC    RAFLG(CNTRLLEN),RAFLG    CLEAR CONTROL INFO IN RA        69745019
         B     TRUNC3                   RETURN TO TRUNC                 69750019
*                                                                       69828019
VREPL130 EQU   *                                                        69834019
*                                                                       69840019
         LH    LRECLR,DCBPRECL          LOAD ACTUAL LENGTH OF RECORD    69860019
         LR    RPARA1,LRECLR            SAVE LRECLR                     69861019
         STC   LRECLR,BYTE(RECADR)      STORE 000L IN SDW               69870019
         SRL   LRECLR,DBLWD             LRECLR = 000L                   69871019
         STC   LRECLR,NULL(RECADR)      STORE 00LL IN SDW               69872019
         XC    CNTLEN(CNTLEN,RECADR),CNTLEN(RECADR) ZERO NEXT TWO BYTES 69873019
*                                            IN SDW                     69874019
         LTR   RPARA1,RPARA1            RECORD LENGTH = 0               69894019
         BZ    VREPL120                 BRANCH IF YES                   69914019
         B     VREPL080                 BRANCH TO MOVE ENTIRE RECORD    69940019
*                                                                       69960019
*********************************************************************** 70000019
*                                                                       70200019
* RECADR - ADDR OF DATA TO BE MOVED                                     70400019
* RPARA1 - ADDR OF AREA TO WHICH DATA IS MOVED                          70600019
* LRECLR - LENGTH OF DATA TO BE MOVED                                   70800019
*                                                                       71000019
MOVERTN  EQU   *                                                        71200019
*                                                                       71400019
         B     SMOVE                    BRANCH TO MOVE                  71600019
*                                                                       71800019
MOVE     MVC   NULL(NULL,RPARA1),NULL(RECADR) MOVE LESS THAN 256 BYTES  72000019
*                                                                       72200019
MOVE256  MVC   NULL(FFF,RPARA1),NULL(RECADR) MOVE 256 BYTES             72400019
*                                                                       72600019
         LA    RECADR,FFF(RECADR)       ADD 256 TO ADDR OF DATA         72800019
         LA    RPARA1,FFF(RPARA1)       ADD 256 TO ADDR OF AREA         73000019
*                                                                       73200019
SMOVE    EQU   *                                                        73300019
*                                                                       73400019
         SH    LRECLR,CONST256          SUBTRACT 256                    73500019
         BH    MOVE256                  LOOP IF MORE THAN 256           73600019
*                                                                       73800019
         AH    LRECLR,CONST255          CORRECT TO ORIGINAL LENGTH      74000019
         EX    LRECLR,MOVE              MOVE REST OF BYTES              74200019
*                                                                       74400019
         BR    RETR                     RETURN TO MAIN LINE             74600019
*                                                                       74800019
*********************************************************************** 75000019
*                                                                       75200019
         DS    0F                                                A37512 75210021
CODE     DC    X'00002000'                                       A37512 75220021
ONE      DC    X'0001'                                           A37512 75230021
CONST0   DC    F'0'                     CONSTANT ZEROES          A35349 75260020
RDWLEN   DC    H'4'                     LENGTH OF RECORD DES-   SA51137 75310021
*                                        CRIPTOR WORD           SA51137 75360021
CONST4   DC    H'4'                     CONSTANT 4                      75400019
CONST255 DC    X'00FF'                  255 IN HEX                      75600019
CONST256 DC    X'0100'                  256 IN HEX                      75800019
MINSEG   DC    H'5'                     NUMBER OF BYTES REQUIRED FOR    76000019
*                                            A SEGMENT                  76200019
*                                                                       76400019
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF WORD BOUNDARY   76600019
         CNOP  0,8                      FORCE ALIGNMENT                 76800019
*                                                                       77000019
*                                                                       77200019
         DCBD  DSORG=PS                                                 77400019
*                                                                       77600019
         DS    0D                       FORCE DOUBLE WORD BOUNDARY      77800019
RCDAREA  DSECT                          FORMAT OF RECORD AREA           78000019
RALNG    DS    CL4                      LENGTH OF RECORD AREA           78200019
RAFLG    DS    CL1                      FLAG BYTE                       78400019
RAINDEX  DS    CL1                      INDEX TO BEGINNING OF DATA      78600019
RADISPL  DS    CL2                      POSITION OF RECORD IN BLOCK     78800019
RATRKAD  DS    0CL8                     TRACK ADDRESS OF BEGINNING      79000019
*                                            SEGMENT OF RECORD          79200019
RAMBBCC  DS    CL5                      MBBCC OF TRACK ADDR (NOT USED   79400019
*                                            IF DCB IS FOR OUTPUT)      79600019
RARECAD  DS    CL3                      RECAD WHEN RECORD TO BE WRITTEN 79800019
*                                            REQUIRES SEGMENTATION      80000019
RANXTIOB DS    CL4                      NEXT IOB ADDRESS                80010019
RACOUNT  DS    CL2                      COUNT FIELD OF NUMBER OF BYTES  80020019
*                                            MOVED                      80030019
         DS    CL2                      RESERVED                        80040019
RAALIGN  DS    0CL8                     FLOATING ALIGNMENT AREA         80200019
RADATA   EQU   RAALIGN                  DATA                            80400019
         END                                                            80600019
