 TITLE 'IGG019BV--SAM CHAN AND ABNORMAL END APPENDAGES FOR OFFSET READ' 00001002
IGG019BV CSECT                                                          00400019
*                                                                       00410019
*        RELEASE 20 DELETIONS                                           01200019
*3495416000,572000                                               20201  01400020
*        RELEASE 21 DELETIONS                                           01600002
*                                                               YA00581 01650002
*        RELEASE 22 DELETIONS                                           02000019
*        RELEASE 23 DELETIONS                                           02400019
*        RELEASE 24 DELETIONS                                           02800019
*        RELEASE 25 DELETIONS                                           03200019
*        RELEASE 26 DELETIONS                                           03600019
*        RELEASE 27 DELETIONS                                           04000019
*        RELEASE 28 DELETIONS                                           04010019
*                                                                       04020019
*STATUS CHANGE LEVEL 003     02/15/73                                   04320002
*                                                                       04800019
*FUNCTION-OPERATION--CHANNEL END APPENDAGE FOR OFFSET READ FUNCTION     05200019
*   OF A BDAM DATA SET USING THE SEQUENTIAL ACCESS METHOD.              05250002
*     1. THE MODULE RECEIVES CONTROL FROM THE I/O INTERRUPTION          05600019
*        SUPERVISOR AT CHANNEL END EXIT.                                06000019
*     2. IF THE APPENDAGE FINDS A UNIT EXCEPTION BIT ON IN THE CHANNEL  06400019
*        STATUS WORD, IT RETURNS TO THE I/O INTERRUPTION SUPERVISOR     06800019
*        IMMEDIATELY.                                                   07200019
*     3. IF THE UNIT CHECK BIT IS ON, THE ABNORMAL ROUTINE IS BRANCHED  07210019
*        TO.  THE ABNORMAL ROUTINE CHANGES9                             07220019
*     4. IF A KEY WAS NOT READ (READ DATA IN CCW) THE COMMAND IS        07600019
*        CHANGED BACK TO READ KEY AND DATA.                             08000019
*     5. IF A KEY WAS EXPECTED (READ KEY AND DATA IN CCW) AND THERE     08400019
*        WAS NO KEY TO READ (KEY LENGTH=0 IN COUNT JUST READ), THEN     08800019
*        THE READ MUST BE RESCHEDULED WITH AN OFFSET.                   09200019
*     6. THE APPENDAGE CALCULATES THE LENGTH OF THE BLOCK AND COMPARES  09600019
*        IT TO THAT IN THE BLOCK LENGTH FIELD.  IF THE LENGTHS ARE      10000019
*        EQUAL, IT TURNS OFF ERROR INDICATORS IN THE ECB.               10400019
*     7. IF THE LENGTHS ARE UNEQUAL, THE CURRENT CHANNEL PROGRAM IS     10800019
*        CHANGED TO READ KEY AND DATA AND CONTROL IS RETURNED TO THE    11200019
*        I/O INTERRUPT SUPERVISOR IMMEDIATELY.  THE I/O INTERRUPTION    11600019
*        SUPERVISOR THEN SETS THE ECB TO SHOW THAT THE CHANNEL PROGRAM  12000019
*        EXECUTED WITH AN ERROR CONDITION.                              12400019
*     8. THE APPENDAGE CHECKS THE SEGMENT DESCRIPTOF WORD TO SEE IF     12800019
*        ANOTHER SEGMENT IS TO FOLLOW.  IF THERE IS, THE NEXT CHANNEL   13200019
*        PROGRAM IS CHANGED TO READ DATA.                               13600019
*                                                                       14000019
*ENTRY POINTS--ENTRY TO THIS ROUTINE IS FROM IOS AFTER CHANNEL END      14400019
*              FROM A READ COMMAND                                      14800019
*                                                                       15200019
*INPUT--IOB AND USERS RECORD                                            15600019
*                                                                       16000019
*OUTPUT--THE INCORRICT LENGTH INDICATOR IN THE CSW IS RESET IF THE      16400019
*        LENGTH OF THE RECORD BEING CHECKED IS CORRECT, AND THE NEXT    16800019
*        CHANNEL PROGRAM IS READIED FOR AN OFFSET READ IF APPLICABLE.   17200019
*                                                                       17600019
*EXTERNAL ROUTINES--NONE                                                18000019
*                                                                       18400019
*EXITS NORMAL--THE CSW WRONG LENGTH INDICATOR IS TURNED OFF AND THE     18800019
*              IOB EXCEPTION FLAG IS TURNED OFF AND CONTROL IS PASSED   19200019
*              TO IOS.                                                  19600019
*                                                                       20000019
*EXITS ERROR--RETURN TO IOS WITH THE CSW WRONG LENGTH INDICATOR AND     20400019
*             THE IOB EXCEPTION FLAG ON.                                20800019
*                                                                       21200019
*ATTRIBUTES--DISABLED                                                   21600019
*                                                                       22000019
IOBR     EQU   2                        BASE FOR IOS IOB                22400019
DCBR     EQU   4                        BASE FOR DCB                    22800019
BLKDESWD EQU   9                        ADDR OF BLK DESCRIPTOR WORD     22810019
KEYLEN   EQU   10                       REG FOR KEY LENGTH              23600019
WORKR    EQU   11                       WORK REGISTER                   24000019
RESIDCTR EQU   WORKR                    REG FOR CSW RESIDUAL COUNT      24400019
WORKR2   EQU   12                       WORK REGISTER                   24800019
CPR      EQU   13                       BASE FOR CHANNEL PROGRAM        25210019
RETRNR   EQU   14                       RETURN REGISTER                 25600019
BASER    EQU   15                       BASE FOR MODULE                 26000019
*                                                                       26400019
*                         CONSTANT EQUATES                              26800019
*                                                                       27200019
UNITEXCP EQU   X'01'                    UNIT EXCEPTION BIT IN CSW       27600019
UNITCHEK EQU   X'02'                    UNIT CHECK BIT IN CSW           27610019
CYLNEND  EQU   X'20'                    CYLINDER END BIT IN SENSE BYTE  27620019
FILEPRTK EQU   X'04'                    FILE PROTECT SENSE BIT          27630019
RDKYDATA EQU   X'8E'                    READ KEY & DATA COMMAND         28000019
READDATA EQU   X'86'                    READ DATA COMMAND               28400019
RDKEYBIT EQU   X'08'                    READ KEY BIT                    28800019
KEYBTOFF EQU   X'F7'                    TO TURN KEY BIT OFF             29200019
NOKEY    EQU   0                        TEST COUNT FIELD FOR KEY        29600019
CLRBYTE  EQU   0                        TO CLEAR HIGH ORDER BYTE        30000019
CCHHRLEN EQU   5                        LENGTH OF CCHHR                 30010019
ONEIOB   EQU   1                        TO TEST FOR ONE IOB             30020019
IOBLNGTH EQU   40                       LENGTH OF IOB                   30400019
SEGCODE  EQU   6                        OFFSET TO SEGMENT CODE FROM     30800019
*                                         BLOCK DESCRIPTOR WORD         31200019
LASTSEG  EQU   8                        BCR CODE FOR LAST SEG IN RCD    31600019
BYTELEN  EQU   8                        NUMBER OF BITS/BYTE FOR A SLL   32000019
CPRETRY  EQU   8                        RETURN OFFSET TO IOS FOR A      32400019
*                                         CHANNEL PROGRAM RETRY         32800019
LLDIS    EQU   0                        OFFSET TO LL IN BLK DESCRIPTOR  33200019
*                                         WORD                          33600019
SCNDBYT  EQU   1                        SECOND BYTE OF LL IN BDW        34000019
ONES     EQU   1                        BCR CODE FOR TM--ONES           34400019
NOTEQUAL EQU   7                        BCR CODE FOR NOT EQUAL          34800019
IFLGERBT EQU   X'3F'                    ERROR BIT IN DCBIFLG            35200019
FLG1ERBT EQU   X'FB'                    ERROR BIT IN IOBFLAG1           35600019
SKIPFLAG EQU   X'10'                    SKIP FLAG IN CCW                36000019
SLIBIT   EQU   X'BF'                    SLI BIT IN CCW                  36400019
RCDCONTN EQU   X'01'                                                    36800019
         USING IHADCB,DCBR              BASE FOR DCB                    37200019
         USING IGG019BV,BASER           BASE FOR MODULE                 37600019
         USING DEFIOB,IOBR              BASE FOR IOB                    38000019
         USING DEFCP,CPR                BASE FOR CHANNEL PROGRAM        38010019
*                                                                       39200019
BEGIN    EQU   *                                                        39600019
         LA    CPR,IOBLNGTH(IOBR)       CHANNEL PROGRAM ADDR            40000019
         TM    CSWSTAT1,UNITEXCP        TEST FOR UNIT EXCEPTION         40400019
         BCR   ONES,RETRNR              RETURN IF ON                    40800019
         CLI   DCBNCP,ONEIOB            ONE IOB                         40801019
         BE    ONECP                    YES--BRANCH                     40802019
         LR    WORKR,IOBR               ADDR OF IOS IOB                 40803019
         SH    WORKR,PREFXLEN           ADDR OF IOB CHAIN               40804019
         LR    WORKR2,IOBR              SAVE IOB ADDR                   40805019
         L     IOBR,0(WORKR)            NEXT IOB                        40806019
         AH    IOBR,PREFXLEN            IOS IOB                         40807019
         LA    CPR,IOBLNGTH(IOBR)       ADDR OF CHANNEL PROGRAM         40808019
         MVC   IOBSKCC(CCHHRLEN),CPCOUNT  MOVE SEEK ADDR INTO IOBSEEK   40809019
         LR    IOBR,WORKR2              RESTORE CURRENT IOB ADDR        40809119
         LA    CPR,IOBLNGTH(IOBR)       RESET TO CURRENT IOB            40809219
ONECP    EQU   *                                                        40809319
         TM    CSWSTAT1,UNITCHEK        TEST FOR UNIT CHECK             40810019
         BO    ABNORML                  ABNORMAL CHANNEL END            40820019
         TM    RKDFLAGS,SKIPFLAG        TEST FOR SKIP FLAG              41200019
         BO    RETURN                   YES, BRANCH              20201  41400020
         SR    KEYLEN,KEYLEN            ZERO FOR IC                     41610019
         IC    KEYLEN,DCBKEYLE          GET KEY LENGTH                  41620019
         TM    RKDCC,RDKEYBIT           IS COMMAND READ KEY & DATA      42000019
         BZ    CHNGCP                   NO-BRANCH                       42400019
         LR    WORKR,IOBR               ADDR OF IOS IOB                 42410019
         SH    WORKR,PREFXLEN           ADDR OF IOB CHAIN               42420019
         L     CPR,0(WORKR)             NEXT IOB                        42430019
         AH    CPR,PREFXLEN             IOS IOB                         42440019
         LA    CPR,IOBLNGTH(CPR)        ADDR OF CHANNEL PROGRAM         42450019
         CLI   KEYLNGTH,NOKEY           CHECK COUNT FOR ZERO KEY LENGTH 42800019
         LA    CPR,IOBLNGTH(IOBR)       RESET TO CURRENT IOB            42810019
         BNE   CKLENGTH                 BRANCH IF KEY WAS READ          43200019
*                                                                       43600019
* A KEY WAS EXPECTED BUT NOT READ, THEREFORE THE SEGMENT IS NOT OFFSET  44000019
* IN THE BUFFER.  THE READ MUST BE RESCHEDULED WITH THE REQUIRED        44400019
* OFFSET.                                                               44800019
*                                                                       45200019
         L     WORKR,RKDDATAD           GET BUFFER ADDR                 46400019
         LA    WORKR,CLRBYTE(WORKR)     CLEAR HIGH ORDER BYTE           46800019
         AR    WORKR,KEYLEN             OFFSET BUFFER ADDR BY KEY LEN   47200019
         ST    WORKR,RKDDATAD           STORE NEW BUFFER ADDR           47600019
         MVI   RKDCC,READDATA           COMMAND CODE--READ DATA         48000019
         LH    WORKR,RKDBYTCT           GET BYTE COUNT                  48400019
         SR    WORKR,KEYLEN             DECREMENT BYTE COUNT BY KEY LEN 48410019
         STH   WORKR,RKDBYTCT           INSERT NEW BYTE COUNT           49200019
         NI    DCBIFLGS,IFLGERBT        TURN OFF ERROR BITS IN DCBIFLG  49600019
         NI    IOBFLAG1,FLG1ERBT        TURN OFF ERROR BIT IN IOBFLAG1  50000019
         MVC   IOBERRCT,ZERO            ZERO OUT ERROR COUNT IN IOB     50400019
         LA    RETRNR,CPRETRY(RETRNR)   IOS ENTRY FOR RETRY             50800019
         BR    RETRNR                   RETURN                          51200019
*                                                                       51600019
CHNGCP   EQU   *                                                        52000019
* THERE WAS NO KEY READ WITH THIS SEGMENT, THEREFORE THE CHANNEL        52400019
* PROGRAM MUST BE REINITIALIZED WITH A COMMAND CODE TO READ KEY & DATA  52800019
*                                                                       53600019
         LTR   KEYLEN,KEYLEN            TEST FOR ZERO KEY LENGTH M4877  53700019
         BZ    AFTRKDCC                 BYPASS COMMAND CHANGE    M4877  53800019
         OI    RKDCC,RDKEYBIT           CHANGE COMMAND--READ KEY & DATA 54000019
*                                                                       55600019
AFTRKDCC EQU   *                                                 M4877  55605019
         L     BLKDESWD,RKDCC           ADDR OF BUFFER                  55610019
         LA    BLKDESWD,CLRBYTE(BLKDESWD)  CLEAR HIGH ORDER BYTE        55620019
         B     CKLEN2                   GO TO CHECK LENGTH              55630019
*                                                                       55640019
CKLENGTH EQU   *                                                        56000019
* HERE, A CHECK IS MADE TO VERIFY THAT THE SEGMENT READ WAS THE         56400019
* CORRECT LENGTH.                                                       56800019
*                                                                       56870020
* CHECK FOR RPS AND UPDATE SECTOR IF USED                               56940020
*                                                                       57010020
         CLI   SECTCCW,SETSC            RPS USED                 20201  57080020
         BNE   NORPS                    BRANCH NO                20201  57150020
         L     BLKDESWD,SECTCCW         GET SECTOR ADDR          20201  57220020
         MVC   0(ONES,BLKDESWD),ONES(BLKDESWD) UPDATE SECTOR     20201  57290020
*                                                                       57360020
NORPS    EQU   *                                                 20201  57430020
*                                                                       57500020
         L     BLKDESWD,RKDCC           ADDR OF BUFFER                  57600019
         LA    BLKDESWD,CLRBYTE(BLKDESWD)  CLEAR HIGH ORDER BYTE        57610019
         AR    BLKDESWD,KEYLEN          ADDR OF BLOCK DESCRIPTOR WORD   58000019
CKLEN2   EQU   *                                                        58010019
         LH    RESIDCTR,CSWBYTCT        GET  RESIDUAL COUNT FROM CSW    58400019
         SR    WORKR2,WORKR2            CLEAR FOR LL INSERTION          58800019
         IC    WORKR2,LLDIS(BLKDESWD)   FIRST BYTE OF LL FIELD          59200019
         SLL   WORKR2,BYTELEN                                           59600019
         IC    WORKR2,SCNDBYT(BLKDESWD) SECOND BYTE OF LL               60000019
         AR    WORKR2,RESIDCTR          ADD RESIDUAL COUNT AND LL       60400019
         CH    WORKR2,DCBBLKSI          SUM SHOULD EQUAL BLOCK SIZE     60800019
         BNE   RETURN                   RETURN TO IOS WITH FLAGS ON     61200019
*                                                                       61600019
* LENGTH CHECK CONFIRMED, ERROR FLAGS CAN BE TURNED OFF.                62000019
*                                                                       62400019
         NI    CSWSTAT2,SLIBIT          TURN OFF SLI BIT IN CSW         62800019
         NI    IOBFLAG1,FLG1ERBT        TURN OFF IOB EXCEPTION FLAG     63200019
*                                                                       63600019
* THE SEGMENT DESCRIPTOR WORD WILL BE CHECKED TO SEE IF THERE IS        64000019
* ANOTHER SEGMENT TO THIS RECORD.  IF THERE IS, THE NEXT CHANNEL        64400019
* PROGRAM WILL HAVE TO BE READIED BY CHANGING THE COMMAND TO READ DATA  64800019
*                                                                       65200019
         TM    SEGCODE(BLKDESWD),RCDCONTN ANOTHER SEGMENT TO FOLLOW     65600019
         BC    LASTSEG,RETURN           NO--RETURN TO IOS               66000019
         LR    WORKR,IOBR               ADDR OF IOS IOB                 66400019
         SH    WORKR,PREFXLEN           ADDR OF IOB CHAIN               66800019
         L     CPR,0(WORKR)             NEXT IOB                        67200019
         AH    CPR,PREFXLEN             IOS IOB                         67201019
         LA    CPR,IOBLNGTH(CPR)        ADDR OF CHANNEL PROGRAM         67210019
         L     WORKR,RKDCC              BUFFER ADDR                     67220019
         LA    WORKR,0(WORKR)           CLEAR HIGH ORDER BYTE           67230019
         AR    WORKR,KEYLEN             OFFSET BY KEY LENGTH            67240019
         ST    WORKR,RKDCC              OFFSET BUFFER ADDR              67250019
         MVI   RKDCC,READDATA           READ DATE COMMAND               67260019
         LH    WORKR,RKDBYTCT           BYTE COUNT                      67270019
         SR    WORKR,KEYLEN             DECREMENT BY KEY LENGTH         67280019
         STH   WORKR,RKDBYTCT                                           67290019
*                                                                       68400019
RETURN   EQU   *                                                        68410019
         SR    BLKDESWD,BLKDESWD        CLEAR FOR IOS                   68800019
         BR    RETRNR                   RETURN TO IOS                   69200019
*                                                                       69600019
ABNORML  EQU   *                                                        70000019
         TM    IOBSENS1,CYLNEND         CYLINDER END                    70410019
         BCR   ONES,RETRNR              YES--RETURN TO IOS              70420019
         TM    IOBSENS1,FILEPRTK        FILE PROTECT (END OF TRACK)     70430019
         BCR   ONES,RETRNR              YES--RETURN TO IOS              70440019
         OI    RKDCC,RDKEYBIT           CHANGE COMMAND--READ KEY & DATA 70800019
         BR    RETRNR                   RETURN TO IOS                   73600019
*                                                                       74000019
ZERO     DC    H'0'                     TO ZERO OUT A TWO BYTE FIELD    74400019
PREFXLEN DC    H'8'                     IOB PREFIX LENGTH               74800019
*                                                                       75200019
DEFIOB   DSECT                          IOB STRUCTURE                   75600019
IOBFLAG1 DS    BL1                      I/O FLAGS                       76000019
IOBFLAG2 DS    BL1                      I/O FLAGS                       76400019
IOBSENS0 DS    BL1                      FIRST SENSE BYTE                76800019
IOBSENS1 DS    BL1                      SECOND SENSE BYTE               77200019
IOBECBCC DS    0X                       COMPLETION CODE                 77600019
IOBECBPT DS    A                        ADDR OF ECB                     78000019
IOBFLAG3 DS    BL1                      I/O FLAGS                       78400019
IOBCSW   DS    CL7                      LOW ORDER BYTES OF LAST CSW     78800019
         ORG   *-4                      BACK TO STATUS BYTES            79200019
CSWSTAT1 DS    XL1                      FIRST STATUS BYTE               79210019
CSWSTAT2 DS    XL1                      SECOND STATUS BYTE              79600019
CSWBYTCT DS    XL2                      BYTE COUNT                      80000019
IOBSIOCC DS    0X                       SIO CONDITION CODE              80400019
IOBSTART DS    A                        ADDR OF CHANNEL PROG            80800019
         DS    0C                       RESERVED                        81200019
IOBDCBPT DS    A                        ADDR OF DCB                     81600019
IOBRESTR DS    CL4                      PURGE CHAIN/CCHH/COMMAND,CP     82000019
IOBINCAM DS    2C                       USE VARIES                      82400019
IOBERRCT DS    H                        NO OF ERROR RETRIES             82800019
IOBSEEK  DS    0D                       SEEK FIELD FOR DA               83200019
IOBSKM   DS    1X                       EXTENT NUMBER                   83600019
IOBSKBB  DS    2X                       BIN                             84000019
IOBSKCC  DS    2X                       CYLINDER                        84400019
IOBSKHH  DS    2X                       HEAD                            84800019
IOBSKR   DS    1X                       RECORD                          85200019
*                                                                       85600019
DEFCP    DSECT                          CHANNEL PROGRAM                 86000019
CPNOP1   DS    0D                       NOP                             86400019
SETSC    EQU   X'23'                    SET SECTOR CCW           20201  86500020
SECTCCW  EQU   CPNOP1                   SET SECTOR CCW CMND      20201  86600020
NOP1CC   DS    0X                       COMMAND CODE                    86800019
NOP1DATA DS    A                        DATA ADDR                       87200019
NOP1FLAG DS    BL1                      FLAGS                           87600019
         DS    1X                       NOT USED                        88000019
NOP1BYTC DS    2X                       BYTE COUNT                      88400019
CPSCH    DS    D                        SEARCH ID EQUAL                 88800019
CPTIC1   DS    D                        TIC BACK TO SEARCH              89200019
CPTIC2   DS    D                        TIC TO READ COUNT               89600019
CPRDCNT  DS    0D                       READ COUNT                      90000019
RCTCC    DS    0X                       COMMAND CODE                    90400019
RCTDATAD DS    A                        DATA ADDR                       90800019
RCTFLAGS DS    BL1                      FLAGS                           91200019
         DS    1X                       NOT USED                        91600019
RCTBYTCT DS    2X                       BYTE COUNT                      92000019
CPRDKD   DS    0D                       READ (KEY) DATA                 92400019
RKDCC    DS    0X                       COMMAND CODE                    92800019
RKDDATAD DS    A                        DATA ADDR                       93200019
RKDFLAGS DS    BL1                      FLAGS                           93600019
         DS    1X                       NOT USED                        94000019
RKDBYTCT DS    2X                       BYTE COUNT                      94400019
CPNOP2   DS    0D                       NOP                             94800019
NOP2CC   DS    0X                       COMMAND CODE                    95200019
NOP2DATA DS    A                        DATA ADDR                       95600019
NOP2FLAG DS    BL1                      FLAGS                           96000019
         DS    1X                       NOT USED                        96400019
NOP2BYTC DS    2X                       BYTE COUNT                      96800019
CPCOUNT  DS    D                        FIELD TO READ COUNT INTO        97200019
         ORG   *-3                      BACK TO KEY LENGTH FIELD        97600019
KEYLNGTH DS    1X                       KEY LENGTH IN COUNT             98000019
*                                                                       98400019
         DCBD  DSORG=BS,DEVD=DA         DCB DSECT                       98800019
         END                                                            99200019
