         TITLE 'IGG019EI SAM AB/CHAN END APPENDAGE, BYPASS DOS CHKPT RE*00200021
               CORDS, FORMATS F AND U'                                  00400021
IGG019EI CSECT                                                          00600021
*                                                                       00800021
*                                                                       01000021
*         RELEASE 21 - NEW MODULE                                       01600021
*                                                               SA56518 01650001
*                                                                       01800021
*        RELEASE 21.8 CHANGES/DELETIONS                                 01850000
*D758000,760000                                                 SA68944 01900000
*                                                                       01950000
*        RELEASE VS1-3.1 CHANGES/DELETIONS                              01960000
*XA04507 IS FLAGGED AS SA68944                                  XA04507 01970000
*                                                                       02000021
* STATUS CHANGE LEVEL 001                                               02200001
*                                                                       02400021
*********************************************************************** 02600021
*                                                                       02800021
*                                                                       03000021
* FUNCTION - ENTERED AT CHAN. END TIME FOR FORMAT F, FB, OR U FILES     03200021
*    OPENED FOR TAPE INPUT OR INOUT SPECIFYING BYPASS DOS EMBEDDED      03400021
*    CHKPT RCDS. READ CCW HAS SUPPRESS INCORRECT FLAG ON FOR FORMAT U,  03600021
*    OFF FOR F OR FB.  APPENDAGE TESTS EACH INPUT BLOCK FOR CHKPT HDR   03800021
*    RCD.  UPON ENCOUNTERING CHKPT HDR RCD SETS BIT 0 OF DEBTFLGS TO    04000021
*    INDICATE BYPASSING CHKPT RCDS, RE-INITIALIZES IOB FLAGS 1, 2, AND  04200021
*    3 FIELDS, DECREMENTS DCBBLKCT, AND (1) FOR QSAM MOVES X'50' INTO   04400021
*    THE IOB COMPLETION CODE FIELD - INDICATES TO SYNCHRONIZING         04600021
*    ROUTINE THAT THE BUFFER CONTAINS A DOS CHKPT RCD - AND TAKES THE   04800021
*    NORMAL EXIT TO IOS.  (2) FOR BSAM IT RETURNS TO IOS VIA THE        05000021
*    RE-EXCP EXIT TO RESCHEDULE THE I/O REQUEST.  ON ENCOUNTERING THE   05200021
*    CHKPT TRLR RCD TURNS BYPASS FLAG OFF, RE-INIT. IOB FLAGS,          05400021
*    DECREMENTS DCBBLKCT, AND RETURNS TO IOS AS INDICATED ABOVE FOR     05600021
*    QSAM AND BSAM.                                                     05800021
*                                                                       06000021
*    WHEN NOT IN PROCESS OF BYPASSING CHKPT RCDS (BYPASS FLAG OFF) THE  06200021
*    APPENDAGE PERFORMS THE REQUIRED LENGTH CHECK FOR F BLOCKED RCDS.   06400021
*    FOR TRUNCATED BLOCKED RECORDS THE INCORRECT LENGTH INDICATION IS   06600021
*    RESET PRIOR TO RETURN (NORMAL) TO IOS.  TRUNCATED F STANDARD RCD   06800021
*    WILL CAUSE NEXT RCD READ TO BE TREATED AS A FILE MARK.             07000021
*                                                                       07200021
*    APPENDAGE IS ENTERED ON ABNORMAL CONDITIONS - RETURNS IF ERROR     07400021
*    IS UN-ACCEPTABLE (CAN ONLY ACCEPT DATA ERROR).  IF DATA ERROR      07600021
*    WILL TEST FOR CHKPT HDR OR TRLR RCD AS IN CHAN. END ENTRY. IF      07800021
*    TEST FAILS WILL THEN TEST FOR ID ON BYTE BY BYTE BASIS.  IF TEN    08000021
*    OR MORE COMPARE IT WILL BE ASSUMED TO BE A CHKPT HDR OR TRLR.RCD.  08200021
*    IT THEN PERFORMS SAME FUNCTION AS IN CHAN. END ENTRY.              08400021
*                                                                       08600021
*********************************************************************** 08800021
*                                                                       09000021
* ENTRY POINTS -                                                        09200021
*                                                                       09400021
*         IGG019EI FROM IOS                                             09600021
*                                                                       09800021
*********************************************************************** 10000021
*                                                                       10200021
* INPUT -                                                               10400021
*                                                                       10600021
*    REG 2    - ADDRESS OF IOB                                          10800021
*    REG 3    - ADDRESS OF DEB                                          11000021
*    REG 4    - ADDRESS OF DCB                                          11200021
*    REG 14   - RETURN ADDRESS IN IOS                                   11400021
*    REG 15   - ENTRY POINT ADDRESS OF APPENDAGE                        11600021
*    DCBCIND1 - X'02' INDICATES PREV. RCD WAS TRUNCATED F STANDARD      11800021
*    DCBRECFM - X'80' INDICATES F STANDARD FORMAT                       12000021
*    DCBLRECL - LOGICAL RECORD LENGTH                                   12200021
*    IOB + 0  - READ OR WRITE INDICATORS                                12400021
*    IOB + 16 - CSW ADDRESS = LAST CCW EXECUTED + 8                     12600021
*    IOB + 20 - CSW STATUS BYTE                                         12800021
*    IOB + 22 - CSW RESIDUAL COUNT                                      13000021
*    READ CCW - ORIGINAL READ COUNT                                     13200021
*    DEBTFLGS - X'80' INDICATES BYPASSING EMBEDDED CHKT RCDS.           13400021
*                                                                       13600021
*********************************************************************** 13800021
*                                                                       14000021
* OUTPUT -                                                              14200021
*                                                                       14400021
*    DCBCIND1 - X'10' VOLUME FULL BIT.                                  14600021
*    DCBIFLGS - X'C0' INDICATES PERMANENT I/O ERROR.                    14800021
*    DEBTFLGS - X'80' BYPASSING EMBEDDED DOS CHKPT RCDS.                15000021
*    IOB + 4  - SET TO X'01' TO INDICATE TRUNCATED RCD. MUST            15200021
*               BE RESET BY USER.                                       15400021
*    IOB + 4  - SET TO X'50' TO INDICATE TO QSAM THAT THE BUFFER        15600021
*               CONTAINS A DOS CHKPT RCD.                               15800021
*    IOB + 20 - CSW STATUS INDICATORS.  X'01' INDICATES FILE MARK.      16000021
*    IOB + 21 - CSW STATUS - X'40' INDICATES INCORRECT LENGTH.          16200021
*                                                                       16400021
*********************************************************************** 16600021
*                                                                       16800021
* EXTERNAL REFERENCES -                                                 17000021
*                                                                       17200021
*         USERS PROGRAM DCB, DEB, IOB, AND BUFFER                       17400021
*                                                                       17600021
*********************************************************************** 17800021
*                                                                       18000021
* EXITS,NORMAL -                                                        18200021
*                                                                       18400021
*         RETURN TO IOS ON REGISTER 14 WHEN NOT BYPASSING CHKPT RCDS    18600021
*         OR PERMANENT I/O ERROR.  FOR TRUNCATED FB RCDS TURN OFF       18800021
*         WRONG LENGTH INDICATION IN CSW AND IOB FLAGS.                 19000021
*                                                                       19200021
*         WHEN BYPASS CHKPT RCDS FLAG IS SET RETURN TO IOS ON REGISTER  19400021
*         14 PLUS 8 (RE-EXCP EXIT) FOR BSAM AND NORMAL EXIT FOR QSAM.   19600021
*                                                                       19800021
*********************************************************************** 20000021
*                                                                       20200021
* EXITS,ERROR -                                                         20400021
*                                                                       20600021
*         NONE                                                          20800021
*                                                                       21000021
*********************************************************************** 21200021
*                                                                       21400021
* TABLES/WORKAREAS -                                                    21600021
*                                                                       21800021
*    DCBD AND IECDSECT DSECTS                                           22000021
*                                                                       22200021
*********************************************************************** 22400021
*                                                                       22600021
* ATTRIBUTES -                                                          22800021
*                                                                       23000021
*    DISABLED                                                           23200021
*    REENTRANT                                                          23400021
*    READONLY                                                           23600021
*    REUSABLE                                                           23800021
*                                                                       24000021
*********************************************************************** 24200021
*                                                                       24400021
* CHARACTER CODE DEPENDENCY -                                           24600021
*                                                                       24800021
*    OPERATION OF THIS MODULE IS NOT DEPENDENT UPON A PARTICULAR        25000021
*    INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.             25200021
*                                                                       25400021
*********************************************************************** 25600021
*                                                                       25800021
* NOTES -                                                               26000021
*                                                                       26200021
*    REGISTER EQUATES                                                   26400021
*                                                                       26600021
IOBR     EQU   2                        IOB BASE REGISTER               26800021
DEBR     EQU   3                        DEB REGISTER                    27000021
DCBR     EQU   4                        DCB REGISTER                    27200021
ICR      EQU   9                        INCREMENT REGISTER              27400021
WRKR1    EQU   10                       WORK REGISTER                   27600021
WRKR2    EQU   11                       WORK REGISTER                   27800021
WRKR3    EQU   12                       WORK REGISTER                   28000021
WRKR4    EQU   13                       WORK REGISTER                   28200021
RETRNR   EQU   14                       RETURN REGISTER                 28400021
BASER    EQU   15                       BASE REGISTER                   28600021
*                                                                       28800021
*********************************************************************** 29000021
*                                                                       29200021
*    MASK EQUATES                                                       29400021
*                                                                       29600021
*********************************************************************** 29800021
*                                                                       30000021
BSAM     EQU   X'20'                    BSAM ACCESS METHOD USED         30200021
BYPASS   EQU   X'80'                    TEST FOR BYPASS IN PROGRESS     30400021
BYPSSOFF EQU   X'7F'                    TURN OFF BYPASS FLAG            30600021
CHKPTRCD EQU   X'50'                    INDICATE  DOS EMBEDDED          30800021
*                                       CHKPT RCD                       31000021
CONTROL  EQU   X'08'                    TEST FOR CNTRL OR NOTE/POINT    31200021
ERROR    EQU   X'C0'                    SET PERM ERROR IN DCB           31400021
EXCHB    EQU   X'01'                    TEST FOR EXCHANGE BUFFERING     31600021
FBLKD    EQU   X'10'                    FIXED-BLOCKED FORMAT            31800021
FLAG1    EQU   X'C2'                    RE-INIT IOB FLAG1 FIELD         32000021
FSTD     EQU   X'08'                    F STANDARD FORMAT               32200021
FBS      EQU   FBLKD+FSTD               FB OR FBS FORMAT                32400021
IOBEROFF EQU   X'FB'                    TURN OFF IOB ERROR FLAG         32600021
PERMERR  EQU   X'3F'                    TEST FOR PERM I/O ERROR         32800021
RDBACK   EQU   X'0C'                    READ BACKWARDS OP CODE          33000021
TRUNCIND EQU   X'01'                    TRUNCATED RECORD INDICATOR      33200021
UNITCHK  EQU   X'02'                    TEST FOR UNIT CHECK             33400021
UNITEXCP EQU   X'01'                    TEST FOR UNIT EXCEPTION         33600021
VBIT     EQU   X'10'                    VOLUME FULL BIT                 33800021
WLIOFF   EQU   X'BF'                    TURN OFF WRONG LEN IND IN CSW   34000021
WRITE    EQU   X'40'                    TEST FOR WRITE                  34200021
*                                                                       34400021
*********************************************************************** 34600021
*                                                                       34800021
*    MISC. EQUATES                                                      35000021
*                                                                       35200021
*********************************************************************** 35400021
*                                                                       35600021
ONE      EQU   1                        CONSTANT ONE                    35800021
BYTE     EQU   1                        BYTE LENGTH                     36000021
L3       EQU   3                        LENGTH DISP                     36200021
D4       EQU   4                        DISPLACEMENT OF 4               36400021
D5       EQU   5                        DISPLACEMENT OF 5               36600021
D6       EQU   6                        DISPLACEMENT OF 6               36800021
D8       EQU   8                        DISPLACEMENT OF 8               37000021
NONZERO  EQU   7                        CONDITION CODE FOR NONZERO      37200021
EIGHT    EQU   8                        CONSTANT                        37400021
CCZERO   EQU   8                        CONDITION CODE OF ZERO          37600021
TEN      EQU   10                       TEST CONSTANT                   37800021
IDLEN    EQU   12                       DOS CHKPT ID LENGTH             38000021
UNCONDIT EQU   15                       CONDITION CODE FOR UNCOND BR    38200021
D19      EQU   19                       DISPLACEMENT                    38400021
TWENTY   EQU   20                       DOS CHKPT HDR/TRLR RCD LENGTH   38600021
*                                                                       38800021
*********************************************************************** 39000021
*                                                                       39200021
*                                                                       39400021
         USING IGG019EI,BASER           BASE REGISTER                   39600021
         USING IHADCB,DCBR              DCB REGISTER                    39800021
         USING DXIOB,IOBR               IOB REGISTER                    40000021
         USING DXDEB,DEBR               DEB REGISTER                    40200021
*                                                                       40400021
         LA    ICR,8                    LENGTH OF IOB PREFIX    SA56518 40600001
         LR    WRKR2,IOBR               OBTAIN IOS IOB PTR      SA56518 40650001
         SR    WRKR2,ICR                POINT TO SAM IOB        SA56518 40700001
*                                                                       40800021
         TM    0(WRKR2),WRITE           THIS A WRITE                    41000021
         BO    RETURN                   BRANCH ON YES                   41200021
*                                                                       41400021
         TM    IOBCSW+D4,UNITEXCP       UNIT EXCEPTION ON IN CSW        41600021
         BO    RETURN                   BRANCH ON YES                   41800021
*                                                                       42000021
         TM    IOBCSW+D5,PERMERR        PERM ERROR INDICATED IN CSW     42200021
         BM    RETURN                   BRANCH ON YES                   42400021
*                                                                       42600021
         L     WRKR4,IOBSIOCC           LOAD CHANNEL PROGRAM ADDRESS    42800021
         L     WRKR3,0(WRKR4)           READ CCW DATA ADDRESS - BUFFER  43000021
*                                                                       43200021
         CLI   0(WRKR4),RDBACK          IS OP CODE READ BACKWARDS       43400021
         BNE   ACE000                   BRANCH NO                       43600021
*                                                                       43800021
         LA    WRKR1,D19                SUBTRACT NINETEEN FROM          44000021
         SR    WRKR3,WRKR1               CCW DATA ADDR FOR READ         44200021
*                                        BACKWARDS                      44400021
ACE000   EQU   *                                                        44600021
*                                                                       44800021
         TM    IOBCSW+D4,UNITCHK        UNIT CHECK INDICATED            45000021
         BZ    ACE030                   BRANCH ON NO                    45200021
*                                                                       45400021
*********************************************************************** 45600021
*                                                                       45800021
*    DATA ERROR - TEST FIRST 12 BYTES OF BLOCK FOR CHKPT RCD ID         46000021
*                 NO BLOCK LENGTH TEST FOR 20 BYTES ON DATA ERROR       46200021
*                                                                       46400021
*********************************************************************** 46600021
*                                                                       46800021
         CLC   CHKPTID,0(WRKR3)         CHKPT HDR/TRLR RCD              47000021
         BE    ACE050                   BRANCH ON YES                   47200021
*                                                                       47400021
*********************************************************************** 47600021
*                                                                       47800021
*    TEST FOR CHKPT RCD ID ON BYTE BY BYTE BASIS - BYTE IN ERROR        48000021
*    MAY BE IN CHKPT HDR OR TRLR RCD                                    48200021
*                                                                       48400021
*********************************************************************** 48600021
*                                                                       48800021
         SR    ICR,ICR                  INIT. EQ COMPARISON COUNTER     49000021
         LA    WRKR1,CHKPTID            PT TO FIRST BYE OF CHKPT ID     49200021
         LA    WRKR2,IDLEN              LENGTH OF CHKPT ID FIELD        49400021
         B     ACE010                                                   49600021
ACE005   EQU   *                                                        49800021
         LA    WRKR1,ONE(WRKR1)         INCREMENT ID POINTER            50000021
         LA    WRKR3,ONE(WRKR3)         INCREMENT BUFFER POINTER        50200021
ACE010   EQU   *                                                        50400021
         CLC   0(BYTE,WRKR3),0(WRKR1)   CHARACTERS IN ID AND BUFFER EQ  50600021
         BNE   ACE020                   BRANCH ON NO                    50800021
         LA    ICR,ONE(ICR)             INCREMENT EQ COMPARE COUNTER    51000021
ACE020   EQU   *                                                        51200021
         BCT   WRKR2,ACE005             BRANCH UNTIL ALL 12 BYTES OF    51400021
*                                       THE ID ARE COMPARED TO BUFFER   51600021
         LA    WRKR1,TEN                TEST VALUE                      51800021
         CR    ICR,WRKR1                TEN OR MORE EQ COMPARISIONS     52000021
         BNL   ACE050                   BRANCH ON YES - IS HDR/TRLR RCD 52200021
         B     ACE040                   NOT CHKPT HDR/TRLR RCD          52400021
*                                                                       52600021
*********************************************************************** 52800021
*                                                                       53000021
*    TEST FOR A CONTROL MACRO IN USE                                    53200021
*                                                                       53400021
*********************************************************************** 53600021
*                                                                       53800021
ACE030   EQU   *                                                        54000021
         TM    0(WRKR2),CONTROL         IOB BEING USED BY NOTE/POINT    54200021
*                                       OR CNTRL                        54400021
         BZ    ACE060                   BRANCH ON NO                    54600021
*                                                                       54800021
         CLC   CHKPTID,0(WRKR3)         CHKTPT HDR/TRLR RCD             55000021
         BE    ACE050                   BRANCH ON YES                   55200021
*                                                                       55400021
ACE040   EQU   *                                                        55600021
         TM    DEBBYPAS,BYPASS          BYPASS FLAG ON                  55800021
         BZ    ACE130                   BRANCH ON NO                    56000021
         B     REXCP                    RESCHEDULE CHAN. PROGRAM        56200021
*                                                                       56400021
ACE050   EQU   *                                                        56600021
         TM    DEBBYPAS,BYPASS          BYPASS FLAG ON                  56800021
         BO    ACE070                   BRANCH ON YES                   57000021
         B     ACE090                   GO TURN ON BYPASS FLAG          57200021
*                                                                       57400021
*********************************************************************** 57600021
*                                                                       57800021
*    COMPUTE NUMBER OF BYTES READ                                       58000021
*                                                                       58200021
*********************************************************************** 58400021
*                                                                       58600021
ACE060   EQU   *                                                        58800021
         LH    WRKR1,D6(WRKR4)          READ CCW BYTE COUNT             59000021
         SH    WRKR1,IOBCSW+D6           SUBTRACT RESIDUAL COUNT        59200021
*                                                                       59400021
*********************************************************************** 59600021
*                                                                       59800021
*    TEST FOR BYPASSING EMBEDDED CHKPT RCDS IN PROGRESS, TURNS          60000021
*    OFF BYPASS FLAG IF THE RCD IS FOUND TO BE A CHKPT TRLR RCD         60200021
*                                                                       60400021
*********************************************************************** 60600021
*                                                                       60800021
         LA    ICR,TWENTY               DOS CHKPT HDR RCD LENGTH        61000021
         TM    DEBBYPAS,BYPASS          BYPASS FLAG ON                  61200021
         BZ    ACE080                   BRANCH ON NO                    61400021
*                                                                       61600021
         CR    WRKR1,ICR                20 BYTE BLOCK READ              61800021
         BNE   REXCP                    BRANCH ON NO                    62000021
*                                                                       62200021
         CLC   CHKPTID,0(WRKR3)         CHKPT HDR/TRLR RCD              62400021
         BNE   REXCP                    BRANCH ON NO                    62600021
*                                                                       62800021
ACE070   EQU   *                                                        63000021
         NI    DEBBYPAS,BYPSSOFF        TURN OFF BYPASS FLAG            63200021
         B     REXCP                    RESCHEDULE CHAN. PROGRAM        63400021
*                                                                       63600021
*********************************************************************** 63800021
*                                                                       64000021
*    TEST INPUT BLOCK FOR CHKPT HDR RCD (TRLR IF RDBACK),TURNS ON       64200021
*    BYPASS FLAG IF HDR RCD                                             64400021
*                                                                       64600021
*********************************************************************** 64800021
*                                                                       65000021
ACE080   EQU   *                                                        65200021
         CR    WRKR1,ICR                20 BYTE BLOCK READ              65400021
         BNE   ACE100                   BRANCH ON NO                    65600021
*                                                                       65800021
         CLC   CHKPTID,0(WRKR3)         CHKPT HDR/TRLR RCD              66000021
         BNE   ACE100                   BRANCH ON NO                    66200021
*                                                                       66400021
ACE090   EQU   *                                                        66600021
         OI    DEBBYPAS,BYPASS          TURN ON BYPASS FLAG             66800021
         B     REXCP                    RESCHEDULE CHANNEL PROGRAM      67000021
*                                                                       67200021
*********************************************************************** 67400021
*                                                                       67600021
*    THIS SECTION OF CODE TESTS FOR TRUNCATED F STANDARD READ ON        67800021
*    PREVIOUS READ - SETS ERROR INDICATORS IN CSW AND DCB FOR TRUNC FBS 68000021
*                                                                       68200021
*********************************************************************** 68400021
*                                                                       68600021
ACE100   EQU   *                                                        68800021
         TM    DCBCIND1,VBIT            LAST RCD TRUNCATED F STANDARD   69000021
         BZ    ACE110                   BRANCH ON NO                    69200021
         OI    IOBCSW+D4,UNITEXCP       SET UNIT EXCEPTION IN CSW       69400021
         OI    DCBIFLGS,ERROR           SET PERM ERROR IN DCB           69600021
         B     ACE125                   RETURN                          69800021
*                                                                       70000021
ACE110   EQU   *                                                        70200021
         TM    DCBRECFM,FBS             F BLOCKED OR STANDARD           70400021
         BZ    ACE125                   BRANCH ON NO                    70600021
*                                                                       70800021
         LH    WRKR2,IOBCSW+D6          RESIDUAL COUNT                  71000021
         LTR   WRKR2,WRKR2              RESIDUAL COUNT ZERO             71200021
         BC    CCZERO,ACE125            BRANCH ON YES                   71400021
*                                                                       71600021
*********************************************************************** 71800021
*                                                                       72000021
*    WRONG LENGTH IS INDICATED.  EVEN/ODD PAIR WRKR1-WRKR2 HAS          72200021
*    RESIDUAL COUNT                                                     72400021
*                                                                       72600021
*********************************************************************** 72800021
*                                                                       73000021
         SR    WRKR1,WRKR1              ZERO REGISTER                   73200021
         LH    WRKR3,DCBLRECL           GET LOGICAL RECORD LENGTH       73400021
         DR    WRKR1,WRKR3              DIVIDE RESIDUAL BY RCD LENGTH   73600021
         LTR   WRKR1,WRKR1              IS THERE A REMAINDER            73800021
         BC    NONZERO,ACE130           BRANCH ON YES                   74000021
*                                                                       74200021
         TM    DCBRECFM,FSTD            F STANDARD RCD FORMAT           74400021
         BZ    ACE120                   BRANCH ON NO                    74600021
*                                                                       74800021
         OI    DCBCIND1,VBIT            TURN ON VOL FULL BIT            75000021
ACE120   EQU   *                                                        75200021
         NI    IOBCSW+D5,WLIOFF         TURN OFF WRONG LENGTH INDICATOR 75400021
         NI    IOBFLAG1,IOBEROFF        TURN OFF IOB ERROR FLAG         75600021
*                                                                       76200021
ACE125   EQU   *                                                        76400021
*                                                                       76600021
         TM    DCBCIND1,EXCHB           EXCHANGE BUFFERING              76800021
         BZ    ACE130                   BRANCH ON NO                    77000021
         LA    ICR,EIGHT                LENGTH OF CCW                   77200021
         L     WRKR2,IOBCSW             LOAD CSW COMMAND ADDRESS        77400021
         SR    WRKR2,ICR                SUBTRACT 8 FROM ADDRESS         77600021
         ST    WRKR2,IOBCSW             STORE UPDATED CSW COMMAND ADDR  77800021
*                                                                       78000021
ACE130   EQU   *                                                        78200021
         SR    ICR,ICR                  CLEAR REG 9 FOR IOS             78400021
RETURN   EQU   *                                                        78600021
         BR    RETRNR                   RETURN                          78800021
*                                                                       79000021
*********************************************************************** 79200021
*                                                                       79400021
*    FOLLOWING REINITIALIZES IOB, DECREMENTS DCBBLKCT, AND              79600021
*    RESCHEDULES USER CHAN. PROGRAM                                     79800021
*                                                                       80000021
*********************************************************************** 80200021
*                                                                       80400021
REXCP    EQU   *                                                        80600021
*                                                                       80800021
*                                                                       81000021
         TM    IOBCSW+4,UNITCHK         UNIT CHECK INDICATED            81200021
         BO    ACE135                   BRANCH YES-DCBBLKCT NOT         81400021
*                                       INCREMENTED BY IOS              81600021
*                                                                       81800021
         L     WRKR2,DCBBLKCT           BLOCK COUNT                     82000021
         SH    WRKR2,IOBINCAM           DCBBLKCT MINUS BLOCK INCREMENT  82200021
         ST    WRKR2,DCBBLKCT           STORE UPDATED BLOCK COUNT       82400021
*                                                                       82600021
ACE135   EQU   *                                                        82800021
*                                                                       83000021
         SR    ICR,ICR                  CLEAR REG 9 FOR IOS             83200021
         NI    IOBFLAG1,FLAG1           RE-INIT. IOBFLAG1               83400021
         XC    IOBFLAG2(L3),IOBFLAG2     CLEAR IOBFAG2 AND IOBSNS       83600021
         XC    IOBCSW,IOBCSW            CLEAR IOBFLAG3 AND CSW          83800021
         XC    IOBERRCT,IOBERRCT        CLEAR IOB ERROR COUNTS FIELD    84000021
*                                                                       84200021
         TM    DCBMACRF,BSAM            BSAM ACCESS METHOD              84400021
         BO    ACE140                   BRANCH IF YES                   84600021
         MVI   IOBECBPT,CHKPTRCD        INDICATE TO QSAM THAT THIS      84800021
*                                       IS A DOS CHKPT RCD              85000021
         B     RETURN                   RETURN TO IOS                   85200021
*                                                                       85400021
ACE140   EQU   *                                                        85600021
         B     D8(RETRNR)               RESCHEDULE CHANNEL PGM          85800021
*                                                                       86000021
         DS    0H                                                       86200021
CHKPTID  DC    CL12'/// CHKPT //'       DOS CHKPT HDR/TRLR RCD ID       86400021
*                                                                       86600021
         CNOP  0,8                      PAD TO DOUBLE WORD BDRY         86800021
*                                                                       87000021
*                                                                       87200021
*                                                                       87400021
         DCBD  DSORG=PS,DEVD=TA                                         87600021
         EJECT                                                          87800021
         IECDSECT                                                       88000021
*                                                                       88200021
DEBBYPAS EQU   DXDEBSHH                 EQUATE TO USE DSECT TO ADDRESS  88400021
*                                       OFFSET 4.0 IN QSAM SECTION OF   88600021
*                                       THE DEB                         88800021
*                                                                       89000021
         END                                                            89200021
