IGG019FS CSECT                                                          00100020
*          RELEASE 21 DELETIONS                                         00150021
*0100077000,150000,231000,248000,328000,354000,387000             M1759 00160021
*                                                                       00200020
*TITLE -- ASYNCHRONOUS ROUTINE TO PROCESS UCS AND PLB PARITY ERRORS     00300020
*                                                                       00400020
*FUNCTION -- DETERMINES IF THE ENTRY IS DUE TO A PLB PARITY ERROR OR    00500020
*            A UCS BUFFER PARITY ERROR                                  00600020
*            * PLB PARITY ERROR IS DENOTED BY EQUIPTMENT CHECK AND      00700020
*              COMMAND RETRY ON IN THE SENSE.                           00800020
*            * UCS PARITY ERROR IS DENOTED BY BUFFER PARITY ERROR AND   00900020
*              COMMAND RETRY ON IN THE SENSE.                           01000020
*         -- THE PRINT LINE ASSOCIATED WITH A PLB PARITY ERROR IS       01100020
*            RETRIED WHEN THE PROBLEM PROGRAM IS USING QSAM AND         01200020
*            3 OR MORE BUFFERS.                                         01300020
*         -- THE UCS IMAGE IS RELODED AND THE PRINT LINE RETRIED ON     01400020
*            A UCS PARITY ERROR WHEN THE PROBLEM PROGRAM IS USING QSAM  01500020
*            AND 3 OR MORE BUFFERS.                                     01600020
*         -- A SKIP TO CHANNEL 0 IS ISSUED TO RESET THE PRINTER WHEN    01700020
*            A PLB PARITY ERROR OCCURES AND THE PROBLEM PROGRAM IS      01800020
*            USING BSAM OR QSAM AND LESS THAN 3 BUFFERS.                01900020
*         -- THE UCS IMAGE IS RELOADED AND A SKIP TO CHANNEL 0 IS       02000020
*            ISSUED ON A UCS PARITY ERROR WHEN THE PROBLEM PROGRAM      02100020
*            IS USING BSAM OR QSAM ANB LESS THEN 3 BUFFERS              02200020
*                                                                       02300020
*ENTRY POINTS -- MODULE NAME (ROUTINE IS SCHEDULED ASYNCHRONOUSLY BY AN 02400020
*                ABNORMAL END APPENDAGE).                               02500020
*                                                                       02600020
*INPUTS -- DCB ADDR IN REG 1.                                           02700020
*                                                                       02800020
*OUTPUTS -- NONE                                                        02900020
*                                                                       03000020
*EXTERNAL ROUTINES USED - NONE                                          03100020
*                                                                       03200020
*EXITS NORMAL -- RETURN TO DISPATCHER VIA SVC 3 AND BACK TO CALLING RTN 03300020
*                                                                       03400020
*EXITS ERROR -- RETURN TO DISPATCHER VIA SVC 3 AND BACK TO CALLING RTN  03500020
*            -- RETURNS TO IOS                                          03600020
*                                                                       03700020
*TABLES/WORKAREAS -- CVT,IRB,DCB,IOB,BLDLIOB                            03800020
*                                                                       03900020
*ATTRIBUTES - REENTRANENT,REUSEABLE,MONITOR MODE                        04000020
*                                                                       04100020
**********************************************************************  04200020
*                                                                       04300020
*   REGISTER CONVENTIONS USED                                           04400020
*                                                                       04500020
IRBADR   EQU   8                       DISP OF IRB ADDR                 04600020
IQEADR   EQU   96                      DISP OF IQE ADDR                 04700020
RFLAG    EQU   24                      DISP TO RETRY FLAG               04800020
SKIP0    EQU   X'40'                   SKIP FLAG                        04900020
COMADR   EQU   8                       DISP TO CSW                      05000020
CPBEGIN  EQU   16                      DISP TO CP START                 05100020
RPAR1    EQU   0                                                        05200020
RPAR2    EQU   1                                                        05300020
RBASE    EQU   2                                                        05400020
RCVT     EQU   3                                                        05500020
RIOB     EQU   4                                                        05600020
RCORE    EQU   5                                                        05700020
RDCB     EQU   6                                                        05800020
RWORK1   EQU   7                                                        05900020
RWORK2   EQU   8                                                        06000020
RWORK3   EQU   9                                                        06100020
RWORK4   EQU   10                                                       06200020
RECB     EQU   11                                                       06300020
RUCB     EQU   12                                                       06400020
RSAVE    EQU   13                                                       06500020
RDEB     EQU   14                                                       06600020
RENTRY   EQU   15                                                       06700020
RJ       EQU   15                                                       06800020
RF       EQU   1                                                        06900020
RD       EQU   14                                                       07000020
RWKIOB   EQU   RWORK4                                                   07100020
*                                                                       07200020
**********************************************************************  07300020
*                                                                       07400020
*   DCB  MASKS                                                          07500020
*                                                                       07600020
PCIMASK  EQU   X'04'                    PCI MASK IN DCBCIND2     M1759  07700021
QSAMMASK EQU   X'01'                    QSAM MASK IN DCBIND2 FIELD      07800020
PRMERROF EQU   X'3F'            MASK TO TURN PERM ERR FLG OFF DCB       07900020
*                                                                       08000020
*                                                                       08100020
*   COMMAND CODE MASKS                                                  08200020
*                                                                       08300020
LDUCSCMD EQU   X'FB'                    COMMAND CODE EQ  LOAD UCS       08400020
FOLDCMD  EQU   X'43'                    COMMAND CODE EQ  FOLD UCS       08500020
SKP0CMD  EQU   X'83'                    COMMAND CODE EQ SKIP TO CH 0    08600020
NOOPCMD  EQU   X'03'                    NOOP COMMAND CODE               08700020
*                                                                       08800020
*   ERROR CONDITION MASKS                                               08900020
*                                                                       09000020
COMPOK   EQU   X'7F'                    SUCCESSFULL COMPLETION MASK     09100020
PERMERR  EQU   X'41'                    MASK FOR PERMANENT ERR COND.    09200020
INTERCPT EQU   X'44'                    MASK FOR INTERCEPT CONDITION    09300020
CSRESTRT EQU   X'02'                    RESTART BIT CHAINED SCHED       09400020
SILIMASK EQU   X'20'                    SET SILI BIT ON MASK            09500020
FOLDMK   EQU   X'40'                    FOLD UCS IMAGE SPECIFIED        09600020
CMCHMASK EQU   X'40'                    COMMAND CHAINING MASK           09700020
UNRLMASK EQU   X'02'                    IOB UNRELATED FLAG MASK         09800020
*                                                                       09900020
*   MASKS                                                               10000020
*                                                                       10100020
ECBADOFS EQU   X'0C'                    OFFSET TO ECB ADDR IN IOB       10200020
UCBADOFS EQU   X'20'                    OFFSET TO UCB ADDR IN DEB = 32  10300020
UCBEXOFS EQU   X'1C'                    OFFSET TO UCB EXTENTION =28     10400020
DCBADOFS EQU   X'1C'                    DCB ADDRESS OFFSET IN IOB =28   10500020
CPOFS    EQU   X'18'                    OFFSET TO CP ADDR IN IOB  =24   10600020
UCSOPOFS EQU   X'04'                    OFFSET TO UCS OPTIONS IN UCB    10700020
CSWOFS   EQU   X'10'                    OFFSET TO CSW  IN ICB           10800020
CPOFSC   EQU   X'20'                    CHANNEL PROG. OFFSET CHND SCH   10900020
UCSLNTH  EQU   512                      LENGTH OF UCS IMAGES            11000020
SUBPOOL  EQU   X'00'          SUBPOOL 0                                 11100020
SNSBY0OF EQU   X'0A'                    OFFSET TO IOB SNSBYTE 0         11200020
SNSBY1OF EQU   X'0B'                    OFFSET TO SNS BYTE 1            11300020
CMDRTYON EQU   X'80'                    MASK FOR CMD RTY BIT ON         11400020
EQCKFLG  EQU   X'10'                    MASK FOR EQ CK IN SNSBYTE0      11500020
BUFPARER EQU   X'04'                    BUFF PARITY ERR SNSBYTE0        11600020
SHIFT24  EQU   X'18'                    SHIFT MASK                      11700020
ECBADROF EQU   X'0C'                    OFFSET TO ECB ADDR IN IOB       11800020
ECBOFS   EQU   4                        OFFSET TO ECB IN IOB PREFX      11900020
PURGEMSK EQU   X'48'                    PURGE MASK                      12000020
*                                                                       12100020
*   CONSTANTS                                                           12200020
*                                                                       12300020
NULL     EQU   X'00'                                                    12400020
ONE      EQU   X'01'                                                    12500020
THREE    EQU   X'03'                                                    12600020
FOUR     EQU   X'04'                                                    12700020
EIGHT    EQU   X'08'                                                    12800020
K16      EQU   X'10'                    CONSTANT=16                     12900020
K12      EQU   X'0C'                DISP OF 12                          13000020
K52      EQU   X'34'         CONSTANT=52                                13100020
*                                                                       13200020
**********************************************************************  13300020
*                                                                       13400020
*   INITIALIZE REGISTER AND ENABLE ALL INTERUPTS                        13500020
*                                                                       13600020
**********************************************************************  13700020
*                                                                       13800020
         BALR  RBASE,0                  SET UP BASE REGISTER            13900020
         USING SYNE000,RBASE                                            14000020
         USING IHADCB,RDCB                                              14100020
         USING CVT,RCVT                                                 14200020
         USING SRT,RUCB                                                 14300020
         USING BLDLIOB,RCORE                                            14400020
*                                                                       14500020
SYNE000  EQU   *                        STARTING ADDRESS NAME           14600020
*                                                                       14700020
         LR    RDCB,RPAR2               GET DCB ADDR FROM REG1          14800020
         LA    RDCB,NULL(RDCB)          CLEAR BYTE 0                    14900020
         TM    DCBCIND2,PCIMASK        CHAINED SCHEDULING        M1759  15000021
         BO    CHAINR                  YES GO TO PROPER ROUTINE         15100020
         L     RIOB,DCBIOBA             GET IOB ADDR FROM DCB           15200020
*                                       *IOB PREFIX - NORMAL SCHEDULE   15300020
SYNE005  EQU   *                        *ICB - CHAINED SCHEDULING       15400020
*                                                                       15500020
         L     RECB,ECBADROF(RIOB)      GET ECB ADDR FROM IOB           15600020
*                                                                       15700020
*   TEST IF THIS IS THE IOB POSTED IN ERROR WITH A X'41' OR X'44'       15800020
*                                                                       15900020
         CLI   NULL(RECB),PERMERR       TEST IF IOB HAD PREM ERR        16000020
         BE    SYNE010                  YES GO DETERMINE ERROR          16100020
         CLI   NULL(RECB),INTERCPT      TEST IF IOB INTERCEPTED         16200020
         BE    SYNE010                  YES GO DETERMINE ERROR          16300020
*                                                                       16400020
*   GO TEST IF NEXT IOB IN ERROR                                        16500020
*                                                                       16600020
         L     RIOB,NULL(RIOB)         GET ADDR OF NEXT IOB             16700020
         LA    RIOB,NULL(RIOB)         CLEAR BYTE 0                     16800020
         C     RIOB,DCBIOBA             TEST FOR LAST IOB               16900020
         BNE   SYNE005                  NO GO TEST IF THIS IOB          17000020
*                                       IS IN ERROR                     17100020
         SVC   3                        YES NO IOB'S POSTED IN          17200020
*                                       ERROR RETURN TO DISPATCH        17300020
*                                                                       17400020
*********************************************************************   17500020
*                                                                       17600020
*   DETERMINE WHEATHER THE ERROR IS A PLB PARITY ERROR OR A UCS PARITY  17700020
*   ERROR AND IF IT IS RETRYABLE                                        17800020
*                                                                       17900020
*********************************************************************   18000020
*                                                                       18100020
SYNE010  EQU   *                                                        18200020
*                                                                       18300020
         TM    SNSBY1OF(RIOB),CMDRTYON  TEST IF COMAND RTY ON.          18400020
         BNO   SYNE015                  NO RETURN TO DISPATCHER         18500020
         TM    SNSBY0OF(RIOB),EQCKFLG   TEST IF EQ CK ON                18600020
         BO    SYNE050                  YES GO TEST IF PLB PARITY       18700020
*                                       ERROR IS RETRYABLE              18800020
         TM    SNSBY0OF(RIOB),BUFPARER  TEST IF BUFFER PARITY ERR       18900020
*                                       IS ON                           19000020
         BO    SYNE020                  YES GO RELOAD UCS BUFFER.       19100020
*                                       ERROR IS NOT RETRYABLE BY THIS  19200020
*                                       ROUTINE - RETURN TO DISPATCHER  19300020
*                                                                       19400020
SYNE015  EQU   *                                                        19500020
*                                                                       19600020
         SVC   3                        RETURN TO DISPATCHER.           19700020
*                                                                       19800020
*                                                                       19900020
**********************************************************************  20000020
*                                                                       20100020
*   ROUTINE TO RELOAD THE UCS BUFFER                                    20200020
*   (1) FINDS UCS ID IN UCB                                             20300020
*   (2) DOES BLDL TO FIND UCS IMAGE                                     20400020
*   (3) LOADS UCS IMAGE INTO CPU CORE                                   20500020
*   (4) BUILDS CCW'S TO LOAD UCS AND EXECUTE                            20600020
*                                                                       20700020
**********************************************************************  20800020
*                                                                       20900020
SYNE020  EQU   *                                                        21000020
*                                                                       21100020
         L     RDEB,DCBDEBAD            GET ADDRESS OF DEB FROM DCB     21200020
         L     RUCB,UCBADOFS(RDEB)      GET ADDRESS OF UCB FROM DEB     21300020
         L     RWORK1,UCBEXOFS(RUCB)    GET ADDRESS OF UCS ID AND UCB   21400020
         LA    RPAR1,SUBPOOL            GET SUBPOOL NUMBER              21500020
         SLL   RPAR1,SHIFT24            MOVE SUBPOOL NO TO BYTE0        21600020
         IC    RPAR1,WKARSIZE           GET LENGTH OF WORK AREA         21700020
         GETMAIN R,LV=(0)             ISSUE GETMAIN                     21800020
         LR    RCORE,RF                 GET ADDR OF WORK AREA           21900020
*                                       EXTENTION FROM UCB              22000020
*                                                                       22100020
*   BLDL ROUTINE TO LOCATE THE UCS IMAGE IN SVCLIB                      22200020
*                                                                       22300020
         MVC   WORKAREA(4),BLDLLTHC     MOVE BLDL LENGTH TO BLDL LIST   22400020
         MVC   WORKAREA+4(4),UCSCONST   MOVE 'UCS2' TO BLDL LIST        22500020
         MVC   WORKAREA+8(4),NULL(RWORK1) MOVE UCS ID FROM UCB TO LIST  22600020
         SR    RPAR2,RPAR2      SET INPUT FOR SVC U/K                   22700020
         SVC   105       OPEN IMAGE LIB                                 22800020
         LTR   15,15    TEST IF IMAGE LIB OPENED                        22900020
         BZ    GOOD                    YES,  CONTINUE                   23000020
         TM    DCBCIND2,PCIMASK        CHAIN   SCHEDULING       M1759   23100021
         BO    GOAGAIN                 YES, DO RETRY                    23200020
         B     SYNE100                 DO SKIP TO 0                     23300020
GOOD     EQU   *                                                        23400020
         ST    RPAR2,IMDCBSAV    SAVE ADDR OF IMAGELIB                  23500020
         LA    RPAR1,WORKAREA           GET ADDR OF LIST FOR BLDL       23600020
*                                                                       23700020
         BLDL  (1),(0)                  ISSUE BLDL TO LOCATE THE IMAGE  23800020
*                                                                       23900020
*   TEST RETURN CODE FROM BLDL                                          24000020
*   -X'00'-IMAGE FOUND                                                  24100020
*   -X'04'-IMAGE NOT FOUND                                              24200020
*   -X'08'-PERMANENT I/O ERROR DURING BLDL                              24300020
*                                                                       24400020
         LTR   RJ,RJ                    CK IF BLDL SUCCESSFUL IN        24500020
*                                       FINDING THE UCS IMAGE           24600020
         BZ    GEP                     YES, CONTINUE                    24700020
         TM    DCBCIND2,PCIMASK        CHAINED SCHEDULING        M1759  24800021
         BO    GOAGAIN                 YES, DO RETRY                    24900020
         B     SYNE100                  NO GO RESET CONTROL UNIT SKP 0  25000020
GEP      EQU   *                                                        25100020
*                                                                       25200020
**********************************************************************  25300020
*                                                                       25400020
*   USE LOAD MACRO TO LOAD UCS IMAGE FROM SVCLIB INTO CPU CORE          25500020
*                                                                       25600020
**********************************************************************  25700020
*                                                                       25800020
         LA    RPAR1,WORKAREA+4         GET ADDR OF ENTRY POINT NAME    25900020
         L     RPAR2,IMDCBSAV     GET ADDR OG IMAGELIB DCB              26000020
*                                                                       26100020
         LOAD  DE=(0),DCB=(1)           ISSUE LOAD TO LOAD IMAGE        26200020
*                                                                       26300020
         LR    RWORK3,RPAR1             SAVE ADDR OF WHERE UCS LOADED   26400020
         SR    RPAR2,RPAR2   ZERO REG 1                                 26500020
         IC    RPAR2,ONE(RWORK3)    GET N VERIFY LINES                  26600020
         LA    RWORK3,2(RWORK3,RPAR2)   GET UCS START ADDR              26700020
*                 UCS START = ADDR LOAD MOD +2 +N VERIFY LINES          26800020
         L     RPAR2,IMDCBSAV           GET IMAGELIB DCB TO CLOSE       26900020
         SVC   105    CLOSE IMAGELIB                                    27000020
*                                                                       27100020
**********************************************************************  27200020
*                                                                       27300020
*   BUILD IOB AND CCW'S TO LOAD UCS IMAGE INTO THE UCS BUFFER           27400020
*                                                                       27500020
**********************************************************************  27600020
*                                                                       27700020
*   BUILD IOB                                                           27800020
*                                                                       27900020
         LA    RWKIOB,K12(RCORE)    GET ADDR FOR IOB                    28000020
         XC    NULL(40,RWKIOB),NULL(RWKIOB) INITIALIZE IOB              28100020
         ST    RWKIOB,NULL(RWKIOB)      LINK WORK IOB TO ITSELF         28200020
         LA    RWORK2,FOUR(RWKIOB)      GET ECB ADDRESS                 28300020
         ST    RWORK2,ECBADOFS(RWKIOB)  STORE ECB ADDRESS IN IOB        28400020
         MVI   SIOBFLG1,UNRLMASK        SET IOB UNRELATED.              28500020
         ST    RDCB,DCBADOFS(RWKIOB)    STORE DCB ADDR IN IOB           28600020
         LA    RWORK2,SCCW1             GET ADDR OF CCW'S               28700020
         ST    RWORK2,CPOFS(RWKIOB)     STORE ADDR OF CP IN IOB         28800020
*                                                                       28900020
*   FORM CCW'S TO LOAD UCS                                              29000020
*                                                                       29100020
         XC    SCCW1(16),SCCW1          RESET CCW'S                     29200020
         ST    RWORK3,SCCW1             STORE ADDR OF UCS IMAGE IN CCW  29300020
         MVI   SCCW1,LDUCSCMD           MOVE IN LOAD UCS COMMAND CODE   29400020
         LA    RWORK2,UCSLNTH           GET LENGTH OF UCS IMAGE         29500020
         ST    RWORK2,SCCW1+4           STORE LENGTH OF UCS IN CCW      29600020
         TM    UCSOPOFS(RWORK1),FOLDMK  CK IF FOLD SPECIFIED IN UCS OP  29700020
         BNO   SYNE025                  NO GO TO EXCP                   29800020
         OI    SCCW1+4,CMCHMASK         SET COMMAND CHAINING IN CCW     29900020
*                                                                       30000020
*   FORM CCW TO FOLD UCS                                                30100020
*                                                                       30200020
         MVI   SCCW2+7,ONE              SET LENGTH EQ 1                 30300020
         MVI   SCCW2+4,SILIMASK         SET SILI ON                     30400020
         MVI   SCCW2,FOLDCMD            GET COMMAND CODE TO FOLD UCS    30500020
*                                                                       30600020
*   ISSUE EXCP TO LOAD UCS                                              30700020
*                                                                       30800020
SYNE025  EQU   *                        LOAD UCS EXCP                   30900020
*                                                                       31000020
         LA    RWORK2,ONE               SET COUNTER FOR 1 RETRY         31100020
*                                                                       31200020
SYNE030  EQU   *                        ENTRY FOR RETRY OF UCS LOAD     31300020
*                                                                       31400020
         NI    DCBIFLGS,PRMERROF     TURN PERM ERR FLGS OFF             31500020
         MVI   SIOBECB,NULL             POST ECB NOT COMPLETE           31600020
         LA    RPAR2,SIOB               GET IOB ADDR FOR EXCP           31700020
*                                                                       31800020
         EXCP  (1)                      ISSUE EXCP                      31900020
*                                                                       32000020
         LA    RPAR2,SIOBECB            GET ADDR OF ECB FOR WAIT MACRO  32100020
*                                                                       32200020
         WAIT  ECB=(1)                  WAIT FOR UCS LOAD               32300020
*                                                                       32400020
         TM    SIOBECB,COMPOK           CK FOR SUCCESSFUL COMPLETION    32500020
         BO    SYNE040                  YES GO DELETE UCS IMAGE         32600020
         BCT   RWORK2,SYNE030           IF ERROR RETRY ONCE             32700020
         TM    DCBCIND2,PCIMASK        CHAINED SCHEDULING        M1759  32800021
         BO    MESS                    YES, DONT DO SKIP YET            32900020
*                                                                       33000020
*********************************************************************   33100020
*                                                                       33200020
*   UNABLE TO LOAD UCS - RESET 3811 CONTROL UNIT AND ISSUE MESSAGE      33300020
*   'IEC126I     UNCORRECTABLE ERROR LOADING UCS '                      33400020
*                                                                       33500020
*********************************************************************   33600020
*                                                                       33700020
*                                                                       33800020
         LA    RWORK2,SKP0CCW           GET ADDR OF SKP CH 0 CCW        33900020
         ST    RWORK2,CPOFS(RWKIOB)     STORE ADDR OF SKP 0 CCW         34000020
         LA    RPAR2,SIOB               GET ADDR OF IOB FOR EXCP        34100020
*                                                                       34200020
         EXCP  (1)                      ISSUE SKIP TO CH 0              34300020
*                                                                       34400020
         L     RPAR2,SIOB+FOUR          GET ECB ADDR                    34500020
         WAIT   ECB=(1)                 WAIT FOR SKP 0                  34600020
MESS     EQU   *                                                        34700020
         MVC   WORKAREA(K52),DSPLY126   MOVE MSG+DES+RT CODES TO MSG    34800020
         MVC   WORKAREA+12(3),UCBNAME   MOVE DEVICE NAME INTO MESSAGE   34900020
         LA    RPAR2,WORKAREA           GET ADDR OF MESSAGE FOR WTO     35000020
         SVC   35                       ISSUE WTO                       35100020
*                                                                       35200020
         BAL   RWKIOB,SYNE045    GO FREE WORK AREA                      35300020
         TM    DCBCIND2,PCIMASK       CHAIN SCHEDULING?         M1759   35400021
         BO    GOAGAIN                 RETRY LINE                       35500020
*                                                                       35600020
         SVC   3                        RETURN TO DISPATCHER            35700020
*                         ,             UNABLE TO RETRY                 35800020
*                                                                       35900020
*********************************************************************   36000020
*                                                                       36100020
*   DELETE UCS IMAGE LOADED FROM SYS1.SVCLIB                            36200020
*                                                                       36300020
*********************************************************************   36400020
*                                                                       36500020
SYNE040  EQU   *                                                        36600020
*                                                                       36700020
         LA    RPAR1,WORKAREA+4         GET ADDR OF MEMBER NAME TO DEL  36800020
*                                                                       36900020
         DELETE EPLOC=(0)               DELETE IMAGE LOADED             37000020
*                                                                       37100020
         LA    RWKIOB,SYNE050    SET ADDR FOR BC AFTER FREE W A         37200020
*                                                                       37300020
SYNE045  EQU   *                                                        37400020
         SR    RPAR1,RPAR1     ZERO OUT REG 0                           37500020
         IC    RPAR1,WKARSIZE       GET SIZE OF WORK AREA               37600020
         LR    RPAR2,RCORE       GET ADDR OF WRK AREA                   37700020
         FREEMAIN  R,LV=(0),A=(1)                                       37800020
         BR    RWKIOB     CONTINUE                                      37900020
**********************************************************************  38000020
*                                                                       38100020
*   DETERMINE IF RETRY OF PLB POSSIBLE OR ISSUE SKIP TO CHANNEL 0       38200020
*                                                                       38300020
**********************************************************************  38400020
*                                                                       38500020
SYNE050  EQU   *                        ENTRY FOR PLB PARITY ERR RTRY   38600020
         TM    DCBCIND2,PCIMASK         CHAIN SCHEDULING         M1759  38700021
         BO    GOAGAIN                 DO RETRY                         38800020
*                                                                       38900020
         TM    DCBCIND2,QSAMMASK        CK DCB FOR QSAM BEING USED      39000020
         BNO   SYNE100                  NO GO ISSUE SKIP TO CH 0        39100020
         CLI   DCBBUFNO,THREE           CK IF 3 OR MORE BUFFERS IN DCB  39200020
         BL    SYNE100                  NO GO ISSUE SKIP TO CH 0        39300020
*                                                                       39400020
*   FIND IOB ASSOCIATED WITH THE FAILING PRINT LINE. UNDER NORMAL       39500020
*   SCHEDULING IT IS THE IOB PROCEEDING THE INTERCEPTED IOB             39600020
*                                                                       39700020
         LR    RWORK2,RIOB              SAVE IOB IN ERR ADDR            39800020
*                                                                       39900020
SYNE055  EQU   *                                                        40000020
*                                                                       40100020
         L     RWORK3,NULL(RIOB)        GET ADDR OF NEXT IOB            40200020
         LA    RWORK3,NULL(RWORK3)      ZERO OUT HIGH ORDER BYTE        40300020
         CLI   FOUR(RWORK3),INTERCPT    CK IF NEXT IOB INTERCEPTED      40400020
         BE    SYNE060                  YES GO RESCHEDULE IOB           40500020
*                                       NO CONTINUE TESTING IOB'S       40600020
         LR    RIOB,RWORK3              UPDATE IOB ADDR                 40700020
         CR    RWORK3,RWORK2            CK IF ALL IOB'S TSTED           40800020
         BNE   SYNE055                  NO GO TEST NEXT IOB             40900020
         SVC   3                        YES INTERCEPTED IOB NOT         41000020
*                                       FOUND RETURN TO CALLING RTN     41100020
*                                                                       41200020
*   REISSUE FAILING IOB                                                 41300020
*                                                                       41400020
SYNE060  EQU   *                                                        41500020
*                                                                       41600020
         NI    DCBIFLGS,PRMERROF   TURN OFF PERM ERR FLGS               41700020
         MVI   FOUR(RIOB),NULL          RESET ECB TO NOT COMPLETE       41800020
         LA    RPAR2,EIGHT(RIOB)        GET ADDR OF IOB FOR EXCP        41900020
*                                                                       42000020
         EXCP  (1)                      REISSUE FAILING PRINT LINE      42100020
*                                                                       42200020
         LA    RPAR2,FOUR(RIOB)         GET ADDR OF ECB FOR WAIT        42300020
*                                                                       42400020
         WAIT  ECB=(1)                  ISSUE WAIT FOR CP TO PRT LINE   42500020
*                                                                       42600020
         CLI   FOUR(RIOB),COMPOK        CK FOR SUCCESSFUL COMP X'7F'    42700020
         BNE   SYNE090                  NO GO CK IF SAME ERR PERSISTS   42800020
*                                                                       42900020
*   RESCHEDULE INTERCEPTED OR FAILING IOB AND CK FOR ERROR              43000020
*                                                                       43100020
         LA    RPAR2,EIGHT(RWORK3)      GET ADDR OF NEXT IOB FOR EXCP   43200020
*                                                                       43300020
         EXCP  (1)                      REISSUE FAILING OR X'44' IOB    43400020
*                                                                       43500020
         LA    RPAR2,FOUR(RWORK3)       GET ADDR OF ECB FOR WAIT        43600020
*                                                                       43700020
         WAIT  ECB=(1)                  ISSUE WAIT                      43800020
*                                                                       43900020
         CLI   FOUR(RWORK3),COMPOK      CK FOR SUCCESSFUL COMPLETION    44000020
         BNE   SYNE090                  NO GO CK IF SAME ERR PERSISTS   44100020
*                                       YES RESCHEDULE REST OF IOB'S    44200020
*                                                                       44300020
*   RESCHEDULE THE OTHER IOB'S                                          44400020
*                                                                       44500020
SYNE070  EQU   *                                                        44600020
*                                                                       44700020
         L     RWORK3,NULL(RWORK3)      GET ADDR OF NEXT IOB TO RESCH   44800020
         LA    RWORK3,NULL(RWORK3)      ZERO OUT HIGH ORDER BYTE        44900020
         CR    RIOB,RWORK3              CK IF ALL IOB'S RESCHEDULED     45000020
         BE    SYNE080                  YES GO RETURN TO USER           45100020
         CLI   ECBOFS(RWORK3),PURGEMSK    CK IF IOB PURGED              45200020
         BNE   SYNE070                  NO DON'T RESCHEDULE             45300020
         LA    RPAR2,EIGHT(RWORK3)      GET IOB ADDR FOR EXCP           45400020
*                                                                       45500020
         EXCP  (1)                      RESCHEDULE IOB                  45600020
*                                                                       45700020
         B     SYNE070                  GO GET NEXT IOB TO RESCHEDULE   45800020
*                                                                       45900020
*********************************************************************   46000020
*                                                                       46100020
*   RETURN TO CALLING ROUTINE                                           46200020
*                                                                       46300020
*********************************************************************   46400020
*                                                                       46500020
SYNE080  EQU   *                                                        46600020
*                                                                       46700020
         SVC   3                        RETURN TO CALLING RTN           46800020
*                                                                       46900020
*********************************************************************   47000020
*                                                                       47100020
*   RETRYABLE ERR WITH PCI SCHEDULING                                   47200020
*                                                                       47300020
*********************************************************************   47400020
*                                                                       47500020
SYNE085  EQU   *                                                        47600020
         TM    FOUR(RWORK3),PERMERR     TEST IF NEXT ICB HAS PERM ERR   47700020
         BNE   SYNE080                  NO RETURN TO CALLING RTN        47800020
*                                                                       47900020
*   FIND FAILING CCW BY USING CSW INFORMATION IN ICB                    48000020
*                                                                       48100020
         L     RPAR1,CSWOFS(RWORK3)    GET COMMAND ADDR FROM ICB        48200020
         LA    RPAR1,NULL(RPAR1)       Z)RO HIGH ORDER BYTE             48300020
         LA    RPAR2,EIGHT             GET DISPLACEMENT TO CCW          48400020
         SR    RPAR2,RPAR1             GET ADDR OF CCW THAT FAILED      48500020
*                                                                       48600020
*   SET UP TO ISSUE FAILING CCW                                         48700020
*                                                                       48800020
         L     RWORK2,DCBIOBAD         GET ADDR OF IOB FROM DCB         48900020
         L     RWORK4,CPOFSC(RWORK2)   SAVE DADR OF CP IN IOB           49000020
         ST    RPAR2,CPOFSC(RWORK2)    STORE ADDR OF CP IN IOB TO RTY   49100020
         NI    DCBIFLGS,PRMERROF   TURN OFF PERM ERR FLGS               49200020
         LA    RPAR2,K16(RWORK2)       GET ADDR OF IOB FOR EXCP         49300020
*                                                                       49400020
         EXCP  (1)                                                      49500020
*                                                                       49600020
         LR    RPAR2,RWORK2            GET ADDR OF ECB                  49700020
*                                                                       49800020
         WAIT  ECB=(1)                 WAIT FOR EXCP TO FINISH          49900020
*                                                                       50000020
         TM    FOUR(RWORK2),COMPOK     CK FOR SUCCESSFUL COMPLETION     50100020
         BNO   SYNE090                 NO GO CK IF ANOTHER RETRY ERR    50200020
         TM    NULL(RWORK2),CSRESTRT   CK IF RESTART BIT ON IN IOB      50300020
         BNO   SYNE080                 NO RETURN TO PERR RTN            50400020
*                                      YES RESTART CHANNEL PROB         50500020
         ST    RWORK4,CPOFSC(RWORK2)   RESET IOB C.P. ADDRESS           50600020
         LA    RPAR2,K16(RWORK2)       GET IOB ADDR FOR EXCP            50700020
         MVI   FOUR(RWORK2),NULL       POST IOB NOT COMPLETE            50800020
*                                                                       50900020
         EXCP  (1)                     RESCHEDULE REMAINDER OF CP       51000020
*                                                                       51100020
         B     SYNE080                 RETURN TO PUT ERR ROUTINE        51200020
*                                                                       51300020
*                                                                       51400020
*   CHECK IF STILL HAVE RETRYABLE ERROR AND IF SO ISSUE SKIP TO 0       51500020
*                                                                       51600020
SYNE090  EQU   *                                                        51700020
*                                                                       51800020
*                                                                       51900020
         TM    SNSBY1OF(RIOB),CMDRTYON  TEST IF COMMAND RTY BIT ON      52000020
         BO    SYNE100                  YES GO ISSUE SKP CH 0           52100020
         B     SYNE080                  NO RETURN TO CALLING RTN        52200020
*                                                                       52300020
**********************************************************************  52400020
*                                                                       52500020
*   FORM SKIP TO CH 0 CCW TO RESET 2811 CONTROL UNIT                    52600020
*                                                                       52700020
**********************************************************************  52800020
*                                                                       52900020
SYNE100  EQU   *                                                        53000020
*                                                                       53100020
         L     RWORK2,CPOFS(RIOB)       SAVE IOB'S CP ADDR + SIO C.C.   53200020
         LA    RWORK4,SKP0CCW           GET ADDR OF SKP 0 CCW           53300020
         ST    RWORK4,CPOFS(RIOB)       STORE ADDR OF WORK CCW IN IOB   53400020
         LA    RPAR2,EIGHT(RIOB)        GET ADDR OF IOB FOR EXCP        53500020
         OI    NULL(RPAR2),UNRLMASK     MAKE IOB UNRELATED              53600020
*                                                                       53700020
*        EXCP  (1)                      ISSUE SKIP TO 0 COMMAND         53800020
         LA    RPAR2,FOUR(RIOB)         GET ECB ADDR FOR WAIT           53900020
*                                                                       54000020
         WAIT  ECB=(1)                  WAIT FOR SKIP 0 TO COMPLETE     54100020
*                                                                       54200020
         XI    EIGHT(RIOB),UNRLMASK   TURN OFF UNRELATED FLG            54300020
         ST    RWORK2,CPOFS(RIOB)       RESET IOB CP ADDR               54400020
         B     SYNE080                  RETURN TO CALLING RTN           54500020
*                                                                       54600020
*                                                                       54700020
*                                                                       54800020
CHAINR   L     RIOB,DCBIOBAD           GRT ADDR MAIN IOB                54900020
         L     RDEB,DCBDEBAD           DET DEB ADDR                     55000020
         L     RWORK1,IRBADR(RDEB)     GET IRB ADDR                     55100020
         L     RWORK1,IQEADR(RWORK1)   GET IQE ADDR                     55200020
         TM    RFLAG(RWORK1),SKIP0     SHOULD WE SKIP TO 0              55300020
         BO    CSKIP                   YES, GO DO IT                    55400020
*                                                                       55500020
         LA    RIOB,EIGHT(RIOB)        POINT AT IOB LESS 8              55600020
         TM    SNSBY0OF(RIOB),EQCKFLG  PLB PARITY ERR                   55700020
         BZ    SYNE020                 NO, UCS BUFFER PARITY ERR        55800020
*                                                                       55900020
GOAGAIN  LA    RIOB,EIGHT(RIOB)        POINT AT IOB START               56000020
         L     RWORK1,COMADR(RIOB)     GRT COMMAND ADDR                 56100020
         LA    RWORK1,NULL(RWORK1)     CLEAR HIGH ORDER                 56200020
         LA    RWORK2,EIGHT            GRT DECREMENT                    56300020
         SR    RWORK1,RWORK2           POINT AT BAD COMMAND             56400020
         ST    RWORK1,CPBEGIN(RIOB)    CHANGE CP ADDR                   56500020
         NI    DCBIFLGS,PRMERROF       TURN OFF ERR FLAGS               56600020
         LR    RF,RIOB      SET ADDR IN REG1 FOR EXCP                   56700020
         EXCP  (1)                     DO RETRY                         56800020
         B     SYNE080                 GO RETURN                        56900020
*                                                                       57000020
CSKIP    LA    RPAR1,SUBPOOL           SPECIFY SUBPOOL 0                57100020
         SLL   RPAR1,SHIFT24           MOVE TO BYTE 0                   57200020
         IC    RPAR1,WKARSIZE          GET LENGTH                       57300020
         GETMAIN   R,LV=(0)            GET CORE                         57400020
         LR    RCORE,RF                ADDR OF CORE INTO RCORE          57500020
         LA    RWKIOB,K12(RCORE)       POINT TO IOB                     57600020
         XC    NULL(40,RWKIOB),NULL(RWKIOB)  CLEAR AREA                 57700020
         ST    RWKIOB,NULL(RWKIOB)     POINT IOB TO ITSELF              57800020
         LA    RWORK2,FOUR(RWKIOB)     GET ECB ADDR                     57900020
         ST    RWORK2,ECBADOFS(RWKIOB)  STORE ECB ADDR IN IOB           58000020
         MVI   SIOBFLG1,UNRLMASK       SET UNRELATED                    58100020
         ST    RDCB,DCBADOFS(RWKIOB)   STORE DCB ADDR                   58200020
         LA    RWORK2,SCCW1            GET CCW ADDR                     58300020
         ST    RWORK2,CPOFS(RWKIOB)    STORE IT                         58400020
         XC    SCCW1(16),SCCW1         CLEAR CCWS                       58500020
         MVC   SCCW1(8),SKP0CCW        SET FOR SKIP                     58600020
         NI    DCBIFLGS,PRMERROF       RESET FLAGS                      58700020
         LA    RPAR2,SIOB              GET IOB ADDR                     58800020
*                                                                       58900020
         EXCP  (1)                     SKIP TO 0                        59000020
         LA    RPAR2,SIOBECB           GET ECB ADDR                     59100020
         WAIT  ECB=(1)                                                  59200020
         SVC   3                       EXIT                             59300020
**********************************************************************  59400020
*                                                                       59500020
*   CONSTANTS                                                           59600020
*                                                                       59700020
WKARSIZE DC    X'4C'                    LENGTH OF WORK AREA             59800020
SKP0CCW  CCW   X'83',0,X'20',1          CCW TO RESET 3211               59900020
BLDLLTHC DC    X'00010030'                                              60000020
UCSCONST DC    C'UCS2'                                                  60100020
DSPLY126 DC    X'00308000'                                              60200020
         DC    C'IEC126I     UNCORRECTABLE ERROR LOADING UCS '          60300020
DESROUT  DC    X'10000200'    DES AND ROUTING CODES                     60400020
*                                                                       60500020
**********************************************************************  60600020
*   WORK AREA FOR BLDL AND IOB TO LOAD UCS - OVERLAY OF SVRB EXTENTION  60700020
*                                                                       60800020
**********************************************************************  60900020
BLDLIOB  DSECT                                                          61000020
WORKAREA DS    CL12                                                     61100020
SIOBFLGS DS    0F                                                       61200020
SNXTIOBA DS    F        12                                              61300020
SIOBECB  DS    F        16                                              61400020
SIOB     DS    0F       20                                              61500020
SIOBFLG1 DS    CL1      21                                              61600020
SIOBFLG2 DS    CL1       2                                              61700020
SIOBSNS0 DS    CL1       3                                              61800020
SIOBSNS1 DS    CL1       4                                              61900020
SECBCC   DS    0F                                                       62000020
SIOBECBA DS    F        28                                              62100020
SIOBFLG3 DS    0F                                                       62200020
SIOBCSW  DS    2F       36                                              62300020
SIBSIOCC DS    0F                                                       62400020
SIOBSTRT DS    F        40                                              62500020
SIOBDCB  DS    F        44                                              62600020
SIOBREST DS    2F                                                       62700020
SCCW1    DS    D                                                        62800020
SCCW2    DS    D                                                        62900020
IMDCBSAV DS    F    SAVE AREA FOR IMGLIG DCB ADDR                       63000020
*                                                                       63100020
         DCBD  DSORG=PS                                                 63200020
*                                                                       63300020
SRT      DSECT                                                          63400020
         IEFUCBOB                                                       63500020
CVT      DSECT                                                          63600020
         CVT                                                            63700020
         END                                                            63800020
