19C1 TITLE 'IGG019C1 -- TRACK OVERFLOW ASYNCHRONOUS ERROR ROUTINE'      00020021
IGG019C1 CSECT                                                          00020521
*          RELEASE 17 DELETIONS                                         00021000
*2074030020-030180,048800,052000-053600                           6M670 00022000
*          RELEASE 18 DELETIONS                                         00023000
*          RELEASE 19 DELETIONS                                         00024000
*0375042600,065200                                               A28698 00024519
*          RELEASE 20 DELETIONS                                         00025000
*0216                                                            A39795 00025520
*          RELEASE 21 DELETIONS                                         00026000
*          RELEASE 21.8 CHANGES                                         00026221
*A000204,070700,078900                                          SA69163 00026421
*C051200                                                        SA69163 00026621
*D022000-022600,023600-025200,026400-027000,028000-028800,      SA69163 00026821
*D030000,041000,073400                                          SA69163 00027021
*          VS1 RELEASE 3.1 CHANGES                                      00027321
*    XA04511 IS FLAGGED AS SA69163                              XA04511 00027621
*                                                                       00030021
*STATUS CHANGE LEVEL - MAY, 1974                                        00035021
*FUNCTION/OPERATION - THIS ROUTINE WILL DETERMINE A NEW SEARCH ADDRESS  00040000
*      WHEN SOME PART OF THE CHANNEL PROGRAM HAS FAILED IN EXECUTION.   00060000
*                                                                       00080000
*        IF THE CHANNEL PROGRAM FAILED ON ANY PART EXCEPT A READ DATA,  00100000
*      THE NEW SEARCH ARGUMENT WILL BE RECORD ZERO OF THE TRACK FOLLOW- 00120000
*      ING THE TRACK ORIGINALLY SEARCHED.                               00140000
*                                                                       00160000
*        IF IT FAILED ON THE READ DATA CCW WHILE READING A NOT-LAST     00180000
*      SEGMENT OF AN OVERFLOW RECORD WHICH WAS NOT ON AN ALTERNATE      00200000
*      TRACK, THE NEW SEARCH ARGUMENT WILL BE RECORD ZERO OF THE TRACK  00220000
*      FOLLOWING THE TRACK ON WHICH THE ERROR OCCURRED.  IF IT WAS ON   00240000
*      AN ALTERNATE TRACK, THE NEW SEARCH ARGUMENT WILL BE RECORD ZERO  00260000
*      OF THE TRACK ON WHICH THE SECOND SEGMENT OF THE DATA RECORD IS   00280000
*      FOUND.                                                           00300000
*                                                                       00320000
*        IF IT FAILED ON THE READ DATA WITH THE SKIP FLAG WHILE READING 00340000
*      THE LAST SEGMENT OF A RECORD WHICH WAS ON AN ALTERNATE TRACK,    00360000
*      THE NEW SEARCH ARGUMENT WILL BE RECORD ONE OF THE TRACK FOLLOW-  00380000
*      ING THE TRACK ORIGINALLY SEARCHED.                               00400000
*                                                                       00420000
*        IN ALL THE ABOVE CASES, THE ECB WILL BE POSTED IN ERROR AND    00440000
*      NORMAL SCHEDULING WILL FOLLOW.                                   00460000
*                                                                       00480000
*        IN THE FOLLOWING CASES, THE IOB WILL BE RESCHEDULED AND THE    00500000
*      USER WILL NOT KNOW THE ERROR OCCURRED.                           00520000
*                                                                       00540000
*        IF THE CHANNEL PROGRAM FAILED ON THE READ DATA WITH THE SKIP   00560000
*      FLAG WHILE READING THE LAST SEGMENT OF ANY RECORD WHICH          00580000
*      WAS NOT ON AN ALTERNATE TRACK, THE READ SKIP WILL BE CHANGED TO  00600000
*      A NOP AND THE NEW SEARCH ARGUMENT WILL BE THE ADDRESS OF THAT    00620000
*      LAST SEGMENT.                                                    00640000
*                                                                       00660000
*        IF IT FAILED ON THE READ DATA WITH THE SKIP FLAG WHILE READING 00680000
*      A NOT-LAST SEGMENT OF AN OVERFLOW RECORD WHICH WAS NOT ON AN     00700000
*      ALTERNATE TRACK, THE NEW SEARCH ARGUMENT WILL BE THE ADDRESS OF  00720000
*      THE SEGMENT THAT FAILED.  IF IT WAS ON AN ALTERNATE TRACK, THE   00740000
*      NEW SEARCH ARGUMENT WILL BE RECORD ONE OF THE TRACK FOLLOWING    00760000
*      THE TRACK ORIGINALLY SEARCHED.                                   00780000
*                                                                       00800000
*ENTRY POINTS - ENTERED BY DISPATCHER WITH STANDARD LINKAGE AND ADDRESS 00820000
*      OF RQE (REQUEST QUEUE ELEMENT) IN REGISTER ONE.                  00840021
*                                                                       00860000
*INPUT - RQE,                                                           00880000
*          OFFSET 4 - IOB ADDRESS                                       00900000
*      DCB,                                                             00920000
*          DCBDEBAD                                                     00940000
*          DCBOFFSR                                                     00960000
*      DEB,                                                             00980000
*          DEBENDCC                                                     01000000
*          DEBEXSCL                                                     01020000
*          DEBUSRPG                                                     01040000
*      CVT,                                                             01060000
*          CVTPCNVT                                                     01080000
*          CVTPRLTV                                                     01100000
*          CVTPTR                                                       01120000
*      IOB,                                                             01140000
*          IOBCOMAD                                                     01160000
*          IOBDCBPT                                                     01180000
*          IOBECBPT                                                     01200000
*          IOBFLAG1                                                     01220000
*          IOBRESTR                                                     01240000
*          IOBSENS1                                                     01260000
*                                                                       01280000
*OUTPUT - DCB,                                                          01300000
*          DCBIFLGS                                                     01320000
*      IOB,                                                             01340000
*          CHANNEL PROGRAM MODIFIED AS EXPLAINED ABOVE.                 01360000
*          NEW SEARCH ARGUMENT.                                         01380000
*          PURGED IOB'S SOMETIMES RESTORED.                             01400000
*          ECB SOMETIMES POSTED.                                        01420000
*                                                                       01440000
*EXTERNAL ROUTINES -  POST, RESTORE, EXCP                               01460000
*                                                                       01480000
*EXITS - NORMAL - STANDARD RETURN LINKAGE TO TERMINATOR.                01500000
*                                                                       01520000
*TABLES/WORK AREA - CHANNEL PROGRAM                                     01540000
*          SEARCH ID EQUAL                                              01560000
*          TIC *-8                                                      01580000
*          READ DATA (SKIP FLAG AND SILI FLAG ON)                       01600000
*          READ COUNT                                                   01620000
*          READ DATA                                                    01640000
*                                                                       01660000
*ATTRIBUTES - REENTRANT, ENABLED, REFRESHABLE.                          01680021
*                                                                       01700000
         EJECT                                                          01720000
         SPACE 1                                                        01740000
*        REGISTER DEFINITIONS                                           01760000
         SPACE 1                                                        01780000
ZROR     EQU   0                        PARAMETER REGISTER ZERO.        01800000
XQER     EQU   1                        ADDRESS OF REQUEST ELEMENT FOR  01820000
*                                         THIS ROUTINE.                 01840000
SRGR     EQU   2                        ADDRESS OF THE SEARCH ARGUMENT. 01860000
DEBR     EQU   3                        ADDRESS OF THE DEB.             01880000
DCBR     EQU   4                        ADDRESS OF THE DCB.             01900000
IOBR     EQU   5                        ADDRESS OF THE IOB.             01920000
BASR     EQU   6                        BASE ADDRESS OF THIS ROUTINE.   01940000
RETR     EQU   7                        RETURN REGISTER THIS ROUTINE.   01960000
SUBR     EQU   8                        RETURN REGISTER FOR INDEPINC.   01980000
WKRE     EQU   8                        WORK REGISTER                   02000000
ICHR     EQU   9                        REGISTER WITH HIGH ORDER 3      02020000
*                                         BYTES OF ZERO.                02040000
RECR     EQU   10                       RECORD NUMBER REGISTER.         02060000
WKRA     EQU   11                       WORK REGISTER                   02080000
WKRB     EQU   12                       WORK REGISTER                   02100000
WKRC     EQU   14                       WORK REGISTER--CONTAINS RETURN  02120000
*                                         ADDRESS ON ENTRY.             02140000
WKRD     EQU   15                       WORK REGISTER--CONTAINS BASE    02160000
*                                         ADDRESS ON ENTRY.             02180000
         SPACE 1                                                        02280000
*        OPERAND USED TO OBTAIN COMPLEMENTS OF OTHER OPERANDS           02300000
         SPACE 1                                                        02320000
NOT      EQU   X'FF'                                                    02340000
         SPACE                                                          02540000
*        CHANNEL STATUS AND SENSE BYTES                                 02560000
         SPACE                                                          02580000
OVFLINC  EQU   X'01'                    OVERFLOW INCOMPLETE.            02600000
UNITEXCP EQU   X'01'                    UNIT EXCEPTION                  02620000
         SPACE                                                          02720000
*        CHANNEL COMMAND CODES                                          02740000
         SPACE                                                          02760000
TIC      EQU   X'08'                    TRANSFER IN CHANNEL.            02780000
         EJECT                                                          02900000
         USING IHADCB,DCBR                                              02920000
         USING SAMIOB,IOBR                                              02940000
         USING SAMDEB,DEBR                                              02960000
         USING IGG019C1,BASR                                            02980000
         LR    RETR,WKRC                SET UP BASE AND RETURN REGS.    03020000
         LR    BASR,WKRD                                                03040000
         L     IOBR,4(XQER)             GET ADDRESS OF IOB.             03060000
         LA    IOBR,0(IOBR)                                             03080000
         LA    WKRA,8                   DECREMENT BY EIGHT TO POINT TO  03100000
         SR    IOBR,WKRA                  SAM IOB.                      03120000
         L     DCBR,IOBDCBPT            GET ADDRESS OF DCB.             03140000
         L     DEBR,DCBDEBAD            GET ADDRESS OF DEB.             03160000
         SR    RECR,RECR                SET RECORD NUMBER TO ZERO.      03180000
         SPACE 1                                                        03200000
*   DETERMINE WHICH COMMAND WAS BEING EXECUTED WHEN THE ERROR OCCURRED  03220000
* BY FINDING ITS POSITION RELATIVE TO THE READ DATA CCW.                03240000
         SPACE 1                                                        03260000
         SR    ICHR,ICHR                CLEAR REGISTER.                 03280000
         IC    ICHR,DCBOFFSR            GET OFFSET OF READ DATA COMMAND 03300000
*                                         IN THE CURRENT IOB.           03320000
         LA    WKRA,0(IOBR)             GET IOB ADDRESS.                03340000
         AR    WKRA,ICHR                CALCULATE ADDR. OF READ DATA    03360000
*                                         COMMAND.                      03380000
         LA    WKRC,16                                                  03400000
         LR    SRGR,WKRA                GET ADDRESS OF READ DATA.       03420000
         SR    SRGR,WKRC                POINT TO SEARCH COMMAND.        03440000
         SR    SRGR,WKRC                                                03460000
         LR    WKRE,SRGR                SAVE ADDRESS OF SEARCH COMMAND. 03480000
         L     SRGR,0(SRGR)             GET ADDRESS OF SEARCH ARGUMENT. 03500000
         LA    WKRD,3                   POINT BACK TO EXTENT NUMBER.    03520000
         SR    SRGR,WKRD                                                03540000
         SPACE 1                                                        03560000
         L     WKRB,IOBCOMAD            GET ADDRESS OF COMMAND FOLLOW-  03580000
         LA    WKRB,0(WKRB)               ING LAST COMMAND EXECUTED AND 03600000
*                                         SET HIGH ORDER BITS TO ZERO.  03620000
         CR    WKRB,WKRA                WAS IT THE READ DATA CCW?       03640000
         BH    READDATA                 IF SO, BRANCH.                  03660000
         BE    NEWTRACK                 NO.    BRANCH IF IT WAS THE     03680000
*                                         READ COUNT CCW.               03700000
         SR    WKRA,WKRC                NEITHER, POINT TO READ WITH     03720000
*                                         SKIP BIT.                     03740000
         CR    WKRB,WKRA                WAS IT THE READ WITH SKIP BIT?  03760000
         BNH   NEWTRACK                 IF NOT, BRANCH.                 03780000
*                                       YES, CONTINUE                   03800000
         SPACE 1                                                        03820000
*   ERROR WAS DETECTED WHILE READING WITH THE SKIP BIT ON. DETERMINE    03840000
* WHETHER THE FINAL SEGMENT OF THE RECORD WAS BEING READ.               03860000
         SPACE 1                                                        03880000
         LA    RECR,1                   SET RECORD NUMBER TO ONE.       03900000
         TM    IOBSTAT0,UNITEXCP       WAS EOF ENCOUNTERED?             03920000
         BO    NOTOVFL                 IF SO, BRANCH--THIS MUST BE THE  03940000
*                                        FIRST READ OF A PAM DATA SET.  03960000
         TM    IOBSENS1,OVFLINC         DID ERROR OCCUR IN A SEGMENT OF 03980000
*                                         AN OVERFLOW RECORD WHICH WAS  04000000
*                                         NOT THE LAST SEGMENT?         04020000
         BZ    LASTSEG                  BRANCH IF LAST SEGMENT.         04040000
*                                       NOT LAST SEGMENT.               04060000
         SPACE 2                                                        04080021
*   THE ERROR OCCURRED IN SOME SEGMENT WHICH WAS NOT THE LAST SEGMENT   04140000
* OF AN OVERFLOW RECORD.                                                04160000
         SPACE 1                                                        04180000
*   DETERMINE WHETHER IT OCCURRED ON AN ALTERNATE TRACK.  IF SO, THE    04200000
* TRACK WILL APPEAR TO BE OUTSIDE THE CURRENT EXTENT.                   04220000
         SPACE                                                          04240000
         CLC   IOBRESTR(4),3(SRGR)      IS THE TRACK ON          A28698 04250019
*                                       WHICH THE ERROR                 04260019
*                                         OCCURRED OUTSIDE THE CURRENT  04280000
*                                         EXTENT?                       04300000
         BH    NEXTRACK                 IF SO, BRANCH.                  04320000
         SPACE 1                                                        04340000
*   THE ERROR WAS ON A PRIMARY TRACK.  USE THE ADDRESS OF THAT TRACK    04360000
* PLUS ONE TO GET A NEW SEARCH ARGUMENT.  WHEN THE CHANNEL PROGRAM IS   04380000
* STARTED AGAIN THE TRACK IN ERROR WILL NOT BE READ.                    04400000
         SPACE 1                                                        04420000
         MVC   3(4,SRGR),IOBRESTR       REPLACE OLD CCHH WITH THAT OF   04440000
*                                         THE ERROR TRACK.              04460000
         SPACE 1                                                        04480000
NEXTRACK EQU   *                                                        04500000
         SPACE 1                                                        04520000
*   IF THE ERROR WAS ON AN ALTERNATE TRACK THE ADDRESS OF THAT TRACK    04540000
* CANNOT BE USED TO CALCULATE A NEW SEARCH ARGUMENT.  THE CURRENT       04560000
* SEARCH ARGUMENT WILL BE INCREASED BY ONE AND THE CHANNEL PROGRAM      04580000
* STARTED AGAIN.  THIS ROUTINE WILL BE ENTERED REPEATEDLY UNTIL ENTRY   04600000
* IS MADE WITH THE SEARCH ARGUMENT EQUAL TO THE ADDRESS OF THE TRACK    04620000
* REPLACED BY THE ALTERNATE TRACK ON WHICH THE ERROR IS OCCURRING.      04640000
         SPACE 1                                                        04660000
         STC   RECR,7(SRGR)             SET NEW RECORD NUMBER = 1.      04680000
         BAL   SUBR,INDEPINC            GO TO ROUTINE TO INCREASE HH    04700000
*                                         BY ONE IN A DEVICE INDEPEND-  04720000
*                                         ENT MANNER.  RETURNS TO NEXT  04740000
*                                         INSTRUCTION.                  04760000
         SPACE 1                                                        04780000
RESCHED  EQU   *                                                        04800000
         SPACE 1                                                        04820000
*   START THE CHANNEL PROGRAM AGAIN AND RESTORE THE PURGED IOBS.        04840000
         SPACE 1                                                        04860000
         SR    WKRA,WKRA                POINT TO READ WITH SKIP BIT BY  04900000
         IC    WKRA,DCBOFFSR            POINTING TO READ DATA AND       04920000
         LA    WKRC,16                  SUBTRACTING 16.                 04940000
         SR    WKRA,WKRC                                                04960000
         AR    WKRA,IOBR                                                04980000
         MVI   5(WKRA),X'FF'            SET RESCHEDULE BITS ON    6M670 05000000
         LR    WKRB,WKRA                GET ADDR OF READ SKIP.          05020000
         TM    DCBCIND2,X'01'           TEST FOR QSAM             6M670 05022000
         BO    CONTINUE                 BRANCH = QSAM, NO NEED    6M670 05024000
*                                       TO SAVE ECB PTR. , ITS    6M670 05026000
*                                       ALWAYS AT SAM IOB+4       6M670 05028000
         MVC   5(3,IOBR),IOBECBPT+1     SAVE ECB PTR FOR BSAM     6M670 05030000
CONTINUE EQU   *                                                  6M670 05032000
         LA    WKRC,4                   POINT TO LAST HALF OF TIC PRE-  05040000
         SR    WKRB,WKRC                CEDING IT BY SUBTRACTING 4.     05060000
         ST    WKRB,IOBECBPT            USE THAT AS ECB FOR             05080000
*                                       THE RE-READ.                    05100000
         NI    DCBIFLGS,NOT-DCBIFEC     RESET IOS PERMANENT ERROR FLAGS 05120021
*                                         IN DCB.                       05140000
         NI    8(IOBR),X'BF'            RESET EXCEPTIONAL COND    6M670 05150000
         EXCP  8(IOBR)                  START THE CHANNEL PROGRAM.      05160000
         RESTORE DEBUSRPG               RESTORE PURGED IOBS.            05180000
         BR    RETR                                               6M670 05280000
*                                                                       05380000
         SPACE 1                                                        05400000
LASTSEG  EQU   *                                                        05420000
         SPACE 1                                                        05440000
*   THE ERROR OCCURRED ON THE LAST SEGMENT OF AN OVERFLOW RECORD OR     05460000
* THE ONLY SEGMENT OF A NORMAL RECORD.  DETERMINE WHETHER IT WAS ON AN  05480000
* ALTERNATE TRACK.                                                      05500000
         SPACE 1                                                        05520000
         CLC   IOBRESTR(4),0(SRGR)     IS THE TRACK ON WHICH THE ERROR  05540000
*                                         OCCURRED OUTSIDE THE CURRENT  05560000
*                                         EXTENT?                       05580000
         BH    NEWTRACK                 IF SO, BRANCH.                  05600000
         SPACE 1                                                        05620000
*   THE ERROR WAS ON A PRIMARY TRACK.  DETERMINE WHETHER THE RECORD WAS 05640000
* OVERFLOW OR NOT OVERFLOW.                                             05660000
         SPACE 1                                                        05680000
         CLC   IOBRESTR(4),3(SRGR)      WAS THE ERROR ON TRACK TO WHICH 05700000
*                                         THE SEARCH ARGUMENT POINTS?   05720000
         BE    NOTOVFL                  IF SO, BRANCH--THE RECORD WAS   05740000
*                                         NOT AN OVERFLOW RECORD AND    05760000
*                                         THERE IS NO NEED TO CHANGE    05780000
*                                         THE SEARCH ARGUMENT.          05800000
         SPACE 1                                                        05820000
*   THE ERROR WAS ON THE LAST SEGMENT OF AN OVERFLOW RECORD.  REPLACE   05840000
* THE HEAD ADDRESS OF THE CURRENT SEARCH ARGUMENT WITH THE HEAD ADDRESS 05860000
* OF THE TRACK ON WHICH THE ERROR OCCURRED AND SET THE RECORD NUMBER    05880000
* TO ONE.                                                               05900000
         SPACE 1                                                        05920000
         MVC   3(4,SRGR),IOBRESTR       REPLACE BOTH CYLINDER AND HEAD  05940000
*                                         ADDRESSES IN CASE NEW HEAD IS 05960000
*                                         IN NEXT CYLINDER.             05980000
         STC   RECR,7(SRGR)             SET RECORD NUMBER TO ONE.       06000000
         SPACE 1                                                        06020000
*   CHANGE THE READ SKIP COMMAND TO A NOP.  THE READ SKIP IS NECESSARY  06040000
* ONLY IF THERE IS  MORE THAN ONE SEGMENT TO PASS OVER BEFORE READING   06060000
* THE COUNT OF THE DATA RECORD.  AT THIS POINT IT IS KNOWN THAT THERE   06080000
* IS ONLY ONE SEGMENT.                                                  06100000
         SPACE 1                                                        06120000
NOTOVFL  EQU   *                                                        06140000
         SPACE 1                                                        06160000
         LA    WKRC,8(WKRA)             POINT TO CCW FOLLOWING READ     06180000
*                                         WITH SKIP BIT.                06200000
         ST    WKRC,0(WKRA)             REPLACE READ WITH SKIP BIT WITH 06220000
*                                         A TIC TO THE NEXT CCW.        06240000
         LA    WKRC,TIC                 GET TIC COMMAND CODE.           06260000
         STC   WKRC,0(WKRA)             STORE AS OP CODE.               06280000
         B     RESCHED                  RESCHEDULE THIS IOB.            06300000
         SPACE 1                                                        06320000
*   THE ERROR OCCURRED WHILE READING THE DATA RECORD.                   06340000
         SPACE 1                                                        06360000
READDATA EQU   *                                                        06380000
         SPACE 1                                                        06400000
         TM    IOBSENS1,OVFLINC         DID ERROR OCCUR IN A SEGMENT    06420000
*                                         WHICH WAS THE LAST SEGMENT    06440000
*                                         OF THE RECORD?                06460000
         BZ    POST                     IF SO, BRANCH.                  06480000
*                                       NO, CONTINUE.                   06500000
         CLC   IOBRESTR(4),3(SRGR)      IS THE TRACK ON          A28698 06510019
*                                       WHICH THR ERROR                 06520019
*                                         OCCURRED OUTSIDE THE CURRENT  06540000
*                                         EXTENT?                       06560000
         BH    NEWTRACK                 IF SO, BRANCH--IT MUST HAVE     06580000
*                                         BEEN AN ALTERNATE TRACK.      06600000
         L     WKRB,24(WKRE)            GET ADDRESS, IN NEXT IOB, INTO  06620000
*                                         WHICH THE ID WAS READ.        06640000
         MVC   0(4,WKRB),IOBRESTR       USE ADDRESS OF ERROR TRACK      06660000
*                                         RATHER THAN ADDRESS OF FIRST  06680000
*                                         SEGMENT OF DATA RECORD.       06700000
         B     STOR                                                     06720000
         SPACE 1                                                        06740000
NEWTRACK EQU   *                                                        06760000
         SPACE 1                                                        06780000
*   IF THE READ DATA FAILED, THE NEXT IOB CONTAINS THE CCHHR OF THE     06800000
* FIRST SEGMENT OF THE DATA RECORD ITSELF.  IF ANY OTHER COMMAND        06820000
* FAILED, IT IS NECESSARY TO USE THE ORIGINAL SEARCH ARGUMENT (INCRE-   06840000
* MENTED BY ONE LATER).                                                 06860000
         SPACE 1                                                        06880000
         L     WKRB,24(WKRE)            GET ADDRESS IN NEXT IOB, INTO   06900000
*                                         WHICH THE ID OF THE RECORD IN 06920000
*                                         ERROR WAS WAS TO BE READ.     06940000
         MVC   0(4,WKRB),3(SRGR)        MOVE CURRENT CCHH THERE.        06960000
         SPACE 1                                                        06980000
STOR     EQU   *                                                        07000000
         SPACE 1                                                        07020000
         LR    SRGR,WKRB                POINT SEARCH ARGUMENT REGISTER  07040000
*                                         TO NEXT IOB.                  07060000
         SH    SRGR,MBBLEN              PT TO MBB BEFORE CCHHR  SA69163 07070021
         STC   RECR,4(WKRB)             STORE NEW RECORD NUMBER IN      07080000
*                                         NEXT IOB.                     07100000
         BAL   SUBR,INDEPINC            GO TO ROUTINE TO INCREASE HH    07120000
*                                         BY ONE IN A DEVICE INDEPEND-  07140000
*                                         ENT MANNER.  RETURNS TO NEXT  07160000
*                                         INSTRUCTION.                  07180000
         SPACE 1                                                        07200000
POST     EQU   *                                                        07220000
         SPACE 1                                                        07240000
*   POST THE ECB WITH THE ERROR CODE IOS WOULD HAVE POSTED AND RETURN.  07260000
         SPACE 1                                                        07280000
         L     ZROR,IOBECBPT            GET ERROR CODE TO POST.         07300000
         SPACE                                                          07320000
         L     XQER,IOBECBPT            GET ADDRESS OF ECB.             07380000
         LA    XQER,0(XQER)            CLEAR HIGH ORDER BYTE     A39795 07390020
         POST  (1),(0)                  POST THE ECB.                   07400000
         BR    RETR                                                     07420000
         SPACE 1                                                        07440000
INDEPINC EQU   *                                                        07460000
         SPACE 1                                                        07480000
*   THIS SUBROUTINE WILL USE THE RESIDENT CONVERT ROUTINE TO CONVERT    07500000
* MBBCCHHR TO TTR, ADD ONE TO TT, AND CONVERT THE NEW TTR TO MBBCCHHR.  07520000
         SPACE 1                                                        07540000
         USING CVT,WKRD                                                 07560000
         LR    XQER,DEBR                GIVE DEB ADDRESS TO CONVERT     07580000
*                                         ROUTINE IN REGISTER 1.        07600000
         L     WKRD,CVTPTR              GET ADDRESS OF CONVERT ROUTINE  07620000
         L     WKRD,CVTPRLTV              FROM CVT (MBBCCHHR TO TTR).   07640000
         BALR  WKRC,WKRD                GO TO CONVERT ROUTINE.          07660000
         L     WKRA,TTINC               ADD ONE TO IT.                  07680000
         ALR   ZROR,WKRA                                                07700000
         L     WKRD,CVTPTR              GET ADDRESS OF CONVERT ROUTINE  07720000
         L     WKRD,CVTPCNVT              (TTR TO MBBCCHHR).            07740000
         BALR  WKRC,WKRD                GO TO CONVERT RTN.              07760000
         BR    SUBR                     RETURN.                         07780000
         SPACE 1                                                        07800000
*        CONSTANTS                                                      07820000
         SPACE 1                                                        07840000
         DS    0F                                                       07860000
TTINC    DC    X'00010000'              USED TO INCREMENT TT BY ONE.    07880000
MBBLEN   DC    H'3'                     LEN OF MBB IN MBBCCHHR  SA69163 07890021
         CNOP  0,8                      PAD TO DBL WD LENGTH.           07900000
         SPACE 1                                                        07920000
SAMIOB   DSECT                                                          07940000
IOBSAMFL DS    0BL1                     SAM IOB USE FLAGS.              07960000
IOBLINK  DS    F                        ADDR. OF NEXT IOB IN THE CHAIN. 07980000
IOBQECB  DS    F                        QSAM ECB--SPARE SPACE IN BSAM.  08000000
IOBFLAG1 DS    BL1                      IOS FLAGS.                      08020000
IOBFLAG2 DS    BL1                      IOS FLAGS.                      08040000
IOBSENS0 DS    BL1                      SENSE BYTE ZERO.                08060000
IOBSENS1 DS    BL1                      SENSE BYTE ONE.                 08080000
IOBECBPT DS    F                        ECB/DECB ADDRESS.               08100000
IOBCSW   DS    0D                       CHANNEL STATUS WORD.            08120000
IOBCOMAD DS    F                          KEY/X'0'/COMMAND ADDRESS.     08140000
IOBSTAT0 DS    BL1                        STATUS BYTE ZERO.             08160000
IOBSTAT1 DS    BL1                        STATUS BYTE ONE.              08180000
IOBCNT   DS    BL2                        RESIDUAL COUNT.               08200000
IOBSIOCC DS    0BL1                                                     08220000
IOBSTART DS    F                        CHANNEL PROGRAM START ADDRESS.  08240000
IOBWGHT  DS    0BL1                                                     08260000
IOBDCBPT DS    F                        DCB ADDRESS.                    08280000
IOBRESTR DS    F                                                        08300000
IOBINCAM DS    BL2                      BLOCK COUNT INCREMENT.          08320000
IOBERRCT DS    BL2                      ERROR COUNT.                    08340000
IOBSEEK  DS    0D                       FULL DISK ADDRESS.              08360000
IOBSKM   DS    BL1                        EXTENT ID.                    08380000
IOBSKBB  DS    BL2                        BIN NUMBER.                   08400000
IOBSKCC  DS    BL2                        CYLINDER.                     08420000
IOBSKHH  DS    BL2                        TRACK.                        08440000
IOBSKR   DS    BL1                        RECORD NUMBER.                08460000
IOBCP    DS    0D                                                       08480000
         SPACE                                                          08500000
*        DEB AS DEFINED IN SYSTEM CONTROL BLOCKS MANUAL.                08520000
SAMDEB   DSECT                                                          08540000
         SPACE 1                                                        08560000
DEBNMSUB DS    0BL1                                                     08580000
DEBTCBAD DS    F                                                        08600000
DEBAMLNG DS    0BL1                                                     08620000
DEBDEBAD DS    F                                                        08640000
DEBOFLGS DS    0BL1                                                     08660000
DEBIRBAD DS    F                                                        08680000
DEBOPATB DS    0BL1                                                     08700000
DEBSYSPG DS    F                                                        08720000
DEBNMEXT DS    0BL1                                                     08740000
DEBUSRPG DS    F                                                        08760000
DEBPRIOR DS    0BL1                                                     08780000
DEBECBAD DS    F                                                        08800000
DEBPROTG DS    0BL1                                                     08820000
DEBDEBID DS    0BL1                                                     08840000
DEBDCBAD DS    F                                                        08860000
DEBEXSCL DS    0BL1                                                     08880000
DEBAPPAD DS    F                                                        08900000
DEBDVMOD DS    0BL1                                                     08920000
DEBUCBAD DS    F                                                        08940000
RESERVED DS    H                                                        08960000
DEBSTRCC DS    H                                                        08980000
DEBSTRHH DS    H                                                        09000000
DEBENDCC DS    H                                                        09020000
DEBENDHH DS    H                                                        09040000
DEBNMTRK DS    H                                                        09060000
         SPACE 1                                                        09080000
         DCBD  DSORG=PS                                                 09100000
         SPACE 1                                                        09120000
CVT      DSECT                                                          09140000
         CVT                                                            09160000
         END                                                            09180000
