         MACRO                                                          00020000
&NAME    IF    &A,&IS=,&ISNOT=,&GOTO=                                   00040000
         LCLB  &NOERR                                                   00060000
&NOERR   SETB  1                                                        00080000
         AIF   ('&A' NE '').SKIP                                        00100000
         MNOTE 'TEST  ADDRESS NOT SPECIFIED.'                           00120000
&NOERR   SETB  0                                                        00140000
.SKIP    AIF   ('&GOTO' NE '').SKIP2                                    00160000
         MNOTE 'BRANCH ADDRESS MISSING.'                                00180000
&NOERR   SETB  0                                                        00200000
.SKIP2   AIF   ('&IS' NE '' OR '&ISNOT' NE '').SKIP3                    00220000
         MNOTE 'TEST CONDITION NOT SPECIFIED.'                          00240000
&NOERR   SETB  0                                                        00260000
.SKIP3   AIF   (&NOERR).SKIP4                                           00280000
         MEXIT                                                          00300000
.SKIP4   AIF   ('&IS' EQ '').NOIS                                       00320000
***                                                                     00340000
&NAME    TM    &A,&IS                                                   00360000
         BO    &GOTO                                                    00380000
***                                                                     00400000
         MEXIT                                                          00420000
.NOIS    ANOP                                                           00440001
***                                                                     00460000
&NAME    TM    &A,&ISNOT                                                00480000
         BZ    &GOTO                                                    00500000
***                                                                     00520000
         MEND                                                           00540000
IGG019C2 CSECT                                                          00560000
*7004 1040-1048                                                    000D 00570013
*                                                                       00580000
*              RELEASE 18 DELETIONS                                   * 00581018
*1633111000                                                       22209 00581218
*1633101400,119800                                                22837 00581518
*1633121800                                                       23227 00582018
*1633                                                             M2057 00582518
*              RELEASE 19 DELETIONS                                   * 00583018
*              RELEASE 20 DELETIONS                                   * 00584018
*2341094600                                                      A32558 00584520
*2341093120,093200                                               A34460 00584720
*2341035400,055600,056600,090000,096200,135200,136600            20201  00584820
*                                                                XM4343 00585003
*STATUS CHANGE LEVEL 003                                                00594020
         TITLE 'IGG019C2, EOB RTN FOR D.A. OUTPUT WITH TRK OVFLOW.'     00600000
*FUNCTION/OPERATION - DETERMINES WHETHER CURRENT RECORD TO BE WRITTEN * 00620000
*   OR READ(F STANDARD) WILL FIT ON CURRENT TRACK. THIS CALCULATION   * 00640000
*   ASSUMES THIS RECORD WILL BE LAST ON TRACK. IF RECORD WILL FIT,    * 00660000
*   SPACE REQUIRED IS RECALCULATED ASSUMING RECORD IS NOT THE LAST.   * 00680000
*   DCBTRACKBALANCE IS REDUCED BY THIS AMOUNT. IF RECORD WILL NOT FIT * 00700000
*   THE NEXT SEQUENTIAL TRACK IS FOUND. IF NONE EXISTS,AN EOV         * 00720000
*   CONDITION IS SIMULATED. FOR STANDARD F THE SEEK ADDRESS IN THE IOB* 00740000
*   IS INCEMENTED BY ONE SINCE SEARCH DIRECT IS USED.                 * 00760000
*                                                                     * 00780000
* ENTRY POINTS - IGG019C2 FROM ALL GET, PUT, READ/WRITE MODULES.        00800000
*               LA   2,DCB                                            * 00820000
*               LA   3,IOB                                            * 00840000
*               L    4,DCBOFFSR  OR DCBOFFSW                          * 00860000
*               L   15,76(2)    FOR WRITE(BSAM)                       * 00880000
*               L   15,92(2)    FOR QSAM                              * 00900000
*               BALR 14,15                                            * 00920000
*                                                                     * 00940000
*INPUT - IOB                                                          * 00960000
*         IOB+OFFSET - RECORD LENGTH IN CCW                           * 00980000
*        DCB                                                          * 01000000
*         DCBDVTBL - POINTS TO DEVICE ENTRY IN IECZDTAB               * 01020000
*         DCBDEB AD - DEBADDRESS                                      * 01040000
*         DCBTRBAL - BYTES REMAINING ON TRACK                         * 01060000
*         DCBFDAD  - POINTS TO LAST RECORD READ OR WRITTEN            * 01080000
*         DCBKEYLE - KEYLENGTH - ADDED TO BLKSIZE FOR TOTAL LENGTH    * 01100000
*         DCBCIND1 - VOL.FULL BIT ON - INDICATES PREVIOUS WRITE EOV   * 01120000
*        DEB                                                          * 01140000
*         DEBNMEXT - NUMBER OF EXTENTS IN DEB                         * 01160000
*         DEBOFLGS - X'04' MEANS SPLIT CYL EXTENTS                    * 01180000
*         DEBSTRCC AND DEBSTRHH - STARTING CCHH OF EXTENT             * 01200000
*         BEBENDCC AND DEBENDHH - ENDING CCHH OF EXTENT               * 01220000
*        IECZDTAB - I/O DEVICE TABLE                                  * 01240000
*                   LAST RECORD OV'HD                                 * 01260000
*                   NOT LAST RECORD OV'HD                             * 01280000
*                   KEY OV'HD                                         * 01300000
*                   MAX,TRACK LENGTH                                  * 01320000
*                   TOLERANCE                                         * 01340000
*                                                                     * 01360000
* OUTPUT - ECB - POSTED IN ERROR IF EOV .                               01380000
*        DCBTRBAL - UPDATED REMAING TRACK LENGTH                      * 01400000
*        DCBFDAD - UPDATED RECORD ADDRESS = LAST SEGMENT                01420000
*        IOBSEEK - RECORD ADDRESS = FIRST SEGMENT                       01440000
*        IOB+20   - UNIT EXCEP. IN CSW SET FOR EOV                    * 01460000
*                                                                     * 01480000
* EXTERNAL ROUTINES - SVC 25  ENTERED WITH THE TRACK OVERFLOW BIT IN    01500000
*                     DCBCIND2 SET- PURPOSE IS TO ERASE TO EOE.         01520000
*                    THE ORIGINAL TRACK BALANCE,SAVED BEFORE BEGINNING* 01524020
*                    THE CHAN PGM FOR RECORD THAT DOES NOT FIT, IS PAS* 01528020
*                    SED TO THE ERASE ROUT IN REG 0. DCBTRBAL FIELD   * 01532020
*                    IS USED FOR THE CURRENT CHAN PGM BEING BUILT     * 01536020
*                                                                     * 01540000
         EJECT                                                          01560000
*EXITS/NORMAL - RETURN TO GET/PUT/WRITE/READ ROUTINE ON REG.14 AFTER  * 01580000
*               SCHEDULING I/O,OR POSTING ECB COMPLETE,ERROR IF EOV   * 01600000
*                                                                     * 01620000
*EXITS/ERROR - ABEND - CODE 00002000 - ISSUED IF-                     * 01640000
*          1.RECORD SIZE EXCEEDS 32,760                               * 01660000
*                                                                     * 01680000
*TABLES/WORK AREAS - ASSUMES USER REGS.2-8 SAVED.SAVES REGS.9-10 INTO * 01700000
*                    SAVE AREA + 64                                     01720000
*                                                                     * 01740000
*ATTRIBUTES - READONLY,REENTRANT,REUSABLE                             * 01760000
* REGISTER NAMES AND USAGE.                                             01780000
*                                                                       01800000
RALPHA   EQU   0                        WORK REG. ALPHA MAY NOT BE USED 01820000
*                                       AS AN ADDRESS REG.              01840000
R1       EQU   1                        THE NAME PRESERVES IDENTITY.    01860000
RDEB     EQU   1                        DEB ADDRESS LOADED IN THIS RTN. 01880000
RGAMMA   EQU   4                        WORK REG.                       01900000
RDELTA   EQU   5                        WORK REG.                       01920000
RSTEPPER EQU   RDELTA                   STEPS THRU COUNT FLD AND S.A.'S 01940000
RSIGMA   EQU   6                        WORK REG.                       01960000
RCPBASE  EQU   RSIGMA                   CP SEGMENT BASE REG.            01980000
*                                                                       02000000
RDCB     EQU   2                        HOLDS DCB ADDRESS UPON ENTRY.   02020000
RIOB     EQU   3                        HOLDS IOB ADDRESS UPON ENTRY.   02040000
ROFFSW   EQU   7                        HOLDS WRITE CCW OFFSET ON ENTRY 02060000
*              BUT WILL BE CLOBBERED, AND RESTORED FROM DCB PROIR TO    02080000
*              EXIT.  REG MUST BE X-PARENT FOR QSAM.                    02100000
ROVFLO   EQU   ROFFSW                   CCW OFFSET KNOWN. OVFLO =       02120000
*                                       LENGTH REMAINING TO BE WRITTEN. 02140000
RBETA    EQU   9                        SAVED FIRST, USED AS WORK REG.  02160000
RDEVTAB  EQU   10                       SAVED FIRST, DEVTABLE ADDRESS   02180000
*                                       LOADED.                         02200000
RSAVE    EQU   13                       USERS REGISTER SAVE AREA.       02220000
RRETN    EQU   14                       RETURN TO BSAM/QSAM RTN.        02240000
RBASE    EQU   15                       ENTRY-POINT/BASE REG.           02260000
*                                                                       02280000
DONTUSE8 EQU   8                        NOT SAVED. HOLDS USER CONTENTS. 02300000
OR11     EQU   11                       NOT SAVED. HOLDS USER CONTENTS. 02320000
OR12     EQU   12                       NOT SAVED. HOLDS USER CONTENTS. 02340000
*                                                                       02360000
*                                                                       02380000
UNITEXC  EQU   X'01'                    SETS IOBFLAG3.                  02400000
COMPWERR EQU   X'42'                    END OF EXTENT CONDITION HAS     02420000
*                                       BEEN ENCOUNTERED.               02440000
CPSEGLEN EQU   32                       LENGTH OF ONE CP SEGMENT.       02460000
D0       EQU   0                        DISPLACEMENT OF ZERO     20201  02462020
B1       EQU   1                        BYTE COUNT OF ONE        20201  02464020
B4       EQU   4                        BYTE COUNT OF FOUR       20201  02466020
D8       EQU   8                        DISPLACEMENT OF EIGHT    20201  02468020
D12      EQU   12                       DISPLACEMENT OF TWELVE   20201  02470020
D16      EQU   16                       DISPLACEMENT OF SIXTEEN  20201  02472020
D20      EQU   20                       DISPLACEMENT OF 20       20201  02474020
TBOVHD   EQU   X'08'                    FLAG INDICATIN TWO       20201  02476020
*                                       BYTE OVERHEAD                   02478020
EIGHT    EQU   8                        LENGTH OF A COUNT FIELD         02480000
RLTV     EQU   32                       VECTOR OFFSET IN CVT.           02500000
CNVT     EQU   28                       VECTOR OFFSET IN CVT.           02520000
ZERO     EQU   0                        G.P. CONSTANT.                  02540000
TRKOVFLO EQU   X'80'                    T.O. INDICATOR IN DCBCIND1      02560000
NOERROR  EQU   X'7F'                    ECB MASK. ALL BITS ON = NOERROR 02580000
ANYZERO  EQU   14                       MASK FOR TESTING ANY SELECTED   02600000
*                                       BITS = ZERO.                    02620000
ONES     EQU   X'FF'                    G.P. CONSTANT.                  02640000
VOLFULL  EQU   X'20'                                                    02660000
IOBSIZE  EQU   48                       STANDARD IOB + BSAM/QSAM EXTEN. 02680000
VALCHK   EQU   X'80'                    WRITE VALIDITY CHECK BIT IN     02700000
*                                       DCBOPTCD.                       02720000
SPLIT    EQU   X'04'                                                    02740000
* COMMAND CODES FOR THE 2841 C.U.                                       02760000
*                                                                       02780000
SEEKCYL  EQU   X'0B'                    CYLINDER SEEK.                  02800000
SRCHEQMT EQU   X'B1'                    SEARCH EQ ID IN MULTI-TRACK.    02820000
WCKD     EQU   X'1D'                    WRITE COUNT, KEY AND DATA.      02840000
WSCKD    EQU   1                        WRITE SPECIAL OP CODE.          02860000
SETSC    EQU   X'23'                    SET SECTOR COMMAND       20201  02862020
RDSC     EQU   X'22'                    READ SECTOR COMMAND      20201  02864020
TIC      EQU   X'08'                    TIC CCW OP CODE          20201  02866020
PERMERR  EQU   X'C0'                    PERM ERR POSTING IN DCB  XM4343 02866403
ONEIOB   EQU   X'01'                    ONE IOB INDICATOR        XM4343 02866803
ECBADDR  EQU   12                       OFFSET IN IOB TO ECB     XM4343 02867203
CSWSTAT  EQU   20                       OFFSET IN IOB TO CSW     XM4343 02867603
CSWSTAT1 EQU   21                          STATUS BYTES          XM4343 02867703
PGMCHK   EQU   X'20'                    PGM CHK INDICATOR        XM4343 02867803
ERROR    EQU   X'40'                    ECB ERROR POSTING        XM4343 02867903
*                                                                       02868020
*                                                                       02870020
*                                                                       02872020
* CCW FLAGS                                                             02880000
CC       EQU   X'40'                    COMMAND CHAIN.                  02900000
*                                                                       02920000
         USING IGG019C2,RBASE                                           02940000
         USING SAMSIOB,RIOB                                             02960000
         USING IHADCB,RDCB                                              02980000
*                                                                       03000000
         STM   RBETA,RDEVTAB,64(RSAVE)  SAVE USERS 9 AND 10.            03020000
*                                                                       03040000
         IF    DCBCIND1,IS=VOLFULL,GOTO=POSTECB                         03060000
*                                                                       03080000
*      FOR BSAM, INOUT OR OUTIN, AN INVALID I/O REQUEST MAY             03090003
*      HAVE BEEN ISSUED.  THIS ROUTINE CHECKS FOA AN INVALID            03092003
*      REQUEST AGAINST AN IOB AND POSTS IT IN ERROR.                    03094003
*                                                                       03096003
         TM    DCBIFLGS,PERMERR         DCB POSTED IN PERM ERR   XM4343 03098003
         BZ    CONTIN                   NO CONTINUE              XM4343 03098403
         CLI   DCBNCP,ONEIOB            ONE IOB PRESENT?         XM4343 03098803
         BNE   CONTIN                   NO - IOS WILL POST ERR   XM4343 03099203
         L     RGAMMA,ECBADDR(RIOB)     GET ECB                  XM4343 03099603
         MVI   0(RGAMMA),ERROR          POST ECB IN ERROR        XM4343 03099703
         OI    CSWSTAT(RIOB),PGMCHK     SET PGM CHK IN CSW       XM4343 03099803
         MVI   CSWSTAT1(RIOB),X'00'     CLEAR CSW FIRST BYTE     XM4343 03099903
         BR    RRETN                    RETURN TO USER           XM4343 03106603
CONTIN   EQU   *                                                 XM4343 03108603
         SR    RCPBASE,RCPBASE                                          03113300
         IC    RCPBASE,DCBWCPO          BUILD WRITE CHANNEL PGM         03120000
         AR    RCPBASE,RIOB             ADDRESSABILITY.                 03140000
         USING WCPMAP,RCPBASE                                           03160000
* WORK REG SIGMA IS IN USE AS 'RCPBASE'.                                03180000
         SR    RSTEPPER,RSTEPPER                                        03200000
         IC    RSTEPPER,DCBWCPL         NUMBER OF CCW'S BETWEEN IOB AND 03220000
*                                       FIRST COUNT FIELD.              03240000
         SLL   RSTEPPER,3               DBL WDS TO BYTES.               03260000
*                                                                       03280000
         AR    RSTEPPER,RCPBASE         CP START ADDR + ITS LENGTH      03300000
*                                       GIVES ADDRESSABILITY FOR COUNT  03320000
*                                       FIELDS AND S.A.'S. (THEY ARE    03340000
*                                       INTERLEAVED, WITH A COUNT FIELD 03360000
*                                       BEING FIRST, EACH IS A DBL WD). 03380000
         USING COUNTFLD,RSTEPPER                                        03400000
* WORK REG DELTA IS IN USE AS 'RSTEPPER'.                               03420000
         L     RDEVTAB,DCBDVTBL         ADDRESS OF DEV TABLE ENTRY FOR  03440000
*                                       THIS UNIT.                      03460000
         USING DEVTAB,RDEVTAB                                           03480000
*                                                                       03500000
         L     RDEB,DCBDEBAD            DEB ADDRESSABILITY.             03520000
*                                                                       03524020
* CHECK FOR RCD READY FEATURE BEING USED AND IF NOT ADJUST              03528020
* RCPBASE, IF YES, UPDATE SECTOR VALUE                                  03532020
*                                                                       03536020
         CLI   CHANPGM,SETSC            RCD READY CHP            20201  03540020
         BNE   NOFET3                   BRANCH IF NO             20201  03544020
         AH    RCPBASE,ATE8             ADJUST RCPBASE FOR RCD   20201  03548020
*                                       READY FEAT                      03552020
NOFET3   EQU   *                                                 20201  03556020
*                                                                       03560000
         L     ROVFLO,DATALEN-2         GET COMPOSITE KL+DL FROM CCW.   03580000
         LA    ROVFLO,0(ROVFLO)         CLEAR OUT THE FLAGS.            03600000
         LR    RBETA,ROVFLO             TEMP WORK REG.                  03620000
         SR    RALPHA,RALPHA                                            03640000
         IC    RALPHA,DCBKEYLE          TO REMOVE KL FROM KL+DL.        03660000
         SR    RBETA,RALPHA             BETA=DL.                        03680000
         CH    RBETA,DCBBLKSI           ABEND IF RECORD LENGTH          03700000
         BH    ABEND                    GREATER THAN BLKSIZE.           03720000
         LA    RBETA,7(RBETA)           MAKES POSSIBLE AN LTR FOR       03740000
*                                       DL GT 32760.                    03760000
         SLL   RBETA,16                 ALIGN FOR SIGN TEST.            03780000
         LTR   RBETA,RBETA              DL+7 MUST BE LESS THAN 32768.   03800000
         BM    ABEND                    BRANCH IF DL GT 32760           03820000
*                                                                       03840000
         LA    RALPHA,2                 LENGTH OF CCW LENGTH FIELD.     03860000
         LR    RBETA,RSTEPPER           COPY REG.                       03880000
         CLI   CHANPGM,SETSC            RCD READY CHP            20201  03882020
         BNE   NOFET4                   BRANCH IF NO             20201  03884020
         TM    DCBOPTCD,VALCHK          VALIDITY CHK USED        20201  03886020
         BO    NOFET4                   BRANCH IF YES            20201  03888020
         AH    RALPHA,ATE8              INCREMENT FOR RD SECTOR  20201  03890020
NOFET4   EQU   *                                                 20201  03892020
         SR    RBETA,RALPHA             BETA POINTS TO THE LAST CCW     03900000
*                                       LENGTH FIELD. (MAY OR MAY NOT   03920000
*                                       BE THE WRITE VALIDITY CHECK     03940000
*                                       SEGMENT).                       03960000
*                                                                       03980000
         STH   ROVFLO,0(RBETA)          USING THE LAST CCW LENGTH TO    04000000
*                                       SAVE THE OVFLO AMOUNT. USED TO  04020000
*                                       RECOVER AFTER GETTING A NEW     04040000
*                                       EXTENT,  IS ALSO  THE WRITE     04060000
*                                       VALIDITY CHECK LENGTH IF THE    04080000
*                                       VAL CHK CP EXISTS.              04100000
         MVC   TEMPSAVE(2),DCBTRBAL     PRESERVE THE ORIGINAL TRK BAL.  04120000
*                                       WILL BE RESTORED IF A RECORD    04140000
*                                       CANNOT BE WRITTEN.              04160000
SETFDAD  MVC   IOBFDAD(8),DCBFDAD       COPY FDAD INTO IOB.             04180000
RUPBY1   IC    RBETA,DCBFDAD+7          GET 'R'.                        04200000
         LA    RBETA,1(RBETA)           R=R+1.                          04220000
         STC   RBETA,DCBFDAD+7          PUT IT BACK.                    04240000
*                                                                       04260000
         MVC   CYLINDER(5),DCBFDAD+3    INITIALIZE THE ID PART OF THE   04280000
*                                       FIRST COUNT FIELD.              04300000
*                                                                       04320000
* END OF FIRST TIME LOGIC.                                              04340000
*                                                                       04360000
* BEGIN LOOP LOGIC.                                                     04380000
*                                                                       04400000
* CALCULATE THE SPACE REQUIRED TO WRITE THE DATA AS A LAST RECORD.      04420000
*                                                                       04440000
STRTLOOP SR    RBETA,RBETA                                              04460000
         SR    RALPHA,RALPHA                                            04480000
         IC    RBETA,OVERL              L = OVHD FOR LAST RECORD.       04500000
         TM    DEVFLAG,TBOVHD           USING TWO BYTE OVHD      20201  04504020
         BNO   MZ0010                   BRANCH NO                20201  04508020
         LH    RBETA,OVERI              GET TWO BYTE OVHD        20201  04512020
MZ0010   EQU   *                                                 20201  04516020
         IC    RALPHA,DCBKEYCN          KEYCN = EITHER 0 OR K (IF OR    04520000
*                                       IF NOT KEYS, RESPECTIVELY).     04540000
         LR    RGAMMA,ROVFLO            COPY THE AMOUNT REMAINING TO    04560000
*                                       BE WRITTEN (OVERFLOW).          04580000
         AR    RGAMMA,RBETA             OVFLO+L                         04600000
         SR    RGAMMA,RALPHA            OVFLO+L-KEYCN IS THE SPACE FOR  04620000
*                                       A LAST RECORD.                  04640000
*                                                                       04660000
         CH    RGAMMA,DCBTRBAL          WILL THIS TRACK HOLD THE RECORD 04680000
         BNH   FINAL                    YES. BRANCH TO DO FINAL LOGIC   04700000
*                                       FOR THE LAST CP SEGMENT.        04720000
*                                                                       04740000
* RECORD WILL NOT FIT AS A LAST RECORD. CALCULATE HOW MUCH WILL FIT AND 04760000
* TAILOR THE CURRENT CP SEGMENT TO WRITE THAT AMOUNT. AT LEAST ONE MORE 04780000
* RECORD SEGMENT WILL BE WRITTEN AFTER THIS ONE.                        04800000
* CCWLENGTH=TRBAL+KEYCN-L IS AMOUNT THAT WILL FIT.                      04820000
         LH    RGAMMA,DCBTRBAL          GET TRACK BAL.                  04840000
         AR    RGAMMA,RALPHA            TRBAL+KEYCN.                    04860000
         SR    RGAMMA,RBETA             TRBAL+KEYCN-L IN GAMMA.         04880000
MIDLOOP  MVC   DCBTRBAL,TRKCAP          RESET TRBAL TO DEVICE MAX.      04900000
         NI    TRACKFUL,ZERO            HOUSEKEEP TRACK FULL SWITCH.    04920000
         LTR   RGAMMA,RGAMMA            SEE IF ANY DATA CAN BE WRITTEN. 04940000
         BP    WILLFIT                  BRANCH IF ROOM FOR DATA.        04960000
         OI    TRACKFUL,ONES            SET TRACK FULL SWITCH. OCCURS   04980000
*                                       ONLY IF FIRST TRACK HAS NO ROOM 05000000
*                                       FOR DATA. ACTION REQ'D IS TO    05020000
*                                       ADVANCE TO NEXT TRACK.          05040000
         B     CONVERT                  NO ROOM FOR DATA. OVERHEAD      05060000
*                                       EXCEEDS TRK BAL.  GET A NEW     05080000
*                                       TRACK.                          05100000
WILLFIT  SR    ROVFLO,RGAMMA            REDUCE THE OVFLO FIGURE BY THE  05120000
*                                       CURRENT TRACK LENGTH.           05140000
*                                                                       05160000
         MVI   WRTOPCD,WSCKD            WRITE SPECIAL BECAUSE THIS IS   05180000
*                                       NOT THE LAST SEGMENT.           05200000
         MVI   NULLFLAG,CC              COMMAND CHAIN TO NEXT SEGMENT.  05220000
         STH   RGAMMA,DATALEN           PUT SEGMENT LENGTH IN WRT CCW.  05240000
         SR    RALPHA,RALPHA                                            05260000
         IC    RALPHA,KEYLENTH          KEY LENGTH FROM COUNT FIELD.    05280000
         SR    RGAMMA,RALPHA            DATA LEN= SEG LEN - KL.         05300000
         STH   RGAMMA,DLDL              PUT IT IN COUNT FLD DATA LENGTH 05320000
         AR    RGAMMA,RALPHA            RECONSTRUCT SEGMENT LENGTH.     05340000
*                                                                       05360000
         L     RBETA,DATAADDR           GET THE DATA ADDRESS            05380000
         LA    RBETA,0(RBETA)           CLEAR HI BYTE.                  05400000
         AR    RGAMMA,RBETA             ADDRESS+LENGTH=NEXT ADDRESS.    05420000
*                                                                       05440000
         LA    RCPBASE,CPSEGLEN(RCPBASE) ADVANCE CP BASE TO NEXT SEG.   05460000
         LA    RSTEPPER,EIGHT(RSTEPPER)  POINTS TO S.A. THE 'CCHHR' OF  05480000
*                                       THE COUNTFLD DSECT IS VALID.    05500000
         ST    RGAMMA,DATAADDR          THIS DATA ADDRESS = LAST + LEN. 05520000
         MVI   SRCHOPCD,SRCHEQMT        OP CODE SET FOR MULTI-TRACK     05540000
*                                                                       05548020
         CLI   CHANPGM,SETSC            RCD READY CHANNEL PROG   20201  05556020
         BE    FEATX                    BRANCH IF YES            20201  05564020
*                                                                       05572020
*                                                                       05580000
         IF    DCBOPTCD,ISNOT=VALCHK,GOTO=CONVERT                       05600000
* RECONSTRUCT THE FIRST CCW SEARCH ADDRESS. REASON- IT MAY HAVE BEEN    05620000
* CHANGED TO A TIC TO WRT CHK CP ON A PREVIOUS USE.                     05640000
*                                                                       05650020
FEATX    EQU   *                                                 20201  05660020
*                                                                       05670020
         MVC   SRCHADDR+1(3),PARASITE+1 THE CORRECT SEARCH ADDRESS HAS  05680000
*                                       BEEN A PARASITE IN THE TIC CCW. 05700000
*                                                                       05720000
CONVERT  EQU   *                                                        05740000
* THE DCB FULL DISK ADDRESS MUST BE UPDATED TO THE ADDRESS OF THE NEXT  05760000
* TRACK, ON WHICH THE NEXT RECORD SEGMENT WILL BE WRITTEN. THE NEXT     05780000
* TRACK MAY BE ACCROSS A CYLINDER BOUNDARY, SO THE DISK ADDRESS IS      05800000
* UPDATED IN THE TTR FORM. THE CONVERT ROUTINE ALSO PROVIDES VALIDITY   05820000
* CHECKING OF THE NEW FDAD.                                             05840000
*                                                                       05860000
         LA    RGAMMA,FDADTTR           THIS IS A CONCEALED ENTRY TO A  05880000
*                                       CLOSED SUBROUTINE.              05900000
*********************************************************************** 05920000
*        THE FOLLOWING ROUTINE WILL DETERMINE THE NEXT TRACK ADDRESS. * 05940000
*        BY ADDING 1 TO THE CURRENT TT AND SENDING THIS VALUE TO THE  * 05960000
*      RESIDENT CONVERT ROUTINE, THE NEXT TRACK WILL BE DETERMINED. IF* 05980000
*      THE NUMBER OF TRACKS IN THE DEB ARE EXCEEDED, THE CONVERT ROU- * 06000000
*      TINE WILL PASS A RETURN CODE OF 4 IN REGISTER 15               * 06020000
*                                                                     * 06040000
*        REGISTER CONTENTS PRIOR TO BRANCHING TO THE CONVERT ROUTINES * 06060000
*      ARE:                                                           * 06080000
*        R0 ---NEXT TTR RETURNED BY IECPRTLV OR TTRN IF GOING TO THE  * 06100000
*              IECPCNVT ROUTINE. (TTR TO MBBCCHHR)                    * 06120000
*        R1 ---ADDRESS OF DEB                                         * 06140000
*        R2 ---ADDRESS OF USER MBBCCHHR                               * 06160000
*        R3 ---BASE REGISTER OF THIS MODULE                           * 06180000
*        R4 ---RETURN TO USER                                         * 06200000
*        R5 ---USER (11)                                              * 06220000
*        R6 ---USER (12)                                              * 06240000
*        R7 ---ADDRESS OF SAVE AREA                                   * 06260000
*        R8 ---TEMPORARY STORAGE OF TTRN FOR SPLIT CYLINDER USE.        06280000
*              R9 ---REGS 9 - 13 ARE                                    06300000
*        R10---USED           VO                                      * 06320000
*        R11--- BY              LA                                    * 06340000
*        R12---  CONVERT          TI                                  * 06360000
*        R13---   ROUTINES               LE                           * 06380000
*                                                                     * 06400000
*        R14---RETURN FOR CONVERT ROUTINE                             * 06420000
*              R15---ENTRY/ERROR CODE REG.                              06440000
*                                                                     * 06460000
*                                                                       06480000
*                                                                       06500000
*                                                                       06520000
*                                                                       06540000
*              IECPRLTV -ENTRY TO ROUTINE VIA A BALR THAT CONVERTS AN   06560000
*                        ABSOLUTE DIRECT ACCESS ADDRESS, MBBCCHHR, INTO 06580000
*                        ITS RELATIVE EQUIVALENT, TTR0. REGISTER        06600000
*                        CONVENTIONS UPON ENTRY AND UPON EXIT ARE AS    06620000
*                        FOLLOWS--                                      06640000
*                                                                       06660000
*                           REGISTER         ENTRY             EXIT     06680000
*                             0          IGNORED            TTR0 RESULT 06700000
*                             1          DEB ADDRESS        TRANSPARENT 06720000
*                             2          ADDRESS OF         TRANSPARENT 06740000
*                                          MBBCCHHR IN CORE             06760000
*                             3-8        IGNORED            TRANSPARENT 06780000
*                             9-13       IGNORED            DESTROYED   06800000
*                             14         RETURN ADDRESS     TRANSPARENT 06820000
*                             15         ENTRY ADDRESS      ZERO        06840000
*                                                                       06860000
*              IECPCNVT -ENTRY TO ROUTINE VIA A BALR THAT CONVERTS A    06880000
*                        RELATIVE DIRECT ACCESS ADDRESS AND             06900000
*                        CONCATENATION NUMBER, TTRN, INTO ITS ABSOLUTE  06920000
*                        EQUIVALENT, MBBCCHHR. REGISTER CONVENTIONS     06940000
*                        UPON ENTRY AND UPON EXIT ARE AS FOLLOWS--      06960000
*                                                                       06980000
*                           REGISTER         ENTRY             EXIT     07000000
*                             0          ACTUAL TTRN        DESTROYED   07020000
*                             1          DEB ADDRESS        TRANSPARENT 07040000
*                             2          ADDRESS OF 8 BYTE  TRANSPARENT 07060000
*                                          AREA FOR MBBCCHHR            07080000
*                             3-8        IGNORED            TRANSPARENT 07100000
*                             9-13       IGNORED            DESTROYED   07120000
*                             14         RETURN ADDRESS     TRANSPARENT 07140000
*                             15         ENTRY ADDRESS      ERROR CODE  07160000
*                                                                       07180000
*                        THE ERROR CODE FOR IECPCNVT WILL BE 0 FOR      07200000
*                        SUCCESSFUL CONVERSION, OR 4 IF VALUE OF TT     07220000
*                        EXCEEDS TOTAL EXTENTS ASSIGNED.                07240000
*                                                                       07260000
*                                                                     * 07280000
*********************************************************************** 07300000
*                                                                       07320000
REGMANIP EQU   *                        START OF A CLOSED SUBROUTINE    07340000
*                                       FOR REGISTER MAINIPULATION.     07360000
* THE FOLLOWING REGISTER MANIPULATIONS ARE REQUIRED IN ORDER TO USE     07380000
* THE CONVERT ROUTINES.                                                 07400000
* THE CURRENT CP SEGMENT S.A. AND COUNT FIELD (2 CONTIG. DBL WDS)       07420000
* PROVIDE A CONVENIENT PLACE TO SAVE SOME REGS. RSTEPPER HAS THIS ADDR. 07440000
*                                                                       07460000
         STM   RCPBASE,DONTUSE8,0(RSTEPPER)  SAVE REGS 6,7,8. HI BYTE   07480000
*                                            OF REG 7 MUST BE ZERO FOR  07500000
*                                            IT OVERLAYS R=0 OF THE SA. 07520000
         LR    DONTUSE8,RSTEPPER        REG 8 IS TRANSPARENT ACCROSS    07540000
*                                       CONVERT, CAN HOLD S.A. ADDRESS. 07560000
*                                       USERS CONTENTS OF 8 ARE SAVED   07580000
*                                       THERE.                          07600000
* MOVE USERS REGS 11, 12, 13, 14, AND EOB BASE 15, TO 5,6,7,4,3 RESPEC- 07620000
* TIVELY.                                                               07640000
         LR    RSTEPPER,OR11            11 TO 5.                        07660000
         LR    RCPBASE,OR12             12 TO 6.                        07680000
         LR    ROVFLO,RSAVE             13 TO 7.                        07700000
         LR    RSAVE,RGAMMA             SAVE THIS ROUTINE'S RETURN REG. 07720000
         LR    RGAMMA,RRETN             14 TO 4.                        07740000
         LR    RIOB,RBASE               15 TO 3.                        07760000
         DROP  RBASE                                                    07780000
         DROP  RIOB                                                     07800000
         USING IGG019C2,RIOB                                            07820000
         LA    RDCB,DCBFDAD             POINT TO M OF FDAD.             07840000
         USING DCBFDAD,RDCB                                             07860000
         BR    RSAVE                    RETURN TO CALLER OF 'REGMANIP'. 07880000
FDADTTR  EQU   *                                                        07900000
         L     RBASE,16                 GET  CVT ADDRESS                07920000
         L     RBASE,RLTV(RBASE)        GET IECPRLTV ENTRY POINT.       07940000
         BALR  RRETN,RBASE              GO TO CONVERT MBBCCHHR TO TTR.  07960000
* ON RETURN, REG 0 HAS THE TTR, LEFT ADJUSTED.                          07980000
         SRL   RALPHA,16               TRUNCATE 'RZ' OF 'TTRZ'.         08000000
         AH    RALPHA,ONE               TT=TT+1.                        08020000
         L     RBETA,DCBIOBA            TEMPORARY IOB ADDRESSABILITY.   08040000
         USING SAMSIOB,RBETA                                            08060000
         STH   RALPHA,TTSAVE            SAVE TT FOR USE IN SPLIT TESTS. 08080000
         DROP  RBETA                                                    08100000
TTRFDAD  EQU   *                                                        08120000
         SLL   RALPHA,16               RE-ALIGN TO 'TT00'.              08140000
         L     RBASE,16                 GET CVT ADDR.                   08160000
         L     RBASE,CNVT(RBASE)        GET IECPCNVT ENTRY POINT.       08180000
         BALR  RRETN,RBASE              GO TO CONVERT TTR TO MBBCCHHR.  08200000
* ON RETURN, REG 15 HAS THE RETURN CODE.                                08220000
         LR    RALPHA,RBASE             SAVE THE RETURN CODE FOR LATER  08240000
*                                       INSPECTION.                     08260000
* REGISTER RECONSTRUCTION - PUT THEM BACK AS THEY WERE BEFORE CONVER-   08280000
* SION.                                                                 08300000
* MOVE REGS 5,6,7,4,3 BACK TO 11,12,13,14,15                            08320000
         LR    OR11,RSTEPPER            5 TO 11.                        08340000
         LR    OR12,RCPBASE             6 TO 12.                        08360000
         LR    RSAVE,ROVFLO             7 TO 13.                        08380000
         LR    RRETN,RGAMMA             4 TO 14.                        08400000
         LR    RBASE,RIOB               3 TO 15.                        08420000
*                                                                       08440000
         USING IGG019C2,RBASE                                           08460000
*                                                                       08480000
         LR    RSTEPPER,DONTUSE8        RESTORE REG # 5 FROM XPARENT 8. 08500000
         LM    RCPBASE,DONTUSE8,0(RSTEPPER) RESTORE 6,7,8.              08520000
         USING WCPMAP,RCPBASE                                           08540000
*                                                                       08560000
         LA    RBETA,5                  OFFSET OF DCBFDAD.              08580000
         SR    RDCB,RBETA               DCB ADDRESSABILITY REGAINED.    08600000
         USING IHADCB,RDCB                                              08620000
*                                                                       08640000
         L     RIOB,DCBIOBA             IOB ADDRESSABILITY REGAINED.    08660000
         USING SAMSIOB,RIOB                                             08680000
*                                                                       08700000
         L     RDEVTAB,DCBDVTBL         DEV TABLE ADDR. REGAINED.       08720000
         USING DEVTAB,RDEVTAB                                           08740000
*                                                                       08760000
* REGISTERS RECONSTRUCTED. ALPHA, BETA, GAMMA HAVE BEEN USED.           08780000
* RETURN CODE WAS SAVED IN ALPHA. TEST IT FOR VALID FDAD.               08800000
*                                                                       08820000
         LTR   RALPHA,RALPHA            COMPARE CODE TO ZERO.           08840000
         BZ    TSTSPLIT                 BRANCH IF ZERO. CODE INDICATES  08860000
*                                       A VALID FDAD, WITHIN THIS EXT.  08880000
* THE RETURN CODE NOT-ZERO INDICATES THE FDAD WAS OUTSIDE THIS EXTENT.  08900000
* ACTION REQUIRED IS TO ISSUE SVC 25, WHICH WILL USE THE CP PORTION     08920000
* THAT HAS BEEN CONSTRUCTED TO ERASE THE UNUSED REMAINDER OF THIS EX-   08940000
* TENT. AFTER RETURN FROM SVC 25, WILL REPAIR THE CP FOR RESTART BY EOV 08960000
ERASE    EQU   *                        ERASE THE CURRENT EXTENT.       08980000
         IF    TRACKFUL,IS=ONES,GOTO=CHECKEXT                      000D 09010013
*                                                                       09020000
         LA    RBETA,CPSEGLEN           RECOVER ADDRESSABILITY FOR THE  09040000
         SR    RCPBASE,RBETA            LAST WCP SEGMENT THAT FITS ON   09060000
*                                       THIS EXTENT.                    09080000
         MVI   NULLFLAG,ZERO            TERMINATE CP.                   09100000
         L     RBETA,COUNTADR           GET ADDRESS OF THE LAST COUNT   09120000
*                                       FIELD MADE UP.                  09140000
         MVC   DCBFDAD+3(5),0(RBETA)    RECONSTRUCT THE DCBFDAD TO      09160000
*                                       POINT TO LAST SEGMENT TO BE     09180000
*                                       ERASED. MAKES CORRECT STARTING  09200000
*                                       POINT IF ANOTHER EXTENT (SAY A  09220000
*                                       DISCONTIGUOUS PRIMARY) IS AVAIL 09240000
*                                       ABLE. ALSO NEEDED FOR SVC 25    09260000
*                                       INTERFACE.                      09280000
         MVC   DCBFDAD(1),IOBFDAD       KEEPS 'M' IN STEP WITH 'CCHHR'. 09300000
*                                                                       09304013
         LH    RALPHA,TEMPSAVE          GET ORIG. TRK BAL.         000D 09308013
         LTR   RCPBASE,RALPHA          SAVE AND TEST ORIG TRKBAL A34460 09309020
         BP    TRKBALOK                IF POSITIVE, LEAVE AS IS  A34460 09310020
         LH    RALPHA,DCBTRBAL         IF NEG,LOAD TRK CAP TO    A34460 09311020
*                                       PASS                     A34460 09312020
*                                                                       09316013
TRKBALOK OI    DCBCIND1,TRKOVFLO       SET DCB TRKOVRFLOW IND.   A34460 09326020
*                                       WHICH TELLS SVC 25 TO ERASE TO  09340000
*                                       END OF EXTENT.                  09360000
*                                                                       09380000
         LR    RGAMMA,RRETN             SAVE 14.                        09400000
         LR    RBETA,RBASE              SAVE 15.                        09420000
         DROP  RBASE                                                    09440000
         LA    R1,0(RDCB)               DEB REG HOLDS PARAM TO   A32558 09450020
*                                       SVC 25                          09460020
*                                                                       09480000
         SVC   25                       ERASE.                          09500000
*                                                                       09520000
         LR    RRETN,RGAMMA             RESTORE 14                      09540000
         LR    RBASE,RBETA              RESTORE 15.                     09560000
         USING IGG019C2,RBASE                                           09580000
         L     RDEB,DCBDEBAD            RECOVER DEB ADDRESSABILITY.     09600000
*                                                                       09640000
         STH   RCPBASE,TEMPSAVE   ORIG. TRK BAL SAVED ACCROSS      000D 09646013
*                                       SVC 25.                    000D 09652013
* RECOVER INITIAL CP AND COUNT FIELD ADDRESSABILITY.                    09660000
* REASON- NEED TO RESTORE THE TOTAL BLOCK LENGTH TO BE WRITTEN INTO     09680000
* THE WRITE CCW POINTED TO BY OFFSW.  THE TOTAL LENGTH HAS BEEN SAVED   09700000
* AT THE CCW JUST IN FRONT OF THE FIRST COUNT FIELD.                    09720000
         SR    RCPBASE,RCPBASE                                          09740000
         IC    RCPBASE,DCBWCPO                                          09760000
         AR    RCPBASE,RIOB             IOBA+WCPO                       09780000
         USING WCPMAP,RCPBASE                                           09800000
         SR    RSTEPPER,RSTEPPER                                        09820000
         IC    RSTEPPER,DCBWCPL                                         09840000
         SLL   RSTEPPER,3               DBL WDS TO BYTES.               09860000
         AR    RSTEPPER,RCPBASE         IOBA+WCPO+WCPL*8                09880000
* CP ADDRESS, S.A. AND COUNT FIELD ADRESS RESTORED TO INITIAL VALUES.   09900000
         LA    RALPHA,2                 LENGTH OF A CCW LENGTH FIELD.   09920000
         LR    RBETA,RSTEPPER           COPY FOR WORK.                  09940000
         CLI   CHANPGM,SETSC            RCD READY CHP            20201  09941020
         BNE   NOFET19                  BRANCH IF NO             20201  09942020
         AH    RCPBASE,ATE8             IF YES INCR BASE FOR SET 20201  09943020
*                                       SC                       20201  09944020
         TM    DCBOPTCD,VALCHK          VALIDITY CHK USED        20201  09945020
         BO    NOFET19                  BRANCH IF YES            20201  09946020
         AH    RALPHA,ATE8              INCR FOR RD SECTOR       20201  09947020
*                                                                       09948020
NOFET19  EQU   *                                                 20201  09949020
*                                                                       09950020
         USING DEB,RDEB                                          20201  09951020
         SR    RBETA,RALPHA             BETA POINTS TO WHERE THE        09960000
*                                       INITIAL CCW LENGTH WAS SAVED.   09980000
         LH    ROVFLO,0(RBETA)          RESET OVFLO TO ORIGINAL VALUE.  10000000
         STH   ROVFLO,DATALEN           WILL NEED THE FULL RECORD       10020000
*                                       LENGTH ON NEXT ENTRY TO EOB IF  10040000
*                                       CAN'T EXCP THIS TIME.           10060000
*                                                                       10062013
* DETERMINE IF ERASE HAD ANY ERRORS.                               000D 10064013
         L     RGAMMA,IOBECBPT           GET ECB ADDR.             000D 10066013
         TM    0(RGAMMA),NOERROR         IS THE ECB POSTED IN ERR. 000D 10068013
         BC    ANYZERO,RESTORE           BRANCH IF YES             000D 10070013
*                                                                       10072013
CHECKEXT EQU   *                                                   000D 10074013
*                                                                       10080000
* CHECK FOR ANOTHER EXTENT, DCBFDAD 'M'+1 MUST BE LESS THAN DEBNMEXT.   10100000
         SR    RBETA,RBETA              HOUSEKEEP                       10120000
         IC    RBETA,IOBFDAD            GET CURRENT M             22837 10140018
         LA    RBETA,1(RBETA)           M=M+1.                          10160000
         STC   RBETA,IOBFDAD            TEMP WORK AREA.                 10180000
         CLC   IOBFDAD(1),DEBNMEXT      COMPARE M+1 TO NMBR OF EXTENTS. 10200000
         BL    EXTAVAIL                 BRANCH IF ANOTHER EXTENT.       10220000
         OI    DCBCIND1,VOLFULL         SET VOLUME FULL INDICATOR.      10240000
* REPAIR DCB FDAD AND TRK BAL TO THEIR VALUES AT ENTRY TO THIS MODULE.  10260000
         BCTR  RBETA,0                  DECREMENT M AND STORE     M2057 10266018
         STC   RBETA,IOBFDAD            BACK TO IOB               M2057 10272018
         MVC   DCBFDAD(8),IOBFDAD       IOB INITIALIZED FROM THE FIRST  10280000
*                                       DCB VALUE.                      10300000
         MVC   DCBTRBAL(2),TEMPSAVE     TRK BAL SAVED IN IOB CSW.       10320000
         B     POSTECB                  MAKES EOV RE-SCHEDULE THIS IOB. 10340000
*                                                                       10360000
EXTAVAIL EQU   *                                                        10380000
*                                                                       10500000
* GET NEXT EXTENT FDAD FROM DEB TO DCB. DCBFDAD 'M' IN BETA IS CORRECT  10520000
* EXTENT NMBR (FROM M=M+1). 'M' TIMES THE EXTENT SCALE GIVES AN INDEX-  10540000
* ING FACTOR USED TO LOCATE THE DEVICE DEPENDENT EXTENT ENTRY.          10560000
*                                                                       10580000
         STC   RBETA,DCBFDAD            UPDATE 'M' TO NEXT EXTENT.      10600000
         SR    RGAMMA,RGAMMA                                            10620000
         IC    RGAMMA,DEBEXSCL          GET EXTENT SCALE(=4 FOR DA).    10640000
         SLL   RBETA,0(RGAMMA)          EXTENT NMBR TIMES SIZE.         10660000
         AR    RDEB,RBETA               BECAUSE MVC NOT INDEXABLE.      10680000
         MVC   DCBFDAD+3(4),DEBSTRCC    GET NEXT EXTENT FDAD.           10700000
         SR    RDEB,RBETA               TAKE OUT THE INDEXING FACTOR.   10720000
         MVI   DCBFDAD+7,ZERO           SET R=0.                        10740000
         B     SETFDAD                  START UP ON NEW EXTENT.         10760000
*                                                                       10780000
TSTSPLIT EQU   *                                                        10800000
* FOLLOWING CODE ENTERED WHEN IT HAS BEEN DETERMINED THAT AT LEAST ONE  10820000
* MORE RECORD SEGMENT WILL BE NEEDED AND A TRACK TO HOLD IT HAS BEEN    10840000
* FOUND.                                                                10860000
*                                                                       10880000
*                                                                       10900000
         SR    RGAMMA,RGAMMA                                            10920000
         IC    RGAMMA,DEBEXSCL          EXTENT SCALE(=4 FOR D.A.)       10940000
         SR    RBETA,RBETA                                              10960000
         IC    RBETA,IOBFDAD            GET CURRENT/LAST 'M'.           10980000
*                                       DCB HAS CURRENT/NEXT 'M' IN IT. 11000000
         SLL   RBETA,0(RGAMMA)          EXTENT NMBR TIMES SIZE.         11020000
*                                       KEEP RBETA FOR INDEXING DEB     11040000
*                                       BASE REG.                       11060000
* TEST FOR SPLIT ALLOCATION, WHICH IS ALLOWED ONLY ON THE PRIMARY.      11080000
         CLI   DCBFDAD,0                Q-FIRST EXTENT. IF        22209 11100018
*                                       FIRST IS NOT PRIMARY, DEBOFLGS  11120000
*                                       REFLECT A NON-SPLIT ALLOC.      11140000
         BNE   TESTPRIM                 BRANCH IF NOT ON FIRST EXTENT.  11160000
*                                       CANNOT BE SPLIT.                11180000
         TM    DEBOFLGS,SPLIT           IS IT SPLIT ALLOCATION.         11200000
         BZ    TESTPRIM                 BRANCH IF NO.                   11220000
*THE FDAD IN THE DCB IS 'VALID' (AS PER THE CONVERT ROUTINE ERROR CODE) 11240000
* AND THE ALLOCATION IS 'SPLIT'. NOW DETERMINE IF THE FDAD IS WITHIN    11260000
* THE LIMITS DEFINED BY THE STARTING AND ENDING HH'S IN THE DEB. IF     11280000
* NOT, THE NEXT PART OF THE SPLIT EXTENT (THERE MUST BE ONE FOR THE     11300000
* FDAD TO BE 'VALID') MAY BE FOUND BY-                                  11320000
*  TT(OF DCBFDAD) + MAXHH - (ENDHH - STRHH) -1                          11340000
* MAXHH IS THE NUMBER OF TRACKS IN A CYLINDER, AND IS THEREFORE DEVICE  11360000
* DEPENDENT.                                                            11380000
* ALPHA AND GAMMA ARE AVAILABLE WORK REGS.                              11400000
* REG BETA HOLDS THE INDEXING FACTOR BY WHICH RDEB HAS BEEN ADJUSTED.   11420000
         AR    RDEB,RBETA               BECAUSE SS INSTRUCTIONS NOT IN- 11440000
*                                       DEXABLE.                        11460000
         CLC   DCBFDAD+6(1),DEBSTRHH+1  IS IT BELOW STARTING HH.        11480000
         BL    OUTSIDE                  BRANCH IF YES.                  11500000
         CLC   DCBFDAD+6(1),DEBENDHH+1  IS IT ABOVE ENDING HH.          11520000
         BNH   FIXRDEB                  BRANCH IF NOT ABOVE. GO TO      11540000
*                                       REPAIR DEB REG.                 11560000
OUTSIDE  EQU   *                                                        11580000
* FDAD IS OUTSIDE THE SPLIT. ADVANCE TO THE NEXT PART OF THIS SPLIT     11600000
* EXTENT, USING THE ABOVE FORMULA.                                      11620000
         SR    RALPHA,RALPHA                                            11640000
         SR    RGAMMA,RGAMMA                                            11660000
         IC    RGAMMA,DEBENDHH+1        GET UPPER LIMIT, ENDHH.         11680000
         IC    RALPHA,DEBSTRHH+1        GET LOWER LIMIT, STRHH.         11700000
         SR    RGAMMA,RALPHA            ENDHH - STRHH                   11720000
         IC    RALPHA,MAXHH             MAXHH                           11740000
         SR    RALPHA,RGAMMA            MAXHH - (ENDHH - STRHH)         11760000
         BCT   RALPHA,*+4               MAXHH - (ENDHH - STRHH) -1      11780000
         AH    RALPHA,TTSAVE            TT+MAXHH-(ENDHH-STRHH)-1        11800000
         SR    RDEB,RBETA               REPAIR DEB REG.                 11820000
         BAL   RGAMMA,REGMANIP          GO TO REGISTER MANIPULATION     11840000
*                                       INTERFACE. REQ'D FOR USE OF     11860000
*                                       CONVERT ROUTINE.                11880000
         B     TTRFDAD                  WILL DO A CONVERT.              11900000
TESTPRIM EQU   *                                                        11920000
         AR    RDEB,RBETA               BECAUSE SS INSTRUCTIONS NOT IN- 11940000
*                                       DEXABLE.                        11960000
         CLC   DCBFDAD(1),IOBFDAD       CROSS AN EXTENT           22837 11970018
         L     RDEB,DCBDEBAD            RESTORE DEB ADDRESS       23227 11990018
         BH    ERASE                    THE VALID TTR LAST GIVEN TO     12000000
*                                       'CONVERT' PRODUCED AN FDAD      12020000
*                                       OUTSIDE THE CURRENT EXTENT.     12040000
*                                       IT MUST BE THE FDAD FOR THE     12060000
*                                       NEXT EXTENT OF A DISCONTIGUOUS  12080000
*                                       PRIMARY. ACTION- ERASE AND      12100000
*                                       CHECK FOR ANOTHER EXTENT.       12120000
*                                       RDEB HAS BEEN TAMPERED WITH.    12140000
FIXRDEB  EQU   *                                                        12160000
*                                                                       12200000
* IF THE OVERFLOW AMOUNT WILL FIT ON THE CURRENT TRACK, WILL EXIT THE   12220000
* LOOP TO DO FINAL LOGIC.  IF NOT, WILL SET UP TO RE-ENTER THE LOOP     12240000
* BUILDING C.P.'S.                                                      12260000
*                                                                       12280000
TESTFULL IF    TRACKFUL,ISNOT=ONES,GOTO=NOTFULL                         12300000
MOVEFDAD EQU   *                        FIRST TRACK HAD NO ROOM FOR     12320000
*                                       DATA. A NEW TRACK WAS GOTTEN    12340000
*                                       FOR THE FIRST RECORD SEGMENT.   12360000
         MVC   IOBFDAD(8),DCBFDAD       COPY NEW FDAD.                  12380000
         MVC   KEYLENTH,DCBKEYLE        RE-INIT KEYKENGTH. WAS OVERLAID 12400000
*                                       WITH A SAVED REG DURING CONVERT 12420000
         B     TESTOVFL                 SEE IF RECORD WILL FIT ON THIS  12440000
*                                       NEW TRACK.                      12460000
*                                                                       12480000
* RSTEPPER POINTS TO THE CURRENT S.A.                                   12500000
*                                                                       12520000
NOTFULL  MVC   CYLINDER(5),DCBFDAD+3    INIT CCHHR IN S.A.              12540000
         LA    RSTEPPER,EIGHT(RSTEPPER) POINT TO THE COUNT FIELD.       12560000
TESTOVFL LH    RGAMMA,TRKCAP            SET DL=MAX.                     12580000
         SR    RBETA,RBETA              CLEAR REG                20201  12581020
         IC    RBETA,OVERK              GET KEY OVERHEAD         20201  12582020
         AR    RGAMMA,RBETA             ADD KEY OVERHEAD NO KEY  20201  12583020
         IC    RBETA,OVERL              GET LAST BLOCK OVERHEAD  20201  12584020
         TM    DEVFLAG,TBOVHD           IS THIS 2 BYTE OVERHEAD  20201  12585020
         BNO   MZ0050                   BRANCH IF NO             20201  12586020
         LH    RBETA,OVERI              GET 2 BYTE OVERHEAD      20201  12587020
MZ0050   EQU   *                                                 20201  12588020
         SR    RGAMMA,RBETA             SUBTRACT LAST BLOCK      20201  12589020
*                                       OVERHD                   20201  12590020
         CR    ROVFLO,RGAMMA            COMPARE OVFLO TO DEVICE MAX.    12600000
         BNH   RUPBY1                   BRANCH IF OVFLO IS LT OR EQ TO  12620000
*                                       DEVICE MAX. (RECORD WILL FIT).  12640000
UPRBY1   EQU   *                                                        12660000
         IC    RBETA,DCBFDAD+7          GET 'R'.                        12680000
         LA    RBETA,1(RBETA)           R=R+1                           12700000
         STC   RBETA,DCBFDAD+7          PUT IT BACK.                    12720000
         MVC   CYLINDER(5),DCBFDAD+3    INIT CCHHR IN COUNT.            12740000
*                                                                       12760000
         B     MIDLOOP                  CLOSE THE BASIC BUILDING LOOP.  12780000
*                                                                       12800000
* FINAL LOGIC.  THE REMAINING LENGTH IN ROVFLO WILL FIT ON THE CURRENT  12820000
* TRACK. MUST CALCULATE THE SPACE REQUIRED AS A NOT-LAST RECORD, SET    12840000
* UP CP TO WRITE IT, ISSUE EXCP.                                        12860000
*                                                                       12880000
FINAL    STH   ROVFLO,DATALEN           PUT LENGTH IN WRITE CCW.        12900000
         SR    RBETA,RBETA                                              12920000
         IC    RBETA,KEYLENTH           KEY LENGTH FROM COUNT FIELD.    12940000
         SR    ROVFLO,RBETA             SEGMENT LENGTH - KL = DATA LEN. 12960000
         STH   ROVFLO,DLDL              GOES IN COUNT FIELD.            12980000
         AR    ROVFLO,RBETA             RECONSTRUCT SEGMENT LENGTH.     13000000
*                                                                       13020000
*CALCULATE SPACE FOR A NOT-LAST-RECORD, USING                           13040000
*   (SEGMENT LENGTH)*TOL/512 - DCBKEYCN + I                             13060000
*                                                                       13080000
* DEB NO LONGER NEEDED. WILL USE THE DEB REG UNDER THE ALIAS RALPHA+1   13100000
* TO INSURE CONTIGUOUS REGISTERS FOR THE MULTIPLY.                      13120000
*                                                                       13140000
         LR    RALPHA,ROVFLO            GET KL+DL                       13160000
         LH    RALPHA+1,TOLER           GET TOLERANCE                   13180000
         MR    RALPHA,RALPHA            (KL+DL)*TOL                     13200000
         SRDA  RALPHA,9                 (KL+DL)*TOL/512 IS IN RALPHA+1  13220000
         SR    RALPHA,RALPHA                                            13240000
         IC    RALPHA,OVERI             GET NOT-LAST-RECORD OVERHEAD.   13260000
         TM    DEVFLAG,TBOVHD           USING TWO BYTE OVHD      20201  13264020
         BNO   MZ0020                   BRANCH NO                20201  13268020
         LH    RALPHA,OVERI             GET TWO BYTE OVHD        20201  13272020
MZ0020   EQU   *                                                 20201  13276020
         AR    RALPHA+1,RALPHA          AOD IT.                         13280000
         SR    RALPHA,RALPHA            CLEAR REG                20201  13290020
         IC    RALPHA,DCBKEYCN          GET KEY OVERHEAD CONSTANT.      13300000
         SR    RALPHA+1,RALPHA          (KL+DL)*TOL/512+I-DCBKEYCN IS   13320000
*                                       THE AMOUNT TO SUBTRACT FROM     13340000
*                                       TRACK BALANCE.                  13360000
         LH    RBETA,DCBTRBAL           GET TRK BALANCE.                13380000
         SR    RBETA,RALPHA+1           DETERMINE NEW BALANCE.          13400000
         STH   RBETA,DCBTRBAL           UPDATE THE DCB.                 13420000
*                                                                       13440000
* END OF TRACK LENGTH CALCULATIONS.                                     13460000
*                                                                       13480000
         MVI   WRTOPCD,WCKD             SET OP CODE OF THE FINAL WRITE. 13500000
*                                                                       13506020
         DROP  RDEB                                              20201  13512020
         USING SAMSIOB,RIOB                                      20201  13518020
         CLI   CHANPGM,SETSC            IS THIS RCD READY CHP    20201  13524020
         BE    FEAT41                   GO AROUND NEXT INST      20201  13530020
         IF    DCBOPTCD,ISNOT=VALCHK,GOTO=FLAGZERO                      13540000
*                                                                       13560000
*                                                                       13565020
FEAT41   EQU   *                                                 20201  13570020
*                                                                       13575020
         MVI   NULLFLAG,CC              COMMAND CHAIN CCW4.             13580000
*                                                                       13600000
* ADVANCE CP BASE REG TO NEXT SEGMENT. IF IT IS NOT THE WRITE VALIDITY  13620000
* CHECK SEGMENT, OVERLAY THE FIRST CCW WITH A TIC TO THE VALIDITY       13640000
* CHECK SEGMENT. SAME FOR RCD READY.                                    13660020
*                                                                       13680000
         LA    RCPBASE,CPSEGLEN(RCPBASE) ADDRESS OF NEXT SEGMENT.       13700000
         USING VCMAP,RCPBASE                                            13720000
         CLI   SEEKOPCD,SEEKCYL         ONLY SEEK IS IN WRITE CHECK SEG 13740000
         BE    EXCP                     WRITE VALIDITY CHECK SEGMENT IS 13760000
*                                       CONTIGUOUS WITH LAST SEGMENT    13780000
*                                       MADE UP. DONT NEED A TIC TO IT. 13800000
         CLI   D0(RCPBASE),RDSC         IS THIS A READ SECTOR    20201  13806020
         BE    EXCP                     IF YES BRANCH            20201  13812020
         USING WCPMAP,RCPBASE                                           13820000
         SR    RBETA,RBETA                                              13840000
         IC    RBETA,DCBWCPO            BUILD ADDRESS OF WCP            13860000
         AR    RBETA,RIOB               BECAUSE MVC NOT INDEXABLE.      13880000
         CLI   CHANPGM,SETSC            IS THIS A RCD READY CHP  20201  13882020
         BNE   NOFET27                  BRANCH IF NO             20201  13884020
         LA    RBETA,EIGHT(RBETA)       INCREMENT FOR SET SECT   20201  13886020
*                                       CMND                     20201  13888020
*                                                                       13890020
NOFET27  EQU   *                                                 20201  13892020
*                                                                       13894020
         MVC   SRCHCCW(4),12(RBETA)     OVERLAY THE SEARCH WITH         13900000
*                                       PARASITIC TIC FROM CCW2.        13920000
         B     EXCP                                                     13940000
FLAGZERO MVI   NULLFLAG,ZERO            TERMINATE CP CHAIN.             13960000
*                                                                       13980000
* PREPARE FOR EXCP. CP'S ALL BUILT.                                     14000000
*                                                                       14020000
EXCP     EQU   *                                                        14040000
         LA    R1,8(RIOB)              ADJUST POINTER FROM SAM'S TO     14060000
*                                      IOS' IOB.                        14080000
         EXCP  (1)                                                      14100000
*                                                                       14120000
RESTORE  LM    RBETA,RDEVTAB,64(RSAVE)  RESTORE USERS 9 AND 10.         14140000
         SR    ROFFSW,ROFFSW                                            14160000
         IC    ROFFSW,DCBOFFSW         QSAM NEEDS IT TO GET NEXT        14180000
*                                      BUFFER ADDRESS.                  14200000
*                                                                       14220000
         BR    RRETN                                                    14240000
POSTECB  L     RBETA,IOBECBPT           GET ECB ADDRESS.                14260000
         MVI   0(RBETA),COMPWERR        POST COMPLETE WITH ERROR.       14280000
UEX      OI    IOBSTAT0,UNITEXC         SET CSW STATUS BYTE 0 TO UEX.   14300000
         B     RESTORE                                                  14320000
ABEND    LA    R1,X'002'                RECORD TOO LARGE.               14340000
         SLL   R1,12                    ALIGN ABEND CODE.               14360000
         ABEND (1),DUMP                                                 14380000
ONE      DC    H'1'                                                     14400000
ATE8     DC    H'8'                     CCW LENGTH               20201  14402020
HYGDN    DC    C'IGGR'                  THIS CONSTANT IS TO      20201  14404020
*                                       IDENTIFY THIS MODULE AS         14406020
*                                       BEING IGGR19C2, A               14408020
*                                       ROTATIONAL POSITION             14410020
*                                       SENSING MODULE.                 14412020
         CNOP  0,8                      PAD MODULE TO MULTIPLE OF       14420000
*                                       DOUBLE WORD LENGTH.             14440000
*                                                                       14460000
* FOLLOWING IS A MAP OF A WRITE CP SEGMENT.                             14480000
*                                                                       14500000
WCPMAP   DSECT                                                          14520000
*                                                                       14540000
*        SEARCH  (CCW1 OR 5)                                            14560000
*                                                                       14580000
SRCHCCW  EQU   *                                                        14600000
SRCHADDR DS    F                                                        14620000
SRCHOPCD EQU   SRCHADDR                 OP CODE IS HI ORDER BYTE.       14640000
SRCHFLAG DS    XL1                                                      14660000
         DS    CL2                                                      14680000
SRCHLEN  DS    XL1                      LENGTHS NORMALLY FIT IN 1 BYTE. 14700000
*                                                                       14720000
*        TIC   (CCW2 OR 6)                                              14740000
*                                                                       14760000
TICADDR  DS    F                                                        14780000
TICOPCD  EQU   TICADDR                                                  14800000
UNUSED   DS    F                        ONLY REQUIRES BITS 37-39 = 0.   14820000
PARASITE EQU   UNUSED                   BITS 37-39 =0 RESTRICTION ON    14840000
*                                       OP CODES, A PLACE FOR ADDRESSES 14860000
*                                                                       14880000
*        WRITE  (CCW3)                                                  14900000
*                                                                       14920000
COUNTADR DS    F                        COUNT FIELD ADDRESS.            14940000
WRTOPCD  EQU   COUNTADR                                                 14960000
WRTFLAG  DS    XL1                      FLAG FIELD.                     14980000
         DS    CL2                      SPACER.                         15000000
COUNTLEN DS    XL1                      COUNT FIELD LENGTH (NORMALLY 8) 15020000
*                                                                       15040000
*        NULL OP CODE  (CCW4)           OP PROPAGATED FROM WRITE CCW.   15060000
*                                                                       15080000
DATAADDR DS    F                        ADDRESS OF BLOCK OF DATA TO BE  15100000
*                                       WRITTEN.                        15120000
NULLOPCD EQU   DATAADDR                 USED AS A FLAG TO SIGNAL LAST   15140000
*                                       SEGMENT.                        15160000
NULLFLAG DS    XL1                                                      15180000
         DS    C                                                        15200000
DATALEN  DS    H                        DATA TO BE WRITTEN.             15220000
*                                                                       15240000
*                                                                       15260000
* FOLLOWING IS THE VALIDITY CHECK CP OVERLAY.                           15280000
*                                                                       15300000
VCMAP    DSECT                                                          15320000
*        SEEK  (CCW7)                                                   15340000
SEEKADDR DS    F                                                        15360000
SEEKOPCD EQU   SEEKADDR                                                 15380000
SEEKFLAG DS    XL1                                                      15400000
         DS    CL2                                                      15420000
SEEKLEN  DS    XL1                                                      15440000
*                                                                       15460000
*        SEARCH (CCW8)             LABELS PREFIXED BY 'VC' (VALIDITY    15480000
VCSRCH   EQU   *                        CHECK).                         15500000
VCSRCHAD DS    F                                                        15520000
VCSRCHOP EQU   VCSRCHAD                                                 15540000
VCSRCHFL DS    XL1                      FLAGS.                          15560000
         DS    CL2                                                      15580000
VCSRCHLE DS    XL1                      LENGTH.                         15600000
*                                                                       15620000
*        TIC   (CCW9)                                                   15640000
VCTICAD  DS    F                                                        15660000
VCTICOP  EQU   VCTICAD                                                  15680000
NOTUSED  DS    F                                                        15700000
*                                                                       15720000
*        READ DATA (CCW10)                                              15740000
VCRDAD   DS    F                                                        15760000
VCRDOP   EQU   VCRDAD                                                   15780000
VCRDFLAG DS    XL1                      NORMALLY SET FOR SKIP.          15800000
VCRDLEN  DS    FL3                                                      15820000
*                                                                       15840000
* FOLLOWING IS AN OVERLAY OF THE COUNT FIELD.                           15860000
*                                                                       15880000
COUNTFLD DSECT                                                          15900000
*                                                                       15920000
CYLINDER DS    H                        CYLINDER ADDRESS (CC).          15940000
HEAD     DS    H                        HEAD ADDRESS     (HH).          15960000
RECORD   DS    XL1                      RECORD NUMBER    (R).           15980000
KEYLENTH DS    XL1                      KEY LENGTH       (KL).          16000000
DLDL     DS    H                        DATA LENGTH      (DLDL).        16020000
*                                                                       16040000
* END COUNT FIELD. (CCHHRKDD)                                           16060000
*                                                                       16080000
*                                                                       16100000
* DIRECT ACCESS DEVICE TABLE OVERLAY                                    16120000
*                                                                       16140000
DEVTAB   DSECT                                                          16160000
DEVSIZE  DS    F                       MAX SIZ FOR DEVICE.              16180000
MAXHH    EQU   DEVSIZE+3                LO ORDER BYTE OF DEVICE SIZE IS 16200000
*                                       MAX HEAD ADDRESS.               16220000
TRKCAP   DS    H                       TRACK CAPACITY.                  16240000
OVERI    DS    XL1                     OVERHEAD FOR NOT-LAST RECORD.    16260000
OVERL    DS    XL1                     OVERHEAD FOR LAST RECORD.        16280000
OVERK    DS    XL1                     OVERHEAD REDUCTION FOR NON-KEY   16300000
*                                      RECORDS.                         16320000
DEVFLAG  DS    XL1                                                      16340000
TOLER    DS    H                       TOLERANCE/512 USED FOR VARIABLE  16360000
*                                       GAP LENGTH CALCULATIONS.        16380000
* END DEVTAB OVERLAY.                                                   16400000
*                                                                       16420000
*                                                                       16440000
         DCBD  DSORG=PS                                                 16460000
*                                                                       16480000
*                                                                       16500000
*                                                                       16520000
*                                                                       16540000
FORECORE DSECT                                                          16560000
         IECDSECT                                                       16580000
*                                                                       16600000
* IOB OVERLAY                                                           16620000
* THE FORECORE DSECT IOB OVERLAY IS USED WITH THE FOLOWING ADDITIONS-   16640000
*                                                                       16660000
* BSAM/BPAM/QSAM IOB EXTENSION-                                         16680000
LINK     EQU   DXIOB-8                  FORWARD CHAIN FIELD (TO NEXT    16700000
*                                       IOB).                           16720000
SAMSIOB  EQU   LINK                                                     16740000
FLAG     EQU   LINK                     HI BYTE OF LINK USED AS FLAG.   16760000
ECB      EQU   DXIOB-4                                                  16780000
* END EXTENSION DEFINITIONS                                             16800000
*                                                                       16820000
TRACKFUL EQU   IOBCSW+1                 CSW ADDRESS BYTE USED FOR       16840000
*                                       A TEMPORARY SWITCH.             16860000
TEMPSAVE EQU   IOBCSW+2                 PLACE TO KEEP THE ORIG. TRK BAL 16880000
*                                                                       16900000
*                                       IS OK BECAUSE IOB BEING PROCESS 16920000
*                                       -ED IS NOT IN ERROR, THEREFORE  16940000
*                                       CSW NOT NEEDED.                 16960000
TTSAVE   EQU   IOBCSW+6                 PLACE TO KEEP THE UPDATED TT    16980000
IOBFDAD  EQU   DXDAADDR                 FDAD IN FORECORE IOB.           17000000
CHANPGM  EQU   DXDAADDR+8               START OF CHANNEL PROGRAM.       17020000
*                                       LENGTH MAY VARY.                17040000
* END IOB DEFINITIONS.                                                  17060000
*                                                                       17080000
DEB      EQU   DXDEB                    WILL USE THE DEB FROM FORECORE. 17100000
DEBNMEXT EQU   DXDEBUSR                                                 17120000
DEBEXSCL EQU   DXDEBAPP                                                 17140000
DEBDVMOD EQU   DXDEBUCB                                                 17160000
DEBSTRCC EQU   DXDEBSCC                                                 17180000
DEBENDCC EQU   DXDEBECC                                                 17200000
DEBSTRHH EQU   DXDEBSHH                                                 17220000
DEBENDHH EQU   DXDEBEHH                                                 17240000
DEBOFLGS EQU   DXDEBOFL                                                 17260000
         END                                                            17280000
