   TITLE 'IGG019C0  FORMAT U CHANNEL END APPENDAGE'                     00007020
IGG019C0 CSECT                                                          00014020
*          RELEASE 20 DELETIONS                                       * 00025020
*                                                                S20201 00025520
*          RELEASE 21 DELETIONS                                       * 00026020
*0334007200-007400                                               M0552  00026521
*          RELEASE 22 DELETIONS                                       * 00027020
*          RELEASE 23 DELETIONS                                       * 00028020
*          RELEASE 24 DELETIONS                                       * 00029020
*STATUS CHANGE LEVEL 003                                                00034020
*FUNCTION/OPERATION: ALL VARIABLE LENGTH RECORDS FOR DISK AND TAPE    * 00040020
*      WILL COME THROUGH THIS ROUTINE WHICH WILL DETERMINE IF THE     * 00060020
*      RECORD IS CORRECT LENGTH OR NOT. THIS IS ASCERTAINED BY COMPAR-* 00080020
*      -ING THE NUMBER OF CHARACTERS READ VERSUS THE COUNT SUPPLIED BY* 00100020
*      THE USER FOR A RECORD. THIS ROUTINE DOES NOT CHECK VARIABLE    * 00120020
*      LENGTH RECORDS FOR A WRITE COMMAND.                            * 00140020
*ENTRY POINTS  ENTRY TO THIS ROUTINE IS FROM IOS AFTER A READ COMMAND * 00160020
*INPUT:USERS RECORD ,   CHANNEL COMMAND WORD AND CHANNEL STATUS WORD  * 00180020
*OUTPUT  THE INCORRECT LENGTH INDICATOR IN THE CSW IS RESET IF THE    * 00200020
*        LENGTH OF THE RECORD BEING CHECKED IS CORRECT                * 00220020
*EXTERNAL ROUTINES: NOT APPLICABLE                                    * 00240020
*EXITS NORMAL THE CSW WRONG LENGTH INDICATOR IS TURNED OFF AND THE IOB* 00260020
*        EXCEPTION FLAG IS TURNED OFF AND CONTROL IS PASSED TO IOS    * 00280020
*EXITS ERROR   RETURN TO IOS WITH THE CSW WRONG LENGTH INDICATOR AND  * 00300020
*        THE IOB EXCEPTION FLAG ON                                    * 00320020
*TABLES/WORK AREAS: NOT APPLICABLE                                    * 00340020
*ATTRIBUTES: DISABLED                                                 * 00360020
*NOTES: NOT APPLICABLE                                                * 00380020
*                                                                       00402020
*                                                                       00404020
*                                                                       00406020
*                                                                       00408020
*                                                                       00410020
*                                                                       00412020
*                                                                       00414020
*                                                                       00416020
*                                                                       00418020
BASR     EQU   15                                                       00420020
DCBADDR  EQU   4                                                        00440020
RETRN    EQU   14                                                       00460020
BLKSIREG EQU   9                                                        00480020
IOBADDR  EQU   2                                                        00500020
CSW      EQU   10                                                       00520020
CCWCOUNT EQU   12                                                       00540020
LL       EQU   13                                                       00560020
RESIDCTR EQU   11                                                       00580020
PAM      EQU   X'02'                                                    00600020
WRITE    EQU   X'40'                                                    00620020
DISKTEST EQU   X'20'                                                    00640020
UNITEXCP EQU   X'01'                                                    00660020
C1       EQU   1                                                        00660420
C3       EQU   3                                                        00660820
C0       EQU   0                                                        00661220
C5       EQU   5                                                        00661620
SEEK     EQU   43                                                       00662020
TRKOVFLO EQU   X'20'                    TRACK OVERFLOW BIT              00662420
MTRDCNT  EQU   X'92'                                                    00662820
TIC      EQU   X'08'                    TIC CCW CMND                    00663220
KEYOP    EQU   X'08'                    KEY RCD OP CODE MASK            00663620
CCWLENTH EQU   8                                                        00664020
RSIDOFST EQU   14                       OFFSET OF RESIDUAL COUNT        00664420
WRKR2    EQU   RESIDCTR                                                 00664820
CCWSTART EQU   16                       ADDR OF START OF CHAN PGM       00665220
SETSECTR EQU   X'23'                    SET SECTOR COMMAND              00665620
FLAGBYTE EQU   4                        OFFSET OF FLAGS IN CCW          00666020
CHAINING EQU   X'C0'                    COMMAND OR DATA CHAIN           00666420
CSWOFSET EQU   8                        OFFSET OF CSW IN IOB            00666820
RCOUNT   EQU   14                       RESIDUAL COUNT OFFSET IN        00667220
*                                       THE IOB CSW                     00667620
CSWSTAT2 EQU   13                       OFFSET OF CSW STATUS BYTE2      00668020
READCNT  EQU   X'12'                                                    00668420
DDLNTH   EQU   2                        DD LENGTH IN COUNT              00668820
DD       EQU   6                                                        00669220
DACCESS  EQU   X'20'                                                    00669620
ZERO     EQU   0                        CONSTANT OF 0                   00670020
ONE      EQU   1                        CONSTANT OF ONE                 00670420
TWO      EQU   2                        CONSTANT OF 2                   00670820
SIX      EQU   6                        CONSTANT OF 6                   00671220
FLAGOFF  EQU   4                        CCW OFFSET TO FLAGS             00671620
K        EQU   5                        OFFSET TO KEYLENGTH BYTE        00672020
M8       EQU   8                        MASK FOR BCR                    00672420
READSCT  EQU   X'22'                    READ SECTOR COMMAND             00672820
D40      EQU   40                       CONSTANT OF 40                  00673220
D48      EQU   48                       CONSTANT OF 48                  00673620
D8       EQU   8                        CONSTANT OF 8                   00674020
CMNDCH   EQU   X'40'                    COMMAND CHAIN FLAG              00674420
DATACH   EQU   X'80'                    DATA CHAIN FLAG                 00674820
STATFLAG EQU   12                       OFFSET OF STATUS FLAG BYTE      00675220
*                                       IN DEB                          00675620
UPDATE   EQU   X'04'                    MASK TO TEST FOR UPDATE         00676020
OTHERS   EQU   X'0B'                    MASK TO COMPLETE UPDATE TEST    00676420
SIXTEEN  EQU  16                        CONSTANT OF 16                  00676820
         USING IHADCB,DCBADDR                                           00680020
         USING IGG019C0,BASR                                            00700020
         TM    DCBDEVT,DISKTEST         IS THIS A DISK                  00743020
         BCR   M8,RETRN                 NO RETURN                       00746020
         L     LL,D40(IOBADDR)          CONTENTS OF FIRST CCW           00749020
         CLI   D40(IOBADDR),SETSECTR    IS IT RPS                       00752020
         BNE   RETURN                   BRANCH AROUND RPS CODE          00755020
         LA    CSW,D48(IOBADDR)         POINT TO SECOND CCW             00758020
CHKNXT   EQU   *                                                        00761020
         CLI   C0(CSW),READSCT          IS IT A READ SECTOR             00764020
         BE    ALLOK                    BRANCH AROUND                   00767020
         LA    CSW,D8(CSW)              BUMP TO NEXT CCW                00770020
         B     CHKNXT                   GO TEST NEXT CCW                00773020
ALLOK    EQU   *                                                        00776020
         L     CSW,C0(CSW)              GET SECTOR ADDR                 00779020
         BCTR  CSW,ZERO                 DECREMENT BY ONE                00782020
         MVC   C0(ONE,CSW),C1(CSW)      UPDATE SECTOR                   00785020
         MVC   C0(ONE,LL),C1(CSW)       UPDATE SECTOR                   00788020
         LR    CSW,IOBADDR              COPY IOB ADDR                   00791020
         SH    CSW,EIGHT                POINT TO SAM IOB                00794020
         TM    0(CSW),X'48'             IS THIS WRITE/BACKSPACE   16367 00800020
         BCR   7,RETRN                  RETURN ON YES             16367 00820020
         L     WRKR2,CCWSTART(IOBADDR)  CHP START ADDR                  00829020
FINDCNT  EQU   *                                                        00838020
         LA    WRKR2,CCWLENTH(WRKR2)    POINT TO NEXT CCW               00847020
         CLI   ZERO(WRKR2),READCNT      IS THIS A READ COUNT            00856020
         BE    COMPARE                  YES COMPARE LENGTHS             00865020
         CLI   ZERO(WRKR2),MTRDCNT      IS THIS A M/T READ COUNT        00874020
         BE    COMPARE                  YES COMPARE LENGTHS             00883020
         CLI   ZERO(WRKR2),TIC          IS CMND A TIC                   00892020
         BE    FINDCNT                  BRANCH IF YES                   00901020
         TM    FLAGOFF(WRKR2),DATACH+CMNDCH CHAINING IN CCW             00910020
         BZ    RETURN                   BRANCH IF NO                    00919020
         B     FINDCNT                  IS NEXT CCW READ COUNT          00928020
COMPARE  EQU   *                                                        00937020
         LA    CCWCOUNT,D8(WRKR2)       ADDR OF READ CCW                00946020
         L     WRKR2,ZERO(WRKR2)        LOAD ADDR OF COUNT              00955020
*                                                                       00964020
* THE CCW COUNT ADDRESS IS IN REG CSW AND THE 8 BYTE COUNT AREA         00973020
* ADDRESS OF THE RECORD IS IN WRKR2                                     00982020
*                                                                       00991020
         L     BLKSIREG,DCBIOBA         LOAD THE IOB ADDRESS            01000020
         CLC   DCBIOBA+C1(C3),C1(BLKSIREG) COMP CURRENT IOB TO NEXT     01009020
         BNE   EGP450                   BRANCH IF MORE THAN ONE IOB     01018020
         MVC   DCBFDAD+C3(C5),C0(WRKR2) MOVE CCHHR TO DCBFDAD+3         01027020
         B     LAB03                    BRANCH TO LAB03                 01036020
EGP450   EQU   *                                                        01045020
         SH    IOBADDR,EIGHT            POINT TO SAM IOB                01054020
         L     BLKSIREG,C0(IOBADDR)     BUMP TO NEXT IOB                01063020
         AH    IOBADDR,EIGHT            POINT BACK TO IOS IOB           01072020
         L     CSW,DCBDEBAD             GET DEBADDR FOR UPDATE TEST     01081020
         TM    STATFLAG(CSW),UPDATE     IS UPDATE BIT ON                01090020
         BZ    TAB01                    BRANCH IF NO                    01099020
         TM    STATFLAG(CSW),OTHERS     ARE OTHER BITS OFF              01108020
         BNZ   TAB01                    BRANCH IF NOT UPDATE            01117020
*              WRKR2 CONTAINS THE ADDRESS OF THE CCHHR TO BE MOVED      01126020
*              LOAD CSW WITH THE ADDRESS OF THE SPECIAL FDAD+3 OF       01135020
*              THE NEXT IOB                                             01144020
         SR    CSW,CSW                  ZERO OUT CSW                    01153020
         IC    CSW,DCBOFFSR             INSERT READ CCW OFFSET          01162020
         AR    CSW,BLKSIREG             POINT TO THE READ CCW OF        01171020
*                                       THE NEXT IOB                    01180020
         LA    CSW,SIXTEEN(CSW)         POINT TO THE SPECIAL FDAD       01189020
         MVC   C3(C5,CSW),C0(WRKR2)     MOVE CCHHR TO NEXT IOB          01198020
*                                       SPECIAL FDAD+3                  01207020
         B     LAB03                    GET OUT                         01216020
TAB01    EQU   *                                                        01225020
         MVC   SEEK(C5,BLKSIREG),C0(WRKR2)  MOVE CCHHR TO NXT           01234020
LAB03    EQU   *                                                        01243020
         XR    BLKSIREG,BLKSIREG        CLEAR REGISTER                  01252020
         TM    ZERO(CCWCOUNT),KEYOP     READING KEYS                    01261020
         BNO   NOKEYS                   BRANCH NO                       01270020
         IC    BLKSIREG,K(WRKR2)        GET KEY LENGTH                  01279020
NOKEYS   EQU   *                                                        01288020
         AH    BLKSIREG,DD(WRKR2)       ADD DATA LENGTH                 01297020
         LH    CCWCOUNT,DD(CCWCOUNT)    GET ATTEMPTED TO READ LENGTH    01306020
         SR    CCWCOUNT,BLKSIREG        SUB DD FROM CCW COUNT           01315020
         BM    RETURN                   BRANCH NO RESIDUAL COUNT        01324020
         STH   CCWCOUNT,RCOUNT(IOBADDR) PUT IN IOB CSW                  01333020
RETURN   EQU   *                                                        01342020
*                                                                       01351020
*     THE CSW NOW REFLECTS A PSUDO RESIDUAL COUNT AND REG WRKR2         01360020
*     HOLDS THE ADDRESS OF THE 8 BYTE COUNT FIELD                       01369020
         SR    BLKSIREG,BLKSIREG        CLEAR REG FOR IOS               01378020
         BR    RETRN                    RETURN VIA LINK REG             01387020
EIGHT    DC    H'8'                     DEFINED HALFWORD OF 8           01396020
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY   01440020
         CNOP  0,8                 PAD MODULE TO DOUBLE WORD MULTIPLE   01460020
         DCBD  DSORG=PS                                                 01480020
         END                                                            01500020
