         TITLE 'IGG019EJ SAM AB/CHAN END APPENDAGE, BYPASS DOS CHKPT RE*00200021
               CORDS, FORMAT V'                                         00400021
IGG019EJ CSECT                                                          00600021
*                                                                       00800021
*                                                                       01000021
*         RELEASE 21 - NEW MODULE                                       01600021
*                                                                       01800021
*D336000                                                         XM4387 01850003
*                                                                       02000021
* STATUS CHANGE LEVEL 000                                               02200021
*                                                                       02400021
*********************************************************************** 02600021
*                                                                       02800021
*                                                                       03000021
* FUNCTION - ENTERED AT CHAN. END FOR FORMAT V OR VB FILES OPENED       03200021
*    FOR TAPE INPUT OR INOUT SPECIFYING BYPASS DOS EMBEDDED CHKPT       03400021
*    RCDS.   APPENDAGE TESTS EACH BLOCK TO DETERMINE IF THE VARIABLE    03600021
*    LENGTH RECORD IS THE CORRECT LENGTH OR NOT.  THIS IS ASCERTAINED   03800021
*    BY COMPARING THE NUMBER BYTES READ VERSUS THE COUNT SUPPLIED BY    04000021
*    THE USER FOR THE RECORD.  IF IT FAILS THIS TEST, THE BLOCK WILL    04200021
*    BE TESTED FOR A DOS CHKPT HDR RCD.  UPON ENCOUNTERING CHKPT HDR    04400021
*    RCD SETS BIT 0 OF DEBTFLGS TO INDICATE BYPASSING CHKPT RCDS,       04600021
*    RE-INIT. IOB FLAGS, DECREMENTS DCBBLKCT, AND EXITS TO IOS VIA      04800021
*    THE RE-EXCP EXIT FOR BSAM AND NORMAL EXIT FOR QSAM. ON             05000021
*    ENCOUNTERING CHKPT TRLR RCD TURNS BYPASS FLAG OFF, RE-INIT. IOB    05200021
*    FLAGS,DECREMENTS DCBBLKCT AND EXITS TO IOS VIA RE-EXCP FOR BSAM    05400021
*    OR NORMAL EXIT FOR QSAM.  BYPASSING OF EMBEDDED CHKPT RCDS IS      05600021
*    DONE BY APPENDAGE FOR BSAM.  THE GET, EOB, AND SYNCH.              05800021
*    ROUTINES PERFORM BYPASSING FOR QSAM.                               06000021
*                                                                       06200021
*    APPENDAGE IS ENTERED ON ABNORMAL CONDITIONS - RETURNS IF ERROR     06400021
*    IS PERMANENT.  IF DATA ERROR WILL TEST FOR CHKPT HDR/TRLR RCD      06600021
*    AS IN CHAN. END ENTRY.  IF TEST FAILS WILL THEN TEST FOR CHKPT ID  06800021
*    ON BYTE BY BYTE BASIS.  IF TEN OR MORE COMPARE IT WILL BE          07000021
*    ASSUMED TO BE A CHKPT HDR OR TRLR RCD.  THE SAME FUNCTION IS       07200021
*    PERFORMED AS IN CHAN END ENTRY.                                    07400021
*                                                                       07600021
*********************************************************************** 07800021
*                                                                       08000021
* ENTRY POINTS -                                                        08200021
*                                                                       08400021
*         IGG019EJ FROM IOS                                             08600021
*                                                                       08800021
*********************************************************************** 09000021
*                                                                       09200021
* INPUT -                                                               09400021
*                                                                       09600021
*    REG 2    - IOB ADDRESS                                             09800021
*    REG 3    - DEB ADDRESS                                             10000021
*    REG 4    - DCB ADDRESS                                             10200021
*    REG14    - RETURN ADDRESS IN IOS                                   10400021
*    REG15    - ENTRY POINT ADDRESS OF APPENDAGE                        10600021
*    DCBBLKCT - BLOCK COUNT                                             10800021
*    DCBBLKSI - MAXIMUM BLOCK SIZE                                      11000021
*    DEBTFLGS - X'80' INDICATES BYPASSING EMBEDDED CHKPT RCDS           11200021
*    IOB + 0  - READ/WRITE,NOTE/POINT,CNTRL INDICATORS                  11400021
*    IOB + 16 - CSW ADDRESS = LAST CCW EXECUTED + 8                     11600021
*    IOB + 20 - CSW STATUS BYTE                                         11800021
*    IOB + 22 - CSW RESIDUAL COUNT                                      12000021
*    READ CCW - ORIGINAL READ COUNT                                     12200021
*                                                                       12400021
*********************************************************************** 12600021
*                                                                       12800021
* OUTPUT -                                                              13000021
*                                                                       13200021
*    DEBTFLGS - X'80' BYPASSING EMBEDDED DOS CHKPT RCDS                 13400021
*    ECB      - X'50' INDICATES TO QSAM THAT THE BUFFER CONTAINS        13600021
*               A DOS CHKPT RCD.                                        13800021
*    IOB + 21 - CSW STATUS - X'40' INDICATES INCORRECT LENGTH           14000021
*                                                                       14200021
*********************************************************************** 14400021
*                                                                       14600021
* EXTERNAL REFERENCES -                                                 14800021
*                                                                       15000021
*         USERS PROGRAM DCB, DEB, IOB, AND BUFFER                       15200021
*                                                                       15400021
*********************************************************************** 15600021
*                                                                       15800021
* EXITS,NORMAL -                                                        16000021
*                                                                       16200021
*         RETURN TO IOS ON REGISTER 14 WHEN NOT BYPASSING CHKPT RCDS    16400021
*         OR PERMANENT I/O ERROR.  FOR CORRECT LENGTH V(B) BLOCKS THE   16600021
*         WRONG LENGTH INDICATOR IN THE CSW AND IOB EXCEPTION FLAG      16800021
*         ARE TURNED OFF.                                               17000021
*                                                                       17200021
*         WHEN THE BYPASS CHKPT RCDS FLAG IS SET RETURNS TO IOS ON      17400021
*         REGISTER 14 PLUS 8 (RE-EXCP EXIT).                            17600021
*                                                                       17800021
*********************************************************************** 18000021
*                                                                       18200021
* EXITS,ERROR -                                                         18400021
*                                                                       18600021
*         RETURN TO IOS ON REGISTER 14 LEAVING WRONG LENGTH INDICATED   18800021
*         IN CSW AND IOB EXCEPTION FLAG ON.                             19000021
*                                                                       19200021
*                                                                       19400021
*********************************************************************** 19600021
*                                                                       19800021
* TABLES/WORKAREAS -                                                    20000021
*                                                                       20200021
*    DCBD AND IECDSECTS                                                 20400021
*                                                                       20600021
*********************************************************************** 20800021
*                                                                       21000021
* ATTRIBUTES -                                                          21200021
*                                                                       21400021
*    DISABLED                                                           21600021
*    REENTRANT                                                          21800021
*    READONLY                                                           22000021
*    REUSABLE                                                           22200021
*                                                                       22400021
*********************************************************************** 22600021
*                                                                       22800021
* CHARACTER CODE DEPENDENCY -                                           23000021
*                                                                       23200021
*    OPERATION OF THIS MODULE IS NOT DEPENDENT UPON A PARTICULAR        23400021
*    INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.             23600021
*                                                                       23800021
*********************************************************************** 24000021
*                                                                       24200021
* NOTES -                                                               24400021
*                                                                       24600021
*    REGISTER EQUATES -                                                 24800021
*                                                                       25000021
IOBR     EQU   2                        IOB REGISTER                    25200021
DEBR     EQU   3                        DEB REGISTER                    25400021
DCBR     EQU   4                        DCB REGISTER                    25600021
ICR      EQU   9                        INCREMENT REGISTER              25800021
WRKR1    EQU   10                       WORK REGISTER                   26000021
WRKR2    EQU   11                       WORK REGISTER                   26200021
WRKR3    EQU   12                       WORK REGISTER                   26400021
WRKR4    EQU   13                       WORK REGISTER                   26600021
RETRNR   EQU   14                       RETURN REGISTER                 26800021
BASER    EQU   15                       BASE REGISTER                   27000021
*                                                                       27200021
*********************************************************************** 27400021
*                                                                       27600021
*    MASK EQUATES                          MASK USAGE                   27800021
*                                                                       28000021
BSAM     EQU   X'20'                    BSAM ACCESS METHOD              28200021
BYPASS   EQU   X'80'                    TEST FOR BYPASS IN PROGRESS     28400021
BYPSSOFF EQU   X'7F'                    TURN OFF BYPASS FLAG            28600021
CHKPTRCD EQU   X'50'                    INDICATE DOS CHKPT RCD READ     28800021
CONTROL  EQU   X'08'                    TEST FOR NOTE/POINT OR CNTRL    29000021
EXCHB    EQU   X'01'                    TEST FOR EXCHANGE BUFFERING     29200021
FLAG1    EQU   X'C2'                    RE-INIT IOBFLAG1 FIELD          29400021
IOBEROFF EQU   X'FB'                    TURN OFF IOB ERROR FLAG         29600021
IOBERON  EQU   X'04'                    IOB EXCEPTION FLAG BIT          29800021
PERMERR  EQU   X'3F'                    PERM I/O ERROR                  30000021
UNCONDIT EQU   15                       UNCONDITIONAL BRANCH            30200021
UNITCHK  EQU   X'02'                    UNIT CHECK                      30400021
UNITEXCP EQU   X'01'                    UNIT EXCEPTION                  30600021
WLIOFF   EQU   X'BF'                    TURN OFF WRONG LEN IND IN CSW   30800021
WLION    EQU   X'40'                    WLI BIT IN CSW                  31000021
WRITE    EQU   X'40'                    TEST FOR WRITE                  31200021
*                                                                       31400021
*********************************************************************** 31600021
*                                                                       31800021
*    MISC. EQUATES                                                      32000021
*                                                                       32200021
ONE      EQU   1                        INCREMENT                       32400021
BYTE     EQU   1                        BYTE LENGTH                     32600021
L3       EQU   3                        LENGTH CONSTANT                 32800021
D4       EQU   4                        DISPLACEMENT OF 4               33000021
D5       EQU   5                        DISPLACEMENT OF 5               33200021
D6       EQU   6                        DISPLACEMENT OF 6               33400021
D8       EQU   8                        DISPLACEMENT OF 8               33600021
TEN      EQU   10                       TEST CONSTANT                   33800021
IDLEN    EQU   12                       DOS CHKPT ID LENGTH             34000021
MINBLKSI EQU   18                       MINIMUM INPUT BLOCKSIZE         34200021
D19      EQU   19                       DISPLACEMENT                    34400021
TWENTY   EQU   20                       LENGTH OF DOS CHKPT HDR RCD     34600021
*                                                                       34800021
*                                                                       35000021
*********************************************************************** 35200021
*                                                                       35400021
         USING IGG019EJ,BASER           BASE REGISTER                   35600021
         USING IHADCB,DCBR              DCB REGISTER                    35800021
         USING DXIOB,IOBR               IOB REGISTER                    36000021
         USING DXDEB,DEBR               DEB REGISTER                    36200021
*                                                                       36400021
         LA    ICR,8                    LENGTH OF IOB PREFIX     XM4387 36600003
         LR    WRKR2,IOBR               OBTAIN IOS IOB PTR       XM4387 36650003
         SR    WRKR2,ICR                POINT TO SAM IOB         XM4387 36700003
*                                                                       36800021
         TM    0(WRKR2),WRITE           THIS A WRITE                    37000021
         BO    RETURN                   BRANCH ON YES                   37200021
*                                                                       37400021
         TM    IOBCSW+D4,UNITEXCP       UNIT EXCEPTION ON IN CSW        37600021
         BO    RETURN                   BRANCH ON YES                   37800021
*                                                                       38000021
         TM    IOBCSW+D5,PERMERR        PERM I/O ERROR                  38200021
         BM    RETURN                   BRANCH ON YES                   38400021
*                                                                       38600021
*********************************************************************** 38800021
*                                                                       39000021
*    COMPUTE NO. BYTES READ AND LOAD BUFFER ADDRESS                     39200021
*                                                                       39400021
*********************************************************************** 39600021
*                                                                       39800021
         L     WRKR3,IOBSIOCC           POINT TO READ CCW               40000021
         LH    WRKR4,D6(WRKR3)          READ CCW COUNT AND              40200021
         SH    WRKR4,IOBCSW+D6           SUBTRACT RESIDUAL COUNT        40400021
         L     WRKR1,0(WRKR3)           LOAD CCW DATA ADDRESS           40600021
*                                                                       40800021
         TM    IOBCSW+D4,UNITCHK        DATA ERROR                      41000021
         BZ    ACE040                   BRANCH ON NO                    41200021
*                                                                       41400021
*********************************************************************** 41600021
*                                                                       41800021
*    DATA ERROR - TEST FIRST 12 BYTES OF BLOCK FOR CHKPT RCD ID         42000021
*                 NO BLOCK LENGTH TEST FOR 20 BYTES ON DATA ERROR       42200021
*                                                                       42400021
*********************************************************************** 42600021
*                                                                       42800021
         CLC   CHKPTID,0(WRKR1)         CHKPT HDR/TRLR RCD              43000021
         BE    ACE060                   BRANCH ON YES                   43200021
*                                                                       43400021
*********************************************************************** 43600021
*                                                                       43800021
*    TEST FOR CHKPT RCD ID ON BYTE BY BYTE BASIS - BYTE IN ERROR        44000021
*    MAY BE IN CHKPT HDR OR TRLR RCD                                    44200021
*                                                                       44400021
*********************************************************************** 44600021
*                                                                       44800021
         SR    ICR,ICR                  CLEAR EQ COMPARE COUNTER        45000021
         LA    WRKR2,CHKPTID            CHKPT RCD ID CONSTANT ADDRESS   45200021
         LA    WRKR3,IDLEN              CHKPT ID FIELD LENGTH           45400021
         B     ACE020                                                   45600021
*                                                                       45800021
ACE010   EQU   *                                                        46000021
         LA    WRKR1,ONE(WRKR1)         INCREMENT BUFFER POINTER        46200021
         LA    WRKR2,ONE(WRKR2)         INCREMENT ID POINTER            46400021
ACE020   EQU   *                                                        46600021
         CLC   0(BYTE,WRKR1),0(WRKR2)   CHARACTERS EQUAL                46800021
         BNE   ACE030                   BRANCH ON NO                    47000021
         LA    ICR,ONE(ICR)             INCREMENT EQ COMPARE COUNTER    47200021
ACE030   EQU   *                                                        47400021
         BCT   WRKR3,ACE010             BRANCH UNTIL FIRST 12 BYTES OF  47600021
*                                       THE BUFFER COMPARED TO CHKPTID  47800021
         LA    WRKR3,TEN                CONSTANT FOR COMPARISON         48000021
         CR    ICR,WRKR3                TEN OR MORE EQ COMPARISONS      48200021
         BNL   ACE060                   BRANCH ON YES - IS CHKPT HDR    48400021
         B     ACE050                   NOT A CHKPT HDR/TRLR RCD        48600021
*                                                                       48800021
*********************************************************************** 49000021
*                                                                       49200021
*    TEST FOR CONTROL MACRO IN USE                                      49400021
*                                                                       49600021
*********************************************************************** 49800021
*                                                                       50000021
ACE040   EQU   *                                                        50200021
         TM    0(WRKR2),CONTROL         IOB USED BY NOTE/POINT OR CNTRL 50400021
         BZ    ACE070                   BRANCH ON NO                    50600021
*                                                                       50800021
         CLC   CHKPTID,0(WRKR1)         CHKPT HDR/TRLR RCD - NO RCD LEN 51000021
*                                       CHECK AS CONTROL MODULES READ   51200021
*                                       20 BYTES FOR THIS FEATURE       51400021
         BE    ACE060                   BRANCH ON YES                   51600021
ACE050   EQU   *                                                        51800021
         TM    DEBBYPAS,BYPASS          BYPASS FLAG ON                  52000021
         BO    REXCP                    BRANCH ON YES                   52200021
         B     ACE150                   RETURN                          52400021
*                                                                       52600021
ACE060   EQU   *                                                        52800021
         TM    DEBBYPAS,BYPASS          BYPASS FLAG ON                  53000021
         BO    ACE080                   BRANCH ON YES                   53200021
         B     ACE140                   GO TURN ON FLAG AND RE-EXCP     53400021
*                                                                       53600021
*********************************************************************** 53800021
*                                                                       54000021
*    TEST FOR NORMAL BYPASSING OF EMBEDDED CHKPT RCDS - NO ERRORS       54200021
*    OR CONTROL MODULE IN USE                                           54400021
*                                                                       54600021
*********************************************************************** 54800021
*                                                                       55000021
ACE070   EQU   *                                                        55200021
         TM    DEBBYPAS,BYPASS          BYPASS FLAG ON                  55400021
         BZ    ACE090                   BRANCH ON NO                    55600021
         LA    WRKR2,TWENTY             DOS CHKPT HDR/TRLR RCD LENGTH   55800021
         CR    WRKR4,WRKR2              WAS A 20 BYTE BLOCK READ        56000021
         BNE   REXCP                    BRANCH ON NO                    56200021
*                                                                       56400021
         CLC   CHKPTID,0(WRKR1)         CHKPT HDR/TRLR RCD              56600021
         BNE   REXCP                    BRANCH ON NO                    56800021
*                                                                       57000021
ACE080   EQU   *                                                        57200021
         NI    DEBBYPAS,BYPSSOFF        TURN OFF BYPASS FLAG            57400021
         B     REXCP                    RESCHEDULE CHANNEL PROGRAM      57600021
*                                                                       57800021
*********************************************************************** 58000021
*                                                                       58200021
*    TEST FOR VALID VARIABLE LENGTH BLOCK                               58400021
*                                                                       58600021
*********************************************************************** 58800021
*                                                                       59000021
ACE090   EQU   *                                                        59200021
         SR    ICR,ICR                  THIS CODE IS NECESSARY AS THE   59400021
         IC    ICR,0(WRKR1)               BLOCK DESCRIPTOR WORD LL MAY  59600021
         SLL   ICR,8                      RESIDE ON AN ODD BYTE         59800021
         IC    ICR,ONE(WRKR1)             BOUNDARY                      60000021
         AH    ICR,IOBCSW+D6            ADD RESIDUAL COUNT TO LL        60200021
         LH    WRKR2,DCBBLKSI           LOAD THE BLOCK SIZE             60400021
         CLR   ICR,WRKR2                LL EQUAL BLKSIZE                60600021
         BE    ACE120                   BRANCH ON YES - NORMALIZE       60800021
*                                         FLAGS AND RETURN              61000021
         SH    ICR,IOBCSW+D6            RESET LL                        61200021
         LA    WRKR3,MINBLKSI           LOAD 18                         61400021
         CLR   ICR,WRKR3                LL GRTR THAN 18                 61600021
         BNL   ACE130                   BRANCH ON YES                   61800021
         LH    WRKR1,IOBCSW+D6          RESIDUAL COUNT                  62000021
         CLR   WRKR2,WRKR3              BLKSIZE LESS THAN 18            62200021
         BL    ACE100                   BRANCH ON YES                   62400021
         LA    WRKR1,MINBLKSI(WRKR1)    INCREASE RESIDUAL BY 18         62600021
         B     ACE110                                                   62800021
*                                                                       63000021
ACE100   EQU   *                                                        63200021
         AR    WRKR1,WRKR2              ADD BLKSIZE TO RESIDUAL COUNT   63400021
ACE110   EQU   *                                                        63600021
         CLR   WRKR1,WRKR2              RESIDUAL EQUAL BLOCKSIZE        63800021
         BNE   ACE145                   BRANCH ON NO                    64000021
*                                                                       64200021
*********************************************************************** 64400021
*                                                                       64600021
*    VALID RECORD READ                                                  64800021
*                                                                       65000021
*********************************************************************** 65200021
*                                                                       65400021
ACE120   EQU   *                                                        65600021
         NI    IOBCSW+D5,WLIOFF         TURN OFF WLI IN CSW             65800021
         NI    IOBFLAG1,IOBEROFF        TURN OFF IOB EXCEPTION FLAG     66000021
*                                                                       66200021
         TM    DCBCIND1,EXCHB           EXCHANGE BUFFERING              66400021
         BZ    ACE150                   BR NO TO RETURN                 66600021
*                                                                       66800021
         LA    ICR,D8                   LOAD CCW LENGTH                 67000021
         L     WRKR2,IOBCSW             LOAD CSW COMMAND ADDRESS        67200021
         SR    WRKR2,ICR                SUBTRACT 8 FROM ADDRESS         67400021
         ST    WRKR2,IOBCSW             STORE UPDATED CSW COMMAND ADDR  67600021
         B     ACE150                   RETURN                          67800021
*                                                                       68000021
*********************************************************************** 68200021
*                                                                       68400021
*    TEST FOR CHKPT HDR/TRLR RCD - INVALID VARIABLE LENGTH              68600021
*    BLOCK WAS READ                                                     68800021
*                                                                       69000021
*********************************************************************** 69200021
*                                                                       69400021
ACE130   EQU   *                                                        69600021
         LA    WRKR2,TWENTY             LENGTH OF CHKPT HDR/TRLR RCD    69800021
         CLR   WRKR4,WRKR2              WAS A 20 BLOCK READ             70000021
         BNE   ACE145                   BRANCH ON NO                    70200021
*                                                                       70400021
         CLC   CHKPTID,0(WRKR1)         CHKPT HDR/TRLR RCD              70600021
         BNE   ACE145                   BRANCH ON NO                    70800021
*                                                                       71000021
ACE140   EQU   *                                                        71200021
         OI    DEBBYPAS,BYPASS          TURN ON BYPASS FLAG             71400021
*                                                                       71600021
*********************************************************************** 71800021
*                                                                       72000021
*    THIS SECTION OF CODE INITIALIZES THE IOB AND DCBBLKCT FOR          72200021
*    RE-SCHEDULING OF THE CHANNEL PROGRAM                               72400021
*                                                                       72600021
*********************************************************************** 72800021
*                                                                       73000021
REXCP    EQU   *                                                        73200021
*                                                                       73400021
         TM    IOBCSW+4,UNITCHK         UNIT CHECK INDICATED            73600021
         BO    ACE141                   BRANCH YES - DCBBLKCT WAS NOT   73800021
*                                       INCREMENTED BY IOS              74000021
         L     WRKR2,DCBBLKCT           BLOCK COUNT                     74200021
         SH    WRKR2,IOBINCAM           BLOCK COUNT MINUS BLOCK INCR.   74400021
         ST    WRKR2,DCBBLKCT           STORE UPDATED BLK COUNT         74600021
*                                                                       74800021
ACE141   EQU   *                                                        75000021
*                                                                       75200021
         SR    ICR,ICR                  CLEAR REG 9 FOR IOS             75400021
         NI    IOBFLAG1,FLAG1           RE-INIT. IOB FLAG1 FIELD        75600021
         XC    IOBFLAG2(L3),IOBFLAG2     CLEAR IOB FLAG2 AND SENSE FLDS 75800021
         XC    IOBCSW,IOBCSW            CLEAR IOB FLAG3 AND CSW FIELDS  76000021
         XC    IOBERRCT,IOBERRCT        CLEAR IOB ERROR COUNTS FIELD    76200021
*                                                                       76400021
         TM    DCBMACRF,BSAM            IS IT BSAM                      76600021
         BO    ACE142                   BRANCH IF YES                   76800021
*                                                                       77000021
         MVI   IOBECBPT,CHKPTRCD        INDICATE TO QSAM THAT THIS      77200021
*                                       IS A DOS CHKPT RCD.             77400021
         B     RETURN                   RETURN TO IOS                   77600021
*                                                                       77800021
ACE142   EQU   *                                                        78000021
         BC    UNCONDIT,D8(RETRNR)      RETURN TO IOS - RE-SCHEDULE     78200021
*                                       CHANNEL PROGRAM EXIT            78400021
*                                                                       78600021
*********************************************************************** 78800021
*                                                                       79000021
*    NORMAL RETURN TO IOS                                               79200021
*                                                                       79400021
*********************************************************************** 79600021
*                                                                       79800021
ACE145   EQU   *                                                        80000021
         LH    WRKR2,IOBCSW+D6          OBTAIN RESIDUAL COUNT           80200021
         LTR   WRKR2,WRKR2              IS RESIDUAL COUNT ZERO          80400021
         BNZ   ACE150                   BRANCH IF NOT ZERO              80600021
*                                                                       80800021
*    SET WLI AND IOB EXCEPTION FLAG - INVALID BLOCK SAME SIZE AS        81000021
*    DCBBLKSI AND WRONG LENGTH INDICATION WAS NOT SET.                  81200021
*                                                                       81400021
         OI    IOBCSW+D5,WLION          SET WLI IN CSW                  81600021
         OI    IOBFLAG1,IOBERON         SET IOB EXCEPTION FLAG          81800021
*                                                                       82000021
ACE150   EQU   *                                                        82200021
         SR    ICR,ICR                  CLEAR REG 9 FOR IOS             82400021
RETURN   EQU   *                                                        82600021
         BR    RETRNR                   RETURN                          82800021
         DS    0H                                                       83000021
CHKPTID  DC    CL12'/// CHKPT //'       CHECKPOINT HDR/TRLR RCD ID      83200021
*                                                                       83400021
         CNOP  0,8                      PAD MODULE TO DOUBLE-WORD BDRY  83600021
*                                                                       83800021
         DCBD  DSORG=PS,DEVD=TA                                         84000021
*                                                                       84200021
         IECDSECT                                                       84400021
*                                                                       84600021
DEBBYPAS EQU   DXDEBSHH                 EQUATE TO USE DSECT TO ADDRESS  84800021
*                                       OFFSET 4.0 IN QSAM SECTION OF   85000021
*                                       THE DEB                         85200021
         END                                                            85400021
