IGG019FR CSECT                                                          00700020
*          RELEASE 21 DELETIONS                                         00750021
*0100154000,217000,413000                                         M1758 00800021
* TITLE -- ABNORMAL END APPENDAGE FOR 3211 PRINTER                      01400020
* FUNCTION -- THIS MODULE IS AN ABNORMAL END APPENDAGE THAT SCHEDULES   02100020
*             AN ASYNCHRONOUS ROUTINE WHEN A BUFFER PARITY ERROR IS     02800020
*             TO BE RETRIED.  THE FIRST TIME THS MODULE RECIEVES        03500020
*             CONTROL IT RETURNS IOS SO THAT THE ERP CAN BE SCHEDULED.  04200020
*             ON THE SECOND ENTRY THIS MODULE TEST FOR BUFFER PARITY    04900020
*             ERRORS AND SCHEDULES THE ASYNCHRONOUS ROUTINE WHICH       05600020
*             WILL PERFORM THE RETRY.                                   06300020
* INPUT -- REGISTER 2 CONTAINS THE IOB ADDRESS, REGISTER 4 CONTAINS     07000020
*          THE DCB ADDRESS                                              07700020
* OUTPUT -- NONE                                                        08400020
* EXTERNAL REFERENCES -- CVT0EF00 TO SCHEDULE THE ASYNCHRONOUS ERROR    09100020
*                        ROUTINE.                                       09800020
* ENTRY POINT -- IGG0197G                                               10500020
* EXITS,NORMAL -- RETURN TO INPUT/OUTPUT SUPERVISOR                     11200020
* EXITS,ERROR -- NONE                                                   11900020
* TABLES/WORKAREAS -- NONE                                              12600020
* ATTRIBUTES -- REENTRANT,RESUABLE                                      13300020
*                                                                       14000020
NULL     EQU   X'00'                                                    14700020
DEBTCBAD EQU   X'00'                    OFFSET TO TCB ADDR IN DEB       16100020
DEBIRBAD EQU   X'08'                    OFFSET TO ADDR OF IRB IN DEB    16800020
TCBRBP   EQU   X'00'                    OFFSET TO RB ADDR IN TCB        17500020
IQEPAROF EQU   X'04'                    OFFSET TO IQEPARM FIELD         18200020
IQEOFF   EQU   X'60'                    OFFSET TO IQE ADDR IN IRB       18900020
CVTEEFOF EQU   X'04'        OFFSET TO ADDR EXT EFFECTOR IN CVT          19600020
TCBFX    EQU   29                       OFFSET TO TCB FLAG FOR ASN EXTS 20300020
NOASYNEX EQU   X'01'                    NO ASYNCHRONOUS EXITS FLG       21000020
IOBSNS1  EQU   X'03'                    OFFSET TO SNS BYTE 1 IN IOB     22400020
CMDRETRY EQU   X'80'                    MASK FOR COMMAND RETRY SNS 1    23100020
*                                       ADDRESS OF CVT ADDRESS          23800020
* NOTE -- THIS ROUTINE RELIES ON THE REGISTER USAGE OF IOS              24500020
*                                                                       25200020
RZERO    EQU   0                                                        25900020
RONE     EQU   1                                                        26600020
RIOB     EQU   2                        ADDR OF IOB PASSED FROM IOS     27300020
RDCB     EQU   4                        ADDR OF DCB PASSED FROM IOS     28000020
BASR5    EQU   5                        SAVE REG FOR BASR               28700020
RUCB     EQU   7                        ADDR OF UCB PASSED FROM IOS     29400020
RWRK1    EQU   10                       WORK REG 1                      30100020
RWRK2    EQU   11                       WORK REG 2                      30800020
RDEB     EQU   3                        ADDR OF DEB PASSED FROM IOS     31500020
RETRN    EQU   14                       ADDR USED TO RETURN TO IOS      32200020
BASR     EQU   15                       ADDR OF START OF APPENDAGE      32900020
         USING IGG019FR,BASR                                            33600020
         USING IHADCB,RDCB                                              34300020
         USING IOBSTDRD,RIOB                                      M1758 34350021
         STM   RZERO,BASR,SAVEAREA      SAVE REGS                       35000020
**********************************************************************  35700020
*                                                                       36400020
*   TEST IF THIS IS FIRST ENTRY FROM IOS                                37100020
*   * YES - RETURN TO IOS TO SCHEDULE 3211 ERP                          37800020
*   * NO  - GO TEST IF PRINT LINE SHOULD BE RETRIED                     38500020
*                                                                       39200020
**********************************************************************  39900020
*                                                                       40600020
         TM    IOBFLAG1,IOBIOERR        CK FOR 1ST ENTRY          M1758 41300021
         BO    ABAPP010                 NO RETURN TO IOS                42000020
*                                       NO GO CK FOR RETRY CONDITION    42700020
*                                       THE ERP CHANGES THE IOBECBCC    43400020
*                                       FIELD TO X'44'OR X'41' BEFORE   44100020
*                                       THE 2ND ENTRY                   44800020
*                                                                       45500020
**********************************************************************  46200020
*                                                                       46900020
*   TEST IF PRINT LINE IS TO BE RETRIED                                 47600020
*                                                                       48300020
**********************************************************************  49000020
*                                                                       49700020
         TM    IOBSNS1(RIOB),CMDRETRY   TEST IF COMMAND RETRY ON        50400020
         BO    ABAPP020                 YES GO SCHEDULE ROUTINE         51100020
*                                                                       51800020
**********************************************************************  52500020
*                                                                       53200020
*   RETURN TO IOS -- ADDRESS IN REG 14                                  53900020
*                                                                       54600020
**********************************************************************  55300020
*                                                                       56000020
ABAPP010 EQU   *                                                        56700020
*                                                                       57400020
         LM    RZERO,BASR,SAVEAREA      RESTORE REGS                    58100020
         BR    RETRN                    RETURN TO IOS                   58800020
*                                                                       59500020
**********************************************************************  60200020
*                                                                       60900020
*   TEST IF ASYNCHRONOUS ROUTINE SHOULD BE SCHEDULED                    61600020
*                                                                       62300020
**********************************************************************  63000020
*                                                                       63700020
*                                                                       64400020
ABAPP020 EQU   *                                                        65100020
*                                                                       65800020
         L     RWRK1,DEBTCBAD(RDEB)     GET ADDR OF TCB FROM DEB        66500020
         TM    TCBFX(RWRK1),NOASYNEX    TEST IF ASYN EXITS ALLOWED      67200020
         BO    ABAPP010                 NO RETURN TO IOS                67900020
         L     RWRK2,DEBIRBAD(RDEB)     GET ADDR OF IRB FROM DEB        68600020
         LA    RWRK2,NULL(RWRK2)       ZERO OUT BYTE 0                  69300020
         L     RWRK1,TCBRBP(RWRK1)      GET RB ADDR FROM TCB            70000020
         LA    RWRK1,NULL(RWRK1)        ZERO OUT BYTE 0                 70700020
         CR    RWRK2,RWRK1              TEST IF RB ADDR EQ IRB ADDR     71400020
         BE    ABAPP010                 YES-ERROR OCCURED DURING PRINT  72100020
*                                       LINE RETRY-RETURN TO IOS        72800020
*                                       NO -SCHEDULE ASYNCH RTN         73500020
*                                                                       74200020
**********************************************************************  74900020
*                                                                       75600020
*   SCHEDULE THE 3211 PRINT LINE RETRY MODULE (ASYNCHRONOUSLY)          76300020
*                                                                       77000020
**********************************************************************  77700020
*                                                                       78400020
         L     RONE,IQEOFF(RWRK2)       GET ADDR OF IQE FROM IRB        79100020
         LA    RONE,NULL(RONE)          ZERO BYTE 0                     79800020
         XC    NULL(4,RONE),NULL(RONE)      ZERO NXT IQE PTR            80500020
         ST    RDCB,IQEPAROF(RONE)      SAVE DCB ADDR FOR ERR RTY       81200020
         LCR   RONE,RONE                COMPLEMENT IQE ADDR FOR EXIT    81900020
*                                       EFFECTOR                        82600020
         LR    BASR5,BASR               SAVE BASE REG                   83300020
         L     BASR,CVTPTR              GET ADDR OF CVT                 84000020
         L     BASR,CVTEEFOF(BASR)    GET ADDR OF EXIT EFF              84700020
         BALR  RETRN,BASR           GO TO EXT EFFECTOR TO SCHED         85400020
*                                       ASYNCH RTN                      86100020
         LR    BASR,BASR5               RESTORE BASR                    86800020
         B     ABAPP010                 GO RTN TO IOS                   87500020
SAVEAREA DC    16F'0'     SAVE AREA FOR APPENDAGE                       88200020
CVT      DSECT                                                          88900020
         CVT                                                            89600020
         DCBD  DSORG=PS                                                 90300020
         IEZIOB                                                         90350021
         END                                                            91000020
