         TITLE 'IGG019FK-EOB RTN FOR 3525 DATA PROTECTION IMAGE (DPI)'  00400000
         START                                                          00800000
* A 444500                                                     @SA57768 00900021
* D 016000-024000                                              @SA57768 01000021
*********************************************************************** 01200000
*                                                                       02800000
*STATUS CHANGE LEVEL- 21.8                                              03200021
*                                                                       03600000
*FUNCTION/OPERATION--SAM END OF BLOCK ROUTINE FOR 3525 RD/PCH (RPD)     04000000
*                    OR RD/PCH/PRT (RPWD) WITH DATA PROTECTION (DPI)    04400000
*                    AND MACHINE C CHARACTERS, ASCII C CHARACTERS       04800000
*                    OR NO C CHARACTERS SPECIFIED. IT WILL BLANK OUT    05200000
*                    BYTES IN BUFFER AREA THAT CORRESPOND TO BLANK      05600000
*                    BYTES IN DPI IMAGE. SETS UP COMMAND BYTE           06000000
*                    (WR,FD,SS) IN THE CCW. THE BUFFER ADDRESS AND      06400000
*                    RECORD LENGTH ARE PASSED FROM PUT OR WRITE         06800000
*                    ROUTINE IN THE CCW. THE CHANNEL PROGRAM IS         07200000
*                    SCHEDULED WITH AN EXCP MACRO.                      07600000
*                                                                       08000000
*ENTRY POINTS--      IGG019FK FROM PUT OR WRITE ROUTINES.               08400000
*                    LA    2,DCB                                        08800000
*                    LA    3,IOB                                        09200000
*                    L     15,76(DCB)       FOR BSAM                    09600000
*                    (OR)                                               10000000
*                    L     15,92(DCB)       FOR QSAM                    10400000
*                    BALR  14,15                                        10800000
*                                                                       11200000
*INPUT--             IOB+40            BUFFER ADDRESS                   11600000
*                    IOB+46            BLOCK SIZE                       12000000
*                    DCBRECFM          TEST FOR MACHINE C CHAR.         12400000
*                                      TEST FOR ASCII C CHAR.           12800000
*                                                                       13200000
*OUTPUT--            IOB+40            WRITE CCW SET WITH C CHAR,       13600000
*                                      BUFFER ADDRESS AND LENGTH.       14000000
*                    IOB+24            LOADED WITH START ADDRESS        14400000
*                                      OF CHANNEL PROGRAM.              14800000
*                                                                       15200000
*EXTERNAL ROUTINES-- NONE                                               15600000
*                                                                       16000000
*EXITS-NORMAL--      RETURN TO PUT OR WRITE ROUTINE ON REG. 14          16400000
*                                                                       16800000
*EXITS-ERROR--       003 - ABEND-- ASSOCIATED DATA SET I/O SEQUENCE     17200000
*                    ERROR. RETURN CODE OF 2 IN REG. 15                 17600000
*                                                                       18000000
*TABLES/WORKAREA--   NONE                                               18400000
*                                                                       18800000
*ATTRIBUTES--        REENTRANT,REUSABLE.                                19200000
*                                                                       19600000
*********************************************************************** 20000000
WRKR0    EQU   0                                                        20400000
WRKR1    EQU   1                       TABLE INCREMENT AMOUNT (2)       20800000
COUNTER  EQU   1                       COUNTER REGISTER                 21200000
LRECLR   EQU   1                       LENGTH OF RECORD REGISTER        21600000
DCBR     EQU   2                       DCB ADDRESS UPON ENTRY           22000000
IOBR     EQU   3                       IOB ADDRESS UPON ENTRY           22400000
WRKR2    EQU   4                       TABLE END ADDRESS                22800000
DPIR     EQU   4                       ADDRESS OF DPI IMAGE             23200000
WRKR3    EQU   5                       TABLE START ADDRESS              23600000
DEBR     EQU   6                       REG. USED FOR DEB DSECT          24000000
BUFR     EQU   6                       BUFFER ADDRESS                   24400000
OPR      EQU   7                       OP CODE REGISTER                 24800000
RETR     EQU   14                      CALLING ROUTINE RETURN ADDRESS   25200000
BASR     EQU   15                      BASE REGISTER                    25600000
*                                                                       26000000
MCHAR    EQU   X'02'                   MACHINE CONTROL CHARACTER MASK   26400000
ASCII    EQU   X'04'                   ASCII CONTROL CHARACTER MASK     26800000
USED     EQU   X'7F'                   DCB USED INDICATOR               27200000
SEQFLAG  EQU   X'08'                                                    27600000
SEQFLGOF EQU   X'F7'                                                    28000000
SSCLEAR  EQU   X'BF'                                                    28400000
BLANK    EQU   X'40'                                                    28800000
THRE     EQU   X'03'                                                    29200000
EIGHTY   EQU   X'50'                   LENGTH MASK FOR COUNTER DECREMNT 29600000
RPW      EQU   X'70'                                                    30000000
SLI      EQU   X'20'                                                    30400000
SIX      EQU   6                                                        30800000
ONE      EQU   1                                                        31200000
N2       EQU   2                                                        31600000
Z0       EQU   0                                                        32000000
*                                                                       32400000
IGG019FK CSECT                                                          32800000
*                                                                       33200000
*                                                                       33600000
*                                                                       34000000
         USING DEBBASIC,DEBR                                            34400000
         USING IGG019FK,BASR                                            34800000
         USING IHADCB,DCBR                                              35200000
         USING IOB,IOBR                                                 35600000
*                                                                       36000000
* ENTRY POINT                                                           36400000
*                                                                       36800000
         L     DEBR,DCBDEBAD           GET DEB ADDRESS                  37200000
READSEQ  EQU   *                                                        37600000
*                                                                       38000000
*  THIS ROUTINE WILL CHECK THE ASSOCIATIVE DATA SET DCB'S TO INSURE     38400000
*  THAT THEY HAVE BEEN OPENED,AND THAT EACH DCB IS BEING PROCESSED IN   38800000
*  THE CORRECT ORDER                                                    39200000
*                                                                       39600000
         CLC   DEBRDCBA(THRE),ZEROES   IS READ DCB OPEN                 40000000
         BE    WRTOPROG                NO, WRITE ERROR MSG. TO PROGMR.  40400000
         L     DCBR,DEBRDCB            YES, GET READ DCB ADDRESS        40800000
         TM    DCBQSWS,SEQFLAG         IS READ SEQUENCE FLAG ON         41200000
         BZ    WRTOPROG                NO, WRT ERROR MSG TO PROGRAMMER  41600000
         NI    DCBQSWS,SEQFLGOF        YES,TURN OFF READ SEQ. FLAG      42000000
         TM    DCBFUNC,RPW             RD/PCH/PRT ASSOC. D. S.          42400000
         BNO   DPI00                   NO, BRANCH                       42800000
         CLC   DEBWDCBA(THRE),ZEROES   PRINT DCB OPEN                   43200000
         BE    DPI00                   NO BRANCH                        43600000
         L     DCBR,DEBWDCB            GET PRINT DCB ADDR.              44000000
         NI    DCBQSWS,SEQFLGOF        TURN OFF PRINT SEQ. FLAG         44400000
         MVI   DCBLNP,Z0               RESET LINE CTR TO ZERO  @SA57768 44600021
*                                                                       44800000
DPI00    EQU   *                                                        45200000
*                                                                       45600000
         L     DCBR,DEBDCBAD           GET CURRENT DCB ADDRESS AGAIN    46000000
         TM    DCBQSWS,SEQFLAG         IS PUNCH SEQUENCE FLAG ON        46400000
         BO    WRTOPROG                YES, ERROR INVOLVED. BRANCH      46800000
         OI    DCBQSWS,SEQFLAG         TURN ON PUNCH SEQ. FLAG          47200000
DPI10    EQU   *                                                        47600000
         LA    COUNTER,EIGHTY          LOAD COUNT OF 80                 48000000
         L     BUFR,CCW1AD             GET BUFFER ADDRESS               48400000
         TM    DCBRECFM,SIX            ASCII OR MACHINE CONTROL CHARS.  48800000
         BZ    DPI30                   NO, BRANCH FOR DPI TRANSLATION   49200000
DPI20    EQU   *                                                        49600000
         LA    BUFR,ONE(BUFR)          INCREMENT ADDRESS BY ONE         50000000
*                                                                       50400000
*  THIS ROUTINE WILL BLANK OUT ALL BYTES IN THE BUFFER THAT DOES NOT    50800000
*  CORRESPOND WITH THE 80 BYTE DPI IMAGE LOADED FROM SYS1.IMAGELIB WHEN 51200000
*  DCB WAS OPENED                                                       51600000
*                                                                       52000000
DPI30    LA    DPIR,IOBDPI             GET DPI IMAGE ADDRESS            52400000
DPI40    CLI   0(DPIR),BLANK           IS DPI BYTE BLANK                52800000
         BNE   DPI50                   NO, BRANCH                       53200000
         MVI   0(BUFR),BLANK           BLANK OUT COINCIDING USER BYTE   53600000
DPI50    EQU   *                                                        54000000
         LA    DPIR,ONE(DPIR)          POINT TO NEXT DPI BYTE           54400000
         LA    BUFR,ONE(BUFR)          POINT TO NEXT USER BUFFER BYTE   54800000
         BCT   COUNTER,DPI40           CK ALL DPI BYTES, THEN CONTINUE  55200000
         TM    DCBRECFM,ASCII          ASCII USED                       55600000
         BZ    DDA2                    NO, GO CK FOR MACHINE CNTL CHAR  56000000
DDB2     EQU   *                                                        56400000
         L     BUFR,CCW1AD             GET BUFFER ADDRESS               56800000
         LA    WRKR3,TABLE             LOAD TABLE START ADDRESS         57200000
         LA    WRKR2,TABLY             TABLE END PLUS TWO               57600000
         LA    WRKR1,N2(Z0)            LOAD TABLE INCREMENT AMT         58000000
DDB3     CLC   Z0(ONE,BUFR),Z0(WRKR3)  COMPARE ASCII CHAR TO TABLE      58400000
         BE    DDB4                    BR IF ASCII CHAR IS FOUND        58800000
         BXLE  WRKR3,WRKR1,DDB3        INCR AND REPEAT IF NOT END       59200000
*                                                                       59600000
*  THIS ROUTINE WILL BUILD CCW'S AND ISSUE EXCP TO EXECUTE CCW'S BUILT  60000000
*                                                                       60400000
*                                                                       60800000
DDB4     EQU   *                                                        61200000
         LA    BUFR,ONE(BUFR)          PT TO FIRST CHAR FOR OUTPUT PROC 61600000
         IC    WRKR2,CCW2OP            STORE COMMAND BYTE OF WRT CCW    62000000
         ST    BUFR,CCW2OP             STORE DATA ADDR IN WRITE CCW     62400000
         STC   WRKR2,CCW2OP            RESTORE WRITE COMMAND            62800000
         LH    LRECLR,CCW1LN           LOAD BLOCK LENGTH                63200000
         BCTR  LRECLR,WRKR0            SUBTRACT ONE FROM BLOCK LENGTH   63600000
         STH   LRECLR,CCW2LN           STORE LENGTH IN WRITE CCW        64000000
         NI    CCW2OP,SSCLEAR          CLEAR STACKER SELECT OPTION      64400000
         OC    CCW2OP(ONE),ONE(WRKR3)  OR IN STACKER SELECT/OPTION      64800000
         LA    WRKR3,CCW2OP            START ADDRESS                    65200000
         ST    WRKR3,IOBSTAD           PUNCH START ADDRESS              65600000
         MVI   CCW2FL,SLI              TURN ON SILI BIT IN 2ND CCW      66000000
LABEL    EQU   *                                                        66400000
         LA    WRKR1,IOBIOS            LOAD IOS IOB ADDR FOR EXCP       66800000
         EXCP  (1)                     SCHEDULE I/O                     67200000
         NI    DCBCIND1,USED           INDICATE DCB HAS BEEN USED       67600000
         BCR   15,RETR                 RETURN TO WRITE/PUT ROUTINE      68000000
DDA2     EQU   *                                                        68400000
         IC    OPR,CCW2AD              SAVE OP CODE                     68800000
         L     BUFR,CCW1AD             LOAD BUFFER ADDR FROM CCW        69200000
         LH    LRECLR,CCW1LN           LOAD RECORD LENGTH               69600000
         TM    DCBRECFM,MCHAR          MACHINE CONTROL CHARACTERS USED  70000000
         BZ    DDA3                    NO, BRANCH                       70400000
         BCTR  LRECLR,Z0               SUBTRACT ONE                     70800000
         IC    OPR,0(BUFR)             INSERT CONTROL CHARACTER         71200000
         LA    BUFR,ONE(BUFR)          ADD ONE TO BUFFER ADDRESS        71600000
DDA3     EQU   *                                                        72000000
         ST    BUFR,CCW2AD             STORE RECORD ADDR IN WRITE CCW   72400000
         STH   LRECLR,CCW2LN           STORE LENGTH IN WRITE CCW        72800000
         STC   OPR,CCW2OP              STORE CMND BYTE IN WRITE CCW     73200000
         LA    LRECLR,CCW2OP           LOAD ADDR OF WRITE CCW           73600000
         ST    LRECLR,IOBSTAD          STORE START ADDRESS FOR IOS      74000000
         MVI   CCW2FL,SLI              TURN ON SILI BIT IN 2ND CCW      74400000
         B     LABEL                   BR TO SCHEDULE I/O               74800000
LEVELID  DC    C'01'                   MODULE LEVEL CONTROL             75200000
WRTOPROG EQU   *                                                        75600000
*                                                                       76000000
*  WRITE TO PROGRAMMER (WTP) AND ABEND ROUTINE                          76400000
*                                                                       76800000
         LR    BUFR,BASR               SAVE BASE ADDR                   77200000
         DROP  BASR                    DROP OLD BASE REG                77600000
         USING IGG019FK,BUFR           SET UP NEW BASE                  78000000
         WTO   'IEC950I 003-2 3525 ASSOCIATED DATA SET I/O SEQUENCE ERR*78400000
               OR',ROUTCDE=(11),DESC=4                                  78800000
         LR    BASR,BUFR               SAVE BASE ADDR.                  79200000
         DROP  BUFR                    DROP OLD BASE REG.               79600000
         USING IGG019FK,BASR           SET UP NEW BASE                  80000000
         B     ABEN                    BRANCH TO ISSUE ABNED            80400000
*                                                                       80800000
         DS    0F                      ALIGN ON A FULLWORD BOUNDARY     81200000
ABEND3   DC    X'00000003'             ABEND CODE OF 3                  81600000
ZEROES   DC    X'00000000'             WORK DC                          82000000
TABLE    DC    C'V'                    ASCII C CHAR FOR NEXT OP CODE    82400000
         DC    X'01'                   OP CODE-SELECT PUNCH STACKER 1   82800000
         DC    C'W'                    ASCII C CHAR FOR NEXT OP CODE    83200000
         DC    X'41'                   OP CODE-SELECT PUNCH STACKER 2   83600000
TABLY    EQU   TABLE+2                 POINTER                          84000000
*                                                                       84400000
ABEN     EQU   *                                                        84800000
         LA    BASR,N2                 INDICATE ASSOCIATED DATA         85200000
*                                      SET PUNCH SEQUENCE ERROR         85600000
*                                      CODE TO BE PASSED TO USER        86000000
*                                      VIA REGISTER 15                  86400000
         L     WRKR1,ABEND3            GET SAM ABEND ERROR CODE         86800000
         SLL   WRKR1,12                SET UP REGISTER ONE FOR ABEND    87200000
         ABEND (1),DUMP                ISSUE ABEND INSTRUCTION          87600000
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY * 88000000
*                                                                       88400000
         CNOP  0,8                     PAD MODULE TO DOUBLE-WD MULTIPLE 88800000
*                                                                       89200000
*  DSECTS  ************************************************************ 89600000
*                                                                       90000000
IOB      DSECT                                                          90400000
IOBLINK  EQU   IOB                                                      90800000
         DS    2F                      ECB AREA & ADDR OF NEXT IOB      91200000
IOBIOS   DS    1F                      IOBFLAGS AND SENSE INFO          91600000
         DS    3F                      ECB ADDR & CSW INFO              92000000
IOBSTAD  DS    1F                      CHANNEL PROG ADDRESS             92400000
         DS    3F                      DCB ADDR & OTHER INFO            92800000
CCW1OP   DS    1F                      OP CODE                          93200000
CCW1AD   EQU   CCW1OP                  CCW OP CODE                      93600000
CCW1FL   DS    1H                      FLAGS                            94000000
CCW1LN   DS    1H                      LENGTH                           94400000
CCW2OP   DS    1F                      OP CODE                          94800000
CCW2AD   EQU   CCW2OP                  CCW OP CODE                      95200000
CCW2FL   DS    1H                      FLAGS                            95600000
CCW2LN   DS    1H                      LENGTH                           96000000
IOBDPI   DS    CL80                    DPI IMAGE FORMAT                 96400000
         DCBD  DSORG=PS                                                 96800000
         IEZDEB                                                         97200000
         END                                                            97600000
