         TITLE 'IGG019BQ - QSAM UPDATE SYNCHRONIZING ROUTINE FOR VARIAB*00100019
               LE LENGTH RECORD EXTENTION'                              00200019
IGG019BQ CSECT                                                          00300019
*                                                                       00400019
*********************************************************************** 00500019
*                                                                       00600019
*          RELEASE 20 DELETIONS                                         00700019
*          RELEASE 21 CHANGES                                           00800021
*C115500                                                        SA63747 00810021
*A008500,115500-115600,420500,423500                            SM5235  00850021
*          RELEASE 21.8 CHANGES                                         00860021
*0429000                                                        SA67209 00870021
*A427500-427997,430600-430900                                   SA67209 00880021
*C430000                                                        SA67209 00890021
*          RELEASE 22 DELETIONS                                         00900019
*          RELEASE 23 DELETIONS                                         01000019
*          RELEASE 24 DELETIONS                                         01100019
*          RELEASE 25 DELETIONS                                         01200019
*          RELEASE 26 DELETIONS                                         01300019
*          RELEASE 27 DELETIONS                                         01400019
*          RELEASE 28 DELETIONS                                         01500019
*                                                                       01600019
*STATUS- CHANGE LEVEL 001                                               01700021
*                                                                       01800019
*MODULE TYPE- QSAM SUBROUTINE LOADED BY LINKAGE EDITOR                  01900019
*                                                                       02000019
*FUNCTION/OPERATION- THIS ROUTINE IS THE UPDATE BUFFER ACQUISTION AND   02100019
*      ERROR DETERMINATION ROUTINE.  IT ACQUIRES THE NEXT SEQUENTIAL    02200019
*      IOB AND WAITS FOR COMPLETION. IT TESTS THE PREVIOUS EXCP STATUS  02300019
*      FOR-  1)NORMAL COMPLETION RETURNS TO GET ROUTINE                 02400019
*            2)INCOMPLETION ISSUES SVC 1 TO WAIT                        02500019
*            3)ABNORMAL COMPLETION DETERMINES TYPE OF ERROR AND         02600019
*                  A)LINKS TO USERS SYNAD ROUTINE IF PRESENT            02700019
*                  B)PERFORMS ACCEPT, SKIP, OR TERMINATE OPTION AS      02800019
*                       SPECIFIED AND PREPARES IOB'S FOR RESCHEDULING.  02900019
*            IF END-OF-VOLUME CONDITION EXISTED, UPDATES ARE COMPLETED  03000019
*      ON THIS VOLUME PRIOR TO ISSUING SVC 55 TO SAM EOV EXECUTOR TO    03100019
*      PREPARE FOR VOLUME SWITCHING.                                    03200019
*                                                                       03300019
*OPTIONS SUPPLIED- 1) SKIP      - SELF EXPLANATORY                      03400019
*                  2) ACCEPT    - SELF EXPLANATORY                      03500019
*                  3) TERMINATE - IF NO SYNAD OR OPTIONS ARE SPECIFIED  03600019
*                                                                       03700019
*EXTERNAL REFERENCES- DCB, IOB, USERS SAVE AREA, RECORD AREA            03800019
*                                                                       03900019
*SUPERVISOR FUNCTIONS- EOV (SVC 55)                                     04000019
*                     ABEND (SVC 13)                                    04100019
*                     EXCP (SVC 0)                                      04200019
*                     WAIT (SVC 1)                                      04300019
*                                                                       04400019
*EXTERNAL ROUTINES- SAM DIAGNOSTIC ROUTINE FOR VOLUME SWITCHING         04500019
*                   UPDATE END-OF-BLOCK ROUTINE FOR BUFFER REINITIAL-   04600019
*                   IZATION                                             04700019
*                                                                       04800019
*ENTRY POINT - IGG019BQ FROM UPDATE GET ROUTINE (IGG019BN)              04900019
*              VIA BALR 14,15                                           05000019
*      REGISTER 2  DCB ADDRESS                                          05100019
*      REGISTER 3  ERROR IOB ADDRESS                                    05200019
*      REGISTER 13 USER SAVE AREA ADDRESS                               05300019
*      REGISTER 14 RETURN ADDRESS WITHIN QSAM ROUTINE                   05400019
*      REGISTER 15 IGG019BQ FIRST LOCATION ADDRESS                      05500019
*                                                                       05600019
*INPUT- SEE DESCRIPTION OF REGISTERS                                    05700019
*                                                                       05800019
*OUTPUT- SEE DESCRIPTION OF REGISTERS                                   05900019
*                                                                       06000019
*EXITS-NORMAL- WAIT BY SVC 1                                            06100019
*              QSAM BY BCR 15,14                                        06200019
*                                                                       06300019
*EXITS-ERROR- SAM DIAGNOSTIC BY SVC 55 FOR VOLUME SWITCHING             06400019
*             SYNAD BY BALR 14,15                                       06500019
*                                                                       06600019
*********************************************************************** 06700019
*                                                                       06800019
**                                                                      06900019
*                                                                       07000019
RPARA0   EQU   0                        PARAMETER REG 0                 07100019
RPARA1   EQU   1                        PARAMETER REG 1 AND IOB         07200019
DCBR     EQU   2                        DCBR REG                        07300019
IOBAR    EQU   3                        IOB  REG                        07400019
WORKR1   EQU   4                        ERR IOB NEXT COMMAND ADDR       07500019
WORKR2   EQU   5                        ERR IOB READ CCW OFFSET         07600019
WORKR3   EQU   6                        ENDING IOB IN RESCHEDULING LOOP 07700019
WORKR4   EQU   7                        READ CHANNEL PROG. POINTER      07800019
BASR     EQU   8                        BASE REG                        07900019
SAVR     EQU   13                       USERS SAVE AREA ADDR REG        08000019
RETR     EQU   14                       RETURN REG                      08100019
ENTR     EQU   15                       ENTRY REG                       08200019
*                                                                       08300019
**                                                                      08400019
*                                                                       08500019
COMPERR  EQU   X'7F'                    COMPLETE WITH NO ERROR MASK     08600019
READONLY EQU   X'20'                    IOB READ ONLY INDICATOR         08700019
UNITEXCP EQU   X'01'                    END OF VOLUME                   08800019
ACCEPTOP EQU   X'80'                    ACCEPT OPTION                   08900019
SKIPOP   EQU   X'40'                    SKIP OPTION                     09000019
CLOSEB   EQU   X'20'                    CLOSE IN PROCESS                09100019
NOT      EQU   X'FF'                    MASK                            09200019
EOVB     EQU   X'40'                    END OF VOLUME FLAG              09300019
FEOVB    EQU   X'02'                    FORCE END OF VOLUME BIT         09400019
UPDATFLG EQU   X'50'                    UPDATE FLAG                     09500019
PUTXERR  EQU   X'50'                    PUTX ERROR FLAG                 09600019
CC       EQU   X'40'                    COMMAND CHAIN FLAG              09700019
*                                                                       09800019
MTP3     EQU   3                        MULTIPLY FACTOR                 09900019
ADLEN    EQU   3                        LENGTH OF ADDRESS               10000019
MBB      EQU   3                        NUMBER OF BYTES FOR MBB         10100019
CCHHR    EQU   5                        NUMBER OF BYTES FOR CCHHR       10200019
ONE      EQU   X'01'                    CONSTANT ONE                    10300019
THREE    EQU   X'03'                    CONSTANT THREE                  10400019
NULL     EQU   0                        ZERO DISPLACEMENT               10500019
BYTE     EQU   1                        ONE BYTE DISPLACEMENT           10600019
WORD     EQU   4                        FULLWORD DISPLACEMENT           10700019
DBLWD    EQU   8                        DOUBLE WORD DISPLACEMENT        10800019
TWODBLWD EQU   16                       2 DOUBLE WORD LENGTH            10900019
ASSEMBLE EQU   X'01'                    ASSEMBLING IN PROCESS           11000019
SEGMENT  EQU   X'10'                    SEGMENTATION IN PROCESS         11050019
SPANFLG  EQU   X'04'                    SPANNED RECORD FLAG             11100019
RELFLAG  EQU   X'F0'                    RELEASE BIT                     11150019
BASEOFF  EQU   24                       BASE OF GET OFFSET              11200019
REG2OFST EQU   36                       REG 2 OFFSET IN SAVE AREA       11300019
SAOFF    EQU   64                       SAVE AREA OFFSET                11400019
REG8OFST EQU   68                       REG 8 OFFSET IN SAVE AREA       11500019
REAL8OFS EQU   60                       REAL OFFSET TO USER'S   SA63747 11550021
*                                       REGISTER 8 IN SAVE AREA SM5235  11560021
FIRST    EQU   X'01'                    FIRST IOB INDICATOR             11600019
RECNO    EQU   7                        R FIELD OFFSET OF TRACK ADDR    11700019
SEEKLEN  EQU   8                        IOBSEEK FIELD LENGTH            11800019
SPFDAD   EQU   11                       OFFSET TO SPECIAL FDAD IN CP    11900019
STATUS   EQU   20                       OFFSET TO STATUS BYTE OF CSW    12000019
STARTCP  EQU   24                       START OF CHANNEL PROGRAM OFFSET 12100019
SEEKOFST EQU   40                       IOBSEEK FIELD OFFSET            12200019
FIRSTEXT EQU   X'00'                    FIRST EXTENT OF DEB             12300019
TRKADLEN EQU   6                        BBCCHH LENGTH                   12400019
TRKAD    EQU   36                       BBCCHH OFFSET IN DEB            12500019
HIORDER  EQU   24                       HIGH ORDER POSITION             12600019
CODEOFST EQU   12                       ABEND CODE POSITION             12700019
ERROFF   EQU   X'3F'                    MASK TO TURN OFF ERROR FLAG     12800019
EOD      EQU   X'80'                    EOV OR EOF FLAG                 12850019
EOFATEOV EQU   X'20'                    EOF OCCURRED AFTER 1ST EOV      12855019
FEOVFLAG EQU   X'20'                    FE0V FLAG                       12860019
PURGED   EQU   X'48'                    IOB PURGED BIT                  12880019
ABCODE   EQU   1                                                 I21042 12890021
*                                                                       12900019
**                                                                      13000019
*                                                                       13100019
         USING IGG019BQ,BASR            SET BASE REGISTER               13200019
         USING IHADCB,DCBR              ESTABLISH ADDRESSIBILITY        13300019
*                                                                       13400019
         STM   RETR,ENTR,SAOFF(SAVR)    SAVE ENTRY AND RETURN TO GET    13500019
         LR    BASR,ENTR                ESTABLISH BASE                  13600019
         L     IOBAR,NULL(IOBAR)        GET NEXT IOB IN SEQUENCE        13700019
         LA    IOBAR,NULL(IOBAR)        CLEAR HIGH ORDER BYTE           13800019
*                                                                       13900019
*********************************************************************** 14000019
*                                                                       14100019
*      TEST STATUS OF IOB - WAIT FOR COMPLETION - RETURN TO GET IF      14200019
*           COMPLETE WITHOUT ERROR - ANY OTHER CONDITION, CONTINUE      14300019
*                                                                       14400019
*********************************************************************** 14500019
*                                                                       14600019
TESTCOMP EQU   *                                                        14700019
*                                                                       14800019
         TM    WORD(IOBAR),COMPERR      TEST FOR COMPLETION AND ERROR   14900019
         BO    RETURN                   BRANCH COMPLETE WITHOUT ERROR   15000019
         BM    ERROR                    BRANCH ON ERROR                 15100019
*                                                                       15200019
         WAIT  ECB=WORD(IOBAR)          INCOMPLETE- WAIT TILL COMPLETE  15300019
         B     TESTCOMP                 TEST AGAIN                      15400019
*                                                                       15500019
RETURN0  EQU   *                                                        15600019
*                                                                       15700019
         NI    DCBCIND2,NOT-EOVB        TURN OFF VOL FULL INDICATOR     15800019
*                                                                       15900019
RETURN   EQU   *                                                        16000019
*                                                                       16100019
         ST    IOBAR,DCBIOBA            UPDATE DCB TO CURRENT IOB       16200019
*                                                                       16300019
RETURN1  EQU   *                                                        16400019
         L     BASR,BASEOFF(SAVR)       RESTORE BASE OF GET ROUTINE     16500019
         L     RETR,SAOFF(SAVR)         GET ADDRESS OF GET ROUTINE      16600019
         BR    RETR                     RETURN TO GET                   16700019
*                                                                       16800019
ERROR    EQU   *                                                        16900019
*                                                                       16930019
         L     WORKR3,DCBBUFCB          GET BUFCB                       16960019
         LA    WORKR3,NULL(WORKR3)      CLEAR HIGH ORDER BYTE           16990019
         L     WORKR3,DBLWD(WORKR3)     OFFSET TO RECORD AREA ADDR      17020019
         TM    WORD(WORKR3),SEGMENT     SEGMENTING OF SPANNED RECORD    17050019
         BNO   ERROR1                   PROCESS ERROR                   17060019
*                                                                       17070019
         TM    STATUS(IOBAR),UNITEXCP   EOF OCCURRED                    17080019
         BNO   ERROR1                   BRANCH TO PROCESS ERROR         17090019
*                                                                       17100019
         CLI   DCBIOBAD,FEOVFLAG        HAS FEOV OCCURRED FOR SPANNED   17102019
*                                            REECORD UPDATE             17104019
         BE    ERROR1                   BRANCH YES TO EOV PROCESSING    17106019
*                                                                       17108019
         NI    DCBIFLGS,ERROFF          TURN OFF ERROR FLAGS IN DCB     17110019
*                                                                       17120019
         OI    NULL(WORKR3),EOD         SET EOF FLAG IN R.A.            17130019
         SR    WORKR4,WORKR4            CLEAR REG                       17131019
         SR    WORKR1,WORKR1            CLEAR REG                       17132019
         IC    WORKR4,DCBWCPO           GET WRITE CHANNEL PROG. OFFSET  17133019
         IC    WORKR1,DCBWCPL           GET WRITE CHANNEL PROG. LENGTH  17134019
         SLL   WORKR1,MTP3              CHANGE DBLWDS TO BYTES          17135019
         AR    WORKR4,WORKR1            COMBINE AND ADD 8 TO POINT TO   17136019
         LA    WORKR4,DBLWD(WORKR4)        CHANNEL PROG READ SEQUENCE   17137019
*                                                                       17137419
RESET    EQU   *                                                        17137619
*                                                                       17137819
         L     IOBAR,NULL(IOBAR)        LINK TO NEXT IOB IN SEQUENCE    17138019
         LA    IOBAR,NULL(IOBAR)        CLEAR HIGH ORDER BYTE           17138219
         CLI   WORD(IOBAR),PURGED       IS IOB PURGED                   17138419
         BNE   RESET5                   BRANCH NO TO SET UP IOBAR       17138619
*                                                                       17138819
         TM    NULL(IOBAR),READONLY     IS THIS 'ONLY READ' CP          17139019
         BO    RESET4                   BRANCH YES TO SET COMPLETE      17139219
*                                                                       17139419
         AR    WORKR4,IOBAR             CAL RD SEQ START ADDR           17139619
         LA    WORKR1,TWODBLWD          SUBTRACT 16 TO POINT TO         17139819
         SR    WORKR4,WORKR1              WRITE CCW                     17140019
         NI    WORD(WORKR4),NOT-CC      TURN OFF COMMAND CHAIN BIT      17140219
*                                                                       17140419
         LA    RPARA1,DBLWD(IOBAR)      POINT TO IOS'S IOB              17140619
*                                                                       17140819
         EXCP  (1)                      RESCHEDULE WRITE IOB            17141019
*                                                                       17141219
RESET1   EQU   *                                                        17141419
*                                                                       17141619
         TM    WORD(IOBAR),COMPERR      TEST FOR COMPLETION AND ERROR   17141819
         BO    RESET2                   COMPLETE WITHOUT ERROR          17142019
         BM    RESET3                   ERROR                           17142219
*                                                                       17142419
         WAIT  ECB=WORD(IOBAR)          INCOMPLETE - WAIT TILL COMPLETE 17142619
         B     RESET1                   TEST AGAIN                      17142819
*                                                                       17143019
RESET2   EQU   *                                                        17143219
*                                                                       17143419
         OI    WORD(WORKR4),CC          RESET COMMAND CHAIN BIT         17143619
         AR    WORKR4,WORKR1            RESTORE READ CP OFFSET IN IOB   17143819
         ST    WORKR4,STARTCP(IOBAR)    SET IOB CP START ADDR TO READ   17144019
         SR    WORKR4,IOBAR             RESTORE READ CP OFFSET          17144219
         OI    NULL(IOBAR),READONLY     TURN ON READ ONLY FLAG          17144419
         B     RESET                    BRANCH TO GET NEXT IOB ADDR     17144619
*                                                                       17144819
RESET3   EQU   *                                                        17145019
*                                                                       17145219
         TM    DCBSYNAD+ADLEN,BYTE      SYNAD USED                      17145419
         BNO   SYNAD1                   YES,BRANCH                      17145619
*                                                                       17145819
         CLI   DCBEROPT,ACCEPTOP        ACCEPT OPTION                   17146019
         BE    RESET2                   YES, BRANCH                     17146219
*                                                                       17146419
         CLI   DCBEROPT,SKIPOP          SKIP OPTION                     17146619
         BE    RESET2                   YES, BRANCH                     17146819
         B     TERM                     NO, TERMINATE                   17147019
*                                                                       17147219
RESET4   EQU   *                                                        17147419
*                                                                       17147619
         MVI   WORD(IOBAR),COMPERR      SET IOB TO COMPLETE WITHOUT     17147819
*                                            ERROR                      17148019
         B     RESET                    BRANCH TO GET NEXT IOB ADDR     17148219
*                                                                       17148419
RESET5   EQU   *                                                        17148619
*                                                                       17148819
         L     IOBAR,DCBIOBA            RESET IOB IN USE IN IOBAR       17149219
         B     RETURN1                  RETURN TO CALLER                17149619
*                                                                       17150019
ERROR1   EQU   *                                                        17160019
         SR    WORKR4,WORKR4            CLEAR REG                       17180019
         SR    WORKR1,WORKR1            CLEAR REG                       17200019
         IC    WORKR4,DCBWCPO           GET WRITE CHANNEL PROG. OFFSET  17300019
         IC    WORKR1,DCBWCPL           GET WRITE CHANNEL PROG. LENGTH  17400019
         SLL   WORKR1,MTP3              CHANGE DBLWDS TO BYTES          17500019
         AR    WORKR4,WORKR1            COMBINE AND ADD 8 TO POINT TO   17600019
         LA    WORKR4,DBLWD(WORKR4)        CHANNEL PROG READ SEQUENCE   17700019
         L     WORKR1,TWODBLWD(IOBAR)   GET NEXT COMMAND ADDR FROM CSW  17800019
         LA    WORKR1,NULL(WORKR1)      CLEAR HIGH ORDER BYTE           17900019
*                                                                       18000019
         NI    DCBIFLGS,ERROFF          TURN OFF ERROR FLAGS IN DCB     18100019
         TM    NULL(IOBAR),READONLY     IS THIS 'ONLY READ' CP          18200019
         BZ    ERRDETER                 NO, BRANCH                      18300019
*                                                                       18400019
VOLFULL  EQU   *                                                        18500019
*                                                                       18600019
         AR    WORKR4,IOBAR             ADD IOB ADDR TO RD CP OFFSET    18700019
         TM    STATUS(IOBAR),UNITEXCP   DOES CSW INDICATE VOLUME FULL   18800019
         BO    RESCHED                  YES, BRANCH TO RESCHEDULE WRITE 18900019
*                                                                       19000019
SYNAD    EQU   *                                                        19100019
*                                                                       19200019
         TM    DCBCIND2,CLOSEB          ARE WE IN CLOSE                 19300019
         BO    RETURN                   YES, RETURN                     19400019
         TM    DCBSYNAD+ADLEN,BYTE      SYNAD PRESENT IN DCB            19500019
         BNO   SYNAD1                   YES, BRANCH                     19600019
*                                                                       19700019
ACCEPT   EQU   *                                                        19800019
*                                                                       19900019
         CLI   DCBEROPT,ACCEPTOP        ACCEPT OPTION SPECIFIED         20000019
         BE    ACCEPT1                  YES, BRANCH                     20100019
*                                                                       20200019
         CLI   DCBEROPT,SKIPOP          SKIP OPTION SPECIFIED           20300019
         BE    SKIP                     YES, BRANCH                     20400019
*                                                                       20500019
         TM    NULL(IOBAR),READONLY     SEQUENCE IN WHICH ERROR OCCURED 20600019
         BO    RESCHED1                 READ ERROR                      20700019
*                                       WRITE ERROR                     20800019
*********************************************************************** 20900019
*                                                                       21000019
*      TERMINATE ONLY AFTER ALL PENDING UPDATES ARE RESCHEDULED AND     21100019
*           WRITTEN CORRECTLY                                           21200019
*                                                                       21300019
*********************************************************************** 21400019
*                                                                       21500019
TERM     EQU   *                                                        21600019
*                                                                       21700019
         LA    RPARA0,ABCODE            SET ABEND CODE           I21042 21800021
         SLL   RPARA0,CODEOFST          IN REG 0                 I21042 21850021
         LR    RPARA1,DCBR              PUT DCB PTR IN REG1      I21042 21900021
         SVC   55                       ISSUE EOV FOR            I21042 21950021
*                                       WRITE-TO-PROG AND ABEND         22000021
*                                                                       22200019
*********************************************************************** 22300019
*                                                                       22400019
*      DETERMINE IF ERROR OCCURRED IN READ OR WRITE SEQUENCE OF CHANNEL 22500019
*           PROGRAM AND FLAG IOB FOR READ ONLY IF READ ERROR            22600019
*                                                                       22700019
*********************************************************************** 22800019
*                                                                       22900019
ERRDETER EQU   *                                                        23000019
*                                                                       23100019
         LR    WORKR2,WORKR4            COPY READ CP OFFSET             23200019
         AR    WORKR2,IOBAR             BUILD READ CP ADDRESS           23300019
         LA    WORKR2,NULL(WORKR2)      CLEAR HIGH ORDER BYTE           23400019
         CR    WORKR1,WORKR2            COMPARE CSW ADDR TO RD CP ADDR  23500019
         BL    VOLFULL                  CSW IS LESS - ERR IN WRITE SEQ  23600019
*                                       RD CP ADDR IS LESS - RD SEQ ERR 23700019
         OI    NULL(IOBAR),READONLY     FLAG IOB FOR 'READ ONLY'        23800019
         B     VOLFULL                  BRANCH TO CHECK ERROR           24000019
*                                                                       24100019
*********************************************************************** 24200019
*                                                                       24300019
*      VOLUME FULL CONDITION EXISTS.  RESCHEDULE ALL PENDING UPDATES TO 24400019
*           THIS VOLUME PRIOR TO ISSUEING SVC 55 TO SWITCH VOLUMES.     24500019
*                                                                       24600019
*********************************************************************** 24700019
*                                                                       24800019
RESCHED  EQU   *                                                        24900019
*                                                                       25000019
         OI    DCBCIND2,EOVB            TURN ON END OF VOLUME FLAG      26100019
         MVI   WORD(IOBAR),COMPERR      SET IOB COMPLETE WITH NO ERROR  26200019
*                                                                       26300019
RESCHED1 EQU   *                                                        26400019
*                                                                       26500019
         LR    WORKR3,IOBAR             SAVE ERROR IOB ADDRESS          26600019
*                                                                       26730019
RESCHED2 EQU   *                                                        26800019
*                                                                       26900019
         ST    WORKR4,STARTCP(IOBAR)    SET IOB CP START ADDR TO READ   27000019
         SR    WORKR4,IOBAR             RESTORE RD CP OFFSET            27100019
         OI    NULL(IOBAR),READONLY     TURN ON READ ONLY FLAG          27200019
*                                                                       30300019
RESCHED3 EQU   *                                                        30400019
*                                                                       30500019
         L     IOBAR,NULL(IOBAR)        LINK TO NEXT IOB IN SEQUENCE    30600019
         LA    IOBAR,NULL(IOBAR)        CLEAR HIGH ORDER BYTE           30700019
         CR    WORKR3,IOBAR             HAS THIS IOB BEEN RESCHEDULED   30800019
         BE    RESCHED8                 YES, BRANCH OUT                 30900019
*                                                                       31000019
         AR    WORKR4,IOBAR             CAL RD SEQ. START ADDR          31400019
         LA    WORKR1,TWODBLWD          SUBTRACT 16 TO POINT TO         31500019
         SR    WORKR4,WORKR1              WRITE CCW                     31600019
*                                                                       31600119
         L     WORKR2,DCBBUFCB          GET BUFCB                       31600419
         LA    WORKR2,NULL(WORKR2)      CLEAR HIGH ORDER BYTE           31600519
         L     WORKR2,DBLWD(WORKR2)     OFFSET TO RECORD AREA ADDR      31600619
         TM    NULL(WORKR2),EOD         HAS EOF OCCURRED                31600719
         BO    RESCHED4                 BRANCH YES TO READ ONLY         31600819
*                                                                       31601019
         TM    NULL(IOBAR),READONLY     WHAT TYPE CP WAS TO BE EXECUTED 31610019
         BO    RESCHED3                 READ ONLY                       31620019
*                                                                       31630019
         NI    WORD(WORKR4),NOT-CC      TURN OFF COMMAND CHAIN BIT      31700019
*                                                                       31800019
         LA    RPARA1,DBLWD(IOBAR)      POINT TO IOS'S IOB              31900019
*                                                                       32000019
         EXCP  (1)                      RESCHEDULE WRITE IOB            32100019
*                                                                       32200019
*********************************************************************** 32300019
*                                                                       32400019
*      TEST EACH RESCHEDULED IOB FOR COMPLETION WITHOUT ERROR. IF AN    32500019
*           ERROR OCCURS GO TO USERS SYNAD ROUTINE.                     32600019
*                                                                       32700019
*********************************************************************** 32800019
*                                                                       32900019
RESCHED4 EQU   *                                                        33000019
*                                                                       33100019
         TM    WORD(IOBAR),COMPERR      TEST FOR COMPLETION AND ERROR   33200019
         BO    RESCHED5                 COMPLETE WITHOUT ERROR          33300019
         BM    RESCHED6                 ERROR                           33400019
*                                                                       33450019
         WAIT  ECB=WORD(IOBAR)          INCOMPLETE- WAIT TILL COMPLETE  33500019
         B     RESCHED4                 TEST AGAIN                      33600019
*                                                                       33700019
RESCHED5 EQU   *                                                        33800019
*                                                                       33900019
         OI    WORD(WORKR4),CC          RESET COMMAND CHAIN BIT         34000019
         AR    WORKR4,WORKR1            RESTORE READ CP OFFSET          34100019
         B     RESCHED2                 BRANCH TO GET NEXT IOB          34200019
*                                                                       34300019
RESCHED6 EQU   *                                                        34400019
*                                                                       34500019
         TM    DCBSYNAD+ADLEN,BYTE      SYNAD USED                      34600019
         BO    RESCHED7                 NO, BRANCH                      34700019
*                                                                       34800019
         TM    DCBCIND2,CLOSEB          WERE WE IN CLOSE EXECUTOR       34900019
         BO    RETURN                   YES, RETURN                     35000019
         B     SYNAD1                   NO, BRANCH                      35100019
*                                                                       35200019
RESCHED7 EQU   *                                                        35300019
*                                                                       35400019
         CLI   DCBEROPT,ACCEPTOP        ACCEPT OPTION                   35500019
         BE    RESCHED5                 YES, BRANCH                     35600019
*                                                                       35700019
         CLI   DCBEROPT,SKIPOP          SKIP OPTION                     35800019
         BE    RESCHED5                 YES, BRANCH                     35900019
         B     TERM                     NO, TERMINATE                   36000019
*                                                                       36110019
RESCHED8 EQU   *                                                        36200019
*                                                                       36300019
         TM    DCBCIND2,FEOVB           FEOV SPECIFIED                  36400019
         BO    RETURN0                  YES, RETURN TO CALLER           36500019
*                                                                       36600019
         L     WORKR3,DCBBUFCB          GET BUFCB ADDR           M4894  36610019
         LA    WORKR3,NULL(WORKR3)      CLEAR HIGH ORDER BYTE    M4894  36620019
         L     WORKR3,DBLWD(WORKR3)     OFFSET TO RECORD AREA    M4894  36630019
*                                       ADDR                     M4894  36640019
*                                                                       36650019
         TM    DCBCIND2,CLOSEB          WERE WE IN CLOSE EXECUTOR       36700019
         BNO   EOVTEST                  NO,GO TEST RESCHED       M4894  36740019
*                                       WRITES                   M4894  36780019
         TM    WORD(WORKR3),SEGMENT     IS UPDATE COMPLETE       M4894  36820019
         BNO   RETURN                   YES,RETURN TO CALLER     M4894  36860019
*                                                                       36900019
EOVTEST  EQU   *                                                 M4894  36950019
         TM    DCBCIND2,EOVB            RESCHEDULING WRITES FOR EOV     37000019
         BNO   TERM                     NO, TERMINATE                   37100019
*                                                                       37201019
         TM    WORD(WORKR3),ASSEMBLE    ASSEMBLING OF SPANNED RECORD    37250019
         BZ    RESCHED0                 NO, BRANCH                      37260019
*                                                                       37270019
         OI    NULL(IOBAR),SPANFLG      SET SPANNED RECORD FLAG         37280019
*                                                                       37290019
RESCHED0 EQU   *                                                        37291019
*                                                                       37292019
         NI    NULL(WORKR3),NOT-EOD     TURN OFF EOF FLAG IN R. A.      37296019
         LR    RPARA0,IOBAR             SET UP PARAMETERS FOR           37300019
         LR    RPARA1,DCBR                SVC ROUTINE                   37400019
*                                                                       37500019
         EOV   0(1)                     GO TO SWITCH VOLUMES            37600019
*                                                                       37700019
         L     WORKR3,DCBBUFCB          GET BUFCB                       37800019
         LA    WORKR3,NULL(WORKR3)      CLEAR HIGH ORDER BYTE           37900019
         L     WORKR3,DBLWD(WORKR3)     OFFSET TO RECORD AREA ADDR      38000019
         TM    NULL(WORKR3),EOFATEOV    HAS EOF OCCURRED AFTER 1ST EOV  38010019
         BZ    RESCHED9                 BRANCH NO                       38020019
         OI    NULL(WORKR3),EOD         TURN BACK ON EOF FLAG IN R.A.   38030019
         NI    NULL(WORKR3),NOT-EOFATEOV TURN OFF EOV INDICATOR         38040019
*                                                                       38050019
RESCHED9 EQU   *                                                        38060019
*                                                                       38070019
         TM    WORD(WORKR3),ASSEMBLE    ASSEMBLING OF SPANNED RECORD    38100019
         BZ    TESTCOMP                 BRANCH NO TO TEST I/O COMPLETE  38200019
*                                                                       38300019
         NI    NULL(IOBAR),NOT-SPANFLG  TURN OFF SPANNED RECORD FLAG    38400019
         B     TESTCOMP                 BRANCH TO TEST COMPLETION       38500019
*                                                                       38600019
*********************************************************************** 38700019
*                                                                       38800019
*      PASS PARAMETERS TO USERS SYNAD ROUTINE.  IF USER RETURNS CONTROL 38900019
*           DETERMINE IF EOV CONDITION EXISTS AND COMPLETE RESCHEDULING 39000019
*           ALL PENDING UPDATES.  IF NOT EOV PERFORM USERS ERROR OPTION 39100019
*                                                                       39200019
*********************************************************************** 39300019
*                                                                       39400019
SYNAD1   EQU   *                                                        39500019
*                                                                       39600019
         L     ENTR,DCBSYNAD            GET SYNAD ADDRESS               39700019
         SR    WORKR1,WORKR1            CLEAR REG                       39800019
         SR    WORKR2,WORKR2            CLEAR REG                       39900019
         LR    RPARA1,DCBR              GET DCB ADDR FOR SYNAD PARAM    40000019
         BO    SYNAD2                   YES BRANCH                      40200019
*                                                                       40300019
         IC    WORKR1,DCBOFFSR          GET READ CCW OFFSET             40400019
         B     SYNAD3                   BRANCH TO GO TO SYNAD           40500019
*                                                                       40600019
SYNAD2   EQU   *                                                        40700019
*                                                                       40800019
         IC    WORKR2,PUTXERR           GET PUTX ERROR INDICATOR        40900019
         SLL   WORKR2,HIORDER           SHIFT TO HIGH ORDER BYTE        41000019
         OR    RPARA1,WORKR2            PLACE IN SAME REG AS DCB ADDR   41100019
         IC    WORKR1,DCBOFFSW          GET WRITE CCW OFFSET            41200019
*                                                                       41300019
SYNAD3   EQU   *                                                        41400019
*                                                                       41500019
         SLL   WORKR1,HIORDER           SHIFT TO HIGH ORDER BYTE        41600019
         LA    WORKR2,DBLWD(IOBAR)      PUT IOB ADDR IN SAME REG AS     41700019
         OR    WORKR1,WORKR2              OFFSET                        41800019
         LR    RPARA0,WORKR1            LOAD SYNAD PARAMETER REG        41900019
         LM    DCBR,BASR,REG2OFST(SAVR) RESTORE USERS REGS 2-8          42000019
         ST    RPARA1,REAL8OFS(,SAVR)   SAVE OUR REGISTER 1     SM5235  42050021
**                                                                      42100019
         BALR  RETR,ENTR                TO USERS SYNAD ROUTINE          42200019
**                                                                      42300019
         L     RPARA1,REAL8OFS(,SAVR)   RESTORE OUR REGISTER 1  SM5235  42350021
         STM   DCBR,BASR,REG2OFST(SAVR) SAVE USERS REGS 2-8             42400019
         L     BASR,REG8OFST(SAVR)      REESTABLISH BASE                42500019
         LR    DCBR,RPARA1              RE-ESTABLISH DCB ADDR. AND      42600019
         L     IOBAR,DCBIOBA              IOB ADDR.                     42700019
         SR    WORKR4,WORKR4            CLEAR REGISTER          SA67209 42750021
         SR    WORKR1,WORKR1            CLEAR REGISTER          SA67209 42760021
         IC    WORKR4,DCBWCPO           GET WRITE CHAN PROG     SA67209 42770021
*                                         OFFSET                SA67209 42780021
         IC    WORKR1,DCBWCPL           GET WRITE CHAN PROG     SA67209 42790021
*                                          OFFSET               SA67209 42794021
         SLL   WORKR1,3                 CHANGE DB WDS TO BYTES  SA67209 42796021
         AR    WORKR4,WORKR1            COMBINE AND ADD 8 FOR   SA67209 42798021
         LA    WORKR4,8(WORKR4)            OFFSET TO CHAN PROG  SA67209 42798421
*                                          READ SEQUENCE FROM   SA67209 42798821
*                                          IOB PREFIX           SA67209 42799221
         AR    WORKR4,IOBAR             GET ADDR OF READ CHAN   SA67209 42799621
*                                          PROG                 SA67209 42799721
         TM    DCBCIND2,EOVB            WERE WE RESCHEDULING WRITES     42800019
        BZ    ACCEPT                   NO, CHECK USERS OPTIONS          43000021
         LA    WORKR1,TWODBLWD          REG HAS VALUE OF 16     SA67209 43060021
         SR    WORKR4,WORKR1            BACKUP READ CHAN PROG   SA67209 43070021
*                                          POINTER              SA67209 43080021
         B     RESCHED7                 BRANCH TO RESCHEDULE    SA67209 43090021
*                                                                       43100019
*********************************************************************** 43200019
*                                                                       43300019
*      ACCEPT ERROR IOB AND RESCHEDULE PURGED IOB'S                     43400019
*                                                                       43500019
*********************************************************************** 43600019
*                                                                       43700019
ACCEPT1  EQU   *                                                        43800019
*                                                                       43900019
         ST    IOBAR,DCBIOBA            SAVE ERROR IOB FOR USER         44000019
         LR    WORKR3,IOBAR             SAVE ERROR IOB TO END LOOP      44100019
*                                                                       44200019
         TM    NULL(IOBAR),READONLY     ERROR REC. FROM RD. OR WRT. SEQ 44300019
         BO    ACCEPT2                  READ ERROR                      44400019
*                                       WRITE ERROR                     44500019
         ST    WORKR4,STARTCP(IOBAR)    SET IOB CP START ADDR TO READ   44600019
*                                                                       44700019
         MVC   SEEKOFST(SEEKLEN,IOBAR),SEEKOFST(WORKR4) MOVE RD. SEQ.   44800019
*                                          SEEK ADDR. TO IOS            44900019
*                                                                       45100019
ACCEPT2  EQU   *                                                        45200019
*                                                                       45300019
         MVI   WORD(IOBAR),COMPERR      FLAG IOB COMPLETE WITHOUT ERROR 45400019
         B     SCHED2                   BRANCH TO GET NEXT IOB          45500019
*                                                                       45600019
SCHED1   EQU   *                                                        45700019
*                                                                       45800019
         LA    RPARA1,DBLWD(IOBAR)      POINT TO IOS'S IOB              45900019
*                                                                       46000019
         EXCP  (1)                      RESCHEDULE THIS IOB             46100019
*                                                                       46200019
SCHED2   EQU   *                                                        46300019
*                                                                       46400019
         L     IOBAR,NULL(IOBAR)        LINK TO NEXT IOB IN SEQUENCE    46500019
         LA    IOBAR,NULL(IOBAR)        CLEAR HIGH ORDER BYTE           46600019
*                                                                       46700019
         CR    WORKR3,IOBAR             HAS THIS IOB BEEN RESCHEDULED   46800019
         BE    TESTCOMP                 YES, TEST FOR COMPLETION        46900019
         B     SCHED1                   NO, RESCHEDULE IT               47000019
*                                                                       47100019
*********************************************************************** 47200019
*                                                                       47300019
*      SKIP ERROR IOB AND RESCHEDULE PURGED IOB'S                       47400019
*                                                                       47500019
*********************************************************************** 47600019
*                                                                       47700019
SKIP     EQU   *                                                        47800019
*                                                                       47900019
         TM    NULL(IOBAR),READONLY     ERROR REC. FROM READ OR WRITE   48000019
         BNO   ACCEPT1                  WRITE - SAME AS ACCEPT OPTION   48100019
*                                       READ - GO TO REINITIALIZE IOB   48200019
*                                                                       48220019
         OI    DCBRECAD,RELFLAG         SET RELEASE FLAG ON TO INDICATE 48240019
*                                            ERROR IN READ CHANNEL PROG 48260019
*                                            WITH SKIP OPTION SPECIFIED 48280019
         OI    NULL(IOBAR),READONLY     FLAG IOB FOR 'READ ONLY'        48300019
         L     IOBAR,NULL(IOBAR)        LINK TO NEXT IOB IN SEQUENCE    48400019
         LA    IOBAR,NULL(IOBAR)        CLEAR HIGH ORDER BYTE           48500019
         ST    IOBAR,DCBIOBA            SAVE FOR USER                   48700019
         LR    WORKR3,IOBAR             SAVE AS ENDING IOB IN LOOP      48800019
         CLI   DCBBUFNO,ONE             ONE IOB ONLY USED               48900019
         BH    SCHED1                   NO, BRANCH                      49000019
         SR    WORKR2,WORKR2            CLEAR REG                       49100019
         IC    WORKR2,DCBOFFSR          GET OFFSET TO RD DATA CCW       49200019
         AR    WORKR2,IOBAR             POINT TO RD DATA CCW THIS IOB   49300019
         MVC   SPFDAD(CCHHR,WORKR2),DCBFDAD+MBB PLACE FDAD IN SPECIAL   49400019
*                                          FDAD                         49500019
         B     SCHED1                   RESCHEDULE                      49600019
*                                                                       49700019
*********************************************************************** 49800019
*                                                                       49900019
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY   50000019
*                                                                       50100019
*********************************************************************** 50200019
*                                                                       50300019
         CNOP  0,8                      PAD MOD TO DOUBLE WORD MULTIPLE 50400019
*                                                                       50500019
*********************************************************************** 50600019
*                                                                       50700019
         DCBD  DSORG=PS                                                 50800019
         END                                                            50900019
