         TITLE 'IGG019FA-CNTRL MOD. FOR SKIP AND SPACE ON 3525 DEVICE'  00400000
         START                                                          00800000
*********************************************************************** 01200000
*                                                                       02800000
*STATUS CHANGE LEVEL- 21.8                                              03200021
*                                                                       03600000
*FUNCTION/OPERATION--BSAM/QSAM CONTROL FOR SKIPPING AND SPACING ON      04000000
*                    THE 3525 CARD PUNCH. MODIFIES COMMAND BYTE IN      04400000
*                    WRITE CCW TO CAUSE REQUESTED SKIP OR SPACE.        04800000
*                    INCREMENTS LINE POSITION COUNTER (DCBLNP) TO       05200000
*                    INDICATE LINE BEING SKIPPED TO OR SPACED TO.       05600000
*                                                                       06000000
*ENTRY POINTS--      IGG019FA FROM CNTRL MACRO EXPANSION.               06400000
*                             SPACE                                     06800000
*                    LA    1,DCB                                        07200000
*                    LA    0,1         (SPACE 1)                        07600000
*                    L     15,84(1,0)                                   08000000
*                    BALR  14,15                                        08400000
*                                                                       08800000
*                             SKIP                                      09200000
*                    LA    1,DCB                                        09600000
*                    LA    0,1         (SKIP 1)                         10000000
*                    LCR   0,0                                          10400000
*                    L     15,84(1,0)                                   10800000
*                    BALR  14,15                                        11200000
*                                                                       11600000
*INPUT--             PARAMETERS                                         12000000
*                    DCB ADDRESS IN REGISTER 1                          12400000
*                    SPACE OR SKIP MASK IN REGISTER 0                   12800000
*                    DCB'S FOLLOWING FIELDS:                            13200000
*                             DCBIOBA--IOB ADDRESS                      13600000
*                             DCBLNP---LINE POSITION COUNTER            14000000
*                             DCBCIND2-X'01' INDICATES QSAM             14400000
*                                                                       14800000
*OUTPUT--            IOB                                                15200000
*                    DCBLNP INCREMENTED TO INDICATE LINE POSITION.      15600000
*                    CONTROL MODIFIER IN OP CODE OF CCW.                16000000
*                                                                       16400000
*EXTERNAL ROUTINES-- IOS SUPERVISOR (EXCP, WAIT)                        16800000
*                                                                       17200000
*EXITS-NORMAL--      RETURN TO CALLING ROUTINE ON REG. 14               17600000
*                                                                       18000000
*EXITS-ERROR--       NONE                                               18400000
*                                                                       18800000
*TABLES/WORKAREA--   CALLING ROUTINE'S SAVE AREA--REGS. 14-8            19200000
*                    BEGINNING IN SAVE+0.                               19600000
*                                                                       20000000
*ATTRIBUTES--        REENTRANT AND REUSABLE.                            20400000
*********************************************************************** 20800000
PUTLOC   EQU   X'48'                                                    21200000
QSAM     EQU   X'01'                                                    21600000
ONE      EQU   X'01'                                                    22000000
TWELVE   EQU   X'0C'                                                    22400000
COMP     EQU   X'40'                                                    22800000
RATE     EQU   8                       LAST REG USED BY THIS ROUTINE    23200000
WRKR     EQU   0                                                        23600000
WRKR4    EQU   4                                                        24000000
DCBR     EQU   7                       DCB ADDRESS                      24400000
IOBAR    EQU   2                                                        24800000
COUNTR   EQU   6                                                        25200000
BASR     EQU   5                       BASE REG FOR THIS ROUTINE        25600000
SAVR     EQU   13                                                       26000000
RETR     EQU   14                                                       26400000
ENTR     EQU   15                      CONTAINS BASE OF THIS ROUTINE    26800000
LINECTR  EQU   3                       AT ENTRY                         27200000
PARAM    EQU   1                                                        27600000
CCWR     EQU   8                                                        28000000
ONEBUFF  EQU   X'FE'                                                    28400000
HUNDRD31 EQU   X'83'                                                    28800000
FOUR     EQU   X'04'                                                    29200000
CCOFF    EQU   X'B0'                                                    29600000
CNTRL   EQU   X'08'                                                     30000000
ZERO     EQU   X'00'                                                    30400000
TWENTY4  EQU   X'18'                                                    30800000
FDSSCMD  EQU   X'23'                   FEED, STACKER SELECT COMAND      31200000
RP       EQU   X'60'                   MASK FOR READ/PUNCH DADS         31600000
RW       EQU   X'50'                   MASK FOR READ/WRITE DADS         32000000
PW       EQU   X'30'                   MASK FOR PUNCH/PRINT DADS        32400000
D20      EQU   20                                                       32800000
D08      EQU   8                                                        33200000
D01      EQU   1                                                        33600000
D03      EQU   3                                                        34000000
D40      EQU   40                                                       34400000
D07      EQU   7                                                        34800000
DEBR     EQU   9                                               @SA57768 34880021
PCHBIT   EQU   X'20'                                           @SA57768 34960021
RDBIT    EQU   X'40'                                           @SA57768 35040021
SEQFLAG  EQU   X'08'                                           @SA57768 35120021
*                                                                       35200000
*                                                                       35600000
IGG019FA CSECT                                                          36000000
* A 348500-350000,368500,416500,644500-647600,652500-654500,   @SA57768 36080021
* A 892500                                                     @SA57768 36160021
* C 644000                                                     @SA57768 36240021
* D 016000-024000                                              @SA57768 36320021
*                                                                       36400000
         USING IHADCB,DCBR                                              36800000
         USING DEBBASIC,DEBR                                   @SA57768 37000021
         USING IGG019FA,BASR                                            37200000
*                                                                       37600000
*                                                                       38000000
*                                                                       38400000
*  THIS ROUTINE SAVE REGISTERS AND CHECKS TO SEE IF THE IOB'S ECB IS    38800000
*  POSTED AS BEING COMPLETE. IF NOT A WAIT IS ISSUED TO IOB'S ECB. WHEN 39200000
*  ECB IS POSTED COMPLETE AND CNTRL ISSUED FOR SPACE ADD THIS VALUE TO  39600000
*  LINE COUNTER BUCKET IN 'DCBLNP'.                                     40000000
*                                                                       40400000
         STM   RETR,RATE,D20(SAVR)     SAVE USER REGS. 14 THRU 8        40800000
         LR    BASR,ENTR               GET BASE ADDRESS                 41200000
         LR    DCBR,PARAM              GET DCB ADDRESS                  41600000
         L     DEBR,DCBDEBAD           GET DEB ADDR FOR BASE   @SA57768 41800021
         L     IOBAR,DCBIOBA           LOAD IOB START ADDRESS           42000000
         OI    ZERO(IOBAR),CNTRL       SET CONTROL FLAG IN IOB PREFIX   42400000
         LR    COUNTR,WRKR             COPY REG 0 TO GET SP AND SK PARM 42800000
         L     IOBAR,ZERO(IOBAR)       LINK TO NEXT IOB                 43200000
         TM    DCBCIND2,QSAM           IS QSAM BEING USED               43600000
         BZ    BSAM                    NO,BRANCH                        44000000
         L     PARAM,TWELVE(IOBAR)     LOAD ECB ADDRESS IN A REGISTER   44400000
         TM    ZERO(PARAM),COMP        IS EVENT COMPLETE                44800000
         BO    COMPLETE                YES, BR TO CK FOR SP AND SK PARM 45200000
         LA    WRKR,D01                LOAD WAIT COUNT                  45600000
         WAIT  (0),ECB=(1)                                              46000000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 46400000
*                                                                       46800000
COMPLETE LTR   COUNTR,COUNTR           IS THIS A SKIP OR SPACE OPRATION 47200000
         BM    MINUS                   MINUS IS SKIP. PLUS IS SPACE.    47600000
         TM    DCBFUNC,RP              READ OR PUNCH BIT ON             48000000
         BM    SPACE                   YES, BRANCH AROUND               48400000
         BO    SPACE                   YES, BRANCH AROUND               48800000
         CLI   DCBLNP,ZERO             LINE POSITION IS ZERO            49200000
         BNE   SPACE                   NO, BRANCH                       49600000
         B     CONTINUE                YES, DO FD, SS COMMAND           50000000
SPACE    EQU   *                                                        50400000
         SR    LINECTR,LINECTR         ZERO OUT REGISTER                50800000
         IC    LINECTR,DCBLNP          GET LINE COUNT BUCKET FROM DCB   51200000
         AR    LINECTR,COUNTR          INCREMENT LINE COUNTER           51600000
         STC   LINECTR,DCBLNP          RESTORE LINE COUNTER IN DCB      52000000
         B     RETURN                  RETURN TO CALLING PROGRAM        52400000
LEVELID  DC    C'05'                   MODULE LEVEL CONTROL             52800000
*                                                                       53200000
*  THIS ROUTINE SKIP TO WHATEVER CHANNEL SPECIFIED ON CNTRL MACRO BY    53600000
*        1.ISSUING A FD,SS COMMAND IS SKIP TO CHANNEL 1 IS SPECIFIED OR 54000000
*          IF THE CHANNEL SPECIFIED IS LESS THAN THE CHANNEL'S PRESENT  54400000
*          LOCATION. THE 'DCBLNP' IS RESET TO CORRESPONDING LINE        54800000
*          POSITION AND EXCP ISSUED TO FEED ANOTHER CARD                55200000
*                                                                       55600000
*        2.UPDATING 'DCBLNP' IF SPECIFIED CHANNEL IS GREATER THAN THE   56000000
*          PRESENT CHANNEL'S LOCATION.                                  56400000
*                                                                       56800000
MINUS    EQU   *                                                        57200000
         LCR   COUNTR,COUNTR           PUT SKIP NUMBER IN PLUS FORM     57600000
         TM    DCBFUNC,RP              READ OR PUNCH BIT ON             58000000
         BM    SKIP                    YES, BRANCH AROUND               58400000
         BO    SKIP                    YES, BRANCH AROUND               58800000
         CLI   DCBLNP,ZERO             LINE POSITION IS ZERO            59200000
         BNE   SKIP                    NO, BRANCH                       59600000
         B     CONTINUE                YES, DO FD, SS COMMAND           60000000
SKIP     EQU   *                                                        60400000
         LA    LINECTR,D01             SET UP TO COMPARE FOR CH-1       60800000
         CR    COUNTR,LINECTR          SKIP TO CHANNEL 1                61200000
         BE    CONTINUE                YES, BRANCH TO ISSUE FD,SS CMD   61600000
         SR    LINECTR,LINECTR         ZERO OUT REGISTER                62000000
         IC    LINECTR,DCBLNP          GET LINE COUNT BUCKET FROM DCB   62400000
         LR    WRKR4,COUNTR            SET UP WORK REG FOR COMPARE      62800000
         SLA   WRKR4,ONE               MULTIPLY BY TWO                  63200000
         BCTR  WRKR4,ZERO              SUBTRACT ONE                     63600000
         CLR   LINECTR,WRKR4           SKIP AMOUNT GE TO MASK           64000000
         BL    VALIDSKP                NO. BR TO CONTINUE      @SA57768 64400021
         TM    DCBFUNC,PCHBIT          IS PUNCH BIT ON         @SA57768 64440021
         BNO   CKRDBIT                 NO. CHECK FOR READ BIT  @SA57768 64480021
         L     DCBR,DEBPDCB            GET PUNCH DCB ADDRESS   @SA57768 64520021
SEQCK    EQU   *                                               @SA57768 64560021
         TM    DCBQSWS,SEQFLAG         IS SEQUENCE FLAG ON     @SA57768 64600021
         BZ    PRNTWTP                 NO, BR TO ERROR MESSAGE @SA57768 64640021
         L     DCBR,DEBDCBAD           GET CURRENT DCB ADDR.   @SA57768 64680021
VALIDSKP EQU   *                                               @SA57768 64720021
         STC   WRKR4,DCBLNP            RESTORE LINE COUNTER IN DCB      64800000
         B     RETURN                  BRANCH, TO RETURN TO CALLER      65200000
CKRDBIT  EQU   *                                               @SA57768 65260021
         TM    DCBFUNC,RDBIT           IS READ BIT ON          @SA57768 65320021
         BNO   CONTINUE                NO,GO ISSUE FDSS CMD    @SA57768 65380021
         L     DCBR,DEBRDCB            YES, GET READ DCB ADDR. @SA57768 65440021
         B     SEQCK                   GO CHECK FOR SEQ FLAG   @SA57768 65500021
CONTINUE TM    DCBFUNC,RP              READ PUNCH ASSOCIATED DATA SET   65600000
         BO    PRNTWTP                 YES, BRANCH FOR ERROR MESSAGE    66000000
         TM    DCBFUNC,RW              READ PRINT ASSOCIATED DATA SET   66400000
         BO    PRNTWTP                 YES, BRANCH FOR ERROR MESSAGE    66800000
         TM    DCBFUNC,PW              PUNCH PRINT ASSOCIATED DATA SET  67200000
         BO    PRNTWTP                 YES, BRANCH FOR ERROR MESSAGE    67600000
         LA    CCWR,D40(IOBAR)         GET CCW ADDRESS                  68000000
         NI    FOUR(CCWR),CCOFF        TURN OFF CMND CHAIN FLAG         68400000
         ST    CCWR,TWENTY4(IOBAR)     PUT CCW START ADDR IN IOB        68800000
         MVI   ZERO(CCWR),FDSSCMD      MOVE IN A FD,SS CMD              69200000
         MVI   D07(CCWR),ONE           LOAD BYTE COUNT OF ONE           69600000
*                                                                       70000000
*  ON SKIP TO CHANNEL Z 'DCBLNP'=2(Z)-1. E.G IF Z=5 THEN 'DCBLNP'=9     70400000
*  SINCE CHANNEL TO SKIP (Z) IS LESS THAN PRESENT CHANNEL POSITION      70800000
*  ISSUE FEED,STACKER,SELECT CCW AND UPDATE 'DCBLNP' WITH LINE VALUE    71200000
*                                                                       71600000
         SLA   COUNTR,ONE               DCBLNP = 2 TIMES CHANNEL VALUE  72000000
         BCTR  COUNTR,ZERO                       MINUS 1                72400000
*                                                                       72800000
         STC   COUNTR,DCBLNP            UPDATE DCBLNP WITH LINE COUNT   73200000
         LA    PARAM,D08(IOBAR)        PUT IOS IOB ADDRESS IN REG 1     73600000
         EXCP  (1)                     EXECUTE CHANNEL PROGRAM          74000000
         TM    DCBMACRF+ONE,PUTLOC     IS THIS IN PUT LOCATE MODE       74400000
         BZ    WAIT                    NO, BRANCH BECAUSE THIS IS BSAM  74800000
         BM    RETURN                  THIS IS QSAM WITHOUT LOCATE MODE 75200000
         CLI   DCBBUFNO,ONEBUFF        QSAM-LOCATE MODE WITH ONE BUFFER 75600000
         BM    RETURN                  NO, MORE THAN ONE BUFFER         76000000
WAIT     EQU   *                                                        76400000
         LA    PARAM,FOUR(IOBAR)       LOAD ECB ADDR IN REG 1           76800000
         LA    WRKR,D01                LOAD WAIT COUNT                  77200000
         WAIT  (0),ECB=(1)             WAIT                             77600000
RETURN   EQU   *                                                        78000000
         LM    RETR,RATE,D20(SAVR)     RESTORE USER'S REGISTERS         78400000
         BR    RETR                    RETURN TO CALLING ROUTINE        78800000
*                                                                       79200000
*                                                                       79600000
BSAM     EQU   *                                                        80000000
*                                                                       80400000
*                                                                       80800000
         LA    PARAM,FOUR(IOBAR)       GET ECB ADDRESS                  81200000
         ST    PARAM,TWELVE(IOBAR)      STORE ECB IN IOB                81600000
         B     COMPLETE                 GO DETERMINE TYPE OF CNTRL      82000000
*                                                                       82400000
*                                                                       82800000
PRNTWTP  EQU   *                                                        83200000
         WTO   'IEC950I 003-3 3525 ASSOCIATED DATA SET I/O SEQUENCE ERR*83600000
               OR',ROUTCDE=(11),DESC=4                                  84000000
         LA    ENTR,D03                INDICATE ASSOCIATED DATA SET     84400000
*                                      PRINT SEQUENCE ERROR CODE TO BE  84800000
*                                      PASSED TO USER VIA REGISTER 15   85200000
         L     PARAM,ABEND3            GET SAM ABEND ERROR CODE         85600000
         SLL   PARAM,12                SET UP REGISTER 1 FOR ABEND      86000000
         ABEND (1),DUMP                                                 86400000
*                                                                       86800000
         DS    0F                      ALIGN ON A FULLWORD BOUNDARY     87200000
ABEND3   DC    X'00000003'             ABEND CODE OF 3                  87600000
         DC    12CL4'ZAPS'             MAINTENANCE AREA                 88000000
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY   88400000
         CNOP  0,8                                                      88800000
         DCBD  DSORG=PS                                                 89200000
         IEZDEB                                                         89400021
         END                                                            89600000
