         TITLE 'IGG019BU-SAM OFFSET READ OF A KEYED, VS, BDAM DATA SET' 00041002
IGG019BU CSECT                                                          00400019
*                                                                       00410019
*        RELEASE 20 DELETIONS                                           01200019
*        RELEASE 21 DELETIONS                                           01600019
*                                                               YA00581 01650002
*        RELEASE 22 DELETIONS                                           02000019
*        RELEASE 23 DELETIONS                                           02400019
*        RELEASE 24 DELETIONS                                           02800019
*        RELEASE 25 DELETIONS                                           03200019
*        RELEASE 26 DELETIONS                                           03600019
*        RELEASE 27 DELETIONS                                           04000019
*        RELEASE 28 DELETIONS                                           04010019
*                                                                       04020019
*STATUS CHANGE LEVEL 001         02/15/73                               04400002
*                                                                       04410019
*FUNCTION-OPERATION--OFFSET READ ROUTINE FOR BDAM DATA SETS             04800019
*  USING THE SEQUENTIAL ACCESS METHOD.                                  04850002
*     1. THE ROUTINE RECEIVES CONTROL WHEN A READ MACRO-INSTRUCTION     05200019
*        IS ENCOUNTERED IN THE PROCESSING PROGRAM.                      05600019
*     2. IT ENTERS THE ADDRESS OF THE IOB INTO THE DECB TO PER-         06000019
*        MIT THE CHECK ROUTINE TO LATER TEST EXECUTION OF THE           06400019
*        CHANNEL PROGRAM.                                               06800019
*     3. IT COMPLETES THE CHANNEL PROGRAM BY INSERTING THE BUFFER       07200019
*        ADDRESS AND THE RECORD LENGTH.  THE BUFFER ADDRESS IS OBTAINED 07600019
*        FROM THE DECB AND OFFSET BY KEY LENGTH IF THERE IS NO KEY      08000019
*        WITH THIS SEGMENT (I.E., IF THIS IS A SEGMENT SUBSEQUENT TO    08400019
*        THE FIRST SEGMENT OF A RECORD).  THIS DETERMINATION IS MADE    08800019
*        BY CHECKING TO SEE IF THE CCW HAS BEEN CHANGED BY MODULE       09200019
*        IGG019BV TO READ JUST DATA.  THE RECORD LENGTH IS OBTAINED     09600019
*        FROM THE DCB AND MODIFIED BY KEY LENGTH IF APPROPRIATE.        10000019
*     4. IT THEN ISSUES EXCP                                            10400019
*                                                                       10800019
*ENTRY POINT--IGG019BU IS ENTERED FROM A READ MACRO EXPANSION           11200019
*              LA    1,DECB                                             11600019
*              LA    14,DCB                                             12000019
*              L     15,48(14)                                          12400019
*              BALR  14,15                                              12800019
*                                                                       13200019
*INPUT--DECB                                                            13600019
*                                                                       14000019
*OUTPUT--DECB                                                           14400019
*         DECSDECB--ECB                                                 14800019
*         DECIOBPT--ADDRESS OF IOS IOB (SAM IOB + 8)                    15200019
*        DCB                                                            15600019
*         DCBIOBA--ADDRESS OF CURRENT IOB                               16000019
*        IOB                                                            16400019
*         IOBFLAG0--READ INDICATED--X'20'                               16800019
*         IOBECBPT--ADDRESS OF ECB                                      17200019
*         IOBSTART--STARTING ADDRESS OF CHANNEL PROGRAM                 17600019
*        CHANNEL PROGRAM                                                18000019
*         ADDRESS OF I/O AREA (OFFSET BY KEY LENGTH IF APPROPRIATE)     18400019
*         LENGTH OF RECORD (INCLUDING KEY LENGTH IF APPROPRIATE)        18800019
*                                                                       19200019
*EXTERNAL ROUTINES--NONE                                                19600019
*                                                                       20000019
*EXITS NORMAL--RETURN TO CALLER ON REG 14 AFTER SCHEDULING I/0          20400019
*                                                                       20800019
*EXITS ERROR--NONE                                                      21200019
*                        REGISTER ASSIGNMENTS                           21600019
*                                                                       22000019
WORKR    EQU   0                        WORK REG                        22400019
DECBR    EQU   1                        DECB ADDR                       22800019
PARMR    EQU   DECBR                    REG FOR PASSING PARAMETERS      23200019
DCBR     EQU   2                        DCB ADDR                        23600019
IOBR     EQU   3                        ADDR OF IOB (SAM, PAM, PREFIX)  24000019
KEYLEN   EQU   4                        KEY LENGTH                      24400019
WORKR2   EQU   5                        WORK REG                        24800019
BLKSIZE  EQU   6                        BLOCK SIZE                      25200019
CPR      EQU   7                        CHANNEL PROG ADDR               25600019
BASER    EQU   8                        BASE REG                        26000019
SAVER    EQU   13                       SAVE AREA ADDR                  26400019
RETRNR   EQU   14                       RETURN ADDR                     26800019
ENTRYR   EQU   15                       ENTRY POINT ADDR                27200019
*                                                                       27600019
         USING IGG019BU,BASER           BASE FOR MODULE                 28000019
         USING IHADCB,DCBR              BASE FOR DCB                    28400019
         USING DEFDECB,DECBR            BASE FOR DECB                   28800019
         USING DEFIOB,IOBR              BASE FOR IOB                    29200019
         USING DEFCP,CPR                BASE FOR CHANNEL PROG           29600019
*                                                                       30000019
*                          CONSTANT EQUATES                             30400019
*                                                                       30800019
IOBSIZE  EQU   48                       IOB SIZE                        31200019
ADDRLEN  EQU   3                        LENGTH OF ADDRESS               31600019
CCHHRLEN EQU   5                        LENGTH OF BLOCK ID (CCHHR)      32000019
PREFXLEN EQU   8                        LENGTH OF IOB PREFIX            32400019
ADOFFSET EQU   1                        OFFSET TO ADDR FROM FULL WORD   32800019
SAVOFFST EQU   20                       OFFSET IN SAVE AREA             33200019
RDKYDATA EQU   X'08'                    BIT=1 MEANS READ KEY & DATA     33600019
BITSOFF  EQU   X'7F'                    TURN OFF BITS IN DCBOFLGS       34000019
BITOFF   EQU   X'01'                    TURN OFF BIT IN IOBFLAG0        34400019
READBIT  EQU   X'20'                    READ BIT IN IOBFLAG1            34800019
INVLDNPT EQU   X'41'                    CODE FOR INVALID NOTE-POINT     35200019
ERRORMSK EQU   X'FF'                    TEST FOR ERROR FROM POINT RTN   35600019
RDBKBIT  EQU   X'BF'                    READ BACK BIT IN DCBOFLGS       36000019
*                                                                       36400019
*                                                                       36800019
ENTRY    EQU   *                                                        37200019
         STM   RETRNR,BASER,SAVOFFST(SAVER)  SAVE USER REGS             38000019
         LR    BASER,ENTRYR             ESTABLISH ADDRESSABILITY        38010019
         L     DCBR,DECDCBAD            DCB ADDR                        38400019
         L     IOBR,DCBIOBA             IOB ADDR (MINUS 8)              38800019
         L     IOBR,IOBCHAIN            NEXT IOB ON CHAIN               39200019
         LA    CPR,IOBSIZE(IOBR)        CHANNEL PROG ADDR               39600019
         NI    DCBOFLGS,RDBKBIT         TURN OFF READ BACK BIT IN OFLGS 40000019
         LA    WORKR,IOBFLAG1           IOS IOB POINTER                 40400019
         ST    WORKR,DECIOBPT           PLACE IN DECB                   40800019
         ST    DECBR,IOBECBPT           PUT ECB PTR IN IOB              41200019
         CLI   IOBECB,ERRORMSK          ERROR IN A POINT RTN            41600019
         BNE   PROCESS                  NO--BRANCH TO PROCESS           42000019
         MVI   DECSDECB,INVLDNPT        YES--INDICATE ERROR IN ECB      42400019
         LM    RETRNR,BASER,SAVOFFST(SAVER)  RESTORE USER REGS          42800019
         BR    RETRNR                   RETURN TO USER                  43200019
*                                                                       43600019
*                                                                       44000019
PROCESS  EQU   *                                                        44400019
         NI    IOBFLAG0,BITOFF          TURN OFF BITS IN IOB            44800019
         OI    IOBFLAG0,READBIT         TURN ON READ BIT                45200019
         ST    CPR,IOBSTART             PUT ADDR OF CHANNEL PROG IN IOB 45600019
         NI    DCBOFLGS,BITSOFF         TURN OFF OFLAGS                 46000019
         SR    KEYLEN,KEYLEN                                            46400019
         IC    KEYLEN,DCBKEYLE          GET KEY LENGTH                  46800019
         LH    BLKSIZE,DCBBLKSI         BLOCK SIZE FROM DCB             47200019
         L     WORKR2,DECAREA           BUFFER ADDR                     47600019
         LA    WORKR2,0(WORKR2)         CLEAR HIGH ORDER BYTE           48000019
*                                                                       48400019
*  THIS SECTION OF CODE DETERMINES IF THE RECORD ABOUT TO BE READ IS A  48800019
*  SEGMENT OF A SEGMENTED RECORD.  IF IT IS AND IT IS NOT THE FIRST     49200019
*  SEGMENT, THEN THE READ WILL BE OFFSET IN THE BUFFER BY KEY LENGTH.   49600019
*  THE DETERMINATION IS MADE BY CHECKING TO SEE IF THE CCW HAS BEEN     50000019
*  CHANGED BY THE CHANNEL END APPENDAGE TO READ JUST DATA RATHER THAN   50400019
*  KEY AND DATA                                                         50800019
*                                                                       51200019
         TM    RKDCC,RDKYDATA           IS CCW FOR READ JUST DATA       51600019
         BO    NOOFFSET                 NO--OFFSET NOT NEEDED           52000019
         AR    WORKR2,KEYLEN            ADD KEY LENGTH                  52400019
FILLCCW  EQU   *                                                        52800019
         IC    WORKR,RKDCC              SAVE CCW OP CODE                53200019
         ST    WORKR2,RKDCC             PUT BUFFER ADDR IN CCW          53600019
         STC   WORKR,RKDCC              PUT OP CODE BACK                54000019
         STH   BLKSIZE,RKDBYTCT         PUT LENGTH IN CCW               54400019
         B     UPDATDCB                 GO TO UPDATE DCB                54800019
*                                                                       55200019
NOOFFSET EQU   *                                                        55600019
         AR    BLKSIZE,KEYLEN           ADJUST LENGTH FOR KEY           56000019
         B     FILLCCW                  GO TO COMPLETE CCW              56400019
UPDATDCB EQU   *                                                        56800019
         ST    IOBR,DCBIOBA             UPDATE DCB IOB POINTER          57200019
         MVC   IOBSKCC(CCHHRLEN),CPCOUNT   MOVE CCHHR INTO IOBSEEK      57600019
         LA    PARMR,PREFXLEN(IOBR)     ADDR OF IOS IOB                 58000019
         EXCP  (1)                                                      58400019
*                                                                       58800019
         LM    RETRNR,BASER,SAVOFFST(SAVER) RESTORE USER REGS           59200019
         BR    RETRNR                   RETURN TO USER                  59600019
*                                                                       60000019
DEFDECB  DSECT                          DECB STRUCTURE                  60400019
DECSDECB DS    CL4                      ECB                             60800019
DECTYPE  DS    CL2                      TYPE OF I/O MACRO & OPTIONS     61200019
DECLNGTH DS    CL2                      LENGTH OF DATA OR KEY & DATA    61600019
DECDCBAD DS    A                        ADDR OF DCB                     62000019
DECAREA  DS    A                        ADDR OF READ/WRITE AREA         62400019
DECIOBPT DS    A                        ADDR OF IOB                     62800019
*                                                                       63200019
DEFIOB   DSECT                          IOB STRUCTURE                   63600019
IOBFLAG0 DS    0BL1                     I/O FLAGS                       64000019
IOBCHAIN DS    A                        ADDR OF NEXT IOB                64400019
IOBECB   DS    F                        ECB                             64800019
IOBFLAG1 DS    BL1                      I/O FLAGS                       65200019
IOBFLAG2 DS    BL1                      I/O FLAGS                       65600019
IOBSENS0 DS    BL1                      FIRST SENSE BYTE                66000019
IOBSENS1 DS    BL1                      SECOND SENSE BYTE               66400019
IOBECBCC DS    0X                       COMPLETION CODE                 66800019
IOBECBPT DS    A                        ADDR OF ECB                     67200019
IOBFLAG3 DS    BL1                      I/O FLAGS                       67600019
IOBCSW   DS    CL7                      LOW ORDER BYTES OF LAST CSW     68000019
IOBSIOCC DS    0X                       SIO CONDITION CODE              68400019
IOBSTART DS    A                        ADDR OF CHANNEL PROG            68800019
         DS    0C                       RESERVED                        69200019
IOBDCBPT DS    A                        ADDR OF DCB                     69600019
IOBRESTR DS    CL4                      PURGE CHAIN/CCHH/COMMAND,CP     70000019
IOBINCAM DS    2C                       USE VARIES                      70400019
IOBERRCT DS    2X                       NO OF ERROR RETRIES             70800019
IOBSEEK  DS    0D                       SEEK FIELD FOR DA               71200019
IOBSKM   DS    1X                       EXTENT NUMBER                   71600019
IOBSKBB  DS    2X                       BIN                             72000019
IOBSKCC  DS    2X                       CYLINDER                        72400019
IOBSKHH  DS    2X                       HEAD                            72800019
IOBSKR   DS    1X                       RECORD                          73200019
*                                                                       73600019
DEFCP    DSECT                          OFFSET READ CHANNEL PROG        74000019
CPNOP1   DS    0D                       NOP                             74400019
NOP1CC   DS    0X                       COMMAND CODE                    74800019
NOP1DATA DS    A                        DATA ADDR                       75200019
NOP1FLAG DS    BL1                      FLAGS                           75600019
         DS    1X                       NOT USED                        76000019
NOP1BYTC DS    2X                       BYTE COUNT                      76400019
CPSCH    DS    D                        SEARCH ID EQUAL                 76800019
CPTIC1   DS    D                        TIC TO SEARCH                   77200019
CPTIC2   DS    D                        TIC TO READ COUNT               77600019
CPRDCNT  DS    0D                       READ COUNT                      78000019
RCTCC    DS    0X                       COMMAND CODE                    78400019
RCTDATAD DS    A                        DATA ADDR                       78800019
RCTFLAGS DS    BL1                      FLAGS                           79200019
         DS    1X                       NOT USED                        79600019
RCTBYTCT DS    2X                       BYTE COUNT                      80000019
CPRDKD   DS    0D                       READ (KEY) DATA                 80400019
RKDCC    DS    0X                       COMMAND CODE                    80800019
RKDDATAD DS    A                        DATA ADDR                       81200019
RKDFLAGS DS    BL1                      FLAGS                           81600019
         DS    1X                       NOT USED                        82000019
RKDBYTCT DS    2X                       BYTE COUNT                      82400019
CPNOP2   DS    0D                       NOP                             82800019
NOP2CC   DS    0X                       COMMAND CODE                    83200019
NOP2DATA DS    A                        DATA ADDR                       83600019
NOP2FLAG DS    BL1                      FLAGS                           84000019
         DS    1X                       NOT USED                        84400019
NOP2BYTC DS    2X                       BYTE COUNT                      84800019
CPCOUNT  DS    D                        FIELD TO READ COUNT INTO        85200019
         ORG   *-3                      BACK TO KEY LENGTH FIELD        85600019
KEYLNGTH DS    1X                       KEY LENGTH IN COUNT             86000019
*                                                                       86400019
         DCBD  DSORG=BS,DEVD=DA         DCB DSECT                       86800019
         END                                                            87200019
